qcsrc/server/mutators/gamemode_lms.qc

   1 #include "gamemode_lms.qh"
   2 #include "../_all.qh"
   3
   4 #include "gamemode.qh"
   5
   6 #include "../campaign.qh"
   7 #include "../command/cmd.qh"
   8
   9 // main functions
  10 float LMS_NewPlayerLives()
  11 {
  12         float fl;
  13         fl = autocvar_fraglimit;
  14         if(fl == 0)
  15                 fl = 999;
  16
  17         // first player has left the game for dying too much? Nobody else can get in.
  18         if(lms_lowest_lives < 1)
  19                 return 0;
  20
  21         if(!autocvar_g_lms_join_anytime)
  22                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
  23                         return 0;
  24
  25         return bound(1, lms_lowest_lives, fl);
  26 }
  27
  28 // mutator hooks
  29 MUTATOR_HOOKFUNCTION(lms_ResetMap)
  30 {
  31         lms_lowest_lives = 999;
  32         lms_next_place = player_count;
  33
  34         return false;
  35 }
  36
  37 MUTATOR_HOOKFUNCTION(lms_ResetPlayers)
  38 {SELFPARAM();
  39         entity e;
  40         if(restart_mapalreadyrestarted || (time < game_starttime))
  41         FOR_EACH_CLIENT(e)
  42         if(IS_PLAYER(e))
  43         {
  44                 SELFCALL(e, PlayerScore_Add(e, SP_LMS_LIVES, LMS_NewPlayerLives()));
  45                 SELFCALL_DONE();
  46         }
  47
  48         return false;
  49 }
  50
  51 MUTATOR_HOOKFUNCTION(lms_PlayerPreSpawn)
  52 {SELFPARAM();
  53         // player is dead and becomes observer
  54         // FIXME fix LMS scoring for new system
  55         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
  56         {
  57                 self.classname = "observer";
  58                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_LMS_NOLIVES);
  59         }
  60
  61         return false;
  62 }
  63
  64 MUTATOR_HOOKFUNCTION(lms_PlayerDies)
  65 {SELFPARAM();
  66         self.respawn_flags |= RESPAWN_FORCE;
  67
  68         return false;
  69 }
  70
  71 MUTATOR_HOOKFUNCTION(lms_RemovePlayer)
  72 {SELFPARAM();
  73         // Only if the player cannot play at all
  74         if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
  75                 self.frags = FRAGS_SPECTATOR;
  76         else
  77                 self.frags = FRAGS_LMS_LOSER;
  78
  79         if(self.killcount != -666)
  80                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0 && self.lms_spectate_warning != 2)
  81                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_NOLIVES, self.netname);
  82                 else
  83                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_FORFEIT, self.netname);
  84
  85         return false;
  86 }
  87
  88 MUTATOR_HOOKFUNCTION(lms_ClientConnect)
  89 {SELFPARAM();
  90         self.classname = "player";
  91         campaign_bots_may_start = 1;
  92
  93         if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
  94         {
  95                 PlayerScore_Add(self, SP_LMS_RANK, 666);
  96                 self.frags = FRAGS_SPECTATOR;
  97         }
  98
  99         return false;
 100 }
 101
 102 MUTATOR_HOOKFUNCTION(lms_PlayerThink)
 103 {SELFPARAM();
 104         if(self.deadflag == DEAD_DYING)
 105                 self.deadflag = DEAD_RESPAWNING;
 106
 107         return false;
 108 }
 109
 110 MUTATOR_HOOKFUNCTION(lms_PlayerRegen)
 111 {
 112         if(autocvar_g_lms_regenerate)
 113                 return false;
 114         return true;
 115 }
 116
 117 MUTATOR_HOOKFUNCTION(lms_ForbidThrowing)
 118 {
 119         // forbode!
 120         return true;
 121 }
 122
 123 MUTATOR_HOOKFUNCTION(lms_GiveFragsForKill)
 124 {
 125         // remove a life
 126         float tl;
 127         tl = PlayerScore_Add(frag_target, SP_LMS_LIVES, -1);
 128         if(tl < lms_lowest_lives)
 129                 lms_lowest_lives = tl;
 130         if(tl <= 0)
 131         {
 132                 if(!lms_next_place)
 133                         lms_next_place = player_count;
 134                 else
 135                         lms_next_place = min(lms_next_place, player_count);
 136                 PlayerScore_Add(frag_target, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 137                 --lms_next_place;
 138         }
 139         frag_score = 0;
 140
 141         return true;
 142 }
 143
 144 MUTATOR_HOOKFUNCTION(lms_SetStartItems)
 145 {
 146         start_items &= ~IT_UNLIMITED_AMMO;
 147         start_health       = warmup_start_health       = cvar("g_lms_start_health");
 148         start_armorvalue   = warmup_start_armorvalue   = cvar("g_lms_start_armor");
 149         start_ammo_shells  = warmup_start_ammo_shells  = cvar("g_lms_start_ammo_shells");
 150         start_ammo_nails   = warmup_start_ammo_nails   = cvar("g_lms_start_ammo_nails");
 151         start_ammo_rockets = warmup_start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 152         start_ammo_cells   = warmup_start_ammo_cells   = cvar("g_lms_start_ammo_cells");
 153         start_ammo_plasma  = warmup_start_ammo_plasma  = cvar("g_lms_start_ammo_plasma");
 154         start_ammo_fuel    = warmup_start_ammo_fuel    = cvar("g_lms_start_ammo_fuel");
 155
 156         return false;
 157 }
 158
 159 MUTATOR_HOOKFUNCTION(lms_KeepScore)
 160 {
 161         // don't clear player score
 162         return true;
 163 }
 164
 165 MUTATOR_HOOKFUNCTION(lms_FilterItem)
 166 {SELFPARAM();
 167         if(autocvar_g_lms_extra_lives)
 168         if(self.itemdef == ITEM_HealthMega)
 169         {
 170                 self.max_health = 1;
 171                 return false;
 172         }
 173
 174         return true;
 175 }
 176
 177 MUTATOR_HOOKFUNCTION(lms_ItemTouch)
 178 {SELFPARAM();
 179         // give extra lives for mega health
 180         if (self.items & ITEM_HealthMega.m_itemid)
 181         {
 182                 Send_Notification(NOTIF_ONE, other, MSG_CENTER, CENTER_EXTRALIVES);
 183                 PlayerScore_Add(other, SP_LMS_LIVES, autocvar_g_lms_extra_lives);
 184         }
 185
 186         return MUT_ITEMTOUCH_CONTINUE;
 187 }
 188
 189 // scoreboard stuff
 190 void lms_ScoreRules()
 191 {
 192         ScoreRules_basics(0, 0, 0, false);
 193         ScoreInfo_SetLabel_PlayerScore(SP_LMS_LIVES,    "lives",     SFL_SORT_PRIO_SECONDARY);
 194         ScoreInfo_SetLabel_PlayerScore(SP_LMS_RANK,     "rank",      SFL_LOWER_IS_BETTER | SFL_RANK | SFL_SORT_PRIO_PRIMARY | SFL_ALLOW_HIDE);
 195         ScoreRules_basics_end();
 196 }
 197
 198 void lms_Initialize()
 199 {
 200         lms_lowest_lives = 9999;
 201         lms_next_place = 0;
 202
 203         lms_ScoreRules();
 204 }
 205
 206 MUTATOR_DEFINITION(gamemode_lms)
 207 {
 208         MUTATOR_HOOK(reset_map_global, lms_ResetMap, CBC_ORDER_ANY);
 209         MUTATOR_HOOK(reset_map_players, lms_ResetPlayers, CBC_ORDER_ANY);
 210         MUTATOR_HOOK(PutClientInServer, lms_PlayerPreSpawn, CBC_ORDER_ANY);
 211         MUTATOR_HOOK(PlayerDies, lms_PlayerDies, CBC_ORDER_ANY);
 212         MUTATOR_HOOK(MakePlayerObserver, lms_RemovePlayer, CBC_ORDER_ANY);
 213         MUTATOR_HOOK(ClientConnect, lms_ClientConnect, CBC_ORDER_ANY);
 214         MUTATOR_HOOK(PlayerPreThink, lms_PlayerThink, CBC_ORDER_ANY);
 215         MUTATOR_HOOK(PlayerRegen, lms_PlayerRegen, CBC_ORDER_ANY);
 216         MUTATOR_HOOK(ForbidThrowCurrentWeapon, lms_ForbidThrowing, CBC_ORDER_ANY);
 217         MUTATOR_HOOK(GiveFragsForKill, lms_GiveFragsForKill, CBC_ORDER_ANY);
 218         MUTATOR_HOOK(SetStartItems, lms_SetStartItems, CBC_ORDER_ANY);
 219         MUTATOR_HOOK(ForbidPlayerScore_Clear, lms_KeepScore, CBC_ORDER_ANY);
 220         MUTATOR_HOOK(FilterItem, lms_FilterItem, CBC_ORDER_ANY);
 221         MUTATOR_HOOK(ItemTouch, lms_ItemTouch, CBC_ORDER_ANY);
 222
 223         MUTATOR_ONADD
 224         {
 225                 if(time > 1) // game loads at time 1
 226                         error("This is a game type and it cannot be added at runtime.");
 227                 lms_Initialize();
 228         }
 229
 230         MUTATOR_ONROLLBACK_OR_REMOVE
 231         {
 232                 // we actually cannot roll back lms_Initialize here
 233                 // BUT: we don't need to! If this gets called, adding always
 234                 // succeeds.
 235         }
 236
 237         MUTATOR_ONREMOVE
 238         {
 239                 LOG_INFO("This is a game type and it cannot be removed at runtime.");
 240                 return -1;
 241         }
 242
 243         return 0;
 244 }