qcsrc/server/mutators/mutator_multijump.qc

   1 .float multijump_count;
   2 .float multijump_ready;
   3
   4 #ifdef CSQC
   5
   6 #define PHYS_MOVE_MULTIJUMP                     pm_multijump
   7 #define PHYS_MULTIJUMP                          getstati(STAT_MULTIJUMP)
   8 #define PHYS_MULTIJUMP_SPEED            getstatf(STAT_MULTIJUMP_SPEED)
   9 #define PHYS_MULTIJUMP_ADD                      getstati(STAT_MULTIJUMP_ADD)
  10
  11 #elif defined(SVQC)
  12
  13 #define PHYS_MOVE_MULTIJUMP                     player_multijump
  14 #define PHYS_MULTIJUMP                          autocvar_g_multijump
  15 #define PHYS_MULTIJUMP_SPEED            autocvar_g_multijump_speed
  16 #define PHYS_MULTIJUMP_ADD                      autocvar_g_multijump_add
  17
  18
  19 .float stat_multijump;
  20 .float stat_multijump_speed;
  21 .float stat_multijump_add;
  22
  23 void multijump_UpdateStats()
  24 {
  25         self.stat_multijump = PHYS_MULTIJUMP;
  26         self.stat_multijump_speed = PHYS_MULTIJUMP_SPEED;
  27         self.stat_multijump_add = PHYS_MULTIJUMP_ADD;
  28 }
  29
  30 void multijump_AddStats()
  31 {
  32         addstat(STAT_MULTIJUMP, AS_INT, stat_multijump);
  33         addstat(STAT_MULTIJUMP_SPEED, AS_FLOAT, stat_multijump_speed);
  34         addstat(STAT_MULTIJUMP_ADD, AS_INT, stat_multijump_add);
  35 }
  36
  37 #endif
  38
  39 void PM_multijump()
  40 {
  41         if(!PHYS_MULTIJUMP) { return; }
  42
  43         if(IS_ONGROUND(self))
  44         {
  45                 if (PHYS_MULTIJUMP > 0)
  46                         self.multijump_count = 0;
  47                 else
  48                         self.multijump_count = -2; // the cvar value for infinite jumps is -1, so this needs to be smaller
  49         }
  50
  51 #ifdef SVQC
  52         multijump_UpdateStats();
  53 #endif
  54 }
  55
  56 float PM_multijump_checkjump()
  57 {
  58         if(!PHYS_MULTIJUMP) { return FALSE; }
  59
  60         if (!IS_JUMP_HELD(self) && !IS_ONGROUND(self)) // jump button pressed this frame and we are in midair
  61                 self.multijump_ready = TRUE;  // this is necessary to check that we released the jump button and pressed it again
  62         else
  63                 self.multijump_ready = FALSE;
  64
  65         if(!PHYS_MOVE_MULTIJUMP && self.multijump_ready && self.multijump_count < PHYS_MULTIJUMP && self.velocity_z > PHYS_MULTIJUMP_SPEED)
  66         {
  67                 if (PHYS_MULTIJUMP)
  68                 {
  69                         if (!PHYS_MULTIJUMP_ADD) // in this case we make the z velocity == jumpvelocity
  70                         {
  71                                 if (self.velocity_z < PHYS_JUMPVELOCITY)
  72                                 {
  73                                         PHYS_MOVE_MULTIJUMP = TRUE;
  74                                         self.velocity_z = 0;
  75                                 }
  76                         }
  77                         else
  78                                 PHYS_MOVE_MULTIJUMP = TRUE;
  79
  80                         if(PHYS_MOVE_MULTIJUMP)
  81                         {
  82                                 if(PHYS_INPUT_MOVEVALUES(self)_x != 0 || PHYS_INPUT_MOVEVALUES(self)_y != 0) // don't remove all speed if player isnt pressing any movement keys
  83                                 {
  84                                         float curspeed = vlen(vec2(self.velocity));
  85                                         vector wishvel, wishdir;
  86
  87                                         makevectors(PHYS_INPUT_ANGLES(self)_y * '0 1 0');
  88                                         wishvel = v_forward * PHYS_INPUT_MOVEVALUES(self)_x + v_right * PHYS_INPUT_MOVEVALUES(self)_y;
  89                                         wishdir = normalize(wishvel);
  90
  91                                         self.velocity_x = wishdir_x * curspeed; // allow "dodging" at a multijump
  92                                         self.velocity_y = wishdir_y * curspeed;
  93                                         // keep velocity_z unchanged!
  94                                 }
  95                                 if (PHYS_MULTIJUMP > 0)
  96                                         self.multijump_count += 1;
  97                         }
  98                 }
  99                 self.multijump_ready = FALSE; // require releasing and pressing the jump button again for the next jump
 100         }
 101
 102         return FALSE;
 103 }
 104
 105 #ifdef SVQC
 106 MUTATOR_HOOKFUNCTION(multijump_PlayerPhysics)
 107 {
 108         PM_multijump();
 109
 110         return FALSE;
 111 }
 112
 113 MUTATOR_HOOKFUNCTION(multijump_PlayerJump)
 114 {
 115         return PM_multijump_checkjump();
 116 }
 117
 118 MUTATOR_HOOKFUNCTION(multijump_BuildMutatorsString)
 119 {
 120         ret_string = strcat(ret_string, ":multijump");
 121         return FALSE;
 122 }
 123
 124 MUTATOR_HOOKFUNCTION(multijump_BuildMutatorsPrettyString)
 125 {
 126         ret_string = strcat(ret_string, ", Multi jump");
 127         return FALSE;
 128 }
 129
 130 MUTATOR_DEFINITION(mutator_multijump)
 131 {
 132         MUTATOR_HOOK(PlayerPhysics, multijump_PlayerPhysics, CBC_ORDER_ANY);
 133         MUTATOR_HOOK(PlayerJump, multijump_PlayerJump, CBC_ORDER_ANY);
 134         MUTATOR_HOOK(BuildMutatorsString, multijump_BuildMutatorsString, CBC_ORDER_ANY);
 135         MUTATOR_HOOK(BuildMutatorsPrettyString, multijump_BuildMutatorsPrettyString, CBC_ORDER_ANY);
 136
 137         MUTATOR_ONADD
 138         {
 139                 multijump_AddStats();
 140         }
 141
 142         return FALSE;
 143 }
 144 #endif