qcsrc/server/command/vote.qc

   1 // =============================================
   2 //  Server side voting code, reworked by Samual
   3 //  Last updated: December 27th, 2011
   4 // =============================================
   5
   6 //  Nagger for players to know status of voting
   7 float Nagger_SendEntity(entity to, float sendflags)
   8 {
   9         float nags, i, f, b;
  10         entity e;
  11         WriteByte(MSG_ENTITY, ENT_CLIENT_NAGGER);
  12
  13         // bits:
  14         //   1 = ready
  15         //   2 = player needs to ready up
  16         //   4 = vote
  17         //   8 = player needs to vote
  18         //  16 = warmup
  19         // sendflags:
  20         //  64 = vote counts
  21         // 128 = vote string
  22
  23         nags = 0;
  24         if(readycount)
  25         {
  26                 nags |= 1;
  27                 if(to.ready == 0)
  28                         nags |= 2;
  29         }
  30         if(vote_called)
  31         {
  32                 nags |= 4;
  33                 if(to.vote_selection == 0)
  34                         nags |= 8;
  35         }
  36         if(inWarmupStage)
  37                 nags |= 16;
  38
  39         if(sendflags & 64)
  40                 nags |= 64;
  41
  42         if(sendflags & 128)
  43                 nags |= 128;
  44
  45         if(!(nags & 4)) // no vote called? send no string
  46                 nags &~= (64 | 128);
  47
  48         WriteByte(MSG_ENTITY, nags);
  49
  50         if(nags & 64)
  51         {
  52                 WriteByte(MSG_ENTITY, vote_accept_count);
  53                 WriteByte(MSG_ENTITY, vote_reject_count);
  54                 WriteByte(MSG_ENTITY, vote_needed_overall);
  55                 WriteChar(MSG_ENTITY, to.vote_selection);
  56         }
  57
  58         if(nags & 128)
  59                 WriteString(MSG_ENTITY, vote_called_display);
  60
  61         if(nags & 1)
  62         {
  63                 for(i = 1; i <= maxclients; i += 8)
  64                 {
  65                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
  66                                 if(!IS_REAL_CLIENT(e) || e.ready)
  67                                         f |= b;
  68                         WriteByte(MSG_ENTITY, f);
  69                 }
  70         }
  71
  72         return TRUE;
  73 }
  74
  75 void Nagger_Init()
  76 {
  77         Net_LinkEntity(nagger = spawn(), FALSE, 0, Nagger_SendEntity);
  78 }
  79
  80 void Nagger_VoteChanged()
  81 {
  82         if(nagger)
  83                 nagger.SendFlags |= 128;
  84 }
  85
  86 void Nagger_VoteCountChanged()
  87 {
  88         if(nagger)
  89                 nagger.SendFlags |= 64;
  90 }
  91
  92 void Nagger_ReadyCounted()
  93 {
  94         if(nagger)
  95                 nagger.SendFlags |= 1;
  96 }
  97
  98
  99 // =======================
 100 //  Game logic for voting
 101 // =======================
 102
 103 void VoteReset()
 104 {
 105         entity tmp_player;
 106
 107         FOR_EACH_CLIENT(tmp_player) { tmp_player.vote_selection = 0; }
 108
 109         if(vote_called)
 110         {
 111                 strunzone(vote_called_command);
 112                 strunzone(vote_called_display);
 113         }
 114
 115         vote_called = VOTE_NULL;
 116         vote_caller = world;
 117         vote_endtime = 0;
 118
 119         vote_called_command = string_null;
 120         vote_called_display = string_null;
 121
 122         vote_parsed_command = string_null;
 123         vote_parsed_display = string_null;
 124
 125         Nagger_VoteChanged();
 126 }
 127
 128 void VoteStop(entity stopper)
 129 {
 130         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", GetCallerName(vote_caller), "^2's vote\n");
 131         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid))); }
 132
 133         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 134         if((vote_caller) && (stopper == vote_caller)) { vote_caller.vote_waittime = time + autocvar_sv_vote_stop; }
 135
 136         VoteReset();
 137 }
 138
 139 void VoteAccept()
 140 {
 141         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 142
 143         if((vote_called == VOTE_MASTER) && vote_caller)
 144                 vote_caller.vote_master = 1;
 145         else
 146                 localcmd(strcat(vote_called_command, "\n"));
 147
 148         if(vote_caller) { vote_caller.vote_waittime = 0; } // people like your votes, you don't need to wait to vote again
 149
 150         VoteReset();
 151         Announce("voteaccept");
 152 }
 153
 154 void VoteReject()
 155 {
 156         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 157         VoteReset();
 158         Announce("votefail");
 159 }
 160
 161 void VoteTimeout()
 162 {
 163         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ", vote_called_display, "^2 timed out\n");
 164         VoteReset();
 165         Announce("votefail");
 166 }
 167
 168 void VoteSpam(float notvoters, float mincount, string result)
 169 {
 170         bprint(strcat(
 171                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 172                 strcat("^2:^1", ftos(vote_reject_count)),
 173                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 174                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 175                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 176
 177         if(autocvar_sv_eventlog)
 178         {
 179                 GameLogEcho(strcat(
 180                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 181                         strcat(":", ftos(vote_reject_count)),
 182                         strcat(":", ftos(vote_abstain_count)),
 183                         strcat(":", ftos(notvoters)),
 184                         strcat(":", ftos(mincount))));
 185         }
 186 }
 187
 188 void VoteCount(float first_count)
 189 {
 190         // declarations
 191         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 192
 193         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 194                                 || ((autocvar_sv_vote_nospectators == 1) && (inWarmupStage || gameover))
 195                                 || (autocvar_sv_vote_nospectators == 0));
 196
 197         float vote_player_count = 0, notvoters = 0;
 198         float vote_real_player_count = 0, vote_real_accept_count = 0;
 199         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 200         float vote_needed_of_voted, final_needed_votes;
 201         float vote_factor_overall, vote_factor_of_voted;
 202
 203         entity tmp_player;
 204
 205         Nagger_VoteCountChanged();
 206
 207         // add up all the votes from each connected client
 208         FOR_EACH_REALCLIENT(tmp_player)
 209         {
 210                 ++vote_player_count;
 211                 if(IS_PLAYER(tmp_player)) { ++vote_real_player_count; }
 212
 213                 switch(tmp_player.vote_selection)
 214                 {
 215                         case VOTE_SELECT_REJECT: { ++vote_reject_count; { if(IS_PLAYER(tmp_player)) ++vote_real_reject_count; } break; }
 216                         case VOTE_SELECT_ACCEPT: { ++vote_accept_count; { if(IS_PLAYER(tmp_player)) ++vote_real_reject_count; } break; }
 217                         case VOTE_SELECT_ABSTAIN: { ++vote_abstain_count; { if(IS_PLAYER(tmp_player)) ++vote_real_abstain_count; } break; }
 218                         default: break;
 219                 }
 220         }
 221
 222         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 223         if((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 224         {
 225                 if(vote_caller) { vote_caller.vote_waittime = 0; }
 226                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 227                 VoteReset();
 228                 return;
 229         }
 230
 231         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 232         if(!spectators_allowed && (vote_real_player_count > 0))
 233         {
 234                 vote_accept_count = vote_real_accept_count;
 235                 vote_reject_count = vote_real_reject_count;
 236                 vote_abstain_count = vote_real_abstain_count;
 237                 vote_player_count = vote_real_player_count;
 238         }
 239
 240         // people who have no opinion in any way :D
 241         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 242
 243         // determine the goal for the vote to be passed or rejected normally
 244         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 245         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 246
 247         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 248         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 249         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 250
 251         // are there any players at all on the server? it could be an admin vote
 252         if(vote_player_count == 0 && first_count)
 253         {
 254                 VoteSpam(0, -1, "yes"); // no players at all, just accept it
 255                 VoteAccept();
 256                 return;
 257         }
 258
 259         // since there ARE players, finally calculate the result of the vote
 260         if(vote_accept_count >= vote_needed_overall)
 261         {
 262                 VoteSpam(notvoters, -1, "yes"); // there is enough acceptions to pass the vote
 263                 VoteAccept();
 264                 return;
 265         }
 266
 267         if(vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 268         {
 269                 VoteSpam(notvoters, -1, "no"); // there is enough rejections to deny the vote
 270                 VoteReject();
 271                 return;
 272         }
 273
 274         // there is not enough votes in either direction, now lets just calculate what the voters have said
 275         if(time > vote_endtime)
 276         {
 277                 final_needed_votes = vote_needed_overall;
 278
 279                 if(autocvar_sv_vote_majority_factor_of_voted)
 280                 {
 281                         if(vote_accept_count >= vote_needed_of_voted)
 282                         {
 283                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 284                                 VoteAccept();
 285                                 return;
 286                         }
 287
 288                         if(vote_accept_count + vote_reject_count > 0)
 289                         {
 290                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 291                                 VoteReject();
 292                                 return;
 293                         }
 294
 295                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 296                 }
 297
 298                 // it didn't pass or fail, so not enough votes to even make a decision.
 299                 VoteSpam(notvoters, final_needed_votes, "timeout");
 300                 VoteTimeout();
 301         }
 302 }
 303
 304 void VoteThink()
 305 {
 306         if(vote_endtime > 0) // a vote was called
 307         if(time > vote_endtime) // time is up
 308         {
 309                 VoteCount(FALSE);
 310         }
 311
 312         return;
 313 }
 314
 315
 316 // =======================
 317 //  Game logic for warmup
 318 // =======================
 319
 320 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 321 void ReadyRestart_think()
 322 {
 323         restart_mapalreadyrestarted = 1;
 324         reset_map(TRUE);
 325         Score_ClearAll();
 326         remove(self);
 327
 328         return;
 329 }
 330
 331 // Forces a restart of the game without actually reloading the map // this is a mess...
 332 void ReadyRestart_force()
 333 {
 334         entity tmp_player, restart_timer;
 335
 336         bprint("^1Server is restarting...\n");
 337
 338         VoteReset();
 339
 340         // clear overtime, we have to decrease timelimit to its original value again.
 341         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2) { cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime))); }
 342
 343         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 344
 345         readyrestart_happened = 1;
 346         game_starttime = time;
 347         if(!g_ca && !g_arena) { game_starttime += RESTART_COUNTDOWN; }
 348
 349         // clear alivetime
 350         FOR_EACH_CLIENT(tmp_player)
 351         {
 352                 tmp_player.alivetime = 0;
 353                 PlayerStats_Event(tmp_player, PLAYERSTATS_ALIVETIME, -PlayerStats_Event(tmp_player, PLAYERSTATS_ALIVETIME, 0));
 354         }
 355
 356         restart_mapalreadyrestarted = 0; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 357
 358         // disable the warmup global for the server
 359         inWarmupStage = 0; // once the game is restarted the game is in match stage
 360
 361         // reset the .ready status of all players (also spectators)
 362         FOR_EACH_CLIENTSLOT(tmp_player) { tmp_player.ready = 0; }
 363         readycount = 0;
 364         Nagger_ReadyCounted(); // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 365
 366         // lock teams with lockonrestart
 367         if(autocvar_teamplay_lockonrestart && teamplay)
 368         {
 369                 lockteams = 1;
 370                 bprint("^1The teams are now locked.\n");
 371         }
 372
 373         //initiate the restart-countdown-announcer entity
 374         if(autocvar_sv_ready_restart_after_countdown && !g_ca && !g_arena)
 375         {
 376                 restart_timer = spawn();
 377                 restart_timer.think = ReadyRestart_think;
 378                 restart_timer.nextthink = game_starttime;
 379         }
 380
 381         // after a restart every players number of allowed timeouts gets reset, too
 382         if(autocvar_sv_timeout) { FOR_EACH_REALPLAYER(tmp_player) { tmp_player.allowed_timeouts = autocvar_sv_timeout_number; } }
 383
 384         //reset map immediately if this cvar is not set
 385         if not(autocvar_sv_ready_restart_after_countdown) { reset_map(TRUE); }
 386
 387         if(autocvar_sv_eventlog) { GameLogEcho(":restart"); }
 388 }
 389
 390 void ReadyRestart()
 391 {
 392         // no arena, assault support yet...
 393         if(g_arena | g_assault | gameover | intermission_running | race_completing)
 394                 localcmd("restart\n");
 395         else
 396                 localcmd("\nsv_hook_gamerestart\n");
 397
 398         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 399         // Otherwise scores could be manipulated during the countdown.
 400         if not(autocvar_sv_ready_restart_after_countdown) { Score_ClearAll(); }
 401
 402         ReadyRestart_force();
 403
 404         return;
 405 }
 406
 407 // Count the players who are ready and determine whether or not to restart the match
 408 void ReadyCount()
 409 {
 410         entity tmp_player;
 411         float ready_needed_factor, ready_needed_count;
 412         float t_ready = 0, t_players = 0;
 413
 414         FOR_EACH_REALPLAYER(tmp_player)
 415         {
 416                 ++t_players;
 417                 if(tmp_player.ready) { ++t_ready; }
 418         }
 419
 420         readycount = t_ready;
 421
 422         Nagger_ReadyCounted();
 423
 424         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 425         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 426
 427         if(readycount >= ready_needed_count)
 428         {
 429                 ReadyRestart();
 430         }
 431
 432         return;
 433 }
 434
 435
 436 // ======================================
 437 //  Supporting functions for VoteCommand
 438 // ======================================
 439
 440 float Votecommand_check_assignment(entity caller, float assignment)
 441 {
 442         float from_server = (!caller);
 443
 444         if((assignment == VC_ASGNMNT_BOTH)
 445                 || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 446                 || (from_server && assignment == VC_ASGNMNT_SERVERONLY)))
 447         {
 448                 return TRUE;
 449         }
 450
 451         return FALSE;
 452 }
 453
 454 string VoteCommand_extractcommand(string input, float startpos, float argc)
 455 {
 456         string output;
 457
 458         if((argc - 1) < startpos)
 459                 output = "";
 460         else
 461                 output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 462
 463         return output;
 464 }
 465
 466 float VoteCommand_checknasty(string vote_command)
 467 {
 468         if((strstrofs(vote_command, ";", 0) >= 0)
 469                 || (strstrofs(vote_command, "\n", 0) >= 0)
 470                 || (strstrofs(vote_command, "\r", 0) >= 0)
 471                 || (strstrofs(vote_command, "$", 0) >= 0))
 472                 return FALSE;
 473
 474         return TRUE;
 475 }
 476
 477 float VoteCommand_checkinlist(string vote_command, string list)
 478 {
 479         string l = strcat(" ", list, " ");
 480
 481         if(strstrofs(l, strcat(" ", vote_command, " "), 0) >= 0)
 482                 return TRUE;
 483
 484         return FALSE;
 485 }
 486
 487 string ValidateMap(string validated_map, entity caller)
 488 {
 489         validated_map = MapInfo_FixName(validated_map);
 490
 491         if not(validated_map)
 492         {
 493                 print_to(caller, "This map is not available on this server.");
 494                 return string_null;
 495         }
 496
 497         if(!autocvar_sv_vote_override_mostrecent && caller)
 498         {
 499                 if(Map_IsRecent(validated_map))
 500                 {
 501                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 502                         return string_null;
 503                 }
 504         }
 505
 506         if(!MapInfo_CheckMap(validated_map))
 507         {
 508                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 509                 return string_null;
 510         }
 511
 512         return validated_map;
 513 }
 514
 515 float VoteCommand_checkargs(float startpos, float argc)
 516 {
 517         float p, q, check, minargs;
 518         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 519         string cmdrestriction = cvar_string(cvarname); // note: this warns on undefined cvar. We want that.
 520         string charlist, arg;
 521         float checkmate;
 522
 523         if(cmdrestriction == "")
 524                 return TRUE;
 525
 526         ++startpos; // skip command name
 527
 528         // check minimum arg count
 529
 530         // 0 args: argc == startpos
 531         // 1 args: argc == startpos + 1
 532         // ...
 533
 534         minargs = stof(cmdrestriction);
 535         if(argc - startpos < minargs)
 536                 return FALSE;
 537
 538         p = strstrofs(cmdrestriction, ";", 0); // find first semicolon
 539
 540         for(;;)
 541         {
 542                 // we know that at any time, startpos <= argc - minargs
 543                 // so this means: argc-minargs >= startpos >= argc, thus
 544                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 545                 // have been seen already
 546
 547                 if(startpos >= argc) // all args checked? GOOD
 548                         break;
 549
 550                 if(p < 0) // no more args? FAIL
 551                 {
 552                         // exception: exactly minargs left, this one included
 553                         if(argc - startpos == minargs)
 554                                 break;
 555
 556                         // otherwise fail
 557                         return FALSE;
 558                 }
 559
 560                 // cut to next semicolon
 561                 q = strstrofs(cmdrestriction, ";", p+1); // find next semicolon
 562                 if(q < 0)
 563                         charlist = substring(cmdrestriction, p+1, -1);
 564                 else
 565                         charlist = substring(cmdrestriction, p+1, q - (p+1));
 566
 567                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 568                 // charlist = strreplace("^^", ";", charlist);
 569
 570                 if(charlist != "")
 571                 {
 572                         // verify the arg only contains allowed chars
 573                         arg = argv(startpos);
 574                         checkmate = strlen(arg);
 575                         for(check = 0; check < checkmate; ++check)
 576                                 if(strstrofs(charlist, substring(arg, check, 1), 0) < 0)
 577                                         return FALSE; // not allowed character
 578                         // all characters are allowed. FINE.
 579                 }
 580
 581                 ++startpos;
 582                 --minargs;
 583                 p = q;
 584         }
 585
 586         return TRUE;
 587 }
 588
 589 float VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, float argc)
 590 {
 591         string first_command;
 592
 593         first_command = argv(startpos);
 594
 595         if not(VoteCommand_checkinlist(first_command, vote_list))
 596                 return FALSE;
 597
 598         if not(VoteCommand_checkargs(startpos, argc))
 599                 return FALSE;
 600
 601         switch(first_command) // now go through and parse the proper commands to adjust as needed.
 602         {
 603                 case "kick":
 604                 case "kickban": // catch all kick/kickban commands
 605                 {
 606                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 607                         float accepted = VerifyClientEntity(victim, TRUE, FALSE);
 608
 609                         if(accepted > 0)
 610                         {
 611                                 string reason = ((argc > next_token) ? substring(vote_command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)) : "No reason provided");
 612                                 string command_arguments;
 613
 614                                 if(first_command == "kickban")
 615                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 616                                 else
 617                                         command_arguments = reason;
 618
 619                                 vote_parsed_command = strcat(first_command, " # ", ftos(num_for_edict(victim)), " ", command_arguments);
 620                                 vote_parsed_display = strcat("^1", vote_command, " (^7", victim.netname, "^1): ", reason);
 621                         }
 622                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return FALSE; }
 623
 624                         break;
 625                 }
 626
 627                 case "map":
 628                 case "chmap":
 629                 case "gotomap": // re-direct all map selection commands to gotomap
 630                 {
 631                         vote_command = ValidateMap(argv(startpos + 1), caller);
 632                         if not(vote_command) { return FALSE; }
 633                         vote_parsed_command = strcat("gotomap ", vote_command);
 634                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 635
 636                         break;
 637                 }
 638
 639                 default:
 640                 {
 641                         vote_parsed_command = vote_command;
 642                         vote_parsed_display = strzone(strcat("^1", vote_command));
 643
 644                         break;
 645                 }
 646         }
 647
 648         return TRUE;
 649 }
 650
 651
 652 // =======================
 653 //  Command Sub-Functions
 654 // =======================
 655
 656 void VoteCommand_abstain(float request, entity caller) // CLIENT ONLY
 657 {
 658         switch(request)
 659         {
 660                 case CMD_REQUEST_COMMAND:
 661                 {
 662                         if not(vote_called) { print_to(caller, "^1No vote called."); }
 663                         else if not(caller.vote_selection == VOTE_SELECT_NULL || autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 664
 665                         else // everything went okay, continue changing vote
 666                         {
 667                                 print_to(caller, "^1You abstained from your vote.");
 668                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 669                                 msg_entity = caller;
 670                                 if(!autocvar_sv_vote_singlecount) { VoteCount(FALSE); }
 671                         }
 672
 673                         return;
 674                 }
 675
 676                 default:
 677                 case CMD_REQUEST_USAGE:
 678                 {
 679                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 680                         print_to(caller, "  No arguments required.");
 681                         return;
 682                 }
 683         }
 684 }
 685
 686 void VoteCommand_call(float request, entity caller, float argc, string vote_command) // BOTH
 687 {
 688         switch(request)
 689         {
 690                 case CMD_REQUEST_COMMAND:
 691                 {
 692                         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 693                                 || ((autocvar_sv_vote_nospectators == 1) && inWarmupStage)
 694                                 || (autocvar_sv_vote_nospectators == 0));
 695
 696                         float tmp_playercount = 0;
 697                         entity tmp_player;
 698
 699                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 700
 701                         if not(autocvar_sv_vote_call || !caller) { print_to(caller, "^1Vote calling is not allowed."); }
 702                         else if(!autocvar_sv_vote_gamestart && time < game_starttime) { print_to(caller, "^1Vote calling is not allowed before the match has started."); }
 703                         else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
 704                         else if(!spectators_allowed && (caller && !IS_PLAYER(caller))) { print_to(caller, "^1Only players can call a vote."); }
 705                         else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
 706                         else if(caller && (time < caller.vote_waittime)) { print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote.")); }
 707                         else if not(VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
 708                         else if not(VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
 709
 710                         else // everything went okay, continue with calling the vote
 711                         {
 712                                 vote_caller = caller; // remember who called the vote
 713                                 vote_called = VOTE_NORMAL;
 714                                 vote_called_command = strzone(vote_parsed_command);
 715                                 vote_called_display = strzone(vote_parsed_display);
 716                                 vote_endtime = time + autocvar_sv_vote_timeout;
 717
 718                                 if(caller)
 719                                 {
 720                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 721                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 722                                         msg_entity = caller;
 723                                 }
 724
 725                                 FOR_EACH_REALCLIENT(tmp_player) { ++tmp_playercount; }
 726                                 if(tmp_playercount > 1) { Announce("votecall"); } // don't announce a "vote now" sound if player is alone
 727
 728                                 bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2 calls a vote for ", vote_called_display, "\n");
 729                                 if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
 730                                 Nagger_VoteChanged();
 731                                 VoteCount(TRUE); // needed if you are the only one
 732                         }
 733
 734                         return;
 735                 }
 736
 737                 default:
 738                 case CMD_REQUEST_USAGE:
 739                 {
 740                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
 741                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
 742                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 743                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 744                         return;
 745                 }
 746         }
 747 }
 748
 749 void VoteCommand_master(float request, entity caller, float argc, string vote_command) // CLIENT ONLY
 750 {
 751         switch(request)
 752         {
 753                 case CMD_REQUEST_COMMAND:
 754                 {
 755                         if(autocvar_sv_vote_master)
 756                         {
 757                                 switch(strtolower(argv(2)))
 758                                 {
 759                                         case "do":
 760                                         {
 761                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 762
 763                                                 if not(caller.vote_master) { print_to(caller, "^1You do not have vote master privelages."); }
 764                                                 else if not(VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
 765                                                 else if not(VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
 766
 767                                                 else // everything went okay, proceed with command
 768                                                 {
 769                                                         localcmd(strcat(vote_parsed_command, "\n"));
 770                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 771                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 772                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display)); }
 773                                                 }
 774
 775                                                 return;
 776                                         }
 777
 778                                         case "login":
 779                                         {
 780                                                 if not(autocvar_sv_vote_master_password != "") { print_to(caller, "^1Login to vote master is not allowed."); }
 781                                                 else if(caller.vote_master) { print_to(caller, "^1You are already logged in as vote master."); }
 782                                                 else if not(autocvar_sv_vote_master_password == argv(3)) { print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller))); }
 783
 784                                                 else // everything went okay, proceed with giving this player master privilages
 785                                                 {
 786                                                         caller.vote_master = TRUE;
 787                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 788                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 789                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid))); }
 790                                                 }
 791
 792                                                 return;
 793                                         }
 794
 795                                         default: // calling a vote for master
 796                                         {
 797                                                 float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 798                                                         || ((autocvar_sv_vote_nospectators == 1) && inWarmupStage)
 799                                                         || (autocvar_sv_vote_nospectators == 0));
 800
 801                                                 if not(autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
 802                                                 else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
 803                                                 else if(!spectators_allowed && (caller && !IS_PLAYER(caller))) { print_to(caller, "^1Only players can call a vote."); }
 804                                                 else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
 805
 806                                                 else // everything went okay, continue with creating vote
 807                                                 {
 808                                                         vote_caller = caller;
 809                                                         vote_called = VOTE_MASTER;
 810                                                         vote_called_command = strzone("XXX");
 811                                                         vote_called_display = strzone("^3master");
 812                                                         vote_endtime = time + autocvar_sv_vote_timeout;
 813
 814                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 815                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 816
 817                                                         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2 calls a vote to become ^3master^2.\n");
 818                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
 819                                                         Nagger_VoteChanged();
 820                                                         VoteCount(TRUE); // needed if you are the only one
 821                                                 }
 822
 823                                                 return;
 824                                         }
 825                                 }
 826                         }
 827                         else { print_to(caller, "^1Master control of voting is not allowed."); }
 828
 829                         return;
 830                 }
 831
 832                 default:
 833                 case CMD_REQUEST_USAGE:
 834                 {
 835                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
 836                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
 837                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
 838                         return;
 839                 }
 840         }
 841 }
 842
 843 void VoteCommand_no(float request, entity caller) // CLIENT ONLY
 844 {
 845         switch(request)
 846         {
 847                 case CMD_REQUEST_COMMAND:
 848                 {
 849                         if not(vote_called) { print_to(caller, "^1No vote called."); }
 850                         else if not(caller.vote_selection == VOTE_SELECT_NULL || autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 851                         else if(((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote) { VoteStop(caller); }
 852
 853                         else // everything went okay, continue changing vote
 854                         {
 855                                 print_to(caller, "^1You rejected the vote.");
 856                                 caller.vote_selection = VOTE_SELECT_REJECT;
 857                                 msg_entity = caller;
 858                                 if(!autocvar_sv_vote_singlecount) { VoteCount(FALSE); }
 859                         }
 860
 861                         return;
 862                 }
 863
 864                 default:
 865                 case CMD_REQUEST_USAGE:
 866                 {
 867                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
 868                         print_to(caller, "  No arguments required.");
 869                         return;
 870                 }
 871         }
 872 }
 873
 874 void VoteCommand_status(float request, entity caller) // BOTH
 875 {
 876         switch(request)
 877         {
 878                 case CMD_REQUEST_COMMAND:
 879                 {
 880                         if(vote_called)
 881                                 print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", GetCallerName(vote_caller), "^7."));
 882                         else
 883                                 print_to(caller, "^1No vote called.");
 884
 885                         return;
 886                 }
 887
 888                 default:
 889                 case CMD_REQUEST_USAGE:
 890                 {
 891                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
 892                         print_to(caller, "  No arguments required.");
 893                         return;
 894                 }
 895         }
 896 }
 897
 898 void VoteCommand_stop(float request, entity caller) // BOTH
 899 {
 900         switch(request)
 901         {
 902                 case CMD_REQUEST_COMMAND:
 903                 {
 904                         if not(vote_called) { print_to(caller, "^1No vote called."); }
 905                         else if((caller == vote_caller) || !caller || caller.vote_master) { VoteStop(caller); }
 906                         else { print_to(caller, "^1You are not allowed to stop that vote."); }
 907
 908                         return;
 909                 }
 910
 911                 default:
 912                 case CMD_REQUEST_USAGE:
 913                 {
 914                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
 915                         print_to(caller, "  No arguments required.");
 916                         return;
 917                 }
 918         }
 919 }
 920
 921 void VoteCommand_yes(float request, entity caller) // CLIENT ONLY
 922 {
 923         switch(request)
 924         {
 925                 case CMD_REQUEST_COMMAND:
 926                 {
 927                         if not(vote_called) { print_to(caller, "^1No vote called."); }
 928                         else if not(caller.vote_selection == VOTE_SELECT_NULL || autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 929
 930                         else // everything went okay, continue changing vote
 931                         {
 932                                 print_to(caller, "^1You accepted the vote.");
 933                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
 934                                 msg_entity = caller;
 935                                 if(!autocvar_sv_vote_singlecount) { VoteCount(FALSE); }
 936                         }
 937
 938                         return;
 939                 }
 940
 941                 default:
 942                 case CMD_REQUEST_USAGE:
 943                 {
 944                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
 945                         print_to(caller, "  No arguments required.");
 946                         return;
 947                 }
 948         }
 949 }
 950
 951 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 952 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 953 void VoteCommand_(float request)
 954 {
 955         switch(request)
 956         {
 957                 case CMD_REQUEST_COMMAND:
 958                 {
 959
 960                         return;
 961                 }
 962
 963                 default:
 964                 case CMD_REQUEST_USAGE:
 965                 {
 966                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
 967                         print_to(caller, "  No arguments required.");
 968                         return;
 969                 }
 970         }
 971 }
 972 */
 973
 974
 975 // ================================
 976 //  Macro system for vote commands
 977 // ================================
 978
 979 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 980 #define VOTE_COMMANDS(request,caller,arguments,command) \
 981         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
 982         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
 983         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
 984         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
 985         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
 986         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
 987         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
 988         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
 989         /* nothing */
 990
 991 void VoteCommand_macro_help(entity caller, float argc)
 992 {
 993         string command_origin = GetCommandPrefix(caller);
 994
 995         if(argc == 2) // help display listing all commands
 996         {
 997                 print_to(caller, "\nVoting commands:\n");
 998                 #define VOTE_COMMAND(name,function,description,assignment) \
 999                         { if(Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1000
1001                 VOTE_COMMANDS(0, caller, 0, "")
1002                 #undef VOTE_COMMAND
1003
1004                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1005                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1006                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1007         }
1008         else // usage for individual command
1009         {
1010                 #define VOTE_COMMAND(name,function,description,assignment) \
1011                         { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(2))) { function; return; } } }
1012
1013                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "")
1014                 #undef VOTE_COMMAND
1015         }
1016
1017         return;
1018 }
1019
1020 float VoteCommand_macro_command(entity caller, float argc, string vote_command)
1021 {
1022         #define VOTE_COMMAND(name,function,description,assignment) \
1023                 { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(1))) { function; return TRUE; } } }
1024
1025         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command)
1026         #undef VOTE_COMMAND
1027
1028         return FALSE;
1029 }
1030
1031
1032 // ======================================
1033 //  Main function handling vote commands
1034 // ======================================
1035
1036 void VoteCommand(float request, entity caller, float argc, string vote_command)
1037 {
1038         // Guide for working with argc arguments by example:
1039         // argc:   1    - 2      - 3     - 4
1040         // argv:   0    - 1      - 2     - 3
1041         // cmd     vote - master - login - password
1042
1043         switch(request)
1044         {
1045                 case CMD_REQUEST_COMMAND:
1046                 {
1047                         if(VoteCommand_macro_command(caller, argc, vote_command))
1048                                 return;
1049                 }
1050
1051                 default:
1052                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1053                 case CMD_REQUEST_USAGE:
1054                 {
1055                         VoteCommand_macro_help(caller, argc);
1056                         return;
1057                 }
1058         }
1059 }