qcsrc/server/command/vote.qc

   1 // =============================================
   2 //  Server side voting code, reworked by Samual
   3 //  Last updated: December 27th, 2011
   4 // =============================================
   5
   6 //  Nagger for players to know status of voting
   7 float Nagger_SendEntity(entity to, float sendflags)
   8 {
   9         float nags, i, f, b;
  10         entity e;
  11         WriteByte(MSG_ENTITY, ENT_CLIENT_NAGGER);
  12
  13         // bits:
  14         //   1 = ready
  15         //   2 = player needs to ready up
  16         //   4 = vote
  17         //   8 = player needs to vote
  18         //  16 = warmup
  19         // sendflags:
  20         //  64 = vote counts
  21         // 128 = vote string
  22
  23         nags = 0;
  24         if(readycount)
  25         {
  26                 nags |= 1;
  27                 if(to.ready == 0)
  28                         nags |= 2;
  29         }
  30         if(vote_called)
  31         {
  32                 nags |= 4;
  33                 if(to.vote_selection == 0)
  34                         nags |= 8;
  35         }
  36         if(inWarmupStage)
  37                 nags |= 16;
  38
  39         if(sendflags & 64)
  40                 nags |= 64;
  41
  42         if(sendflags & 128)
  43                 nags |= 128;
  44
  45         if(!(nags & 4)) // no vote called? send no string
  46                 nags &~= (64 | 128);
  47
  48         WriteByte(MSG_ENTITY, nags);
  49
  50         if(nags & 64)
  51         {
  52                 WriteByte(MSG_ENTITY, vote_accept_count);
  53                 WriteByte(MSG_ENTITY, vote_reject_count);
  54                 WriteByte(MSG_ENTITY, vote_needed_overall);
  55                 WriteChar(MSG_ENTITY, to.vote_selection);
  56         }
  57
  58         if(nags & 128)
  59                 WriteString(MSG_ENTITY, vote_called_display);
  60
  61         if(nags & 1)
  62         {
  63                 for(i = 1; i <= maxclients; i += 8)
  64                 {
  65                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
  66                                 if(clienttype(e) != CLIENTTYPE_REAL || e.ready)
  67                                         f |= b;
  68                         WriteByte(MSG_ENTITY, f);
  69                 }
  70         }
  71
  72         return TRUE;
  73 }
  74
  75 void Nagger_Init()
  76 {
  77         Net_LinkEntity(nagger = spawn(), FALSE, 0, Nagger_SendEntity);
  78 }
  79
  80 void Nagger_VoteChanged()
  81 {
  82         if(nagger)
  83                 nagger.SendFlags |= 128;
  84 }
  85
  86 void Nagger_VoteCountChanged()
  87 {
  88         if(nagger)
  89                 nagger.SendFlags |= 64;
  90 }
  91
  92 void Nagger_ReadyCounted()
  93 {
  94         if(nagger)
  95                 nagger.SendFlags |= 1;
  96 }
  97
  98
  99 // =======================
 100 //  Game logic for voting
 101 // =======================
 102
 103 void VoteReset()
 104 {
 105         entity tmp_player;
 106
 107         FOR_EACH_CLIENT(tmp_player) { tmp_player.vote_selection = 0; }
 108
 109         if(vote_called)
 110         {
 111                 strunzone(vote_called_command);
 112                 strunzone(vote_called_display);
 113         }
 114
 115         vote_called = VOTE_NULL;
 116         vote_caller = world;
 117         vote_endtime = 0;
 118
 119         vote_called_command = string_null;
 120         vote_called_display = string_null;
 121
 122         vote_parsed_command = string_null;
 123         vote_parsed_display = string_null;
 124
 125         Nagger_VoteChanged();
 126 }
 127
 128 void VoteStop(entity stopper)
 129 {
 130         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", GetCallerName(vote_caller), "^2's vote\n");
 131         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid))); }
 132
 133         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 134         if((vote_caller) && (stopper == vote_caller)) { vote_caller.vote_waittime = time + autocvar_sv_vote_stop; }
 135
 136         VoteReset();
 137 }
 138
 139 void VoteAccept()
 140 {
 141         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 142
 143         if((vote_called == VOTE_MASTER) && vote_caller)
 144                 vote_caller.vote_master = 1;
 145         else
 146                 localcmd(strcat(vote_called_command, "\n"));
 147
 148         if(vote_caller) { vote_caller.vote_waittime = 0; } // people like your votes, you don't need to wait to vote again
 149
 150         VoteReset();
 151         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 152 }
 153
 154 void VoteReject()
 155 {
 156         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 157         VoteReset();
 158         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
 159 }
 160
 161 void VoteTimeout()
 162 {
 163         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ", vote_called_display, "^2 timed out\n");
 164         VoteReset();
 165         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
 166 }
 167
 168 void VoteSpam(float notvoters, float mincount, string result)
 169 {
 170         bprint(strcat(
 171                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 172                 strcat("^2:^1", ftos(vote_reject_count)),
 173                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 174                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 175                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 176
 177         if(autocvar_sv_eventlog)
 178         {
 179                 GameLogEcho(strcat(
 180                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 181                         strcat(":", ftos(vote_reject_count)),
 182                         strcat(":", ftos(vote_abstain_count)),
 183                         strcat(":", ftos(notvoters)),
 184                         strcat(":", ftos(mincount))));
 185         }
 186 }
 187
 188 void VoteCount(float first_count)
 189 {
 190         // declarations
 191         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 192
 193         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 194                                 || ((autocvar_sv_vote_nospectators == 1) && (inWarmupStage || gameover))
 195                                 || (autocvar_sv_vote_nospectators == 0));
 196
 197         float vote_player_count = 0, is_player, notvoters = 0;
 198         float vote_real_player_count = 0, vote_real_accept_count = 0;
 199         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 200         float vote_needed_of_voted, final_needed_votes;
 201         float vote_factor_overall, vote_factor_of_voted;
 202
 203         entity tmp_player;
 204
 205         Nagger_VoteCountChanged();
 206
 207         // add up all the votes from each connected client
 208         FOR_EACH_REALCLIENT(tmp_player)
 209         {
 210                 is_player = (tmp_player.classname == "player");
 211
 212                 ++vote_player_count;
 213                 if(is_player) { ++vote_real_player_count; }
 214
 215                 switch(tmp_player.vote_selection)
 216                 {
 217                         case VOTE_SELECT_REJECT: { ++vote_reject_count; { if(is_player) ++vote_real_reject_count; } break; }
 218                         case VOTE_SELECT_ACCEPT: { ++vote_accept_count; { if(is_player) ++vote_real_reject_count; } break; }
 219                         case VOTE_SELECT_ABSTAIN: { ++vote_abstain_count; { if(is_player) ++vote_real_abstain_count; } break; }
 220                         default: break;
 221                 }
 222         }
 223
 224         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 225         if((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 226         {
 227                 if(vote_caller) { vote_caller.vote_waittime = 0; }
 228                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 229                 VoteReset();
 230                 return;
 231         }
 232
 233         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 234         if(!spectators_allowed && (vote_real_player_count > 0))
 235         {
 236                 vote_accept_count = vote_real_accept_count;
 237                 vote_reject_count = vote_real_reject_count;
 238                 vote_abstain_count = vote_real_abstain_count;
 239                 vote_player_count = vote_real_player_count;
 240         }
 241
 242         // people who have no opinion in any way :D
 243         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 244
 245         // determine the goal for the vote to be passed or rejected normally
 246         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 247         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 248
 249         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 250         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 251         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 252
 253         // are there any players at all on the server? it could be an admin vote
 254         if(vote_player_count == 0 && first_count)
 255         {
 256                 VoteSpam(0, -1, "yes"); // no players at all, just accept it
 257                 VoteAccept();
 258                 return;
 259         }
 260
 261         // since there ARE players, finally calculate the result of the vote
 262         if(vote_accept_count >= vote_needed_overall)
 263         {
 264                 VoteSpam(notvoters, -1, "yes"); // there is enough acceptions to pass the vote
 265                 VoteAccept();
 266                 return;
 267         }
 268
 269         if(vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 270         {
 271                 VoteSpam(notvoters, -1, "no"); // there is enough rejections to deny the vote
 272                 VoteReject();
 273                 return;
 274         }
 275
 276         // there is not enough votes in either direction, now lets just calculate what the voters have said
 277         if(time > vote_endtime)
 278         {
 279                 final_needed_votes = vote_needed_overall;
 280
 281                 if(autocvar_sv_vote_majority_factor_of_voted)
 282                 {
 283                         if(vote_accept_count >= vote_needed_of_voted)
 284                         {
 285                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 286                                 VoteAccept();
 287                                 return;
 288                         }
 289
 290                         if(vote_accept_count + vote_reject_count > 0)
 291                         {
 292                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 293                                 VoteReject();
 294                                 return;
 295                         }
 296
 297                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 298                 }
 299
 300                 // it didn't pass or fail, so not enough votes to even make a decision.
 301                 VoteSpam(notvoters, final_needed_votes, "timeout");
 302                 VoteTimeout();
 303         }
 304 }
 305
 306 void VoteThink()
 307 {
 308         if(vote_endtime > 0) // a vote was called
 309         if(time > vote_endtime) // time is up
 310         {
 311                 VoteCount(FALSE);
 312         }
 313
 314         return;
 315 }
 316
 317
 318 // =======================
 319 //  Game logic for warmup
 320 // =======================
 321
 322 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 323 void ReadyRestart_think()
 324 {
 325         restart_mapalreadyrestarted = 1;
 326         reset_map(TRUE);
 327         Score_ClearAll();
 328         remove(self);
 329
 330         return;
 331 }
 332
 333 // Forces a restart of the game without actually reloading the map // this is a mess...
 334 void ReadyRestart_force()
 335 {
 336         entity tmp_player, restart_timer;
 337
 338         bprint("^1Server is restarting...\n");
 339
 340         VoteReset();
 341
 342         // clear overtime, we have to decrease timelimit to its original value again.
 343         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2) { cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime))); }
 344
 345         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 346
 347         readyrestart_happened = 1;
 348         game_starttime = time;
 349         if(!g_ca && !g_arena) { game_starttime += RESTART_COUNTDOWN; }
 350
 351         // clear player attributes
 352         FOR_EACH_CLIENT(tmp_player)
 353         {
 354                 tmp_player.alivetime = 0;
 355                 tmp_player.killcount = 0;
 356                 PlayerStats_Event(tmp_player, PLAYERSTATS_ALIVETIME, -PlayerStats_Event(tmp_player, PLAYERSTATS_ALIVETIME, 0));
 357         }
 358
 359         restart_mapalreadyrestarted = 0; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 360
 361         // disable the warmup global for the server
 362         inWarmupStage = 0; // once the game is restarted the game is in match stage
 363
 364         // reset the .ready status of all players (also spectators)
 365         FOR_EACH_CLIENTSLOT(tmp_player) { tmp_player.ready = 0; }
 366         readycount = 0;
 367         Nagger_ReadyCounted(); // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 368
 369         // lock teams with lockonrestart
 370         if(autocvar_teamplay_lockonrestart && teamplay)
 371         {
 372                 lockteams = 1;
 373                 bprint("^1The teams are now locked.\n");
 374         }
 375
 376         //initiate the restart-countdown-announcer entity
 377         if(autocvar_sv_ready_restart_after_countdown && !g_ca && !g_arena)
 378         {
 379                 restart_timer = spawn();
 380                 restart_timer.think = ReadyRestart_think;
 381                 restart_timer.nextthink = game_starttime;
 382         }
 383
 384         // after a restart every players number of allowed timeouts gets reset, too
 385         if(autocvar_sv_timeout) { FOR_EACH_REALPLAYER(tmp_player) { tmp_player.allowed_timeouts = autocvar_sv_timeout_number; } }
 386
 387         //reset map immediately if this cvar is not set
 388         if not(autocvar_sv_ready_restart_after_countdown) { reset_map(TRUE); }
 389
 390         if(autocvar_sv_eventlog) { GameLogEcho(":restart"); }
 391 }
 392
 393 void ReadyRestart()
 394 {
 395         // no arena, assault support yet...
 396         if(g_arena | g_assault | gameover | intermission_running | race_completing)
 397                 localcmd("restart\n");
 398         else
 399                 localcmd("\nsv_hook_gamerestart\n");
 400
 401         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 402         // Otherwise scores could be manipulated during the countdown.
 403         if not(autocvar_sv_ready_restart_after_countdown) { Score_ClearAll(); }
 404
 405         ReadyRestart_force();
 406
 407         return;
 408 }
 409
 410 // Count the players who are ready and determine whether or not to restart the match
 411 void ReadyCount()
 412 {
 413         entity tmp_player;
 414         float ready_needed_factor, ready_needed_count;
 415         float t_ready = 0, t_players = 0;
 416
 417         FOR_EACH_REALPLAYER(tmp_player)
 418         {
 419                 ++t_players;
 420                 if(tmp_player.ready) { ++t_ready; }
 421         }
 422
 423         readycount = t_ready;
 424
 425         Nagger_ReadyCounted();
 426
 427         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 428         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 429
 430         if(readycount >= ready_needed_count)
 431         {
 432                 ReadyRestart();
 433         }
 434
 435         return;
 436 }
 437
 438
 439 // ======================================
 440 //  Supporting functions for VoteCommand
 441 // ======================================
 442
 443 float Votecommand_check_assignment(entity caller, float assignment)
 444 {
 445         float from_server = (!caller);
 446
 447         if((assignment == VC_ASGNMNT_BOTH)
 448                 || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 449                 || (from_server && assignment == VC_ASGNMNT_SERVERONLY)))
 450         {
 451                 return TRUE;
 452         }
 453
 454         return FALSE;
 455 }
 456
 457 string VoteCommand_extractcommand(string input, float startpos, float argc)
 458 {
 459         string output;
 460
 461         if((argc - 1) < startpos)
 462                 output = "";
 463         else
 464                 output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 465
 466         return output;
 467 }
 468
 469 float VoteCommand_checknasty(string vote_command)
 470 {
 471         if((strstrofs(vote_command, ";", 0) >= 0)
 472                 || (strstrofs(vote_command, "\n", 0) >= 0)
 473                 || (strstrofs(vote_command, "\r", 0) >= 0)
 474                 || (strstrofs(vote_command, "$", 0) >= 0))
 475                 return FALSE;
 476
 477         return TRUE;
 478 }
 479
 480 float VoteCommand_checkinlist(string vote_command, string list)
 481 {
 482         string l = strcat(" ", list, " ");
 483
 484         if(strstrofs(l, strcat(" ", vote_command, " "), 0) >= 0)
 485                 return TRUE;
 486
 487         return FALSE;
 488 }
 489
 490 string ValidateMap(string validated_map, entity caller)
 491 {
 492         validated_map = MapInfo_FixName(validated_map);
 493
 494         if not(validated_map)
 495         {
 496                 print_to(caller, "This map is not available on this server.");
 497                 return string_null;
 498         }
 499
 500         if(!autocvar_sv_vote_override_mostrecent && caller)
 501         {
 502                 if(Map_IsRecent(validated_map))
 503                 {
 504                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 505                         return string_null;
 506                 }
 507         }
 508
 509         if(!MapInfo_CheckMap(validated_map))
 510         {
 511                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 512                 return string_null;
 513         }
 514
 515         return validated_map;
 516 }
 517
 518 float VoteCommand_checkargs(float startpos, float argc)
 519 {
 520         float p, q, check, minargs;
 521         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 522         string cmdrestriction = cvar_string(cvarname); // note: this warns on undefined cvar. We want that.
 523         string charlist, arg;
 524         float checkmate;
 525
 526         if(cmdrestriction == "")
 527                 return TRUE;
 528
 529         ++startpos; // skip command name
 530
 531         // check minimum arg count
 532
 533         // 0 args: argc == startpos
 534         // 1 args: argc == startpos + 1
 535         // ...
 536
 537         minargs = stof(cmdrestriction);
 538         if(argc - startpos < minargs)
 539                 return FALSE;
 540
 541         p = strstrofs(cmdrestriction, ";", 0); // find first semicolon
 542
 543         for(;;)
 544         {
 545                 // we know that at any time, startpos <= argc - minargs
 546                 // so this means: argc-minargs >= startpos >= argc, thus
 547                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 548                 // have been seen already
 549
 550                 if(startpos >= argc) // all args checked? GOOD
 551                         break;
 552
 553                 if(p < 0) // no more args? FAIL
 554                 {
 555                         // exception: exactly minargs left, this one included
 556                         if(argc - startpos == minargs)
 557                                 break;
 558
 559                         // otherwise fail
 560                         return FALSE;
 561                 }
 562
 563                 // cut to next semicolon
 564                 q = strstrofs(cmdrestriction, ";", p+1); // find next semicolon
 565                 if(q < 0)
 566                         charlist = substring(cmdrestriction, p+1, -1);
 567                 else
 568                         charlist = substring(cmdrestriction, p+1, q - (p+1));
 569
 570                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 571                 // charlist = strreplace("^^", ";", charlist);
 572
 573                 if(charlist != "")
 574                 {
 575                         // verify the arg only contains allowed chars
 576                         arg = argv(startpos);
 577                         checkmate = strlen(arg);
 578                         for(check = 0; check < checkmate; ++check)
 579                                 if(strstrofs(charlist, substring(arg, check, 1), 0) < 0)
 580                                         return FALSE; // not allowed character
 581                         // all characters are allowed. FINE.
 582                 }
 583
 584                 ++startpos;
 585                 --minargs;
 586                 p = q;
 587         }
 588
 589         return TRUE;
 590 }
 591
 592 float VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, float argc)
 593 {
 594         string first_command;
 595
 596         first_command = argv(startpos);
 597
 598         if not(VoteCommand_checkinlist(first_command, vote_list))
 599                 return FALSE;
 600
 601         if not(VoteCommand_checkargs(startpos, argc))
 602                 return FALSE;
 603
 604         switch(first_command) // now go through and parse the proper commands to adjust as needed.
 605         {
 606                 case "kick":
 607                 case "kickban": // catch all kick/kickban commands
 608                 {
 609                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 610                         float accepted = VerifyClientEntity(victim, TRUE, FALSE);
 611
 612                         if(accepted > 0)
 613                         {
 614                                 string reason = ((argc > next_token) ? substring(vote_command, argv_start_index(next_token), strlen(vote_command) - argv_start_index(next_token)) : "No reason provided");
 615                                 string command_arguments;
 616
 617                                 if(first_command == "kickban")
 618                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 619                                 else
 620                                         command_arguments = reason;
 621
 622                                 vote_parsed_command = strcat(first_command, " # ", ftos(num_for_edict(victim)), " ", command_arguments);
 623                                 vote_parsed_display = strcat("^1", vote_command, " (^7", victim.netname, "^1): ", reason);
 624                         }
 625                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return FALSE; }
 626
 627                         break;
 628                 }
 629
 630                 case "map":
 631                 case "chmap":
 632                 case "gotomap": // re-direct all map selection commands to gotomap
 633                 {
 634                         vote_command = ValidateMap(argv(startpos + 1), caller);
 635                         if not(vote_command) { return FALSE; }
 636                         vote_parsed_command = strcat("gotomap ", vote_command);
 637                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 638
 639                         break;
 640                 }
 641
 642                 default:
 643                 {
 644                         vote_parsed_command = vote_command;
 645                         vote_parsed_display = strzone(strcat("^1", vote_command));
 646
 647                         break;
 648                 }
 649         }
 650
 651         return TRUE;
 652 }
 653
 654
 655 // =======================
 656 //  Command Sub-Functions
 657 // =======================
 658
 659 void VoteCommand_abstain(float request, entity caller) // CLIENT ONLY
 660 {
 661         switch(request)
 662         {
 663                 case CMD_REQUEST_COMMAND:
 664                 {
 665                         if not(vote_called) { print_to(caller, "^1No vote called."); }
 666                         else if not(caller.vote_selection == VOTE_SELECT_NULL || autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 667
 668                         else // everything went okay, continue changing vote
 669                         {
 670                                 print_to(caller, "^1You abstained from your vote.");
 671                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 672                                 msg_entity = caller;
 673                                 if(!autocvar_sv_vote_singlecount) { VoteCount(FALSE); }
 674                         }
 675
 676                         return;
 677                 }
 678
 679                 default:
 680                 case CMD_REQUEST_USAGE:
 681                 {
 682                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 683                         print_to(caller, "  No arguments required.");
 684                         return;
 685                 }
 686         }
 687 }
 688
 689 void VoteCommand_call(float request, entity caller, float argc, string vote_command) // BOTH
 690 {
 691         switch(request)
 692         {
 693                 case CMD_REQUEST_COMMAND:
 694                 {
 695                         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 696                                 || ((autocvar_sv_vote_nospectators == 1) && inWarmupStage)
 697                                 || (autocvar_sv_vote_nospectators == 0));
 698
 699                         float tmp_playercount = 0;
 700                         entity tmp_player;
 701
 702                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 703
 704                         if not(autocvar_sv_vote_call || !caller) { print_to(caller, "^1Vote calling is not allowed."); }
 705                         else if(!autocvar_sv_vote_gamestart && time < game_starttime) { print_to(caller, "^1Vote calling is not allowed before the match has started."); }
 706                         else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
 707                         else if(!spectators_allowed && (caller && (caller.classname != "player"))) { print_to(caller, "^1Only players can call a vote."); }
 708                         else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
 709                         else if(caller && (time < caller.vote_waittime)) { print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote.")); }
 710                         else if not(VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
 711                         else if not(VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
 712
 713                         else // everything went okay, continue with calling the vote
 714                         {
 715                                 vote_caller = caller; // remember who called the vote
 716                                 vote_called = VOTE_NORMAL;
 717                                 vote_called_command = strzone(vote_parsed_command);
 718                                 vote_called_display = strzone(vote_parsed_display);
 719                                 vote_endtime = time + autocvar_sv_vote_timeout;
 720
 721                                 if(caller)
 722                                 {
 723                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 724                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 725                                         msg_entity = caller;
 726                                 }
 727
 728                                 FOR_EACH_REALCLIENT(tmp_player) { ++tmp_playercount; }
 729                                 if(tmp_playercount > 1) { Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_CALL); } // don't announce a "vote now" sound if player is alone
 730
 731                                 bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2 calls a vote for ", vote_called_display, "\n");
 732                                 if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
 733                                 Nagger_VoteChanged();
 734                                 VoteCount(TRUE); // needed if you are the only one
 735                         }
 736
 737                         return;
 738                 }
 739
 740                 default:
 741                 case CMD_REQUEST_USAGE:
 742                 {
 743                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
 744                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
 745                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 746                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 747                         return;
 748                 }
 749         }
 750 }
 751
 752 void VoteCommand_master(float request, entity caller, float argc, string vote_command) // CLIENT ONLY
 753 {
 754         switch(request)
 755         {
 756                 case CMD_REQUEST_COMMAND:
 757                 {
 758                         if(autocvar_sv_vote_master)
 759                         {
 760                                 switch(strtolower(argv(2)))
 761                                 {
 762                                         case "do":
 763                                         {
 764                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 765
 766                                                 if not(caller.vote_master) { print_to(caller, "^1You do not have vote master privelages."); }
 767                                                 else if not(VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
 768                                                 else if not(VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
 769
 770                                                 else // everything went okay, proceed with command
 771                                                 {
 772                                                         localcmd(strcat(vote_parsed_command, "\n"));
 773                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 774                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 775                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display)); }
 776                                                 }
 777
 778                                                 return;
 779                                         }
 780
 781                                         case "login":
 782                                         {
 783                                                 if not(autocvar_sv_vote_master_password != "") { print_to(caller, "^1Login to vote master is not allowed."); }
 784                                                 else if(caller.vote_master) { print_to(caller, "^1You are already logged in as vote master."); }
 785                                                 else if not(autocvar_sv_vote_master_password == argv(3)) { print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller))); }
 786
 787                                                 else // everything went okay, proceed with giving this player master privilages
 788                                                 {
 789                                                         caller.vote_master = TRUE;
 790                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 791                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 792                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid))); }
 793                                                 }
 794
 795                                                 return;
 796                                         }
 797
 798                                         default: // calling a vote for master
 799                                         {
 800                                                 float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 801                                                         || ((autocvar_sv_vote_nospectators == 1) && inWarmupStage)
 802                                                         || (autocvar_sv_vote_nospectators == 0));
 803
 804                                                 if not(autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
 805                                                 else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
 806                                                 else if(!spectators_allowed && (caller && (caller.classname != "player"))) { print_to(caller, "^1Only players can call a vote."); }
 807                                                 else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
 808
 809                                                 else // everything went okay, continue with creating vote
 810                                                 {
 811                                                         vote_caller = caller;
 812                                                         vote_called = VOTE_MASTER;
 813                                                         vote_called_command = strzone("XXX");
 814                                                         vote_called_display = strzone("^3master");
 815                                                         vote_endtime = time + autocvar_sv_vote_timeout;
 816
 817                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 818                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 819
 820                                                         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2 calls a vote to become ^3master^2.\n");
 821                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
 822                                                         Nagger_VoteChanged();
 823                                                         VoteCount(TRUE); // needed if you are the only one
 824                                                 }
 825
 826                                                 return;
 827                                         }
 828                                 }
 829                         }
 830                         else { print_to(caller, "^1Master control of voting is not allowed."); }
 831
 832                         return;
 833                 }
 834
 835                 default:
 836                 case CMD_REQUEST_USAGE:
 837                 {
 838                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
 839                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
 840                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
 841                         return;
 842                 }
 843         }
 844 }
 845
 846 void VoteCommand_no(float request, entity caller) // CLIENT ONLY
 847 {
 848         switch(request)
 849         {
 850                 case CMD_REQUEST_COMMAND:
 851                 {
 852                         if not(vote_called) { print_to(caller, "^1No vote called."); }
 853                         else if not(caller.vote_selection == VOTE_SELECT_NULL || autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 854                         else if(((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote) { VoteStop(caller); }
 855
 856                         else // everything went okay, continue changing vote
 857                         {
 858                                 print_to(caller, "^1You rejected the vote.");
 859                                 caller.vote_selection = VOTE_SELECT_REJECT;
 860                                 msg_entity = caller;
 861                                 if(!autocvar_sv_vote_singlecount) { VoteCount(FALSE); }
 862                         }
 863
 864                         return;
 865                 }
 866
 867                 default:
 868                 case CMD_REQUEST_USAGE:
 869                 {
 870                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
 871                         print_to(caller, "  No arguments required.");
 872                         return;
 873                 }
 874         }
 875 }
 876
 877 void VoteCommand_status(float request, entity caller) // BOTH
 878 {
 879         switch(request)
 880         {
 881                 case CMD_REQUEST_COMMAND:
 882                 {
 883                         if(vote_called)
 884                                 print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", GetCallerName(vote_caller), "^7."));
 885                         else
 886                                 print_to(caller, "^1No vote called.");
 887
 888                         return;
 889                 }
 890
 891                 default:
 892                 case CMD_REQUEST_USAGE:
 893                 {
 894                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
 895                         print_to(caller, "  No arguments required.");
 896                         return;
 897                 }
 898         }
 899 }
 900
 901 void VoteCommand_stop(float request, entity caller) // BOTH
 902 {
 903         switch(request)
 904         {
 905                 case CMD_REQUEST_COMMAND:
 906                 {
 907                         if not(vote_called) { print_to(caller, "^1No vote called."); }
 908                         else if((caller == vote_caller) || !caller || caller.vote_master) { VoteStop(caller); }
 909                         else { print_to(caller, "^1You are not allowed to stop that vote."); }
 910
 911                         return;
 912                 }
 913
 914                 default:
 915                 case CMD_REQUEST_USAGE:
 916                 {
 917                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
 918                         print_to(caller, "  No arguments required.");
 919                         return;
 920                 }
 921         }
 922 }
 923
 924 void VoteCommand_yes(float request, entity caller) // CLIENT ONLY
 925 {
 926         switch(request)
 927         {
 928                 case CMD_REQUEST_COMMAND:
 929                 {
 930                         if not(vote_called) { print_to(caller, "^1No vote called."); }
 931                         else if not(caller.vote_selection == VOTE_SELECT_NULL || autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 932
 933                         else // everything went okay, continue changing vote
 934                         {
 935                                 print_to(caller, "^1You accepted the vote.");
 936                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
 937                                 msg_entity = caller;
 938                                 if(!autocvar_sv_vote_singlecount) { VoteCount(FALSE); }
 939                         }
 940
 941                         return;
 942                 }
 943
 944                 default:
 945                 case CMD_REQUEST_USAGE:
 946                 {
 947                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
 948                         print_to(caller, "  No arguments required.");
 949                         return;
 950                 }
 951         }
 952 }
 953
 954 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 955 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 956 void VoteCommand_(float request)
 957 {
 958         switch(request)
 959         {
 960                 case CMD_REQUEST_COMMAND:
 961                 {
 962
 963                         return;
 964                 }
 965
 966                 default:
 967                 case CMD_REQUEST_USAGE:
 968                 {
 969                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
 970                         print_to(caller, "  No arguments required.");
 971                         return;
 972                 }
 973         }
 974 }
 975 */
 976
 977
 978 // ================================
 979 //  Macro system for vote commands
 980 // ================================
 981
 982 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 983 #define VOTE_COMMANDS(request,caller,arguments,command) \
 984         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
 985         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
 986         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
 987         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
 988         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
 989         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
 990         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
 991         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
 992         /* nothing */
 993
 994 void VoteCommand_macro_help(entity caller, float argc)
 995 {
 996         string command_origin = GetCommandPrefix(caller);
 997
 998         if(argc == 2) // help display listing all commands
 999         {
1000                 print_to(caller, "\nVoting commands:\n");
1001                 #define VOTE_COMMAND(name,function,description,assignment) \
1002                         { if(Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1003
1004                 VOTE_COMMANDS(0, caller, 0, "")
1005                 #undef VOTE_COMMAND
1006
1007                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1008                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1009                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1010         }
1011         else // usage for individual command
1012         {
1013                 #define VOTE_COMMAND(name,function,description,assignment) \
1014                         { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(2))) { function; return; } } }
1015
1016                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "")
1017                 #undef VOTE_COMMAND
1018         }
1019
1020         return;
1021 }
1022
1023 float VoteCommand_macro_command(entity caller, float argc, string vote_command)
1024 {
1025         #define VOTE_COMMAND(name,function,description,assignment) \
1026                 { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(1))) { function; return TRUE; } } }
1027
1028         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command)
1029         #undef VOTE_COMMAND
1030
1031         return FALSE;
1032 }
1033
1034
1035 // ======================================
1036 //  Main function handling vote commands
1037 // ======================================
1038
1039 void VoteCommand(float request, entity caller, float argc, string vote_command)
1040 {
1041         // Guide for working with argc arguments by example:
1042         // argc:   1    - 2      - 3     - 4
1043         // argv:   0    - 1      - 2     - 3
1044         // cmd     vote - master - login - password
1045
1046         switch(request)
1047         {
1048                 case CMD_REQUEST_COMMAND:
1049                 {
1050                         if(VoteCommand_macro_command(caller, argc, vote_command))
1051                                 return;
1052                 }
1053
1054                 default:
1055                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1056                 case CMD_REQUEST_USAGE:
1057                 {
1058                         VoteCommand_macro_help(caller, argc);
1059                         return;
1060                 }
1061         }
1062 }