data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float stomachkick_delay, system_delay, action_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         float swallow_range;\r
  16         vector vore_w_shotorg, vore_w_shotdir;\r
  17 \r
  18         swallow_range = cvar("g_balance_vore_swallow_range");\r
  19         if(cvar("g_healthsize")) // we can swallow from further or closer based on our size\r
  20                 swallow_range *= self.scale;\r
  21         makevectors(self.angles);\r
  22         vore_w_shotorg = self.origin;\r
  23         vore_w_shotdir = v_forward;\r
  24 \r
  25         if(self.antilag_debug)\r
  26                 WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, self.antilag_debug);\r
  27         else\r
  28                 WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
  29         if(trace_fraction < 1)\r
  30         if(trace_ent.classname == "player")\r
  31                 return trace_ent;\r
  32         return world;\r
  33 }\r
  34 \r
  35 float Swallow_condition_check(entity prey)\r
  36 {\r
  37         // checks the necessary conditions for swallowing a player\r
  38 \r
  39         if(prey != self)\r
  40         if(prey.classname == "player" && !prey.stat_eaten && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  41         if(self.classname == "player" && !self.stat_eaten && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  42         if(!self.BUTTON_REGURGITATE && time > self.action_delay)\r
  43         if not(vlen(self.velocity) > cvar("g_balance_vore_load_pred_speedcap") / (self.stomach_maxload / self.stomach_load))\r
  44         {\r
  45                 string swallow_complain;\r
  46                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  47                         swallow_complain = "You cannot swallow your team mates\n";\r
  48                 else if(!cvar("g_vore_spawnshield") && prey.spawnshieldtime > time)\r
  49                         swallow_complain = "You cannot swallow someone protected by the spawn shield\n";\r
  50                 else if(self.stomach_load >= self.stomach_maxload)\r
  51                         swallow_complain = "You do not have any more room to swallow this player.\n";\r
  52                 else if(cvar("g_vore_biggergut") && prey.stomach_load > self.stomach_load)\r
  53                         swallow_complain = "You cannot swallow someone with a bigger stomach than yours\n";\r
  54                 else if(cvar("g_vore_biggersize") && prey.scale > self.scale)\r
  55                         swallow_complain = "You cannot swallow someone larger than you\n";\r
  56 \r
  57                 if(swallow_complain != "")\r
  58                 {\r
  59                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  60                         {\r
  61                                 play2(self, "misc/forbidden.wav");\r
  62                                 sprint(self, swallow_complain);\r
  63                                 self.complain_vore = time + complain_delay_time;\r
  64                         }\r
  65                         return FALSE;\r
  66                 }\r
  67                 return TRUE;\r
  68         }\r
  69         return FALSE;\r
  70 }\r
  71 \r
  72 float Stomach_TeamMates_check(entity pred)\r
  73 {\r
  74         // checks if a player's stomach contains any team mates\r
  75 \r
  76         entity head;\r
  77         if(teams_matter)\r
  78         {\r
  79                 FOR_EACH_PLAYER(head)\r
  80                 {\r
  81                         if(head.predator == pred && head.team == pred.team)\r
  82                                 return TRUE;\r
  83                 }\r
  84         }\r
  85         return FALSE;\r
  86 }\r
  87 \r
  88 float Vore_CanLeave()\r
  89 {\r
  90         if(self.stat_eaten)\r
  91         {\r
  92                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
  93                         return TRUE;\r
  94                 if(teams_matter && self.team == self.predator.team)\r
  95                         return TRUE;\r
  96                 if(g_rpg && cvar("g_rpg_canleave"))\r
  97                         return TRUE;\r
  98         }\r
  99         return FALSE;\r
 100 }\r
 101 \r
 102 // position the camera properly for prey\r
 103 void Vore_SetPreyPositions()\r
 104 {\r
 105         // self is the predator and head is the prey\r
 106 \r
 107         local entity head;\r
 108         local vector origin_apply;\r
 109         local float position_counter;\r
 110 \r
 111         // In order to allow prey to see each other in the stomach, we must position each occupant differently,\r
 112         // else all players overlap in the center. To do this, we run a loop on all players in the same stomach.\r
 113         // For each player, the origin is updated, then a new origin is used for the next player.\r
 114         // This requires that no more than 9 players may be in the stomach at a time!\r
 115         FOR_EACH_PLAYER(head)\r
 116         {\r
 117                 if(head.predator == self)\r
 118                 {\r
 119                         switch(position_counter)\r
 120                         {\r
 121                                 case 0:\r
 122                                         origin_apply = '0 0 0'; // first occupant sits in the middle\r
 123                                         break;\r
 124                                 case 1:\r
 125                                         origin_apply = '1 0 0'; // second occupant sits in the front\r
 126                                         break;\r
 127                                 case 2:\r
 128                                         origin_apply = '-1 0 0'; // third occupant sits in the back\r
 129                                         break;\r
 130                                 case 3:\r
 131                                         origin_apply = '0 1 0'; // fourth occupant sits in the right\r
 132                                         break;\r
 133                                 case 4:\r
 134                                         origin_apply = '0 -1 0'; // fifth occupant sits in the left\r
 135                                         break;\r
 136                                 case 5:\r
 137                                         origin_apply = '1 1 0'; // sixth occupant sits in the front-right\r
 138                                         break;\r
 139                                 case 6:\r
 140                                         origin_apply = '-1 1 0'; // seventh occupant sits in the back-right\r
 141                                         break;\r
 142                                 case 7:\r
 143                                         origin_apply = '1 -1 0'; // eigth occupant sits in the front-left\r
 144                                         break;\r
 145                                 case 8:\r
 146                                         origin_apply = '-1 -1 0'; // ninth occupant sits in the back-left\r
 147                                         break;\r
 148                                 default:\r
 149                                         break;\r
 150                         }\r
 151 \r
 152                         // since prey have their predators set as an aiment, view_ofs will specify the real origin of prey, not just the view offset\r
 153                         head.view_ofs = PL_PREY_VIEW_OFS + origin_apply * cvar("g_vore_neighborprey_distance");\r
 154                         head.view_ofs_z *= self.scale; // stomach center depends on predator scale\r
 155 \r
 156                         // change prey height based on scale\r
 157                         float prey_height;\r
 158                                 prey_height = (head.scale - self.scale) * cvar("g_healthsize_vore_pos");\r
 159                         head.view_ofs_z += prey_height;\r
 160 \r
 161                         position_counter += 1;\r
 162                 }\r
 163         }\r
 164 }\r
 165 \r
 166 .float gurgle_oldstomachload;\r
 167 void Vore_GurgleSound()\r
 168 {\r
 169         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 170         {\r
 171                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 172 \r
 173                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 174                 self.gurgle_oldstomachload = self.stomach_load;\r
 175         }\r
 176 }\r
 177 \r
 178 void Vore_StomachLoad_Apply()\r
 179 {\r
 180         // apply stomach weight that makes you heavier and larger the more you eat\r
 181         // slowing the player is done in cl_physics.qc\r
 182 \r
 183         entity e;\r
 184         float vore_mass;\r
 185 \r
 186         self.stomach_load = 0; // start from zero\r
 187         FOR_EACH_PLAYER(e)\r
 188         {\r
 189                 if(e.predator == self && e.classname == "player")\r
 190                 {\r
 191                         vore_mass = cvar("g_balance_vore_load_prey_mass");\r
 192                         if(cvar("g_healthsize"))\r
 193                                 vore_mass *= self.scale;\r
 194                         self.stomach_load += floor(vore_mass);\r
 195                 }\r
 196         }\r
 197 \r
 198         if(self.stomach_load != self.vore_oldstomachload)\r
 199                 self.gravity += 1 + (self.stomach_load / self.stomach_maxload * cvar("g_balance_vore_load_pred_weight") - self.vore_oldstomachload);\r
 200         if(self.gravity == 0)\r
 201                 self.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 202         self.vore_oldstomachload = self.stomach_load;\r
 203 \r
 204         // apply the stomach capacity of the predator\r
 205         self.stomach_maxload = cvar("g_balance_vore_load_pred_capacity");\r
 206         if(cvar("g_healthsize"))\r
 207                 self.stomach_maxload *= self.scale;\r
 208         self.stomach_maxload = floor(self.stomach_maxload);\r
 209 }\r
 210 \r
 211 void Vore_AutoDigest(entity e)\r
 212 {\r
 213         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 214 \r
 215         if(!cvar("g_vore_digestion") || e.digesting)\r
 216                 return;\r
 217         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
 218                 return; // this feature is only for players, not bots\r
 219         if(e.stomach_load > 1)\r
 220                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 221         if(Stomach_TeamMates_check(e))\r
 222                 return; // never begin automatic digestion if we've swallowed a team mate\r
 223 \r
 224         e.digesting = TRUE;\r
 225 }\r
 226 \r
 227 .entity swallow_model;\r
 228 float Vore_SwallowModel_CustomizeEntityForClient()\r
 229 {\r
 230         // use the same system as the weapon model\r
 231 \r
 232         self.viewmodelforclient = self.owner;\r
 233         self.alpha = self.owner.cvar_cl_vore_swallowmodel;\r
 234 \r
 235         if(other.classname == "spectator")\r
 236         if(other.enemy == self.owner)\r
 237         {\r
 238                 self.viewmodelforclient = other;\r
 239                 self.alpha = other.cvar_cl_vore_swallowmodel;\r
 240         }\r
 241 \r
 242         return TRUE;\r
 243 }\r
 244 \r
 245 void Vore_SwallowModel_Think()\r
 246 {\r
 247         // update the position of the swallow model to match our swallow progress\r
 248         float dist;\r
 249         dist = (-0.5 + self.owner.swallow_progress_prey) * cvar("g_vore_swallowmodel_range"); // the model is centered at 0.5 progress\r
 250         if(cvar("g_healthsize"))\r
 251                 dist *= self.scale;\r
 252         self.view_ofs = '1 0 0' * dist;\r
 253 \r
 254         // if our swallow progress is gone or we are dead, the swallow model also goes away\r
 255         if(!self.owner.swallow_progress_prey || self.owner.deadflag != DEAD_NO || self.owner.classname != "player")\r
 256         {\r
 257                 remove(self.owner.swallow_model);\r
 258                 self.owner.swallow_model = world;\r
 259                 return;\r
 260         }\r
 261 \r
 262         // properties that should update whenever possible, but when the predator is not available\r
 263         self.nextthink = time;\r
 264 }\r
 265 \r
 266 void Vore_SwallowModel_Update(entity prey, entity pred)\r
 267 {\r
 268         // if we don't have a swallow model already, spawn one\r
 269         if(!prey.swallow_model)\r
 270         {\r
 271                 prey.swallow_model = spawn();\r
 272                 prey.swallow_model.movetype = MOVETYPE_FOLLOW;\r
 273                 prey.swallow_model.solid = SOLID_NOT;\r
 274                 //prey.swallow_model.effects |= EF_NOGUNBOB; // let it bob\r
 275                 prey.swallow_model.effects |= EF_NODEPTHTEST; // don't hide behind walls\r
 276                 prey.swallow_model.owner = prey;\r
 277                 prey.swallow_model.customizeentityforclient = Vore_SwallowModel_CustomizeEntityForClient;\r
 278                 prey.swallow_model.think = Vore_SwallowModel_Think;\r
 279                 prey.swallow_model.nextthink = time;\r
 280         }\r
 281 \r
 282         // properties that should update whenever possible, but when the predator is available\r
 283         string player_swallowmodel;\r
 284         player_swallowmodel = strcat(substring(pred.playermodel, 0, strlen(pred.playermodel) - 4), "_swallow.md3"); // 4 is the extension length\r
 285         if(prey.swallow_model.model != player_swallowmodel) // player model can be changed while the predator is active\r
 286                 setmodel(prey.swallow_model, player_swallowmodel);\r
 287         if(prey.swallow_model.skin != pred.skin) // player skin can be changed while the predator is active\r
 288                 prey.swallow_model.skin = pred.skin;\r
 289         if(cvar("g_healthsize"))\r
 290                 prey.swallow_model.scale = pred.scale / prey.scale; // player size difference\r
 291         if(prey.swallow_model.enemy != pred)\r
 292                 prey.swallow_model.enemy = pred; // enemy is the predator\r
 293         if(prey.swallow_model.colormap != pred.colormap)\r
 294                 prey.swallow_model.colormap = pred.colormap; // pants and shirt color\r
 295         if(prey.swallow_model.glowmod != pred.glowmod)\r
 296                 prey.swallow_model.glowmod = pred.glowmod; // glow color\r
 297 }\r
 298 \r
 299 .entity pusher;\r
 300 .float pushltime;\r
 301 void Vore_Swallow(entity e)\r
 302 {\r
 303         // this player is being swallowed by another player, apply the proper changes\r
 304 \r
 305         e.vore_oldmovetype = e.movetype;\r
 306         e.vore_oldsolid = e.solid;\r
 307 \r
 308         e.predator = self;\r
 309         setorigin(e, e.predator.origin);\r
 310         e.velocity = '0 0 0';\r
 311         e.movetype = MOVETYPE_FOLLOW;\r
 312         e.solid = SOLID_NOT;\r
 313         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 314 \r
 315         // drop keys (KH) and flags (CTF) when we get swallowed\r
 316         kh_Key_DropAll(e, FALSE);\r
 317         if(e.flagcarried)\r
 318                 DropFlag(e.flagcarried, world, e.predator);\r
 319 \r
 320         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 321                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
 322 \r
 323         if(teams_matter && e.team == e.predator.team)\r
 324         {\r
 325                 if(cvar("g_vore_kick"))\r
 326                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 327                 if(cvar("g_vore_digestion"))\r
 328                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 329         }\r
 330 \r
 331         PlayerSound(e.predator, playersound_swallow, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 332         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 333         e.predator.punchangle_x -= cvar("g_balance_vore_swallow_punchangle");\r
 334         e.predator.regurgitate_prepare = 0;\r
 335         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 336         e.predator.hitsound += 1; // play this for team mates too, as we could be swallowing them to heal them\r
 337         Vore_AutoDigest(e.predator);\r
 338 \r
 339         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 340         e.predator.weapon_delay = time + button_delay_time;\r
 341         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 342         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 343         e.stomachkick_delay = time + cvar("g_balance_vore_kick_delay"); // don't kick immediately after being swallowed\r
 344 }\r
 345 \r
 346 void Vore_SwallowStep(entity e)\r
 347 {\r
 348         if(!cvar("g_balance_vore_swallow_speed_fill"))\r
 349         {\r
 350                 Vore_Swallow(e);\r
 351                 return;\r
 352         }\r
 353 \r
 354         Vore_SwallowModel_Update(e, self);\r
 355 \r
 356         // increase the progress value until it reaches 1, then swallow the player\r
 357         if(e.swallow_progress_prey < 1)\r
 358         {\r
 359                 float fill;\r
 360                 fill = cvar("g_balance_vore_swallow_speed_fill") * frametime;\r
 361                 if(cvar("g_healthsize") && cvar("g_balance_vore_swallow_speed_fill_scalediff")) // fill rate depends on predator size compared to prey size\r
 362                         fill *= pow(self.scale / e.scale, cvar("g_balance_vore_swallow_speed_fill_scalediff"));\r
 363                 if(cvar("g_balance_vore_swallow_speed_fill_stomachload") && e.stomach_load) // fill rate is influenced by the prey's stomach load\r
 364                         fill /= e.stomach_load;\r
 365 \r
 366                 e.swallow_progress_prey += fill;\r
 367         }\r
 368         else\r
 369         {\r
 370                 Vore_Swallow(e);\r
 371                 e.swallow_progress_prey = 0;\r
 372         }\r
 373 \r
 374         // the predator's progress is how much the prey got swallowed\r
 375         self.swallow_progress_pred = e.swallow_progress_prey;\r
 376 }\r
 377 \r
 378 void Vore_Regurgitate(entity e)\r
 379 {\r
 380         // this player is being regurgitated by their predator, apply the proper changes\r
 381 \r
 382         e.movetype = e.vore_oldmovetype;\r
 383         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 384                 e.solid = e.vore_oldsolid;\r
 385         e.view_ofs_z = PL_VIEW_OFS_z;\r
 386 \r
 387         // apply velocities\r
 388         local vector oldforward, oldright, oldup;\r
 389         oldforward = v_forward;\r
 390         oldright = v_right;\r
 391         oldup = v_up;\r
 392         makevectors(e.predator.v_angle);\r
 393         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 394         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 395         v_forward = oldforward;\r
 396         v_right = oldright;\r
 397         v_up = oldup;\r
 398 \r
 399         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 400         e.pushltime = time + cvar("g_maxpushtime");\r
 401 \r
 402         // regurgitated prey is given this amount of swallow progress, to simulate being more vulnerable\r
 403         if(cvar("g_balance_vore_swallow_speed_fill") && cvar("g_balance_vore_regurgitate_swallowprogress"))\r
 404         {\r
 405                 e.swallow_progress_prey = cvar("g_balance_vore_regurgitate_swallowprogress");\r
 406                 Vore_SwallowModel_Update(e, e.predator);\r
 407         }\r
 408 \r
 409         // apply regurgitation damage to the predator\r
 410         if(cvar("g_balance_vore_regurgitate_damage"))\r
 411         {\r
 412                 float regurgitate_dmg;\r
 413                 regurgitate_dmg = cvar("g_balance_vore_regurgitate_damage");\r
 414                 if(cvar("g_healthsize"))\r
 415                         regurgitate_dmg *= e.scale / e.predator.scale;\r
 416                 Damage(e.predator, e.predator, e.predator, regurgitate_dmg, DEATH_REGURGITATION, e.predator.origin, '0 0 0');\r
 417         }\r
 418 \r
 419         PlayerSound(e.predator, playersound_regurgitate, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 420         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 421         pointparticles(particleeffectnum("vore_regurgitate"), e.predator.origin, '0 0 0', 1);\r
 422         e.predator.punchangle_x += cvar("g_balance_vore_regurgitate_punchangle");\r
 423         e.predator.regurgitate_prepare = 0;\r
 424         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 425 \r
 426         // block firing for a small amount of time, or we'll be firing the next frame\r
 427         e.weapon_delay = time + button_delay_time;\r
 428         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 429         e.predator = world;\r
 430 }\r
 431 \r
 432 void Vore_DeadPrey_Configure(entity e)\r
 433 {\r
 434         // ran when the keepdeadprey feature is enabled and prey stays inside the stomach after dying\r
 435 \r
 436         if(e.fakeprey || !e.stat_eaten) // we already configured everything\r
 437                 return;\r
 438 \r
 439         // this entity is like e.predator but for dead prey, to avoid conflicts\r
 440         e.fakepredator = e.predator;\r
 441         e.fakeprey = TRUE;\r
 442 \r
 443         // first release the prey from the predator, as dead prey needs to be attached differently\r
 444         // the predator's stomach load is also decreased, as dead prey doesn't count any more\r
 445         e.predator = world;\r
 446 \r
 447         // now put our dead prey inside the predator's stomach, but only as an effect\r
 448         e.movetype = MOVETYPE_FOLLOW;\r
 449         e.takedamage = DAMAGE_NO;\r
 450         e.solid = SOLID_NOT;\r
 451         e.aiment = e.fakepredator;\r
 452 }\r
 453 \r
 454 void Vore_DeadPrey_Detach(entity e)\r
 455 {\r
 456         // ran when dead prey must be detached from the stomach (eg: they are respawning)\r
 457         // should only execute after Vore_DeadPrey_Configure has ran first\r
 458 \r
 459         if not(cvar("g_vore_keepdeadprey"))\r
 460                 return;\r
 461 \r
 462         e.fakepredator = world;\r
 463         e.fakeprey = TRUE; // keep fakeprey status\r
 464         e.stat_eaten = 0;\r
 465         e.aiment = world;\r
 466         e.movetype = MOVETYPE_TOSS;\r
 467 }\r
 468 \r
 469 void Vore_PreyRelease(entity e, float pred_disconnect)\r
 470 {\r
 471         if(pred_disconnect)\r
 472         {\r
 473                 if(e.fakeprey)\r
 474                         Vore_DeadPrey_Detach(e);\r
 475                 else\r
 476                         Vore_Regurgitate(e);\r
 477         }\r
 478         else if(self.stat_eaten && !self.fakeprey)\r
 479         {\r
 480                 // if the keepdeadprey feature is on, don't spit a dead prey's carcass out\r
 481                 if(e.deadflag != DEAD_NO && random() < cvar("g_vore_keepdeadprey"))\r
 482                         Vore_DeadPrey_Configure(e);\r
 483                 else\r
 484                         Vore_Regurgitate(e);\r
 485         }\r
 486 }\r
 487 \r
 488 void Vore_Disconnect()\r
 489 {\r
 490         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 491 \r
 492         // prey disconnects or goes spectating while inside someone's belly\r
 493         if(self.stat_eaten)\r
 494                 Vore_PreyRelease(self, TRUE);\r
 495 \r
 496         // pred disconnects or goes spectating with players in their belly\r
 497         entity head;\r
 498         FOR_EACH_PLAYER(head)\r
 499         {\r
 500                 if(head.predator == self || head.fakepredator == self)\r
 501                         Vore_PreyRelease(head, TRUE);\r
 502         }\r
 503         Vore_GurgleSound(); // stop the gurgling sound\r
 504 \r
 505         self.stomach_load = self.gravity = 0; // prevents a bug\r
 506 }\r
 507 \r
 508 .float digestion_step;\r
 509 void Vore_Digest()\r
 510 {\r
 511         // apply digestion to prey\r
 512 \r
 513         if(time > self.digestion_step)\r
 514         {\r
 515                 // if distributed digestion is enabled, reduce digestion strength by the amount of prey in our stomach\r
 516                 float vore_offset;\r
 517                 if(cvar("g_balance_vore_digestion_distribute"))\r
 518                         vore_offset = self.predator.stomach_maxload / self.predator.stomach_load;\r
 519                 else\r
 520                         vore_offset = 1;\r
 521 \r
 522                 float damage;\r
 523                 damage = cvar("g_balance_vore_digestion_damage") / vore_offset;\r
 524 \r
 525                 // apply player scale to digestion damage\r
 526                 if(cvar("g_healthsize") && cvar("g_balance_vore_digestion_scalediff"))\r
 527                         damage *= pow(self.predator.scale / self.scale, cvar("g_balance_vore_digestion_scalediff"));\r
 528 \r
 529                 Damage(self, self.predator, self.predator, damage, DEATH_DIGESTION, self.origin, '0 0 0');\r
 530                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 531                         self.predator.health += cvar("g_balance_vore_digestion_vampire") / vore_offset;\r
 532 \r
 533                 if (self.predator.digestsound_finished < time)\r
 534                 {\r
 535                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 536                         self.predator.digestsound_finished = time + 0.5;\r
 537                 }\r
 538                 self.digestion_step = time + steptime;\r
 539         }\r
 540 \r
 541         if(self.deadflag != DEAD_NO)\r
 542         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
 543                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
 544 }\r
 545 \r
 546 .float teamheal_step;\r
 547 void Vore_Teamheal()\r
 548 {\r
 549         // apply teamheal\r
 550 \r
 551         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 552         if(time > self.teamheal_step)\r
 553         {\r
 554                 self.health += cvar("g_balance_vore_teamheal");\r
 555                 self.teamheal_step = time + steptime;\r
 556 \r
 557                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 558                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 559                 {\r
 560                         play2(self, "misc/beep.wav");\r
 561                         play2(self.predator, "misc/beep.wav");\r
 562                 }\r
 563         }\r
 564 }\r
 565 \r
 566 .float kick_pressed;\r
 567 void Vore_StomachKick()\r
 568 {\r
 569         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 570 \r
 571         if(time > self.stomachkick_delay && !self.kick_pressed)\r
 572         {\r
 573                 float damage, vol;\r
 574                 vector force;\r
 575                 damage = cvar("g_balance_vore_kick_damage");\r
 576                 force = v_forward * cvar("g_balance_vore_kick_force");\r
 577                 vol = VOL_BASE;\r
 578 \r
 579                 // apply player scale to the damage / force of the kick\r
 580                 if(cvar("g_healthsize") && cvar("g_balance_vore_kick_scalediff"))\r
 581                 {\r
 582                         damage *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff"));\r
 583                         force *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff"));\r
 584                         vol *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff")); // kick sound volume based on the same scale\r
 585                 }\r
 586                 vol = bound(0, vol, 1);\r
 587 \r
 588                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, force);\r
 589                 sound(self.predator, CHAN_PROJECTILE, strcat("weapons/hit", ftos(floor(random() * 8)), ".wav"), vol, ATTN_NORM);\r
 590                 self.predator.punchangle_x -= cvar("g_balance_vore_kick_predator_punchangle");\r
 591                 self.punchangle_x += cvar("g_balance_vore_kick_prey_punchangle");\r
 592 \r
 593                 // abort the predator's scheduled regurgitation\r
 594                 if(random() < cvar("g_balance_vore_kick_cutregurgitate"))\r
 595                         self.predator.regurgitate_prepare = 0;\r
 596 \r
 597                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 598                 if(cvar("g_balance_vore_kick_repress"))\r
 599                 if not(clienttype(self) == CLIENTTYPE_BOT) // not for bots, to prevent an issue\r
 600                         self.kick_pressed = TRUE;\r
 601         }\r
 602 }\r
 603 \r
 604 void Vore_StomachLeave()\r
 605 {\r
 606         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 607 \r
 608         if(Vore_CanLeave())\r
 609                 Vore_Regurgitate(self);\r
 610         else if(time > self.complain_vore)\r
 611         {\r
 612                 play2(self, "misc/forbidden.wav");\r
 613                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 614                 self.complain_vore = time + complain_delay_time;\r
 615         }\r
 616 }\r
 617 \r
 618 void Vore_AutoTaunt()\r
 619 {\r
 620         // triggers ambient vore taunts, for both pred and prey\r
 621 \r
 622         float taunt_time;\r
 623 \r
 624         // predator taunts\r
 625         if(self.stomach_load && !Stomach_TeamMates_check(self))\r
 626         {\r
 627                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 628                 {\r
 629                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 630                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 631                 }\r
 632         }\r
 633         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 634         {\r
 635                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 636                 SetAutoTaunt(self, 0, 0);\r
 637         }\r
 638 \r
 639         // prey taunts\r
 640         if(self.stat_eaten && !(teams_matter && self.team == self.predator.team))\r
 641         {\r
 642                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 643                 {\r
 644                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 645                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 646                 }\r
 647         }\r
 648         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 649         {\r
 650                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 651                 SetAutoTaunt(self, 0, 0);\r
 652         }\r
 653 }\r
 654 \r
 655 void Vore_SetSbarRings()\r
 656 {\r
 657         // first clear the ring stats, then configure them if needed\r
 658         self.stat_sbring1_type = self.stat_sbring1_clip = 0;\r
 659         self.stat_sbring2_type = self.stat_sbring2_clip = 0;\r
 660 \r
 661         if(self.stat_eaten)\r
 662         {\r
 663                 if(time <= self.stomachkick_delay)\r
 664                 {\r
 665                         self.stat_sbring1_type = 3; // ring shows stomach kick delay, empties with progress\r
 666                         self.stat_sbring1_clip = bound(0, (time / self.stomachkick_delay - 1) / ((self.stomachkick_delay - cvar("g_balance_vore_kick_delay")) / self.stomachkick_delay - 1), 1);\r
 667                 }\r
 668         }\r
 669         else\r
 670         {\r
 671                 if(self.swallow_progress_pred)\r
 672                 {\r
 673                         self.stat_sbring1_type = 1; // ring shows predator swallow progress, fills with progress\r
 674                         self.stat_sbring1_clip = bound(0, self.swallow_progress_pred, 1);\r
 675                 }\r
 676                 else if(time <= self.action_delay)\r
 677                 {\r
 678                         self.stat_sbring1_type = 2; // ring shows vore action delay, empties with progress\r
 679                         self.stat_sbring1_clip = bound(0, (time / self.action_delay - 1) / ((self.action_delay - cvar("g_balance_vore_action_delay")) / self.action_delay - 1), 1);\r
 680                 }\r
 681 \r
 682                 if(self.swallow_progress_prey)\r
 683                 {\r
 684                         self.stat_sbring2_type = 1; // ring shows prey swallow progress, fills with progress\r
 685                         self.stat_sbring2_clip = bound(0, self.swallow_progress_prey, 1);\r
 686                 }\r
 687                 else if(time <= self.regurgitate_prepare)\r
 688                 {\r
 689                         self.stat_sbring2_type = 2; // ring shows regurgitation preparing, fills with progress\r
 690                         self.stat_sbring2_clip = 1 - bound(0, (time / self.regurgitate_prepare - 1) / ((self.regurgitate_prepare - cvar("g_balance_vore_regurgitate_delay")) / self.regurgitate_prepare - 1), 1);\r
 691                 }\r
 692         }\r
 693 }\r
 694 \r
 695 void Vore()\r
 696 {\r
 697         // main vore code, this is where it all happens\r
 698 \r
 699         Vore_AutoTaunt();\r
 700 \r
 701         // wash the goo away from players once they leave the stomach\r
 702         if(!self.stat_eaten)\r
 703         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 704         if(self.colormod)\r
 705         if(cvar("g_vore_regurgitatecolor_release_fade"))\r
 706         {\r
 707                 self.colormod_x += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 708                 if(self.colormod_x > 1)\r
 709                         self.colormod_x = 1;\r
 710                 self.colormod_y += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 711                 if(self.colormod_y > 1)\r
 712                         self.colormod_y = 1;\r
 713                 self.colormod_z += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 714                 if(self.colormod_z > 1)\r
 715                         self.colormod_z = 1;\r
 716         }\r
 717 \r
 718         // set all vore stats\r
 719         Vore_SetSbarRings();\r
 720         if(self.fakepredator.classname == "player")\r
 721                 self.stat_eaten = num_for_edict(self.fakepredator);\r
 722         else if(self.predator.classname == "player")\r
 723         {\r
 724                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 725                 self.stat_stomachmaxload = self.predator.stomach_maxload; // necessary for the stomach board\r
 726                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 727                 self.stat_eaten = num_for_edict(self.predator);\r
 728         }\r
 729         else\r
 730         {\r
 731                 self.stat_stomachload = self.stomach_load;\r
 732                 self.stat_stomachmaxload = self.stomach_maxload;\r
 733                 self.stat_digesting = self.digesting;\r
 734                 self.stat_eaten = 0;\r
 735         }\r
 736         self.stat_canleave = Vore_CanLeave();\r
 737 \r
 738         // don't allow a player inside a player inside another player :)\r
 739         // prevent this by checking if such has happened, and taking the proper measures\r
 740         // this code has a high priority and must not be stopped by any delay, so run it here\r
 741         if(self.predator.stat_eaten)\r
 742         {\r
 743                 entity target_predator, target_predator_predator, oldself;\r
 744                 target_predator = self.predator;\r
 745                 target_predator_predator = self.predator.predator;\r
 746 \r
 747                 Vore_Regurgitate(self);\r
 748 \r
 749                 // now steal our prey's prey if this probability applies\r
 750                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 751                 {\r
 752                         oldself = self;\r
 753                         self = target_predator_predator;\r
 754                         if(Swallow_condition_check(oldself))\r
 755                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 756                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 757                                 Vore_Swallow(oldself);\r
 758                         self = oldself;\r
 759                 }\r
 760         }\r
 761 \r
 762         // the swallow progress of prey and preds idly decrease by this amount\r
 763         if(cvar("g_balance_vore_swallow_speed_decrease"))\r
 764         {\r
 765                 if(self.swallow_progress_pred)\r
 766                 {\r
 767                         self.swallow_progress_pred -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 768                         if(self.swallow_progress_pred < 0)\r
 769                                 self.swallow_progress_pred = 0;\r
 770                 }\r
 771                 if(self.swallow_progress_prey)\r
 772                 {\r
 773                         self.swallow_progress_prey -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 774                         if(self.swallow_progress_prey < 0)\r
 775                                 self.swallow_progress_prey = 0;\r
 776                 }\r
 777         }\r
 778 \r
 779         // apply delays and skip the vore system under some circumstances\r
 780         if(!cvar("g_vore")) // the vore system is disabled\r
 781         {\r
 782                 Vore_Disconnect();\r
 783                 return;\r
 784         }\r
 785         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 786         {\r
 787                 Vore_Disconnect();\r
 788                 return;\r
 789         }\r
 790         if(self.spectatee_status)\r
 791                 return;\r
 792         if(time < self.system_delay)\r
 793                 return;\r
 794 \r
 795 // --------------------------------\r
 796 // Code that addresses predators:\r
 797 // --------------------------------\r
 798 \r
 799         entity prey;\r
 800         prey = Swallow_player_check();\r
 801 \r
 802         // set the predator's stomach load and capacity\r
 803         Vore_StomachLoad_Apply();\r
 804 \r
 805         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 806         self.stat_canswallow = 0;\r
 807         if(Swallow_condition_check(prey))\r
 808         {\r
 809                 // canswallow stat, used by the HUD\r
 810                 if(teams_matter && prey.team == self.team)\r
 811                         self.stat_canswallow = 2;\r
 812                 else\r
 813                         self.stat_canswallow = 1;\r
 814 \r
 815                 if(self.BUTTON_ATCK)\r
 816                         Vore_SwallowStep(prey);\r
 817         }\r
 818         else if(prey != world)\r
 819                 self.stat_canswallow = -1;\r
 820 \r
 821         // toggle digestion, if the player has someone in their stomach\r
 822         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 823         {\r
 824                 if(self.stomach_load)\r
 825                 {\r
 826                         if(time > self.digest_button_delay_time)\r
 827                         {\r
 828                                 self.digesting = !self.digesting;\r
 829                                 self.digest_button_delay_time = time + button_delay_time;\r
 830                         }\r
 831                 }\r
 832                 else if(time > self.complain_vore)\r
 833                 {\r
 834                         play2(self, "misc/forbidden.wav");\r
 835                         sprint(self, "There is nothing to digest\n");\r
 836                         self.complain_vore = time + complain_delay_time;\r
 837                 }\r
 838         }\r
 839         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 840                 self.digesting = FALSE;\r
 841 \r
 842         // predator wishes to regurgitate his prey\r
 843         if(self.BUTTON_REGURGITATE && time > self.action_delay)\r
 844         {\r
 845                 if(self.stomach_load)\r
 846                 {\r
 847                         if(time > self.regurgitate_button_delay_time)\r
 848                         {\r
 849                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 850                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 851                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE); // looks good for preparing regurgitation\r
 852                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 853                         }\r
 854                 }\r
 855                 else if(time > self.complain_vore)\r
 856                 {\r
 857                         play2(self, "misc/forbidden.wav");\r
 858                         sprint(self, "There is nothing to regurgitate\n");\r
 859                         self.complain_vore = time + complain_delay_time;\r
 860                 }\r
 861         }\r
 862 \r
 863         if(cvar("g_vore_gurglesound"))\r
 864                 Vore_GurgleSound();\r
 865 \r
 866 // --------------------------------\r
 867 // Code that addresses the prey:\r
 868 // --------------------------------\r
 869 \r
 870         Vore_SetPreyPositions();\r
 871 \r
 872         // keepdeadprey - detach dead prey if their predator died or got swallowed\r
 873         if(self.fakeprey)\r
 874         if(self.fakepredator.deadflag != DEAD_NO || self.fakepredator.stat_eaten)\r
 875                 Vore_DeadPrey_Detach(self);\r
 876 \r
 877         if(!self.stat_eaten)\r
 878                 return;\r
 879 \r
 880         if(self.deadflag != DEAD_NO)\r
 881         {\r
 882                 Vore_PreyRelease(self, FALSE);\r
 883                 return;\r
 884         }\r
 885 \r
 886         if(self.predator.deadflag != DEAD_NO)\r
 887                 Vore_Regurgitate(self);\r
 888         else if(vlen(self.predator.velocity) > cvar("g_balance_vore_load_pred_speedcap") / (self.stomach_maxload / self.stomach_load))\r
 889                 Vore_Regurgitate(self);\r
 890 \r
 891         // apply delayed regurgitating if it was scheduled\r
 892         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 893         {\r
 894                 self.predator.regurgitate_prepare = 0;\r
 895                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 896                 Vore_Regurgitate(self);\r
 897         }\r
 898 \r
 899         // execute digesting and team healing\r
 900         if(self.predator.digesting == TRUE)\r
 901                 Vore_Digest();\r
 902         if(teams_matter && self.team == self.predator.team)\r
 903         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 904                 Vore_Teamheal();\r
 905 \r
 906         // execute prey commands\r
 907         if(self.BUTTON_ATCK)\r
 908         {\r
 909                 if(cvar("g_vore_kick"))\r
 910                         Vore_StomachKick();\r
 911         }\r
 912         else\r
 913                 self.kick_pressed = FALSE;\r
 914         if(self.BUTTON_JUMP)\r
 915                 Vore_StomachLeave();\r
 916 \r
 917         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
 918         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
 919         kh_Key_DropAll(self, FALSE);\r
 920 }