qcsrc/server/weapons/weaponsystem.qc

   1 #include "weaponsystem.qh"
   2
   3 #include "selection.qh"
   4
   5 #include "../command/common.qh"
   6 #include "../mutators/_mod.qh"
   7 #include "../round_handler.qh"
   8 #include <common/t_items.qh>
   9 #include <common/animdecide.qh>
  10 #include <common/constants.qh>
  11 #include <common/net_linked.qh>
  12 #include <common/monsters/_mod.qh>
  13 #include <common/notifications/all.qh>
  14 #include <common/util.qh>
  15 #include <common/weapons/_all.qh>
  16 #include <common/state.qh>
  17 #include <lib/csqcmodel/sv_model.qh>
  18 #include <common/wepent.qh>
  19
  20 .int state;
  21
  22 .float weapon_frametime;
  23
  24 float W_WeaponRateFactor(entity this)
  25 {
  26         float t = 1;
  27         if(g_weaponratefactor > 0)
  28                 t = 1.0 / g_weaponratefactor;
  29
  30         MUTATOR_CALLHOOK(WeaponRateFactor, t, this);
  31         t = M_ARGV(0, float);
  32
  33         return t;
  34 }
  35
  36 float W_WeaponSpeedFactor(entity this)
  37 {
  38         float t = 1.0 * g_weaponspeedfactor;
  39
  40         MUTATOR_CALLHOOK(WeaponSpeedFactor, t, this);
  41         t = M_ARGV(0, float);
  42
  43         return t;
  44 }
  45
  46
  47 bool CL_Weaponentity_CustomizeEntityForClient(entity this, entity client)
  48 {
  49         this.viewmodelforclient = this.owner;
  50         if (IS_SPEC(client) && client.enemy == this.owner) this.viewmodelforclient = client;
  51         return true;
  52 }
  53
  54 vector CL_Weapon_GetShotOrg(int wpn)
  55 {
  56         entity wi = Weapons_from(wpn);
  57         entity e = spawn();
  58         CL_WeaponEntity_SetModel(e, wi.mdl, false);
  59         vector ret = e.movedir;
  60         CL_WeaponEntity_SetModel(e, "", false);
  61         delete(e);
  62         return ret;
  63 }
  64
  65 .float m_alpha;
  66 .string w_weaponname;
  67 .int w_dmg;
  68 .int w_deadflag;
  69
  70 void CL_Weaponentity_Think(entity this)
  71 {
  72         this.nextthink = time;
  73         if (game_stopped) this.frame = this.anim_idle.x;
  74         .entity weaponentity = this.weaponentity_fld;
  75         if (this.owner.(weaponentity) != this)
  76         {
  77                 // owner has new gun; remove old one
  78                 if (this.weaponchild) delete(this.weaponchild);
  79                 if (this.hook) delete(this.hook);
  80                 delete(this);
  81                 return;
  82         }
  83         if (IS_DEAD(this.owner))
  84         {
  85                 // owner died; disappear
  86                 this.model = "";
  87                 if (this.weaponchild) this.weaponchild.model = "";
  88                 return;
  89         }
  90         if (this.w_weaponname != this.weaponname
  91             || this.w_dmg != this.modelindex
  92             || this.w_deadflag != this.deadflag)
  93         {
  94                 // owner changed weapons; update appearance
  95                 this.w_weaponname = this.weaponname;
  96                 this.w_dmg = this.modelindex;
  97                 this.w_deadflag = this.deadflag;
  98
  99                 CL_WeaponEntity_SetModel(this, this.weaponname, true);
 100         }
 101
 102         this.alpha = -1;  // TODO: don't render this entity at all
 103
 104         if (this.owner.alpha == default_player_alpha) this.m_alpha = default_weapon_alpha;
 105         else if (this.owner.alpha != 0) this.m_alpha = this.owner.alpha;
 106         else this.m_alpha  = 1;
 107
 108         if (this.weaponchild)
 109         {
 110                 this.weaponchild.alpha = this.alpha;
 111                 this.weaponchild.effects = this.effects;
 112         }
 113 }
 114
 115 void CL_ExteriorWeaponentity_Think(entity this)
 116 {
 117         this.nextthink = time;
 118         .entity weaponentity = this.weaponentity_fld;
 119         entity w_ent = this.owner.(weaponentity);
 120         if (this.owner.exteriorweaponentity != this)
 121         {
 122                 delete(this);
 123                 return;
 124         }
 125         if (IS_DEAD(this.owner))
 126         {
 127                 this.model = "";
 128                 return;
 129         }
 130         if (this.weaponname != w_ent.weaponname || this.dmg != w_ent.modelindex
 131             || this.deadflag != w_ent.deadflag)
 132         {
 133                 this.weaponname = w_ent.weaponname;
 134                 this.dmg = w_ent.modelindex;
 135                 this.deadflag = w_ent.deadflag;
 136                 if (w_ent.weaponname != "")
 137                 {
 138                         _setmodel(this, W_Model(strcat("v_", w_ent.weaponname, ".md3")));
 139                         setsize(this, '0 0 0', '0 0 0');
 140                 }
 141                 else this.model = "";
 142
 143                 int tag_found;
 144                 if ((tag_found = gettagindex(this.owner, "tag_weapon")))
 145                 {
 146                         this.tag_index = tag_found;
 147                         this.tag_entity = this.owner;
 148                 }
 149                 else
 150                 {
 151                         setattachment(this, this.owner, "bip01 r hand");
 152                 }
 153         }
 154         this.effects = this.owner.effects;
 155         this.effects |= EF_LOWPRECISION;
 156         this.effects = this.effects & EFMASK_CHEAP;  // eat performance
 157         if (this.owner.alpha == default_player_alpha) this.alpha = default_weapon_alpha;
 158         else if (this.owner.alpha != 0) this.alpha = this.owner.alpha;
 159         else this.alpha = 1;
 160
 161     Weapon wep = this.owner.(weaponentity).m_weapon;
 162         if (wep) this.glowmod = weaponentity_glowmod(wep, this.owner, this.owner.clientcolors, this.owner.(weaponentity));
 163         this.colormap = this.owner.colormap;
 164
 165         CSQCMODEL_AUTOUPDATE(this);
 166 }
 167
 168 // spawning weaponentity for client
 169 void CL_SpawnWeaponentity(entity actor, .entity weaponentity)
 170 {
 171         entity view = actor.(weaponentity) = new(weaponentity);
 172         view.solid = SOLID_NOT;
 173         view.owner = actor;
 174         setmodel(view, MDL_Null);  // precision set when changed
 175         setorigin(view, '0 0 0');
 176         view.weaponentity_fld = weaponentity;
 177         setthink(view, CL_Weaponentity_Think);
 178         view.nextthink = time;
 179         view.viewmodelforclient = actor;
 180         setcefc(view, CL_Weaponentity_CustomizeEntityForClient);
 181
 182         wepent_link(view);
 183
 184         if (weaponentity == weaponentities[0]) // only one exterior model, thank you very much
 185         {
 186                 entity exterior = actor.exteriorweaponentity = new(exteriorweaponentity);
 187                 exterior.solid = SOLID_NOT;
 188                 exterior.owner = actor;
 189                 exterior.weaponentity_fld = weaponentity;
 190                 setorigin(exterior, '0 0 0');
 191                 setthink(exterior, CL_ExteriorWeaponentity_Think);
 192                 exterior.nextthink = time;
 193
 194                 CSQCMODEL_AUTOINIT(exterior);
 195         }
 196 }
 197
 198 // Weapon subs
 199 void w_clear(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 200 {
 201         actor.(weaponentity).m_weapon = WEP_Null;
 202         actor.(weaponentity).m_switchingweapon = WEP_Null;
 203         entity this = actor.(weaponentity);
 204         if (this)
 205         {
 206                 this.state = WS_CLEAR;
 207                 this.effects = 0;
 208         }
 209 }
 210
 211 void w_ready(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 212 {
 213         entity this = actor.(weaponentity);
 214         if (this) this.state = WS_READY;
 215         weapon_thinkf(actor, weaponentity, WFRAME_IDLE, 1000000, w_ready);
 216 }
 217
 218 .float prevdryfire;
 219 .float prevwarntime;
 220 bool weapon_prepareattack_checkammo(Weapon thiswep, entity actor, bool secondary, .entity weaponentity)
 221 {
 222         if ((actor.items & IT_UNLIMITED_WEAPON_AMMO)) return true;
 223         bool ammo = false;
 224         if (secondary) ammo = thiswep.wr_checkammo2(thiswep, actor, weaponentity);
 225         else ammo = thiswep.wr_checkammo1(thiswep, actor, weaponentity);
 226         if (ammo) return true;
 227         // always keep the Mine Layer if we placed mines, so that we can detonate them
 228         if (thiswep == WEP_MINE_LAYER)
 229         {
 230                 IL_EACH(g_mines, it.owner == actor && it.weaponentity_fld == weaponentity,
 231                 {
 232                         return false;
 233                 });
 234         }
 235
 236         if (thiswep == WEP_SHOTGUN)
 237                 if (!secondary && WEP_CVAR(shotgun, secondary) == 1) return false;           // no clicking, just allow
 238
 239         if (thiswep == actor.(weaponentity).m_switchweapon && time - actor.prevdryfire > 1) // only play once BEFORE starting to switch weapons
 240         {
 241                 sound(actor, CH_WEAPON_A, SND_DRYFIRE, VOL_BASE, ATTEN_NORM);
 242                 actor.prevdryfire = time;
 243         }
 244
 245         // check if the other firing mode has enough ammo
 246         bool ammo_other = false;
 247         if (secondary) ammo_other = thiswep.wr_checkammo1(thiswep, actor, weaponentity);
 248         else ammo_other = thiswep.wr_checkammo2(thiswep, actor, weaponentity);
 249         if (ammo_other)
 250         {
 251                 if (time - actor.prevwarntime > 1)
 252                 {
 253                         Send_Notification(
 254                                 NOTIF_ONE,
 255                                 actor,
 256                                 MSG_MULTI,
 257                                 ITEM_WEAPON_PRIMORSEC,
 258                                 thiswep.m_id,
 259                                 secondary,
 260                                 (1 - secondary)
 261                                          );
 262                 }
 263                 actor.prevwarntime = time;
 264         }
 265         else  // this weapon is totally unable to fire, switch to another one
 266         {
 267                 W_SwitchToOtherWeapon(actor, weaponentity);
 268         }
 269
 270         return false;
 271 }
 272
 273 .float race_penalty;
 274 bool weapon_prepareattack_check(Weapon thiswep, entity actor, .entity weaponentity, bool secondary, float attacktime)
 275 {
 276         if (actor.weaponentity == NULL) return true;
 277         if (!weapon_prepareattack_checkammo(thiswep, actor, secondary, weaponentity)) return false;
 278
 279         // if sv_ready_restart_after_countdown is set, don't allow the player to shoot
 280         // if all players readied up and the countdown is running
 281         if (time < game_starttime || time < actor.race_penalty) return false;
 282
 283         if (timeout_status == TIMEOUT_ACTIVE)  // don't allow the player to shoot while game is paused
 284                 return false;
 285
 286         // do not even think about shooting if switching
 287         if (actor.(weaponentity).m_switchweapon != actor.(weaponentity).m_weapon) return false;
 288
 289         if (attacktime >= 0)
 290         {
 291                 int slot = weaponslot(weaponentity);
 292                 // don't fire if previous attack is not finished
 293                 if (ATTACK_FINISHED(actor, slot) > time + actor.(weaponentity).weapon_frametime * 0.5) return false;
 294                 entity this = actor.(weaponentity);
 295                 // don't fire while changing weapon
 296                 if (this.state != WS_READY) return false;
 297         }
 298         return true;
 299 }
 300
 301 void weapon_prepareattack_do(entity actor, .entity weaponentity, bool secondary, float attacktime)
 302 {
 303         entity this = actor.(weaponentity);
 304         if (this == NULL) return;
 305         this.state = WS_INUSE;
 306
 307         actor.spawnshieldtime = min(actor.spawnshieldtime, time);  // kill spawn shield when you fire
 308
 309         // if the weapon hasn't been firing continuously, reset the timer
 310         if (attacktime >= 0)
 311         {
 312                 int slot = weaponslot(weaponentity);
 313                 if (ATTACK_FINISHED(actor, slot) < time - this.weapon_frametime * 1.5)
 314                 {
 315                         ATTACK_FINISHED(actor, slot) = time;
 316                         // dprint("resetting attack finished to ", ftos(time), "\n");
 317                 }
 318                 ATTACK_FINISHED(actor, slot) = ATTACK_FINISHED(actor, slot) + attacktime * W_WeaponRateFactor(actor);
 319         }
 320         this.bulletcounter += 1;
 321         // dprint("attack finished ", ftos(ATTACK_FINISHED(actor, slot)), "\n");
 322 }
 323
 324 bool weapon_prepareattack(Weapon thiswep, entity actor, .entity weaponentity, bool secondary, float attacktime)
 325 {
 326         if (weapon_prepareattack_check(thiswep, actor, weaponentity, secondary, attacktime))
 327         {
 328                 weapon_prepareattack_do(actor, weaponentity, secondary, attacktime);
 329                 return true;
 330         }
 331         return false;
 332 }
 333
 334 void wframe_send(entity actor, entity weaponentity, int a, bool restartanim);
 335
 336 /**
 337  * @param t defer thinking until time + t
 338  * @param func next think function
 339  */
 340 void weapon_thinkf_ex(entity actor, .entity weaponentity, WFRAME fr, float t, void(Weapon thiswep, entity actor,
 341         .entity weaponentity, int fire) func, bool forcenorestart)
 342 {
 343         entity this = actor.(weaponentity);
 344         if (this == NULL) return;
 345         bool restartanim;
 346         if (fr == WFRAME_DONTCHANGE)
 347         {
 348                 fr = this.wframe;
 349                 restartanim = false;
 350         }
 351         else
 352         {
 353                 restartanim = fr != WFRAME_IDLE;
 354         }
 355
 356         if(forcenorestart)
 357                 restartanim = false;
 358
 359         vector of = v_forward;
 360         vector or = v_right;
 361         vector ou = v_up;
 362
 363         this.wframe = fr;
 364
 365         v_forward = of;
 366         v_right = or;
 367         v_up = ou;
 368
 369         if (this.weapon_think == w_ready && func != w_ready && this.state == WS_RAISE) backtrace(
 370                         "Tried to override initial weapon think function - should this really happen?");
 371
 372         t *= W_WeaponRateFactor(actor);
 373
 374         // VorteX: haste can be added here
 375         if (this.weapon_think == w_ready)
 376         {
 377                 this.weapon_nextthink = time;
 378                 // dprint("started firing at ", ftos(time), "\n");
 379         }
 380         if (this.weapon_nextthink < time - this.weapon_frametime * 1.5
 381             || this.weapon_nextthink > time + this.weapon_frametime * 1.5)
 382         {
 383                 this.weapon_nextthink = time;
 384                 // dprint("reset weapon animation timer at ", ftos(time), "\n");
 385         }
 386         this.weapon_nextthink += t;
 387         this.weapon_think = func;
 388         // dprint("next ", ftos(this.weapon_nextthink), "\n");
 389
 390         if (this)
 391         {
 392                 FOREACH_CLIENT(true, LAMBDA(
 393                         if(it == actor || (IS_SPEC(it) && it.enemy == actor))
 394                                 wframe_send(it, this, fr, restartanim);
 395                 ));
 396         }
 397
 398         if ((fr == WFRAME_FIRE1 || fr == WFRAME_FIRE2) && t)
 399         {
 400                 bool primary_melee = boolean(fr == WFRAME_FIRE1 && (this.m_weapon.spawnflags & WEP_TYPE_MELEE_PRI));
 401                 bool secondary_melee = boolean(fr == WFRAME_FIRE2 && (this.m_weapon.spawnflags & WEP_TYPE_MELEE_SEC));
 402                 int act = (primary_melee || secondary_melee)
 403                         ? ANIMACTION_MELEE
 404                         : ANIMACTION_SHOOT
 405                         ;
 406                 animdecide_setaction(actor, act, restartanim);
 407         }
 408         else if (actor.anim_upper_action == ANIMACTION_SHOOT || actor.anim_upper_action == ANIMACTION_MELEE)
 409         {
 410                 actor.anim_upper_action = 0;
 411         }
 412 }
 413 void weapon_thinkf(entity actor, .entity weaponentity, WFRAME fr, float t, void(Weapon thiswep, entity actor,
 414         .entity weaponentity, int fire) func)
 415 {
 416         weapon_thinkf_ex(actor, weaponentity, fr, t, func, false);
 417 }
 418
 419
 420 bool forbidWeaponUse(entity player)
 421 {
 422         if (time < game_starttime && !autocvar_sv_ready_restart_after_countdown) return true;
 423         if (player.player_blocked) return true;
 424         if (game_stopped) return true;
 425         if (STAT(FROZEN, player)) return true;
 426         if (MUTATOR_CALLHOOK(ForbidWeaponUse, player)) return true;
 427         return false;
 428 }
 429
 430 .bool hook_switchweapon;
 431
 432 void W_WeaponFrame(Player actor, .entity weaponentity)
 433 {
 434     TC(Player, actor);
 435     TC(PlayerState, PS(actor));
 436         entity this = actor.(weaponentity);
 437         if (frametime) this.weapon_frametime = frametime;
 438
 439         if (!this || actor.health < 1) return;  // Dead player can't use weapons and injure impulse commands
 440
 441         int button_atck = PHYS_INPUT_BUTTON_ATCK(actor);
 442         int button_atck2 = PHYS_INPUT_BUTTON_ATCK2(actor);
 443
 444         if (round_handler_IsActive() && !round_handler_IsRoundStarted())
 445                 button_atck = button_atck2 = 0; // forbid primary and secondary fire, switching is allowed
 446
 447         if (forbidWeaponUse(actor))
 448         {
 449                 if (this.state != WS_CLEAR)
 450                 {
 451                         Weapon wpn = this.m_weapon;
 452                         w_ready(wpn, actor, weaponentity, button_atck | (button_atck2 << 1));
 453                         return;
 454                 }
 455         }
 456
 457         if(autocvar_g_weaponswitch_debug == 2 && weaponslot(weaponentity) > 0)
 458         {
 459                 .entity wepe1 = weaponentities[0];
 460                 entity wep1 = actor.(wepe1);
 461                 this.m_switchweapon = wep1.m_switchweapon;
 462                 if(!(this.m_switchweapon.spawnflags & WEP_FLAG_DUALWIELD) && !(actor.dual_weapons & wep1.m_switchweapon.m_wepset))
 463                 {
 464                         this.m_weapon = WEP_Null;
 465                         this.m_switchingweapon = WEP_Null;
 466                         this.m_switchweapon = WEP_Null;
 467                         this.state = WS_CLEAR;
 468                         this.weaponname = "";
 469                         return;
 470                 }
 471         }
 472
 473         if (this.m_switchweapon == WEP_Null)
 474         {
 475                 this.m_weapon = WEP_Null;
 476                 this.m_switchingweapon = WEP_Null;
 477                 this.state = WS_CLEAR;
 478                 this.weaponname = "";
 479                 return;
 480         }
 481
 482         makevectors(actor.v_angle);
 483         vector fo = v_forward;  // save them in case the weapon think functions change it
 484         vector ri = v_right;
 485         vector up = v_up;
 486
 487         // Change weapon
 488         if (this.m_weapon != this.m_switchweapon)
 489         {
 490                 switch (this.state)
 491                 {
 492                         default:
 493                                 LOG_WARNF("unhandled weaponentity (%i) state for player (%i): %d", this, actor, this.state);
 494                                 break;
 495                         case WS_INUSE:
 496                         case WS_RAISE:
 497                                 break;
 498                         case WS_CLEAR:
 499                         {
 500                                 // end switching!
 501                                 Weapon newwep = this.m_switchweapon;
 502                                 this.m_switchingweapon = newwep;
 503
 504                                 // the two weapon entities will notice this has changed and update their models
 505                                 this.m_weapon = newwep;
 506                                 this.weaponname = newwep.mdl;
 507                                 this.bulletcounter = 0;
 508                                 newwep.wr_setup(newwep, actor, weaponentity);
 509                                 this.state = WS_RAISE;
 510
 511                                 // set our clip load to the load of the weapon we switched to, if it's reloadable
 512                                 if ((newwep.spawnflags & WEP_FLAG_RELOADABLE) && newwep.reloading_ammo)  // prevent accessing undefined cvars
 513                                 {
 514                                         this.clip_load = this.(weapon_load[this.m_switchweapon.m_id]);
 515                                         this.clip_size = newwep.reloading_ammo;
 516                                 }
 517                                 else
 518                                 {
 519                                         this.clip_load = this.clip_size = 0;
 520                                 }
 521
 522                                 weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, newwep.switchdelay_raise, w_ready);
 523                                 break;
 524                         }
 525                         case WS_DROP:
 526                         {
 527                                 // in dropping phase we can switch at any time
 528                                 this.m_switchingweapon = this.m_switchweapon;
 529                                 break;
 530                         }
 531                         case WS_READY:
 532                         {
 533                                 // start switching!
 534                                 this.m_switchingweapon = this.m_switchweapon;
 535                                 entity oldwep = this.m_weapon;
 536
 537                                 // set up weapon switch think in the future, and start drop anim
 538                                 if (INDEPENDENT_ATTACK_FINISHED || ATTACK_FINISHED(actor, weaponslot(weaponentity)) <= time + this.weapon_frametime * 0.5)
 539                                 {
 540                                         sound(actor, CH_WEAPON_SINGLE, SND_WEAPON_SWITCH, VOL_BASE, ATTN_NORM);
 541                                         this.state = WS_DROP;
 542                                         weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, oldwep.switchdelay_drop, w_clear);
 543                                 }
 544                                 break;
 545                         }
 546                 }
 547         }
 548
 549         // LordHavoc: network timing test code
 550         // if (actor.button0)
 551         //      print(ftos(frametime), " ", ftos(time), " >= ", ftos(ATTACK_FINISHED(actor, slot)), " >= ", ftos(this.weapon_nextthink), "\n");
 552
 553         Weapon w = this.m_weapon;
 554
 555         // call the think code which may fire the weapon
 556         // and do so multiple times to resolve framerate dependency issues if the
 557         // server framerate is very low and the weapon fire rate very high
 558         for (int c = 0; c < W_TICSPERFRAME; ++c)
 559         {
 560                 if (w != WEP_Null && !(actor.weapons & WepSet_FromWeapon(w)))
 561                 {
 562                         if (this.m_weapon == this.m_switchweapon) W_SwitchWeapon_Force(actor, w_getbestweapon(actor, weaponentity), weaponentity);
 563                         w = WEP_Null;
 564                 }
 565
 566                 v_forward = fo;
 567                 v_right = ri;
 568                 v_up = up;
 569
 570                 bool block_weapon = false;
 571                 {
 572                         bool key_pressed = PHYS_INPUT_BUTTON_HOOK(actor) && !actor.vehicle;
 573                         if (round_handler_IsActive() && !round_handler_IsRoundStarted())
 574                                 key_pressed = false;
 575
 576                         Weapon off = actor.offhand;
 577                         if (off && !(actor.weapons & WEPSET(HOOK)))
 578                         {
 579                                 if (off.offhand_think) off.offhand_think(off, actor, key_pressed);
 580                         }
 581                         else
 582                         {
 583                                 if (key_pressed && this.m_switchweapon != WEP_HOOK && !actor.hook_switchweapon)
 584                                         W_SwitchWeapon(actor, WEP_HOOK, weaponentity);
 585                                 actor.hook_switchweapon = key_pressed;
 586                                 Weapon h = WEP_HOOK;
 587                                 block_weapon = (this.m_weapon == h && (button_atck || key_pressed));
 588                                 h.wr_think(h, actor, weaponentity, block_weapon ? 1 : 0);
 589                         }
 590                 }
 591
 592                 v_forward = fo;
 593                 v_right = ri;
 594                 v_up = up;
 595
 596                 if (!block_weapon)
 597                 {
 598             Weapon e = this.m_weapon;
 599             TC(Weapon, e);
 600                         if (w != WEP_Null)
 601                         {
 602                                 e.wr_think(e, actor, weaponentity, button_atck | (button_atck2 << 1));
 603                         }
 604                         else if (e)
 605                         {
 606                                 e.wr_gonethink(e, actor, weaponentity);
 607                         }
 608                 }
 609
 610                 if (time + this.weapon_frametime * 0.5 >= this.weapon_nextthink)
 611                 {
 612                         if (this.weapon_think)
 613                         {
 614                                 v_forward = fo;
 615                                 v_right = ri;
 616                                 v_up = up;
 617                                 Weapon wpn = this.m_weapon;
 618                                 this.weapon_think(wpn, actor, weaponentity,
 619                                         button_atck | (button_atck2 << 1));
 620                         }
 621                         else
 622                         {
 623                                 bprint("\{1}^1ERROR: undefined weapon think function for ", actor.netname, "\n");
 624                         }
 625                 }
 626         }
 627 }
 628
 629 void W_AttachToShotorg(entity actor, .entity weaponentity, entity flash, vector offset)
 630 {
 631         flash.owner = actor;
 632         flash.angles_z = random() * 360;
 633
 634         entity view = actor.(weaponentity);
 635         entity exterior = actor.exteriorweaponentity;
 636
 637         if (gettagindex(view, "shot")) setattachment(flash, view, "shot");
 638         else setattachment(flash, view, "tag_shot");
 639         setorigin(flash, offset);
 640
 641         entity xflash = spawn();
 642         copyentity(flash, xflash);
 643
 644         flash.viewmodelforclient = actor;
 645
 646         if (view.oldorigin.x > 0)
 647         {
 648                 setattachment(xflash, exterior, "");
 649                 setorigin(xflash, view.oldorigin + offset);
 650         }
 651         else
 652         {
 653                 if (gettagindex(exterior, "shot")) setattachment(xflash, exterior, "shot");
 654                 else setattachment(xflash, exterior, "tag_shot");
 655                 setorigin(xflash, offset);
 656         }
 657 }
 658
 659 void W_DecreaseAmmo(Weapon wep, entity actor, float ammo_use, .entity weaponentity)
 660 {
 661         if (MUTATOR_CALLHOOK(W_DecreaseAmmo, actor, actor.(weaponentity))) return;
 662         if ((actor.items & IT_UNLIMITED_WEAPON_AMMO) && !wep.reloading_ammo) return;
 663
 664         entity w_ent = actor.(weaponentity);
 665
 666         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 667         if (wep.reloading_ammo)
 668         {
 669                 w_ent.clip_load -= ammo_use;
 670                 w_ent.(weapon_load[w_ent.m_weapon.m_id]) = w_ent.clip_load;
 671         }
 672         else if (wep.ammo_field != ammo_none)
 673         {
 674                 actor.(wep.ammo_field) -= ammo_use;
 675                 if (actor.(wep.ammo_field) < 0)
 676                 {
 677                         backtrace(sprintf(
 678                                 "W_DecreaseAmmo(%.2f): '%s' subtracted too much %s from '%s', resulting with '%.2f' left... "
 679                                 "Please notify Samual immediately with a copy of this backtrace!\n",
 680                                 ammo_use,
 681                                 wep.netname,
 682                                 GetAmmoPicture(wep.ammo_field),
 683                                 actor.netname,
 684                                 actor.(wep.ammo_field)
 685                                              ));
 686                 }
 687         }
 688 }
 689
 690 // weapon reloading code
 691
 692 .float reload_ammo_amount, reload_ammo_min, reload_time;
 693 .float reload_complain;
 694 .string reload_sound;
 695
 696 void W_ReloadedAndReady(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 697 {
 698         // finish the reloading process, and do the ammo transfer
 699
 700         entity w_ent = actor.(weaponentity);
 701         Weapon wpn = w_ent.m_weapon;
 702
 703         w_ent.clip_load = w_ent.old_clip_load;  // restore the ammo counter, in case we still had ammo in the weapon before reloading
 704
 705         // if the gun uses no ammo, max out weapon load, else decrease ammo as we increase weapon load
 706         if (!w_ent.reload_ammo_min || (actor.items & IT_UNLIMITED_WEAPON_AMMO) || wpn.ammo_field == ammo_none)
 707         {
 708                 w_ent.clip_load = w_ent.reload_ammo_amount;
 709         }
 710         else
 711         {
 712                 // make sure we don't add more ammo than we have
 713                 float load = min(w_ent.reload_ammo_amount - w_ent.clip_load, actor.(wpn.ammo_field));
 714                 w_ent.clip_load += load;
 715                 actor.(wpn.ammo_field) -= load;
 716         }
 717         w_ent.(weapon_load[w_ent.m_weapon.m_id]) = w_ent.clip_load;
 718
 719         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
 720         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
 721         // so your weapon is disabled for a few seconds without reason
 722
 723         // ATTACK_FINISHED(actor, slot) -= w_ent.reload_time - 1;
 724
 725         w_ready(wpn, actor, weaponentity, PHYS_INPUT_BUTTON_ATCK(actor) | (PHYS_INPUT_BUTTON_ATCK2(actor) << 1));
 726 }
 727
 728 void W_Reload(entity actor, .entity weaponentity, float sent_ammo_min, Sound sent_sound)
 729 {
 730     TC(Sound, sent_sound);
 731         // set global values to work with
 732         entity this = actor.(weaponentity);
 733         Weapon e = this.m_weapon;
 734
 735         if (MUTATOR_CALLHOOK(W_Reload, actor)) return;
 736
 737         this.reload_ammo_min = sent_ammo_min;
 738         this.reload_ammo_amount = e.reloading_ammo;
 739         this.reload_time = e.reloading_time;
 740         if (actor.reload_sound) strunzone(actor.reload_sound);
 741         actor.reload_sound = strzone(Sound_fixpath(sent_sound));
 742
 743         // don't reload weapons that don't have the RELOADABLE flag
 744         if (!(e.spawnflags & WEP_FLAG_RELOADABLE))
 745         {
 746                 LOG_TRACE(
 747                         "Warning: Attempted to reload a weapon that does not have the WEP_FLAG_RELOADABLE flag. Fix your code!\n");
 748                 return;
 749         }
 750
 751         // return if reloading is disabled for this weapon
 752         if (!this.reload_ammo_amount) return;
 753
 754         // our weapon is fully loaded, no need to reload
 755         if (this.clip_load >= this.reload_ammo_amount) return;
 756
 757         // no ammo, so nothing to load
 758         if (e.ammo_field != ammo_none)
 759         {
 760                 if (!actor.(e.ammo_field) && this.reload_ammo_min)
 761                 {
 762                         if (!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
 763                         {
 764                                 if (IS_REAL_CLIENT(actor) && actor.reload_complain < time)
 765                                 {
 766                                         play2(actor, SND(UNAVAILABLE));
 767                                         sprint(actor, strcat("You don't have enough ammo to reload the ^2", this.m_weapon.m_name, "\n"));
 768                                         actor.reload_complain = time + 1;
 769                                 }
 770                                 // switch away if the amount of ammo is not enough to keep using this weapon
 771                                 if (!(e.wr_checkammo1(e, actor, weaponentity) + e.wr_checkammo2(e, actor, weaponentity)))
 772                                 {
 773                                         this.clip_load = -1;  // reload later
 774                                         W_SwitchToOtherWeapon(actor, weaponentity);
 775                                 }
 776                                 return;
 777                         }
 778                 }
 779         }
 780
 781         if (this)
 782         {
 783                 if (this.wframe == WFRAME_RELOAD) return;
 784
 785                 // allow switching away while reloading, but this will cause a new reload!
 786                 this.state = WS_READY;
 787         }
 788
 789         // now begin the reloading process
 790
 791         _sound(actor, CH_WEAPON_SINGLE, actor.reload_sound, VOL_BASE, ATTEN_NORM);
 792
 793         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
 794         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
 795         // so your weapon is disabled for a few seconds without reason
 796
 797         // ATTACK_FINISHED(actor, slot) = max(time, ATTACK_FINISHED(actor, slot)) + this.reload_time + 1;
 798
 799         weapon_thinkf(actor, weaponentity, WFRAME_RELOAD, this.reload_time, W_ReloadedAndReady);
 800
 801         if (this.clip_load < 0) this.clip_load = 0;
 802         this.old_clip_load = this.clip_load;
 803         this.clip_load = this.(weapon_load[this.m_weapon.m_id]) = -1;
 804 }
 805
 806 void W_DropEvent(.void(Weapon, entity actor, .entity) event, entity player, float weapon_type, entity weapon_item, .entity weaponentity)
 807 {
 808         Weapon w = Weapons_from(weapon_type);
 809         weapon_dropevent_item = weapon_item;
 810         w.event(w, player, weaponentity);
 811 }