qcsrc/server/monsters/lib/monsters.qc

   1 // TODO: clean up this file?
   2
   3 void M_Item_Touch ()
   4 {
   5         if(self && IS_PLAYER(other) && other.deadflag == DEAD_NO)
   6         {
   7                 Item_Touch();
   8                 self.think = SUB_Remove;
   9                 self.nextthink = time + 0.1;
  10         }
  11 }
  12
  13 void monster_item_spawn()
  14 {
  15         self.monster_delayedattack();
  16
  17         self.think = SUB_Remove;
  18         self.nextthink = time + 5;
  19         self.gravity = 1;
  20         self.velocity = randomvec() * 175 + '0 0 325';
  21         self.touch = M_Item_Touch;
  22
  23         SUB_SetFade(self, time + 5, 1);
  24 }
  25
  26 void Monster_DropItem (string itype, string itemsize)
  27 {
  28         vector org = self.origin + ((self.mins + self.maxs) * 0.5);
  29         entity e = spawn();
  30
  31         setorigin(e, org);
  32
  33         switch(itype)
  34         {
  35                 case "armor":
  36                 {
  37                         switch(itemsize)
  38                         {
  39                                 case "mega": e.monster_delayedattack = spawnfunc_item_armor_large; break;
  40                                 case "large": e.monster_delayedattack = spawnfunc_item_armor_big; break;
  41                                 case "medium": e.monster_delayedattack = spawnfunc_item_armor_medium; break;
  42                                 case "small": e.monster_delayedattack = spawnfunc_item_armor_small; break;
  43                         }
  44                         break; // break here?
  45                 }
  46                 case "health":
  47                 {
  48                         switch(itemsize)
  49                         {
  50                                 case "mega": e.monster_delayedattack = spawnfunc_item_health_mega; break;
  51                                 case "large": e.monster_delayedattack = spawnfunc_item_health_large; break;
  52                                 case "medium": e.monster_delayedattack = spawnfunc_item_health_medium; break;
  53                                 case "small": e.monster_delayedattack = spawnfunc_item_health_small; break;
  54                         }
  55                         break; // break here?
  56                 }
  57                 case "ammo":
  58                 {
  59                         switch(itemsize)
  60                         {
  61                                 case "shells": e.monster_delayedattack = spawnfunc_item_shells; break;
  62                                 case "cells": e.monster_delayedattack = spawnfunc_item_cells; break;
  63                                 case "rockets": e.monster_delayedattack = spawnfunc_item_rockets; break;
  64                                 case "bullets":
  65                                 case "nails": e.monster_delayedattack = spawnfunc_item_bullets; break;
  66                         }
  67                         break;
  68                 }
  69         }
  70
  71         if(g_minstagib)
  72                 e.monster_delayedattack = spawnfunc_item_minst_cells;
  73
  74         e.think = monster_item_spawn;
  75         e.nextthink = time + 0.1;
  76 }
  77
  78 void monsters_setframe(float _frame)
  79 {
  80         if(self.frame == _frame)
  81                 return;
  82
  83         self.anim_start_time = time;
  84         self.frame = _frame;
  85         self.SendFlags |= MSF_ANIM;
  86 }
  87
  88 float monster_isvalidtarget (entity targ, entity ent)
  89 {
  90         if(!targ || !ent)
  91                 return FALSE; // someone doesn't exist
  92
  93         if(time < game_starttime)
  94                 return FALSE; // monsters do nothing before the match has started
  95
  96         WarpZone_TraceLine(ent.origin, targ.origin, MOVE_NORMAL, ent);
  97
  98         if(vlen(targ.origin - ent.origin) >= ent.target_range)
  99                 return FALSE; // enemy is too far away
 100
 101         if not(targ.vehicle_flags & VHF_ISVEHICLE)
 102         if(trace_ent != targ)
 103                 return FALSE; // we can't see the enemy
 104
 105         if(targ.takedamage == DAMAGE_NO)
 106                 return FALSE; // enemy can't be damaged
 107
 108         if(targ.items & IT_INVISIBILITY)
 109                 return FALSE; // enemy is invisible
 110
 111         if(IS_SPEC(targ) || IS_OBSERVER(targ))
 112                 return FALSE; // enemy is a spectator
 113
 114         if not(targ.vehicle_flags & VHF_ISVEHICLE) // vehicles dont count as alive?
 115         if(targ.deadflag != DEAD_NO || ent.deadflag != DEAD_NO || targ.health <= 0 || ent.health <= 0)
 116                 return FALSE; // enemy/self is dead
 117
 118         if(targ.monster_owner == ent || ent.monster_owner == targ)
 119                 return FALSE; // enemy owns us, or we own them
 120
 121         if not(targ.vehicle_flags & VHF_ISVEHICLE)
 122         if(targ.flags & FL_NOTARGET)
 123                 return FALSE; // enemy can't be targetted
 124
 125         if not(autocvar_g_monsters_typefrag)
 126         if(targ.BUTTON_CHAT)
 127                 return FALSE; // no typefragging!
 128
 129         if not(IsDifferentTeam(targ, ent))
 130                 return FALSE; // enemy is on our team
 131
 132         return TRUE;
 133 }
 134
 135 entity FindTarget (entity ent)
 136 {
 137         if(MUTATOR_CALLHOOK(MonsterFindTarget)) { return ent.enemy; } // Handled by a mutator
 138         entity e;
 139
 140         for(e = world; (e = findflags(e, monster_attack, TRUE)); )
 141         if(monster_isvalidtarget(e, ent))
 142                 return e;
 143
 144         return world;
 145 }
 146
 147 void MonsterTouch ()
 148 {
 149         if(other == world)
 150                 return;
 151
 152         if(self.enemy != other)
 153         if not(other.flags & FL_MONSTER)
 154         if(monster_isvalidtarget(other, self))
 155                 self.enemy = other;
 156 }
 157
 158 void monster_sound(string msound, float sound_delay, float delaytoo)
 159 {
 160         if(delaytoo && time < self.msound_delay)
 161                 return; // too early
 162
 163         if(msound == "")
 164                 return; // sound doesn't exist
 165
 166         sound(self, CHAN_AUTO, msound, VOL_BASE, ATTN_NORM);
 167
 168         self.msound_delay = time + sound_delay;
 169 }
 170
 171 void monster_precachesounds(entity e)
 172 {
 173         precache_sound(e.msound_idle);
 174         precache_sound(e.msound_death);
 175         precache_sound(e.msound_attack_melee);
 176         precache_sound(e.msound_attack_ranged);
 177         precache_sound(e.msound_sight);
 178         precache_sound(e.msound_pain);
 179 }
 180
 181 void monster_setupsounds(string mon)
 182 {
 183         if(self.msound_idle == "") self.msound_idle = strzone(strcat("monsters/", mon, "_idle.wav"));
 184         if(self.msound_death == "") self.msound_death = strzone(strcat("monsters/", mon, "_death.wav"));
 185         if(self.msound_pain == "") self.msound_pain = strzone(strcat("monsters/", mon, "_pain.wav"));
 186         if(self.msound_attack_melee == "") self.msound_attack_melee = strzone(strcat("monsters/", mon, "_melee.wav"));
 187         if(self.msound_attack_ranged == "") self.msound_attack_ranged = strzone(strcat("monsters/", mon, "_attack.wav"));
 188         if(self.msound_sight == "") self.msound_sight = strzone(strcat("monsters/", mon, "_sight.wav"));
 189 }
 190
 191 void monster_melee (entity targ, float damg, float er, float deathtype, float dostop)
 192 {
 193         float bigdmg, dot, rdmg = damg * random();
 194
 195         if (self.health <= 0)
 196                 return;
 197         if (targ == world)
 198                 return;
 199
 200         if(dostop)
 201         {
 202                 self.velocity_x = 0;
 203                 self.velocity_y = 0;
 204                 self.state = MONSTER_STATE_ATTACK_MELEE;
 205                 self.SendFlags |= MSF_MOVE;
 206         }
 207
 208         makevectors (self.angles);
 209         dot = normalize (targ.origin - self.origin) * v_forward;
 210
 211         bigdmg = rdmg * self.scale;
 212
 213         if(dot > er)
 214                 Damage(targ, self, self, bigdmg * monster_skill, deathtype, targ.origin, normalize(targ.origin - self.origin));
 215 }
 216
 217 void Monster_CheckDropCvars (string mon)
 218 {
 219         if not(self.candrop)
 220                 return; // forced off
 221
 222         string dropitem;
 223         string dropsize;
 224
 225         dropitem = cvar_string(strcat("g_monster_", mon, "_drop"));
 226         dropsize = cvar_string(strcat("g_monster_", mon, "_drop_size"));
 227
 228         monster_dropitem = dropitem;
 229         monster_dropsize = dropsize;
 230         MUTATOR_CALLHOOK(MonsterDropItem);
 231         dropitem = monster_dropitem;
 232         dropsize = monster_dropsize;
 233
 234         if(autocvar_g_monsters_forcedrop)
 235                 Monster_DropItem(autocvar_g_monsters_drop_type, autocvar_g_monsters_drop_size);
 236         else if(dropitem != "")
 237                 Monster_DropItem(dropitem, dropsize);
 238         else
 239                 Monster_DropItem("armor", "medium");
 240 }
 241
 242 void ScaleMonster (float scle, vector min_s, vector max_s)
 243 {
 244         // this should prevent monster from falling through floor when scale changes
 245         self.scale = scle;
 246         setsize(self, min_s * scle, max_s * scle);
 247         setorigin(self, self.origin + ('0 0 30' * scle));
 248         self.SendFlags |= MSF_SIZE | MSF_MOVE;
 249 }
 250
 251 void Monster_CheckMinibossFlag ()
 252 {
 253         if(MUTATOR_CALLHOOK(MonsterCheckBossFlag))
 254                 return;
 255
 256         if(self.spawnflags & MONSTERFLAG_GIANT)
 257                 return; // 1 size modifier at a time
 258
 259         float chance = random() * 100;
 260
 261         // g_monsters_miniboss_chance cvar or spawnflags 64 causes a monster to be a miniboss
 262         if ((self.spawnflags & MONSTERFLAG_MINIBOSS) || (chance < autocvar_g_monsters_miniboss_chance))
 263         {
 264                 self.health += autocvar_g_monsters_miniboss_healthboost;
 265                 ScaleMonster(1.5, self.mins, self.maxs);
 266                 self.flags |= MONSTERFLAG_MINIBOSS;
 267                 if not(self.weapon)
 268                         self.weapon = WEP_NEX;
 269         }
 270 }
 271
 272 float Monster_CanRespawn(entity ent)
 273 {
 274         other = ent;
 275         if(MUTATOR_CALLHOOK(MonsterRespawn))
 276                 return TRUE; // enabled by a mutator
 277
 278         if(ent.spawnflags & MONSTERFLAG_NORESPAWN)
 279                 return FALSE;
 280
 281         if not(autocvar_g_monsters_respawn)
 282                 return FALSE;
 283
 284         return TRUE;
 285 }
 286
 287 void Monster_Fade ()
 288 {
 289         if(Monster_CanRespawn(self))
 290         {
 291                 self.monster_respawned = TRUE;
 292                 self.think = self.monster_spawnfunc;
 293                 self.nextthink = time + self.respawntime;
 294                 if(self.spawnflags & MONSTER_RESPAWN_DEATHPOINT)
 295                 {
 296                         self.pos1 = self.origin;
 297                         self.pos2 = self.angles;
 298                 }
 299                 self.event_damage = func_null;
 300                 self.takedamage = DAMAGE_NO;
 301                 setorigin(self, self.pos1);
 302                 self.angles = self.pos2;
 303                 self.health = self.max_health; // TODO: check if resetting to max_health is wise here
 304                 self.SendFlags |= MSF_MOVE;
 305                 return;
 306         }
 307         SUB_SetFade(self, time + 3, 1);
 308 }
 309
 310 float Monster_CanJump (vector vel)
 311 {
 312         if(self.state)
 313                 return FALSE; // already attacking
 314         if not(self.flags & FL_ONGROUND)
 315                 return FALSE; // not on the ground
 316         if(self.health <= 0)
 317                 return FALSE; // called when dead?
 318         if(time < self.attack_finished_single)
 319                 return FALSE; // still attacking
 320
 321         vector old = self.velocity;
 322
 323         self.velocity = vel;
 324         tracetoss(self, self);
 325         self.velocity = old;
 326         if (trace_ent != self.enemy)
 327                 return FALSE;
 328
 329         return TRUE;
 330 }
 331
 332 float monster_leap (float anm, void() touchfunc, vector vel, float anim_finished)
 333 {
 334         if(!Monster_CanJump(vel))
 335                 return FALSE;
 336
 337         monsters_setframe(anm);
 338         self.state = MONSTER_STATE_ATTACK_LEAP;
 339         self.touch = touchfunc;
 340         self.origin_z += 1;
 341         self.velocity = vel;
 342         self.flags &~= FL_ONGROUND;
 343
 344         self.attack_finished_single = time + anim_finished;
 345
 346         return TRUE;
 347 }
 348
 349 float GenericCheckAttack ()
 350 {
 351         // checking attack while dead?
 352         if (self.health <= 0)
 353                 return FALSE;
 354
 355         // reset delays when we have no enemy
 356         if not(self.enemy)
 357         {
 358                 self.monster_delayedattack = func_null;
 359                 self.delay = -1;
 360         }
 361
 362         if(self.monster_delayedattack && self.delay != -1)
 363         {
 364                 if(time < self.delay)
 365                         return FALSE;
 366
 367                 self.monster_delayedattack();
 368         }
 369
 370         if (time < self.attack_finished_single)
 371                 return FALSE;
 372
 373         if(self.attack_melee)
 374         if(vlen(self.enemy.origin - self.origin) <= 100 * self.scale)
 375         {
 376                 monster_sound(self.msound_attack_melee, 0, FALSE); // no delay for attack sounds
 377                 self.attack_melee(); // don't wait for nextthink - too slow
 378                 return TRUE;
 379         }
 380
 381         // monster doesn't have a ranged attack function, so stop here
 382         if not(self.attack_ranged)
 383                 return FALSE;
 384
 385         // see if any entities are in the way of the shot
 386         if not(findtrajectorywithleading(self.origin, '0 0 0', '0 0 0', self.enemy, 800, 0, 2.5, 0, self))
 387                 return FALSE;
 388
 389         if(self.attack_ranged())
 390         {
 391                 monster_sound(self.msound_attack_ranged, 0, FALSE); // no delay for attack sounds
 392                 return TRUE;
 393         }
 394
 395         return FALSE;
 396 }
 397
 398 void monster_use ()
 399 {
 400         if (self.enemy)
 401                 return;
 402         if (self.health <= 0)
 403                 return;
 404
 405         if(!monster_isvalidtarget(activator, self))
 406                 return;
 407
 408         self.enemy = activator;
 409 }
 410
 411 float trace_path(vector from, vector to)
 412 {
 413         vector dir = normalize(to - from) * 15, offset = '0 0 0';
 414         float trace1 = trace_fraction;
 415
 416         offset_x = dir_y;
 417         offset_y = -dir_x;
 418         traceline (from+offset, to+offset, TRUE, self);
 419
 420         traceline(from-offset, to-offset, TRUE, self);
 421
 422         return ((trace1 < trace_fraction) ? trace1 : trace_fraction);
 423 }
 424
 425 .float last_trace;
 426 vector monster_pickmovetarget(entity targ)
 427 {
 428         // enemy is always preferred target
 429         if(self.enemy)
 430         {
 431                 self.monster_movestate = MONSTER_MOVE_ENEMY;
 432                 self.last_trace = time + 0.1;
 433                 return self.enemy.origin;
 434         }
 435         if(targ)
 436         {
 437                 self.monster_movestate = MONSTER_MOVE_WANDER;
 438                 self.last_trace = time + 0.5;
 439                 return targ.origin;
 440         }
 441
 442         switch(self.monster_moveflags)
 443         {
 444                 case MONSTER_MOVE_OWNER:
 445                 {
 446                         self.monster_movestate = MONSTER_MOVE_OWNER;
 447                         self.last_trace = time + 0.3;
 448                         if(self.monster_owner && self.monster_owner.classname != "monster_swarm")
 449                                 return self.monster_owner.origin;
 450                 }
 451                 case MONSTER_MOVE_WANDER:
 452                 {
 453                         self.monster_movestate = MONSTER_MOVE_WANDER;
 454                         self.last_trace = time + 2;
 455
 456                         self.angles_y = random() * 500;
 457                         makevectors(self.angles);
 458                         return self.origin + v_forward * 600;
 459                 }
 460                 case MONSTER_MOVE_SPAWNLOC:
 461                 {
 462                         self.monster_movestate = MONSTER_MOVE_SPAWNLOC;
 463                         self.last_trace = time + 2;
 464                         return self.pos1;
 465                 }
 466                 default:
 467                 case MONSTER_MOVE_NOMOVE:
 468                 {
 469                         self.monster_movestate = MONSTER_MOVE_NOMOVE;
 470                         self.last_trace = time + 2;
 471                         return self.origin;
 472                 }
 473         }
 474 }
 475
 476 void monster_move(float runspeed, float walkspeed, float stopspeed, float manim_run, float manim_walk, float manim_idle)
 477 {
 478         if(self.target2)
 479                 self.goalentity = find(world, targetname, self.target2);
 480
 481         entity targ;
 482
 483         if(self.frozen)
 484         {
 485                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
 486                 self.health = max(1, self.max_health * self.revive_progress);
 487
 488                 if(self.sprite) WaypointSprite_UpdateHealth(self.sprite, self.health);
 489
 490                 movelib_beak_simple(stopspeed);
 491
 492                 self.velocity = '0 0 0';
 493                 self.enemy = world;
 494                 self.nextthink = time + 0.1;
 495
 496                 if(self.revive_progress >= 1)
 497                         Unfreeze(self); // wait for next think before attacking
 498
 499                 self.SendFlags |= MSF_MOVE;
 500
 501                 return; // no moving while frozen
 502         }
 503
 504         if(self.flags & FL_SWIM)
 505         {
 506                 if(self.waterlevel < WATERLEVEL_WETFEET)
 507                 {
 508                         if(time >= self.last_trace)
 509                         {
 510                                 self.last_trace = time + 0.4;
 511
 512                                 Damage (self, world, world, 2, DEATH_DROWN, self.origin, '0 0 0');
 513                                 self.angles = '90 90 0';
 514                                 if(random() < 0.5)
 515                                 {
 516                                         self.velocity_y += random() * 50;
 517                                         self.velocity_x -= random() * 50;
 518                                 }
 519                                 else
 520                                 {
 521                                         self.velocity_y -= random() * 50;
 522                                         self.velocity_x += random() * 50;
 523                                 }
 524                                 self.velocity_z += random() * 150;
 525                         }
 526
 527
 528                         self.movetype = MOVETYPE_BOUNCE;
 529                         //self.velocity_z = -200;
 530
 531                         self.SendFlags |= MSF_MOVE | MSF_ANG;
 532
 533                         return;
 534                 }
 535                 else
 536                 {
 537                         self.angles = '0 0 0';
 538                         self.movetype = MOVETYPE_WALK;
 539                 }
 540         }
 541
 542         if(gameover || time < game_starttime || (autocvar_g_campaign && !campaign_bots_may_start))
 543         {
 544                 runspeed = walkspeed = 0;
 545                 monsters_setframe(manim_idle);
 546                 movelib_beak_simple(stopspeed);
 547                 self.SendFlags |= MSF_MOVE;
 548                 return;
 549         }
 550
 551         targ = self.goalentity;
 552
 553         monster_target = targ;
 554         monster_speed_run = runspeed;
 555         monster_speed_walk = walkspeed;
 556         MUTATOR_CALLHOOK(MonsterMove);
 557         targ = monster_target;
 558         runspeed = monster_speed_run;
 559         walkspeed = monster_speed_walk;
 560
 561         if(IsDifferentTeam(self.monster_owner, self))
 562                 self.monster_owner = world;
 563
 564         if not(monster_isvalidtarget(self.enemy, self))
 565                 self.enemy = world; // check enemy each think frame?
 566
 567         if not(self.enemy)
 568         {
 569                 self.enemy = FindTarget(self);
 570                 if(self.enemy)
 571                         monster_sound(self.msound_sight, 0, FALSE);
 572         }
 573
 574         if(self.state == MONSTER_STATE_ATTACK_MELEE && time >= self.attack_finished_single)
 575                 self.state = 0;
 576
 577         if(self.state != MONSTER_STATE_ATTACK_MELEE) // don't move if set
 578         if(time >= self.last_trace || self.enemy) // update enemy instantly
 579                 self.moveto = monster_pickmovetarget(targ);
 580
 581         if not(self.enemy)
 582                 monster_sound(self.msound_idle, 5, TRUE);
 583
 584         vector angles_face = vectoangles(self.moveto - self.origin);
 585         vector owner_face = vectoangles(self.monster_owner.origin - self.origin);
 586         vector enemy_face = vectoangles(self.enemy.origin - self.origin);
 587
 588         if(self.state != MONSTER_STATE_ATTACK_LEAP)
 589         {
 590                 self.angles_y = angles_face_y;
 591                 self.v_angle = self.angles;
 592         }
 593
 594         if(self.state == MONSTER_STATE_ATTACK_LEAP && (self.flags & FL_ONGROUND))
 595         {
 596                 self.state = 0;
 597                 self.touch = MonsterTouch;
 598         }
 599
 600         v_forward = normalize(self.moveto - self.origin);
 601
 602         float l = vlen(self.moveto - self.origin);
 603         float t1 = trace_path(self.origin+'0 0 10', self.moveto+'0 0 10');
 604         float t2 = trace_path(self.origin-'0 0 15', self.moveto-'0 0 15');
 605
 606         if(t1*l-t2*l>50 && (t1*l > 100 || t1 > 0.8))
 607         if(self.flags & FL_ONGROUND)
 608                 movelib_jump_simple(100);
 609
 610         if(vlen(self.origin - self.moveto) > 64 * self.scale)
 611         {
 612                 if(self.flags & FL_FLY || self.flags & FL_SWIM)
 613                         movelib_move_simple(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 614                 else
 615                         movelib_move_simple_gravity(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 616                 if(time > self.pain_finished)
 617                 if(time > self.attack_finished_single)
 618                         monsters_setframe((self.enemy) ? manim_run : manim_walk);
 619         }
 620         else
 621         {
 622                 if(self.goalentity.target)
 623                         self.target2 = self.goalentity.target;
 624                 else if(self.goalentity.target2)
 625                         self.target2 = self.goalentity.target2;
 626                 else
 627                 {
 628                         movelib_beak_simple(stopspeed);
 629                         if(time > self.attack_finished_single)
 630                         if(time > self.pain_finished)
 631                         if (vlen(self.velocity) <= 30)
 632                         {
 633                                 monsters_setframe(manim_idle);
 634                                 if(self.enemy)
 635                                         self.angles_y = enemy_face_y;
 636                                 else
 637                                         self.angles_y = ((self.monster_owner) ? owner_face_y : self.pos2_y); // reset looking angle now?
 638                         }
 639                 }
 640         }
 641
 642         if(self.enemy && self.checkattack)
 643                 self.checkattack();
 644
 645         self.SendFlags |= MSF_ANG;
 646         self.SendFlags |= MSF_MOVE;
 647 }
 648
 649 void monster_dead_think()
 650 {
 651         self.think = monster_dead_think;
 652         self.nextthink = time + 0.3; // don't need to update so often now
 653
 654         self.deadflag = DEAD_DEAD;
 655
 656         if(time >= self.ltime)
 657         {
 658                 Monster_Fade();
 659                 return;
 660         }
 661
 662         self.SendFlags |= MSF_MOVE; // keep up to date on the monster's location
 663 }
 664
 665 void monsters_setstatus()
 666 {
 667         self.stat_monsters_total = monsters_total;
 668         self.stat_monsters_killed = monsters_killed;
 669 }
 670
 671 void Monster_Appear()
 672 {
 673         self.enemy = activator;
 674         self.spawnflags &~= MONSTERFLAG_APPEAR;
 675         self.monster_spawnfunc();
 676 }
 677
 678 float Monster_CheckAppearFlags(entity ent)
 679 {
 680         if not(ent.spawnflags & MONSTERFLAG_APPEAR)
 681                 return FALSE;
 682
 683         ent.think = func_null;
 684         ent.nextthink = 0;
 685         ent.use = Monster_Appear;
 686         ent.flags = FL_MONSTER; // set so this monster can get butchered
 687
 688         return TRUE;
 689 }
 690
 691 void monsters_reset()
 692 {
 693         setorigin(self, self.pos1);
 694         self.angles = self.pos2;
 695
 696         self.health = self.max_health;
 697         self.velocity = '0 0 0';
 698         self.enemy = world;
 699         self.goalentity = world;
 700         self.attack_finished_single = 0;
 701         self.moveto = self.origin;
 702
 703         WaypointSprite_UpdateHealth(self.sprite, self.health);
 704 }
 705
 706 float monster_send(entity to, float sf)
 707 {
 708         WriteByte(MSG_ENTITY, ENT_CLIENT_MONSTER);
 709         WriteByte(MSG_ENTITY, sf);
 710         if(sf & MSF_SETUP)
 711         {
 712             WriteByte(MSG_ENTITY, self.monsterid);
 713
 714             WriteCoord(MSG_ENTITY, self.origin_x);
 715             WriteCoord(MSG_ENTITY, self.origin_y);
 716             WriteCoord(MSG_ENTITY, self.origin_z);
 717
 718             WriteAngle(MSG_ENTITY, self.angles_x);
 719             WriteAngle(MSG_ENTITY, self.angles_y);
 720
 721                 WriteByte(MSG_ENTITY, self.scale);
 722                 WriteByte(MSG_ENTITY, self.skin);
 723     }
 724
 725         if(sf & MSF_SIZE)
 726         {
 727                 WriteByte(MSG_ENTITY, self.scale);
 728
 729                 WriteCoord(MSG_ENTITY, self.mins_x);
 730             WriteCoord(MSG_ENTITY, self.mins_y);
 731             WriteCoord(MSG_ENTITY, self.mins_z);
 732
 733                 WriteCoord(MSG_ENTITY, self.maxs_x);
 734             WriteCoord(MSG_ENTITY, self.maxs_y);
 735             WriteCoord(MSG_ENTITY, self.maxs_z);
 736         }
 737
 738     if(sf & MSF_ANG)
 739     {
 740         WriteShort(MSG_ENTITY, rint(self.angles_x));
 741         WriteShort(MSG_ENTITY, rint(self.angles_y));
 742     }
 743
 744     if(sf & MSF_MOVE)
 745     {
 746         WriteShort(MSG_ENTITY, rint(self.origin_x));
 747         WriteShort(MSG_ENTITY, rint(self.origin_y));
 748         WriteShort(MSG_ENTITY, rint(self.origin_z));
 749
 750         WriteShort(MSG_ENTITY, rint(self.velocity_x));
 751         WriteShort(MSG_ENTITY, rint(self.velocity_y));
 752         WriteShort(MSG_ENTITY, rint(self.velocity_z));
 753
 754         WriteShort(MSG_ENTITY, rint(self.angles_y));
 755     }
 756
 757     if(sf & MSF_ANIM)
 758     {
 759         WriteCoord(MSG_ENTITY, self.anim_start_time);
 760         WriteByte(MSG_ENTITY, self.frame);
 761     }
 762
 763     if(sf & MSF_STATUS)
 764     {
 765                 WriteByte(MSG_ENTITY, self.skin);
 766
 767         WriteByte(MSG_ENTITY, self.team);
 768
 769         if(self.health <= 0)
 770             WriteByte(MSG_ENTITY, 0);
 771         else
 772             WriteByte(MSG_ENTITY, ceil((self.health / self.max_health) * 255));
 773     }
 774
 775         return TRUE;
 776 }
 777
 778 void monster_link(void() spawnproc)
 779 {
 780     Net_LinkEntity(self, TRUE, 0, monster_send);
 781     self.think      = spawnproc;
 782     self.nextthink  = time;
 783 }
 784
 785 void monsters_corpse_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 786 {
 787         self.health -= damage;
 788
 789         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 790
 791         if(self.health <= -100) // 100 health until gone?
 792         {
 793                 Violence_GibSplash(self, 1, 0.5, attacker);
 794
 795                 self.think = SUB_Remove;
 796                 self.nextthink = time + 0.1;
 797         }
 798 }
 799
 800 void monsters_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 801 {
 802         if(self.frozen && deathtype != DEATH_KILL)
 803                 return;
 804
 805         if(time < self.pain_finished && deathtype != DEATH_KILL)
 806                 return;
 807
 808         if((ignore_turrets && !(attacker.turrcaps_flags & TFL_TURRCAPS_ISTURRET)) || !ignore_turrets)
 809         if(monster_isvalidtarget(attacker, self))
 810                 self.enemy = attacker;
 811
 812         if(deathtype != DEATH_KILL)
 813                 damage *= self.armorvalue;
 814
 815         if(self.weaponentity && self.weaponentity.classname == "shield")
 816                 self.weaponentity.health -= damage;
 817
 818         self.health -= damage;
 819
 820         if(self.sprite)
 821                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 822
 823         self.dmg_time = time;
 824
 825         if(sound_allowed(MSG_BROADCAST, attacker) && deathtype != DEATH_DROWN)
 826                 spamsound (self, CH_PAIN, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);  // FIXME: PLACEHOLDER
 827
 828         self.velocity += force * self.damageforcescale;
 829
 830         if(deathtype != DEATH_DROWN)
 831         {
 832                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 833                 if (damage > 50)
 834                         Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 835                 if (damage > 100)
 836                         Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 837         }
 838
 839         if(self.health <= 0)
 840         {
 841                 if(self.sprite)
 842                 {
 843                         // Update one more time to avoid waypoint fading without emptying healthbar
 844                         WaypointSprite_UpdateHealth(self.sprite, 0);
 845                 }
 846
 847                 if(deathtype == DEATH_KILL)
 848                         self.candrop = FALSE; // killed by mobkill command
 849
 850                 // TODO: fix this?
 851                 activator = attacker;
 852                 other = self.enemy;
 853                 SUB_UseTargets();
 854                 self.target2 = self.oldtarget2; // reset to original target on death, incase we respawn
 855
 856                 self.monster_die();
 857
 858                 frag_attacker = attacker;
 859                 frag_target = self;
 860                 MUTATOR_CALLHOOK(MonsterDies);
 861
 862                 if(self.health <= -100) // check if we're already gibbed
 863                 {
 864                         Violence_GibSplash(self, 1, 0.5, attacker);
 865
 866                         self.think = SUB_Remove;
 867                         self.nextthink = time + 0.1;
 868                 }
 869         }
 870
 871         self.SendFlags |= MSF_STATUS;
 872 }
 873
 874 // used to hook into monster post death functions without a mutator
 875 void monster_hook_death()
 876 {
 877         WaypointSprite_Kill(self.sprite);
 878
 879         if(self.weaponentity)
 880         {
 881                 remove(self.weaponentity);
 882                 self.weaponentity = world;
 883         }
 884
 885         monster_sound(self.msound_death, 0, FALSE);
 886
 887         if(!(self.spawnflags & MONSTERFLAG_SPAWNED) && !self.monster_respawned)
 888                 monsters_killed += 1;
 889
 890         if(self.candrop && self.weapon)
 891                 W_ThrowNewWeapon(self, self.weapon, 0, self.origin, randomvec() * 150 + '0 0 325');
 892
 893         if(IS_CLIENT(self.realowner))
 894                 self.realowner.monstercount -= 1;
 895
 896         self.event_damage       = monsters_corpse_damage;
 897         self.solid                      = SOLID_CORPSE;
 898         self.takedamage         = DAMAGE_AIM;
 899         self.enemy                      = world;
 900         self.movetype           = MOVETYPE_TOSS;
 901         self.moveto                     = self.origin;
 902
 903         if not(self.flags & FL_FLY)
 904                 self.velocity = '0 0 0';
 905
 906         self.SendFlags |= MSF_MOVE;
 907
 908         totalspawned -= 1;
 909 }
 910
 911 // used to hook into monster post spawn functions without a mutator
 912 void monster_hook_spawn()
 913 {
 914         if not(self.monster_respawned)
 915                 Monster_CheckMinibossFlag();
 916
 917         self.max_health = self.health;
 918         self.pain_finished = self.nextthink;
 919         self.anim_start_time = time;
 920
 921         if(self.noalign)
 922         {
 923                 setorigin(self, self.origin);
 924                 tracebox(self.origin + '0 0 100', self.mins, self.maxs, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
 925                 setorigin(self, trace_endpos);
 926         }
 927
 928         self.pos1 = self.origin;
 929
 930         monster_precachesounds(self);
 931
 932         if(teamplay)
 933                 self.monster_attack = TRUE; // we can have monster enemies in team games
 934
 935         if(autocvar_g_monsters_healthbars)
 936         {
 937                 WaypointSprite_Spawn(strzone(strdecolorize(self.netname)), 0, 600, self, '0 0 1' * (self.maxs_z + 15), world, 0, self, sprite, FALSE, RADARICON_DANGER, ((self.team) ? Team_ColorRGB(self.team) : '1 0 0'));
 938                 WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
 939                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 940         }
 941
 942         monster_sound(self.msound_spawn, 0, FALSE);
 943
 944         MUTATOR_CALLHOOK(MonsterSpawn);
 945
 946         self.SendFlags = MSF_SETUP;
 947 }
 948
 949 float monster_initialize(string  net_name, float mon_id,
 950                                                  vector  min_s,
 951                                                  vector  max_s,
 952                                                  float   nodrop,
 953                                                  void() dieproc,
 954                                                  void() spawnproc)
 955 {
 956         if not(autocvar_g_monsters)
 957                 return FALSE;
 958
 959         // support for quake style removing monsters based on skill
 960         if(monster_skill <= autocvar_g_monsters_skill_easy && (self.spawnflags & MONSTERSKILL_NOTEASY)) { return FALSE; }
 961         if(monster_skill == autocvar_g_monsters_skill_normal && (self.spawnflags & MONSTERSKILL_NOTMEDIUM)) { return FALSE; }
 962         if(monster_skill == autocvar_g_monsters_skill_hard && (self.spawnflags & MONSTERSKILL_NOTHARD)) { return FALSE; }
 963         if(monster_skill == autocvar_g_monsters_skill_insane && (self.spawnflags & MONSTERSKILL_NOTINSANE)) { return FALSE; }
 964         if(monster_skill >= autocvar_g_monsters_skill_nightmare && (self.spawnflags & MONSTERSKILL_NOTNIGHTMARE)) { return FALSE; }
 965
 966         if(self.netname == "")
 967                 self.netname = ((net_name == "") ? self.classname : net_name);
 968
 969         if(autocvar_g_monsters_giants_only)
 970                 self.spawnflags |= MONSTERFLAG_GIANT;
 971
 972         if not(self.scale)
 973                 self.scale = 1;
 974
 975         if(self.spawnflags & MONSTERFLAG_GIANT && !autocvar_g_monsters_nogiants)
 976                 self.scale = 5;
 977
 978         if(self.team && !teamplay)
 979                 self.team = 0;
 980
 981         self.flags = FL_MONSTER;
 982
 983         if not(self.spawnflags & MONSTERFLAG_SPAWNED) // naturally spawned monster
 984         if not(self.monster_respawned)
 985                 monsters_total += 1;
 986
 987         ScaleMonster(self.scale, min_s, max_s);
 988
 989         self.takedamage                 = DAMAGE_AIM;
 990         self.bot_attack                 = TRUE;
 991         self.iscreature                 = TRUE;
 992         self.teleportable               = TRUE;
 993         self.damagedbycontents  = TRUE;
 994         self.monsterid                  = mon_id;
 995         self.damageforcescale   = 0.003;
 996         self.monster_die                = dieproc;
 997         self.event_damage               = monsters_damage;
 998         self.touch                              = MonsterTouch;
 999         self.use                                = monster_use;
1000         self.solid                              = SOLID_BBOX;
1001         self.movetype                   = MOVETYPE_WALK;
1002         self.delay                              = -1; // used in attack delay code
1003         monsters_spawned           += 1;
1004         self.enemy                              = world;
1005         self.velocity                   = '0 0 0';
1006         self.moveto                             = self.origin;
1007         self.pos2                               = self.angles;
1008         self.reset                              = monsters_reset;
1009         self.candrop                    = TRUE;
1010         self.view_ofs                   = '0 0 1' * (self.maxs_z * 0.5);
1011         self.oldtarget2                 = self.target2;
1012         self.deadflag                   = DEAD_NO; // UNDEAD
1013         self.noalign                    = !nodrop;
1014         self.dphitcontentsmask  = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
1015
1016         if not(self.ticrate)
1017                 self.ticrate = autocvar_g_monsters_think_delay;
1018
1019         self.ticrate = bound(sys_frametime, self.ticrate, 60);
1020
1021         if not(self.armorvalue)
1022                 self.armorvalue = 1; // multiplier
1023
1024         if not(self.target_range)
1025                 self.target_range = autocvar_g_monsters_target_range;
1026
1027         if not(self.respawntime)
1028                 self.respawntime = autocvar_g_monsters_respawn_delay;
1029
1030         if not(self.monster_moveflags)
1031                 self.monster_moveflags = MONSTER_MOVE_WANDER;
1032
1033         monster_link(spawnproc);
1034
1035         return TRUE;
1036 }