qcsrc/server/t_items.qc

   1 #include "t_items.qh"
   2
   3 #if defined(SVQC)
   4     #include "_all.qh"
   5
   6     #include "g_subs.qh"
   7     #include "waypointsprites.qh"
   8
   9     #include "bot/bot.qh"
  10     #include "bot/waypoints.qh"
  11
  12     #include "mutators/mutators_include.qh"
  13
  14     #include "weapons/common.qh"
  15     #include "weapons/selection.qh"
  16     #include "weapons/weaponsystem.qh"
  17
  18     #include "../common/constants.qh"
  19     #include "../common/deathtypes.qh"
  20     #include "../common/notifications.qh"
  21     #include "../common/util.qh"
  22
  23     #include "../common/monsters/monsters.qh"
  24
  25     #include "../common/weapons/weapons.qh"
  26
  27     #include "../warpzonelib/util_server.qh"
  28 #endif
  29
  30 #ifdef CSQC
  31 void ItemDraw()
  32 {
  33     if(self.gravity)
  34     {
  35         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  36         if(self.move_flags & FL_ONGROUND)
  37         { // For some reason move_avelocity gets set to '0 0 0' here ...
  38             self.oldorigin = self.origin;
  39             self.gravity = 0;
  40
  41             if(autocvar_cl_animate_items)
  42             { // ... so reset it if animations are requested.
  43                 if(self.ItemStatus & ITS_ANIMATE1)
  44                     self.move_avelocity = '0 180 0';
  45
  46                 if(self.ItemStatus & ITS_ANIMATE2)
  47                     self.move_avelocity = '0 -90 0';
  48             }
  49         }
  50     }
  51     else if (autocvar_cl_animate_items)
  52     {
  53         if(self.ItemStatus & ITS_ANIMATE1)
  54         {
  55             self.angles += self.move_avelocity * frametime;
  56             setorigin(self, '0 0 10' + self.oldorigin + '0 0 8' * sin(time * 2));
  57         }
  58
  59         if(self.ItemStatus & ITS_ANIMATE2)
  60         {
  61             self.angles += self.move_avelocity * frametime;
  62             setorigin(self, '0 0 8' + self.oldorigin + '0 0 4' * sin(time * 3));
  63         }
  64     }
  65 }
  66
  67 void ItemDrawSimple()
  68 {
  69     if(self.gravity)
  70     {
  71         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  72
  73         if(self.move_flags & FL_ONGROUND)
  74             self.gravity = 0;
  75     }
  76 }
  77
  78 void ItemRead(float _IsNew)
  79 {
  80     int sf = ReadByte();
  81
  82     if(sf & ISF_LOCATION)
  83     {
  84         self.origin_x = ReadCoord();
  85         self.origin_y = ReadCoord();
  86         self.origin_z = ReadCoord();
  87         setorigin(self, self.origin);
  88         self.oldorigin = self.origin;
  89     }
  90
  91     if(sf & ISF_ANGLES)
  92     {
  93         self.angles_x = ReadCoord();
  94         self.angles_y = ReadCoord();
  95         self.angles_z = ReadCoord();
  96         self.move_angles = self.angles;
  97     }
  98
  99     if(sf & ISF_SIZE)
 100     {
 101         self.mins_x = ReadCoord();
 102         self.mins_y = ReadCoord();
 103         self.mins_z = ReadCoord();
 104         self.maxs_x = ReadCoord();
 105         self.maxs_y = ReadCoord();
 106         self.maxs_z = ReadCoord();
 107         setsize(self, self.mins, self.maxs);
 108     }
 109
 110     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
 111     {
 112         self.ItemStatus = ReadByte();
 113
 114         if(self.ItemStatus & ITS_AVAILABLE)
 115         {
 116             self.alpha = 1;
 117             self.colormod = self.glowmod = '1 1 1';
 118         }
 119         else
 120         {
 121             if (autocvar_cl_ghost_items_color)
 122             {
 123                 self.alpha = autocvar_cl_ghost_items;
 124                 self.colormod = self.glowmod = autocvar_cl_ghost_items_color;
 125             }
 126             else
 127                 self.alpha = -1;
 128         }
 129
 130         if(autocvar_cl_fullbright_items)
 131             if(self.ItemStatus & ITS_ALLOWFB)
 132                 self.effects |= EF_FULLBRIGHT;
 133
 134         if(self.ItemStatus & ITS_STAYWEP)
 135         {
 136             self.colormod = self.glowmod = autocvar_cl_weapon_stay_color;
 137             self.alpha = autocvar_cl_weapon_stay_alpha;
 138
 139         }
 140
 141         if(self.ItemStatus & ITS_POWERUP)
 142         {
 143             if(self.ItemStatus & ITS_AVAILABLE)
 144                 self.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 145             else
 146                  self.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 147         }
 148     }
 149
 150     if(sf & ISF_MODEL)
 151     {
 152         self.drawmask  = MASK_NORMAL;
 153         self.movetype  = MOVETYPE_TOSS;
 154         self.draw       = ItemDraw;
 155
 156         if(self.mdl)
 157             strunzone(self.mdl);
 158
 159         self.mdl = "";
 160         string _fn = ReadString();
 161
 162         if(autocvar_cl_simple_items && (self.ItemStatus & ITS_ALLOWSI))
 163         {
 164             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 165             self.draw = ItemDrawSimple;
 166
 167
 168
 169             if(fexists(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix)))
 170                 self.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix));
 171             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix)))
 172                 self.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix));
 173             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix)))
 174                 self.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix));
 175             else if(fexists(sprintf("%s%s.obj", _fn2, autocvar_cl_simpleitems_postfix)))
 176                 self.mdl = strzone(sprintf("%s%s.obj", _fn2, autocvar_cl_simpleitems_postfix));
 177             else
 178             {
 179                 self.draw = ItemDraw;
 180                 dprint("Simple item requested for ", _fn, " but no model exsist for it\n");
 181             }
 182         }
 183
 184         if(self.draw != ItemDrawSimple)
 185             self.mdl = strzone(_fn);
 186
 187
 188         if(self.mdl == "")
 189             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, " tell tZork aboute this!\n");
 190
 191         precache_model(self.mdl);
 192         setmodel(self, self.mdl);
 193     }
 194
 195     if(sf & ISF_COLORMAP)
 196         self.colormap = ReadShort();
 197
 198     if(sf & ISF_DROP)
 199     {
 200         self.gravity = 1;
 201         //self.move_angles = '0 0 0';
 202         self.move_movetype = MOVETYPE_TOSS;
 203         self.move_velocity_x = ReadCoord();
 204         self.move_velocity_y = ReadCoord();
 205         self.move_velocity_z = ReadCoord();
 206         self.velocity = self.move_velocity;
 207         self.move_origin = self.oldorigin;
 208
 209         if(!self.move_time)
 210         {
 211             self.move_time = time;
 212             self.spawntime = time;
 213         }
 214         else
 215             self.move_time = max(self.move_time, time);
 216     }
 217
 218     if(autocvar_cl_animate_items)
 219     {
 220         if(self.ItemStatus & ITS_ANIMATE1)
 221             self.move_avelocity = '0 180 0';
 222
 223         if(self.ItemStatus & ITS_ANIMATE2)
 224             self.move_avelocity = '0 -90 0';
 225     }
 226 }
 227
 228 #endif
 229
 230 #ifdef SVQC
 231 bool ItemSend(entity to, int sf)
 232 {
 233     if(self.gravity)
 234         sf |= ISF_DROP;
 235     else
 236         sf &= ~ISF_DROP;
 237
 238         WriteByte(MSG_ENTITY, ENT_CLIENT_ITEM);
 239         WriteByte(MSG_ENTITY, sf);
 240
 241         //WriteByte(MSG_ENTITY, self.cnt);
 242     if(sf & ISF_LOCATION)
 243     {
 244         WriteCoord(MSG_ENTITY, self.origin.x);
 245         WriteCoord(MSG_ENTITY, self.origin.y);
 246         WriteCoord(MSG_ENTITY, self.origin.z);
 247     }
 248
 249     if(sf & ISF_ANGLES)
 250     {
 251         WriteCoord(MSG_ENTITY, self.angles.x);
 252         WriteCoord(MSG_ENTITY, self.angles.y);
 253         WriteCoord(MSG_ENTITY, self.angles.z);
 254     }
 255
 256     if(sf & ISF_SIZE)
 257     {
 258         WriteCoord(MSG_ENTITY, self.mins.x);
 259         WriteCoord(MSG_ENTITY, self.mins.y);
 260         WriteCoord(MSG_ENTITY, self.mins.z);
 261         WriteCoord(MSG_ENTITY, self.maxs.x);
 262         WriteCoord(MSG_ENTITY, self.maxs.y);
 263         WriteCoord(MSG_ENTITY, self.maxs.z);
 264     }
 265
 266     if(sf & ISF_STATUS)
 267         WriteByte(MSG_ENTITY, self.ItemStatus);
 268
 269     if(sf & ISF_MODEL)
 270     {
 271
 272         if(self.mdl == "")
 273             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, "exspect a crash just aboute now\n");
 274
 275         WriteString(MSG_ENTITY, self.mdl);
 276     }
 277
 278
 279     if(sf & ISF_COLORMAP)
 280         WriteShort(MSG_ENTITY, self.colormap);
 281
 282     if(sf & ISF_DROP)
 283     {
 284         WriteCoord(MSG_ENTITY, self.velocity.x);
 285         WriteCoord(MSG_ENTITY, self.velocity.y);
 286         WriteCoord(MSG_ENTITY, self.velocity.z);
 287     }
 288
 289     return true;
 290 }
 291
 292 void ItemUpdate(entity item)
 293 {
 294         item.SendFlags |= ISF_LOCATION;
 295 }
 296
 297 float have_pickup_item(void)
 298 {
 299         if(self.flags & FL_POWERUP)
 300         {
 301                 if(autocvar_g_powerups > 0)
 302                         return true;
 303                 if(autocvar_g_powerups == 0)
 304                         return false;
 305         }
 306         else
 307         {
 308                 if(autocvar_g_pickup_items > 0)
 309                         return true;
 310                 if(autocvar_g_pickup_items == 0)
 311                         return false;
 312                 if(g_weaponarena)
 313                         if(self.weapons || (self.items & IT_AMMO)) // no item or ammo pickups in weaponarena
 314                                 return false;
 315         }
 316         return true;
 317 }
 318
 319 /*
 320 float Item_Customize()
 321 {
 322         if(self.spawnshieldtime)
 323                 return true;
 324         if(self.weapons & ~other.weapons)
 325         {
 326                 self.colormod = '0 0 0';
 327                 self.glowmod = self.colormod;
 328                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 329                 return true;
 330         }
 331         else
 332         {
 333                 if(g_ghost_items)
 334                 {
 335                         self.colormod = stov(autocvar_g_ghost_items_color);
 336                         self.glowmod = self.colormod;
 337                         self.alpha = g_ghost_items;
 338                         return true;
 339                 }
 340                 else
 341                         return false;
 342         }
 343 }
 344 */
 345
 346 void Item_Show (entity e, float mode)
 347 {
 348         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 349         e.ItemStatus &= ~ITS_STAYWEP;
 350         if (mode > 0)
 351         {
 352                 // make the item look normal, and be touchable
 353                 e.model = e.mdl;
 354                 e.solid = SOLID_TRIGGER;
 355                 e.spawnshieldtime = 1;
 356                 e.ItemStatus |= ITS_AVAILABLE;
 357         }
 358         else if (mode < 0)
 359         {
 360                 // hide the item completely
 361                 e.model = string_null;
 362                 e.solid = SOLID_NOT;
 363                 e.spawnshieldtime = 1;
 364                 e.ItemStatus &= ~ITS_AVAILABLE;
 365         }
 366         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 367         {
 368                 // make the item translucent and not touchable
 369                 e.model = e.mdl;
 370                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 371                 e.effects |= EF_STARDUST;
 372                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 373                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 374         }
 375         else
 376         {
 377                 //setmodel(e, "null");
 378                 e.solid = SOLID_NOT;
 379                 e.colormod = '0 0 0';
 380                 e.glowmod = e.colormod;
 381                 e.spawnshieldtime = 1;
 382                 e.ItemStatus &= ~ITS_AVAILABLE;
 383         }
 384
 385         if (e.items & IT_STRENGTH || e.items & IT_INVINCIBLE)
 386             e.ItemStatus |= ITS_POWERUP;
 387
 388         if (autocvar_g_nodepthtestitems)
 389                 e.effects |= EF_NODEPTHTEST;
 390
 391
 392     if (autocvar_g_fullbrightitems)
 393                 e.ItemStatus |= ITS_ALLOWFB;
 394
 395         if (autocvar_sv_simple_items)
 396         e.ItemStatus |= ITS_ALLOWSI;
 397
 398         // relink entity (because solid may have changed)
 399         setorigin(e, e.origin);
 400     e.SendFlags |= ISF_STATUS;
 401 }
 402
 403 void Item_Think()
 404 {
 405         self.nextthink = time;
 406         if(self.origin != self.oldorigin)
 407         {
 408                 self.oldorigin = self.origin;
 409                 ItemUpdate(self);
 410         }
 411 }
 412
 413 float it_armor_large_time;
 414 float it_health_mega_time;
 415 float it_invisible_time;
 416 float it_speed_time;
 417 float it_extralife_time;
 418 float it_strength_time;
 419 float it_shield_time;
 420 float it_fuelregen_time;
 421 float it_jetpack_time;
 422 float it_superweapons_time;
 423
 424 void Item_ItemsTime_Init()
 425 {
 426         it_armor_large_time = -1;
 427         it_health_mega_time = -1;
 428         it_invisible_time = -1;
 429         it_speed_time = -1;
 430         it_extralife_time = -1;
 431         it_strength_time = -1;
 432         it_shield_time = -1;
 433         it_fuelregen_time = -1;
 434         it_jetpack_time = -1;
 435         it_superweapons_time = -1;
 436 }
 437 void Item_ItemsTime_Reset()
 438 {
 439         it_armor_large_time = (it_armor_large_time == -1) ? -1 : 0;
 440         it_health_mega_time = (it_health_mega_time == -1) ? -1 : 0;
 441         it_invisible_time   = (it_invisible_time   == -1) ? -1 : 0;
 442         it_speed_time       = (it_speed_time       == -1) ? -1 : 0;
 443         it_extralife_time   = (it_extralife_time   == -1) ? -1 : 0;
 444         it_strength_time    = (it_strength_time    == -1) ? -1 : 0;
 445         it_shield_time      = (it_shield_time      == -1) ? -1 : 0;
 446         it_fuelregen_time   = (it_fuelregen_time   == -1) ? -1 : 0;
 447         it_jetpack_time     = (it_jetpack_time     == -1) ? -1 : 0;
 448         it_superweapons_time= (it_superweapons_time== -1) ? -1 : 0;
 449 }
 450 void Item_ItemsTime_ResetForPlayer(entity e)
 451 {
 452         e.item_armor_large_time = (it_armor_large_time == -1) ? -1 : 0;
 453         e.item_health_mega_time = (it_health_mega_time == -1) ? -1 : 0;
 454         e.item_invisible_time   = (it_invisible_time   == -1) ? -1 : 0;
 455         e.item_speed_time       = (it_speed_time       == -1) ? -1 : 0;
 456         e.item_extralife_time   = (it_extralife_time   == -1) ? -1 : 0;
 457         e.item_strength_time    = (it_strength_time    == -1) ? -1 : 0;
 458         e.item_shield_time      = (it_shield_time      == -1) ? -1 : 0;
 459         e.item_fuelregen_time   = (it_fuelregen_time   == -1) ? -1 : 0;
 460         e.item_jetpack_time     = (it_jetpack_time     == -1) ? -1 : 0;
 461         e.item_superweapons_time= (it_superweapons_time== -1) ? -1 : 0;
 462 }
 463 void Item_ItemsTime_Get(entity e)
 464 {
 465         e.item_armor_large_time = it_armor_large_time;
 466         e.item_health_mega_time = it_health_mega_time;
 467         e.item_invisible_time = it_invisible_time;
 468         e.item_speed_time = it_speed_time;
 469         e.item_extralife_time = it_extralife_time;
 470         e.item_strength_time = it_strength_time;
 471         e.item_shield_time = it_shield_time;
 472         e.item_fuelregen_time = it_fuelregen_time;
 473         e.item_jetpack_time = it_jetpack_time;
 474         e.item_superweapons_time = it_superweapons_time;
 475 }
 476 float Item_ItemsTime_UpdateTime_Check(float item_time, float t)
 477 {
 478         if(t == 0 && item_time == -1)
 479                 return TRUE;
 480         if(time < t && (item_time <= time || t < item_time))
 481                 return TRUE;
 482         return FALSE;
 483 }
 484 void Item_ItemsTime_UpdateTime(entity e, float t)
 485 {
 486         if(g_instagib)
 487         {
 488                 switch(e.items)
 489                 {
 490                         case IT_STRENGTH://"item-invis"
 491                                 if(Item_ItemsTime_UpdateTime_Check(it_invisible_time, t))
 492                                         it_invisible_time = t;
 493                                 break;
 494                         case IT_NAILS://"item-extralife"
 495                                 if(Item_ItemsTime_UpdateTime_Check(it_extralife_time, t))
 496                                         it_extralife_time = t;
 497                                 break;
 498                         case IT_INVINCIBLE://"item-speed"
 499                                 if(Item_ItemsTime_UpdateTime_Check(it_speed_time, t))
 500                                         it_speed_time = t;
 501                                 break;
 502                 }
 503         }
 504         else
 505         {
 506                 switch(e.items)
 507                 {
 508                         case IT_HEALTH:
 509                                 if(!autocvar_sv_itemstime)
 510                                         break;
 511                                 //if (e.classname == "item_health_mega")
 512                                         if(Item_ItemsTime_UpdateTime_Check(it_health_mega_time, t))
 513                                                 it_health_mega_time = t;
 514                                 break;
 515                         case IT_ARMOR:
 516                                 if(!autocvar_sv_itemstime)
 517                                         break;
 518                                 if (e.classname == "item_armor_large")
 519                                         if(Item_ItemsTime_UpdateTime_Check(it_armor_large_time, t))
 520                                                 it_armor_large_time = t;
 521                                 break;
 522                         case IT_STRENGTH://"item-strength"
 523                                 if(Item_ItemsTime_UpdateTime_Check(it_strength_time, t))
 524                                         it_strength_time = t;
 525                                 break;
 526                         case IT_INVINCIBLE://"item-shield"
 527                                 if(Item_ItemsTime_UpdateTime_Check(it_shield_time, t))
 528                                         it_shield_time = t;
 529                                 break;
 530                         default:
 531                                 if(e.weapons & WEPSET_SUPERWEAPONS)
 532                                         if(Item_ItemsTime_UpdateTime_Check(it_superweapons_time, t))
 533                                                         it_superweapons_time = t;
 534                 }
 535         }
 536         switch(e.items)
 537         {
 538                 case IT_FUEL_REGEN://"item-fuelregen"
 539                         if(Item_ItemsTime_UpdateTime_Check(it_fuelregen_time, t))
 540                                 it_fuelregen_time = t;
 541                         break;
 542                 case IT_JETPACK://"item-jetpack"
 543                         if(Item_ItemsTime_UpdateTime_Check(it_jetpack_time, t))
 544                                 it_jetpack_time = t;
 545                         break;
 546         }
 547 }
 548 void Item_ItemsTime_GetForAll()
 549 {
 550         entity e;
 551         if(warmup_stage)
 552         {
 553                 FOR_EACH_REALCLIENT(e)
 554                         Item_ItemsTime_Get(e);
 555         }
 556         else
 557         {
 558                 FOR_EACH_REALCLIENT(e)
 559                 {
 560                         if (e.classname != "player")
 561                                 Item_ItemsTime_Get(e);
 562                 }
 563         }
 564 }
 565
 566 void Item_Respawn (void)
 567 {
 568         Item_Show(self, 1);
 569         // this is ugly...
 570         if(self.items == IT_STRENGTH)
 571                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTEN_NORM);    // play respawn sound
 572         else if(self.items == IT_INVINCIBLE)
 573                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTEN_NORM);      // play respawn sound
 574         else
 575                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTEN_NORM); // play respawn sound
 576         setorigin (self, self.origin);
 577
 578         if(self.flags & FL_POWERUP || self.classname == "item_armor_large" || self.items == IT_HEALTH || (self.weapons & WEPSET_SUPERWEAPONS))
 579         {
 580                 Item_ItemsTime_UpdateTime(self, 0);
 581                 Item_ItemsTime_GetForAll();
 582         }
 583
 584         self.think = Item_Think;
 585         self.nextthink = time;
 586
 587         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 588         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 589 }
 590
 591 void Item_RespawnCountdown (void)
 592 {
 593         if(self.count >= ITEM_RESPAWN_TICKS)
 594         {
 595                 if(self.waypointsprite_attached)
 596                         WaypointSprite_Kill(self.waypointsprite_attached);
 597                 Item_Respawn();
 598         }
 599         else
 600         {
 601                 self.nextthink = time + 1;
 602                 self.count += 1;
 603                 if(self.count == 1)
 604                 {
 605                         string name;
 606                         vector rgb = '1 0 1';
 607                         name = string_null;
 608                         switch(self.items)
 609                         {
 610                                 case IT_FUEL_REGEN: name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 611                                 case IT_JETPACK:    name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 612                                 case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 613                                 case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 614                                 case IT_HEALTH:
 615                                         //if (self.classname == "item_health_mega")
 616                                                 {name = "item_health_mega"; rgb = '1 0 0';}
 617                                         break;
 618                                 case IT_ARMOR:
 619                                         if (self.classname == "item_armor_large")
 620                                                 {name = "item_armor_large"; rgb = '0 1 0';}
 621                                         break;
 622                         }
 623                         item_name = name;
 624                         item_color = rgb;
 625                         MUTATOR_CALLHOOK(Item_RespawnCountdown);
 626                         name = item_name;
 627                         rgb = item_color;
 628                         if(self.flags & FL_WEAPON)
 629                         {
 630                                 entity wi = get_weaponinfo(self.weapon);
 631                                 if(wi)
 632                                 {
 633                                         name = wi.wpmodel;
 634                                         rgb = '1 0 0';
 635                                 }
 636                         }
 637                         if(name)
 638                         {
 639                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, true, RADARICON_POWERUP, rgb);
 640                                 if(self.waypointsprite_attached)
 641                                 {
 642                                         if (self.items == IT_HEALTH || self.items == IT_ARMOR)
 643                                                 WaypointSprite_UpdateRule(self.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 644                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 645                                 }
 646                         }
 647                         else
 648                         {
 649                                 print("Unknown powerup-marked item is wanting to respawn\n");
 650                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 651                         }
 652                 }
 653                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTEN_NORM);        // play respawn sound
 654                 if(self.waypointsprite_attached)
 655                 {
 656                         WaypointSprite_Ping(self.waypointsprite_attached);
 657                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 658                 }
 659         }
 660 }
 661
 662 void Item_RespawnThink()
 663 {
 664         self.nextthink = time;
 665         if(self.origin != self.oldorigin)
 666         {
 667                 self.oldorigin = self.origin;
 668                 ItemUpdate(self);
 669         }
 670
 671         if(time >= self.wait)
 672                 Item_Respawn();
 673 }
 674
 675 void Item_ScheduleRespawnIn(entity e, float t)
 676 {
 677         if((e.flags & FL_POWERUP) || (e.weapons & WEPSET_SUPERWEAPONS) || e.classname == "item_armor_large" || e.items == IT_HEALTH)
 678         {
 679                 entity head;
 680                 e.think = Item_RespawnCountdown;
 681                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 682                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 683                 e.count = 0;
 684                 if(e.weapons & WEPSET_SUPERWEAPONS)
 685                 {
 686                         for(t = e.scheduledrespawntime, head = world; (head = nextent(head)); )
 687                         {
 688                                 if(e == head)
 689                                         continue;
 690                                 if(clienttype(head) == CLIENTTYPE_NOTACLIENT)
 691                                 if(head.weapons & WEPSET_SUPERWEAPONS)
 692                                 if(head.classname != "weapon_info")
 693                                 {
 694                                         if(head.scheduledrespawntime <= time)
 695                                         {
 696                                                 t = 0;
 697                                                 break;
 698                                         }
 699                                         if(head.scheduledrespawntime < t)
 700                                                 t = head.scheduledrespawntime;
 701                                 }
 702                         }
 703                 }
 704                 else
 705                 {
 706                         for(t = e.scheduledrespawntime, head = world; (head = find(head, classname, e.classname)); )
 707                         {
 708                                 // in instagib .classname is "instagib" for every item
 709                                 if(e == head || (g_instagib && e.items != head.items))
 710                                         continue;
 711                                 if(head.scheduledrespawntime <= time)
 712                                 {
 713                                         t = 0;
 714                                         break;
 715                                 }
 716                                 if(head.scheduledrespawntime < t)
 717                                         t = head.scheduledrespawntime;
 718                         }
 719                 }
 720                 Item_ItemsTime_UpdateTime(e, t);
 721                 Item_ItemsTime_GetForAll();
 722         }
 723         else
 724         {
 725                 e.think = Item_RespawnThink;
 726                 e.nextthink = time;
 727                 e.scheduledrespawntime = time + t;
 728                 e.wait = time + t;
 729         }
 730 }
 731
 732 void Item_ScheduleRespawn(entity e)
 733 {
 734         if(e.respawntime > 0)
 735         {
 736                 Item_Show(e, 0);
 737                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 738         }
 739         else // if respawntime is -1, this item does not respawn
 740                 Item_Show(e, -1);
 741 }
 742
 743 void Item_ScheduleInitialRespawn(entity e)
 744 {
 745         Item_Show(e, 0);
 746         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 747 }
 748
 749 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax, float mode)
 750 {
 751         if (!item.(ammotype))
 752                 return false;
 753
 754         if (item.spawnshieldtime)
 755         {
 756                 if ((player.(ammotype) < ammomax) || item.pickup_anyway)
 757                 {
 758                         player.(ammotype) = bound(player.(ammotype), ammomax, player.(ammotype) + item.(ammotype));
 759                         goto YEAH;
 760                 }
 761         }
 762         else if(g_weapon_stay == 2)
 763         {
 764                 float mi = min(item.(ammotype), ammomax);
 765                 if (player.(ammotype) < mi)
 766                 {
 767                         player.(ammotype) = mi;
 768                         goto YEAH;
 769                 }
 770         }
 771
 772         return false;
 773
 774 :YEAH
 775         switch(mode)
 776         {
 777                 case ITEM_MODE_FUEL:
 778                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 779                         break;
 780                 case ITEM_MODE_HEALTH:
 781                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 782                         break;
 783                 case ITEM_MODE_ARMOR:
 784                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 785                         break;
 786                 default:
 787                         break;
 788         }
 789         return true;
 790 }
 791
 792 float Item_GiveTo(entity item, entity player)
 793 {
 794         float _switchweapon;
 795         float pickedup;
 796         float it;
 797         float i;
 798
 799         // if nothing happens to player, just return without taking the item
 800         pickedup = false;
 801         _switchweapon = false;
 802         // in case the player has autoswitch enabled do the following:
 803         // if the player is using their best weapon before items are given, they
 804         // probably want to switch to an even better weapon after items are given
 805         if (player.autoswitch)
 806         if (player.switchweapon == w_getbestweapon(player))
 807                 _switchweapon = true;
 808
 809         if (!(player.weapons & WepSet_FromWeapon(player.switchweapon)))
 810                 _switchweapon = true;
 811
 812         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 813         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 814         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 815         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 816         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 817         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max, ITEM_MODE_NONE);
 818         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 819         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 820
 821         if (item.flags & FL_WEAPON)
 822         {
 823                 WepSet it;
 824                 it = item.weapons;
 825                 it &= ~player.weapons;
 826
 827                 if (it || (item.spawnshieldtime && item.pickup_anyway))
 828                 {
 829                         pickedup = true;
 830                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 831                         if(it & WepSet_FromWeapon(i))
 832                         {
 833                                 W_DropEvent(WR_PICKUP, player, i, item);
 834                                 W_GiveWeapon(player, i);
 835                         }
 836                 }
 837         }
 838
 839         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 840         {
 841                 pickedup = true;
 842                 player.items |= it;
 843                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 844         }
 845
 846         if (item.strength_finished)
 847         {
 848                 pickedup = true;
 849                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 850         }
 851         if (item.invincible_finished)
 852         {
 853                 pickedup = true;
 854                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 855         }
 856         if (item.superweapons_finished)
 857         {
 858                 pickedup = true;
 859                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 860         }
 861
 862 :skip
 863
 864         // always eat teamed entities
 865         if(item.team)
 866                 pickedup = true;
 867
 868         if (!pickedup)
 869                 return 0;
 870
 871         if (_switchweapon)
 872                 if (player.switchweapon != w_getbestweapon(player))
 873                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 874
 875         return 1;
 876 }
 877
 878 void Item_Touch (void)
 879 {
 880         entity e, head;
 881
 882         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 883         if(self.classname == "droppedweapon")
 884         {
 885                 if (ITEM_TOUCH_NEEDKILL())
 886                 {
 887                         remove(self);
 888                         return;
 889                 }
 890         }
 891
 892         if (!IS_PLAYER(other))
 893                 return;
 894         if (other.frozen)
 895                 return;
 896         if (other.deadflag)
 897                 return;
 898         if (self.solid != SOLID_TRIGGER)
 899                 return;
 900         if (self.owner == other)
 901                 return;
 902         if (time < self.item_spawnshieldtime)
 903                 return;
 904
 905         switch(MUTATOR_CALLHOOK(ItemTouch))
 906         {
 907                 case MUT_ITEMTOUCH_RETURN: { return; }
 908                 case MUT_ITEMTOUCH_PICKUP: { goto pickup; }
 909         }
 910
 911         if (self.classname == "droppedweapon")
 912         {
 913                 self.strength_finished = max(0, self.strength_finished - time);
 914                 self.invincible_finished = max(0, self.invincible_finished - time);
 915                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 916         }
 917
 918         if(!Item_GiveTo(self, other))
 919         {
 920                 if (self.classname == "droppedweapon")
 921                 {
 922                         // undo what we did above
 923                         self.strength_finished += time;
 924                         self.invincible_finished += time;
 925                         self.superweapons_finished += time;
 926                 }
 927                 return;
 928         }
 929
 930         :pickup
 931
 932         other.last_pickup = time;
 933
 934         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 935         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTEN_NORM);
 936
 937         if (self.classname == "droppedweapon")
 938                 remove (self);
 939         else if (!self.spawnshieldtime)
 940                 return;
 941         else
 942         {
 943                 if(self.team)
 944                 {
 945                         RandomSelection_Init();
 946                         for(head = world; (head = findfloat(head, team, self.team)); )
 947                         {
 948                                 if(head.flags & FL_ITEM)
 949                                 {
 950                                         Item_Show(head, -1);
 951                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 952                                 }
 953                         }
 954                         e = RandomSelection_chosen_ent;
 955
 956                 }
 957                 else
 958                         e = self;
 959                 Item_ScheduleRespawn(e);
 960         }
 961 }
 962
 963 void Item_Reset()
 964 {
 965         Item_Show(self, !self.state);
 966         setorigin (self, self.origin);
 967
 968         if(self.classname != "droppedweapon")
 969         {
 970                 self.think = Item_Think;
 971                 self.nextthink = time;
 972
 973                 if(self.waypointsprite_attached)
 974                         WaypointSprite_Kill(self.waypointsprite_attached);
 975
 976                 if((self.flags & FL_POWERUP) || (self.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 977                         Item_ScheduleInitialRespawn(self);
 978         }
 979 }
 980
 981 void Item_FindTeam()
 982 {
 983         entity head, e;
 984
 985         if(self.effects & EF_NODRAW)
 986         {
 987                 // marker for item team search
 988                 dprint("Initializing item team ", ftos(self.team), "\n");
 989                 RandomSelection_Init();
 990                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 991                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 992                 e = RandomSelection_chosen_ent;
 993                 e.state = 0;
 994                 Item_Show(e, 1);
 995
 996                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 997                 {
 998                         if(head != e)
 999                         {
1000                                 // make it a non-spawned item
1001                                 Item_Show(head, -1);
1002                                 head.state = 1; // state 1 = initially hidden item
1003                         }
1004                         head.effects &= ~EF_NODRAW;
1005                 }
1006
1007                 Item_Reset();
1008         }
1009 }
1010
1011 // Savage: used for item garbage-collection
1012 // TODO: perhaps nice special effect?
1013 void RemoveItem(void)
1014 {
1015         remove(self);
1016 }
1017
1018 // pickup evaluation functions
1019 // these functions decide how desirable an item is to the bots
1020
1021 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1022
1023 float weapon_pickupevalfunc(entity player, entity item)
1024 {
1025         float c;
1026
1027         // See if I have it already
1028         if(item.weapons & ~player.weapons)
1029         {
1030                 // If I can pick it up
1031                 if(!item.spawnshieldtime)
1032                         c = 0;
1033                 else if(player.ammo_cells || player.ammo_shells || player.ammo_plasma || player.ammo_nails || player.ammo_rockets)
1034                 {
1035                         // Skilled bots will grab more
1036                         c = bound(0, skill / 10, 1) * 0.5;
1037                 }
1038                 else
1039                         c = 0;
1040         }
1041         else
1042                 c = 1;
1043
1044         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
1045         if( bot_custom_weapon && c )
1046         {
1047                 // Find the highest position on any range
1048                 int position = -1;
1049                 for (int j = 0; j < WEP_LAST ; ++j){
1050                         if(
1051                                         bot_weapons_far[j] == item.weapon ||
1052                                         bot_weapons_mid[j] == item.weapon ||
1053                                         bot_weapons_close[j] == item.weapon
1054                           )
1055                         {
1056                                 position = j;
1057                                 break;
1058                         }
1059                 }
1060
1061                 // Rate it
1062                 if (position >= 0 )
1063                 {
1064                         position = WEP_LAST - position;
1065                         // item.bot_pickupbasevalue is overwritten here
1066                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
1067                 }
1068         }
1069
1070         return item.bot_pickupbasevalue * c;
1071 }
1072
1073 float commodity_pickupevalfunc(entity player, entity item)
1074 {
1075         float c, i;
1076         float need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1077         entity wi;
1078         c = 0;
1079
1080         // Detect needed ammo
1081         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
1082         {
1083                 wi = get_weaponinfo(i);
1084
1085                 if (!(player.weapons & WepSet_FromWeapon(i)))
1086                         continue;
1087
1088                 if(wi.items & IT_SHELLS)
1089                         need_shells = true;
1090                 else if(wi.items & IT_NAILS)
1091                         need_nails = true;
1092                 else if(wi.items & IT_ROCKETS)
1093                         need_rockets = true;
1094                 else if(wi.items & IT_CELLS)
1095                         need_cells = true;
1096                 else if(wi.items & IT_PLASMA)
1097                         need_plasma = true;
1098                 else if(wi.items & IT_FUEL)
1099                         need_fuel = true;
1100         }
1101
1102         // TODO: figure out if the player even has the weapon this ammo is for?
1103         // may not affect strategy much though...
1104         // find out how much more ammo/armor/health the player can hold
1105         if (need_shells)
1106         if (item.ammo_shells)
1107         if (player.ammo_shells < g_pickup_shells_max)
1108                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
1109         if (need_nails)
1110         if (item.ammo_nails)
1111         if (player.ammo_nails < g_pickup_nails_max)
1112                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
1113         if (need_rockets)
1114         if (item.ammo_rockets)
1115         if (player.ammo_rockets < g_pickup_rockets_max)
1116                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
1117         if (need_cells)
1118         if (item.ammo_cells)
1119         if (player.ammo_cells < g_pickup_cells_max)
1120                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
1121         if (need_plasma)
1122         if (item.ammo_plasma)
1123         if (player.ammo_plasma < g_pickup_plasma_max)
1124                 c = c + max(0, 1 - player.ammo_plasma / g_pickup_plasma_max);
1125         if (need_fuel)
1126         if (item.ammo_fuel)
1127         if (player.ammo_fuel < g_pickup_fuel_max)
1128                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
1129         if (item.armorvalue)
1130         if (player.armorvalue < item.max_armorvalue)
1131                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
1132         if (item.health)
1133         if (player.health < item.max_health)
1134                 c = c + max(0, 1 - player.health / item.max_health);
1135
1136         return item.bot_pickupbasevalue * c;
1137 }
1138
1139 void Item_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1140 {
1141         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1142                 RemoveItem();
1143 }
1144
1145 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
1146 {
1147         startitem_failed = false;
1148
1149         if(self.model == "")
1150                 self.model = itemmodel;
1151
1152         if(self.model == "")
1153     {
1154         error(strcat("^1Tried to spawn ", itemname, " with no model!\n"));
1155         return;
1156     }
1157
1158         if(self.item_pickupsound == "")
1159                 self.item_pickupsound = pickupsound;
1160
1161         if(!self.respawntime) // both need to be set
1162         {
1163                 self.respawntime = defaultrespawntime;
1164                 self.respawntimejitter = defaultrespawntimejitter;
1165         }
1166
1167         self.items = itemid;
1168         self.weapon = weaponid;
1169
1170         if(weaponid)
1171                 self.weapons = WepSet_FromWeapon(weaponid);
1172
1173         self.flags = FL_ITEM | itemflags;
1174
1175         if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
1176         {
1177                 startitem_failed = true;
1178                 remove(self);
1179                 return;
1180         }
1181
1182         // is it a dropped weapon?
1183         if (self.classname == "droppedweapon")
1184         {
1185                 self.reset = SUB_Remove;
1186                 // it's a dropped weapon
1187                 self.movetype = MOVETYPE_TOSS;
1188
1189                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1190                 self.think = RemoveItem;
1191                 self.nextthink = time + 20;
1192
1193                 self.takedamage = DAMAGE_YES;
1194                 self.event_damage = Item_Damage;
1195
1196                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
1197                 /*
1198                 if(self.items == 0)
1199                 if(!(self.weapons & ~WEPSET_SUPERWEAPONS)) // only superweapons
1200                 if(self.ammo_nails == 0)
1201                 if(self.ammo_cells == 0)
1202                 if(self.ammo_rockets == 0)
1203                 if(self.ammo_shells == 0)
1204                 if(self.ammo_fuel == 0)
1205                 if(self.health == 0)
1206                 if(self.armorvalue == 0)
1207                 */
1208                 {
1209                         // if item is worthless after a timer, have it expire then
1210                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
1211                 }
1212
1213                 // don't drop if in a NODROP zone (such as lava)
1214                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
1215                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1216                 {
1217                         startitem_failed = true;
1218                         remove(self);
1219                         return;
1220                 }
1221         }
1222         else
1223         {
1224                 if(!have_pickup_item())
1225                 {
1226                         startitem_failed = true;
1227                         remove (self);
1228                         return;
1229                 }
1230
1231                 self.reset = Item_Reset;
1232                 // it's a level item
1233                 if(self.spawnflags & 1)
1234                         self.noalign = 1;
1235                 if (self.noalign)
1236                         self.movetype = MOVETYPE_NONE;
1237                 else
1238                         self.movetype = MOVETYPE_TOSS;
1239                 // do item filtering according to game mode and other things
1240                 if (!self.noalign)
1241                 {
1242                         // first nudge it off the floor a little bit to avoid math errors
1243                         setorigin(self, self.origin + '0 0 1');
1244                         // set item size before we spawn a spawnfunc_waypoint
1245                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1246                                 setsize (self, '-16 -16 0', '16 16 48');
1247                         else
1248                                 setsize (self, '-16 -16 0', '16 16 32');
1249
1250                         // note droptofloor returns false if stuck/or would fall too far
1251                         droptofloor();
1252                         waypoint_spawnforitem(self);
1253                 }
1254
1255                 /*
1256                  * can't do it that way, as it would break maps
1257                  * TODO make a target_give like entity another way, that perhaps has
1258                  * the weapon name in a key
1259                 if(self.targetname)
1260                 {
1261                         // target_give not yet supported; maybe later
1262                         print("removed targeted ", self.classname, "\n");
1263                         startitem_failed = true;
1264                         remove (self);
1265                         return;
1266                 }
1267                 */
1268
1269                 if(autocvar_spawn_debug >= 2)
1270                 {
1271                         entity otheritem;
1272                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
1273                         {
1274                             // why not flags & fl_item?
1275                                 if(otheritem.is_item)
1276                                 {
1277                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
1278                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
1279                                         error("Mapper sucks.");
1280                                 }
1281                         }
1282                         self.is_item = true;
1283                 }
1284
1285                 weaponsInMap |= WepSet_FromWeapon(weaponid);
1286
1287                 precache_model (self.model);
1288                 precache_sound (self.item_pickupsound);
1289
1290                 precache_sound ("misc/itemrespawncountdown.wav");
1291                 if(itemid == IT_STRENGTH)
1292                         precache_sound ("misc/strength_respawn.wav");
1293                 else if(itemid == IT_INVINCIBLE)
1294                         precache_sound ("misc/shield_respawn.wav");
1295                 else
1296                         precache_sound ("misc/itemrespawn.wav");
1297
1298                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
1299                         self.target = "###item###"; // for finding the nearest item using find()
1300
1301                 Item_ItemsTime_UpdateTime(self, 0);
1302         }
1303
1304         self.bot_pickup = true;
1305         self.bot_pickupevalfunc = pickupevalfunc;
1306         self.bot_pickupbasevalue = pickupbasevalue;
1307         self.mdl = self.model;
1308         self.netname = itemname;
1309         self.touch = Item_Touch;
1310         setmodel(self, "null"); // precision set below
1311         //self.effects |= EF_LOWPRECISION;
1312
1313         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1314     {
1315         self.pos1 = '-16 -16 0';
1316         self.pos2 = '16 16 48';
1317     }
1318         else
1319     {
1320         self.pos1 = '-16 -16 0';
1321         self.pos2 = '16 16 32';
1322     }
1323     setsize (self, self.pos1, self.pos2);
1324
1325     if(itemflags & FL_POWERUP)
1326         self.ItemStatus |= ITS_ANIMATE1;
1327
1328         if(self.armorvalue || self.health)
1329         self.ItemStatus |= ITS_ANIMATE2;
1330
1331         if(itemflags & FL_WEAPON)
1332         {
1333                 if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1334             self.colormap = 1024; // color shirt=0 pants=0 grey
1335         else
1336             self.gravity = 1;
1337
1338                 self.ItemStatus |= ITS_ANIMATE1;
1339                 self.ItemStatus |= ISF_COLORMAP;
1340         }
1341
1342         self.state = 0;
1343         if(self.team) // broken, no idea why.
1344         {
1345                 if(!self.cnt)
1346                         self.cnt = 1; // item probability weight
1347
1348                 self.effects |= EF_NODRAW; // marker for item team search
1349                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
1350         }
1351         else
1352                 Item_Reset();
1353
1354     Net_LinkEntity(self, false, 0, ItemSend);
1355
1356         self.SendFlags |= ISF_SIZE;
1357         if(self.angles)
1358                 self.SendFlags |= ISF_ANGLES;
1359
1360         // call this hook after everything else has been done
1361         if(MUTATOR_CALLHOOK(Item_Spawn))
1362         {
1363                 startitem_failed = true;
1364                 remove(self);
1365                 return;
1366         }
1367 }
1368 void spawnfunc_item_rockets (void) {
1369         if(!self.ammo_rockets)
1370                 self.ammo_rockets = g_pickup_rockets;
1371         if(!self.pickup_anyway)
1372                 self.pickup_anyway = g_pickup_ammo_anyway;
1373         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1374 }
1375
1376 void spawnfunc_item_bullets (void) {
1377         if(!weaponswapping)
1378         if(autocvar_sv_q3acompat_machineshotgunswap)
1379         if(self.classname != "droppedweapon")
1380         {
1381                 weaponswapping = true;
1382                 spawnfunc_item_shells();
1383                 weaponswapping = false;
1384                 return;
1385         }
1386
1387         if(!self.ammo_nails)
1388                 self.ammo_nails = g_pickup_nails;
1389         if(!self.pickup_anyway)
1390                 self.pickup_anyway = g_pickup_ammo_anyway;
1391         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1392 }
1393
1394 void spawnfunc_item_cells (void) {
1395         if(!self.ammo_cells)
1396                 self.ammo_cells = g_pickup_cells;
1397         if(!self.pickup_anyway)
1398                 self.pickup_anyway = g_pickup_ammo_anyway;
1399         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1400 }
1401
1402 void spawnfunc_item_plasma()
1403 {
1404         if(!self.ammo_plasma)
1405                 self.ammo_plasma = g_pickup_plasma;
1406         if(!self.pickup_anyway)
1407                 self.pickup_anyway = g_pickup_ammo_anyway;
1408         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "plasma", IT_PLASMA, 0, 0, commodity_pickupevalfunc, 2000);
1409 }
1410
1411 void spawnfunc_item_shells (void) {
1412         if(!weaponswapping)
1413         if(autocvar_sv_q3acompat_machineshotgunswap)
1414         if(self.classname != "droppedweapon")
1415         {
1416                 weaponswapping = true;
1417                 spawnfunc_item_bullets();
1418                 weaponswapping = false;
1419                 return;
1420         }
1421
1422         if(!self.ammo_shells)
1423                 self.ammo_shells = g_pickup_shells;
1424         if(!self.pickup_anyway)
1425                 self.pickup_anyway = g_pickup_ammo_anyway;
1426         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1427 }
1428
1429 void spawnfunc_item_armor_small (void) {
1430         if(!self.armorvalue)
1431                 self.armorvalue = g_pickup_armorsmall;
1432         if(!self.max_armorvalue)
1433                 self.max_armorvalue = g_pickup_armorsmall_max;
1434         if(!self.pickup_anyway)
1435                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1436         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1437 }
1438
1439 void spawnfunc_item_armor_medium (void) {
1440         if(!self.armorvalue)
1441                 self.armorvalue = g_pickup_armormedium;
1442         if(!self.max_armorvalue)
1443                 self.max_armorvalue = g_pickup_armormedium_max;
1444         if(!self.pickup_anyway)
1445                 self.pickup_anyway = g_pickup_armormedium_anyway;
1446         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1447 }
1448
1449 void spawnfunc_item_armor_big (void) {
1450         if(!self.armorvalue)
1451                 self.armorvalue = g_pickup_armorbig;
1452         if(!self.max_armorvalue)
1453                 self.max_armorvalue = g_pickup_armorbig_max;
1454         if(!self.pickup_anyway)
1455                 self.pickup_anyway = g_pickup_armorbig_anyway;
1456         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1457 }
1458
1459 void spawnfunc_item_armor_large (void) {
1460         if(!self.armorvalue)
1461                 self.armorvalue = g_pickup_armorlarge;
1462         if(!self.max_armorvalue)
1463                 self.max_armorvalue = g_pickup_armorlarge_max;
1464         if(!self.pickup_anyway)
1465                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1466         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1467 }
1468
1469 void spawnfunc_item_health_small (void) {
1470         if(!self.max_health)
1471                 self.max_health = g_pickup_healthsmall_max;
1472         if(!self.health)
1473                 self.health = g_pickup_healthsmall;
1474         if(!self.pickup_anyway)
1475                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1476         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1477 }
1478
1479 void spawnfunc_item_health_medium (void) {
1480         if(!self.max_health)
1481                 self.max_health = g_pickup_healthmedium_max;
1482         if(!self.health)
1483                 self.health = g_pickup_healthmedium;
1484         if(!self.pickup_anyway)
1485                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1486         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1487 }
1488
1489 void spawnfunc_item_health_large (void) {
1490         if(!self.max_health)
1491                 self.max_health = g_pickup_healthlarge_max;
1492         if(!self.health)
1493                 self.health = g_pickup_healthlarge;
1494         if(!self.pickup_anyway)
1495                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1496         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1497 }
1498
1499 void spawnfunc_item_health_mega (void) {
1500                 if(!self.max_health)
1501                         self.max_health = g_pickup_healthmega_max;
1502                 if(!self.health)
1503                         self.health = g_pickup_healthmega;
1504                 if(!self.pickup_anyway)
1505                         self.pickup_anyway = g_pickup_healthmega_anyway;
1506                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1507 }
1508
1509 // support old misnamed entities
1510 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1511 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1512 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1513 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1514 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1515
1516 void spawnfunc_item_strength (void) {
1517                 precache_sound("weapons/strength_fire.wav");
1518                 if(!self.strength_finished)
1519                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1520                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1521 }
1522
1523 void spawnfunc_item_invincible (void) {
1524                 if(!self.invincible_finished)
1525                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1526                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1527 }
1528
1529 // compatibility:
1530 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1531
1532 void target_items_use (void)
1533 {
1534         if(activator.classname == "droppedweapon")
1535         {
1536                 EXACTTRIGGER_TOUCH;
1537                 remove(activator);
1538                 return;
1539         }
1540
1541         if (!IS_PLAYER(activator))
1542                 return;
1543         if(activator.deadflag != DEAD_NO)
1544                 return;
1545         EXACTTRIGGER_TOUCH;
1546
1547         entity e;
1548         for(e = world; (e = find(e, classname, "droppedweapon")); )
1549                 if(e.enemy == activator)
1550                         remove(e);
1551
1552         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1553                 centerprint(activator, self.message);
1554 }
1555
1556 void spawnfunc_target_items (void)
1557 {
1558         float n, i, j;
1559         entity e;
1560         string s;
1561
1562         self.use = target_items_use;
1563         if(!self.strength_finished)
1564                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1565         if(!self.invincible_finished)
1566                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1567         if(!self.superweapons_finished)
1568                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1569
1570         precache_sound("misc/itempickup.wav");
1571         precache_sound("misc/megahealth.wav");
1572         precache_sound("misc/armor25.wav");
1573         precache_sound("misc/powerup.wav");
1574         precache_sound("misc/poweroff.wav");
1575         precache_sound("weapons/weaponpickup.wav");
1576
1577         n = tokenize_console(self.netname);
1578         if(argv(0) == "give")
1579         {
1580                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1581         }
1582         else
1583         {
1584                 for(i = 0; i < n; ++i)
1585                 {
1586                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1587                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1588                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1589                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1590                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1591                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1592                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1593                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1594                         else
1595                         {
1596                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1597                                 {
1598                                         e = get_weaponinfo(j);
1599                                         s = W_UndeprecateName(argv(i));
1600                                         if(s == e.netname)
1601                                         {
1602                                                 self.weapons |= WepSet_FromWeapon(j);
1603                                                 if(self.spawnflags == 0 || self.spawnflags == 2)
1604                                                         WEP_ACTION(e.weapon, WR_INIT);
1605                                                 break;
1606                                         }
1607                                 }
1608                                 if(j > WEP_LAST)
1609                                         print("target_items: invalid item ", argv(i), "\n");
1610                         }
1611                 }
1612
1613                 string itemprefix, valueprefix;
1614                 if(self.spawnflags == 0)
1615                 {
1616                         itemprefix = "";
1617                         valueprefix = "";
1618                 }
1619                 else if(self.spawnflags == 1)
1620                 {
1621                         itemprefix = "max ";
1622                         valueprefix = "max ";
1623                 }
1624                 else if(self.spawnflags == 2)
1625                 {
1626                         itemprefix = "min ";
1627                         valueprefix = "min ";
1628                 }
1629                 else if(self.spawnflags == 4)
1630                 {
1631                         itemprefix = "minus ";
1632                         valueprefix = "max ";
1633                 }
1634                 else
1635                 {
1636                         error("invalid spawnflags");
1637                         itemprefix = valueprefix = string_null;
1638                 }
1639
1640                 self.netname = "";
1641                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1642                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1643                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1644                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1645                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1646                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1647                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1648                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1649                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1650                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1651                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1652                 if(self.ammo_plasma != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_plasma), "plasma");
1653                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1654                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1655                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1656                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1657                 {
1658                         e = get_weaponinfo(j);
1659                         if(e.weapon)
1660                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & WepSet_FromWeapon(j)), e.netname);
1661                 }
1662         }
1663         self.netname = strzone(self.netname);
1664         //print(self.netname, "\n");
1665
1666         n = tokenize_console(self.netname);
1667         for(i = 0; i < n; ++i)
1668         {
1669                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1670                 {
1671                         e = get_weaponinfo(j);
1672                         if(argv(i) == e.netname)
1673                         {
1674                                 WEP_ACTION(e.weapon, WR_INIT);
1675                                 break;
1676                         }
1677                 }
1678         }
1679 }
1680
1681 void spawnfunc_item_fuel(void)
1682 {
1683         if(!self.ammo_fuel)
1684                 self.ammo_fuel = g_pickup_fuel;
1685         if(!self.pickup_anyway)
1686                 self.pickup_anyway = g_pickup_ammo_anyway;
1687         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1688 }
1689
1690 void spawnfunc_item_fuel_regen(void)
1691 {
1692         if(start_items & IT_FUEL_REGEN)
1693         {
1694                 spawnfunc_item_fuel();
1695                 return;
1696         }
1697         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1698 }
1699
1700 void spawnfunc_item_jetpack(void)
1701 {
1702         if(!self.ammo_fuel)
1703                 self.ammo_fuel = g_pickup_fuel_jetpack;
1704         if(start_items & IT_JETPACK)
1705         {
1706                 spawnfunc_item_fuel();
1707                 return;
1708         }
1709         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1710 }
1711
1712 float GiveWeapon(entity e, float wpn, float op, float val)
1713 {
1714         WepSet v0, v1;
1715         v0 = (e.weapons & WepSet_FromWeapon(wpn));
1716         switch(op)
1717         {
1718                 case OP_SET:
1719                         if(val > 0)
1720                                 e.weapons |= WepSet_FromWeapon(wpn);
1721                         else
1722                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1723                         break;
1724                 case OP_MIN:
1725                 case OP_PLUS:
1726                         if(val > 0)
1727                                 e.weapons |= WepSet_FromWeapon(wpn);
1728                         break;
1729                 case OP_MAX:
1730                         if(val <= 0)
1731                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1732                         break;
1733                 case OP_MINUS:
1734                         if(val > 0)
1735                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1736                         break;
1737         }
1738         v1 = (e.weapons & WepSet_FromWeapon(wpn));
1739         return (v0 != v1);
1740 }
1741
1742 float GiveBit(entity e, .float fld, float bit, float op, float val)
1743 {
1744         float v0, v1;
1745         v0 = (e.(fld) & bit);
1746         switch(op)
1747         {
1748                 case OP_SET:
1749                         if(val > 0)
1750                                 e.(fld) |= bit;
1751                         else
1752                                 e.(fld) &= ~bit;
1753                         break;
1754                 case OP_MIN:
1755                 case OP_PLUS:
1756                         if(val > 0)
1757                                 e.(fld) |= bit;
1758                         break;
1759                 case OP_MAX:
1760                         if(val <= 0)
1761                                 e.(fld) &= ~bit;
1762                         break;
1763                 case OP_MINUS:
1764                         if(val > 0)
1765                                 e.(fld) &= ~bit;
1766                         break;
1767         }
1768         v1 = (e.(fld) & bit);
1769         return (v0 != v1);
1770 }
1771
1772 float GiveValue(entity e, .float fld, float op, float val)
1773 {
1774         float v0, v1;
1775         v0 = e.(fld);
1776         switch(op)
1777         {
1778                 case OP_SET:
1779                         e.(fld) = val;
1780                         break;
1781                 case OP_MIN:
1782                         e.(fld) = max(e.(fld), val); // min 100 cells = at least 100 cells
1783                         break;
1784                 case OP_MAX:
1785                         e.(fld) = min(e.(fld), val);
1786                         break;
1787                 case OP_PLUS:
1788                         e.(fld) += val;
1789                         break;
1790                 case OP_MINUS:
1791                         e.(fld) -= val;
1792                         break;
1793         }
1794         v1 = e.(fld);
1795         return (v0 != v1);
1796 }
1797
1798 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1799 {
1800         if(v1 == v0)
1801                 return;
1802         if(v1 <= v0 - t)
1803         {
1804                 if(snd_decr != "")
1805                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1806         }
1807         else if(v0 >= v0 + t)
1808         {
1809                 if(snd_incr != "")
1810                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1811         }
1812 }
1813
1814 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1815 {
1816         if(v0 < v1)
1817                 e.(rotfield) = max(e.(rotfield), time + rottime);
1818         else if(v0 > v1)
1819                 e.(regenfield) = max(e.(regenfield), time + regentime);
1820 }
1821 float GiveItems(entity e, float beginarg, float endarg)
1822 {
1823         float got, i, j, val, op;
1824         float _switchweapon;
1825         entity wi;
1826         string cmd;
1827
1828         val = 999;
1829         op = OP_SET;
1830
1831         got = 0;
1832
1833         _switchweapon = false;
1834         if (e.autoswitch)
1835                 if (e.switchweapon == w_getbestweapon(e))
1836                         _switchweapon = true;
1837
1838         e.strength_finished = max(0, e.strength_finished - time);
1839         e.invincible_finished = max(0, e.invincible_finished - time);
1840         e.superweapons_finished = max(0, e.superweapons_finished - time);
1841
1842         PREGIVE(e, items);
1843         PREGIVE_WEAPONS(e);
1844         PREGIVE(e, strength_finished);
1845         PREGIVE(e, invincible_finished);
1846         PREGIVE(e, superweapons_finished);
1847         PREGIVE(e, ammo_nails);
1848         PREGIVE(e, ammo_cells);
1849         PREGIVE(e, ammo_plasma);
1850         PREGIVE(e, ammo_shells);
1851         PREGIVE(e, ammo_rockets);
1852         PREGIVE(e, ammo_fuel);
1853         PREGIVE(e, armorvalue);
1854         PREGIVE(e, health);
1855
1856         for(i = beginarg; i < endarg; ++i)
1857         {
1858                 cmd = argv(i);
1859
1860                 if(cmd == "0" || stof(cmd))
1861                 {
1862                         val = stof(cmd);
1863                         continue;
1864                 }
1865                 switch(cmd)
1866                 {
1867                         case "no":
1868                                 op = OP_MAX;
1869                                 val = 0;
1870                                 continue;
1871                         case "max":
1872                                 op = OP_MAX;
1873                                 continue;
1874                         case "min":
1875                                 op = OP_MIN;
1876                                 continue;
1877                         case "plus":
1878                                 op = OP_PLUS;
1879                                 continue;
1880                         case "minus":
1881                                 op = OP_MINUS;
1882                                 continue;
1883                         case "ALL":
1884                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1885                                 got += GiveValue(e, strength_finished, op, val);
1886                                 got += GiveValue(e, invincible_finished, op, val);
1887                                 got += GiveValue(e, superweapons_finished, op, val);
1888                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1889                         case "all":
1890                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1891                                 got += GiveValue(e, health, op, val);
1892                                 got += GiveValue(e, armorvalue, op, val);
1893                         case "allweapons":
1894                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1895                                 {
1896                                         wi = get_weaponinfo(j);
1897                                         if(wi.weapon)
1898                                                 if (!(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED))
1899                                                         got += GiveWeapon(e, j, op, val);
1900                                 }
1901                         case "allammo":
1902                                 got += GiveValue(e, ammo_cells, op, val);
1903                                 got += GiveValue(e, ammo_plasma, op, val);
1904                                 got += GiveValue(e, ammo_shells, op, val);
1905                                 got += GiveValue(e, ammo_nails, op, val);
1906                                 got += GiveValue(e, ammo_rockets, op, val);
1907                                 got += GiveValue(e, ammo_fuel, op, val);
1908                                 break;
1909                         case "unlimited_ammo":
1910                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1911                                 break;
1912                         case "unlimited_weapon_ammo":
1913                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1914                                 break;
1915                         case "unlimited_superweapons":
1916                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1917                                 break;
1918                         case "jetpack":
1919                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1920                                 break;
1921                         case "fuel_regen":
1922                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1923                                 break;
1924                         case "strength":
1925                                 got += GiveValue(e, strength_finished, op, val);
1926                                 break;
1927                         case "invincible":
1928                                 got += GiveValue(e, invincible_finished, op, val);
1929                                 break;
1930                         case "superweapons":
1931                                 got += GiveValue(e, superweapons_finished, op, val);
1932                                 break;
1933                         case "cells":
1934                                 got += GiveValue(e, ammo_cells, op, val);
1935                                 break;
1936                         case "plasma":
1937                                 got += GiveValue(e, ammo_plasma, op, val);
1938                                 break;
1939                         case "shells":
1940                                 got += GiveValue(e, ammo_shells, op, val);
1941                                 break;
1942                         case "nails":
1943                         case "bullets":
1944                                 got += GiveValue(e, ammo_nails, op, val);
1945                                 break;
1946                         case "rockets":
1947                                 got += GiveValue(e, ammo_rockets, op, val);
1948                                 break;
1949                         case "health":
1950                                 got += GiveValue(e, health, op, val);
1951                                 break;
1952                         case "armor":
1953                                 got += GiveValue(e, armorvalue, op, val);
1954                                 break;
1955                         case "fuel":
1956                                 got += GiveValue(e, ammo_fuel, op, val);
1957                                 break;
1958                         default:
1959                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1960                                 {
1961                                         wi = get_weaponinfo(j);
1962                                         if(cmd == wi.netname)
1963                                         {
1964                                                 got += GiveWeapon(e, j, op, val);
1965                                                 break;
1966                                         }
1967                                 }
1968                                 if(j > WEP_LAST)
1969                                         print("give: invalid item ", cmd, "\n");
1970                                 break;
1971                 }
1972                 val = 999;
1973                 op = OP_SET;
1974         }
1975
1976         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1977         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1978         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1979         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1980         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1981         {
1982                 wi = get_weaponinfo(j);
1983                 if(wi.weapon)
1984                 {
1985                         POSTGIVE_WEAPON(e, j, "weapons/weaponpickup.wav", string_null);
1986                         if (!(save_weapons & WepSet_FromWeapon(j)))
1987                                 if(e.weapons & WepSet_FromWeapon(j))
1988                                         WEP_ACTION(wi.weapon, WR_INIT);
1989                 }
1990         }
1991         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1992         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1993         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1994         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1995         POSTGIVE_VALUE(e, ammo_plasma, 0, "misc/itempickup.wav", string_null);
1996         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1997         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1998         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1999         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
2000         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
2001
2002         if(e.superweapons_finished <= 0)
2003                 if(self.weapons & WEPSET_SUPERWEAPONS)
2004                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
2005
2006         if(e.strength_finished <= 0)
2007                 e.strength_finished = 0;
2008         else
2009                 e.strength_finished += time;
2010         if(e.invincible_finished <= 0)
2011                 e.invincible_finished = 0;
2012         else
2013                 e.invincible_finished += time;
2014         if(e.superweapons_finished <= 0)
2015                 e.superweapons_finished = 0;
2016         else
2017                 e.superweapons_finished += time;
2018
2019         if (!(e.weapons & WepSet_FromWeapon(e.switchweapon)))
2020                 _switchweapon = true;
2021         if(_switchweapon)
2022                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
2023
2024         return got;
2025 }
2026 #endif