qcsrc/server/mutators/gamemode_ca.qc

   1 float total_players;
   2 float redalive, bluealive, yellowalive, pinkalive;
   3 .float redalive_stat, bluealive_stat, yellowalive_stat, pinkalive_stat;
   4 float ca_teams;
   5 float allowed_to_spawn;
   6
   7 void CA_count_alive_players()
   8 {
   9         entity e;
  10         total_players = redalive = bluealive = yellowalive = pinkalive = 0;
  11         FOR_EACH_PLAYER(e) {
  12                 if(e.team == NUM_TEAM_1)
  13                 {
  14                         ++total_players;
  15                         if (e.health >= 1) ++redalive;
  16                 }
  17                 else if(e.team == NUM_TEAM_2)
  18                 {
  19                         ++total_players;
  20                         if (e.health >= 1) ++bluealive;
  21                 }
  22                 else if(e.team == NUM_TEAM_3)
  23                 {
  24                         ++total_players;
  25                         if (e.health >= 1) ++yellowalive;
  26                 }
  27                 else if(e.team == NUM_TEAM_4)
  28                 {
  29                         ++total_players;
  30                         if (e.health >= 1) ++pinkalive;
  31                 }
  32         }
  33         FOR_EACH_REALCLIENT(e) {
  34                 e.redalive_stat = redalive;
  35                 e.bluealive_stat = bluealive;
  36                 e.yellowalive_stat = yellowalive;
  37                 e.pinkalive_stat = pinkalive;
  38         }
  39 }
  40
  41 float CA_GetWinnerTeam()
  42 {
  43         float winner_team = 0;
  44         if(redalive >= 1)
  45                 winner_team = NUM_TEAM_1;
  46         if(bluealive >= 1)
  47         {
  48                 if(winner_team) return 0;
  49                 winner_team = NUM_TEAM_2;
  50         }
  51         if(yellowalive >= 1)
  52         {
  53                 if(winner_team) return 0;
  54                 winner_team = NUM_TEAM_3;
  55         }
  56         if(pinkalive >= 1)
  57         {
  58                 if(winner_team) return 0;
  59                 winner_team = NUM_TEAM_4;
  60         }
  61         if(winner_team)
  62                 return winner_team;
  63         return -1; // no player left
  64 }
  65
  66 #define CA_ALIVE_TEAMS() ((redalive > 0) + (bluealive > 0) + (yellowalive > 0) + (pinkalive > 0))
  67 #define CA_ALIVE_TEAMS_OK() (CA_ALIVE_TEAMS() == ca_teams)
  68 float CA_CheckWinner()
  69 {
  70         entity e;
  71         if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
  72         {
  73                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_OVER);
  74                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_OVER);
  75                 allowed_to_spawn = FALSE;
  76                 round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
  77                 FOR_EACH_PLAYER(e)
  78                         nades_Clear(e);
  79                 return 1;
  80         }
  81
  82         CA_count_alive_players();
  83         if(CA_ALIVE_TEAMS() > 1)
  84                 return 0;
  85
  86         float winner_team = CA_GetWinnerTeam();
  87         if(winner_team > 0)
  88         {
  89                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, APP_TEAM_NUM_4(winner_team, CENTER_ROUND_TEAM_WIN_));
  90                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_NUM_4(winner_team, INFO_ROUND_TEAM_WIN_));
  91                 TeamScore_AddToTeam(winner_team, ST_CA_ROUNDS, +1);
  92         }
  93         else if(winner_team == -1)
  94         {
  95                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_TIED);
  96                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_TIED);
  97         }
  98
  99         allowed_to_spawn = FALSE;
 100         round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
 101
 102         FOR_EACH_PLAYER(e)
 103                 nades_Clear(e);
 104
 105         return 1;
 106 }
 107
 108 void CA_RoundStart()
 109 {
 110         if(warmup_stage)
 111                 allowed_to_spawn = TRUE;
 112         else
 113                 allowed_to_spawn = FALSE;
 114 }
 115
 116 float prev_missing_teams_mask;
 117 float CA_CheckTeams()
 118 {
 119         allowed_to_spawn = TRUE;
 120         CA_count_alive_players();
 121         if(CA_ALIVE_TEAMS_OK())
 122         {
 123                 if(prev_missing_teams_mask > 0)
 124                         Kill_Notification(NOTIF_ALL, world, MSG_CENTER_CPID, CPID_MISSING_TEAMS);
 125                 prev_missing_teams_mask = -1;
 126                 return 1;
 127         }
 128         if(total_players == 0)
 129         {
 130                 if(prev_missing_teams_mask > 0)
 131                         Kill_Notification(NOTIF_ALL, world, MSG_CENTER_CPID, CPID_MISSING_TEAMS);
 132                 prev_missing_teams_mask = -1;
 133                 return 0;
 134         }
 135         float missing_teams_mask = (!redalive) + (!bluealive) * 2;
 136         if(ca_teams >= 3) missing_teams_mask += (!yellowalive) * 4;
 137         if(ca_teams >= 4) missing_teams_mask += (!pinkalive) * 8;
 138         if(prev_missing_teams_mask != missing_teams_mask)
 139         {
 140                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
 141                 prev_missing_teams_mask = missing_teams_mask;
 142         }
 143         return 0;
 144 }
 145
 146 float EliminatedPlayers_SendEntity(entity to, float sendflags)
 147 {
 148         float i, f, b;
 149         entity e;
 150         WriteByte(MSG_ENTITY, ENT_CLIENT_ELIMINATEDPLAYERS);
 151         WriteByte(MSG_ENTITY, sendflags);
 152
 153         if(sendflags & 1)
 154         {
 155                 for(i = 1; i <= maxclients; i += 8)
 156                 {
 157                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
 158                         {
 159                                 if(e.caplayer == 0.5 || (e.caplayer == 1 && (e.deadflag != DEAD_NO || e.frags == FRAGS_LMS_LOSER)))
 160                                         f |= b;
 161                         }
 162                         WriteByte(MSG_ENTITY, f);
 163                 }
 164         }
 165
 166         return TRUE;
 167 }
 168
 169 void EliminatedPlayers_Init()
 170 {
 171         Net_LinkEntity(eliminatedPlayers = spawn(), FALSE, 0, EliminatedPlayers_SendEntity);
 172 }
 173
 174
 175 MUTATOR_HOOKFUNCTION(ca_PlayerSpawn)
 176 {
 177         self.caplayer = 1;
 178         if(!warmup_stage)
 179                 eliminatedPlayers.SendFlags |= 1;
 180         return 1;
 181 }
 182
 183 MUTATOR_HOOKFUNCTION(ca_PutClientInServer)
 184 {
 185         if(!allowed_to_spawn)
 186         if(IS_PLAYER(self)) // this is true even when player is trying to join
 187         {
 188                 self.classname = "observer";
 189                 if(self.jointime != time) //not when connecting
 190                 if(!self.caplayer)
 191                 {
 192                         self.caplayer = 0.5;
 193                         if(IS_REAL_CLIENT(self))
 194                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CA_JOIN_LATE);
 195                 }
 196         }
 197         return 1;
 198 }
 199
 200 MUTATOR_HOOKFUNCTION(ca_reset_map_players)
 201 {
 202         FOR_EACH_CLIENT(self)
 203         {
 204                 self.killcount = 0;
 205                 if(!self.caplayer && IS_BOT_CLIENT(self))
 206                 {
 207                         self.team = -1;
 208                         self.caplayer = 1;
 209                 }
 210                 if(self.caplayer)
 211                 {
 212                         self.classname = "player";
 213                         self.caplayer = 1;
 214                         PutClientInServer();
 215                 }
 216         }
 217         return 1;
 218 }
 219
 220 MUTATOR_HOOKFUNCTION(ca_ClientConnect)
 221 {
 222         self.classname = "observer";
 223         return 1;
 224 }
 225
 226 MUTATOR_HOOKFUNCTION(ca_reset_map_global)
 227 {
 228         allowed_to_spawn = TRUE;
 229         return 1;
 230 }
 231
 232 MUTATOR_HOOKFUNCTION(ca_GetTeamCount)
 233 {
 234         ret_float = ca_teams;
 235         return 0;
 236 }
 237
 238 entity ca_LastPlayerForTeam()
 239 {
 240         entity pl, last_pl = world;
 241         FOR_EACH_PLAYER(pl)
 242         {
 243                 if(pl.health >= 1)
 244                 if(pl != self)
 245                 if(pl.team == self.team)
 246                 if(!last_pl)
 247                         last_pl = pl;
 248                 else
 249                         return world;
 250         }
 251         return last_pl;
 252 }
 253
 254 void ca_LastPlayerForTeam_Notify()
 255 {
 256         if(round_handler_IsActive())
 257         if(round_handler_IsRoundStarted())
 258         {
 259                 entity pl = ca_LastPlayerForTeam();
 260                 if(pl)
 261                         Send_Notification(NOTIF_ONE, pl, MSG_CENTER, CENTER_ALONE);
 262         }
 263 }
 264
 265 MUTATOR_HOOKFUNCTION(ca_PlayerDies)
 266 {
 267         ca_LastPlayerForTeam_Notify();
 268         if(!allowed_to_spawn)
 269                 self.respawn_flags =  RESPAWN_SILENT;
 270         if(!warmup_stage)
 271                 eliminatedPlayers.SendFlags |= 1;
 272         return 1;
 273 }
 274
 275 MUTATOR_HOOKFUNCTION(ca_ClientDisconnect)
 276 {
 277         if(self.caplayer == 1)
 278                 ca_LastPlayerForTeam_Notify();
 279         return 1;
 280 }
 281
 282 MUTATOR_HOOKFUNCTION(ca_ForbidPlayerScore_Clear)
 283 {
 284         return 1;
 285 }
 286
 287 MUTATOR_HOOKFUNCTION(ca_MakePlayerObserver)
 288 {
 289         if(self.caplayer == 1)
 290                 ca_LastPlayerForTeam_Notify();
 291         if(self.killindicator_teamchange == -2)
 292                 self.caplayer = 0;
 293         if(self.caplayer)
 294                 self.frags = FRAGS_LMS_LOSER;
 295         if(!warmup_stage)
 296                 eliminatedPlayers.SendFlags |= 1;
 297         return 1;
 298 }
 299
 300 MUTATOR_HOOKFUNCTION(ca_ForbidThrowCurrentWeapon)
 301 {
 302         return 1;
 303 }
 304
 305 MUTATOR_HOOKFUNCTION(ca_GiveFragsForKill)
 306 {
 307         frag_score = 0; // score will be given to the winner team when the round ends
 308         return 1;
 309 }
 310
 311 MUTATOR_HOOKFUNCTION(ca_SetStartItems)
 312 {
 313         start_items &= ~IT_UNLIMITED_AMMO;
 314         start_health       = warmup_start_health       = cvar("g_lms_start_health");
 315         start_armorvalue   = warmup_start_armorvalue   = cvar("g_lms_start_armor");
 316         start_ammo_shells  = warmup_start_ammo_shells  = cvar("g_lms_start_ammo_shells");
 317         start_ammo_nails   = warmup_start_ammo_nails   = cvar("g_lms_start_ammo_nails");
 318         start_ammo_rockets = warmup_start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 319         start_ammo_cells   = warmup_start_ammo_cells   = cvar("g_lms_start_ammo_cells");
 320         start_ammo_fuel    = warmup_start_ammo_fuel    = cvar("g_lms_start_ammo_fuel");
 321
 322         return 0;
 323 }
 324
 325 MUTATOR_HOOKFUNCTION(ca_PlayerDamage)
 326 {
 327         if(IS_PLAYER(frag_target))
 328         if(frag_target.deadflag == DEAD_NO)
 329         if(frag_target == frag_attacker || SAME_TEAM(frag_target, frag_attacker) || frag_deathtype == DEATH_FALL)
 330                 frag_damage = 0;
 331
 332         frag_mirrordamage = 0;
 333
 334         return FALSE;
 335 }
 336
 337 MUTATOR_HOOKFUNCTION(ca_FilterItem)
 338 {
 339         if(autocvar_g_powerups <= 0)
 340         if(self.flags & FL_POWERUP)
 341                 return TRUE;
 342
 343         if(autocvar_g_pickup_items <= 0)
 344                 return TRUE;
 345
 346         return FALSE;
 347 }
 348
 349 MUTATOR_HOOKFUNCTION(ca_PlayerDamage_SplitHealthArmor)
 350 {
 351         float excess = max(0, frag_damage - damage_take - damage_save);
 352
 353         if(frag_target != frag_attacker && IS_PLAYER(frag_attacker))
 354                 PlayerTeamScore_Add(frag_attacker, SP_SCORE, ST_SCORE, (frag_damage - excess) * autocvar_g_ca_damage2score_multiplier);
 355
 356         return FALSE;
 357 }
 358
 359 MUTATOR_HOOKFUNCTION(ca_PlayerRegen)
 360 {
 361         // no regeneration in CA
 362         return TRUE;
 363 }
 364
 365 void ca_Initialize()
 366 {
 367         allowed_to_spawn = TRUE;
 368
 369         ca_teams = autocvar_g_ca_teams_override;
 370         if(ca_teams < 2)
 371                 ca_teams = autocvar_g_ca_teams;
 372         ca_teams = bound(2, ca_teams, 4);
 373         ret_float = ca_teams;
 374         ScoreRules_ca(ca_teams);
 375
 376         round_handler_Spawn(CA_CheckTeams, CA_CheckWinner, CA_RoundStart);
 377         round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
 378
 379         addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 380         addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 381         addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 382         addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 383
 384         EliminatedPlayers_Init();
 385 }
 386
 387 MUTATOR_DEFINITION(gamemode_ca)
 388 {
 389         MUTATOR_HOOK(PlayerSpawn, ca_PlayerSpawn, CBC_ORDER_ANY);
 390         MUTATOR_HOOK(PutClientInServer, ca_PutClientInServer, CBC_ORDER_ANY);
 391         MUTATOR_HOOK(MakePlayerObserver, ca_MakePlayerObserver, CBC_ORDER_ANY);
 392         MUTATOR_HOOK(ClientConnect, ca_ClientConnect, CBC_ORDER_ANY);
 393         MUTATOR_HOOK(reset_map_global, ca_reset_map_global, CBC_ORDER_ANY);
 394         MUTATOR_HOOK(reset_map_players, ca_reset_map_players, CBC_ORDER_ANY);
 395         MUTATOR_HOOK(GetTeamCount, ca_GetTeamCount, CBC_ORDER_EXCLUSIVE);
 396         MUTATOR_HOOK(PlayerDies, ca_PlayerDies, CBC_ORDER_ANY);
 397         MUTATOR_HOOK(ClientDisconnect, ca_ClientDisconnect, CBC_ORDER_ANY);
 398         MUTATOR_HOOK(ForbidPlayerScore_Clear, ca_ForbidPlayerScore_Clear, CBC_ORDER_ANY);
 399         MUTATOR_HOOK(ForbidThrowCurrentWeapon, ca_ForbidThrowCurrentWeapon, CBC_ORDER_ANY);
 400         MUTATOR_HOOK(GiveFragsForKill, ca_GiveFragsForKill, CBC_ORDER_FIRST);
 401         MUTATOR_HOOK(SetStartItems, ca_SetStartItems, CBC_ORDER_ANY);
 402         MUTATOR_HOOK(PlayerDamage_Calculate, ca_PlayerDamage, CBC_ORDER_ANY);
 403         MUTATOR_HOOK(FilterItem, ca_FilterItem, CBC_ORDER_ANY);
 404         MUTATOR_HOOK(PlayerDamage_SplitHealthArmor, ca_PlayerDamage_SplitHealthArmor, CBC_ORDER_ANY);
 405         MUTATOR_HOOK(PlayerRegen, ca_PlayerRegen, CBC_ORDER_ANY);
 406
 407         MUTATOR_ONADD
 408         {
 409                 if(time > 1) // game loads at time 1
 410                         error("This is a game type and it cannot be added at runtime.");
 411                 ca_Initialize();
 412         }
 413
 414         MUTATOR_ONREMOVE
 415         {
 416                 print("This is a game type and it cannot be removed at runtime.");
 417                 return -1;
 418         }
 419
 420         return 0;
 421 }