CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.12 FATAL_ERROR)
   2 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/cmake")
   3 project(NetRadiant C CXX)
   4
   5 if (EXISTS "${PROJECT_SOURCE_DIR}/libs/crunch/inc/crn_decomp.h")
   6     set(DEFAULT_BUILD_CRUNCH ON CACHE INTERNAL "...")
   7 else ()
   8     set(DEFAULT_BUILD_CRUNCH OFF CACHE INTERNAL "...")
   9 endif ()
  10
  11 if (EXISTS "${PROJECT_SOURCE_DIR}/tools/unvanquished/daemonmap/tools/quake3/q3map2/main.c")
  12     set(DEFAULT_BUILD_DAEMONMAP ON CACHE INTERNAL "...")
  13 else ()
  14     set(DEFAULT_BUILD_DAEMONMAP OFF CACHE INTERNAL "...")
  15 endif ()
  16
  17 option(BUILD_RADIANT "Build the GUI" ON)
  18 option(BUILD_TOOLS "Build the tools" ON)
  19 option(BUILD_CRUNCH "Build Crunch image support" ${DEFAULT_BUILD_CRUNCH})
  20 option(BUILD_DAEMONMAP "Build daemonmap navigation mesh generator" ${DEFAULT_BUILD_DAEMONMAP})
  21 option(DOWNLOAD_GAMEPACKS "Download game packs" ON)
  22 option(USE_WERROR "Build with -Werror -pedantic-errors" OFF)
  23 option(FHS_INSTALL "Install according to Filesystem Hierarchy Standard" OFF)
  24
  25 set(BUILD_BINARIES OFF CACHE INTERNAL "...")
  26 if (BUILD_RADIANT OR BUILD_TOOLS)
  27     set(BUILD_BINARIES ON)
  28 endif ()
  29
  30 #-----------------------------------------------------------------------
  31 # Paths
  32 #-----------------------------------------------------------------------
  33
  34 if (CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  35     set(CMAKE_INSTALL_PREFIX "${PROJECT_SOURCE_DIR}/install" CACHE PATH "..." FORCE)
  36 endif ()
  37
  38 set(RADIANT_NAME "NetRadiant" CACHE INTERNAL "...")
  39 add_definitions(-DRADIANT_NAME="${RADIANT_NAME}")
  40 set(RADIANT_BASENAME "netradiant" CACHE INTERNAL "...")
  41 add_definitions(-DRADIANT_BASENAME="${RADIANT_BASENAME}")
  42
  43 set(RADIANT_LIB_DIR ${CMAKE_INSTALL_PREFIX} CACHE INTERNAL "...")
  44 set(RADIANT_BIN_DIR ${CMAKE_INSTALL_PREFIX} CACHE INTERNAL "...")
  45 set(RADIANT_DATA_DIR ${CMAKE_INSTALL_PREFIX} CACHE INTERNAL "...")
  46
  47 if (FHS_INSTALL AND NOT BUNDLE_LIBRARIES)
  48     set(RADIANT_LIB_DIR ${CMAKE_INSTALL_PREFIX}/lib/${RADIANT_BASENAME})
  49     set(RADIANT_BIN_DIR ${CMAKE_INSTALL_PREFIX}/bin)
  50     set(RADIANT_DATA_DIR ${CMAKE_INSTALL_PREFIX}/share/${RADIANT_BASENAME})
  51 endif ()
  52
  53 set(GAMEPACKS_DOWNLOAD_DIR ${PROJECT_BINARY_DIR}/download CACHE PATH "Where to store downloaded game packs")
  54
  55 #-----------------------------------------------------------------------
  56 # Version
  57 #-----------------------------------------------------------------------
  58
  59 # CMake 3.0+ would allow this in project()
  60 set(RADIANT_VERSION_MAJOR 1)
  61 set(RADIANT_VERSION_MINOR 5)
  62 set(RADIANT_VERSION_PATCH 0)
  63 set(RADIANT_VERSION "${RADIANT_VERSION_MAJOR}.${RADIANT_VERSION_MINOR}.${RADIANT_VERSION_PATCH}")
  64
  65 set(RADIANT_ABOUTMSG "Custom build" CACHE STRING "About message")
  66
  67 find_package(Git REQUIRED)
  68
  69 execute_process(
  70      COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
  71      WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
  72      OUTPUT_VARIABLE GIT_VERSION
  73      OUTPUT_STRIP_TRAILING_WHITESPACE
  74 )
  75
  76 set(RADIANT_VERSION_STRING "${RADIANT_VERSION}n")
  77
  78 if (GIT_VERSION)
  79     set(RADIANT_VERSION_STRING "${RADIANT_VERSION_STRING}-git-${GIT_VERSION}")
  80 endif ()
  81
  82 message(STATUS "Building ${PROJECT_NAME} ${RADIANT_VERSION_STRING} ${RADIANT_ABOUTMSG}")
  83
  84 #-----------------------------------------------------------------------
  85 # Language standard
  86 #-----------------------------------------------------------------------
  87
  88 if (BUILD_BINARIES)
  89     set(CMAKE_CXX_STANDARD 11)
  90     set(CMAKE_CXX_STANDARD_REQUIRED ON)
  91     set(CMAKE_CXX_EXTENSIONS OFF)
  92
  93     if (CMAKE_VERSION VERSION_LESS "3.1")
  94         if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" OR CMAKE_COMPILER_IS_GNUCXX)
  95             include(CheckCXXCompilerFlag)
  96             check_cxx_compiler_flag(--std=c++${CMAKE_CXX_STANDARD} STD_CXX)
  97             if (STD_CXX)
  98                 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} --std=c++${CMAKE_CXX_STANDARD}")
  99             else ()
 100                 message(SEND_ERROR "Requires C++${CMAKE_CXX_STANDARD} or better")
 101             endif ()
 102         else ()
 103             message(WARNING "Unrecognized compiler: ${CMAKE_CXX_COMPILER_ID}, make sure it supports C++${CMAKE_CXX_STANDARD}")
 104         endif ()
 105     endif ()
 106 endif ()
 107
 108 #-----------------------------------------------------------------------
 109 # Flags
 110 #-----------------------------------------------------------------------
 111
 112 if (BUILD_BINARIES)
 113     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions -fno-rtti")
 114
 115     macro (addflags_c args)
 116         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${args}")
 117     endmacro ()
 118
 119     macro (addflags_cxx args)
 120         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${args}")
 121     endmacro ()
 122
 123     macro (addflags args)
 124         addflags_c("${args}")
 125         addflags_cxx("${args}")
 126     endmacro ()
 127
 128     addflags("-fno-strict-aliasing")
 129     if (NOT WIN32)
 130         addflags("-fvisibility=hidden")
 131     endif ()
 132
 133     if (USE_WERROR)
 134         addflags("-Werror")
 135         addflags("-pedantic-errors")
 136     endif ()
 137
 138     addflags("-Wall")
 139     addflags("-Wextra")
 140     addflags("-pedantic")
 141
 142     addflags_c("-Wno-deprecated-declarations") # vfs.c: g_strdown
 143
 144     addflags("-Wno-unused-function")
 145     addflags("-Wno-unused-variable")
 146     addflags("-Wno-unused-parameter")
 147
 148     set(CMAKE_POSITION_INDEPENDENT_CODE 1)
 149 endif ()
 150
 151 if (BUILD_RADIANT)
 152     set(GTK_TARGET 2 CACHE STRING "GTK target")
 153     add_definitions(-DGTK_TARGET=${GTK_TARGET})
 154
 155     if (WIN32)
 156         add_definitions(-DWORKAROUND_WINDOWS_FLOATING_WINDOW=1)
 157
 158         if (GTK_TARGET EQUAL 2)
 159             add_definitions(-DWORKAROUND_WINDOWS_GTK2_GLWIDGET=1)
 160         endif ()
 161     endif ()
 162 endif ()
 163
 164 #-----------------------------------------------------------------------
 165 # Defs
 166 #-----------------------------------------------------------------------
 167
 168 if (BUILD_BINARIES)
 169     add_definitions(-DRADIANT_VERSION="${RADIANT_VERSION}")
 170     add_definitions(-DRADIANT_VERSION_STRING="${RADIANT_VERSION_STRING}")
 171
 172     if (NOT CMAKE_BUILD_TYPE MATCHES Release)
 173         add_definitions(-D_DEBUG=1)
 174     endif ()
 175 endif ()
 176
 177 if (BUILD_RADIANT)
 178     add_definitions(-DRADIANT_ABOUTMSG="${RADIANT_ABOUTMSG}")
 179
 180     macro (disable_deprecated name gtk2only)
 181         add_definitions(-D${name}_DISABLE_SINGLE_INCLUDES)
 182         if ((${gtk2only} EQUAL 0) OR (GTK_TARGET EQUAL 2))
 183             add_definitions(-D${name}_DISABLE_DEPRECATED)
 184         endif ()
 185     endmacro ()
 186
 187     disable_deprecated(ATK 0)
 188     disable_deprecated(G 0)
 189     disable_deprecated(GDK 0)
 190     disable_deprecated(GDK_PIXBUF 0)
 191     disable_deprecated(GTK 1)
 192     disable_deprecated(PANGO 0)
 193 endif ()
 194
 195 if (BUILD_BINARIES)
 196     add_custom_target(binaries ALL)
 197
 198     if(APPLE OR ${CMAKE_SYSTEM_NAME} STREQUAL "FreeBSD")
 199         link_directories(
 200             /usr/local/lib
 201         )
 202     endif ()
 203
 204     if (WIN32)
 205         add_definitions(
 206             -DWIN32=1
 207             -D_WIN32=1
 208         )
 209     else ()
 210         add_definitions(
 211             -DPOSIX=1
 212         )
 213     endif ()
 214 endif ()
 215
 216 if (BUILD_RADIANT AND NOT APPLE AND NOT WIN32)
 217     set(XWINDOWS ON)
 218     find_package(X11 REQUIRED)
 219     include_directories(${X11_INCLUDE_DIR})
 220     add_definitions(-DXWINDOWS=1)
 221 endif ()
 222
 223 if (BUILD_BINARIES)
 224     include_directories("${PROJECT_SOURCE_DIR}/include")
 225     include_directories("${PROJECT_SOURCE_DIR}/libs")
 226
 227     if (WIN32 OR "${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
 228         set(BUNDLING_SUPPORTED ON)
 229     endif()
 230
 231     if (BUNDLING_SUPPORTED)
 232         if(WIN32 AND NOT CMAKE_CROSSCOMPILING)
 233             set(BUNDLE_LIBRARIES_DEFAULT ON)
 234         else ()
 235             set(BUNDLE_LIBRARIES_DEFAULT OFF)
 236         endif ()
 237
 238         option(BUNDLE_LIBRARIES "Bundle libraries" ${BUNDLE_LIBRARIES_DEFAULT})
 239     endif ()
 240
 241     if (BUNDLE_LIBRARIES AND BUNDLING_SUPPORTED)
 242         add_subdirectory(bundle)
 243
 244         set(FHS_INSTALL OFF CACHE PATH "Disabled because of BUNDLE_LIBRARIES" FORCE)
 245     endif ()
 246
 247     macro (copy_dlls target)
 248         if (BUNDLE_LIBRARIES AND BUNDLING_SUPPORTED)
 249             add_custom_command(TARGET ${target} POST_BUILD
 250                 COMMAND "${PROJECT_SOURCE_DIR}/library-bundler"
 251                 "register" "${PROJECT_BINARY_DIR}" "$<TARGET_FILE:${target}>"
 252                 VERBATIM
 253             )
 254             add_dependencies(bundle ${target})
 255         endif ()
 256     endmacro ()
 257 endif ()
 258
 259 #-----------------------------------------------------------------------
 260 # Libraries
 261 #-----------------------------------------------------------------------
 262
 263 if (BUILD_BINARIES)
 264     add_subdirectory(libs)
 265 endif ()
 266
 267 if (BUILD_RADIANT)
 268     add_subdirectory(include)
 269 endif ()
 270
 271 #-----------------------------------------------------------------------
 272 # Plugins
 273 #-----------------------------------------------------------------------
 274
 275 if (BUILD_RADIANT)
 276     add_subdirectory(contrib)
 277 endif ()
 278
 279 #-----------------------------------------------------------------------
 280 # Modules
 281 #-----------------------------------------------------------------------
 282
 283 if (BUILD_RADIANT)
 284     add_subdirectory(plugins)
 285 endif ()
 286
 287 #-----------------------------------------------------------------------
 288 # Radiant
 289 #-----------------------------------------------------------------------
 290
 291 if (BUILD_BINARIES)
 292     macro (radiant_tool name)
 293         add_dependencies(binaries ${name})
 294
 295         if (WIN32)
 296             add_executable(${name} ${ARGN} ${PROJECT_SOURCE_DIR}/include/lib.rc)
 297         else ()
 298             add_executable(${name} ${ARGN})
 299         endif()
 300
 301         copy_dlls(${name})
 302
 303         install(
 304             TARGETS ${name}
 305             RUNTIME DESTINATION ${RADIANT_BIN_DIR}
 306         )
 307     endmacro ()
 308
 309     if (BUILD_RADIANT)
 310         add_subdirectory(radiant)
 311     endif ()
 312 endif ()
 313
 314 #-----------------------------------------------------------------------
 315 # Tools
 316 #-----------------------------------------------------------------------
 317
 318 if (BUILD_TOOLS)
 319     add_subdirectory(tools)
 320
 321     file(GLOB DATA_FILES "${PROJECT_SOURCE_DIR}/setup/data/tools/*")
 322
 323     if (NOT (PROJECT_SOURCE_DIR STREQUAL PROJECT_BINARY_DIR))
 324         # Copy data files from sources to the build directory
 325         message(STATUS "Copying data files")
 326         file(COPY ${DATA_FILES} DESTINATION "${PROJECT_BINARY_DIR}")
 327     endif ()
 328 endif ()
 329
 330 #-----------------------------------------------------------------------
 331 # Game packs
 332 #-----------------------------------------------------------------------
 333
 334 set(GAMEPACKS_LICENSE_LIST free CACHE STRING "Download game packs by license")
 335 set(GAMEPACKS_NAME_LIST none CACHE STRING "Download game packs by name")
 336
 337 if (DOWNLOAD_GAMEPACKS)
 338     add_custom_target(gamepacks ALL
 339        COMMAND "${PROJECT_SOURCE_DIR}/gamepack-manager" --license ${GAMEPACKS_LICENSE_LIST} --name ${GAMEPACKS_NAME_LIST} --download-dir "${GAMEPACKS_DOWNLOAD_DIR}" --install-dir "${PROJECT_BINARY_DIR}/gamepacks" --download --install
 340        COMMENT "Downloading game packs"
 341     )
 342 endif ()
 343
 344 #-----------------------------------------------------------------------
 345 # Install
 346 #-----------------------------------------------------------------------
 347
 348 if (BUILD_BINARIES)
 349     install(DIRECTORY
 350         setup/data/tools/base
 351         setup/data/tools/bitmaps
 352         setup/data/tools/gl
 353         setup/data/tools/plugins
 354         docs
 355         DESTINATION ${RADIANT_DATA_DIR}
 356     )
 357
 358     install(FILES
 359         setup/data/tools/global.xlink
 360         DESTINATION ${RADIANT_DATA_DIR}
 361     )
 362 endif ()
 363
 364 if (DOWNLOAD_GAMEPACKS)
 365     if (FHS_INSTALL)
 366        set(GAME_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}/share/netradiant")
 367     else ()
 368        set(GAME_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}")
 369     endif ()
 370
 371     install(DIRECTORY
 372         ${PROJECT_BINARY_DIR}/gamepacks
 373         DESTINATION ${RADIANT_DATA_DIR}
 374     )
 375 endif ()
 376
 377 if(BUILD_BINARIES AND FHS_INSTALL AND NOT WIN32 AND NOT APPLE)
 378     install(FILES
 379         ${PROJECT_SOURCE_DIR}/icons/netradiant.png
 380         DESTINATION ${CMAKE_INSTALL_PREFIX}/share/pixmaps
 381     )
 382     install(FILES
 383         ${PROJECT_SOURCE_DIR}/icons/netradiant.desktop
 384         DESTINATION ${CMAKE_INSTALL_PREFIX}/share/applications
 385     )
 386     install(FILES
 387         ${PROJECT_SOURCE_DIR}/icons/mime/map.xml
 388         DESTINATION ${CMAKE_INSTALL_PREFIX}/share/mime/model
 389     )
 390 endif ()
 391
 392 include(cmake/scripts/package.cmake)