qcsrc/server/teamplay.qc

   1 string cache_mutatormsg;
   2 string cache_lastmutatormsg;
   3
   4 // client counts for each team
   5 float c1, c2, c3, c4;
   6 // # of bots on those teams
   7 float cb1, cb2, cb3, cb4;
   8
   9 //float audit_teams_time;
  10
  11 void TeamchangeFrags(entity e)
  12 {
  13         PlayerScore_Clear(e);
  14 }
  15
  16 void tdm_init();
  17 void entcs_init();
  18
  19 void LogTeamchange(float player_id, float team_number, float type)
  20 {
  21         if(!autocvar_sv_eventlog)
  22                 return;
  23
  24         if(player_id < 1)
  25                 return;
  26
  27         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
  28 }
  29
  30 void default_delayedinit()
  31 {
  32         if(!scores_initialized)
  33                 ScoreRules_generic();
  34 }
  35
  36 void ActivateTeamplay()
  37 {
  38         serverflags |= SERVERFLAG_TEAMPLAY;
  39         teamplay = 1;
  40 }
  41
  42 void InitGameplayMode()
  43 {
  44         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
  45
  46         qualifying_override = -1;
  47
  48         VoteReset();
  49
  50         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
  51         get_mi_min_max(1);
  52         world.mins = mi_min;
  53         world.maxs = mi_max;
  54
  55         MapInfo_LoadMapSettings(mapname);
  56         teamplay = 0;
  57         serverflags &~= SERVERFLAG_TEAMPLAY;
  58
  59         if not(cvar_value_issafe(world.fog))
  60         {
  61                 print("The current map contains a potentially harmful fog setting, ignored\n");
  62                 world.fog = string_null;
  63         }
  64         if(MapInfo_Map_fog != "")
  65                 if(MapInfo_Map_fog == "none")
  66                         world.fog = string_null;
  67                 else
  68                         world.fog = strzone(MapInfo_Map_fog);
  69         clientstuff = strzone(MapInfo_Map_clientstuff);
  70
  71         MapInfo_ClearTemps();
  72
  73         // set both here, gamemode can override it later
  74         timelimit_override = autocvar_timelimit_override;
  75         fraglimit_override = autocvar_fraglimit_override;
  76         leadlimit_override = autocvar_leadlimit_override;
  77         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
  78
  79         if(g_dm)
  80         {
  81         }
  82
  83         if(g_tdm)
  84         {
  85                 ActivateTeamplay();
  86                 tdm_init();
  87                 if(autocvar_g_tdm_team_spawns)
  88                         have_team_spawns = -1; // request team spawns
  89         }
  90
  91         if(g_domination)
  92         {
  93                 ActivateTeamplay();
  94                 fraglimit_override = autocvar_g_domination_point_limit;
  95                 leadlimit_override = autocvar_g_domination_point_leadlimit;
  96                 MUTATOR_ADD(gamemode_domination);
  97                 have_team_spawns = -1; // request team spawns
  98         }
  99
 100         if(g_ctf)
 101         {
 102                 ActivateTeamplay();
 103                 fraglimit_override = autocvar_capturelimit_override;
 104                 leadlimit_override = autocvar_captureleadlimit_override;
 105                 MUTATOR_ADD(gamemode_ctf);
 106                 have_team_spawns = -1; // request team spawns
 107         }
 108
 109         if(g_lms)
 110         {
 111                 fraglimit_override = autocvar_g_lms_lives_override;
 112                 leadlimit_override = 0; // not supported by LMS
 113                 if(fraglimit_override == 0)
 114                         fraglimit_override = -1;
 115                 lms_lowest_lives = 9999;
 116                 lms_next_place = 0;
 117                 ScoreRules_lms();
 118         }
 119
 120         if(g_arena)
 121         {
 122                 fraglimit_override = autocvar_g_arena_point_limit;
 123                 leadlimit_override = autocvar_g_arena_point_leadlimit;
 124                 maxspawned = autocvar_g_arena_maxspawned;
 125                 if(maxspawned < 2)
 126                         maxspawned = 2;
 127                 arena_roundbased = autocvar_g_arena_roundbased;
 128         }
 129
 130         if(g_ca)
 131         {
 132                 ActivateTeamplay();
 133                 fraglimit_override = autocvar_g_ca_point_limit;
 134                 leadlimit_override = autocvar_g_ca_point_leadlimit;
 135                 precache_sound("ctf/red_capture.wav");
 136                 precache_sound("ctf/blue_capture.wav");
 137         }
 138         if(g_keyhunt)
 139         {
 140                 ActivateTeamplay();
 141                 fraglimit_override = autocvar_g_keyhunt_point_limit;
 142                 leadlimit_override = autocvar_g_keyhunt_point_leadlimit;
 143                 MUTATOR_ADD(gamemode_keyhunt);
 144         }
 145
 146         if(g_freezetag)
 147         {
 148                 ActivateTeamplay();
 149                 fraglimit_override = autocvar_g_freezetag_point_limit;
 150                 leadlimit_override = autocvar_g_freezetag_point_leadlimit;
 151                 MUTATOR_ADD(gamemode_freezetag);
 152         }
 153
 154         if(g_assault)
 155         {
 156                 ActivateTeamplay();
 157                 ScoreRules_assault();
 158                 have_team_spawns = -1; // request team spawns
 159         }
 160
 161         if(g_onslaught)
 162         {
 163                 ActivateTeamplay();
 164                 have_team_spawns = -1; // request team spawns
 165                 MUTATOR_ADD(gamemode_onslaught);
 166         }
 167
 168         if(g_race)
 169         {
 170
 171                 if(autocvar_g_race_teams)
 172                 {
 173                         ActivateTeamplay();
 174                         race_teams = bound(2, autocvar_g_race_teams, 4);
 175                         have_team_spawns = -1; // request team spawns
 176                 }
 177                 else
 178                         race_teams = 0;
 179
 180                 qualifying_override = autocvar_g_race_qualifying_timelimit_override;
 181                 fraglimit_override = autocvar_g_race_laps_limit;
 182                 leadlimit_override = 0; // currently not supported by race
 183         }
 184
 185         if(g_cts)
 186         {
 187                 g_race_qualifying = 1;
 188                 fraglimit_override = 0;
 189                 leadlimit_override = 0;
 190         }
 191
 192         if(g_nexball)
 193         {
 194         fraglimit_override = autocvar_g_nexball_goallimit;
 195         leadlimit_override = autocvar_g_nexball_goalleadlimit;
 196         ActivateTeamplay();
 197         have_team_spawns = -1; // request team spawns
 198             MUTATOR_ADD(gamemode_nexball);
 199         }
 200
 201         if(g_keepaway)
 202         {
 203                 MUTATOR_ADD(gamemode_keepaway);
 204         }
 205
 206         if(teamplay)
 207                 entcs_init();
 208
 209         cache_mutatormsg = strzone("");
 210         cache_lastmutatormsg = strzone("");
 211
 212         // enforce the server's universal frag/time limits
 213         if(!autocvar_g_campaign)
 214         {
 215                 if(fraglimit_override >= 0)
 216                         cvar_set("fraglimit", ftos(fraglimit_override));
 217                 if(timelimit_override >= 0)
 218                         cvar_set("timelimit", ftos(timelimit_override));
 219                 if(leadlimit_override >= 0)
 220                         cvar_set("leadlimit", ftos(leadlimit_override));
 221                 if(qualifying_override >= 0)
 222                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 223         }
 224
 225         if(g_race)
 226         {
 227                 // we need to find out the correct value for g_race_qualifying
 228                 if(autocvar_g_campaign)
 229                 {
 230                         g_race_qualifying = 1;
 231                 }
 232                 else if(!autocvar_g_campaign && autocvar_g_race_qualifying_timelimit > 0)
 233                 {
 234                         g_race_qualifying = 2;
 235                         race_fraglimit = autocvar_fraglimit;
 236                         race_leadlimit = autocvar_leadlimit;
 237                         race_timelimit = autocvar_timelimit;
 238                         cvar_set("fraglimit", "0");
 239                         cvar_set("leadlimit", "0");
 240                         cvar_set("timelimit", ftos(autocvar_g_race_qualifying_timelimit));
 241                 }
 242                 else
 243                         g_race_qualifying = 0;
 244         }
 245
 246         if(g_race || g_cts)
 247         {
 248                 if(g_race_qualifying)
 249                         independent_players = 1;
 250
 251                 ScoreRules_race();
 252         }
 253
 254         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 255 }
 256
 257 string GetClientVersionMessage() {
 258         string versionmsg;
 259         if (self.version_mismatch) {
 260                 if(self.version < autocvar_gameversion) {
 261                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 262                 } else {
 263                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 264                 }
 265         } else {
 266                 versionmsg = "^2client version and server version are compatible.^8";
 267         }
 268         return versionmsg;
 269 }
 270
 271 string getwelcomemessage(void)
 272 {
 273         string s, modifications, motd;
 274
 275         ret_string = "";
 276         MUTATOR_CALLHOOK(BuildMutatorsPrettyString);
 277         modifications = ret_string;
 278
 279         if(g_weaponarena)
 280         {
 281                 if(g_weaponarena_random)
 282                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 283                 else
 284                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 285         }
 286         if(autocvar_g_start_weapon_laser == 0)
 287                 modifications = strcat(modifications, ", No start weapons");
 288         if(autocvar_sv_gravity < 800)
 289                 modifications = strcat(modifications, ", Low gravity");
 290         if(g_cloaked && !g_cts)
 291                 modifications = strcat(modifications, ", Cloaked");
 292         if(g_grappling_hook)
 293                 modifications = strcat(modifications, ", Hook");
 294         if(g_midair)
 295                 modifications = strcat(modifications, ", Midair");
 296         if(g_pinata)
 297                 modifications = strcat(modifications, ", Piñata");
 298         if(g_weapon_stay && !g_cts)
 299                 modifications = strcat(modifications, ", Weapons stay");
 300         if(g_bloodloss > 0)
 301                 modifications = strcat(modifications, ", Blood loss");
 302         if(g_jetpack)
 303                 modifications = strcat(modifications, ", Jet pack");
 304         if(autocvar_g_powerups == 0)
 305                 modifications = strcat(modifications, ", No powerups");
 306         if(autocvar_g_powerups > 0)
 307                 modifications = strcat(modifications, ", Powerups");
 308         modifications = substring(modifications, 2, strlen(modifications) - 2);
 309
 310         string versionmessage;
 311         versionmessage = GetClientVersionMessage();
 312
 313         s = strcat("This is Xonotic ", autocvar_g_xonoticversion, "\n", versionmessage);
 314         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 315
 316         if(modifications != "")
 317                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 318
 319         if (g_grappling_hook)
 320                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 321
 322         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
 323         {
 324                 if(cache_lastmutatormsg)
 325                         strunzone(cache_lastmutatormsg);
 326                 if(cache_mutatormsg)
 327                         strunzone(cache_mutatormsg);
 328                 cache_lastmutatormsg = strzone(autocvar_g_mutatormsg);
 329                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 330         }
 331
 332         if (cache_mutatormsg != "") {
 333                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 334         }
 335
 336         motd = autocvar_sv_motd;
 337         if (motd != "") {
 338                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 339         }
 340         return s;
 341 }
 342
 343 void SetPlayerColors(entity pl, float _color)
 344 {
 345         /*string s;
 346         s = ftos(cl);
 347         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 348         pl.team = cl + 1;
 349         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 350         pl.clientcolors = 16*cl + cl;*/
 351
 352         float pants, shirt;
 353         pants = _color & 0x0F;
 354         shirt = _color & 0xF0;
 355
 356
 357         if(teamplay) {
 358                 setcolor(pl, 16*pants + pants);
 359         } else {
 360                 setcolor(pl, shirt + pants);
 361         }
 362 }
 363
 364 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 365 {
 366         float _color;
 367
 368         if(t == 4)
 369                 _color = NUM_TEAM_4 - 1;
 370         else if(t == 3)
 371                 _color = NUM_TEAM_3 - 1;
 372         else if(t == 2)
 373                 _color = NUM_TEAM_2 - 1;
 374         else
 375                 _color = NUM_TEAM_1 - 1;
 376
 377         SetPlayerColors(pl,_color);
 378
 379         if(t != s) {
 380                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
 381
 382                 if(!noprint)
 383                 bprint(pl.netname, "^7 has changed from ", Team_NumberToColoredFullName(s), "^7 to ", Team_NumberToColoredFullName(t), "\n");
 384         }
 385
 386 }
 387
 388 // set c1...c4 to show what teams are allowed
 389 void CheckAllowedTeams (entity for_whom)
 390 {
 391         float dm;
 392         entity head;
 393         string teament_name;
 394
 395         c1 = c2 = c3 = c4 = -1;
 396         cb1 = cb2 = cb3 = cb4 = 0;
 397
 398         teament_name = string_null;
 399         if(g_onslaught)
 400         {
 401                 // onslaught is special
 402                 head = findchain(classname, "onslaught_generator");
 403                 while (head)
 404                 {
 405                         if (head.team == NUM_TEAM_1) c1 = 0;
 406                         if (head.team == NUM_TEAM_2) c2 = 0;
 407                         if (head.team == NUM_TEAM_3) c3 = 0;
 408                         if (head.team == NUM_TEAM_4) c4 = 0;
 409                         head = head.chain;
 410                 }
 411         }
 412         else if(g_domination)
 413                 teament_name = "dom_team";
 414         else if(g_ctf)
 415                 teament_name = "ctf_team";
 416         else if(g_tdm)
 417                 teament_name = "tdm_team";
 418         else if(g_nexball)
 419                 teament_name = "nexball_team";
 420         else if(g_assault)
 421                 c1 = c2 = 0; // Assault always has 2 teams
 422         else
 423         {
 424                 // cover anything else by treating it like tdm with no teams spawned
 425                 if(g_race)
 426                         dm = race_teams;
 427                 else
 428                         dm = 2;
 429
 430                 ret_float = dm;
 431                 MUTATOR_CALLHOOK(GetTeamCount);
 432                 dm = ret_float;
 433
 434                 if(dm >= 4)
 435                         c1 = c2 = c3 = c4 = 0;
 436                 else if(dm >= 3)
 437                         c1 = c2 = c3 = 0;
 438                 else
 439                         c1 = c2 = 0;
 440         }
 441
 442         // find out what teams are allowed if necessary
 443         if(teament_name)
 444         {
 445                 head = find(world, classname, teament_name);
 446                 while(head)
 447                 {
 448                         if(!(g_domination && head.netname == ""))
 449                         {
 450                                 if(head.team == NUM_TEAM_1)
 451                                         c1 = 0;
 452                                 else if(head.team == NUM_TEAM_2)
 453                                         c2 = 0;
 454                                 else if(head.team == NUM_TEAM_3)
 455                                         c3 = 0;
 456                                 else if(head.team == NUM_TEAM_4)
 457                                         c4 = 0;
 458                         }
 459                         head = find(head, classname, teament_name);
 460                 }
 461         }
 462
 463         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 464         if(c3==-1 && c4==-1)
 465         if(autocvar_bot_vs_human && for_whom)
 466         {
 467                 if(autocvar_bot_vs_human > 0)
 468                 {
 469                         // bots are all blue
 470                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 471                                 c1 = c3 = c4 = -1;
 472                         else
 473                                 c2 = -1;
 474                 }
 475                 else
 476                 {
 477                         // bots are all red
 478                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 479                                 c2 = c3 = c4 = -1;
 480                         else
 481                                 c1 = -1;
 482                 }
 483         }
 484
 485         // if player has a forced team, ONLY allow that one
 486         if(self.team_forced == NUM_TEAM_1 && c1 >= 0)
 487                 c2 = c3 = c4 = -1;
 488         else if(self.team_forced == NUM_TEAM_2 && c2 >= 0)
 489                 c1 = c3 = c4 = -1;
 490         else if(self.team_forced == NUM_TEAM_3 && c3 >= 0)
 491                 c1 = c2 = c4 = -1;
 492         else if(self.team_forced == NUM_TEAM_4 && c4 >= 0)
 493                 c1 = c2 = c3 = -1;
 494 }
 495
 496 float PlayerValue(entity p)
 497 {
 498         return 1;
 499         // FIXME: it always returns 1...
 500 }
 501
 502 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 503 // teams that are allowed will now have their player counts stored in c1...c4
 504 void GetTeamCounts(entity ignore)
 505 {
 506         entity head;
 507         float value, bvalue;
 508         // now count how many players are on each team already
 509
 510         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 511         // also remember the lowest-scoring player
 512
 513         FOR_EACH_CLIENT(head)
 514         {
 515                 float t;
 516                 if(head.classname == "player")
 517                         t = head.team;
 518                 else if(head.team_forced > 0)
 519                         t = head.team_forced; // reserve the spot
 520                 else
 521                         continue;
 522                 if(head != ignore)// && head.netname != "")
 523                 {
 524                         value = PlayerValue(head);
 525                         if(clienttype(head) == CLIENTTYPE_BOT)
 526                                 bvalue = value;
 527                         else
 528                                 bvalue = 0;
 529                         if(t == NUM_TEAM_1)
 530                         {
 531                                 if(c1 >= 0)
 532                                 {
 533                                         c1 = c1 + value;
 534                                         cb1 = cb1 + bvalue;
 535                                 }
 536                         }
 537                         if(t == NUM_TEAM_2)
 538                         {
 539                                 if(c2 >= 0)
 540                                 {
 541                                         c2 = c2 + value;
 542                                         cb2 = cb2 + bvalue;
 543                                 }
 544                         }
 545                         if(t == NUM_TEAM_3)
 546                         {
 547                                 if(c3 >= 0)
 548                                 {
 549                                         c3 = c3 + value;
 550                                         cb3 = cb3 + bvalue;
 551                                 }
 552                         }
 553                         if(t == NUM_TEAM_4)
 554                         {
 555                                 if(c4 >= 0)
 556                                 {
 557                                         c4 = c4 + value;
 558                                         cb4 = cb4 + bvalue;
 559                                 }
 560                         }
 561                 }
 562         }
 563
 564         // if the player who has a forced team has not joined yet, reserve the spot
 565         if(autocvar_g_campaign)
 566         {
 567                 switch(autocvar_g_campaign_forceteam)
 568                 {
 569                         case 1: if(c1 == cb1) ++c1; break;
 570                         case 2: if(c2 == cb2) ++c2; break;
 571                         case 3: if(c3 == cb3) ++c3; break;
 572                         case 4: if(c4 == cb4) ++c4; break;
 573                 }
 574         }
 575 }
 576
 577 float TeamSmallerEqThanTeam(float ta, float tb, entity e)
 578 {
 579         // we assume that CheckAllowedTeams and GetTeamCounts have already been called
 580         float f;
 581         float ca = -1, cb = -1, cba = 0, cbb = 0, sa = 0, sb = 0;
 582
 583         switch(ta)
 584         {
 585                 case 1: ca = c1; cba = cb1; sa = team1_score; break;
 586                 case 2: ca = c2; cba = cb2; sa = team2_score; break;
 587                 case 3: ca = c3; cba = cb3; sa = team3_score; break;
 588                 case 4: ca = c4; cba = cb4; sa = team4_score; break;
 589         }
 590         switch(tb)
 591         {
 592                 case 1: cb = c1; cbb = cb1; sb = team1_score; break;
 593                 case 2: cb = c2; cbb = cb2; sb = team2_score; break;
 594                 case 3: cb = c3; cbb = cb3; sb = team3_score; break;
 595                 case 4: cb = c4; cbb = cb4; sb = team4_score; break;
 596         }
 597
 598         // invalid
 599         if(ca < 0 || cb < 0)
 600                 return FALSE;
 601
 602         // equal
 603         if(ta == tb)
 604                 return TRUE;
 605
 606         if(clienttype(e) == CLIENTTYPE_REAL)
 607         {
 608                 if(bots_would_leave)
 609                 {
 610                         ca -= cba * 0.999;
 611                         cb -= cbb * 0.999;
 612                 }
 613         }
 614
 615         // keep teams alive (teams of size 0 always count as smaller, ignoring score)
 616         if(ca < 1)
 617                 if(cb >= 1)
 618                         return TRUE;
 619         if(ca >= 1)
 620                 if(cb < 1)
 621                         return FALSE;
 622
 623         // first, normalize
 624         f = max(ca, cb, 1);
 625         ca /= f;
 626         cb /= f;
 627         f = max(sa, sb, 1);
 628         sa /= f;
 629         sb /= f;
 630
 631         // the more we're at the end of the match, the more take scores into account
 632         f = bound(0, game_completion_ratio * autocvar_g_balance_teams_scorefactor, 1);
 633         ca += (sa - ca) * f;
 634         cb += (sb - cb) * f;
 635
 636         return ca <= cb;
 637 }
 638
 639 // returns # of smallest team (1, 2, 3, 4)
 640 // NOTE: Assumes CheckAllowedTeams has already been called!
 641 float FindSmallestTeam(entity pl, float ignore_pl)
 642 {
 643         float totalteams, t;
 644         totalteams = 0;
 645
 646         // find out what teams are available
 647         //CheckAllowedTeams();
 648
 649         // make sure there are at least 2 teams to join
 650         if(c1 >= 0)
 651                 totalteams = totalteams + 1;
 652         if(c2 >= 0)
 653                 totalteams = totalteams + 1;
 654         if(c3 >= 0)
 655                 totalteams = totalteams + 1;
 656         if(c4 >= 0)
 657                 totalteams = totalteams + 1;
 658
 659         if((autocvar_bot_vs_human || pl.team_forced > 0) && totalteams == 1)
 660                 totalteams += 1;
 661
 662         if(totalteams <= 1)
 663         {
 664                 if(autocvar_g_campaign && pl && clienttype(pl) == CLIENTTYPE_REAL)
 665                         return 1; // special case for campaign and player joining
 666                 else if(g_domination)
 667                         error("Too few teams available for domination\n");
 668                 else if(g_ctf)
 669                         error("Too few teams available for ctf\n");
 670                 else if(g_keyhunt)
 671                         error("Too few teams available for key hunt\n");
 672                 else if(g_freezetag)
 673                         error("Too few teams available for freeze tag\n");
 674                 else
 675                         error("Too few teams available for team deathmatch\n");
 676         }
 677
 678         // count how many players are in each team
 679         if(ignore_pl)
 680                 GetTeamCounts(pl);
 681         else
 682                 GetTeamCounts(world);
 683
 684         RandomSelection_Init();
 685
 686         t = 1;
 687         if(TeamSmallerEqThanTeam(2, t, pl))
 688                 t = 2;
 689         if(TeamSmallerEqThanTeam(3, t, pl))
 690                 t = 3;
 691         if(TeamSmallerEqThanTeam(4, t, pl))
 692                 t = 4;
 693
 694         // now t is the minimum, or A minimum!
 695         if(t == 1 || TeamSmallerEqThanTeam(1, t, pl))
 696                 RandomSelection_Add(world, 1, string_null, 1, 1);
 697         if(t == 2 || TeamSmallerEqThanTeam(2, t, pl))
 698                 RandomSelection_Add(world, 2, string_null, 1, 1);
 699         if(t == 3 || TeamSmallerEqThanTeam(3, t, pl))
 700                 RandomSelection_Add(world, 3, string_null, 1, 1);
 701         if(t == 4 || TeamSmallerEqThanTeam(4, t, pl))
 702                 RandomSelection_Add(world, 4, string_null, 1, 1);
 703
 704         return RandomSelection_chosen_float;
 705 }
 706
 707 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 708 {
 709         float smallest, selectedteam;
 710
 711         // don't join a team if we're not playing a team game
 712         if(!teamplay)
 713                 return 0;
 714
 715         // find out what teams are available
 716         CheckAllowedTeams(pl);
 717
 718         // if we don't care what team he ends up on, put him on whatever team he entered as.
 719         // if he's not on a valid team, then let other code put him on the smallest team
 720         if(!forcebestteam)
 721         {
 722                 if(     c1 >= 0 && pl.team == NUM_TEAM_1)
 723                         selectedteam = pl.team;
 724                 else if(c2 >= 0 && pl.team == NUM_TEAM_2)
 725                         selectedteam = pl.team;
 726                 else if(c3 >= 0 && pl.team == NUM_TEAM_3)
 727                         selectedteam = pl.team;
 728                 else if(c4 >= 0 && pl.team == NUM_TEAM_4)
 729                         selectedteam = pl.team;
 730                 else
 731                         selectedteam = -1;
 732
 733                 if(selectedteam > 0)
 734                 {
 735                         if(!only_return_best)
 736                         {
 737                                 SetPlayerColors(pl, selectedteam - 1);
 738
 739                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
 740                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
 741                                 LogTeamchange(pl.playerid, pl.team, 99);
 742                         }
 743                         return selectedteam;
 744                 }
 745                 // otherwise end up on the smallest team (handled below)
 746         }
 747
 748         smallest = FindSmallestTeam(pl, TRUE);
 749
 750         if(!only_return_best && !pl.bot_forced_team)
 751         {
 752                 TeamchangeFrags(self);
 753                 if(smallest == 1)
 754                 {
 755                         SetPlayerColors(pl, NUM_TEAM_1 - 1);
 756                 }
 757                 else if(smallest == 2)
 758                 {
 759                         SetPlayerColors(pl, NUM_TEAM_2 - 1);
 760                 }
 761                 else if(smallest == 3)
 762                 {
 763                         SetPlayerColors(pl, NUM_TEAM_3 - 1);
 764                 }
 765                 else if(smallest == 4)
 766                 {
 767                         SetPlayerColors(pl, NUM_TEAM_4 - 1);
 768                 }
 769                 else
 770                 {
 771                         error("smallest team: invalid team\n");
 772                 }
 773
 774                 LogTeamchange(pl.playerid, pl.team, 2); // log auto join
 775
 776                 if(pl.deadflag == DEAD_NO)
 777                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 778         }
 779
 780         return smallest;
 781 }
 782
 783 //void() ctf_playerchanged;
 784 void SV_ChangeTeam(float _color)
 785 {
 786         float scolor, dcolor, steam, dteam; //, dbotcount, scount, dcount;
 787
 788         // in normal deathmatch we can just apply the color and we're done
 789         if(!teamplay) {
 790                 SetPlayerColors(self, _color);
 791                 return;
 792         }
 793
 794         scolor = self.clientcolors & 0x0F;
 795         dcolor = _color & 0x0F;
 796
 797         if(scolor == NUM_TEAM_1 - 1)
 798                 steam = 1;
 799         else if(scolor == NUM_TEAM_2 - 1)
 800                 steam = 2;
 801         else if(scolor == NUM_TEAM_3 - 1)
 802                 steam = 3;
 803         else // if(scolor == NUM_TEAM_4 - 1)
 804                 steam = 4;
 805         if(dcolor == NUM_TEAM_1 - 1)
 806                 dteam = 1;
 807         else if(dcolor == NUM_TEAM_2 - 1)
 808                 dteam = 2;
 809         else if(dcolor == NUM_TEAM_3 - 1)
 810                 dteam = 3;
 811         else // if(dcolor == NUM_TEAM_4 - 1)
 812                 dteam = 4;
 813
 814         CheckAllowedTeams(self);
 815
 816         if(dteam == 1 && c1 < 0) dteam = 4;
 817         if(dteam == 4 && c4 < 0) dteam = 3;
 818         if(dteam == 3 && c3 < 0) dteam = 2;
 819         if(dteam == 2 && c2 < 0) dteam = 1;
 820
 821         // not changing teams
 822         if(scolor == dcolor)
 823         {
 824                 //bprint("same team change\n");
 825                 SetPlayerTeam(self, dteam, steam, TRUE);
 826                 return;
 827         }
 828
 829         if((autocvar_g_campaign) || (autocvar_g_changeteam_banned && self.wasplayer)) {
 830                 sprint(self, "Team changes not allowed\n");
 831                 return; // changing teams is not allowed
 832         }
 833
 834         // autocvar_g_balance_teams_prevent_imbalance only makes sense if autocvar_g_balance_teams is on, as it makes the team selection dialog pointless
 835         if(autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 836         {
 837                 GetTeamCounts(self);
 838                 if(!TeamSmallerEqThanTeam(dteam, steam, self))
 839                 {
 840                         sprint(self, "Cannot change to a larger/better/shinier team\n");
 841                         return;
 842                 }
 843         }
 844
 845 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
 846
 847         if(self.classname == "player" && steam != dteam)
 848         {
 849                 // reduce frags during a team change
 850                 TeamchangeFrags(self);
 851         }
 852
 853         SetPlayerTeam(self, dteam, steam, FALSE);
 854
 855         if(self.classname == "player" && steam != dteam)
 856         {
 857                 // kill player when changing teams
 858                 if(self.deadflag == DEAD_NO)
 859                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
 860         }
 861 }
 862
 863 void ShufflePlayerOutOfTeam (float source_team)
 864 {
 865         float smallestteam, smallestteam_count, steam;
 866         float lowest_bot_score, lowest_player_score;
 867         entity head, lowest_bot, lowest_player, selected;
 868
 869         smallestteam = 0;
 870         smallestteam_count = 999999999;
 871
 872         if(c1 >= 0 && c1 < smallestteam_count)
 873         {
 874                 smallestteam = 1;
 875                 smallestteam_count = c1;
 876         }
 877         if(c2 >= 0 && c2 < smallestteam_count)
 878         {
 879                 smallestteam = 2;
 880                 smallestteam_count = c2;
 881         }
 882         if(c3 >= 0 && c3 < smallestteam_count)
 883         {
 884                 smallestteam = 3;
 885                 smallestteam_count = c3;
 886         }
 887         if(c4 >= 0 && c4 < smallestteam_count)
 888         {
 889                 smallestteam = 4;
 890                 smallestteam_count = c4;
 891         }
 892
 893         if(!smallestteam)
 894         {
 895                 bprint("warning: no smallest team\n");
 896                 return;
 897         }
 898
 899         if(source_team == 1)
 900                 steam = NUM_TEAM_1;
 901         else if(source_team == 2)
 902                 steam = NUM_TEAM_2;
 903         else if(source_team == 3)
 904                 steam = NUM_TEAM_3;
 905         else // if(source_team == 4)
 906                 steam = NUM_TEAM_4;
 907
 908         lowest_bot = world;
 909         lowest_bot_score = 999999999;
 910         lowest_player = world;
 911         lowest_player_score = 999999999;
 912
 913         // find the lowest-scoring player & bot of that team
 914         FOR_EACH_PLAYER(head)
 915         {
 916                 if(head.team == steam)
 917                 {
 918                         if(head.isbot)
 919                         {
 920                                 if(head.totalfrags < lowest_bot_score)
 921                                 {
 922                                         lowest_bot = head;
 923                                         lowest_bot_score = head.totalfrags;
 924                                 }
 925                         }
 926                         else
 927                         {
 928                                 if(head.totalfrags < lowest_player_score)
 929                                 {
 930                                         lowest_player = head;
 931                                         lowest_player_score = head.totalfrags;
 932                                 }
 933                         }
 934                 }
 935         }
 936
 937         // prefers to move a bot...
 938         if(lowest_bot != world)
 939                 selected = lowest_bot;
 940         // but it will move a player if it has to
 941         else
 942                 selected = lowest_player;
 943         // don't do anything if it couldn't find anyone
 944         if(!selected)
 945         {
 946                 bprint("warning: couldn't find a player to move from team\n");
 947                 return;
 948         }
 949
 950         // smallest team gains a member
 951         if(smallestteam == 1)
 952         {
 953                 c1 = c1 + 1;
 954         }
 955         else if(smallestteam == 2)
 956         {
 957                 c2 = c2 + 1;
 958         }
 959         else if(smallestteam == 3)
 960         {
 961                 c3 = c3 + 1;
 962         }
 963         else if(smallestteam == 4)
 964         {
 965                 c4 = c4 + 1;
 966         }
 967         else
 968         {
 969                 bprint("warning: destination team invalid\n");
 970                 return;
 971         }
 972         // source team loses a member
 973         if(source_team == 1)
 974         {
 975                 c1 = c1 + 1;
 976         }
 977         else if(source_team == 2)
 978         {
 979                 c2 = c2 + 2;
 980         }
 981         else if(source_team == 3)
 982         {
 983                 c3 = c3 + 3;
 984         }
 985         else if(source_team == 4)
 986         {
 987                 c4 = c4 + 4;
 988         }
 989         else
 990         {
 991                 bprint("warning: source team invalid\n");
 992                 return;
 993         }
 994
 995         // move the player to the new team
 996         TeamchangeFrags(selected);
 997         SetPlayerTeam(selected, smallestteam, source_team, FALSE);
 998
 999         if(selected.deadflag == DEAD_NO)
1000                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
1001         centerprint(selected, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", Team_ColoredFullName(selected.team)));
1002 }
1003
1004 // code from here on is just to support maps that don't have team entities
1005 void tdm_spawnteam (string teamname, float teamcolor)
1006 {
1007         entity e;
1008         e = spawn();
1009         e.classname = "tdm_team";
1010         e.netname = teamname;
1011         e.cnt = teamcolor;
1012         e.team = e.cnt + 1;
1013 }
1014
1015 // spawn some default teams if the map is not set up for tdm
1016 void tdm_spawnteams()
1017 {
1018         float numteams;
1019
1020         numteams = autocvar_g_tdm_teams_override;
1021         if(numteams < 2)
1022                 numteams = autocvar_g_tdm_teams;
1023         numteams = bound(2, numteams, 4);
1024
1025         tdm_spawnteam("Red", NUM_TEAM_1-1);
1026         tdm_spawnteam("Blue", NUM_TEAM_2-1);
1027         if(numteams >= 3)
1028                 tdm_spawnteam("Yellow", NUM_TEAM_3-1);
1029         if(numteams >= 4)
1030                 tdm_spawnteam("Pink", NUM_TEAM_4-1);
1031 }
1032
1033 void tdm_delayedinit()
1034 {
1035         // if no teams are found, spawn defaults
1036         if (find(world, classname, "tdm_team") == world)
1037                 tdm_spawnteams();
1038 }
1039
1040 void tdm_init()
1041 {
1042         InitializeEntity(world, tdm_delayedinit, INITPRIO_GAMETYPE);
1043 }