qcsrc/server/command/vote.qc

   1 // =============================================
   2 //  Server side voting code, reworked by Samual
   3 //  Last updated: December 27th, 2011
   4 // =============================================
   5
   6 //  Nagger for players to know status of voting
   7 float Nagger_SendEntity(entity to, float sendflags)
   8 {
   9         float nags, i, f, b;
  10         entity e;
  11         WriteByte(MSG_ENTITY, ENT_CLIENT_NAGGER);
  12
  13         // bits:
  14         //   1 = ready
  15         //   2 = player needs to ready up
  16         //   4 = vote
  17         //   8 = player needs to vote
  18         //  16 = warmup
  19         // sendflags:
  20         //  64 = vote counts
  21         // 128 = vote string
  22
  23         nags = 0;
  24         if(readycount)
  25         {
  26                 nags |= 1;
  27                 if(to.ready == 0)
  28                         nags |= 2;
  29         }
  30         if(vote_called)
  31         {
  32                 nags |= 4;
  33                 if(to.vote_selection == 0)
  34                         nags |= 8;
  35         }
  36         if(inWarmupStage)
  37                 nags |= 16;
  38
  39         if(sendflags & 64)
  40                 nags |= 64;
  41
  42         if(sendflags & 128)
  43                 nags |= 128;
  44
  45         if(!(nags & 4)) // no vote called? send no string
  46                 nags &~= (64 | 128);
  47
  48         WriteByte(MSG_ENTITY, nags);
  49
  50         if(nags & 64)
  51         {
  52                 WriteByte(MSG_ENTITY, vote_accept_count);
  53                 WriteByte(MSG_ENTITY, vote_reject_count);
  54                 WriteByte(MSG_ENTITY, vote_needed_overall);
  55                 WriteChar(MSG_ENTITY, to.vote_selection);
  56         }
  57
  58         if(nags & 128)
  59                 WriteString(MSG_ENTITY, vote_called_display);
  60
  61         if(nags & 1)
  62         {
  63                 for(i = 1; i <= maxclients; i += 8)
  64                 {
  65                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
  66                                 if(clienttype(e) != CLIENTTYPE_REAL || e.ready)
  67                                         f |= b;
  68                         WriteByte(MSG_ENTITY, f);
  69                 }
  70         }
  71
  72         return TRUE;
  73 }
  74
  75 void Nagger_Init()
  76 {
  77         Net_LinkEntity(nagger = spawn(), FALSE, 0, Nagger_SendEntity);
  78 }
  79
  80 void Nagger_VoteChanged()
  81 {
  82         if(nagger)
  83                 nagger.SendFlags |= 128;
  84 }
  85
  86 void Nagger_VoteCountChanged()
  87 {
  88         if(nagger)
  89                 nagger.SendFlags |= 64;
  90 }
  91
  92 void Nagger_ReadyCounted()
  93 {
  94         if(nagger)
  95                 nagger.SendFlags |= 1;
  96 }
  97
  98
  99 // =======================
 100 //  Game logic for voting
 101 // =======================
 102
 103 void VoteReset()
 104 {
 105         entity tmp_player;
 106
 107         FOR_EACH_CLIENT(tmp_player) { tmp_player.vote_selection = 0; }
 108
 109         if(vote_called)
 110         {
 111                 strunzone(vote_called_command);
 112                 strunzone(vote_called_display);
 113         }
 114
 115         vote_called = VOTE_NULL;
 116         vote_caller = world;
 117         vote_endtime = 0;
 118
 119         vote_called_command = string_null;
 120         vote_called_display = string_null;
 121
 122         vote_parsed_command = string_null;
 123         vote_parsed_display = string_null;
 124
 125         Nagger_VoteChanged();
 126 }
 127
 128 void VoteStop(entity stopper)
 129 {
 130         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", GetCallerName(vote_caller), "^2's vote\n");
 131         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid))); }
 132
 133         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 134         if((vote_caller) && (stopper == vote_caller)) { vote_caller.vote_waittime = time + autocvar_sv_vote_stop; }
 135
 136         VoteReset();
 137 }
 138
 139 void VoteAccept()
 140 {
 141         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 142
 143         if((vote_called == VOTE_MASTER) && vote_caller)
 144                 vote_caller.vote_master = 1;
 145         else
 146                 localcmd(strcat(vote_called_command, "\n"));
 147
 148         if(vote_caller) { vote_caller.vote_waittime = 0; } // people like your votes, you don't need to wait to vote again
 149
 150         VoteReset();
 151         Announce("voteaccept");
 152 }
 153
 154 void VoteReject()
 155 {
 156         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 157         VoteReset();
 158         Announce("votefail");
 159 }
 160
 161 void VoteTimeout()
 162 {
 163         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ", vote_called_display, "^2 timed out\n");
 164         VoteReset();
 165         Announce("votefail");
 166 }
 167
 168 void VoteSpam(float notvoters, float mincount, string result)
 169 {
 170         bprint(strcat(
 171                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 172                 strcat("^2:^1", ftos(vote_reject_count)),
 173                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 174                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 175                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 176
 177         if(autocvar_sv_eventlog)
 178         {
 179                 GameLogEcho(strcat(
 180                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 181                         strcat(":", ftos(vote_reject_count)),
 182                         strcat(":", ftos(vote_abstain_count)),
 183                         strcat(":", ftos(notvoters)),
 184                         strcat(":", ftos(mincount))));
 185         }
 186 }
 187
 188 void VoteCount(float first_count)
 189 {
 190         // declarations
 191         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 192
 193         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 194                                 || ((autocvar_sv_vote_nospectators == 1) && (inWarmupStage || gameover))
 195                                 || (autocvar_sv_vote_nospectators == 0));
 196
 197         float vote_player_count = 0, is_player, notvoters = 0;
 198         float vote_real_player_count = 0, vote_real_accept_count = 0;
 199         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 200         float vote_needed_of_voted, final_needed_votes;
 201         float vote_factor_overall, vote_factor_of_voted;
 202
 203         entity tmp_player;
 204
 205         Nagger_VoteCountChanged();
 206
 207         // add up all the votes from each connected client
 208         FOR_EACH_REALCLIENT(tmp_player)
 209         {
 210                 is_player = (tmp_player.classname == "player");
 211
 212                 ++vote_player_count;
 213                 if(is_player) { ++vote_real_player_count; }
 214
 215                 switch(tmp_player.vote_selection)
 216                 {
 217                         case VOTE_SELECT_REJECT: { ++vote_reject_count; { if(is_player) ++vote_real_reject_count; } break; }
 218                         case VOTE_SELECT_ACCEPT: { ++vote_accept_count; { if(is_player) ++vote_real_reject_count; } break; }
 219                         case VOTE_SELECT_ABSTAIN: { ++vote_abstain_count; { if(is_player) ++vote_real_abstain_count; } break; }
 220                         default: break;
 221                 }
 222         }
 223
 224         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 225         if((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 226         {
 227                 if(vote_caller) { vote_caller.vote_waittime = 0; }
 228                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 229                 VoteReset();
 230                 return;
 231         }
 232
 233         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 234         if(!spectators_allowed && (vote_real_player_count > 0))
 235         {
 236                 vote_accept_count = vote_real_accept_count;
 237                 vote_reject_count = vote_real_reject_count;
 238                 vote_abstain_count = vote_real_abstain_count;
 239                 vote_player_count = vote_real_player_count;
 240         }
 241
 242         // people who have no opinion in any way :D
 243         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 244
 245         // determine the goal for the vote to be passed or rejected normally
 246         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 247         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 248
 249         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 250         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 251         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 252
 253         // are there any players at all on the server? it could be an admin vote
 254         if(vote_player_count == 0 && first_count)
 255         {
 256                 VoteSpam(0, -1, "yes"); // no players at all, just accept it
 257                 VoteAccept();
 258                 return;
 259         }
 260
 261         // since there ARE players, finally calculate the result of the vote
 262         if(vote_accept_count >= vote_needed_overall)
 263         {
 264                 VoteSpam(notvoters, -1, "yes"); // there is enough acceptions to pass the vote
 265                 VoteAccept();
 266                 return;
 267         }
 268
 269         if(vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 270         {
 271                 VoteSpam(notvoters, -1, "no"); // there is enough rejections to deny the vote
 272                 VoteReject();
 273                 return;
 274         }
 275
 276         // there is not enough votes in either direction, now lets just calculate what the voters have said
 277         if(time > vote_endtime)
 278         {
 279                 final_needed_votes = vote_needed_overall;
 280
 281                 if(autocvar_sv_vote_majority_factor_of_voted)
 282                 {
 283                         if(vote_accept_count >= vote_needed_of_voted)
 284                         {
 285                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 286                                 VoteAccept();
 287                                 return;
 288                         }
 289
 290                         if(vote_accept_count + vote_reject_count > 0)
 291                         {
 292                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 293                                 VoteReject();
 294                                 return;
 295                         }
 296
 297                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 298                 }
 299
 300                 // it didn't pass or fail, so not enough votes to even make a decision.
 301                 VoteSpam(notvoters, final_needed_votes, "timeout");
 302                 VoteTimeout();
 303         }
 304 }
 305
 306 void VoteThink()
 307 {
 308         if(vote_endtime > 0) // a vote was called
 309         if(time > vote_endtime) // time is up
 310         {
 311                 VoteCount(FALSE);
 312         }
 313
 314         return;
 315 }
 316
 317
 318 // =======================
 319 //  Game logic for warmup
 320 // =======================
 321
 322 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 323 void ReadyRestart_think()
 324 {
 325         restart_mapalreadyrestarted = 1;
 326         reset_map(TRUE);
 327         Score_ClearAll();
 328         remove(self);
 329
 330         return;
 331 }
 332
 333 // Forces a restart of the game without actually reloading the map // this is a mess...
 334 void ReadyRestart_force()
 335 {
 336         entity tmp_player, restart_timer;
 337
 338         bprint("^1Server is restarting...\n");
 339
 340         VoteReset();
 341
 342         // clear overtime, we have to decrease timelimit to its original value again.
 343         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2) { cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime))); }
 344
 345         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 346
 347         readyrestart_happened = 1;
 348         game_starttime = time;
 349         if(!g_ca && !g_arena) { game_starttime += RESTART_COUNTDOWN; }
 350
 351         // clear alivetime
 352         FOR_EACH_CLIENT(tmp_player)
 353         {
 354                 tmp_player.alivetime = 0;
 355                 PlayerStats_Event(tmp_player, PLAYERSTATS_ALIVETIME, -PlayerStats_Event(tmp_player, PLAYERSTATS_ALIVETIME, 0));
 356         }
 357
 358         restart_mapalreadyrestarted = 0; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 359
 360         // disable the warmup global for the server
 361         inWarmupStage = 0; // once the game is restarted the game is in match stage
 362
 363         // reset the .ready status of all players (also spectators)
 364         FOR_EACH_CLIENTSLOT(tmp_player) { tmp_player.ready = 0; }
 365         readycount = 0;
 366         Nagger_ReadyCounted(); // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 367
 368         // lock teams with lockonrestart
 369         if(autocvar_teamplay_lockonrestart && teamplay)
 370         {
 371                 lockteams = 1;
 372                 bprint("^1The teams are now locked.\n");
 373         }
 374
 375         //initiate the restart-countdown-announcer entity
 376         if(autocvar_sv_ready_restart_after_countdown && !g_ca && !g_arena)
 377         {
 378                 restart_timer = spawn();
 379                 restart_timer.think = ReadyRestart_think;
 380                 restart_timer.nextthink = game_starttime;
 381         }
 382
 383         // after a restart every players number of allowed timeouts gets reset, too
 384         if(autocvar_sv_timeout) { FOR_EACH_REALPLAYER(tmp_player) { tmp_player.allowed_timeouts = autocvar_sv_timeout_number; } }
 385
 386         //reset map immediately if this cvar is not set
 387         if not(autocvar_sv_ready_restart_after_countdown) { reset_map(TRUE); }
 388
 389         if(autocvar_sv_eventlog) { GameLogEcho(":restart"); }
 390 }
 391
 392 void ReadyRestart()
 393 {
 394         // no arena, assault support yet...
 395         if(g_arena | g_assault | gameover | intermission_running | race_completing)
 396                 localcmd("restart\n");
 397         else
 398                 localcmd("\nsv_hook_gamerestart\n");
 399
 400         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 401         // Otherwise scores could be manipulated during the countdown.
 402         if not(autocvar_sv_ready_restart_after_countdown) { Score_ClearAll(); }
 403
 404         ReadyRestart_force();
 405
 406         return;
 407 }
 408
 409 // Count the players who are ready and determine whether or not to restart the match
 410 void ReadyCount()
 411 {
 412         entity tmp_player;
 413         float ready_needed_factor, ready_needed_count;
 414         float t_ready = 0, t_players = 0;
 415
 416         FOR_EACH_REALPLAYER(tmp_player)
 417         {
 418                 ++t_players;
 419                 if(tmp_player.ready) { ++t_ready; }
 420         }
 421
 422         readycount = t_ready;
 423
 424         Nagger_ReadyCounted();
 425
 426         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 427         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 428
 429         if(readycount >= ready_needed_count)
 430         {
 431                 ReadyRestart();
 432         }
 433
 434         return;
 435 }
 436
 437
 438 // ======================================
 439 //  Supporting functions for VoteCommand
 440 // ======================================
 441
 442 float Votecommand_check_assignment(entity caller, float assignment)
 443 {
 444         float from_server = (!caller);
 445
 446         if((assignment == VC_ASGNMNT_BOTH)
 447                 || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 448                 || (from_server && assignment == VC_ASGNMNT_SERVERONLY)))
 449         {
 450                 return TRUE;
 451         }
 452
 453         return FALSE;
 454 }
 455
 456 string VoteCommand_extractcommand(string input, float startpos, float argc)
 457 {
 458         string output;
 459
 460         if((argc - 1) < startpos)
 461                 output = "";
 462         else
 463                 output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 464
 465         return output;
 466 }
 467
 468 float VoteCommand_checknasty(string vote_command)
 469 {
 470         if((strstrofs(vote_command, ";", 0) >= 0)
 471                 || (strstrofs(vote_command, "\n", 0) >= 0)
 472                 || (strstrofs(vote_command, "\r", 0) >= 0)
 473                 || (strstrofs(vote_command, "$", 0) >= 0))
 474                 return FALSE;
 475
 476         return TRUE;
 477 }
 478
 479 float VoteCommand_checkinlist(string vote_command, string list)
 480 {
 481         string l = strcat(" ", list, " ");
 482
 483         if(strstrofs(l, strcat(" ", vote_command, " "), 0) >= 0)
 484                 return TRUE;
 485
 486         return FALSE;
 487 }
 488
 489 string ValidateMap(string validated_map, entity caller)
 490 {
 491         validated_map = MapInfo_FixName(validated_map);
 492
 493         if not(validated_map)
 494         {
 495                 print_to(caller, "This map is not available on this server.");
 496                 return string_null;
 497         }
 498
 499         if(!autocvar_sv_vote_override_mostrecent && caller)
 500         {
 501                 if(Map_IsRecent(validated_map))
 502                 {
 503                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 504                         return string_null;
 505                 }
 506         }
 507
 508         if(!MapInfo_CheckMap(validated_map))
 509         {
 510                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 511                 return string_null;
 512         }
 513
 514         return validated_map;
 515 }
 516
 517 float VoteCommand_checkargs(float startpos, float argc)
 518 {
 519         float p, q, check, minargs;
 520         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 521         string cmdrestriction = cvar_string(cvarname); // note: this warns on undefined cvar. We want that.
 522         string charlist, arg;
 523         float checkmate;
 524
 525         if(cmdrestriction == "")
 526                 return TRUE;
 527
 528         ++startpos; // skip command name
 529
 530         // check minimum arg count
 531
 532         // 0 args: argc == startpos
 533         // 1 args: argc == startpos + 1
 534         // ...
 535
 536         minargs = stof(cmdrestriction);
 537         if(argc - startpos < minargs)
 538                 return FALSE;
 539
 540         p = strstrofs(cmdrestriction, ";", 0); // find first semicolon
 541
 542         for(;;)
 543         {
 544                 // we know that at any time, startpos <= argc - minargs
 545                 // so this means: argc-minargs >= startpos >= argc, thus
 546                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 547                 // have been seen already
 548
 549                 if(startpos >= argc) // all args checked? GOOD
 550                         break;
 551
 552                 if(p < 0) // no more args? FAIL
 553                 {
 554                         // exception: exactly minargs left, this one included
 555                         if(argc - startpos == minargs)
 556                                 break;
 557
 558                         // otherwise fail
 559                         return FALSE;
 560                 }
 561
 562                 // cut to next semicolon
 563                 q = strstrofs(cmdrestriction, ";", p+1); // find next semicolon
 564                 if(q < 0)
 565                         charlist = substring(cmdrestriction, p+1, -1);
 566                 else
 567                         charlist = substring(cmdrestriction, p+1, q - (p+1));
 568
 569                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 570                 // charlist = strreplace("^^", ";", charlist);
 571
 572                 if(charlist != "")
 573                 {
 574                         // verify the arg only contains allowed chars
 575                         arg = argv(startpos);
 576                         checkmate = strlen(arg);
 577                         for(check = 0; check < checkmate; ++check)
 578                                 if(strstrofs(charlist, substring(arg, check, 1), 0) < 0)
 579                                         return FALSE; // not allowed character
 580                         // all characters are allowed. FINE.
 581                 }
 582
 583                 ++startpos;
 584                 --minargs;
 585                 p = q;
 586         }
 587
 588         return TRUE;
 589 }
 590
 591 float VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, float argc)
 592 {
 593         string first_command;
 594
 595         first_command = argv(startpos);
 596
 597         if not(VoteCommand_checkinlist(first_command, vote_list))
 598                 return FALSE;
 599
 600         if not(VoteCommand_checkargs(startpos, argc))
 601                 return FALSE;
 602
 603         switch(first_command) // now go through and parse the proper commands to adjust as needed.
 604         {
 605                 case "kick":
 606                 case "kickban": // catch all kick/kickban commands
 607                 {
 608                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 609                         float accepted = VerifyClientEntity(victim, TRUE, FALSE);
 610
 611                         if(accepted > 0)
 612                         {
 613                                 string reason = ((argc > next_token) ? substring(vote_command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)) : "No reason provided");
 614                                 string command_arguments;
 615
 616                                 if(first_command == "kickban")
 617                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 618                                 else
 619                                         command_arguments = reason;
 620
 621                                 vote_parsed_command = strcat(first_command, " # ", ftos(num_for_edict(victim)), " ", command_arguments);
 622                                 vote_parsed_display = strcat("^1", vote_command, " (^7", victim.netname, "^1): ", reason);
 623                         }
 624                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return FALSE; }
 625
 626                         break;
 627                 }
 628
 629                 case "map":
 630                 case "chmap":
 631                 case "gotomap": // re-direct all map selection commands to gotomap
 632                 {
 633                         vote_command = ValidateMap(argv(startpos + 1), caller);
 634                         if not(vote_command) { return FALSE; }
 635                         vote_parsed_command = strcat("gotomap ", vote_command);
 636                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 637
 638                         break;
 639                 }
 640
 641                 default:
 642                 {
 643                         vote_parsed_command = vote_command;
 644                         vote_parsed_display = strzone(strcat("^1", vote_command));
 645
 646                         break;
 647                 }
 648         }
 649
 650         return TRUE;
 651 }
 652
 653
 654 // =======================
 655 //  Command Sub-Functions
 656 // =======================
 657
 658 void VoteCommand_abstain(float request, entity caller) // CLIENT ONLY
 659 {
 660         switch(request)
 661         {
 662                 case CMD_REQUEST_COMMAND:
 663                 {
 664                         if not(vote_called) { print_to(caller, "^1No vote called."); }
 665                         else if not(caller.vote_selection == VOTE_SELECT_NULL || autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 666
 667                         else // everything went okay, continue changing vote
 668                         {
 669                                 print_to(caller, "^1You abstained from your vote.");
 670                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 671                                 msg_entity = caller;
 672                                 if(!autocvar_sv_vote_singlecount) { VoteCount(FALSE); }
 673                         }
 674
 675                         return;
 676                 }
 677
 678                 default:
 679                 case CMD_REQUEST_USAGE:
 680                 {
 681                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 682                         print_to(caller, "  No arguments required.");
 683                         return;
 684                 }
 685         }
 686 }
 687
 688 void VoteCommand_call(float request, entity caller, float argc, string vote_command) // BOTH
 689 {
 690         switch(request)
 691         {
 692                 case CMD_REQUEST_COMMAND:
 693                 {
 694                         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 695                                 || ((autocvar_sv_vote_nospectators == 1) && inWarmupStage)
 696                                 || (autocvar_sv_vote_nospectators == 0));
 697
 698                         float tmp_playercount = 0;
 699                         entity tmp_player;
 700
 701                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 702
 703                         if not(autocvar_sv_vote_call || !caller) { print_to(caller, "^1Vote calling is not allowed."); }
 704                         else if(!autocvar_sv_vote_gamestart && time < game_starttime) { print_to(caller, "^1Vote calling is not allowed before the match has started."); }
 705                         else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
 706                         else if(!spectators_allowed && (caller && (caller.classname != "player"))) { print_to(caller, "^1Only players can call a vote."); }
 707                         else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
 708                         else if(caller && (time < caller.vote_waittime)) { print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote.")); }
 709                         else if not(VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
 710                         else if not(VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
 711
 712                         else // everything went okay, continue with calling the vote
 713                         {
 714                                 vote_caller = caller; // remember who called the vote
 715                                 vote_called = VOTE_NORMAL;
 716                                 vote_called_command = strzone(vote_parsed_command);
 717                                 vote_called_display = strzone(vote_parsed_display);
 718                                 vote_endtime = time + autocvar_sv_vote_timeout;
 719
 720                                 if(caller)
 721                                 {
 722                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 723                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 724                                         msg_entity = caller;
 725                                 }
 726
 727                                 FOR_EACH_REALCLIENT(tmp_player) { ++tmp_playercount; }
 728                                 if(tmp_playercount > 1) { Announce("votecall"); } // don't announce a "vote now" sound if player is alone
 729
 730                                 bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2 calls a vote for ", vote_called_display, "\n");
 731                                 if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
 732                                 Nagger_VoteChanged();
 733                                 VoteCount(TRUE); // needed if you are the only one
 734                         }
 735
 736                         return;
 737                 }
 738
 739                 default:
 740                 case CMD_REQUEST_USAGE:
 741                 {
 742                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
 743                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
 744                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 745                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 746                         return;
 747                 }
 748         }
 749 }
 750
 751 void VoteCommand_master(float request, entity caller, float argc, string vote_command) // CLIENT ONLY
 752 {
 753         switch(request)
 754         {
 755                 case CMD_REQUEST_COMMAND:
 756                 {
 757                         if(autocvar_sv_vote_master)
 758                         {
 759                                 switch(strtolower(argv(2)))
 760                                 {
 761                                         case "do":
 762                                         {
 763                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 764
 765                                                 if not(caller.vote_master) { print_to(caller, "^1You do not have vote master privelages."); }
 766                                                 else if not(VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
 767                                                 else if not(VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
 768
 769                                                 else // everything went okay, proceed with command
 770                                                 {
 771                                                         localcmd(strcat(vote_parsed_command, "\n"));
 772                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 773                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 774                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display)); }
 775                                                 }
 776
 777                                                 return;
 778                                         }
 779
 780                                         case "login":
 781                                         {
 782                                                 if not(autocvar_sv_vote_master_password != "") { print_to(caller, "^1Login to vote master is not allowed."); }
 783                                                 else if(caller.vote_master) { print_to(caller, "^1You are already logged in as vote master."); }
 784                                                 else if not(autocvar_sv_vote_master_password == argv(3)) { print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller))); }
 785
 786                                                 else // everything went okay, proceed with giving this player master privilages
 787                                                 {
 788                                                         caller.vote_master = TRUE;
 789                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 790                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 791                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid))); }
 792                                                 }
 793
 794                                                 return;
 795                                         }
 796
 797                                         default: // calling a vote for master
 798                                         {
 799                                                 float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 800                                                         || ((autocvar_sv_vote_nospectators == 1) && inWarmupStage)
 801                                                         || (autocvar_sv_vote_nospectators == 0));
 802
 803                                                 if not(autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
 804                                                 else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
 805                                                 else if(!spectators_allowed && (caller && (caller.classname != "player"))) { print_to(caller, "^1Only players can call a vote."); }
 806                                                 else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
 807
 808                                                 else // everything went okay, continue with creating vote
 809                                                 {
 810                                                         vote_caller = caller;
 811                                                         vote_called = VOTE_MASTER;
 812                                                         vote_called_command = strzone("XXX");
 813                                                         vote_called_display = strzone("^3master");
 814                                                         vote_endtime = time + autocvar_sv_vote_timeout;
 815
 816                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 817                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 818
 819                                                         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2 calls a vote to become ^3master^2.\n");
 820                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
 821                                                         Nagger_VoteChanged();
 822                                                         VoteCount(TRUE); // needed if you are the only one
 823                                                 }
 824
 825                                                 return;
 826                                         }
 827                                 }
 828                         }
 829                         else { print_to(caller, "^1Master control of voting is not allowed."); }
 830
 831                         return;
 832                 }
 833
 834                 default:
 835                 case CMD_REQUEST_USAGE:
 836                 {
 837                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
 838                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
 839                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
 840                         return;
 841                 }
 842         }
 843 }
 844
 845 void VoteCommand_no(float request, entity caller) // CLIENT ONLY
 846 {
 847         switch(request)
 848         {
 849                 case CMD_REQUEST_COMMAND:
 850                 {
 851                         if not(vote_called) { print_to(caller, "^1No vote called."); }
 852                         else if not(caller.vote_selection == VOTE_SELECT_NULL || autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 853                         else if(((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote) { VoteStop(caller); }
 854
 855                         else // everything went okay, continue changing vote
 856                         {
 857                                 print_to(caller, "^1You rejected the vote.");
 858                                 caller.vote_selection = VOTE_SELECT_REJECT;
 859                                 msg_entity = caller;
 860                                 if(!autocvar_sv_vote_singlecount) { VoteCount(FALSE); }
 861                         }
 862
 863                         return;
 864                 }
 865
 866                 default:
 867                 case CMD_REQUEST_USAGE:
 868                 {
 869                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
 870                         print_to(caller, "  No arguments required.");
 871                         return;
 872                 }
 873         }
 874 }
 875
 876 void VoteCommand_status(float request, entity caller) // BOTH
 877 {
 878         switch(request)
 879         {
 880                 case CMD_REQUEST_COMMAND:
 881                 {
 882                         if(vote_called)
 883                                 print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", GetCallerName(vote_caller), "^7."));
 884                         else
 885                                 print_to(caller, "^1No vote called.");
 886
 887                         return;
 888                 }
 889
 890                 default:
 891                 case CMD_REQUEST_USAGE:
 892                 {
 893                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
 894                         print_to(caller, "  No arguments required.");
 895                         return;
 896                 }
 897         }
 898 }
 899
 900 void VoteCommand_stop(float request, entity caller) // BOTH
 901 {
 902         switch(request)
 903         {
 904                 case CMD_REQUEST_COMMAND:
 905                 {
 906                         if not(vote_called) { print_to(caller, "^1No vote called."); }
 907                         else if((caller == vote_caller) || !caller || caller.vote_master) { VoteStop(caller); }
 908                         else { print_to(caller, "^1You are not allowed to stop that vote."); }
 909
 910                         return;
 911                 }
 912
 913                 default:
 914                 case CMD_REQUEST_USAGE:
 915                 {
 916                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
 917                         print_to(caller, "  No arguments required.");
 918                         return;
 919                 }
 920         }
 921 }
 922
 923 void VoteCommand_yes(float request, entity caller) // CLIENT ONLY
 924 {
 925         switch(request)
 926         {
 927                 case CMD_REQUEST_COMMAND:
 928                 {
 929                         if not(vote_called) { print_to(caller, "^1No vote called."); }
 930                         else if not(caller.vote_selection == VOTE_SELECT_NULL || autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 931
 932                         else // everything went okay, continue changing vote
 933                         {
 934                                 print_to(caller, "^1You accepted the vote.");
 935                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
 936                                 msg_entity = caller;
 937                                 if(!autocvar_sv_vote_singlecount) { VoteCount(FALSE); }
 938                         }
 939
 940                         return;
 941                 }
 942
 943                 default:
 944                 case CMD_REQUEST_USAGE:
 945                 {
 946                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
 947                         print_to(caller, "  No arguments required.");
 948                         return;
 949                 }
 950         }
 951 }
 952
 953 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 954 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 955 void VoteCommand_(float request)
 956 {
 957         switch(request)
 958         {
 959                 case CMD_REQUEST_COMMAND:
 960                 {
 961
 962                         return;
 963                 }
 964
 965                 default:
 966                 case CMD_REQUEST_USAGE:
 967                 {
 968                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
 969                         print_to(caller, "  No arguments required.");
 970                         return;
 971                 }
 972         }
 973 }
 974 */
 975
 976
 977 // ================================
 978 //  Macro system for vote commands
 979 // ================================
 980
 981 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 982 #define VOTE_COMMANDS(request,caller,arguments,command) \
 983         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
 984         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
 985         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
 986         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
 987         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
 988         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
 989         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
 990         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
 991         /* nothing */
 992
 993 void VoteCommand_macro_help(entity caller, float argc)
 994 {
 995         string command_origin = GetCommandPrefix(caller);
 996
 997         if(argc == 2) // help display listing all commands
 998         {
 999                 print_to(caller, "\nVoting commands:\n");
1000                 #define VOTE_COMMAND(name,function,description,assignment) \
1001                         { if(Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1002
1003                 VOTE_COMMANDS(0, caller, 0, "")
1004                 #undef VOTE_COMMAND
1005
1006                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1007                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1008                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1009         }
1010         else // usage for individual command
1011         {
1012                 #define VOTE_COMMAND(name,function,description,assignment) \
1013                         { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(2))) { function; return; } } }
1014
1015                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "")
1016                 #undef VOTE_COMMAND
1017         }
1018
1019         return;
1020 }
1021
1022 float VoteCommand_macro_command(entity caller, float argc, string vote_command)
1023 {
1024         #define VOTE_COMMAND(name,function,description,assignment) \
1025                 { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(1))) { function; return TRUE; } } }
1026
1027         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command)
1028         #undef VOTE_COMMAND
1029
1030         return FALSE;
1031 }
1032
1033
1034 // ======================================
1035 //  Main function handling vote commands
1036 // ======================================
1037
1038 void VoteCommand(float request, entity caller, float argc, string vote_command)
1039 {
1040         // Guide for working with argc arguments by example:
1041         // argc:   1    - 2      - 3     - 4
1042         // argv:   0    - 1      - 2     - 3
1043         // cmd     vote - master - login - password
1044
1045         switch(request)
1046         {
1047                 case CMD_REQUEST_COMMAND:
1048                 {
1049                         if(VoteCommand_macro_command(caller, argc, vote_command))
1050                                 return;
1051                 }
1052
1053                 default:
1054                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1055                 case CMD_REQUEST_USAGE:
1056                 {
1057                         VoteCommand_macro_help(caller, argc);
1058                         return;
1059                 }
1060         }
1061 }