qcsrc/server/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "../common/items/all.qc"
   4
   5 #if defined(SVQC)
   6
   7     #include "bot/bot.qh"
   8     #include "bot/waypoints.qh"
   9
  10     #include "mutators/mutators_include.qh"
  11
  12     #include "weapons/common.qh"
  13     #include "weapons/selection.qh"
  14     #include "weapons/weaponsystem.qh"
  15
  16     #include "../common/constants.qh"
  17     #include "../common/deathtypes.qh"
  18     #include "../common/notifications.qh"
  19         #include "../common/triggers/subs.qh"
  20     #include "../common/util.qh"
  21
  22     #include "../common/monsters/all.qh"
  23
  24     #include "../common/weapons/all.qh"
  25
  26     #include "../lib/warpzone/util_server.qh"
  27 #endif
  28
  29 #ifdef CSQC
  30 void ItemDraw(entity self)
  31 {
  32     if(self.gravity)
  33     {
  34         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  35         if(self.move_flags & FL_ONGROUND)
  36         { // For some reason move_avelocity gets set to '0 0 0' here ...
  37             self.oldorigin = self.origin;
  38             self.gravity = 0;
  39
  40             if(autocvar_cl_animate_items)
  41             { // ... so reset it if animations are requested.
  42                 if(self.ItemStatus & ITS_ANIMATE1)
  43                     self.move_avelocity = '0 180 0';
  44
  45                 if(self.ItemStatus & ITS_ANIMATE2)
  46                     self.move_avelocity = '0 -90 0';
  47             }
  48         }
  49     }
  50     else if (autocvar_cl_animate_items)
  51     {
  52         if(self.ItemStatus & ITS_ANIMATE1)
  53         {
  54             self.angles += self.move_avelocity * frametime;
  55             setorigin(self, '0 0 10' + self.oldorigin + '0 0 8' * sin(time * 2));
  56         }
  57
  58         if(self.ItemStatus & ITS_ANIMATE2)
  59         {
  60             self.angles += self.move_avelocity * frametime;
  61             setorigin(self, '0 0 8' + self.oldorigin + '0 0 4' * sin(time * 3));
  62         }
  63     }
  64 }
  65
  66 void ItemDrawSimple(entity this)
  67 {
  68     if(self.gravity)
  69     {
  70         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  71
  72         if(self.move_flags & FL_ONGROUND)
  73             self.gravity = 0;
  74     }
  75 }
  76
  77 void Item_PreDraw()
  78 {SELFPARAM();
  79         vector org;
  80         float alph;
  81         org = getpropertyvec(VF_ORIGIN);
  82         if(!checkpvs(org, self)) // this makes sense as long as we don't support recursive warpzones
  83                 alph = 0;
  84         else if(self.fade_start)
  85                 alph = bound(0, (self.fade_end - vlen(org - self.origin - 0.5 * (self.mins + self.maxs))) / (self.fade_end - self.fade_start), 1);
  86         else
  87                 alph = 1;
  88         //printf("%v <-> %v\n", view_origin, self.origin + 0.5 * (self.mins + self.maxs));
  89         if(self.ItemStatus & ITS_AVAILABLE)
  90                 self.alpha = alph;
  91         if(alph <= 0)
  92                 self.drawmask = 0;
  93         else
  94                 self.drawmask = MASK_NORMAL;
  95 }
  96
  97 void ItemRead(float _IsNew)
  98 {SELFPARAM();
  99     int sf = ReadByte();
 100
 101     if(sf & ISF_LOCATION)
 102     {
 103         self.origin_x = ReadCoord();
 104         self.origin_y = ReadCoord();
 105         self.origin_z = ReadCoord();
 106         setorigin(self, self.origin);
 107         self.oldorigin = self.origin;
 108     }
 109
 110     if(sf & ISF_ANGLES)
 111     {
 112         self.angles_x = ReadAngle();
 113         self.angles_y = ReadAngle();
 114         self.angles_z = ReadAngle();
 115         self.move_angles = self.angles;
 116     }
 117
 118     if(sf & ISF_SIZE)
 119     {
 120         float use_bigsize = ReadByte();
 121         setsize(self, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 122     }
 123
 124     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
 125     {
 126         self.ItemStatus = ReadByte();
 127
 128         if(self.ItemStatus & ITS_AVAILABLE)
 129         {
 130             self.alpha = 1;
 131             self.colormod = self.glowmod = '1 1 1';
 132         }
 133         else
 134         {
 135             if (autocvar_cl_ghost_items_color)
 136             {
 137                 self.alpha = autocvar_cl_ghost_items;
 138                 self.colormod = self.glowmod = autocvar_cl_ghost_items_color;
 139             }
 140             else
 141                 self.alpha = -1;
 142         }
 143
 144         if(autocvar_cl_fullbright_items)
 145             if(self.ItemStatus & ITS_ALLOWFB)
 146                 self.effects |= EF_FULLBRIGHT;
 147
 148         if(self.ItemStatus & ITS_STAYWEP)
 149         {
 150             self.colormod = self.glowmod = autocvar_cl_weapon_stay_color;
 151             self.alpha = autocvar_cl_weapon_stay_alpha;
 152
 153         }
 154
 155         if(self.ItemStatus & ITS_POWERUP)
 156         {
 157             if(self.ItemStatus & ITS_AVAILABLE)
 158                 self.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 159             else
 160                  self.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 161         }
 162     }
 163
 164     if(sf & ISF_MODEL)
 165     {
 166         self.drawmask  = MASK_NORMAL;
 167                 self.move_movetype = self.movetype = MOVETYPE_TOSS;
 168         self.draw       = ItemDraw;
 169
 170         self.fade_end = ReadShort();
 171         self.fade_start = ReadShort();
 172         if(self.fade_start && !autocvar_cl_items_nofade)
 173                 self.predraw = Item_PreDraw;
 174
 175         if(self.mdl)
 176             strunzone(self.mdl);
 177
 178         self.mdl = "";
 179         string _fn = ReadString();
 180
 181         if(autocvar_cl_simple_items && (self.ItemStatus & ITS_ALLOWSI))
 182         {
 183             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 184             self.draw = ItemDrawSimple;
 185
 186             if(fexists(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix)))
 187                 self.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix));
 188             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix)))
 189                 self.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix));
 190             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix)))
 191                 self.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix));
 192             else if(fexists(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix)))
 193                 self.mdl = strzone(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix));
 194             else
 195             {
 196                 self.draw = ItemDraw;
 197                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it\n");
 198             }
 199         }
 200
 201         if(self.draw != ItemDrawSimple)
 202             self.mdl = strzone(_fn);
 203
 204
 205         if(self.mdl == "")
 206             LOG_TRACE("^1WARNING!^7 self.mdl is unset for item ", self.classname, " tell tZork aboute this!\n");
 207
 208         precache_model(self.mdl);
 209         _setmodel(self, self.mdl);
 210     }
 211
 212     if(sf & ISF_COLORMAP)
 213         self.colormap = ReadShort();
 214
 215     if(sf & ISF_DROP)
 216     {
 217         self.gravity = 1;
 218         //self.move_angles = '0 0 0';
 219         self.move_movetype = MOVETYPE_TOSS;
 220         self.move_velocity_x = ReadCoord();
 221         self.move_velocity_y = ReadCoord();
 222         self.move_velocity_z = ReadCoord();
 223         self.velocity = self.move_velocity;
 224         self.move_origin = self.oldorigin;
 225
 226         if(!self.move_time)
 227         {
 228             self.move_time = time;
 229             self.spawntime = time;
 230         }
 231         else
 232             self.move_time = max(self.move_time, time);
 233     }
 234
 235     if(autocvar_cl_animate_items)
 236     {
 237         if(self.ItemStatus & ITS_ANIMATE1)
 238             self.move_avelocity = '0 180 0';
 239
 240         if(self.ItemStatus & ITS_ANIMATE2)
 241             self.move_avelocity = '0 -90 0';
 242     }
 243 }
 244
 245 #endif
 246
 247 #ifdef SVQC
 248 bool ItemSend(entity this, entity to, int sf)
 249 {
 250         if(self.gravity)
 251                 sf |= ISF_DROP;
 252         else
 253                 sf &= ~ISF_DROP;
 254
 255         WriteByte(MSG_ENTITY, ENT_CLIENT_ITEM);
 256         WriteByte(MSG_ENTITY, sf);
 257
 258         //WriteByte(MSG_ENTITY, self.cnt);
 259         if(sf & ISF_LOCATION)
 260         {
 261                 WriteCoord(MSG_ENTITY, self.origin.x);
 262                 WriteCoord(MSG_ENTITY, self.origin.y);
 263                 WriteCoord(MSG_ENTITY, self.origin.z);
 264         }
 265
 266         if(sf & ISF_ANGLES)
 267         {
 268                 WriteAngle(MSG_ENTITY, self.angles_x);
 269                 WriteAngle(MSG_ENTITY, self.angles_y);
 270                 WriteAngle(MSG_ENTITY, self.angles_z);
 271         }
 272
 273         if(sf & ISF_SIZE)
 274         {
 275                 WriteByte(MSG_ENTITY, ((self.flags & FL_POWERUP) || self.health || self.armorvalue));
 276         }
 277
 278         if(sf & ISF_STATUS)
 279                 WriteByte(MSG_ENTITY, self.ItemStatus);
 280
 281         if(sf & ISF_MODEL)
 282         {
 283                 WriteShort(MSG_ENTITY, self.fade_end);
 284                 WriteShort(MSG_ENTITY, self.fade_start);
 285
 286                 if(self.mdl == "")
 287                         LOG_TRACE("^1WARNING!^7 self.mdl is unset for item ", self.classname, "exspect a crash just aboute now\n");
 288
 289                 WriteString(MSG_ENTITY, self.mdl);
 290         }
 291
 292
 293         if(sf & ISF_COLORMAP)
 294                 WriteShort(MSG_ENTITY, self.colormap);
 295
 296         if(sf & ISF_DROP)
 297         {
 298                 WriteCoord(MSG_ENTITY, self.velocity.x);
 299                 WriteCoord(MSG_ENTITY, self.velocity.y);
 300                 WriteCoord(MSG_ENTITY, self.velocity.z);
 301         }
 302
 303         return true;
 304 }
 305
 306 void ItemUpdate(entity item)
 307 {
 308         item.SendFlags |= ISF_LOCATION;
 309 }
 310
 311 float have_pickup_item(void)
 312 {SELFPARAM();
 313         if(self.flags & FL_POWERUP)
 314         {
 315                 if(autocvar_g_powerups > 0)
 316                         return true;
 317                 if(autocvar_g_powerups == 0)
 318                         return false;
 319         }
 320         else
 321         {
 322                 if(autocvar_g_pickup_items > 0)
 323                         return true;
 324                 if(autocvar_g_pickup_items == 0)
 325                         return false;
 326                 if(g_weaponarena)
 327                         if(self.weapons || (self.items & IT_AMMO)) // no item or ammo pickups in weaponarena
 328                                 return false;
 329         }
 330         return true;
 331 }
 332
 333 /*
 334 float Item_Customize()
 335 {
 336         if(self.spawnshieldtime)
 337                 return true;
 338         if(self.weapons & ~other.weapons)
 339         {
 340                 self.colormod = '0 0 0';
 341                 self.glowmod = self.colormod;
 342                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 343                 return true;
 344         }
 345         else
 346         {
 347                 if(g_ghost_items)
 348                 {
 349                         self.colormod = stov(autocvar_g_ghost_items_color);
 350                         self.glowmod = self.colormod;
 351                         self.alpha = g_ghost_items;
 352                         return true;
 353                 }
 354                 else
 355                         return false;
 356         }
 357 }
 358 */
 359
 360 void Item_Show (entity e, float mode)
 361 {
 362         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 363         e.ItemStatus &= ~ITS_STAYWEP;
 364         if (mode > 0)
 365         {
 366                 // make the item look normal, and be touchable
 367                 e.model = e.mdl;
 368                 e.solid = SOLID_TRIGGER;
 369                 e.spawnshieldtime = 1;
 370                 e.ItemStatus |= ITS_AVAILABLE;
 371         }
 372         else if (mode < 0)
 373         {
 374                 // hide the item completely
 375                 e.model = string_null;
 376                 e.solid = SOLID_NOT;
 377                 e.spawnshieldtime = 1;
 378                 e.ItemStatus &= ~ITS_AVAILABLE;
 379         }
 380         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 381         {
 382                 // make the item translucent and not touchable
 383                 e.model = e.mdl;
 384                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 385                 e.effects |= EF_STARDUST;
 386                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 387                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 388         }
 389         else
 390         {
 391                 //setmodel(e, "null");
 392                 e.solid = SOLID_NOT;
 393                 e.colormod = '0 0 0';
 394                 e.glowmod = e.colormod;
 395                 e.spawnshieldtime = 1;
 396                 e.ItemStatus &= ~ITS_AVAILABLE;
 397         }
 398
 399         if (e.items & ITEM_Strength.m_itemid || e.items & ITEM_Shield.m_itemid)
 400                 e.ItemStatus |= ITS_POWERUP;
 401
 402         if (autocvar_g_nodepthtestitems)
 403                 e.effects |= EF_NODEPTHTEST;
 404
 405
 406         if (autocvar_g_fullbrightitems)
 407                 e.ItemStatus |= ITS_ALLOWFB;
 408
 409         if (autocvar_sv_simple_items)
 410                 e.ItemStatus |= ITS_ALLOWSI;
 411
 412         // relink entity (because solid may have changed)
 413         setorigin(e, e.origin);
 414         e.SendFlags |= ISF_STATUS;
 415 }
 416
 417 void Item_Think()
 418 {SELFPARAM();
 419         self.nextthink = time;
 420         if(self.origin != self.oldorigin)
 421         {
 422                 self.oldorigin = self.origin;
 423                 ItemUpdate(self);
 424         }
 425 }
 426
 427 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 428 bool Item_ItemsTime_Allow(GameItem it, WepSet _weapons);
 429 float Item_ItemsTime_UpdateTime(entity e, float t);
 430 void Item_ItemsTime_SetTime(entity e, float t);
 431 void Item_ItemsTime_SetTimesForAllPlayers();
 432
 433 void Item_Respawn (void)
 434 {SELFPARAM();
 435         Item_Show(self, 1);
 436         // this is ugly...
 437         if(self.items == ITEM_Strength.m_itemid)
 438                 sound (self, CH_TRIGGER, SND_STRENGTH_RESPAWN, VOL_BASE, ATTEN_NORM);   // play respawn sound
 439         else if(self.items == ITEM_Shield.m_itemid)
 440                 sound (self, CH_TRIGGER, SND_SHIELD_RESPAWN, VOL_BASE, ATTEN_NORM);     // play respawn sound
 441         else
 442                 sound (self, CH_TRIGGER, SND_ITEMRESPAWN, VOL_BASE, ATTEN_NORM);        // play respawn sound
 443         setorigin (self, self.origin);
 444
 445     if (Item_ItemsTime_Allow(self.itemdef, self.weapons))
 446         {
 447                 float t = Item_ItemsTime_UpdateTime(self, 0);
 448                 Item_ItemsTime_SetTime(self, t);
 449                 Item_ItemsTime_SetTimesForAllPlayers();
 450         }
 451
 452         self.think = Item_Think;
 453         self.nextthink = time;
 454
 455         //Send_Effect(EFFECT_ITEM_RESPAWN, self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 456         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 457 }
 458
 459 void Item_RespawnCountdown (void)
 460 {SELFPARAM();
 461         if(self.count >= ITEM_RESPAWN_TICKS)
 462         {
 463                 if(self.waypointsprite_attached)
 464                         WaypointSprite_Kill(self.waypointsprite_attached);
 465                 Item_Respawn();
 466         }
 467         else
 468         {
 469                 self.nextthink = time + 1;
 470                 self.count += 1;
 471                 if(self.count == 1)
 472                 {
 473                         MUTATOR_CALLHOOK(Item_RespawnCountdown, string_null, '0 0 0');
 474                         do {
 475                                 {
 476                                         entity wi = get_weaponinfo(self.weapon);
 477                                         if (wi.m_id) {
 478                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, true, RADARICON_Weapon);
 479                                                 wp.wp_extra = wi.m_id;
 480                                                 break;
 481                                         }
 482                                 }
 483                                 {
 484                                         entity ii = self.itemdef;
 485                                         if (ii.m_id) {
 486                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, true, RADARICON_Item);
 487                                                 wp.wp_extra = ii.m_id;
 488                                                 break;
 489                                         }
 490                                 }
 491                         } while (0);
 492             if(self.waypointsprite_attached)
 493             {
 494                 GameItem def = self.itemdef;
 495                 if (Item_ItemsTime_SpectatorOnly(def))
 496                     WaypointSprite_UpdateRule(self.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 497                 WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 498             }
 499                 }
 500
 501                 if(self.waypointsprite_attached)
 502                 {
 503                         setself(self.waypointsprite_attached);
 504                         entity e;
 505                         FOR_EACH_REALCLIENT(e)
 506                                 if(self.waypointsprite_visible_for_player(e))
 507                                 {
 508                                         msg_entity = e;
 509                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 510                                 }
 511                         setself(this);
 512
 513                         WaypointSprite_Ping(self.waypointsprite_attached);
 514                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 515                 }
 516                 else
 517                         sound(self, CH_TRIGGER, SND_ITEMRESPAWNCOUNTDOWN, VOL_BASE, ATTEN_NORM);        // play respawn sound
 518         }
 519 }
 520
 521 void Item_RespawnThink()
 522 {SELFPARAM();
 523         self.nextthink = time;
 524         if(self.origin != self.oldorigin)
 525         {
 526                 self.oldorigin = self.origin;
 527                 ItemUpdate(self);
 528         }
 529
 530         if(time >= self.wait)
 531                 Item_Respawn();
 532 }
 533
 534 void Item_ScheduleRespawnIn(entity e, float t)
 535 {
 536         if (Item_ItemsTime_Allow(e.itemdef, e.weapons))
 537         {
 538                 e.think = Item_RespawnCountdown;
 539                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 540                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 541                 e.count = 0;
 542                 t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 543                 Item_ItemsTime_SetTime(e, t);
 544                 Item_ItemsTime_SetTimesForAllPlayers();
 545         }
 546         else
 547         {
 548                 e.think = Item_RespawnThink;
 549                 e.nextthink = time;
 550                 e.scheduledrespawntime = time + t;
 551                 e.wait = time + t;
 552         }
 553 }
 554
 555 void Item_ScheduleRespawn(entity e)
 556 {
 557         if(e.respawntime > 0)
 558         {
 559                 Item_Show(e, 0);
 560                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 561         }
 562         else // if respawntime is -1, this item does not respawn
 563                 Item_Show(e, -1);
 564 }
 565
 566 void Item_ScheduleInitialRespawn(entity e)
 567 {
 568         Item_Show(e, 0);
 569         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 570 }
 571
 572 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax, float mode)
 573 {
 574         if (!item.(ammotype))
 575                 return false;
 576
 577         if (item.spawnshieldtime)
 578         {
 579                 if ((player.(ammotype) < ammomax) || item.pickup_anyway)
 580                 {
 581                         player.(ammotype) = bound(player.(ammotype), ammomax, player.(ammotype) + item.(ammotype));
 582                         goto YEAH;
 583                 }
 584         }
 585         else if(g_weapon_stay == 2)
 586         {
 587                 float mi = min(item.(ammotype), ammomax);
 588                 if (player.(ammotype) < mi)
 589                 {
 590                         player.(ammotype) = mi;
 591                         goto YEAH;
 592                 }
 593         }
 594
 595         return false;
 596
 597 :YEAH
 598         switch(mode)
 599         {
 600                 case ITEM_MODE_FUEL:
 601                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 602                         break;
 603                 case ITEM_MODE_HEALTH:
 604                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 605                         break;
 606                 case ITEM_MODE_ARMOR:
 607                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 608                         break;
 609                 default:
 610                         break;
 611         }
 612         return true;
 613 }
 614
 615 float Item_GiveTo(entity item, entity player)
 616 {
 617         float _switchweapon;
 618         float pickedup;
 619         float it;
 620         float i;
 621
 622         // if nothing happens to player, just return without taking the item
 623         pickedup = false;
 624         _switchweapon = false;
 625         // in case the player has autoswitch enabled do the following:
 626         // if the player is using their best weapon before items are given, they
 627         // probably want to switch to an even better weapon after items are given
 628         if (player.autoswitch)
 629         if (player.switchweapon == w_getbestweapon(player))
 630                 _switchweapon = true;
 631
 632         if (!(player.weapons & WepSet_FromWeapon(player.switchweapon)))
 633                 _switchweapon = true;
 634
 635         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 636         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 637         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 638         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 639         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 640         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max, ITEM_MODE_NONE);
 641         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 642         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 643
 644         if (item.flags & FL_WEAPON)
 645         {
 646                 WepSet it;
 647                 it = item.weapons;
 648                 it &= ~player.weapons;
 649
 650                 if (it || (item.spawnshieldtime && item.pickup_anyway))
 651                 {
 652                         pickedup = true;
 653                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 654                         if(it & WepSet_FromWeapon(i))
 655                         {
 656                                 W_DropEvent(wr_pickup, player, i, item);
 657                                 W_GiveWeapon(player, i);
 658                         }
 659                 }
 660         }
 661
 662         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 663         {
 664                 pickedup = true;
 665                 player.items |= it;
 666                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 667         }
 668
 669         if (item.strength_finished)
 670         {
 671                 pickedup = true;
 672                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 673         }
 674         if (item.invincible_finished)
 675         {
 676                 pickedup = true;
 677                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 678         }
 679         if (item.superweapons_finished)
 680         {
 681                 pickedup = true;
 682                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 683         }
 684
 685 :skip
 686
 687         // always eat teamed entities
 688         if(item.team)
 689                 pickedup = true;
 690
 691         if (!pickedup)
 692                 return 0;
 693
 694         // crude hack to enforce switching weapons
 695         if(g_cts && (item.flags & FL_WEAPON))
 696         {
 697                 W_SwitchWeapon_Force(player, item.weapon);
 698                 return 1;
 699         }
 700
 701         if (_switchweapon)
 702                 if (player.switchweapon != w_getbestweapon(player))
 703                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 704
 705         return 1;
 706 }
 707
 708 void Item_Touch (void)
 709 {SELFPARAM();
 710         entity e, head;
 711
 712         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 713         if(self.classname == "droppedweapon")
 714         {
 715                 if (ITEM_TOUCH_NEEDKILL())
 716                 {
 717                         remove(self);
 718                         return;
 719                 }
 720         }
 721
 722         if(!(other.flags & FL_PICKUPITEMS)
 723         || other.frozen
 724         || other.deadflag
 725         || (self.solid != SOLID_TRIGGER)
 726         || (self.owner == other)
 727         || (time < self.item_spawnshieldtime)
 728         ) { return;}
 729
 730         switch(MUTATOR_CALLHOOK(ItemTouch, self, other))
 731         {
 732                 case MUT_ITEMTOUCH_RETURN: { return; }
 733                 case MUT_ITEMTOUCH_PICKUP: { goto pickup; }
 734         }
 735
 736         if (self.classname == "droppedweapon")
 737         {
 738                 self.strength_finished = max(0, self.strength_finished - time);
 739                 self.invincible_finished = max(0, self.invincible_finished - time);
 740                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 741         }
 742         entity it = self.itemdef;
 743         bool gave = (it && it.instanceOfPickup) ? ITEM_HANDLE(Pickup, it, self, other) : Item_GiveTo(self, other);
 744         if (!gave)
 745         {
 746                 if (self.classname == "droppedweapon")
 747                 {
 748                         // undo what we did above
 749                         self.strength_finished += time;
 750                         self.invincible_finished += time;
 751                         self.superweapons_finished += time;
 752                 }
 753                 return;
 754         }
 755
 756         :pickup
 757
 758         other.last_pickup = time;
 759
 760         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 761         _sound (other, CH_TRIGGER, (self.item_pickupsound ? self.item_pickupsound : self.item_pickupsound_ent.sound_str()), VOL_BASE, ATTEN_NORM);
 762
 763         if (self.classname == "droppedweapon")
 764                 remove (self);
 765         else if (self.spawnshieldtime)
 766         {
 767                 if(self.team)
 768                 {
 769                         RandomSelection_Init();
 770                         for(head = world; (head = findfloat(head, team, self.team)); )
 771                         {
 772                                 if(head.flags & FL_ITEM)
 773                                 if(head.classname != "item_flag_team" && head.classname != "item_key_team")
 774                                 {
 775                                         Item_Show(head, -1);
 776                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 777                                 }
 778                         }
 779                         e = RandomSelection_chosen_ent;
 780
 781                 }
 782                 else
 783                         e = self;
 784                 Item_ScheduleRespawn(e);
 785         }
 786 }
 787
 788 void Item_Reset(entity this)
 789 {
 790         Item_Show(this, !this.state);
 791         setorigin(this, this.origin);
 792
 793         if (this.classname != "droppedweapon")
 794         {
 795                 this.think = Item_Think;
 796                 this.nextthink = time;
 797
 798                 if (this.waypointsprite_attached)
 799                         WaypointSprite_Kill(this.waypointsprite_attached);
 800
 801                 if ((this.flags & FL_POWERUP) || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 802                         Item_ScheduleInitialRespawn(this);
 803         }
 804 }
 805 void Item_Reset_self() { SELFPARAM(); Item_Reset(this); }
 806
 807 void Item_FindTeam()
 808 {SELFPARAM();
 809         entity head, e;
 810
 811         if(self.effects & EF_NODRAW)
 812         {
 813                 // marker for item team search
 814                 LOG_TRACE("Initializing item team ", ftos(self.team), "\n");
 815                 RandomSelection_Init();
 816                 for(head = world; (head = findfloat(head, team, self.team)); )
 817                 if(head.flags & FL_ITEM)
 818                 if(head.classname != "item_flag_team" && head.classname != "item_key_team")
 819                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 820                 e = RandomSelection_chosen_ent;
 821                 e.state = 0;
 822                 Item_Show(e, 1);
 823
 824                 for(head = world; (head = findfloat(head, team, self.team)); )
 825                 if(head.flags & FL_ITEM)
 826                 if(head.classname != "item_flag_team" && head.classname != "item_key_team")
 827                 {
 828                         if(head != e)
 829                         {
 830                                 // make it a non-spawned item
 831                                 Item_Show(head, -1);
 832                                 head.state = 1; // state 1 = initially hidden item
 833                         }
 834                         head.effects &= ~EF_NODRAW;
 835                 }
 836
 837                 Item_Reset(self);
 838         }
 839 }
 840
 841 // Savage: used for item garbage-collection
 842 // TODO: perhaps nice special effect?
 843 void RemoveItem(void)
 844 {SELFPARAM();
 845         if(wasfreed(self) || !self) { return; }
 846         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 847         remove(self);
 848 }
 849
 850 // pickup evaluation functions
 851 // these functions decide how desirable an item is to the bots
 852
 853 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 854
 855 float weapon_pickupevalfunc(entity player, entity item)
 856 {
 857         float c;
 858
 859         // See if I have it already
 860         if(item.weapons & ~player.weapons)
 861         {
 862                 // If I can pick it up
 863                 if(!item.spawnshieldtime)
 864                         c = 0;
 865                 else if(player.ammo_cells || player.ammo_shells || player.ammo_plasma || player.ammo_nails || player.ammo_rockets)
 866                 {
 867                         // Skilled bots will grab more
 868                         c = bound(0, skill / 10, 1) * 0.5;
 869                 }
 870                 else
 871                         c = 0;
 872         }
 873         else
 874                 c = 1;
 875
 876         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 877         if( bot_custom_weapon && c )
 878         {
 879                 // Find the highest position on any range
 880                 int position = -1;
 881                 for (int j = 0; j < WEP_LAST ; ++j){
 882                         if(
 883                                         bot_weapons_far[j] == item.weapon ||
 884                                         bot_weapons_mid[j] == item.weapon ||
 885                                         bot_weapons_close[j] == item.weapon
 886                           )
 887                         {
 888                                 position = j;
 889                                 break;
 890                         }
 891                 }
 892
 893                 // Rate it
 894                 if (position >= 0 )
 895                 {
 896                         position = WEP_LAST - position;
 897                         // item.bot_pickupbasevalue is overwritten here
 898                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 899                 }
 900         }
 901
 902         return item.bot_pickupbasevalue * c;
 903 }
 904
 905 float commodity_pickupevalfunc(entity player, entity item)
 906 {
 907         float c, i;
 908         float need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
 909         entity wi;
 910         c = 0;
 911
 912         // Detect needed ammo
 913         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 914         {
 915                 wi = get_weaponinfo(i);
 916
 917                 if (!(player.weapons & WepSet_FromWeapon(i)))
 918                         continue;
 919
 920                 if(wi.items & ITEM_Shells.m_itemid)
 921                         need_shells = true;
 922                 else if(wi.items & ITEM_Bullets.m_itemid)
 923                         need_nails = true;
 924                 else if(wi.items & ITEM_Rockets.m_itemid)
 925                         need_rockets = true;
 926                 else if(wi.items & ITEM_Cells.m_itemid)
 927                         need_cells = true;
 928                 else if(wi.items & ITEM_Plasma.m_itemid)
 929                         need_plasma = true;
 930                 else if(wi.items & ITEM_JetpackFuel.m_itemid)
 931                         need_fuel = true;
 932         }
 933
 934         // TODO: figure out if the player even has the weapon this ammo is for?
 935         // may not affect strategy much though...
 936         // find out how much more ammo/armor/health the player can hold
 937         if (need_shells)
 938         if (item.ammo_shells)
 939         if (player.ammo_shells < g_pickup_shells_max)
 940                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 941         if (need_nails)
 942         if (item.ammo_nails)
 943         if (player.ammo_nails < g_pickup_nails_max)
 944                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 945         if (need_rockets)
 946         if (item.ammo_rockets)
 947         if (player.ammo_rockets < g_pickup_rockets_max)
 948                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 949         if (need_cells)
 950         if (item.ammo_cells)
 951         if (player.ammo_cells < g_pickup_cells_max)
 952                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 953         if (need_plasma)
 954         if (item.ammo_plasma)
 955         if (player.ammo_plasma < g_pickup_plasma_max)
 956                 c = c + max(0, 1 - player.ammo_plasma / g_pickup_plasma_max);
 957         if (need_fuel)
 958         if (item.ammo_fuel)
 959         if (player.ammo_fuel < g_pickup_fuel_max)
 960                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
 961         if (item.armorvalue)
 962         if (player.armorvalue < item.max_armorvalue)
 963                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 964         if (item.health)
 965         if (player.health < item.max_health)
 966                 c = c + max(0, 1 - player.health / item.max_health);
 967
 968         return item.bot_pickupbasevalue * c;
 969 }
 970
 971 void Item_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 972 {
 973         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 974                 RemoveItem();
 975 }
 976
 977 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags)
 978 {
 979         Model itemmodel = def.m_model;
 980     Sound pickupsound = def.m_sound;
 981         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
 982         float pickupbasevalue = def.m_botvalue;
 983
 984         startitem_failed = false;
 985
 986         this.item_model_ent = itemmodel;
 987     this.item_pickupsound_ent = pickupsound;
 988
 989         if(!this.respawntime) // both need to be set
 990         {
 991                 this.respawntime = defaultrespawntime;
 992                 this.respawntimejitter = defaultrespawntimejitter;
 993         }
 994
 995         this.items = itemid;
 996         this.weapon = weaponid;
 997
 998         if(!this.fade_end)
 999         {
1000                 this.fade_start = autocvar_g_items_mindist;
1001                 this.fade_end = autocvar_g_items_maxdist;
1002         }
1003
1004         if(weaponid)
1005                 this.weapons = WepSet_FromWeapon(weaponid);
1006
1007         this.flags = FL_ITEM | itemflags;
1008
1009         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1010         {
1011                 startitem_failed = true;
1012                 remove(this);
1013                 return;
1014         }
1015
1016         // is it a dropped weapon?
1017         if (this.classname == "droppedweapon")
1018         {
1019                 this.reset = SUB_Remove;
1020                 // it's a dropped weapon
1021                 this.movetype = MOVETYPE_TOSS;
1022
1023                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1024                 this.think = RemoveItem;
1025                 this.nextthink = time + 20;
1026
1027                 this.takedamage = DAMAGE_YES;
1028                 this.event_damage = Item_Damage;
1029
1030                 if(this.strength_finished || this.invincible_finished || this.superweapons_finished)
1031                 /*
1032                 if(this.items == 0)
1033                 if(!(this.weapons & ~WEPSET_SUPERWEAPONS)) // only superweapons
1034                 if(this.ammo_nails == 0)
1035                 if(this.ammo_cells == 0)
1036                 if(this.ammo_rockets == 0)
1037                 if(this.ammo_shells == 0)
1038                 if(this.ammo_fuel == 0)
1039                 if(this.health == 0)
1040                 if(this.armorvalue == 0)
1041                 */
1042                 {
1043                         // if item is worthless after a timer, have it expire then
1044                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1045                 }
1046
1047                 // don't drop if in a NODROP zone (such as lava)
1048                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1049                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1050                 {
1051                         startitem_failed = true;
1052                         remove(this);
1053                         return;
1054                 }
1055         }
1056         else
1057         {
1058                 if(!have_pickup_item())
1059                 {
1060                         startitem_failed = true;
1061                         remove (this);
1062                         return;
1063                 }
1064
1065                 if(this.angles != '0 0 0')
1066                         this.SendFlags |= ISF_ANGLES;
1067
1068                 this.reset = Item_Reset_self;
1069                 // it's a level item
1070                 if(this.spawnflags & 1)
1071                         this.noalign = 1;
1072                 if (this.noalign)
1073                         this.movetype = MOVETYPE_NONE;
1074                 else
1075                         this.movetype = MOVETYPE_TOSS;
1076                 // do item filtering according to game mode and other things
1077                 if (!this.noalign)
1078                 {
1079                         // first nudge it off the floor a little bit to avoid math errors
1080                         setorigin(this, this.origin + '0 0 1');
1081                         // set item size before we spawn a spawnfunc_waypoint
1082                         if((itemflags & FL_POWERUP) || this.health || this.armorvalue)
1083                                 setsize (this, '-16 -16 0', '16 16 48');
1084                         else
1085                                 setsize (this, '-16 -16 0', '16 16 32');
1086                         this.SendFlags |= ISF_SIZE;
1087                         // note droptofloor returns false if stuck/or would fall too far
1088                         WITH(entity, self, this, droptofloor());
1089                         waypoint_spawnforitem(this);
1090                 }
1091
1092                 /*
1093                  * can't do it that way, as it would break maps
1094                  * TODO make a target_give like entity another way, that perhaps has
1095                  * the weapon name in a key
1096                 if(this.targetname)
1097                 {
1098                         // target_give not yet supported; maybe later
1099                         print("removed targeted ", this.classname, "\n");
1100                         startitem_failed = true;
1101                         remove (this);
1102                         return;
1103                 }
1104                 */
1105
1106                 if(autocvar_spawn_debug >= 2)
1107                 {
1108                         for(entity otheritem = findradius(this.origin, 3); otheritem; otheritem = otheritem.chain)
1109                         {
1110                             // why not flags & fl_item?
1111                                 if(otheritem.is_item)
1112                                 {
1113                                         LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1114                                         LOG_TRACE(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
1115                                         error("Mapper sucks.");
1116                                 }
1117                         }
1118                         this.is_item = true;
1119                 }
1120
1121                 weaponsInMap |= WepSet_FromWeapon(weaponid);
1122
1123                 precache_model(this.model);
1124                 precache_sound(this.item_pickupsound);
1125
1126                 if ((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
1127                         this.target = "###item###"; // for finding the nearest item using find()
1128
1129                 Item_ItemsTime_SetTime(this, 0);
1130         }
1131
1132         this.bot_pickup = true;
1133         this.bot_pickupevalfunc = pickupevalfunc;
1134         this.bot_pickupbasevalue = pickupbasevalue;
1135         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1136         this.netname = itemname;
1137         this.touch = Item_Touch;
1138         setmodel(this, MDL_Null); // precision set below
1139         //this.effects |= EF_LOWPRECISION;
1140
1141         if((itemflags & FL_POWERUP) || this.health || this.armorvalue)
1142         {
1143                 this.pos1 = '-16 -16 0';
1144                 this.pos2 = '16 16 48';
1145         }
1146         else
1147         {
1148                 this.pos1 = '-16 -16 0';
1149                 this.pos2 = '16 16 32';
1150         }
1151         setsize (this, this.pos1, this.pos2);
1152
1153         this.SendFlags |= ISF_SIZE;
1154
1155         if(itemflags & FL_POWERUP)
1156                 this.ItemStatus |= ITS_ANIMATE1;
1157
1158         if(this.armorvalue || this.health)
1159                 this.ItemStatus |= ITS_ANIMATE2;
1160
1161         if(itemflags & FL_WEAPON)
1162         {
1163                 if (this.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1164                         this.colormap = 1024; // color shirt=0 pants=0 grey
1165                 else
1166                         this.gravity = 1;
1167
1168                 this.ItemStatus |= ITS_ANIMATE1;
1169                 this.ItemStatus |= ISF_COLORMAP;
1170         }
1171
1172         this.state = 0;
1173         if(this.team) // broken, no idea why.
1174         {
1175                 if(!this.cnt)
1176                         this.cnt = 1; // item probability weight
1177
1178                 this.effects |= EF_NODRAW; // marker for item team search
1179                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1180         }
1181         else
1182                 Item_Reset(this);
1183
1184         Net_LinkEntity(this, !((itemflags & FL_POWERUP) || this.health || this.armorvalue), 0, ItemSend);
1185
1186         // call this hook after everything else has been done
1187         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1188         {
1189                 startitem_failed = true;
1190                 remove(this);
1191                 return;
1192         }
1193 }
1194
1195 void StartItem(entity this, GameItem def)
1196 {
1197     _StartItem(
1198         this,
1199         this.itemdef = def,
1200         def.m_respawntime(), // defaultrespawntime
1201         def.m_respawntimejitter(), // defaultrespawntimejitter
1202         def.m_name, // itemname
1203         def.m_itemid, // itemid
1204         0, // weaponid
1205         def.m_itemflags // itemflags
1206         );
1207 }
1208
1209 spawnfunc(item_rockets)
1210 {
1211         if(!self.ammo_rockets)
1212                 self.ammo_rockets = g_pickup_rockets;
1213         if(!self.pickup_anyway)
1214                 self.pickup_anyway = g_pickup_ammo_anyway;
1215     StartItem(this, ITEM_Rockets);
1216 }
1217
1218 spawnfunc(item_bullets)
1219 {
1220         if(!weaponswapping)
1221         if(autocvar_sv_q3acompat_machineshotgunswap)
1222         if(self.classname != "droppedweapon")
1223         {
1224                 weaponswapping = true;
1225                 spawnfunc_item_shells(this);
1226                 weaponswapping = false;
1227                 return;
1228         }
1229
1230         if(!self.ammo_nails)
1231                 self.ammo_nails = g_pickup_nails;
1232         if(!self.pickup_anyway)
1233                 self.pickup_anyway = g_pickup_ammo_anyway;
1234     StartItem(this, ITEM_Bullets);
1235 }
1236
1237 spawnfunc(item_cells)
1238 {
1239         if(!self.ammo_cells)
1240                 self.ammo_cells = g_pickup_cells;
1241         if(!self.pickup_anyway)
1242                 self.pickup_anyway = g_pickup_ammo_anyway;
1243         StartItem(this, ITEM_Cells);
1244 }
1245
1246 spawnfunc(item_plasma)
1247 {
1248         if(!self.ammo_plasma)
1249                 self.ammo_plasma = g_pickup_plasma;
1250         if(!self.pickup_anyway)
1251                 self.pickup_anyway = g_pickup_ammo_anyway;
1252         StartItem(this, ITEM_Plasma);
1253 }
1254
1255 spawnfunc(item_shells)
1256 {
1257         if(!weaponswapping)
1258         if(autocvar_sv_q3acompat_machineshotgunswap)
1259         if(self.classname != "droppedweapon")
1260         {
1261                 weaponswapping = true;
1262                 spawnfunc_item_bullets(this);
1263                 weaponswapping = false;
1264                 return;
1265         }
1266
1267         if(!self.ammo_shells)
1268                 self.ammo_shells = g_pickup_shells;
1269         if(!self.pickup_anyway)
1270                 self.pickup_anyway = g_pickup_ammo_anyway;
1271         StartItem(this, ITEM_Shells);
1272 }
1273
1274 spawnfunc(item_armor_small)
1275 {
1276         if(!self.armorvalue)
1277                 self.armorvalue = g_pickup_armorsmall;
1278         if(!self.max_armorvalue)
1279                 self.max_armorvalue = g_pickup_armorsmall_max;
1280         if(!self.pickup_anyway)
1281                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1282         StartItem(this, ITEM_ArmorSmall);
1283 }
1284
1285 spawnfunc(item_armor_medium)
1286 {
1287         if(!self.armorvalue)
1288                 self.armorvalue = g_pickup_armormedium;
1289         if(!self.max_armorvalue)
1290                 self.max_armorvalue = g_pickup_armormedium_max;
1291         if(!self.pickup_anyway)
1292                 self.pickup_anyway = g_pickup_armormedium_anyway;
1293         StartItem(this, ITEM_ArmorMedium);
1294 }
1295
1296 spawnfunc(item_armor_big)
1297 {
1298         if(!self.armorvalue)
1299                 self.armorvalue = g_pickup_armorbig;
1300         if(!self.max_armorvalue)
1301                 self.max_armorvalue = g_pickup_armorbig_max;
1302         if(!self.pickup_anyway)
1303                 self.pickup_anyway = g_pickup_armorbig_anyway;
1304         StartItem(this, ITEM_ArmorLarge);
1305 }
1306
1307 spawnfunc(item_armor_large)
1308 {
1309         if(!self.armorvalue)
1310                 self.armorvalue = g_pickup_armorlarge;
1311         if(!self.max_armorvalue)
1312                 self.max_armorvalue = g_pickup_armorlarge_max;
1313         if(!self.pickup_anyway)
1314                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1315         StartItem(this, ITEM_ArmorMega);
1316 }
1317
1318 spawnfunc(item_health_small)
1319 {
1320         if(!self.max_health)
1321                 self.max_health = g_pickup_healthsmall_max;
1322         if(!self.health)
1323                 self.health = g_pickup_healthsmall;
1324         if(!self.pickup_anyway)
1325                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1326         StartItem(this, ITEM_HealthSmall);
1327 }
1328
1329 spawnfunc(item_health_medium)
1330 {
1331         if(!self.max_health)
1332                 self.max_health = g_pickup_healthmedium_max;
1333         if(!self.health)
1334                 self.health = g_pickup_healthmedium;
1335         if(!self.pickup_anyway)
1336                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1337     StartItem(this, ITEM_HealthMedium);
1338 }
1339
1340 spawnfunc(item_health_large)
1341 {
1342         if(!self.max_health)
1343                 self.max_health = g_pickup_healthlarge_max;
1344         if(!self.health)
1345                 self.health = g_pickup_healthlarge;
1346         if(!self.pickup_anyway)
1347                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1348         StartItem(this, ITEM_HealthLarge);
1349 }
1350
1351 spawnfunc(item_health_mega)
1352 {
1353     if(!self.max_health)
1354         self.max_health = g_pickup_healthmega_max;
1355     if(!self.health)
1356         self.health = g_pickup_healthmega;
1357     if(!self.pickup_anyway)
1358         self.pickup_anyway = g_pickup_healthmega_anyway;
1359     StartItem(this, ITEM_HealthMega);
1360 }
1361
1362 // support old misnamed entities
1363 spawnfunc(item_armor1) { spawnfunc_item_armor_small(this); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1364 spawnfunc(item_armor25) { spawnfunc_item_armor_large(this); }
1365 spawnfunc(item_health1) { spawnfunc_item_health_small(this); }
1366 spawnfunc(item_health25) { spawnfunc_item_health_medium(this); }
1367 spawnfunc(item_health100) { spawnfunc_item_health_mega(this); }
1368
1369 spawnfunc(item_strength)
1370 {
1371                 if(!self.strength_finished)
1372                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1373                 StartItem(this, ITEM_Strength);
1374 }
1375
1376 spawnfunc(item_invincible)
1377 {
1378                 if(!self.invincible_finished)
1379                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1380                 StartItem(this, ITEM_Shield);
1381 }
1382
1383 // compatibility:
1384 spawnfunc(item_quad) { self.classname = "item_strength";spawnfunc_item_strength(this);}
1385
1386 void target_items_use()
1387 {SELFPARAM();
1388         if(activator.classname == "droppedweapon")
1389         {
1390                 EXACTTRIGGER_TOUCH;
1391                 remove(activator);
1392                 return;
1393         }
1394
1395         if (!IS_PLAYER(activator))
1396                 return;
1397         if(activator.deadflag != DEAD_NO)
1398                 return;
1399         EXACTTRIGGER_TOUCH;
1400
1401         entity e;
1402         for(e = world; (e = find(e, classname, "droppedweapon")); )
1403                 if(e.enemy == activator)
1404                         remove(e);
1405
1406         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1407                 centerprint(activator, self.message);
1408 }
1409
1410 spawnfunc(target_items)
1411 {
1412         float n, i, j;
1413         entity e;
1414         string s;
1415
1416         self.use = target_items_use;
1417         if(!self.strength_finished)
1418                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1419         if(!self.invincible_finished)
1420                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1421         if(!self.superweapons_finished)
1422                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1423
1424         n = tokenize_console(self.netname);
1425         if(argv(0) == "give")
1426         {
1427                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1428         }
1429         else
1430         {
1431                 for(i = 0; i < n; ++i)
1432                 {
1433                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1434                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1435                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1436                         else if(argv(i) == "strength")               self.items |= ITEM_Strength.m_itemid;
1437                         else if(argv(i) == "invincible")             self.items |= ITEM_Shield.m_itemid;
1438                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1439                         else if(argv(i) == "jetpack")                self.items |= ITEM_Jetpack.m_itemid;
1440                         else if(argv(i) == "fuel_regen")             self.items |= ITEM_JetpackRegen.m_itemid;
1441                         else
1442                         {
1443                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1444                                 {
1445                                         e = get_weaponinfo(j);
1446                                         s = W_UndeprecateName(argv(i));
1447                                         if(s == e.netname)
1448                                         {
1449                                                 self.weapons |= WepSet_FromWeapon(j);
1450                                                 if(self.spawnflags == 0 || self.spawnflags == 2) {
1451                                                         Weapon w = get_weaponinfo(e.weapon);
1452                                                         w.wr_init(w);
1453                                                 }
1454                                                 break;
1455                                         }
1456                                 }
1457                                 if(j > WEP_LAST)
1458                                         LOG_INFO("target_items: invalid item ", argv(i), "\n");
1459                         }
1460                 }
1461
1462                 string itemprefix, valueprefix;
1463                 if(self.spawnflags == 0)
1464                 {
1465                         itemprefix = "";
1466                         valueprefix = "";
1467                 }
1468                 else if(self.spawnflags == 1)
1469                 {
1470                         itemprefix = "max ";
1471                         valueprefix = "max ";
1472                 }
1473                 else if(self.spawnflags == 2)
1474                 {
1475                         itemprefix = "min ";
1476                         valueprefix = "min ";
1477                 }
1478                 else if(self.spawnflags == 4)
1479                 {
1480                         itemprefix = "minus ";
1481                         valueprefix = "max ";
1482                 }
1483                 else
1484                 {
1485                         error("invalid spawnflags");
1486                         itemprefix = valueprefix = string_null;
1487                 }
1488
1489                 self.netname = "";
1490                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1491                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1492                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & ITEM_Strength.m_itemid), "strength");
1493                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & ITEM_Shield.m_itemid), "invincible");
1494                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1495                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & ITEM_Jetpack.m_itemid), "jetpack");
1496                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1497                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1498                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1499                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1500                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1501                 if(self.ammo_plasma != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_plasma), "plasma");
1502                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1503                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1504                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1505                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1506                 {
1507                         e = get_weaponinfo(j);
1508                         if(e.weapon)
1509                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & WepSet_FromWeapon(j)), e.netname);
1510                 }
1511         }
1512         self.netname = strzone(self.netname);
1513         //print(self.netname, "\n");
1514
1515         n = tokenize_console(self.netname);
1516         for(i = 0; i < n; ++i)
1517         {
1518                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1519                 {
1520                         e = get_weaponinfo(j);
1521                         if(argv(i) == e.netname)
1522                         {
1523                                 Weapon w = get_weaponinfo(e.weapon);
1524                                 w.wr_init(w);
1525                                 break;
1526                         }
1527                 }
1528         }
1529 }
1530
1531 spawnfunc(item_fuel)
1532 {
1533         if(!self.ammo_fuel)
1534                 self.ammo_fuel = g_pickup_fuel;
1535         if(!self.pickup_anyway)
1536                 self.pickup_anyway = g_pickup_ammo_anyway;
1537         StartItem(this, ITEM_JetpackFuel);
1538 }
1539
1540 spawnfunc(item_fuel_regen)
1541 {
1542         if(start_items & ITEM_JetpackRegen.m_itemid)
1543         {
1544                 spawnfunc_item_fuel(this);
1545                 return;
1546         }
1547         StartItem(this, ITEM_JetpackRegen);
1548 }
1549
1550 spawnfunc(item_jetpack)
1551 {
1552         if(!self.ammo_fuel)
1553                 self.ammo_fuel = g_pickup_fuel_jetpack;
1554         if(start_items & ITEM_Jetpack.m_itemid)
1555         {
1556                 spawnfunc_item_fuel(this);
1557                 return;
1558         }
1559         StartItem(this, ITEM_Jetpack);
1560 }
1561
1562 float GiveWeapon(entity e, float wpn, float op, float val)
1563 {
1564         WepSet v0, v1;
1565         v0 = (e.weapons & WepSet_FromWeapon(wpn));
1566         switch(op)
1567         {
1568                 case OP_SET:
1569                         if(val > 0)
1570                                 e.weapons |= WepSet_FromWeapon(wpn);
1571                         else
1572                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1573                         break;
1574                 case OP_MIN:
1575                 case OP_PLUS:
1576                         if(val > 0)
1577                                 e.weapons |= WepSet_FromWeapon(wpn);
1578                         break;
1579                 case OP_MAX:
1580                         if(val <= 0)
1581                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1582                         break;
1583                 case OP_MINUS:
1584                         if(val > 0)
1585                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1586                         break;
1587         }
1588         v1 = (e.weapons & WepSet_FromWeapon(wpn));
1589         return (v0 != v1);
1590 }
1591
1592 float GiveBit(entity e, .float fld, float bit, float op, float val)
1593 {
1594         float v0, v1;
1595         v0 = (e.(fld) & bit);
1596         switch(op)
1597         {
1598                 case OP_SET:
1599                         if(val > 0)
1600                                 e.(fld) |= bit;
1601                         else
1602                                 e.(fld) &= ~bit;
1603                         break;
1604                 case OP_MIN:
1605                 case OP_PLUS:
1606                         if(val > 0)
1607                                 e.(fld) |= bit;
1608                         break;
1609                 case OP_MAX:
1610                         if(val <= 0)
1611                                 e.(fld) &= ~bit;
1612                         break;
1613                 case OP_MINUS:
1614                         if(val > 0)
1615                                 e.(fld) &= ~bit;
1616                         break;
1617         }
1618         v1 = (e.(fld) & bit);
1619         return (v0 != v1);
1620 }
1621
1622 float GiveValue(entity e, .float fld, float op, float val)
1623 {
1624         float v0, v1;
1625         v0 = e.(fld);
1626         switch(op)
1627         {
1628                 case OP_SET:
1629                         e.(fld) = val;
1630                         break;
1631                 case OP_MIN:
1632                         e.(fld) = max(e.(fld), val); // min 100 cells = at least 100 cells
1633                         break;
1634                 case OP_MAX:
1635                         e.(fld) = min(e.(fld), val);
1636                         break;
1637                 case OP_PLUS:
1638                         e.(fld) += val;
1639                         break;
1640                 case OP_MINUS:
1641                         e.(fld) -= val;
1642                         break;
1643         }
1644         v1 = e.(fld);
1645         return (v0 != v1);
1646 }
1647
1648 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1649 {
1650         if(v1 == v0)
1651                 return;
1652         if(v1 <= v0 - t)
1653         {
1654                 if(snd_decr != "")
1655                         _sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1656         }
1657         else if(v0 >= v0 + t)
1658         {
1659                 if(snd_incr != "")
1660                         _sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1661         }
1662 }
1663
1664 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1665 {
1666         if(v0 < v1)
1667                 e.(rotfield) = max(e.(rotfield), time + rottime);
1668         else if(v0 > v1)
1669                 e.(regenfield) = max(e.(regenfield), time + regentime);
1670 }
1671 float GiveItems(entity e, float beginarg, float endarg)
1672 {SELFPARAM();
1673         float got, i, j, val, op;
1674         float _switchweapon;
1675         entity wi;
1676         string cmd;
1677
1678         val = 999;
1679         op = OP_SET;
1680
1681         got = 0;
1682
1683         _switchweapon = false;
1684         if (e.autoswitch)
1685                 if (e.switchweapon == w_getbestweapon(e))
1686                         _switchweapon = true;
1687
1688         e.strength_finished = max(0, e.strength_finished - time);
1689         e.invincible_finished = max(0, e.invincible_finished - time);
1690         e.superweapons_finished = max(0, e.superweapons_finished - time);
1691
1692         PREGIVE(e, items);
1693         PREGIVE_WEAPONS(e);
1694         PREGIVE(e, strength_finished);
1695         PREGIVE(e, invincible_finished);
1696         PREGIVE(e, superweapons_finished);
1697         PREGIVE(e, ammo_nails);
1698         PREGIVE(e, ammo_cells);
1699         PREGIVE(e, ammo_plasma);
1700         PREGIVE(e, ammo_shells);
1701         PREGIVE(e, ammo_rockets);
1702         PREGIVE(e, ammo_fuel);
1703         PREGIVE(e, armorvalue);
1704         PREGIVE(e, health);
1705
1706         for(i = beginarg; i < endarg; ++i)
1707         {
1708                 cmd = argv(i);
1709
1710                 if(cmd == "0" || stof(cmd))
1711                 {
1712                         val = stof(cmd);
1713                         continue;
1714                 }
1715                 switch(cmd)
1716                 {
1717                         case "no":
1718                                 op = OP_MAX;
1719                                 val = 0;
1720                                 continue;
1721                         case "max":
1722                                 op = OP_MAX;
1723                                 continue;
1724                         case "min":
1725                                 op = OP_MIN;
1726                                 continue;
1727                         case "plus":
1728                                 op = OP_PLUS;
1729                                 continue;
1730                         case "minus":
1731                                 op = OP_MINUS;
1732                                 continue;
1733                         case "ALL":
1734                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1735                                 got += GiveValue(e, strength_finished, op, val);
1736                                 got += GiveValue(e, invincible_finished, op, val);
1737                                 got += GiveValue(e, superweapons_finished, op, val);
1738                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1739                         case "all":
1740                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1741                                 got += GiveValue(e, health, op, val);
1742                                 got += GiveValue(e, armorvalue, op, val);
1743                         case "allweapons":
1744                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1745                                 {
1746                                         wi = get_weaponinfo(j);
1747                                         if(wi.weapon)
1748                                                 if (!(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED))
1749                                                         got += GiveWeapon(e, j, op, val);
1750                                 }
1751                         case "allammo":
1752                                 got += GiveValue(e, ammo_cells, op, val);
1753                                 got += GiveValue(e, ammo_plasma, op, val);
1754                                 got += GiveValue(e, ammo_shells, op, val);
1755                                 got += GiveValue(e, ammo_nails, op, val);
1756                                 got += GiveValue(e, ammo_rockets, op, val);
1757                                 got += GiveValue(e, ammo_fuel, op, val);
1758                                 break;
1759                         case "unlimited_ammo":
1760                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1761                                 break;
1762                         case "unlimited_weapon_ammo":
1763                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1764                                 break;
1765                         case "unlimited_superweapons":
1766                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1767                                 break;
1768                         case "jetpack":
1769                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1770                                 break;
1771                         case "fuel_regen":
1772                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1773                                 break;
1774                         case "strength":
1775                                 got += GiveValue(e, strength_finished, op, val);
1776                                 break;
1777                         case "invincible":
1778                                 got += GiveValue(e, invincible_finished, op, val);
1779                                 break;
1780                         case "superweapons":
1781                                 got += GiveValue(e, superweapons_finished, op, val);
1782                                 break;
1783                         case "cells":
1784                                 got += GiveValue(e, ammo_cells, op, val);
1785                                 break;
1786                         case "plasma":
1787                                 got += GiveValue(e, ammo_plasma, op, val);
1788                                 break;
1789                         case "shells":
1790                                 got += GiveValue(e, ammo_shells, op, val);
1791                                 break;
1792                         case "nails":
1793                         case "bullets":
1794                                 got += GiveValue(e, ammo_nails, op, val);
1795                                 break;
1796                         case "rockets":
1797                                 got += GiveValue(e, ammo_rockets, op, val);
1798                                 break;
1799                         case "health":
1800                                 got += GiveValue(e, health, op, val);
1801                                 break;
1802                         case "armor":
1803                                 got += GiveValue(e, armorvalue, op, val);
1804                                 break;
1805                         case "fuel":
1806                                 got += GiveValue(e, ammo_fuel, op, val);
1807                                 break;
1808                         default:
1809                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1810                                 {
1811                                         wi = get_weaponinfo(j);
1812                                         if(cmd == wi.netname)
1813                                         {
1814                                                 got += GiveWeapon(e, j, op, val);
1815                                                 break;
1816                                         }
1817                                 }
1818                                 if(j > WEP_LAST)
1819                                         LOG_INFO("give: invalid item ", cmd, "\n");
1820                                 break;
1821                 }
1822                 val = 999;
1823                 op = OP_SET;
1824         }
1825
1826         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND(ITEMPICKUP), string_null);
1827         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND(POWERUP), SND(POWEROFF));
1828         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND(POWERUP), SND(POWEROFF));
1829         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND(ITEMPICKUP), string_null);
1830         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1831         {
1832                 wi = get_weaponinfo(j);
1833                 if(wi.weapon)
1834                 {
1835                         POSTGIVE_WEAPON(e, j, SND(WEAPONPICKUP), string_null);
1836                         if (!(save_weapons & WepSet_FromWeapon(j)))
1837                                 if(e.weapons & WepSet_FromWeapon(j)) {
1838                                         Weapon w = get_weaponinfo(wi.weapon);
1839                                         w.wr_init(w);
1840                                 }
1841                 }
1842         }
1843         POSTGIVE_VALUE(e, strength_finished, 1, SND(POWERUP), SND(POWEROFF));
1844         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", SND(POWEROFF));
1845         POSTGIVE_VALUE(e, ammo_nails, 0, SND(ITEMPICKUP), string_null);
1846         POSTGIVE_VALUE(e, ammo_cells, 0, SND(ITEMPICKUP), string_null);
1847         POSTGIVE_VALUE(e, ammo_plasma, 0, SND(ITEMPICKUP), string_null);
1848         POSTGIVE_VALUE(e, ammo_shells, 0, SND(ITEMPICKUP), string_null);
1849         POSTGIVE_VALUE(e, ammo_rockets, 0, SND(ITEMPICKUP), string_null);
1850         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND(ITEMPICKUP), string_null);
1851         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND(ARMOR25), string_null);
1852         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND(MEGAHEALTH), string_null);
1853
1854         if(e.superweapons_finished <= 0)
1855                 if(self.weapons & WEPSET_SUPERWEAPONS)
1856                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1857
1858         if(e.strength_finished <= 0)
1859                 e.strength_finished = 0;
1860         else
1861                 e.strength_finished += time;
1862         if(e.invincible_finished <= 0)
1863                 e.invincible_finished = 0;
1864         else
1865                 e.invincible_finished += time;
1866         if(e.superweapons_finished <= 0)
1867                 e.superweapons_finished = 0;
1868         else
1869                 e.superweapons_finished += time;
1870
1871         if (!(e.weapons & WepSet_FromWeapon(e.switchweapon)))
1872                 _switchweapon = true;
1873         if(_switchweapon)
1874                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1875
1876         return got;
1877 }
1878 #endif