qcsrc/server/mutators/mutator_overkill.qc

   1 void ok_DecreaseCharge(entity ent, float wep)
   2 {
   3         if(!ent.ok_use_ammocharge) return;
   4
   5         entity wepent = get_weaponinfo(wep);
   6
   7         if(wepent.weapon == 0)
   8                 return; // dummy
   9
  10         ent.ammo_charge[wep] -= max(0, cvar(sprintf("g_overkill_ammo_decharge_%s", wepent.netname)));
  11 }
  12
  13 void ok_IncreaseCharge(entity ent, float wep)
  14 {
  15         entity wepent = get_weaponinfo(wep);
  16
  17         if(wepent.weapon == 0)
  18                 return; // dummy
  19
  20         if(ent.ok_use_ammocharge)
  21         if(!ent.BUTTON_ATCK) // not while attacking?
  22                 ent.ammo_charge[wep] = min(autocvar_g_overkill_ammo_charge_limit, ent.ammo_charge[wep] + cvar(sprintf("g_overkill_ammo_charge_rate_%s", wepent.netname)) * frametime / W_TICSPERFRAME);
  23 }
  24
  25 float ok_CheckWeaponCharge(entity ent, float wep)
  26 {
  27         if(!ent.ok_use_ammocharge) return TRUE;
  28
  29         entity wepent = get_weaponinfo(wep);
  30
  31         if(wepent.weapon == 0)
  32                 return 0; // dummy
  33
  34         return (ent.ammo_charge[wep] >= cvar(sprintf("g_overkill_ammo_decharge_%s", wepent.netname)));
  35 }
  36
  37 void start_hmg()
  38 {
  39         self.classname = "weapon_hmg";
  40         self.respawntime = autocvar_g_overkill_superguns_respawn_time;
  41         self.ok_item = TRUE;
  42         setmodel(self, "models/weapons/g_ok_hmg.md3");
  43         self.pickup_anyway = TRUE;
  44         spawnfunc_weapon_hmg();
  45 }
  46
  47 void start_rpc()
  48 {
  49         self.classname = "weapon_rpc";
  50         self.respawntime = autocvar_g_overkill_superguns_respawn_time;
  51         self.ok_item = TRUE;
  52         self.pickup_anyway = TRUE;
  53         setmodel(self, "models/weapons/g_ok_rl.md3");
  54         spawnfunc_weapon_rpc();
  55 }
  56
  57 MUTATOR_HOOKFUNCTION(ok_PlayerDamage_Calculate)
  58 {
  59         if(IS_PLAYER(frag_attacker) && IS_PLAYER(frag_target))
  60         if(DEATH_ISWEAPON(frag_deathtype, WEP_BLASTER))
  61         {
  62                 frag_damage = 0;
  63
  64                 if(frag_attacker != frag_target)
  65                 if(frag_target.health > 0)
  66                 if(frag_target.frozen == 0)
  67                 if(frag_target.deadflag == DEAD_NO)
  68                 {
  69                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_SECONDARY_NODAMAGE);
  70                         frag_force = '0 0 0';
  71                 }
  72         }
  73
  74         return FALSE;
  75 }
  76
  77 MUTATOR_HOOKFUNCTION(ok_PlayerDamage_SplitHealthArmor)
  78 {
  79         if(damage_take)
  80                 self.ok_pauseregen_finished = max(self.ok_pauseregen_finished, time + 2);
  81         return FALSE;
  82 }
  83
  84 MUTATOR_HOOKFUNCTION(ok_PlayerDies)
  85 {
  86         entity oldself = self;
  87
  88         if(self.flags & FL_MONSTER)
  89         {
  90                 remove(other); // remove default item
  91                 other = world;
  92         }
  93
  94         self = spawn();
  95         self.ok_item = TRUE;
  96         self.noalign = TRUE;
  97         self.pickup_anyway = TRUE;
  98         spawnfunc_item_armor_small();
  99         self.movetype = MOVETYPE_TOSS;
 100         self.gravity = 1;
 101         self.reset = SUB_Remove;
 102         setorigin(self, frag_target.origin + '0 0 32');
 103         self.velocity = '0 0 200' + normalize(frag_attacker.origin - self.origin) * 500;
 104         self.classname = "droppedweapon"; // hax
 105         SUB_SetFade(self, time + 5, 1);
 106         self = oldself;
 107
 108         self.ok_lastwep = self.switchweapon;
 109
 110         return FALSE;
 111 }
 112
 113 MUTATOR_HOOKFUNCTION(ok_PlayerRegen)
 114 {
 115         // overkill's values are different, so use custom regen
 116         if(!self.frozen)
 117         {
 118                 self.armorvalue = CalcRotRegen(self.armorvalue, autocvar_g_balance_armor_regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, 1 * frametime * (time > self.ok_pauseregen_finished), 0, 0, 1, 1 * frametime * (time > self.pauserotarmor_finished), autocvar_g_balance_armor_limit);
 119                 self.health = CalcRotRegen(self.health, autocvar_g_balance_health_regenstable, 0, 100, 1 * frametime * (time > self.ok_pauseregen_finished), 200, 0, autocvar_g_balance_health_rotlinear, 1 * frametime * (time > self.pauserothealth_finished), autocvar_g_balance_health_limit);
 120
 121                 float minf, maxf, limitf;
 122
 123                 maxf = autocvar_g_balance_fuel_rotstable;
 124                 minf = autocvar_g_balance_fuel_regenstable;
 125                 limitf = autocvar_g_balance_fuel_limit;
 126
 127                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
 128         }
 129         return TRUE; // return TRUE anyway, as frozen uses no regen
 130 }
 131
 132 MUTATOR_HOOKFUNCTION(ok_ForbidThrowCurrentWeapon)
 133 {
 134         return TRUE;
 135 }
 136
 137 MUTATOR_HOOKFUNCTION(ok_PlayerPreThink)
 138 {
 139         if(intermission_running || gameover)
 140                 return FALSE;
 141
 142         if(self.deadflag != DEAD_NO || !IS_PLAYER(self) || self.frozen)
 143                 return FALSE;
 144
 145         if(self.ok_lastwep)
 146         {
 147                 self.switchweapon = self.ok_lastwep;
 148                 self.ok_lastwep = 0;
 149         }
 150
 151         ok_IncreaseCharge(self, self.weapon);
 152
 153         if(self.BUTTON_ATCK2)
 154         if(!forbidWeaponUse() || self.weapon_blocked) // allow if weapon is blocked
 155         if(time >= self.jump_interval)
 156         {
 157                 self.jump_interval = time + WEP_CVAR_PRI(blaster, refire) * W_WeaponRateFactor();
 158                 makevectors(self.v_angle);
 159
 160                 W_Blaster_Attack(
 161                         WEP_BLASTER | HITTYPE_SECONDARY,
 162                         WEP_CVAR_SEC(vaporizer, shotangle),
 163                         WEP_CVAR_SEC(vaporizer, damage),
 164                         WEP_CVAR_SEC(vaporizer, edgedamage),
 165                         WEP_CVAR_SEC(vaporizer, radius),
 166                         WEP_CVAR_SEC(vaporizer, force),
 167                         WEP_CVAR_SEC(vaporizer, speed),
 168                         WEP_CVAR_SEC(vaporizer, spread),
 169                         WEP_CVAR_SEC(vaporizer, delay),
 170                         WEP_CVAR_SEC(vaporizer, lifetime)
 171                 );
 172         }
 173
 174         self.weapon_blocked = FALSE;
 175
 176         self.ok_ammo_charge = self.ammo_charge[self.weapon];
 177
 178         if(self.ok_use_ammocharge)
 179         if(!ok_CheckWeaponCharge(self, self.weapon))
 180         {
 181                 if(autocvar_g_overkill_ammo_charge_notice && time > self.ok_notice_time && self.BUTTON_ATCK && IS_REAL_CLIENT(self) && self.weapon == self.switchweapon)
 182                 {
 183                         //Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_OVERKILL_CHARGE);
 184                         self.ok_notice_time = time + 2;
 185                         play2(self, "weapons/dryfire.wav");
 186                 }
 187                 if(self.weaponentity.state != WS_CLEAR)
 188                         w_ready();
 189
 190                 self.weapon_blocked = TRUE;
 191         }
 192
 193         self.BUTTON_ATCK2 = 0;
 194
 195         return FALSE;
 196 }
 197
 198 MUTATOR_HOOKFUNCTION(ok_PlayerSpawn)
 199 {
 200         if(autocvar_g_overkill_ammo_charge)
 201         {
 202                 float i;
 203
 204                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 205                         self.ammo_charge[i] = autocvar_g_overkill_ammo_charge_limit;
 206
 207                 self.ok_use_ammocharge = 1;
 208                 self.ok_notice_time = time;
 209         }
 210         else
 211                 self.ok_use_ammocharge = 0;
 212
 213         self.ok_pauseregen_finished = time + 2;
 214
 215         return FALSE;
 216 }
 217
 218 MUTATOR_HOOKFUNCTION(ok_OnEntityPreSpawn)
 219 {
 220         if(autocvar_g_powerups)
 221         if(autocvar_g_overkill_powerups_replace)
 222         {
 223                 if(self.classname == "item_strength")
 224                 {
 225                         entity wep = spawn();
 226                         setorigin(wep, self.origin);
 227                         setmodel(wep, "models/weapons/g_ok_hmg.md3");
 228                         wep.classname = "weapon_hmg";
 229                         wep.ok_item = TRUE;
 230                         wep.noalign = self.noalign;
 231                         wep.cnt = self.cnt;
 232                         wep.team = self.team;
 233                         wep.respawntime = autocvar_g_overkill_superguns_respawn_time;
 234                         wep.pickup_anyway = TRUE;
 235                         wep.think = spawnfunc_weapon_hmg;
 236                         wep.nextthink = time + 0.1;
 237                         return TRUE;
 238                 }
 239
 240                 if(self.classname == "item_invincible")
 241                 {
 242                         entity wep = spawn();
 243                         setorigin(wep, self.origin);
 244                         setmodel(wep, "models/weapons/g_ok_rl.md3");
 245                         wep.classname = "weapon_rpc";
 246                         wep.ok_item = TRUE;
 247                         wep.noalign = self.noalign;
 248                         wep.cnt = self.cnt;
 249                         wep.team = self.team;
 250                         wep.respawntime = autocvar_g_overkill_superguns_respawn_time;
 251                         wep.pickup_anyway = TRUE;
 252                         wep.think = spawnfunc_weapon_rpc;
 253                         wep.nextthink = time + 0.1;
 254                         return TRUE;
 255                 }
 256         }
 257
 258         return FALSE;
 259 }
 260
 261 MUTATOR_HOOKFUNCTION(ok_ItemRemove)
 262 {
 263         if(self.ok_item)
 264                 return FALSE;
 265
 266         switch(self.items)
 267         {
 268                 case IT_HEALTH: return !(autocvar_g_overkill_100h_anyway);
 269                 case IT_ARMOR: return !(autocvar_g_overkill_100a_anyway);
 270         }
 271
 272         return TRUE;
 273 }
 274
 275 MUTATOR_HOOKFUNCTION(ok_SpectateCopy)
 276 {
 277         self.ammo_charge[self.weapon] = other.ammo_charge[other.weapon];
 278         self.ok_use_ammocharge = other.ok_use_ammocharge;
 279
 280         return FALSE;
 281 }
 282
 283 MUTATOR_HOOKFUNCTION(ok_StartItems)
 284 {
 285         WepSet ok_start_items = (WEPSET_MACHINEGUN | WEPSET_VORTEX | WEPSET_SHOTGUN);
 286
 287         if((get_weaponinfo(WEP_RPC)).weaponstart > 0) { ok_start_items |= WEPSET_RPC; }
 288         if((get_weaponinfo(WEP_HMG)).weaponstart > 0) { ok_start_items |= WEPSET_HMG; }
 289
 290         start_items |= IT_UNLIMITED_WEAPON_AMMO;
 291         start_weapons = warmup_start_weapons = ok_start_items;
 292
 293         return FALSE;
 294 }
 295
 296 MUTATOR_HOOKFUNCTION(ok_BuildMutatorsString)
 297 {
 298         ret_string = strcat(ret_string, ":OK");
 299         return FALSE;
 300 }
 301
 302 MUTATOR_HOOKFUNCTION(ok_BuildMutatorsPrettyString)
 303 {
 304         ret_string = strcat(ret_string, ", Overkill");
 305         return FALSE;
 306 }
 307
 308 MUTATOR_HOOKFUNCTION(ok_SetModname)
 309 {
 310         modname = "Overkill";
 311         return TRUE;
 312 }
 313
 314 void ok_SetCvars()
 315 {
 316         // hack to force overkill playermodels
 317         cvar_settemp("sv_defaultcharacter", "1");
 318         cvar_settemp("sv_defaultplayermodel", "models/ok_player/okrobot1.dpm models/ok_player/okrobot2.dpm models/ok_player/okrobot3.dpm models/ok_player/okrobot4.dpm models/ok_player/okmale1.dpm models/ok_player/okmale2.dpm models/ok_player/okmale3.dpm models/ok_player/okmale4.dpm");
 319         cvar_settemp("sv_defaultplayermodel_red", "models/ok_player/okrobot1.dpm models/ok_player/okrobot2.dpm models/ok_player/okrobot3.dpm models/ok_player/okrobot4.dpm");
 320         cvar_settemp("sv_defaultplayermodel_blue", "models/ok_player/okmale1.dpm models/ok_player/okmale2.dpm models/ok_player/okmale3.dpm models/ok_player/okmale4.dpm");
 321 }
 322
 323 void ok_Initialize()
 324 {
 325         ok_SetCvars();
 326
 327         precache_all_playermodels("models/ok_player/*.dpm");
 328
 329         precache_model("models/weapons/h_ok_mg.iqm");
 330         precache_model("models/weapons/v_ok_mg.md3");
 331         precache_model("models/weapons/g_ok_mg.md3");
 332
 333         precache_model("models/weapons/h_ok_shotgun.iqm");
 334         precache_model("models/weapons/v_ok_shotgun.md3");
 335         precache_model("models/weapons/g_ok_shotgun.md3");
 336
 337         precache_model("models/weapons/h_ok_sniper.iqm");
 338         precache_model("models/weapons/v_ok_sniper.md3");
 339         precache_model("models/weapons/g_ok_sniper.md3");
 340
 341         precache_sound("weapons/dryfire.wav");
 342
 343         addstat(STAT_OK_AMMO_CHARGE, AS_FLOAT, ok_use_ammocharge);
 344         addstat(STAT_OK_AMMO_CHARGEPOOl, AS_FLOAT, ok_ammo_charge);
 345
 346         WEP_ACTION(WEP_MACHINEGUN, WR_INIT);
 347         WEP_ACTION(WEP_VORTEX, WR_INIT);
 348         WEP_ACTION(WEP_SHOTGUN, WR_INIT);
 349         WEP_ACTION(WEP_BLASTER, WR_INIT);
 350
 351         WEP_ACTION(WEP_RPC, WR_INIT);
 352         WEP_ACTION(WEP_HMG, WR_INIT);
 353
 354         (get_weaponinfo(WEP_RPC)).spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 355         (get_weaponinfo(WEP_HMG)).spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 356
 357         (get_weaponinfo(WEP_SHOTGUN)).mdl = "ok_shotgun";
 358         (get_weaponinfo(WEP_MACHINEGUN)).mdl = "ok_mg";
 359         (get_weaponinfo(WEP_VORTEX)).mdl = "ok_sniper";
 360 }
 361
 362 MUTATOR_DEFINITION(mutator_overkill)
 363 {
 364         MUTATOR_HOOK(ForbidThrowCurrentWeapon, ok_ForbidThrowCurrentWeapon, CBC_ORDER_ANY);
 365         MUTATOR_HOOK(PlayerPreThink, ok_PlayerPreThink, CBC_ORDER_LAST);
 366         MUTATOR_HOOK(PlayerSpawn, ok_PlayerSpawn, CBC_ORDER_ANY);
 367         MUTATOR_HOOK(PlayerDamage_Calculate, ok_PlayerDamage_Calculate, CBC_ORDER_LAST);
 368         MUTATOR_HOOK(PlayerDamage_SplitHealthArmor, ok_PlayerDamage_SplitHealthArmor, CBC_ORDER_ANY);
 369         MUTATOR_HOOK(PlayerDies, ok_PlayerDies, CBC_ORDER_ANY);
 370         MUTATOR_HOOK(PlayerRegen, ok_PlayerRegen, CBC_ORDER_ANY);
 371         MUTATOR_HOOK(OnEntityPreSpawn, ok_OnEntityPreSpawn, CBC_ORDER_ANY);
 372         MUTATOR_HOOK(FilterItem, ok_ItemRemove, CBC_ORDER_ANY);
 373         MUTATOR_HOOK(MonsterDropItem, ok_PlayerDies, CBC_ORDER_ANY);
 374         MUTATOR_HOOK(SpectateCopy, ok_SpectateCopy, CBC_ORDER_ANY);
 375         MUTATOR_HOOK(SetStartItems, ok_StartItems, CBC_ORDER_ANY);
 376         MUTATOR_HOOK(BuildMutatorsString, ok_BuildMutatorsString, CBC_ORDER_ANY);
 377         MUTATOR_HOOK(BuildMutatorsPrettyString, ok_BuildMutatorsPrettyString, CBC_ORDER_ANY);
 378         MUTATOR_HOOK(SetModname, ok_SetModname, CBC_ORDER_ANY);
 379
 380         MUTATOR_ONADD
 381         {
 382                 ok_Initialize();
 383         }
 384
 385         MUTATOR_ONREMOVE
 386         {
 387                 (get_weaponinfo(WEP_RPC)).spawnflags |= WEP_FLAG_MUTATORBLOCKED;
 388                 (get_weaponinfo(WEP_HMG)).spawnflags |= WEP_FLAG_MUTATORBLOCKED;
 389         }
 390
 391         return FALSE;
 392 }