CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.12 FATAL_ERROR)
   2 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/cmake")
   3 project(NetRadiant C CXX)
   4
   5 option(BUILD_RADIANT "Build the GUI" ON)
   6 option(BUILD_TOOLS "Build the tools" ON)
   7 option(BUILD_CRUNCH "Build Crunch image support" OFF)
   8 option(DOWNLOAD_GAMEPACKS "Download game packs" ON)
   9 option(USE_WERROR "Build with -Werror -pedantic-errors" OFF)
  10 option(FHS_INSTALL "Install according to Filesystem Hierarchy Standard" OFF)
  11
  12 set(BUILD_BINARIES OFF CACHE INTERNAL "...")
  13 if (BUILD_RADIANT OR BUILD_TOOLS)
  14     set(BUILD_BINARIES ON)
  15 endif ()
  16
  17 #-----------------------------------------------------------------------
  18 # Paths
  19 #-----------------------------------------------------------------------
  20
  21 if (CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  22     set(CMAKE_INSTALL_PREFIX "${PROJECT_SOURCE_DIR}/install" CACHE PATH "..." FORCE)
  23 endif ()
  24
  25 set(RADIANT_BASENAME netradiant CACHE INTERNAL "...")
  26 add_definitions(-DRADIANT_BASENAME="${RADIANT_BASENAME}")
  27
  28 set(RADIANT_LIB_DIR ${CMAKE_INSTALL_PREFIX} CACHE INTERNAL "...")
  29 set(RADIANT_BIN_DIR ${CMAKE_INSTALL_PREFIX} CACHE INTERNAL "...")
  30 set(RADIANT_DATA_DIR ${CMAKE_INSTALL_PREFIX} CACHE INTERNAL "...")
  31
  32 if (FHS_INSTALL)
  33     set(RADIANT_LIB_DIR lib/${RADIANT_BASENAME})
  34     set(RADIANT_BIN_DIR bin)
  35     set(RADIANT_DATA_DIR share/${RADIANT_BASENAME})
  36 endif ()
  37
  38 #-----------------------------------------------------------------------
  39 # Version
  40 #-----------------------------------------------------------------------
  41
  42 # CMake 3.0+ would allow this in project()
  43 set(NetRadiant_VERSION_MAJOR 1)
  44 set(NetRadiant_VERSION_MINOR 5)
  45 set(NetRadiant_VERSION_PATCH 0)
  46 set(NetRadiant_VERSION "${NetRadiant_VERSION_MAJOR}.${NetRadiant_VERSION_MINOR}.${NetRadiant_VERSION_PATCH}")
  47
  48 set(RADIANT_ABOUTMSG "Custom build" CACHE STRING "About message")
  49
  50 find_package(Git REQUIRED)
  51
  52 execute_process(
  53         COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
  54         WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
  55         OUTPUT_VARIABLE GIT_VERSION
  56         OUTPUT_STRIP_TRAILING_WHITESPACE
  57 )
  58
  59 set(RADIANT_VERSION_STRING "${NetRadiant_VERSION}n")
  60
  61 if (GIT_VERSION)
  62     set(RADIANT_VERSION_STRING "${RADIANT_VERSION_STRING}-git-${GIT_VERSION}")
  63 endif ()
  64
  65 message(STATUS "Building ${PROJECT_NAME} ${RADIANT_VERSION_STRING} ${RADIANT_ABOUTMSG}")
  66
  67 #-----------------------------------------------------------------------
  68 # Language standard
  69 #-----------------------------------------------------------------------
  70
  71 if (BUILD_BINARIES)
  72     set(CMAKE_CXX_STANDARD 11)
  73     set(CMAKE_CXX_STANDARD_REQUIRED ON)
  74     set(CMAKE_CXX_EXTENSIONS OFF)
  75
  76     if (CMAKE_VERSION VERSION_LESS "3.1")
  77         if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" OR CMAKE_COMPILER_IS_GNUCXX)
  78             include(CheckCXXCompilerFlag)
  79             check_cxx_compiler_flag(--std=c++${CMAKE_CXX_STANDARD} STD_CXX)
  80             if (STD_CXX)
  81                 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} --std=c++${CMAKE_CXX_STANDARD}")
  82             else ()
  83                 message(SEND_ERROR "Requires C++${CMAKE_CXX_STANDARD} or better")
  84             endif ()
  85         else ()
  86             message(WARNING "Unrecognized compiler: ${CMAKE_CXX_COMPILER_ID}, make sure it supports C++${CMAKE_CXX_STANDARD}")
  87         endif ()
  88     endif ()
  89 endif ()
  90
  91 #-----------------------------------------------------------------------
  92 # Flags
  93 #-----------------------------------------------------------------------
  94
  95 if (BUILD_BINARIES)
  96     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions -fno-rtti")
  97
  98     macro(addflags_c args)
  99         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${args}")
 100     endmacro()
 101
 102     macro(addflags_cxx args)
 103         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${args}")
 104     endmacro()
 105
 106     macro(addflags args)
 107         addflags_c("${args}")
 108         addflags_cxx("${args}")
 109     endmacro()
 110
 111     addflags("-fno-strict-aliasing")
 112     if (NOT WIN32)
 113         addflags("-fvisibility=hidden")
 114     endif ()
 115
 116     if (USE_WERROR)
 117         addflags("-Werror")
 118         addflags("-pedantic-errors")
 119     endif ()
 120
 121     addflags("-Wall")
 122     addflags("-Wextra")
 123     addflags("-pedantic")
 124
 125     addflags_c("-Wno-deprecated-declarations") # vfs.c: g_strdown
 126
 127     addflags("-Wno-unused-function")
 128     addflags("-Wno-unused-variable")
 129     addflags("-Wno-unused-parameter")
 130
 131     set(CMAKE_POSITION_INDEPENDENT_CODE 1)
 132 endif ()
 133
 134 if (BUILD_RADIANT)
 135     set(GTK_TARGET 2 CACHE STRING "GTK target")
 136     add_definitions(-DGTK_TARGET=${GTK_TARGET})
 137 endif()
 138
 139 #-----------------------------------------------------------------------
 140 # Defs
 141 #-----------------------------------------------------------------------
 142
 143 if (BUILD_BINARIES)
 144     add_definitions(-DRADIANT_VERSION="${NetRadiant_VERSION}")
 145     add_definitions(-DRADIANT_MAJOR_VERSION="${NetRadiant_VERSION_MAJOR}")
 146     add_definitions(-DRADIANT_MINOR_VERSION="${NetRadiant_VERSION_MINOR}")
 147     add_definitions(-DRADIANT_PATCH_VERSION="${NetRadiant_VERSION_PATCH}")
 148
 149     add_definitions(-DRADIANT_ABOUTMSG="${NetRadiant_ABOUT}")
 150
 151     if (NOT CMAKE_BUILD_TYPE MATCHES Release)
 152         add_definitions(-D_DEBUG=1)
 153     endif ()
 154 endif ()
 155
 156 if (BUILD_RADIANT)
 157     macro(disable_deprecated name gtk2only)
 158         add_definitions(-D${name}_DISABLE_SINGLE_INCLUDES)
 159         if ((${gtk2only} EQUAL 0) OR (GTK_TARGET EQUAL 2))
 160             add_definitions(-D${name}_DISABLE_DEPRECATED)
 161         endif ()
 162     endmacro()
 163
 164     disable_deprecated(ATK 0)
 165     disable_deprecated(G 0)
 166     disable_deprecated(GDK 0)
 167     disable_deprecated(GDK_PIXBUF 0)
 168     disable_deprecated(GTK 1)
 169     disable_deprecated(PANGO 0)
 170 endif ()
 171
 172 IF(${CMAKE_SYSTEM_NAME} STREQUAL "FreeBSD")
 173     link_directories(
 174             /usr/local/lib
 175     )
 176 endif ()
 177
 178 if (BUILD_BINARIES)
 179     if (APPLE)
 180         add_definitions(
 181                 -DPOSIX=1
 182         )
 183
 184         link_directories(
 185                 /usr/local/lib
 186         )
 187     elseif (WIN32)
 188         add_definitions(
 189                 -DWIN32=1
 190                 -D_WIN32=1
 191         )
 192     else ()
 193         if (BUILD_RADIANT)
 194              set(XWINDOWS ON)
 195         endif ()
 196
 197         add_definitions(
 198                 -DPOSIX=1
 199         )
 200     endif ()
 201 endif ()
 202
 203 if (BUILD_RADIANT AND XWINDOWS)
 204     find_package(X11 REQUIRED)
 205     include_directories(${X11_INCLUDE_DIR})
 206     add_definitions(-DXWINDOWS=1)
 207 endif ()
 208
 209 if (BUILD_BINARIES)
 210     include_directories("${PROJECT_SOURCE_DIR}/include")
 211     include_directories("${PROJECT_SOURCE_DIR}/libs")
 212
 213     if (WIN32 AND NOT CMAKE_CROSSCOMPILING)
 214         set(BUNDLE_LIBRARIES_DEFAULT ON)
 215     else ()
 216         set(BUNDLE_LIBRARIES_DEFAULT OFF)
 217     endif ()
 218
 219     option(BUNDLE_LIBRARIES "Bundle libraries" ${BUNDLE_LIBRARIES_DEFAULT})
 220
 221     macro(copy_dlls target)
 222         if (BUNDLE_LIBRARIES AND WIN32)
 223             add_custom_command(TARGET ${target} POST_BUILD
 224                     COMMAND bash
 225                     ARGS -c "ldd '$<TARGET_FILE:${target}>' | egrep -i '\\.dll ' | grep -iv '/c/Windows' | awk '{ print $1 }' | while read dll; do dllbasename=\"$(which \"$dll\")\"; [ -f \"${PROJECT_BINARY_DIR}/$dllbasename\" ] || cp --preserve=timestamps \"$dllbasename\" '${PROJECT_BINARY_DIR}'; done"
 226                     VERBATIM
 227             )
 228         endif ()
 229     endmacro()
 230
 231     macro(bundle_stuff target)
 232         if (BUNDLE_LIBRARIES AND WIN32)
 233                 add_custom_command(TARGET ${target} POST_BUILD
 234                         COMMAND bash
 235                         ARGS -c "mkdir -p '${PROJECT_BINARY_DIR}/share/themes'; mkdir -p '${PROJECT_BINARY_DIR}/lib'; mingw=\"$(echo '${CMAKE_C_COMPILER}' | sed -e 's|/bin/.*||')\"; [ -d '${PROJECT_BINARY_DIR}/share/themes/MS-Windows' ] || cp -r --preserve=timestamps \"$mingw/share/themes/MS-Windows\" '${PROJECT_BINARY_DIR}/share/themes/'; [ -d '${PROJECT_BINARY_DIR}/lib/gdk-pixbuf-2.0' ] || cp -r --preserve=timestamps \"$mingw/lib/gdk-pixbuf-2.0\" '${PROJECT_BINARY_DIR}/lib/'; [ -d '${PROJECT_BINARY_DIR}/lib/gtk-2.0' ] || cp -r --preserve=timestamps \"$mingw/lib/gtk-2.0\" '${PROJECT_BINARY_DIR}/lib/'"
 236                         VERBATIM
 237                         )
 238
 239                 file(GLOB DLL_FILES ${PROJECT_BINARY_DIR}/*.dll)
 240
 241                 install(FILES
 242                     ${DLL_FILES}
 243                     DESTINATION ${CMAKE_INSTALL_PREFIX}
 244                 )
 245
 246                 install(DIRECTORY
 247                         ${PROJECT_BINARY_DIR}/lib
 248                         ${PROJECT_BINARY_DIR}/share
 249                         DESTINATION ${CMAKE_INSTALL_PREFIX}
 250                 )
 251         endif ()
 252     endmacro ()
 253 endif ()
 254
 255 #-----------------------------------------------------------------------
 256 # Libraries
 257 #-----------------------------------------------------------------------
 258
 259 if (BUILD_BINARIES)
 260     add_subdirectory(libs)
 261 endif ()
 262
 263 if (BUILD_RADIANT)
 264     add_subdirectory(include)
 265 endif ()
 266
 267 #-----------------------------------------------------------------------
 268 # Plugins
 269 #-----------------------------------------------------------------------
 270
 271 if (BUILD_RADIANT)
 272     add_subdirectory(contrib)
 273 endif ()
 274
 275 #-----------------------------------------------------------------------
 276 # Modules
 277 #-----------------------------------------------------------------------
 278
 279 if (BUILD_RADIANT)
 280     add_subdirectory(plugins)
 281 endif ()
 282
 283 #-----------------------------------------------------------------------
 284 # Radiant
 285 #-----------------------------------------------------------------------
 286
 287 if (BUILD_BINARIES)
 288     if (CMAKE_EXECUTABLE_SUFFIX)
 289         string(REGEX REPLACE "^[.]" "" RADIANT_EXECUTABLE ${CMAKE_EXECUTABLE_SUFFIX})
 290     endif ()
 291
 292     macro(radiant_tool name)
 293         add_executable(${name} ${ARGN})
 294
 295         copy_dlls(${name})
 296
 297         install(
 298                 TARGETS ${name}
 299                 RUNTIME DESTINATION ${RADIANT_BIN_DIR}
 300         )
 301     endmacro()
 302
 303     if (BUILD_RADIANT)
 304         add_subdirectory(radiant _radiant)
 305         set_target_properties(${RADIANT_BASENAME} PROPERTIES
 306                 COMPILE_DEFINITIONS RADIANT_EXECUTABLE="${RADIANT_EXECUTABLE}"
 307                 )
 308     endif ()
 309 endif ()
 310
 311 #-----------------------------------------------------------------------
 312 # Tools
 313 #-----------------------------------------------------------------------
 314
 315 if (BUILD_TOOLS)
 316     add_subdirectory(tools)
 317
 318     file(GLOB DATA_FILES "${PROJECT_SOURCE_DIR}/setup/data/tools/*")
 319
 320     if (NOT (PROJECT_SOURCE_DIR STREQUAL PROJECT_BINARY_DIR))
 321         # Copy data files from sources to the build directory
 322         message(STATUS "Copying data files")
 323         file(COPY ${DATA_FILES} DESTINATION "${PROJECT_BINARY_DIR}")
 324     endif ()
 325 endif ()
 326
 327 #-----------------------------------------------------------------------
 328 # Game packs
 329 #-----------------------------------------------------------------------
 330
 331 set(GAMEPACKS_LICENSE_LIST free CACHE STRING "Download game packs by license")
 332 set(GAMEPACKS_NAME_LIST none CACHE STRING "Download game packs by name")
 333
 334 if (DOWNLOAD_GAMEPACKS)
 335    add_custom_target(game_packs ALL
 336       COMMAND "${PROJECT_SOURCE_DIR}/gamepack-manager" --license ${GAMEPACKS_LICENSE_LIST} --name ${GAMEPACKS_NAME_LIST} --download-dir "${PROJECT_BINARY_DIR}/download" --install-dir "${PROJECT_BINARY_DIR}" --download --install
 337       COMMENT "Downloading ${GAMEPACKS_LICENSE_LIST} game packs"
 338    )
 339 endif()
 340
 341 #-----------------------------------------------------------------------
 342 # Install
 343 #-----------------------------------------------------------------------
 344
 345 if (BUILD_BINARIES)
 346     install(DIRECTORY
 347             setup/data/tools/base
 348             setup/data/tools/bitmaps
 349             setup/data/tools/gl
 350             setup/data/tools/plugins
 351             docs
 352             DESTINATION ${RADIANT_DATA_DIR}
 353     )
 354 endif ()
 355
 356 if (DOWNLOAD_GAMEPACKS)
 357     if (FHS_INSTALL)
 358        set(GAME_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}/share/netradiant")
 359     else ()
 360        set(GAME_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}")
 361     endif ()
 362
 363     file(GLOB GAME_DIRS ${PROJECT_BINARY_DIR}/*.game)
 364
 365     install(DIRECTORY
 366             ${PROJECT_BINARY_DIR}/games
 367             ${GAME_DIRS}
 368             DESTINATION ${RADIANT_DATA_DIR}
 369     )
 370 endif()
 371
 372 if(BUILD_BINARIES AND FHS_INSTALL AND NOT WIN32 AND NOT APPLE)
 373     install(FILES
 374             ${PROJECT_SOURCE_DIR}/icons/netradiant.png
 375             DESTINATION ${CMAKE_INSTALL_PREFIX}/share/pixmaps
 376     )
 377     install(FILES
 378             ${PROJECT_SOURCE_DIR}/icons/netradiant.desktop
 379             DESTINATION ${CMAKE_INSTALL_PREFIX}/share/applications
 380     )
 381     install(FILES
 382             ${PROJECT_SOURCE_DIR}/icons/mime/map.xml
 383             DESTINATION ${CMAKE_INSTALL_PREFIX}/share/mime/model
 384     )
 385 endif()
 386
 387 include(cmake/scripts/package.cmake)