qcsrc/server/monsters/lib/monsters.qc

   1 // TODO: clean up this file?
   2
   3 void M_Item_Touch ()
   4 {
   5         if(self && IS_PLAYER(other) && other.deadflag == DEAD_NO)
   6         {
   7                 Item_Touch();
   8                 self.think = SUB_Remove;
   9                 self.nextthink = time + 0.1;
  10         }
  11 }
  12
  13 void monster_item_spawn()
  14 {
  15         self.monster_delayedattack();
  16
  17         self.think = monster_item_spawn;
  18         self.nextthink = time + 0.1;
  19         self.gravity = 1;
  20         self.velocity = randomvec() * 175 + '0 0 325';
  21         self.touch = M_Item_Touch;
  22
  23         SUB_SetFade(self, time + 5, 1);
  24 }
  25
  26 void Monster_DropItem (string itype, string itemsize)
  27 {
  28         vector org = self.origin + ((self.mins + self.maxs) * 0.5);
  29         entity e = spawn();
  30
  31         setorigin(e, org);
  32
  33         switch(itype)
  34         {
  35                 case "armor":
  36                 {
  37                         switch(itemsize)
  38                         {
  39                                 case "mega": e.monster_delayedattack = spawnfunc_item_armor_large; break;
  40                                 case "large": e.monster_delayedattack = spawnfunc_item_armor_big; break;
  41                                 case "medium": e.monster_delayedattack = spawnfunc_item_armor_medium; break;
  42                                 case "small": e.monster_delayedattack = spawnfunc_item_armor_small; break;
  43                                 default: break;
  44                         }
  45                         break; // break here?
  46                 }
  47                 case "health":
  48                 {
  49                         switch(itemsize)
  50                         {
  51                                 case "mega": e.monster_delayedattack = spawnfunc_item_health_mega; break;
  52                                 case "large": e.monster_delayedattack = spawnfunc_item_health_large; break;
  53                                 case "medium": e.monster_delayedattack = spawnfunc_item_health_medium; break;
  54                                 case "small": e.monster_delayedattack = spawnfunc_item_health_small; break;
  55                                 default: break;
  56                         }
  57                         break; // break here?
  58                 }
  59                 case "ammo":
  60                 {
  61                         switch(itemsize)
  62                         {
  63                                 case "shells": e.monster_delayedattack = spawnfunc_item_shells; break;
  64                                 case "cells": e.monster_delayedattack = spawnfunc_item_cells; break;
  65                                 case "rockets": e.monster_delayedattack = spawnfunc_item_rockets; break;
  66                                 case "bullets":
  67                                 case "nails": e.monster_delayedattack = spawnfunc_item_bullets; break;
  68                                 default: break;
  69                         }
  70                         break;
  71                 }
  72                 default: break;
  73         }
  74
  75         if(g_minstagib)
  76                 e.monster_delayedattack = spawnfunc_item_minst_cells;
  77
  78         e.think = monster_item_spawn;
  79         e.nextthink = time + 0.1;
  80 }
  81
  82 void monsters_setframe(float _frame)
  83 {
  84         if(self.frame == _frame)
  85                 return;
  86
  87         self.anim_start_time = time;
  88         self.frame = _frame;
  89         self.SendFlags |= MSF_ANIM;
  90 }
  91
  92 float monster_isvalidtarget (entity targ, entity ent)
  93 {
  94         if(!targ || !ent)
  95                 return FALSE; // this check should fix a crash
  96
  97         if(time < game_starttime)
  98                 return FALSE; // monsters do nothing before the match has started
  99
 100         WarpZone_TraceLine(ent.origin, targ.origin, MOVE_NORMAL, ent);
 101
 102         if(vlen(targ.origin - ent.origin) >= ent.target_range)
 103                 return FALSE; // enemy is too far away
 104
 105         if not(targ.vehicle_flags & VHF_ISVEHICLE)
 106         if(trace_ent != targ)
 107                 return FALSE; // we can't see the enemy
 108
 109         if(targ.takedamage == DAMAGE_NO)
 110                 return FALSE; // enemy can't be damaged
 111
 112         if(targ.items & IT_INVISIBILITY)
 113                 return FALSE; // enemy is invisible
 114
 115         if(IS_SPEC(targ) || IS_OBSERVER(targ))
 116                 return FALSE; // enemy is a spectator
 117
 118         if not(targ.vehicle_flags & VHF_ISVEHICLE) // vehicles dont count as alive?
 119         if(targ.deadflag != DEAD_NO || ent.deadflag != DEAD_NO || targ.health <= 0 || ent.health <= 0)
 120                 return FALSE; // enemy/self is dead
 121
 122         if(targ.monster_owner == ent || ent.monster_owner == targ)
 123                 return FALSE; // enemy owns us, or we own them
 124
 125         if not(targ.vehicle_flags & VHF_ISVEHICLE)
 126         if(targ.flags & FL_NOTARGET)
 127                 return FALSE; // enemy can't be targetted
 128
 129         if not(autocvar_g_monsters_typefrag)
 130         if(targ.BUTTON_CHAT)
 131                 return FALSE; // no typefragging!
 132
 133         if not(IsDifferentTeam(targ, ent))
 134                 return FALSE; // enemy is on our team
 135
 136         return TRUE;
 137 }
 138
 139 entity FindTarget (entity ent)
 140 {
 141         if(MUTATOR_CALLHOOK(MonsterFindTarget)) { return ent.enemy; } // Handled by a mutator
 142         entity e;
 143
 144         for(e = world; (e = findflags(e, monster_attack, TRUE)); )
 145         if(monster_isvalidtarget(e, ent))
 146                 return e;
 147
 148         return world;
 149 }
 150
 151 void MonsterTouch ()
 152 {
 153         if(other == world)
 154                 return;
 155
 156         if(self.enemy != other)
 157         if not(other.flags & FL_MONSTER)
 158         if(monster_isvalidtarget(other, self))
 159                 self.enemy = other;
 160 }
 161
 162 void monster_sound(string msound, float sound_delay, float delaytoo)
 163 {
 164         if(delaytoo && time < self.msound_delay)
 165                 return; // too early
 166
 167         if(msound == "")
 168                 return; // sound doesn't exist
 169
 170         sound(self, CHAN_AUTO, msound, VOL_BASE, ATTN_NORM);
 171
 172         self.msound_delay = time + sound_delay;
 173 }
 174
 175 void monster_precachesounds(entity e)
 176 {
 177         precache_sound(e.msound_idle);
 178         precache_sound(e.msound_death);
 179         precache_sound(e.msound_attack_melee);
 180         precache_sound(e.msound_attack_ranged);
 181         precache_sound(e.msound_sight);
 182         precache_sound(e.msound_pain);
 183 }
 184
 185 void monster_melee (entity targ, float damg, float er, float deathtype, float dostop)
 186 {
 187         float bigdmg, dot, rdmg = damg * random();
 188
 189         if (self.health <= 0)
 190                 return;
 191         if (targ == world)
 192                 return;
 193
 194         if(dostop)
 195         {
 196                 self.velocity_x = 0;
 197                 self.velocity_y = 0;
 198                 self.state = MONSTER_STATE_ATTACK_MELEE;
 199                 self.SendFlags |= MSF_MOVE;
 200         }
 201
 202         makevectors (self.angles);
 203         dot = normalize (targ.origin - self.origin) * v_forward;
 204
 205         bigdmg = rdmg * self.scale;
 206
 207         if(dot > er)
 208                 Damage(targ, self, self, bigdmg * monster_skill, deathtype, targ.origin, normalize(targ.origin - self.origin));
 209 }
 210
 211 void Monster_CheckDropCvars (string mon)
 212 {
 213         if not(self.candrop)
 214                 return; // forced off
 215
 216         string dropitem;
 217         string dropsize;
 218
 219         dropitem = cvar_string(strcat("g_monster_", mon, "_drop"));
 220         dropsize = cvar_string(strcat("g_monster_", mon, "_drop_size"));
 221
 222         monster_dropitem = dropitem;
 223         monster_dropsize = dropsize;
 224         MUTATOR_CALLHOOK(MonsterDropItem);
 225         dropitem = monster_dropitem;
 226         dropsize = monster_dropsize;
 227
 228         if(autocvar_g_monsters_forcedrop)
 229                 Monster_DropItem(autocvar_g_monsters_drop_type, autocvar_g_monsters_drop_size);
 230         else if(dropitem != "")
 231                 Monster_DropItem(dropitem, dropsize);
 232         else
 233                 Monster_DropItem("armor", "medium");
 234 }
 235
 236 void ScaleMonster (float scle, vector min_s, vector max_s)
 237 {
 238         // this should prevent monster from falling through floor when scale changes
 239         self.scale = scle;
 240         setsize(self, min_s * scle, max_s * scle);
 241         setorigin(self, self.origin + ('0 0 30' * scle));
 242         self.SendFlags |= MSF_SIZE | MSF_MOVE;
 243 }
 244
 245 void Monster_CheckMinibossFlag ()
 246 {
 247         if(MUTATOR_CALLHOOK(MonsterCheckBossFlag))
 248                 return;
 249
 250         if(self.spawnflags & MONSTERFLAG_GIANT)
 251                 return; // 1 size modifier at a time
 252
 253         float r = random() * 4, chance = random() * 100;
 254
 255         // g_monsters_miniboss_chance cvar or spawnflags 64 causes a monster to be a miniboss
 256         if ((self.spawnflags & MONSTERFLAG_MINIBOSS) || (chance < autocvar_g_monsters_miniboss_chance))
 257         {
 258                 self.health += autocvar_g_monsters_miniboss_healthboost;
 259                 ScaleMonster(1.5, self.mins, self.maxs);
 260                 self.flags |= MONSTERFLAG_MINIBOSS;
 261                 if not(self.weapon)
 262                         self.weapon = WEP_NEX;
 263
 264                 if (r < 2 || self.team == NUM_TEAM_2)
 265                 {
 266                         self.strength_finished = -1;
 267                         self.effects |= (EF_FULLBRIGHT | EF_BLUE);
 268                 }
 269                 else if (r >= 1 || self.team == NUM_TEAM_1)
 270                 {
 271                         self.invincible_finished = -1;
 272                         self.effects |= (EF_FULLBRIGHT | EF_RED);
 273                 }
 274                 else
 275                         self.effects |= (EF_FULLBRIGHT | EF_RED | EF_BLUE);
 276
 277                 if not(self.team)
 278                         self.colormod = randomvec();
 279         }
 280 }
 281
 282 float Monster_CanRespawn(entity ent)
 283 {
 284         other = ent;
 285         if(MUTATOR_CALLHOOK(MonsterRespawn))
 286                 return TRUE; // enabled by a mutator
 287
 288         if(ent.spawnflags & MONSTERFLAG_NORESPAWN)
 289                 return FALSE;
 290
 291         if not(autocvar_g_monsters_respawn)
 292                 return FALSE;
 293
 294         return TRUE;
 295 }
 296
 297 void Monster_Fade ()
 298 {
 299         if(Monster_CanRespawn(self))
 300         {
 301                 self.monster_respawned = TRUE;
 302                 self.netname = ""; // needed to fix sprite (TODO: fix!)
 303                 self.think = self.monster_spawnfunc;
 304                 self.nextthink = time + self.respawntime;
 305                 if(self.respawnflags & MONSTER_RESPAWN_DEATHPOINT)
 306                 {
 307                         self.pos1 = self.origin;
 308                         self.pos2 = self.angles;
 309                 }
 310                 setorigin(self, self.pos1);
 311                 self.angles = self.pos2;
 312                 self.health = self.max_health; // TODO: check if resetting to max_health is wise here
 313                 return;
 314         }
 315         self.think = SUB_Remove;
 316         self.nextthink = time + 4;
 317         SUB_SetFade(self, time + 3, 1);
 318 }
 319
 320 float Monster_CanJump (vector vel)
 321 {
 322         if(self.state)
 323                 return FALSE; // already attacking
 324         if not(self.flags & FL_ONGROUND)
 325                 return FALSE; // not on the ground
 326         if(self.health <= 0)
 327                 return FALSE; // called when dead?
 328         if(time < self.attack_finished_single)
 329                 return FALSE; // still attacking
 330
 331         vector old = self.velocity;
 332
 333         self.velocity = vel;
 334         tracetoss(self, self);
 335         self.velocity = old;
 336         if (trace_ent != self.enemy)
 337                 return FALSE;
 338
 339         return TRUE;
 340 }
 341
 342 float monster_leap (float anm, void() touchfunc, vector vel, float anim_finished)
 343 {
 344         if(!Monster_CanJump(vel))
 345                 return FALSE;
 346
 347         monsters_setframe(anm);
 348         self.state = MONSTER_STATE_ATTACK_LEAP;
 349         self.touch = touchfunc;
 350         self.origin_z += 1;
 351         self.velocity = vel;
 352         self.flags &~= FL_ONGROUND;
 353
 354         self.attack_finished_single = time + anim_finished;
 355
 356         return TRUE;
 357 }
 358
 359 float GenericCheckAttack ()
 360 {
 361         // checking attack while dead?
 362         if (self.health <= 0 || self.enemy == world)
 363                 return FALSE;
 364
 365         if(self.monster_delayedattack && self.delay != -1)
 366         {
 367                 if(time < self.delay)
 368                         return FALSE;
 369
 370                 self.monster_delayedattack();
 371         }
 372
 373         if (time < self.attack_finished_single)
 374                 return FALSE;
 375
 376         if(self.attack_melee)
 377         if(vlen(self.enemy.origin - self.origin) <= 100 * self.scale)
 378         {
 379                 monster_sound(self.msound_attack_melee, 0, FALSE); // no delay for attack sounds
 380                 self.attack_melee(); // don't wait for nextthink - too slow
 381                 return TRUE;
 382         }
 383
 384         // monster doesn't have a ranged attack function, so stop here
 385         if not(self.attack_ranged)
 386                 return FALSE;
 387
 388         // see if any entities are in the way of the shot
 389         if not(findtrajectorywithleading(self.origin, '0 0 0', '0 0 0', self.enemy, 800, 0, 2.5, 0, self))
 390                 return FALSE;
 391
 392         if(self.attack_ranged())
 393         {
 394                 monster_sound(self.msound_attack_ranged, 0, FALSE); // no delay for attack sounds
 395                 return TRUE;
 396         }
 397
 398         return FALSE;
 399 }
 400
 401 void monster_use ()
 402 {
 403         if (self.enemy)
 404                 return;
 405         if (self.health <= 0)
 406                 return;
 407
 408         if(!monster_isvalidtarget(activator, self))
 409                 return;
 410
 411         self.enemy = activator;
 412 }
 413
 414 float trace_path(vector from, vector to)
 415 {
 416         vector dir = normalize(to - from) * 15, offset = '0 0 0';
 417         float trace1 = trace_fraction;
 418
 419         offset_x = dir_y;
 420         offset_y = -dir_x;
 421         traceline (from+offset, to+offset, TRUE, self);
 422
 423         traceline(from-offset, to-offset, TRUE, self);
 424
 425         return ((trace1 < trace_fraction) ? trace1 : trace_fraction);
 426 }
 427
 428 .float last_trace;
 429 vector monster_pickmovetarget(entity targ)
 430 {
 431         // enemy is always preferred target
 432         if(self.enemy)
 433         {
 434                 self.monster_movestate = MONSTER_MOVE_ENEMY;
 435                 self.last_trace = time + 0.1;
 436                 return self.enemy.origin;
 437         }
 438         if(targ)
 439         {
 440                 self.monster_movestate = MONSTER_MOVE_WANDER;
 441                 self.last_trace = time + 0.5;
 442                 return targ.origin;
 443         }
 444
 445         switch(self.monster_moveflags)
 446         {
 447                 case MONSTER_MOVE_OWNER:
 448                 {
 449                         self.monster_movestate = MONSTER_MOVE_OWNER;
 450                         self.last_trace = time + 0.3;
 451                         if(self.monster_owner && self.monster_owner.classname != "monster_swarm")
 452                                 return self.monster_owner.origin;
 453                 }
 454                 case MONSTER_MOVE_WANDER:
 455                 {
 456                         self.monster_movestate = MONSTER_MOVE_WANDER;
 457                         self.last_trace = time + 2;
 458
 459                         self.angles_y = random() * 500;
 460                         makevectors(self.angles);
 461                         return self.origin + v_forward * 600;
 462                 }
 463                 case MONSTER_MOVE_SPAWNLOC:
 464                 {
 465                         self.monster_movestate = MONSTER_MOVE_SPAWNLOC;
 466                         self.last_trace = time + 2;
 467                         return self.pos1;
 468                 }
 469                 default:
 470                 case MONSTER_MOVE_NOMOVE:
 471                 {
 472                         self.monster_movestate = MONSTER_MOVE_NOMOVE;
 473                         self.last_trace = time + 2;
 474                         return self.origin;
 475                 }
 476         }
 477 }
 478
 479 void monster_move(float runspeed, float walkspeed, float stopspeed, float manim_run, float manim_walk, float manim_idle)
 480 {
 481         if(self.target)
 482                 self.goalentity = find(world, targetname, self.target);
 483
 484         entity targ;
 485
 486         if(self.frozen)
 487         {
 488                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
 489                 self.health = max(1, self.max_health * self.revive_progress);
 490
 491                 if(self.sprite) WaypointSprite_UpdateHealth(self.sprite, self.health);
 492
 493                 movelib_beak_simple(stopspeed);
 494
 495                 self.velocity = '0 0 0';
 496                 self.enemy = world;
 497                 self.nextthink = time + 0.1;
 498
 499                 if(self.revive_progress >= 1)
 500                         Unfreeze(self); // wait for next think before attacking
 501
 502                 return; // no moving while frozen
 503         }
 504
 505         if(self.flags & FL_SWIM)
 506         {
 507                 if(self.waterlevel < WATERLEVEL_WETFEET)
 508                 {
 509                         if(time >= self.last_trace)
 510                         {
 511                                 self.last_trace = time + 0.4;
 512                                 self.angles = '0 0 -90';
 513                                 Damage (self, world, world, 2, DEATH_DROWN, self.origin, '0 0 0');
 514                                 if(random() < 0.5)
 515                                 {
 516                                         self.velocity_y += random() * 50;
 517                                         self.velocity_x -= random() * 50;
 518                                 }
 519                                 else
 520                                 {
 521                                         self.velocity_y -= random() * 50;
 522                                         self.velocity_x += random() * 50;
 523                                 }
 524                                 //self.velocity_z += random() * 150;
 525                                 self.movetype = MOVETYPE_BOUNCE;
 526                                 self.velocity_z = -200;
 527                         }
 528                         return;
 529                 }
 530                 else
 531                 {
 532                         self.angles = '0 0 0';
 533                         self.movetype = MOVETYPE_WALK;
 534                 }
 535         }
 536
 537         if(gameover || time < game_starttime)
 538         {
 539                 runspeed = walkspeed = 0;
 540                 monsters_setframe(manim_idle);
 541                 movelib_beak_simple(stopspeed);
 542                 return;
 543         }
 544
 545         targ = self.goalentity;
 546
 547         monster_target = targ;
 548         monster_speed_run = runspeed;
 549         monster_speed_walk = walkspeed;
 550         MUTATOR_CALLHOOK(MonsterMove);
 551         targ = monster_target;
 552         runspeed = monster_speed_run;
 553         walkspeed = monster_speed_walk;
 554
 555         if(IsDifferentTeam(self.monster_owner, self))
 556                 self.monster_owner = world;
 557
 558         if not(monster_isvalidtarget(self.enemy, self))
 559                 self.enemy = world; // check enemy each think frame?
 560
 561         if not(self.enemy)
 562         {
 563                 self.enemy = FindTarget(self);
 564                 if(self.enemy)
 565                         monster_sound(self.msound_sight, 0, FALSE);
 566         }
 567
 568         if(self.state == MONSTER_STATE_ATTACK_MELEE && time >= self.attack_finished_single)
 569                 self.state = 0;
 570
 571         if(self.state != MONSTER_STATE_ATTACK_MELEE) // don't move if set
 572         if(time >= self.last_trace || self.enemy) // update enemy instantly
 573                 self.moveto = monster_pickmovetarget(targ);
 574
 575         if not(self.enemy)
 576                 monster_sound(self.msound_idle, 5, TRUE);
 577
 578         vector angles_face = vectoangles(self.moveto - self.origin);
 579         vector owner_face = vectoangles(self.monster_owner.origin - self.origin);
 580         vector enemy_face = vectoangles(self.enemy.origin - self.origin);
 581
 582         if(self.state != MONSTER_STATE_ATTACK_LEAP)
 583         {
 584                 self.angles_y = angles_face_y;
 585                 self.v_angle = self.angles;
 586         }
 587
 588         if(self.state == MONSTER_STATE_ATTACK_LEAP && (self.flags & FL_ONGROUND))
 589         {
 590                 self.state = 0;
 591                 self.touch = MonsterTouch;
 592         }
 593
 594         v_forward = normalize(self.moveto - self.origin);
 595
 596         float l = vlen(self.moveto - self.origin);
 597         float t1 = trace_path(self.origin+'0 0 10', self.moveto+'0 0 10');
 598         float t2 = trace_path(self.origin-'0 0 15', self.moveto-'0 0 15');
 599
 600         if(t1*l-t2*l>50 && (t1*l > 100 || t1 > 0.8))
 601         if(self.flags & FL_ONGROUND)
 602                 movelib_jump_simple(100);
 603
 604         if(vlen(self.origin - self.moveto) > 64 * self.scale)
 605         {
 606                 if(self.flags & FL_FLY || self.flags & FL_SWIM)
 607                         movelib_move_simple(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 608                 else
 609                         movelib_move_simple_gravity(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 610                 if(time > self.pain_finished)
 611                 if(time > self.attack_finished_single)
 612                         monsters_setframe((self.enemy) ? manim_run : manim_walk);
 613         }
 614         else
 615         {
 616                 movelib_beak_simple(stopspeed);
 617                 if(time > self.attack_finished_single)
 618                 if(time > self.pain_finished)
 619                 if (vlen(self.velocity) <= 30)
 620                 {
 621                         monsters_setframe(manim_idle);
 622                         if(self.enemy)
 623                                 self.angles_y = enemy_face_y;
 624                         else
 625                                 self.angles_y = ((self.monster_owner) ? owner_face_y : self.pos2_y); // reset looking angle now?
 626                 }
 627         }
 628
 629         if(self.enemy && self.checkattack)
 630                 self.checkattack();
 631
 632         self.SendFlags |= MSF_ANG;
 633         if(vlen(self.velocity) > 0)
 634                 self.SendFlags |= MSF_MOVE;
 635 }
 636
 637 void monsters_setstatus()
 638 {
 639         self.stat_monsters_total = monsters_total;
 640         self.stat_monsters_killed = monsters_killed;
 641 }
 642
 643 void Monster_Appear()
 644 {
 645         self.enemy = activator;
 646         self.spawnflags &~= MONSTERFLAG_APPEAR;
 647         self.monster_spawnfunc();
 648 }
 649
 650 float Monster_CheckAppearFlags(entity ent)
 651 {
 652         if not(ent.spawnflags & MONSTERFLAG_APPEAR)
 653                 return FALSE;
 654
 655         ent.think = func_null;
 656         ent.nextthink = -1;
 657         ent.use = Monster_Appear;
 658         ent.flags = FL_MONSTER; // set so this monster can get butchered
 659
 660         return TRUE;
 661 }
 662
 663 void monsters_reset()
 664 {
 665         setorigin(self, self.pos1);
 666         self.angles = self.pos2;
 667
 668         self.health = self.max_health;
 669         self.velocity = '0 0 0';
 670         self.enemy = world;
 671         self.goalentity = world;
 672         self.attack_finished_single = 0;
 673         self.moveto = self.origin;
 674
 675         WaypointSprite_UpdateHealth(self.sprite, self.health);
 676 }
 677
 678 float monster_send(entity to, float sf)
 679 {
 680         WriteByte(MSG_ENTITY, ENT_CLIENT_MONSTER);
 681         WriteByte(MSG_ENTITY, sf);
 682         if(sf & MSF_SETUP)
 683         {
 684             WriteByte(MSG_ENTITY, self.monsterid);
 685
 686             WriteCoord(MSG_ENTITY, self.origin_x);
 687             WriteCoord(MSG_ENTITY, self.origin_y);
 688             WriteCoord(MSG_ENTITY, self.origin_z);
 689
 690             WriteAngle(MSG_ENTITY, self.angles_x);
 691             WriteAngle(MSG_ENTITY, self.angles_y);
 692
 693                 WriteByte(MSG_ENTITY, self.scale);
 694                 WriteByte(MSG_ENTITY, self.skin);
 695     }
 696
 697         if(sf & MSF_SIZE)
 698         {
 699                 WriteByte(MSG_ENTITY, self.scale);
 700
 701                 WriteCoord(MSG_ENTITY, self.mins_x);
 702             WriteCoord(MSG_ENTITY, self.mins_y);
 703             WriteCoord(MSG_ENTITY, self.mins_z);
 704
 705                 WriteCoord(MSG_ENTITY, self.maxs_x);
 706             WriteCoord(MSG_ENTITY, self.maxs_y);
 707             WriteCoord(MSG_ENTITY, self.maxs_z);
 708         }
 709
 710     if(sf & MSF_ANG)
 711     {
 712         WriteShort(MSG_ENTITY, rint(self.angles_x));
 713         WriteShort(MSG_ENTITY, rint(self.angles_y));
 714     }
 715
 716     if(sf & MSF_MOVE)
 717     {
 718         WriteShort(MSG_ENTITY, rint(self.origin_x));
 719         WriteShort(MSG_ENTITY, rint(self.origin_y));
 720         WriteShort(MSG_ENTITY, rint(self.origin_z));
 721
 722         WriteShort(MSG_ENTITY, rint(self.velocity_x));
 723         WriteShort(MSG_ENTITY, rint(self.velocity_y));
 724         WriteShort(MSG_ENTITY, rint(self.velocity_z));
 725
 726         WriteShort(MSG_ENTITY, rint(self.angles_y));
 727     }
 728
 729     if(sf & MSF_ANIM)
 730     {
 731         WriteCoord(MSG_ENTITY, self.anim_start_time);
 732         WriteByte(MSG_ENTITY, self.frame);
 733     }
 734
 735     if(sf & MSF_STATUS)
 736     {
 737         WriteByte(MSG_ENTITY, self.team);
 738
 739         if(self.health <= 0)
 740             WriteByte(MSG_ENTITY, 0);
 741         else
 742             WriteByte(MSG_ENTITY, ceil((self.health / self.max_health) * 255));
 743     }
 744
 745         return TRUE;
 746 }
 747
 748 void monster_link(void() spawnproc)
 749 {
 750     Net_LinkEntity(self, TRUE, 0, monster_send);
 751     self.think      = spawnproc;
 752     self.nextthink  = time;
 753 }
 754
 755 void monsters_corpse_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 756 {
 757         self.health -= damage;
 758
 759         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 760
 761         if(self.health <= -100) // 100 health until gone?
 762         {
 763                 Violence_GibSplash(self, 1, 0.5, attacker);
 764
 765                 self.think = SUB_Remove;
 766                 self.nextthink = time + 0.1;
 767         }
 768 }
 769
 770 void monsters_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 771 {
 772         if(self.frozen && deathtype != DEATH_KILL)
 773                 return;
 774
 775         if(time < self.pain_finished && deathtype != DEATH_KILL)
 776                 return;
 777
 778         if((ignore_turrets && !(attacker.turrcaps_flags & TFL_TURRCAPS_ISTURRET)) || !ignore_turrets)
 779         if(monster_isvalidtarget(attacker, self))
 780                 self.enemy = attacker;
 781
 782         if(deathtype != DEATH_KILL)
 783                 damage *= self.armorvalue;
 784
 785         self.health -= damage;
 786
 787         if(self.sprite)
 788                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 789
 790         self.dmg_time = time;
 791
 792         if(sound_allowed(MSG_BROADCAST, attacker) && deathtype != DEATH_DROWN)
 793                 spamsound (self, CH_PAIN, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);  // FIXME: PLACEHOLDER
 794
 795         self.velocity += force * self.damageforcescale;
 796
 797         if(deathtype != DEATH_DROWN)
 798         {
 799                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 800                 if (damage > 50)
 801                         Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 802                 if (damage > 100)
 803                         Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 804         }
 805
 806         if(self.health <= 0)
 807         {
 808                 if(self.sprite)
 809                 {
 810                         // Update one more time to avoid waypoint fading without emptying healthbar
 811                         WaypointSprite_UpdateHealth(self.sprite, 0);
 812                 }
 813
 814                 if(deathtype == DEATH_KILL)
 815                         self.candrop = FALSE; // killed by mobkill command
 816
 817                 activator = attacker;
 818                 other = self.enemy;
 819                 self.target = self.target2;
 820                 self.target2 = "";
 821                 SUB_UseTargets();
 822
 823                 self.monster_die();
 824
 825                 frag_attacker = attacker;
 826                 frag_target = self;
 827                 MUTATOR_CALLHOOK(MonsterDies);
 828
 829                 if(self.health <= -100) // check if we're already gibbed
 830                 {
 831                         Violence_GibSplash(self, 1, 0.5, attacker);
 832
 833                         self.think = SUB_Remove;
 834                         self.nextthink = time + 0.1;
 835                 }
 836         }
 837
 838         self.SendFlags |= MSF_STATUS;
 839 }
 840
 841 // used to hook into monster post death functions without a mutator
 842 void monster_hook_death()
 843 {
 844         WaypointSprite_Kill(self.sprite);
 845
 846         if(self.weaponentity)
 847         {
 848                 remove(self.weaponentity);
 849                 self.weaponentity = world;
 850         }
 851
 852         monster_sound(self.msound_death, 0, FALSE);
 853
 854         if(!(self.spawnflags & MONSTERFLAG_SPAWNED) && !self.monster_respawned)
 855                 monsters_killed += 1;
 856
 857         if(self.candrop && self.weapon)
 858                 W_ThrowNewWeapon(self, self.weapon, 0, self.origin, randomvec() * 150 + '0 0 325');
 859
 860         if(IS_CLIENT(self.realowner))
 861                 self.realowner.monstercount -= 1;
 862
 863         self.event_damage       = monsters_corpse_damage;
 864         self.solid                      = SOLID_CORPSE;
 865         self.takedamage         = DAMAGE_AIM;
 866         self.enemy                      = world;
 867         self.movetype           = MOVETYPE_TOSS;
 868
 869         totalspawned -= 1;
 870 }
 871
 872 // used to hook into monster post spawn functions without a mutator
 873 void monster_hook_spawn()
 874 {
 875         if not(self.monster_respawned)
 876                 Monster_CheckMinibossFlag();
 877
 878         self.max_health = self.health;
 879         self.pain_finished = self.nextthink;
 880         self.anim_start_time = time;
 881
 882         monster_precachesounds(self);
 883
 884         if(self.team)
 885         {
 886                 //self.colormod = Team_ColorRGB(self.team);
 887                 //self.glowmod = self.colormod;
 888                 self.colormap = 1024 + (self.team - 1) * 17;
 889                 self.colormod = '1 1 1';
 890                 self.glowmod = Team_ColorRGB(self.team);
 891                 self.monster_attack = TRUE;
 892         }
 893         else
 894                 self.colormod = self.glowmod = '1 1 1';
 895
 896         // TODO: fix this...
 897         if (self.target)
 898         {
 899                 self.target2 = self.target;
 900                 self.goalentity = find(world, targetname, self.target);
 901         }
 902
 903         self.sprite_height *= self.scale; // do this after setting the monster's scale
 904
 905         if(autocvar_g_monsters_healthbars)
 906         {
 907                 WaypointSprite_Spawn(self.message, 0, 600, self, '0 0 1' * self.sprite_height, world, 0, self, sprite, FALSE, RADARICON_DANGER, ((self.team) ? Team_ColorRGB(self.team) : '1 0 0'));
 908                 WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
 909                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 910         }
 911
 912         self.message = self.oldmessage;
 913
 914         monster_sound(self.msound_spawn, 0, FALSE);
 915
 916         MUTATOR_CALLHOOK(MonsterSpawn);
 917
 918         self.SendFlags = MSF_SETUP;
 919 }
 920
 921 float monster_initialize(string  net_name, float mon_id,
 922                                                  string  bodymodel,
 923                                                  vector  min_s,
 924                                                  vector  max_s,
 925                                                  float   nodrop,
 926                                                  void() dieproc,
 927                                                  void() spawnproc)
 928 {
 929         if not(autocvar_g_monsters)
 930                 return FALSE;
 931
 932         // support for quake style removing monsters based on skill
 933         if(monster_skill <= autocvar_g_monsters_skill_easy && (self.spawnflags & MONSTERSKILL_NOTEASY)) { return FALSE; }
 934         if(monster_skill == autocvar_g_monsters_skill_normal && (self.spawnflags & MONSTERSKILL_NOTMEDIUM)) { return FALSE; }
 935         if(monster_skill == autocvar_g_monsters_skill_hard && (self.spawnflags & MONSTERSKILL_NOTHARD)) { return FALSE; }
 936         if(monster_skill == autocvar_g_monsters_skill_insane && (self.spawnflags & MONSTERSKILL_NOTINSANE)) { return FALSE; }
 937         if(monster_skill >= autocvar_g_monsters_skill_nightmare && (self.spawnflags & MONSTERSKILL_NOTNIGHTMARE)) { return FALSE; }
 938
 939         if(self.model == "" || self.model == "null")
 940         if(bodymodel == "")
 941                 error("monsters: missing bodymodel!");
 942
 943         if(self.netname == "")
 944         {
 945                 if(net_name != "" && IS_PLAYER(self.realowner))
 946                         net_name = strzone(sprintf("%s^7's %s", self.realowner.netname, net_name));
 947                 self.netname = ((net_name == "") ? self.classname : net_name);
 948                 self.oldmessage = self.message;
 949                 self.message = strzone(strdecolorize(self.netname));
 950         }
 951
 952         if(autocvar_g_monsters_giants_only)
 953                 self.spawnflags |= MONSTERFLAG_GIANT;
 954
 955         if not(self.scale)
 956                 self.scale = 1;
 957
 958         if(self.spawnflags & MONSTERFLAG_GIANT && !autocvar_g_monsters_nogiants)
 959                 self.scale = 5;
 960
 961
 962         if(self.team && !teamplay)
 963                 self.team = 0;
 964
 965         self.flags = FL_MONSTER;
 966
 967         if(self.model && self.model != "null")
 968                 bodymodel = self.model; // TODO: find out why monsters can become invisible
 969
 970         if not(self.spawnflags & MONSTERFLAG_SPAWNED) // naturally spawned monster
 971         if not(self.monster_respawned)
 972                 monsters_total += 1;
 973
 974         precache_model(bodymodel);
 975
 976         setmodel(self, bodymodel);
 977         ScaleMonster(self.scale, min_s, max_s);
 978
 979         self.takedamage                 = DAMAGE_AIM;
 980         self.bot_attack                 = TRUE;
 981         self.iscreature                 = TRUE;
 982         self.teleportable               = TRUE;
 983         self.damagedbycontents  = TRUE;
 984         self.monsterid                  = mon_id;
 985         self.damageforcescale   = 0.003;
 986         self.monster_die                = dieproc;
 987         self.event_damage               = monsters_damage;
 988         self.touch                              = MonsterTouch;
 989         self.use                                = monster_use;
 990         self.solid                              = SOLID_BBOX;
 991         self.movetype                   = MOVETYPE_WALK;
 992         self.delay                              = -1; // used in attack delay code
 993         monsters_spawned           += 1;
 994         self.enemy                              = world;
 995         self.velocity                   = '0 0 0';
 996         self.moveto                             = self.origin;
 997         self.pos2                               = self.angles;
 998         self.reset                              = monsters_reset;
 999         self.candrop                    = TRUE;
1000         self.view_ofs                   = '0 0 1' * self.maxs_z;
1001
1002         if not(self.ticrate)
1003                 self.ticrate = 0.05;
1004
1005         if not(self.armorvalue)
1006                 self.armorvalue = 1; // multiplier
1007
1008         if not(self.target_range)
1009                 self.target_range = autocvar_g_monsters_target_range;
1010
1011         if not(self.respawntime)
1012                 self.respawntime = autocvar_g_monsters_respawn_delay;
1013
1014         if not(self.monster_moveflags)
1015                 self.monster_moveflags = MONSTER_MOVE_WANDER;
1016
1017         if(autocvar_g_nodepthtestplayers)
1018                 self.effects |= EF_NODEPTHTEST;
1019
1020         if(autocvar_g_fullbrightplayers)
1021                 self.effects |= EF_FULLBRIGHT;
1022
1023         if not(nodrop)
1024         {
1025                 setorigin(self, self.origin);
1026                 tracebox(self.origin + '0 0 100', self.mins, self.maxs, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
1027                 setorigin(self, trace_endpos);
1028         }
1029
1030         self.pos1 = self.origin;
1031
1032         monster_link(spawnproc);
1033
1034         return TRUE;
1035 }