qcsrc/common/weapons/all.qc

   1 #include "all.qh"
   2 #ifndef WEAPONS_ALL_C
   3 #define WEAPONS_ALL_C
   4
   5 #if defined(CSQC)
   6         #include "../constants.qh"
   7         #include "../stats.qh"
   8         #include <lib/warpzone/anglestransform.qh>
   9         #include <lib/warpzone/common.qh>
  10         #include <lib/warpzone/client.qh>
  11         #include "../util.qh"
  12         #include <client/autocvars.qh>
  13         #include "../deathtypes/all.qh"
  14         #include <lib/csqcmodel/interpolate.qh>
  15         #include "../physics/movetypes/movetypes.qh"
  16         #include <client/main.qh>
  17         #include <lib/csqcmodel/cl_model.qh>
  18 #elif defined(MENUQC)
  19 #elif defined(SVQC)
  20         #include <common/items/_mod.qh>
  21         #include <lib/warpzone/anglestransform.qh>
  22         #include <lib/warpzone/common.qh>
  23         #include <lib/warpzone/util_server.qh>
  24         #include <lib/warpzone/server.qh>
  25         #include "../constants.qh"
  26         #include "../stats.qh"
  27         #include "../teams.qh"
  28         #include <common/util.qh>
  29         #include "../monsters/_mod.qh"
  30         #include "config.qh"
  31         #include <server/weapons/common.qh>
  32         #include <server/weapons/csqcprojectile.qh>
  33         #include <server/weapons/tracing.qh>
  34         #include <server/items/spawning.qh>
  35         #include <server/autocvars.qh>
  36         #include "../notifications/all.qh"
  37         #include "../deathtypes/all.qh"
  38         #include <server/mutators/_mod.qh>
  39         #include "../mapinfo.qh"
  40         #include <server/command/_mod.qh>
  41         #include <lib/csqcmodel/sv_model.qh>
  42         #include <server/portals.qh>
  43 #include <server/hook.qh>
  44 #endif
  45 #ifdef GAMEQC
  46         #include "calculations.qc"
  47 #endif
  48 #ifdef SVQC
  49         #include "config.qc"
  50 #endif
  51
  52 #include "weapon/_mod.inc"
  53
  54
  55 // WEAPON PLUGIN SYSTEM
  56
  57 WepSet _WepSet_FromWeapon(int a)
  58 {
  59         a -= WEP_FIRST;
  60         if (REGISTRY_MAX(Weapons) > 24)
  61                 if (a >= 24)
  62                 {
  63                         a -= 24;
  64                         if (REGISTRY_MAX(Weapons) > 48)
  65                                 if (a >= 24)
  66                                 {
  67                                         a -= 24;
  68                                         return '0 0 1' * (2 ** a);
  69                                 }
  70                         return '0 1 0' * (2 ** a);
  71                 }
  72         return '1 0 0' * (2 ** a);
  73 }
  74 #ifdef SVQC
  75         void WriteWepSet(float dst, WepSet w)
  76         {
  77                 if (REGISTRY_MAX(Weapons) > 48) WriteInt72_t(dst, w);
  78                 else if (REGISTRY_MAX(Weapons) > 24) WriteInt48_t(dst, w);
  79                 else WriteInt24_t(dst, w.x);
  80         }
  81 #endif
  82 #ifdef CSQC
  83         WepSet WepSet_GetFromStat()
  84         {
  85                 return STAT(WEAPONS);
  86         }
  87         WepSet WepSet_GetFromStat_InMap()
  88         {
  89                 return STAT(WEAPONSINMAP);
  90         }
  91         WepSet ReadWepSet()
  92         {
  93                 if (REGISTRY_MAX(Weapons) > 48) return ReadInt72_t();
  94                 if (REGISTRY_MAX(Weapons) > 24) return ReadInt48_t();
  95                 return ReadInt24_t() * '1 0 0';
  96         }
  97 #endif
  98
  99 string W_FixWeaponOrder(string order, float complete)
 100 {
 101         return fixPriorityList(order, WEP_FIRST, WEP_LAST, WEP_IMPULSE_BEGIN - WEP_FIRST, complete);
 102 }
 103 string W_NameWeaponOrder_MapFunc(string s)
 104 {
 105         int i = stof(s);
 106         if (s == "0" || i)
 107         {
 108                 entity wi = REGISTRY_GET(Weapons, i);
 109                 if (wi != WEP_Null) return wi.netname;
 110         }
 111         return s;
 112 }
 113
 114 string W_UndeprecateName(string s)
 115 {
 116         switch (s)
 117         {
 118                 case "nex": return "vortex";
 119                 case "rocketlauncher": return "devastator";
 120                 case "laser": return "blaster";
 121                 case "minstanex": return "vaporizer";
 122                 case "grenadelauncher": return "mortar";
 123                 case "uzi": return "machinegun";
 124                 case "hmg": return "okhmg";
 125                 case "rpc": return "okrpc";
 126                 default: return s;
 127         }
 128 }
 129 string W_NameWeaponOrder(string order)
 130 {
 131         return mapPriorityList(order, W_NameWeaponOrder_MapFunc);
 132 }
 133 string W_NumberWeaponOrder_MapFunc(string s)
 134 {
 135         if (s == "0" || stof(s)) return s;
 136         s = W_UndeprecateName(s);
 137         FOREACH(Weapons, it != WEP_Null && it.netname == s, return ftos(i));
 138         return s;
 139 }
 140 string W_NumberWeaponOrder(string order)
 141 {
 142         return mapPriorityList(order, W_NumberWeaponOrder_MapFunc);
 143 }
 144
 145 float W_FixWeaponOrder_BuildImpulseList_buf[REGISTRY_MAX(Weapons)];
 146 string W_FixWeaponOrder_BuildImpulseList_order;
 147 void W_FixWeaponOrder_BuildImpulseList_swap(int i, int j, entity pass)
 148 {
 149         float h;
 150         h = W_FixWeaponOrder_BuildImpulseList_buf[i];
 151         W_FixWeaponOrder_BuildImpulseList_buf[i] = W_FixWeaponOrder_BuildImpulseList_buf[j];
 152         W_FixWeaponOrder_BuildImpulseList_buf[j] = h;
 153 }
 154 float W_FixWeaponOrder_BuildImpulseList_cmp(int i, int j, entity pass)
 155 {
 156         int si = W_FixWeaponOrder_BuildImpulseList_buf[i];
 157         Weapon e1 = REGISTRY_GET(Weapons, si);
 158         int sj = W_FixWeaponOrder_BuildImpulseList_buf[j];
 159         Weapon e2 = REGISTRY_GET(Weapons, sj);
 160         int d = (e1.impulse + 9) % 10 - (e2.impulse + 9) % 10;
 161         if (d != 0) return -d;  // high impulse first!
 162         string s = strcat(" ", W_FixWeaponOrder_BuildImpulseList_order, " ");
 163         return strstrofs(s, sprintf(" %d ", si), 0)
 164                 - strstrofs(s, sprintf(" %d ", sj), 0); // low char index first!
 165 }
 166 string W_FixWeaponOrder_BuildImpulseList(string o)
 167 {
 168         int i;
 169         W_FixWeaponOrder_BuildImpulseList_order = o;
 170         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 171                 W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST] = i;
 172         heapsort(WEP_LAST - WEP_FIRST + 1, W_FixWeaponOrder_BuildImpulseList_swap, W_FixWeaponOrder_BuildImpulseList_cmp,
 173                 NULL);
 174         o = "";
 175         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 176                 o = strcat(o, " ", ftos(W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST]));
 177         W_FixWeaponOrder_BuildImpulseList_order = string_null;
 178         return substring(o, 1, -1);
 179 }
 180
 181 string W_FixWeaponOrder_AllowIncomplete(entity this, string order)
 182 {
 183         return W_FixWeaponOrder(order, 0);
 184 }
 185
 186 string W_FixWeaponOrder_ForceComplete(string order)
 187 {
 188         if (order == "") order = W_NumberWeaponOrder(cvar_defstring("cl_weaponpriority"));
 189         return W_FixWeaponOrder(order, 1);
 190 }
 191
 192 WepSet W_RandomWeapons(entity e, WepSet remaining, int n)
 193 {
 194         WepSet result = '0 0 0';
 195         for (int j = 0; j < n; ++j)
 196         {
 197                 RandomSelection_Init();
 198                 FOREACH(Weapons, it != WEP_Null, {
 199                         if (remaining & (it.m_wepset))
 200                                 RandomSelection_AddEnt(it, 1, 1);
 201                 });
 202                 Weapon w = RandomSelection_chosen_ent;
 203                 result |= WepSet_FromWeapon(w);
 204                 remaining &= ~WepSet_FromWeapon(w);
 205         }
 206         return result;
 207 }
 208
 209 string GetAmmoPicture(int ammotype)
 210 {
 211         switch (ammotype)
 212         {
 213                 case RES_SHELLS:  return ITEM_Shells.m_icon;
 214                 case RES_BULLETS: return ITEM_Bullets.m_icon;
 215                 case RES_ROCKETS: return ITEM_Rockets.m_icon;
 216                 case RES_CELLS:   return ITEM_Cells.m_icon;
 217                 case RES_PLASMA:  return ITEM_Plasma.m_icon;
 218                 case RES_FUEL:    return ITEM_JetpackFuel.m_icon;
 219                 default: return "";  // wtf, no ammo type?
 220         }
 221 }
 222
 223 string GetAmmoName(int ammotype)
 224 {
 225         switch (ammotype)
 226         {
 227                 case RES_SHELLS:  return ITEM_Shells.m_name;
 228                 case RES_BULLETS: return ITEM_Bullets.m_name;
 229                 case RES_ROCKETS: return ITEM_Rockets.m_name;
 230                 case RES_CELLS:   return ITEM_Cells.m_name;
 231                 case RES_PLASMA:  return ITEM_Plasma.m_name;
 232                 case RES_FUEL:    return ITEM_JetpackFuel.m_name;
 233                 default:          return "batteries";
 234         }
 235 }
 236
 237 #ifdef CSQC
 238 int GetAmmoTypeFromNum(int i)
 239 {
 240         switch (i)
 241         {
 242                 case 0: return RES_SHELLS;
 243                 case 1: return RES_BULLETS;
 244                 case 2: return RES_ROCKETS;
 245                 case 3: return RES_CELLS;
 246                 case 4: return RES_PLASMA;
 247                 case 5: return RES_FUEL;
 248                 default: return RES_NONE;
 249         }
 250 }
 251
 252 int GetAmmoStat(int ammotype)
 253 {
 254         switch (ammotype)
 255         {
 256                 case RES_SHELLS: return STAT_SHELLS;
 257                 case RES_BULLETS: return STAT_NAILS;
 258                 case RES_ROCKETS: return STAT_ROCKETS;
 259                 case RES_CELLS: return STAT_CELLS;
 260                 case RES_PLASMA: return STAT_PLASMA.m_id;
 261                 case RES_FUEL: return STAT_FUEL.m_id;
 262                 default: return -1;
 263         }
 264 }
 265 #endif
 266
 267 string W_Sound(string w_snd)
 268 {
 269         string output = strcat("weapons/", w_snd);
 270         MUTATOR_CALLHOOK(WeaponSound, w_snd, output);
 271         return M_ARGV(1, string);
 272 }
 273
 274 string W_Model(string w_mdl)
 275 {
 276         string output = strcat("models/weapons/", w_mdl);
 277         MUTATOR_CALLHOOK(WeaponModel, w_mdl, output);
 278         return M_ARGV(1, string);
 279 }
 280
 281 #ifdef GAMEQC
 282 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float algn)
 283 {
 284         switch (algn)
 285         {
 286                 default:
 287                 case 3:
 288                         // right alignment
 289                         break;
 290                 case 4:
 291                         // left
 292                         vecs.y = -vecs.y;
 293                         break;
 294                 case 1:
 295                 case 2:
 296                         // center
 297                         vecs.y = 0;
 298                         vecs.z -= 2;
 299                         break;
 300         }
 301         return vecs;
 302 }
 303
 304 vector shotorg_adjust_values(vector vecs, bool y_is_right, bool visual, int algn)
 305 {
 306         string s;
 307         if (visual)
 308         {
 309                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 310         }
 311         else if (STAT(SHOOTFROMEYE))
 312         {
 313                 vecs.y = vecs.z = 0;
 314         }
 315         else if (STAT(SHOOTFROMCENTER))
 316         {
 317                 vecs.y = 0;
 318                 vecs.z -= 2;
 319         }
 320         else if ((s = G_SHOOTFROMFIXEDORIGIN) != "")
 321         {
 322                 vector v = stov(s);
 323                 if (y_is_right) v.y = -v.y;
 324                 if (v.x != 0) vecs.x = v.x;
 325                 vecs.y = v.y;
 326                 vecs.z = v.z;
 327         }
 328         else  // just do the same as top
 329         {
 330                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 331         }
 332
 333         return vecs;
 334 }
 335
 336 #define shotorg_adjust shotorg_adjust_values
 337
 338 /**
 339  * supported formats:
 340  *
 341  * 1. simple animated model, muzzle flash handling on h_ model:
 342  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 343  *      tags:
 344  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 345  *        shell = casings ejection point (must be on the right hand side of the gun)
 346  *        weapon = attachment for v_tuba.md3
 347  *    v_tuba.md3 - first and third person model
 348  *    g_tuba.md3 - pickup model
 349  *
 350  * 2. simple animated model, muzzle flash handling on v_ model:
 351  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 352  *      tags:
 353  *        weapon = attachment for v_tuba.md3
 354  *    v_tuba.md3 - first and third person model
 355  *      tags:
 356  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 357  *        shell = casings ejection point (must be on the right hand side of the gun)
 358  *    g_tuba.md3 - pickup model
 359  *
 360  * 3. fully animated model, muzzle flash handling on h_ model:
 361  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 362  *      tags:
 363  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 364  *        shell = casings ejection point (must be on the right hand side of the gun)
 365  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 366  *    v_tuba.md3 - third person model
 367  *    g_tuba.md3 - pickup model
 368  *
 369  * 4. fully animated model, muzzle flash handling on v_ model:
 370  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 371  *      tags:
 372  *        shot = muzzle end (shot origin)
 373  *        shell = casings ejection point (must be on the right hand side of the gun)
 374  *    v_tuba.md3 - third person model
 375  *      tags:
 376  *        shot = muzzle end (for muzzle flashes)
 377  *    g_tuba.md3 - pickup model
 378  *
 379  * writes:
 380  *   this.origin, this.angles
 381  *   this.weaponchild
 382  *   this.movedir, this.view_ofs, this.movedir_aligned
 383  *   attachment stuff
 384  *   anim stuff
 385  * to free:
 386  *   call again with ""
 387  *   remove the ent
 388  */
 389 void CL_WeaponEntity_SetModel(entity this, string name, bool _anim)
 390 {
 391         if (name == "")
 392         {
 393                 vector oldmin = this.mins, oldmax = this.maxs;
 394                 setmodel(this, MDL_Null);
 395                 setsize(this, oldmin, oldmax);
 396                 if (this.weaponchild) delete(this.weaponchild);
 397                 this.weaponchild = NULL;
 398                 this.movedir = '0 0 0';
 399                 this.spawnorigin = '0 0 0';
 400                 this.oldorigin = '0 0 0';
 401                 this.anim_fire1  = '0 1 0.01';
 402                 this.anim_fire2  = '0 1 0.01';
 403                 this.anim_idle   = '0 1 0.01';
 404                 this.anim_reload = '0 1 0.01';
 405         }
 406         else
 407         {
 408                 // if there is a child entity, hide it until we're sure we use it
 409                 if (this.weaponchild) this.weaponchild.model = "";
 410                 _setmodel(this, W_Model(strcat("v_", name, ".md3")));
 411                 int v_shot_idx;  // used later
 412                 (v_shot_idx = gettagindex(this, "shot")) || (v_shot_idx = gettagindex(this, "tag_shot"));
 413
 414                 _setmodel(this, W_Model(strcat("h_", name, ".iqm")));
 415                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 416                 this.anim_fire1  = animfixfps(this, '0 1 0.01', '0 0 0');
 417                 this.anim_fire2  = animfixfps(this, '1 1 0.01', '0 0 0');
 418                 this.anim_idle   = animfixfps(this, '2 1 0.01', '0 0 0');
 419                 this.anim_reload = animfixfps(this, '3 1 0.01', '0 0 0');
 420
 421                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 422                 // if we don't, this is a "real" animated model
 423                 string t;
 424                 if ((t = "weapon", gettagindex(this, t)) || (t = "tag_weapon", gettagindex(this, t)))
 425                 {
 426                         if (!this.weaponchild)
 427                         {
 428                                 this.weaponchild = new(weaponchild);
 429 #ifdef CSQC
 430                                 this.weaponchild.drawmask = MASK_NORMAL;
 431                                 this.weaponchild.renderflags |= RF_VIEWMODEL;
 432 #endif
 433                         }
 434                         _setmodel(this.weaponchild, W_Model(strcat("v_", name, ".md3")));
 435                         setsize(this.weaponchild, '0 0 0', '0 0 0');
 436                         setattachment(this.weaponchild, this, t);
 437                 }
 438                 else
 439                 {
 440                         if (this.weaponchild) delete(this.weaponchild);
 441                         this.weaponchild = NULL;
 442                 }
 443
 444                 setsize(this, '0 0 0', '0 0 0');
 445                 setorigin(this, '0 0 0');
 446                 this.angles = '0 0 0';
 447                 this.frame = 0;
 448 #ifdef SVQC
 449                 this.viewmodelforclient = NULL;
 450 #else
 451                 this.renderflags &= ~RF_VIEWMODEL;
 452 #endif
 453                 if (v_shot_idx)  // v_ model attached to invisible h_ model
 454                 {
 455                         this.movedir = gettaginfo(this.weaponchild, v_shot_idx);
 456                 }
 457                 else
 458                 {
 459                         int idx;
 460                         if ((idx = gettagindex(this, "shot")) || (idx = gettagindex(this, "tag_shot")))
 461                         {
 462                                 this.movedir = gettaginfo(this, idx);
 463                         }
 464                         else
 465                         {
 466                                 LOG_WARNF("weapon model %s does not support the 'shot' tag, will display shots TOTALLY wrong",
 467                                         this.model);
 468                                 this.movedir = '0 0 0';
 469                         }
 470                 }
 471                 {
 472                         int idx = 0;
 473                         // v_ model attached to invisible h_ model
 474                         if (this.weaponchild
 475                                 && ((idx = gettagindex(this.weaponchild, "shell")) || (idx = gettagindex(this.weaponchild, "tag_shell"))))
 476                         {
 477                                 this.spawnorigin = gettaginfo(this.weaponchild, idx);
 478                         }
 479                         else if ((idx = gettagindex(this, "shell")) || (idx = gettagindex(this, "tag_shell")))
 480                         {
 481                                 this.spawnorigin = gettaginfo(this, idx);
 482                         }
 483                         else
 484                         {
 485                                 LOG_WARNF("weapon model %s does not support the 'shell' tag, will display casings wrong",
 486                                         this.model);
 487                                 this.spawnorigin = this.movedir;
 488                         }
 489                 }
 490                 if (v_shot_idx)
 491                 {
 492                         this.oldorigin = '0 0 0';  // use regular attachment
 493                 }
 494                 else
 495                 {
 496                         int idx;
 497                         if (this.weaponchild)
 498                                 (idx = gettagindex(this, "weapon")) || (idx = gettagindex(this, "tag_weapon"));
 499                         else
 500                                 (idx = gettagindex(this, "handle")) || (idx = gettagindex(this, "tag_handle"));
 501                         if (idx)
 502                         {
 503                                 this.oldorigin = this.movedir - gettaginfo(this, idx);
 504                         }
 505                         else
 506                         {
 507                                 LOG_WARNF(
 508                                         "weapon model %s does not support the 'handle' tag "
 509                                         "and neither does the v_ model support the 'shot' tag, "
 510                                         "will display muzzle flashes TOTALLY wrong\n",
 511                                         this.model);
 512                                 this.oldorigin = '0 0 0';  // there is no way to recover from this
 513                         }
 514                 }
 515
 516 #ifdef SVQC
 517                 this.viewmodelforclient = this.owner;
 518 #else
 519                 this.renderflags |= RF_VIEWMODEL;
 520 #endif
 521         }
 522
 523         this.view_ofs = '0 0 0';
 524         this.movedir_aligned = this.movedir;
 525
 526         if (this.movedir.x >= 0)
 527         {
 528                 //int algn = STAT(GUNALIGN, this.owner);
 529                 int algn = W_GunAlign(this, STAT(GUNALIGN, this.owner));
 530         #ifdef SVQC
 531                 this.m_gunalign = algn;
 532         #endif
 533                 vector v = this.movedir;
 534                 this.movedir = shotorg_adjust(v, false, false, algn);
 535                 this.movedir_aligned = shotorg_adjust(v, false, true, algn);
 536                 this.view_ofs = shotorg_adjust(v, false, true, algn) - v;
 537         }
 538         int compressed_shotorg = compressShotOrigin(this.movedir);
 539         // make them match perfectly
 540 #ifdef SVQC
 541         // null during init
 542         if (this.owner) STAT(SHOTORG, this.owner) = compressed_shotorg;
 543 #endif
 544         this.movedir = decompressShotOrigin(compressed_shotorg);
 545
 546         this.spawnorigin += this.view_ofs;  // offset the casings origin by the same amount
 547
 548         // check if an instant weapon switch occurred
 549         setorigin(this, this.view_ofs);
 550         if (!_anim) return;
 551         // reset animstate now
 552         this.wframe = WFRAME_IDLE;
 553         setanim(this, this.anim_idle, true, false, true);
 554 }
 555 #endif
 556
 557 #ifdef GAMEQC
 558
 559 REGISTER_NET_TEMP(wframe)
 560 #ifdef CSQC
 561 NET_HANDLE(wframe, bool isNew)
 562 {
 563         WFRAME fr = ReadByte();
 564         float t = ReadFloat();
 565         int slot = ReadByte();
 566         bool restartanim = ReadByte();
 567         entity wepent = viewmodels[slot];
 568         if(fr == WFRAME_IDLE)
 569                 wepent.animstate_looping = false; // we don't need to enforce idle animation
 570         else
 571         {
 572                 vector a = '0 0 0';
 573                 switch(fr)
 574                 {
 575                         default:
 576                         case WFRAME_IDLE: a = wepent.anim_idle; break;
 577                         case WFRAME_FIRE1: a = wepent.anim_fire1; break;
 578                         case WFRAME_FIRE2: a = wepent.anim_fire2; break;
 579                         case WFRAME_RELOAD: a = wepent.anim_reload; break;
 580                 }
 581                 a.z *= t;
 582                 anim_set(wepent, a, !restartanim, restartanim, restartanim);
 583         }
 584         wepent.state = ReadByte();
 585         wepent.weapon_nextthink = ReadFloat();
 586         switch (wepent.state)
 587         {
 588                 case WS_RAISE:
 589                         wepent.weapon_switchdelay = wepent.activeweapon.switchdelay_raise;
 590                         break;
 591                 case WS_DROP:
 592                         wepent.weapon_switchdelay = wepent.activeweapon.switchdelay_drop;
 593                         break;
 594                 default:
 595                         wepent.weapon_switchdelay = 0;
 596                         break;
 597         }
 598         return true;
 599 }
 600 #endif
 601
 602 #ifdef SVQC
 603 void wframe_send(entity actor, entity weaponentity, int wepframe, float attackrate, bool restartanim)
 604 {
 605         if (!IS_REAL_CLIENT(actor)) return;
 606         int channel = MSG_ONE;
 607         msg_entity = actor;
 608         WriteHeader(channel, wframe);
 609         WriteByte(channel, wepframe);
 610         WriteFloat(channel, attackrate);
 611         WriteByte(channel, weaponslot(weaponentity.weaponentity_fld));
 612         WriteByte(channel, restartanim);
 613         WriteByte(channel, weaponentity.state);
 614         WriteFloat(channel, weaponentity.weapon_nextthink);
 615 }
 616 #endif
 617
 618 REGISTER_NET_C2S(w_whereis)
 619 #ifdef SVQC
 620 void Weapon_whereis(Weapon this, entity cl);
 621 NET_HANDLE(w_whereis, bool)
 622 {
 623         Weapon wpn = ReadRegistered(Weapons);
 624         if (wpn != WEP_Null) Weapon_whereis(wpn, sender);
 625         return true;
 626 }
 627 #else
 628 void w_whereis(Weapon this)
 629 {
 630         int channel = MSG_C2S;
 631         WriteHeader(channel, w_whereis);
 632         WriteRegistered(Weapons, channel, this);
 633 }
 634 CLIENT_COMMAND(weapon_find, "Show spawn locations of a weapon")
 635 {
 636         switch (request)
 637         {
 638                 case CMD_REQUEST_COMMAND:
 639                 {
 640                         string s = argv(1);
 641                         if (s == "all")
 642                         {
 643                                 FOREACH(Weapons, it != WEP_Null, w_whereis(it));
 644                                 return;
 645                         }
 646                         if (s == "unowned")
 647                         {
 648                                 FOREACH(Weapons, it != WEP_Null && !(STAT(WEAPONS) & it.m_wepset), w_whereis(it));
 649                                 return;
 650                         }
 651                         FOREACH(Weapons, it != WEP_Null && it.netname == s,
 652                         {
 653                                 w_whereis(it);
 654                                 return;
 655                         });
 656                 }
 657                 default:
 658                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 659                 case CMD_REQUEST_USAGE:
 660                 {
 661                         LOG_HELP("Usage:^3 cl_cmd weapon_find weapon");
 662                         LOG_HELP("  Where 'weapon' is the lowercase weapon name, 'all' or 'unowned'.");
 663                         return;
 664                 }
 665         }
 666 }
 667 #endif
 668
 669 #ifdef SVQC
 670 void W_MuzzleFlash_Model_AttachToShotorg(entity actor, .entity weaponentity, entity flash, vector offset)
 671 {
 672         flash.owner = actor;
 673         flash.angles_z = random() * 360;
 674
 675         entity view = actor.(weaponentity);
 676         entity exterior = actor.exteriorweaponentity;
 677
 678         if (view.oldorigin.x > 0)
 679         {
 680                 setattachment(flash, exterior, "");
 681                 setorigin(flash, view.oldorigin + offset);
 682         }
 683         else
 684         {
 685                 if (gettagindex(exterior, "shot")) setattachment(flash, exterior, "shot");
 686                 else setattachment(flash, exterior, "tag_shot");
 687                 setorigin(flash, offset);
 688         }
 689 }
 690 #elif defined(CSQC)
 691 void W_MuzzleFlash_Model_AttachToShotorg(entity wepent, entity flash, vector offset)
 692 {
 693         flash.owner = wepent;
 694         flash.angles_z = random() * 360;
 695
 696         if (gettagindex(wepent, "shot")) setattachment(flash, wepent, "shot");
 697         else setattachment(flash, wepent, "tag_shot");
 698         setorigin(flash, offset);
 699 }
 700 #endif
 701
 702 void W_MuzzleFlash_Model_Think(entity this)
 703 {
 704         this.frame += 2;
 705         this.scale *= 0.5;
 706         this.alpha -= 0.25;
 707         this.nextthink = time + 0.05;
 708
 709         if(this.alpha <= 0)
 710         {
 711                 setthink(this, SUB_Remove);
 712                 this.nextthink = time;
 713                 this.realowner.muzzle_flash = NULL;
 714                 return;
 715         }
 716 }
 717
 718 void W_MuzzleFlash_Model(entity wepent, entity muzzlemodel)
 719 {
 720         if(wepent.muzzle_flash == NULL)
 721                 wepent.muzzle_flash = spawn();
 722
 723         entity flash = wepent.muzzle_flash;
 724         setmodel(flash, muzzlemodel); // precision set below
 725
 726         flash.scale = 0.75;
 727         setthink(flash, W_MuzzleFlash_Model_Think);
 728         flash.nextthink = time + 0.02;
 729         flash.frame = 2;
 730         flash.alpha = 0.75;
 731         flash.angles_z = random() * 180;
 732         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT;
 733         flash.owner = flash.realowner = wepent;
 734
 735 #ifdef CSQC
 736         flash.drawmask = MASK_NORMAL;
 737 #endif
 738 }
 739
 740 REGISTER_NET_TEMP(w_muzzleflash)
 741
 742 #ifdef SVQC
 743 void W_MuzzleFlash(Weapon thiswep, entity actor, .entity weaponentity, vector shotorg, vector shotdir)
 744 {
 745         // don't show an exterior muzzle effect for the off-hand
 746         if(weaponslot(weaponentity) == 0)
 747         {
 748                 Send_Effect_Except(thiswep.m_muzzleeffect, shotorg, shotdir * 1000, 1, actor);
 749
 750                 if(thiswep.m_muzzlemodel != MDL_Null)
 751                 {
 752                         W_MuzzleFlash_Model(actor.exteriorweaponentity, thiswep.m_muzzlemodel);
 753                         W_MuzzleFlash_Model_AttachToShotorg(actor, weaponentity, actor.exteriorweaponentity.muzzle_flash, '5 0 0');
 754                 }
 755         }
 756
 757         FOREACH_CLIENT(it == actor || (IS_SPEC(it) && it.enemy == actor),
 758         {
 759                 if(!IS_REAL_CLIENT(it))
 760                         continue;
 761                 int channel = MSG_ONE;
 762                 msg_entity = it;
 763                 WriteHeader(channel, w_muzzleflash);
 764                 WriteByte(channel, thiswep.m_id);
 765                 WriteByte(channel, weaponslot(weaponentity));
 766                 WriteVector(channel, shotorg);
 767         });
 768 }
 769 #elif defined(CSQC)
 770 NET_HANDLE(w_muzzleflash, bool isNew)
 771 {
 772         return = true;
 773         int weapon_id = ReadByte();
 774         int slot = ReadByte();
 775         vector sv_shotorg = ReadVector();
 776
 777         Weapon thiswep = REGISTRY_GET(Weapons, weapon_id);
 778         vector viewangles = getpropertyvec(VF_CL_VIEWANGLES);
 779         vector forward, right, up;
 780         MAKE_VECTORS(viewangles, forward, right, up);
 781
 782         if(autocvar_chase_active)
 783         {
 784                 // in third person mode, show the muzzle flash from the server side weapon position
 785                 // we don't have a view model to reference in this case
 786                 pointparticles(thiswep.m_muzzleeffect, sv_shotorg, forward * 1000, 1);
 787                 return;
 788         }
 789         if(!autocvar_r_drawviewmodel) return;
 790
 791         entity wepent = viewmodels[slot];
 792         // get the local player entity to calculate shot origin
 793         entity rlplayer = CSQCModel_server2csqc(player_localentnum - 1);
 794         if(!rlplayer)
 795                 rlplayer = csqcplayer; // fall back to the global
 796
 797         vector md = wepent.movedir_aligned;
 798         vector vecs = ((md.x > 0) ? md : '0 0 0');
 799         vector dv = forward * vecs.x + right * -vecs.y + up * vecs.z;
 800         vector org = rlplayer.origin + rlplayer.view_ofs + dv;
 801
 802         pointparticles(thiswep.m_muzzleeffect, org, forward * 1000, 1);
 803
 804         if(thiswep.m_muzzlemodel != MDL_Null)
 805         {
 806                 W_MuzzleFlash_Model(wepent, thiswep.m_muzzlemodel);
 807                 W_MuzzleFlash_Model_AttachToShotorg(wepent, wepent.muzzle_flash, '5 0 0');
 808         }
 809 }
 810 #endif
 811
 812
 813 #endif
 814
 815 #endif