X-Git-Url: http://git.xonotic.org/?a=blobdiff_plain;f=qcsrc%2Fclient%2Fdamage.qc;h=2ac4a01c138f4c7c1511a2985465ab7472350998;hb=d03bf59652dab079deef7cf35e5b80599b13df05;hp=57d4c5c0e7da66651f4280e8abdadabea0d6e072;hpb=e1f5688a2d0b36249850a8d8ab4707da5796f1df;p=xonotic%2Fxonotic-data.pk3dir.git

diff --git a/qcsrc/client/damage.qc b/qcsrc/client/damage.qc
index 57d4c5c0e..2ac4a01c1 100644
--- a/qcsrc/client/damage.qc
+++ b/qcsrc/client/damage.qc
@@ -1,6 +1,7 @@
+void DamageEffect(vector hitorg, float dmg, float type, float specnum1);
 void Ent_DamageInfo(float isNew)
 {
-	float dmg, rad, edge, thisdmg, forcemul;
+	float dmg, rad, edge, thisdmg, forcemul, species;
 	vector force, thisforce;
 	entity oldself;
 
@@ -18,6 +19,7 @@ void Ent_DamageInfo(float isNew)
 	rad = ReadByte();
 	edge = ReadByte();
 	force = decompressShortVector(ReadShort());
+	species = ReadByte();
 
 	if not(isNew)
 		return;
@@ -32,15 +34,14 @@ void Ent_DamageInfo(float isNew)
 	
 	for(self = findradius(w_org, rad + MAX_DAMAGEEXTRARADIUS); self; self = self.chain)
 	{
-		vector p = NearestPointOnBox(self, w_org);
-		if(vlen(p - w_org) > rad + self.damageextraradius)
-			continue;
-
+		vector nearest = NearestPointOnBox(self, w_org);
 		if(rad)
 		{
-			thisdmg = vlen(self.origin - w_org) / rad;
+			thisdmg = ((vlen (nearest - w_org) - bound(MIN_DAMAGEEXTRARADIUS, self.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
 			if(thisdmg >= 1)
-				thisdmg = 1;
+				continue;
+			if(thisdmg < 0)
+				thisdmg = 0;
 			if(dmg)
 			{
 				thisdmg = dmg + (edge - dmg) * thisdmg;
@@ -54,6 +55,9 @@ void Ent_DamageInfo(float isNew)
 		}
 		else
 		{
+			if(vlen(nearest - w_org) > bound(MIN_DAMAGEEXTRARADIUS, self.damageextraradius, MAX_DAMAGEEXTRARADIUS))
+				continue;
+
 			thisdmg = dmg;
 			thisforce = forcemul * force;
 		}
@@ -70,6 +74,8 @@ void Ent_DamageInfo(float isNew)
 
 		if(self.event_damage)
 			self.event_damage(thisdmg, w_deathtype, w_org, thisforce);
+
+		DamageEffect(w_org, thisdmg, w_deathtype, species);
 	}
 
 	self = oldself;
@@ -231,3 +237,89 @@ void DamageInfo_Precache()
 	for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 		(get_weaponinfo(i)).weapon_func(WR_PRECACHE);
 }
+
+void DamageEffect_Think()
+{
+	if(time >= self.cnt || self.owner == world || self.owner.model == "" || !self.owner.drawmask)
+	{
+		// time is up or the player got gibbed / disconnected
+		remove(self);
+		return;
+	}
+	if(self.owner.entnum == player_localentnum && !autocvar_chase_active)
+		return; // if we aren't using a third person view, hide our own effects
+
+	// now generate the particles
+	vector org;
+	org = gettaginfo(self, 0); // origin at attached location
+	pointparticles(self.team, org, '0 0 0', 1);
+	self.nextthink = time + autocvar_cl_damageeffect_ticrate;
+}
+
+void DamageEffect(vector hitorg, float dmg, float type, float specnum)
+{
+	// particle effects for players and objects damaged by weapons (eg: flames coming out of victims shot with rockets)
+
+	float life, i;
+	string specstr, effectnum;
+	entity e;
+
+	if(autocvar_cl_gentle || autocvar_cl_gentle_damage)
+		return;
+	if(self == world || self.model == "" || !self.drawmask)
+		return;
+
+	// return if we reached our damage effect limit
+	for(e = world; (e = find(e, classname, "damageeffect")); )
+		if(e.owner.entnum == self.entnum)
+			i += 1;
+	if(autocvar_cl_damageeffect < 1 || (self.isplayermodel && i >= autocvar_cl_damageeffect_limit))
+		return; // allow multiple damage effects on players
+	if(autocvar_cl_damageeffect < 2 || (!self.isplayermodel && i))
+		return; // allow a single damage effect on objects
+
+	specstr = species_prefix(specnum);
+	life = bound(autocvar_cl_damageeffect_lifetime_min, dmg * autocvar_cl_damageeffect_lifetime, autocvar_cl_damageeffect_lifetime_max);
+	type = DEATH_WEAPONOF(type);
+	e = get_weaponinfo(type);
+
+	effectnum = strcat("weapondamage_", e.netname);
+	// if the weapon is a bullet weapon, its damage effect is blood
+	// since blood is species dependent, use the species tag for this effect
+	if(type == WEP_SHOTGUN || type == WEP_UZI || type == WEP_RIFLE)
+	{
+		if(self.isplayermodel)
+		{
+			effectnum = strcat(effectnum, "_", specstr);
+			effectnum = substring(effectnum, 0, strlen(effectnum) - 1); // remove the _ symbol at the end of the species tag
+		}
+		else
+			return; // objects don't bleed
+	}
+
+	// if this is a player, damage effects will show on the limb where damage was dealt
+	// we do this by choosing the skeletal bone closest to the impact, and attaching the effect there
+	if(self.isplayermodel)
+	{
+		float closest;
+		FOR_EACH_TAG(self)
+		{
+			// go through all skeletal bones on the player, and choose the one closest to the damage origin
+			if(!closest || vlen(hitorg - gettaginfo(self, tagnum)) <= vlen(hitorg - gettaginfo(self, closest)))
+				closest = tagnum;
+		}
+		gettaginfo(self, closest); // set gettaginfo_name to our bone
+	}
+	else
+		gettaginfo(self, 0); // set gettaginfo_name to entity origin
+
+	e = spawn();
+	setmodel(e, "models/null.md3"); // necessary to attach and read origin
+	setattachment(e, self, gettaginfo_name); // attach to the given bone
+	e.owner = self;
+	e.cnt = time + life;
+	e.classname = "damageeffect";
+	e.team = particleeffectnum(effectnum);
+	e.think = DamageEffect_Think;
+	e.nextthink = time;
+}