X-Git-Url: http://git.xonotic.org/?a=blobdiff_plain;f=qcsrc%2Fserver%2Fmutators%2Fsandbox.qc;h=36d1db83c2bdb4d5af35909f604e638397ae87ea;hb=918b244767365c352b5b526333e8cb119dd602d0;hp=0e8303e1e197bed1cc5f03aff1e46412c38b899b;hpb=8e87e6bf749066d4295c974ad34334ddc6b826dc;p=xonotic%2Fxonotic-data.pk3dir.git

diff --git a/qcsrc/server/mutators/sandbox.qc b/qcsrc/server/mutators/sandbox.qc
index 0e8303e1e..36d1db83c 100644
--- a/qcsrc/server/mutators/sandbox.qc
+++ b/qcsrc/server/mutators/sandbox.qc
@@ -1,44 +1,256 @@
+.string object_clipboard;
+
+entity sandbox_EditObject()
+{
+	// returns the traced entity if the player can edit it, and world if not
+
+	makevectors(self.v_angle);
+	WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_edit, MOVE_NORMAL, self);
+	if(trace_ent.classname == "object" && trace_ent.realowner == self)
+		return trace_ent;
+	else
+		return world;
+}
+
+entity sandbox_SpawnObject()
+{
+	// spawn a new object with default properties
+
+	entity e;
+	e = spawn();
+	e.realowner = self;
+	e.classname = "object";
+	e.takedamage = DAMAGE_NO;
+	e.movetype = MOVETYPE_TOSS;
+	e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
+
+	// set origin and direction based on player position and view angle
+	makevectors(self.v_angle);
+	WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, self);
+	setorigin(e, trace_endpos);
+	e.angles_y = self.v_angle_y;
+
+	return e;
+}
+
 MUTATOR_HOOKFUNCTION(sandbox_PlayerCommand)
 {
 	if(MUTATOR_RETURNVALUE) // command was already handled?
-		return 0;
+		return FALSE;
 	if(cmd_name == "g_sandbox")
 	{
 		if(cmd_argc < 2)
 		{
-			print_to(self, "Sandbox mode is active. For more information, use 'g_sandbox help'");
-			return 1;
+			print_to(self, "Sandbox mode is active. For usage information, type 'sandbox help'");
+			return TRUE;
 		}
 
+		entity e;
 		if(argv(1) == "help")
 		{
 			print_to(self, "You can use the following sandbox commands:");
-			print_to(self, "^7\"^2spawn ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
-			return 1;
+			print_to(self, "^7\"^2spawn_item ^3item^7\" spawns the specified item in front of the player. Only weapons are currently supported");
+			print_to(self, "^7\"^2spawn_object ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
+			print_to(self, "^7\"^2remove_object^7\" removes the object the player is looking at. Players can only remove their own objects");
+			print_to(self, "^7\"^2duplicate_object_copy^7\" copies the object the player is looking at. Players can only copy their own objects");
+			print_to(self, "^7\"^2duplicate_object_paste^7\" pastes the copied object in front of the player");
+			print_to(self, "^7\"^2edit_object ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
+			print_to(self, "^7Object properties for ^2edit_object^7:");
+			print_to(self, "^3skin ^7- changes the skin of the object");
+			print_to(self, "^3frame ^7- object animation frame, for self-animated models");
+			print_to(self, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
+			return TRUE;
 		}
-		else if(argv(1) == "spawn")
+		else if(argv(1) == "spawn_item")
 		{
-			// spawn a new object with the default settings
+			// only weapons are currently supported
+
+			if(cmd_argc < 3)
+			{
+				print_to(self, "WARNING: Attempted to spawn an item without specifying its type. Please specify the name of your item after the 'spawn_item' command");
+				return TRUE;
+			}
 
-			entity e;
-			e = spawn();
+			// spawn a new item
+			float i;
 			makevectors(self.v_angle);
-			traceline(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 250, MOVE_NOMONSTERS, self);
-			setorigin(e, trace_endpos);
-			setmodel(e, "models/vehicles-static/raptor.md3");
+			WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NOMONSTERS, self);
+
+			for(i = WEP_FIRST; i <= WEP_LAST; ++i)
+			{
+				e = get_weaponinfo(i);
+				if(e.netname == argv(2))
+				{
+					W_ThrowNewWeapon(self, i, FALSE, trace_endpos, '0 0 0');
+					if(autocvar_g_sandbox_info)
+						print(strcat(self.netname, " spawned a ^2", e.netname, "^7 at origin ", vtos(e.origin), "\n"));
+					return TRUE;
+				}
+			}
+
+			print_to(self, "WARNING: Attempted to spawn an invalid or unsupported item. See 'sandbox help' for allowed items");
+			return TRUE;
+		}
+		else if(argv(1) == "spawn_object")
+		{
+			// don't allow spawning objects without a model
+			if(cmd_argc < 3)
+			{
+				print_to(self, "WARNING: Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'spawn_object' command");
+				return TRUE;
+			}
+			else if not(fexists(argv(2)))
+			{
+				print_to(self, "WARNING: Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
+				return TRUE;
+			}
+
+			e = sandbox_SpawnObject();
+			setmodel(e, argv(2));
 
 			if(autocvar_g_sandbox_info)
 				print(strcat(self.netname, " spawned an object at origin ", vtos(e.origin), "\n"));
 
-			return 1;
+			return TRUE;
+		}
+		else if(argv(1) == "remove_object")
+		{
+			e = sandbox_EditObject();
+			if(e != world)
+			{
+				if(autocvar_g_sandbox_info)
+					print(strcat(self.netname, " removed an object at origin ", vtos(e.origin), "\n"));
+				remove(e);
+				e = world;
+				return TRUE;
+			}
+
+			print_to(self, "WARNING: Object could not be removed. Make sure you are facing an object that belongs to you");
+			return TRUE;
+		}
+		else if(argv(1) == "duplicate_object_copy")
+		{
+			// copies customizable properties of the selected object to the clipboard
+
+			e = sandbox_EditObject(); // you can only copy objects you can edit, so this works
+			if(e != world)
+			{
+				// set clipboard properties
+				if(self.object_clipboard)
+					strunzone(self.object_clipboard);
+				self.object_clipboard = strzone(strcat(e.model, " ", ftos(e.skin), " ", ftos(e.frame), " ", ftos(e.movetype)));
+
+				print_to(self, "Object copied to clipboard");
+				return TRUE;
+			}
+
+			print_to(self, "WARNING: Object could not be copied. Make sure you are facing an object that belongs to you");
+			return TRUE;
 		}
+		else if(argv(1) == "duplicate_object_paste")
+		{
+			// spawns a new object using the properties in the player's clipboard
+
+			if(!self.object_clipboard) // no object in clipboard
+			{
+				print_to(self, "WARNING: No object in clipboard. You must copy an object before you can paste it");
+				return TRUE;
+			}
+
+			e = sandbox_SpawnObject();
+			tokenize_console(self.object_clipboard);
+
+			// apply clipboard properties
+			setmodel(e, argv(0));
+			e.skin = stof(argv(1));
+			e.frame = stof(argv(2));
+			e.movetype = stof(argv(3));
+
+			print_to(self, "Object pasted");
+			if(autocvar_g_sandbox_info)
+				print(strcat(self.netname, " pasted an object at origin ", vtos(e.origin), "\n"));
+
+			return TRUE;
+		}
+		else if(argv(1) == "edit_object")
+		{
+			if(!argv(2) || !argv(3))
+			{
+				print_to(self, "WARNING: Too few parameters. You must specify a property to edit, followed by its value");
+				return TRUE;
+			}
+
+			e = sandbox_EditObject();
+			if(e != world)
+			{
+				if(argv(2) == "skin")
+					e.skin = stof(argv(3));
+				else if(argv(2) == "frame")
+					e.frame = stof(argv(3));
+				else
+					print_to(self, "WARNING: Invalid object property. For usage information, type 'sandbox help'");
+
+				return TRUE;
+			}
+
+			print_to(self, "WARNING: Object could not be edited. Make sure you are facing an object that belongs to you");
+			return TRUE;
+		}
+		else
+		{
+			print_to(self, "Invalid command. For usage information, type 'sandbox help'");
+			return TRUE;
+		}
+	}
+	return FALSE;
+}
+
+MUTATOR_HOOKFUNCTION(sandbox_PlayerPreThink)
+{
+	// if the player is close enough to their object, they can drag it
+
+	if(autocvar_sv_cheats)
+		return FALSE; // cheat dragging is used instead
+
+	// grab is TRUE if the object can be picked up. While an object is being carried, the Drag() function
+	// must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
+	// This also makes sure that an object can only pe picked up if in range, but does not get dropped if
+	// it goes out of range while slinging it around.
+
+	entity e;
+	float grab;
+
+	e = sandbox_EditObject();
+	if(e != world && vlen(e.origin - self.origin) <= autocvar_g_sandbox_editor_distance_edit)
+		grab = TRUE;
+
+	if(Drag(e, grab)) // execute dragging
+	{
+		if(autocvar_g_sandbox_info)
+			print(strcat(self.netname, " grabbed an object at origin ", vtos(e.origin), "\n"));
+		return TRUE;
 	}
-	return 0;
+
+	return FALSE;
+}
+
+MUTATOR_HOOKFUNCTION(sandbox_ClientDisconnect)
+{
+	// unzone the player's clipboard if it's not empty
+	if(self.object_clipboard)
+	{
+		strunzone(self.object_clipboard);
+		self.object_clipboard = string_null;
+	}
+
+	return FALSE;
 }
 
 MUTATOR_DEFINITION(sandbox)
 {
 	MUTATOR_HOOK(SV_ParseClientCommand, sandbox_PlayerCommand, CBC_ORDER_ANY);
+	MUTATOR_HOOK(PlayerPreThink, sandbox_PlayerPreThink, CBC_ORDER_ANY);
+	MUTATOR_HOOK(ClientDisconnect, sandbox_ClientDisconnect, CBC_ORDER_ANY);
 
-	return 0;
+	return FALSE;
 }