qcsrc/common/weapons/weapon/shotgun.qc

   1 #include "shotgun.qh"
   2
   3 #ifdef SVQC
   4
   5 // enable to debug melee range
   6 //#define SHOTGUN_MELEEDEBUG
   7
   8 METHOD(Shotgun, m_spawnfunc_hookreplace, Weapon(Shotgun this, entity e))
   9 {
  10         if (autocvar_sv_q3acompat_machineshotgunswap && !Item_IsLoot(e))
  11         {
  12                 return WEP_MACHINEGUN;
  13         }
  14         return this;
  15 }
  16
  17 void W_Shotgun_Attack(Weapon thiswep, entity actor, .entity weaponentity, float isprimary, float ammocount, float damage, float bullets, float spread, float solidpenetration, float force, entity bullet_trail_effect)
  18 {
  19         W_DecreaseAmmo(thiswep, actor, ammocount, weaponentity);
  20
  21         W_SetupShot(actor, weaponentity, true, 5, SND_SHOTGUN_FIRE, ((isprimary) ? CH_WEAPON_A : CH_WEAPON_SINGLE), damage * bullets, thiswep.m_id);
  22
  23         // TRICK: do the antilag outside the regular fireBullet function, so it isn't performed unnecessarily on every single bullet!
  24         float lag = antilag_getlag(actor);
  25         if(lag && bullets > 0)
  26                 antilag_takeback_all(actor, lag);
  27
  28         for(int sc = 0;sc < bullets;sc = sc + 1)
  29                 fireBullet_antilag(actor, weaponentity, w_shotorg, w_shotdir, spread, solidpenetration, damage, 0, force, thiswep.m_id, bullet_trail_effect, false);
  30
  31         if(lag && bullets > 0)
  32                 antilag_restore_all(actor);
  33
  34         W_MuzzleFlash(thiswep, actor, weaponentity, w_shotorg, w_shotdir);
  35
  36         // casing code
  37         if(autocvar_g_casings >= 1)
  38         {
  39                 makevectors(actor.v_angle); // for some reason, this is lost
  40                 //for(int sc = 0;sc < WEP_CVAR_PRI(shotgun, ammo);sc = sc + 1)
  41                         SpawnCasing(((random() * 50 + 50) * v_right) - (v_forward * (random() * 25 + 25)) - ((random() * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, actor, weaponentity);
  42         }
  43 }
  44
  45 .float swing_prev;
  46 .entity swing_alreadyhit;
  47 void W_Shotgun_Melee_Think(entity this)
  48 {
  49         // declarations
  50         float i, f, swing, swing_factor, swing_damage, meleetime, is_player;
  51         entity target_victim;
  52         vector targpos;
  53
  54         if(!this.cnt) // set start time of melee
  55         {
  56                 this.cnt = time;
  57                 W_PlayStrengthSound(this.realowner);
  58         }
  59
  60         makevectors(this.realowner.v_angle); // update values for v_* vectors
  61
  62         // calculate swing percentage based on time
  63         meleetime = WEP_CVAR_SEC(shotgun, melee_time) * W_WeaponRateFactor(this.realowner);
  64         swing = bound(0, (this.cnt + meleetime - time) / meleetime, 10);
  65         f = ((1 - swing) * WEP_CVAR_SEC(shotgun, melee_traces));
  66
  67         // check to see if we can still continue, otherwise give up now
  68         if(IS_DEAD(this.realowner) && WEP_CVAR_SEC(shotgun, melee_no_doubleslap))
  69         {
  70                 delete(this);
  71                 return;
  72         }
  73
  74         // if okay, perform the traces needed for this frame
  75         for(i=this.swing_prev; i < f; ++i)
  76         {
  77                 swing_factor = ((1 - (i / WEP_CVAR_SEC(shotgun, melee_traces))) * 2 - 1);
  78
  79                 targpos = (this.realowner.origin + this.realowner.view_ofs
  80                         + (v_forward * WEP_CVAR_SEC(shotgun, melee_range))
  81                         + (v_up * swing_factor * WEP_CVAR_SEC(shotgun, melee_swing_up))
  82                         + (v_right * swing_factor * WEP_CVAR_SEC(shotgun, melee_swing_side)));
  83
  84                 WarpZone_traceline_antilag(this.realowner, this.realowner.origin + this.realowner.view_ofs, targpos, false, this.realowner, ((IS_CLIENT(this.realowner)) ? ANTILAG_LATENCY(this.realowner) : 0));
  85
  86                 // draw lightning beams for debugging
  87         #ifdef SHOTGUN_MELEEDEBUG
  88                 te_lightning2(NULL, targpos, this.realowner.origin + this.realowner.view_ofs + v_forward * 5 - v_up * 5);
  89                 te_customflash(targpos, 40,  2, '1 1 1');
  90         #endif
  91
  92                 is_player = (IS_PLAYER(trace_ent) || trace_ent.classname == "body" || IS_MONSTER(trace_ent));
  93
  94                 if((trace_fraction < 1) // if trace is good, apply the damage and remove this
  95                         && (trace_ent.takedamage != DAMAGE_NO)
  96                         && (trace_ent != this.swing_alreadyhit)
  97                         && (is_player || WEP_CVAR_SEC(shotgun, melee_nonplayerdamage)))
  98                 {
  99                         target_victim = trace_ent; // so it persists through other calls
 100
 101                         if(is_player) // this allows us to be able to nerf the non-player damage done in e.g. assault or onslaught.
 102                                 swing_damage = (WEP_CVAR_SEC(shotgun, damage) * min(1, swing_factor + 1));
 103                         else
 104                                 swing_damage = (WEP_CVAR_SEC(shotgun, melee_nonplayerdamage) * min(1, swing_factor + 1));
 105
 106                         //print(strcat(this.realowner.netname, " hitting ", target_victim.netname, " with ", strcat(ftos(swing_damage), " damage (factor: ", ftos(swing_factor), ") at "), ftos(time), " seconds.\n"));
 107
 108                         Damage(target_victim, this.realowner, this.realowner,
 109                                 swing_damage, WEP_SHOTGUN.m_id | HITTYPE_SECONDARY, this.weaponentity_fld,
 110                                 this.realowner.origin + this.realowner.view_ofs,
 111                                 v_forward * WEP_CVAR_SEC(shotgun, force));
 112
 113                         if(accuracy_isgooddamage(this.realowner, target_victim)) { accuracy_add(this.realowner, WEP_SHOTGUN, 0, swing_damage); }
 114
 115                         // draw large red flash for debugging
 116                 #ifdef SHOTGUN_MELEEDEBUG
 117                         te_customflash(targpos, 200, 2, '15 0 0');
 118                 #endif
 119
 120                         if(WEP_CVAR_SEC(shotgun, melee_multihit)) // allow multiple hits with one swing, but not against the same player twice.
 121                         {
 122                                 this.swing_alreadyhit = target_victim;
 123                                 continue; // move along to next trace
 124                         }
 125                         else
 126                         {
 127                                 delete(this);
 128                                 return;
 129                         }
 130                 }
 131         }
 132
 133         if(time >= this.cnt + meleetime)
 134         {
 135                 // melee is finished
 136                 delete(this);
 137                 return;
 138         }
 139         else
 140         {
 141                 // set up next frame
 142                 this.swing_prev = i;
 143                 this.nextthink = time;
 144         }
 145 }
 146
 147 void W_Shotgun_Attack2(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 148 {
 149         sound(actor, CH_WEAPON_A, SND_SHOTGUN_MELEE, VOL_BASE, ATTEN_NORM);
 150         weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(shotgun, animtime), w_ready);
 151
 152         entity meleetemp = new_pure(meleetemp);
 153         meleetemp.realowner = actor;
 154         setthink(meleetemp, W_Shotgun_Melee_Think);
 155         meleetemp.nextthink = time + WEP_CVAR_SEC(shotgun, melee_delay) * W_WeaponRateFactor(actor);
 156         meleetemp.weaponentity_fld = weaponentity;
 157         W_SetupShot_Range(actor, weaponentity, true, 0, SND_Null, 0, WEP_CVAR_SEC(shotgun, damage), WEP_CVAR_SEC(shotgun, melee_range), WEP_SHOTGUN.m_id | HITTYPE_SECONDARY);
 158 }
 159
 160 // alternate secondary weapon frames
 161 void W_Shotgun_Attack3_Frame2(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 162 {
 163         if (!thiswep.wr_checkammo2(thiswep, actor, weaponentity))
 164         if (!(actor.items & IT_UNLIMITED_AMMO))
 165         {
 166                 W_SwitchWeapon_Force(actor, w_getbestweapon(actor, weaponentity), weaponentity);
 167                 w_ready(thiswep, actor, weaponentity, fire);
 168                 return;
 169         }
 170
 171         sound(actor, CH_WEAPON_SINGLE, SND_Null, VOL_BASE, ATTN_NORM); // kill previous sound
 172         W_Shotgun_Attack(thiswep, actor, weaponentity, true,
 173                 WEP_CVAR_PRI(shotgun, ammo),
 174                 WEP_CVAR_PRI(shotgun, damage),
 175                 WEP_CVAR_PRI(shotgun, bullets),
 176                 WEP_CVAR_PRI(shotgun, spread),
 177                 WEP_CVAR_PRI(shotgun, solidpenetration),
 178                 WEP_CVAR_PRI(shotgun, force),
 179                 EFFECT_BULLET_WEAK); // actually is secondary, but we trick the last shot into playing full reload sound
 180         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_SEC(shotgun, alt_animtime), w_ready);
 181 }
 182 void W_Shotgun_Attack3_Frame1(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 183 {
 184         if (!thiswep.wr_checkammo2(thiswep, actor, weaponentity))
 185         if (!(actor.items & IT_UNLIMITED_AMMO))
 186         {
 187                 W_SwitchWeapon_Force(actor, w_getbestweapon(actor, weaponentity), weaponentity);
 188                 w_ready(thiswep, actor, weaponentity, fire);
 189                 return;
 190         }
 191
 192         W_Shotgun_Attack(thiswep, actor, weaponentity, false,
 193                 WEP_CVAR_PRI(shotgun, ammo),
 194                 WEP_CVAR_PRI(shotgun, damage),
 195                 WEP_CVAR_PRI(shotgun, bullets),
 196                 WEP_CVAR_PRI(shotgun, spread),
 197                 WEP_CVAR_PRI(shotgun, solidpenetration),
 198                 WEP_CVAR_PRI(shotgun, force),
 199                 EFFECT_BULLET_WEAK);
 200         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_SEC(shotgun, alt_animtime), W_Shotgun_Attack3_Frame2);
 201 }
 202
 203 .float shotgun_primarytime;
 204
 205 METHOD(Shotgun, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
 206 {
 207     if(vdist(actor.origin - actor.enemy.origin, <=, WEP_CVAR_SEC(shotgun, melee_range)))
 208         PHYS_INPUT_BUTTON_ATCK2(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false);
 209     else
 210         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false);
 211 }
 212
 213 METHOD(Shotgun, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 214 {
 215     if(WEP_CVAR(shotgun, reload_ammo) && actor.(weaponentity).clip_load < WEP_CVAR_PRI(shotgun, ammo)) // forced reload
 216     {
 217         // don't force reload an empty shotgun if its melee attack is active
 218         if(WEP_CVAR(shotgun, secondary) < 2) {
 219             thiswep.wr_reload(thiswep, actor, weaponentity);
 220         }
 221     }
 222     else
 223     {
 224         if(fire & 1)
 225         {
 226             if(time >= actor.(weaponentity).shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 227             {
 228                 if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(shotgun, animtime)))
 229                 {
 230                     W_Shotgun_Attack(thiswep, actor, weaponentity, true,
 231                                                 WEP_CVAR_PRI(shotgun, ammo),
 232                                                 WEP_CVAR_PRI(shotgun, damage),
 233                                                 WEP_CVAR_PRI(shotgun, bullets),
 234                                                 WEP_CVAR_PRI(shotgun, spread),
 235                                                 WEP_CVAR_PRI(shotgun, solidpenetration),
 236                                                 WEP_CVAR_PRI(shotgun, force),
 237                                                 EFFECT_BULLET_WEAK);
 238                     actor.(weaponentity).shotgun_primarytime = time + WEP_CVAR_PRI(shotgun, refire) * W_WeaponRateFactor(actor);
 239                     weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(shotgun, animtime), w_ready);
 240                 }
 241             }
 242         }
 243         else if((fire & 2) && WEP_CVAR(shotgun, secondary) == 2)
 244         {
 245             if(time >= actor.(weaponentity).shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 246             {
 247                 if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_SEC(shotgun, alt_animtime)))
 248                 {
 249                     W_Shotgun_Attack(thiswep, actor, weaponentity, false,
 250                                                 WEP_CVAR_PRI(shotgun, ammo),
 251                                                 WEP_CVAR_PRI(shotgun, damage),
 252                                                 WEP_CVAR_PRI(shotgun, bullets),
 253                                                 WEP_CVAR_PRI(shotgun, spread),
 254                                                 WEP_CVAR_PRI(shotgun, solidpenetration),
 255                                                 WEP_CVAR_PRI(shotgun, force),
 256                                                 EFFECT_BULLET_WEAK);
 257                     actor.(weaponentity).shotgun_primarytime = time + WEP_CVAR_SEC(shotgun, alt_refire) * W_WeaponRateFactor(actor);
 258                     weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_SEC(shotgun, alt_animtime), W_Shotgun_Attack3_Frame1);
 259                 }
 260             }
 261         }
 262     }
 263     if(actor.(weaponentity).clip_load >= 0) // we are not currently reloading
 264     if(WEP_CVAR(shotgun, secondary) == 1)
 265     if(((fire & 1) && GetResource(actor, thiswep.ammo_type) <= 0 && !(actor.items & IT_UNLIMITED_AMMO)) || (fire & 2))
 266     if(weapon_prepareattack(thiswep, actor, weaponentity, true, WEP_CVAR_SEC(shotgun, refire)))
 267     {
 268         // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 269         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, 0, W_Shotgun_Attack2);
 270     }
 271 }
 272 METHOD(Shotgun, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 273 {
 274     float ammo_amount = GetResource(actor, thiswep.ammo_type) >= WEP_CVAR_PRI(shotgun, ammo);
 275     ammo_amount += actor.(weaponentity).(weapon_load[thiswep.m_id]) >= WEP_CVAR_PRI(shotgun, ammo);
 276     return ammo_amount;
 277 }
 278 METHOD(Shotgun, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 279 {
 280     if(IS_BOT_CLIENT(actor))
 281     if(vdist(actor.origin - actor.enemy.origin, >, WEP_CVAR_SEC(shotgun, melee_range)))
 282         return false; // bots cannot use secondary out of range (fixes constant melee when out of ammo)
 283     switch(WEP_CVAR(shotgun, secondary))
 284     {
 285         case 1: return true; // melee does not use ammo
 286         case 2: // secondary triple shot
 287         {
 288             float ammo_amount = GetResource(actor, thiswep.ammo_type) >= WEP_CVAR_PRI(shotgun, ammo);
 289             ammo_amount += actor.(weaponentity).(weapon_load[thiswep.m_id]) >= WEP_CVAR_PRI(shotgun, ammo);
 290             return ammo_amount;
 291         }
 292         default: return false; // secondary unavailable
 293     }
 294 }
 295 METHOD(Shotgun, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 296 {
 297     W_Reload(actor, weaponentity, WEP_CVAR_PRI(shotgun, ammo), SND_RELOAD); // WEAPONTODO
 298 }
 299 METHOD(Shotgun, wr_suicidemessage, Notification(entity thiswep))
 300 {
 301     return WEAPON_THINKING_WITH_PORTALS;
 302 }
 303 METHOD(Shotgun, wr_killmessage, Notification(entity thiswep))
 304 {
 305     if(w_deathtype & HITTYPE_SECONDARY)
 306         return WEAPON_SHOTGUN_MURDER_SLAP;
 307     else
 308         return WEAPON_SHOTGUN_MURDER;
 309 }
 310
 311 #endif
 312 #ifdef CSQC
 313 .float prevric;
 314
 315 METHOD(Shotgun, wr_impacteffect, void(entity thiswep, entity actor))
 316 {
 317     vector org2 = w_org + w_backoff * 2;
 318     pointparticles(EFFECT_SHOTGUN_IMPACT, org2, w_backoff * 1000, 1);
 319     if(!w_issilent && time - actor.prevric > 0.25)
 320     {
 321         if(w_random < 0.05)
 322             sound(actor, CH_SHOTS, SND_RIC_RANDOM(), VOL_BASE, ATTEN_NORM);
 323         actor.prevric = time;
 324     }
 325 }
 326
 327 #endif