qcsrc/server/monsters/lib/monsters.qc

   1 // TODO: clean up this file?
   2
   3 void M_Item_Touch ()
   4 {
   5         if(self && IS_PLAYER(other) && other.deadflag == DEAD_NO)
   6         {
   7                 Item_Touch();
   8                 self.think = SUB_Remove;
   9                 self.nextthink = time + 0.1;
  10         }
  11 }
  12
  13 void monster_item_spawn()
  14 {
  15         self.monster_delayedattack();
  16
  17         self.gravity = 1;
  18         self.velocity = randomvec() * 175 + '0 0 325';
  19         self.touch = M_Item_Touch;
  20
  21         SUB_SetFade(self, time + autocvar_g_monsters_drop_time, 1);
  22 }
  23
  24 void Monster_DropItem (string itype, string itemsize)
  25 {
  26         vector org = self.origin + ((self.mins + self.maxs) * 0.5);
  27         entity e = spawn();
  28
  29         setorigin(e, org);
  30
  31         switch(itype)
  32         {
  33                 case "armor":
  34                 {
  35                         switch(itemsize)
  36                         {
  37                                 case "mega": e.monster_delayedattack = spawnfunc_item_armor_large; break;
  38                                 case "large": e.monster_delayedattack = spawnfunc_item_armor_big; break;
  39                                 case "medium": e.monster_delayedattack = spawnfunc_item_armor_medium; break;
  40                                 case "small": e.monster_delayedattack = spawnfunc_item_armor_small; break;
  41                         }
  42                         break; // break here?
  43                 }
  44                 case "health":
  45                 {
  46                         switch(itemsize)
  47                         {
  48                                 case "mega": e.monster_delayedattack = spawnfunc_item_health_mega; break;
  49                                 case "large": e.monster_delayedattack = spawnfunc_item_health_large; break;
  50                                 case "medium": e.monster_delayedattack = spawnfunc_item_health_medium; break;
  51                                 case "small": e.monster_delayedattack = spawnfunc_item_health_small; break;
  52                         }
  53                         break; // break here?
  54                 }
  55                 case "ammo":
  56                 {
  57                         switch(itemsize)
  58                         {
  59                                 case "shells": e.monster_delayedattack = spawnfunc_item_shells; break;
  60                                 case "cells": e.monster_delayedattack = spawnfunc_item_cells; break;
  61                                 case "rockets": e.monster_delayedattack = spawnfunc_item_rockets; break;
  62                                 case "bullets":
  63                                 case "nails": e.monster_delayedattack = spawnfunc_item_bullets; break;
  64                         }
  65                         break;
  66                 }
  67         }
  68
  69         if(g_minstagib)
  70                 e.monster_delayedattack = spawnfunc_item_minst_cells;
  71
  72         e.think = monster_item_spawn;
  73         e.nextthink = time + 0.1;
  74 }
  75
  76 void monsters_setframe(float _frame)
  77 {
  78         if(self.frame == _frame)
  79                 return;
  80
  81         self.anim_start_time = time;
  82         self.frame = _frame;
  83         self.SendFlags |= MSF_ANIM;
  84 }
  85
  86 float monster_isvalidtarget (entity targ, entity ent)
  87 {
  88         if(!targ || !ent)
  89                 return FALSE; // someone doesn't exist
  90
  91         if(time < game_starttime)
  92                 return FALSE; // monsters do nothing before the match has started
  93
  94         WarpZone_TraceLine(ent.origin, targ.origin, MOVE_NORMAL, ent);
  95
  96         if(vlen(targ.origin - ent.origin) >= ent.target_range)
  97                 return FALSE; // enemy is too far away
  98
  99         if not(targ.vehicle_flags & VHF_ISVEHICLE)
 100         if(trace_ent != targ)
 101                 return FALSE; // we can't see the enemy
 102
 103         if(targ.takedamage == DAMAGE_NO)
 104                 return FALSE; // enemy can't be damaged
 105
 106         if(targ.items & IT_INVISIBILITY)
 107                 return FALSE; // enemy is invisible
 108
 109         if(substring(targ.classname, 0, 10) == "onslaught_")
 110                 return FALSE; // don't attack onslaught targets
 111
 112         if(IS_SPEC(targ) || IS_OBSERVER(targ))
 113                 return FALSE; // enemy is a spectator
 114
 115         if not(targ.vehicle_flags & VHF_ISVEHICLE) // vehicles dont count as alive?
 116         if(targ.deadflag != DEAD_NO || ent.deadflag != DEAD_NO || targ.health <= 0 || ent.health <= 0)
 117                 return FALSE; // enemy/self is dead
 118
 119         if(targ.monster_owner == ent || ent.monster_owner == targ)
 120                 return FALSE; // enemy owns us, or we own them
 121
 122         if not(targ.vehicle_flags & VHF_ISVEHICLE)
 123         if(targ.flags & FL_NOTARGET)
 124                 return FALSE; // enemy can't be targetted
 125
 126         if not(autocvar_g_monsters_typefrag)
 127         if(targ.BUTTON_CHAT)
 128                 return FALSE; // no typefragging!
 129
 130         if not(IsDifferentTeam(targ, ent))
 131                 return FALSE; // enemy is on our team
 132
 133         if(autocvar_g_monsters_target_infront)
 134         if(ent.enemy != targ)
 135         {
 136                 float dot;
 137
 138                 makevectors (ent.angles);
 139                 dot = normalize (targ.origin - ent.origin) * v_forward;
 140
 141                 if(dot <= 0.3)
 142                         return FALSE;
 143         }
 144
 145         return TRUE;
 146 }
 147
 148 entity FindTarget (entity ent)
 149 {
 150         if(MUTATOR_CALLHOOK(MonsterFindTarget)) { return ent.enemy; } // Handled by a mutator
 151         entity e;
 152
 153         for(e = world; (e = findflags(e, monster_attack, TRUE)); )
 154         if(monster_isvalidtarget(e, ent))
 155                 return e;
 156
 157         return world;
 158 }
 159
 160 void MonsterTouch ()
 161 {
 162         if(other == world)
 163                 return;
 164
 165         if(self.enemy != other)
 166         if not(other.flags & FL_MONSTER)
 167         if(monster_isvalidtarget(other, self))
 168                 self.enemy = other;
 169 }
 170
 171 void monster_sound(string msound, float sound_delay, float delaytoo)
 172 {
 173         if(delaytoo && time < self.msound_delay)
 174                 return; // too early
 175
 176         if(msound == "")
 177                 return; // sound doesn't exist
 178
 179         sound(self, CHAN_AUTO, msound, VOL_BASE, ATTN_NORM);
 180
 181         self.msound_delay = time + sound_delay;
 182 }
 183
 184 void monster_precachesounds(entity e)
 185 {
 186         precache_sound(e.msound_idle);
 187         precache_sound(e.msound_death);
 188         precache_sound(e.msound_attack_melee);
 189         precache_sound(e.msound_attack_ranged);
 190         precache_sound(e.msound_sight);
 191         precache_sound(e.msound_pain);
 192 }
 193
 194 void monster_setupsounds(string mon)
 195 {
 196         if(self.msound_idle == "") self.msound_idle = strzone(strcat("monsters/", mon, "_idle.wav"));
 197         if(self.msound_death == "") self.msound_death = strzone(strcat("monsters/", mon, "_death.wav"));
 198         if(self.msound_pain == "") self.msound_pain = strzone(strcat("monsters/", mon, "_pain.wav"));
 199         if(self.msound_attack_melee == "") self.msound_attack_melee = strzone(strcat("monsters/", mon, "_melee.wav"));
 200         if(self.msound_attack_ranged == "") self.msound_attack_ranged = strzone(strcat("monsters/", mon, "_attack.wav"));
 201         if(self.msound_sight == "") self.msound_sight = strzone(strcat("monsters/", mon, "_sight.wav"));
 202 }
 203
 204 void monster_melee (entity targ, float damg, float er, float deathtype, float dostop)
 205 {
 206         float dot, rdmg = damg * random();
 207
 208         if (self.health <= 0)
 209                 return;
 210         if (targ == world)
 211                 return;
 212
 213         if(dostop)
 214         {
 215                 self.velocity_x = 0;
 216                 self.velocity_y = 0;
 217                 self.state = MONSTER_STATE_ATTACK_MELEE;
 218                 self.SendFlags |= MSF_MOVE;
 219         }
 220
 221         makevectors (self.angles);
 222         dot = normalize (targ.origin - self.origin) * v_forward;
 223
 224         if(dot > er)
 225                 Damage(targ, self, self, rdmg * monster_skill, deathtype, targ.origin, normalize(targ.origin - self.origin));
 226 }
 227
 228 void Monster_CheckDropCvars (string mon)
 229 {
 230         if not(self.candrop)
 231                 return; // forced off
 232
 233         string dropitem;
 234         string dropsize;
 235
 236         dropitem = cvar_string(strcat("g_monster_", mon, "_drop"));
 237         dropsize = cvar_string(strcat("g_monster_", mon, "_drop_size"));
 238
 239         monster_dropitem = dropitem;
 240         monster_dropsize = dropsize;
 241         MUTATOR_CALLHOOK(MonsterDropItem);
 242         dropitem = monster_dropitem;
 243         dropsize = monster_dropsize;
 244
 245         if(autocvar_g_monsters_forcedrop)
 246                 Monster_DropItem(autocvar_g_monsters_drop_type, autocvar_g_monsters_drop_size);
 247         else if(dropitem != "")
 248                 Monster_DropItem(dropitem, dropsize);
 249         else
 250                 Monster_DropItem("armor", "medium");
 251 }
 252
 253 void Monster_CheckMinibossFlag ()
 254 {
 255         if(MUTATOR_CALLHOOK(MonsterCheckBossFlag))
 256                 return;
 257
 258         float chance = random() * 100;
 259
 260         // g_monsters_miniboss_chance cvar or spawnflags 64 causes a monster to be a miniboss
 261         if ((self.spawnflags & MONSTERFLAG_MINIBOSS) || (chance < autocvar_g_monsters_miniboss_chance))
 262         {
 263                 self.health += autocvar_g_monsters_miniboss_healthboost;
 264                 self.flags |= MONSTERFLAG_MINIBOSS;
 265                 if not(self.weapon)
 266                         self.weapon = WEP_NEX;
 267         }
 268 }
 269
 270 float Monster_CanRespawn(entity ent)
 271 {
 272         other = ent;
 273         if(MUTATOR_CALLHOOK(MonsterRespawn))
 274                 return TRUE; // enabled by a mutator
 275
 276         if(ent.spawnflags & MONSTERFLAG_NORESPAWN)
 277                 return FALSE;
 278
 279         if not(autocvar_g_monsters_respawn)
 280                 return FALSE;
 281
 282         return TRUE;
 283 }
 284
 285 void Monster_Fade ()
 286 {
 287         if(Monster_CanRespawn(self))
 288         {
 289                 self.monster_respawned = TRUE;
 290                 self.think = self.monster_spawnfunc;
 291                 self.nextthink = time + self.respawntime;
 292                 self.deadflag = DEAD_RESPAWNING;
 293                 if(self.spawnflags & MONSTER_RESPAWN_DEATHPOINT)
 294                 {
 295                         self.pos1 = self.origin;
 296                         self.pos2 = self.angles;
 297                 }
 298                 self.event_damage = func_null;
 299                 self.takedamage = DAMAGE_NO;
 300                 setorigin(self, self.pos1);
 301                 self.angles = self.pos2;
 302                 self.health = self.max_health; // TODO: check if resetting to max_health is wise here
 303
 304                 self.SendFlags |= MSF_MOVE;
 305                 self.SendFlags |= MSF_STATUS;
 306
 307                 return;
 308         }
 309         SUB_SetFade(self, time + 3, 1);
 310 }
 311
 312 float Monster_CanJump (vector vel)
 313 {
 314         if(self.state)
 315                 return FALSE; // already attacking
 316         if not(self.flags & FL_ONGROUND)
 317                 return FALSE; // not on the ground
 318         if(self.health <= 0)
 319                 return FALSE; // called when dead?
 320         if(time < self.attack_finished_single)
 321                 return FALSE; // still attacking
 322
 323         vector old = self.velocity;
 324
 325         self.velocity = vel;
 326         tracetoss(self, self);
 327         self.velocity = old;
 328         if (trace_ent != self.enemy)
 329                 return FALSE;
 330
 331         return TRUE;
 332 }
 333
 334 float monster_leap (float anm, void() touchfunc, vector vel, float anim_finished)
 335 {
 336         if(!Monster_CanJump(vel))
 337                 return FALSE;
 338
 339         monsters_setframe(anm);
 340         self.state = MONSTER_STATE_ATTACK_LEAP;
 341         self.touch = touchfunc;
 342         self.origin_z += 1;
 343         self.velocity = vel;
 344         self.flags &~= FL_ONGROUND;
 345
 346         self.attack_finished_single = time + anim_finished;
 347
 348         return TRUE;
 349 }
 350
 351 void monster_checkattack(entity e, entity targ)
 352 {
 353         if(e == world)
 354                 return;
 355         if(targ == world)
 356         {
 357                 e.monster_delayedattack = func_null;
 358                 e.delay = -1;
 359                 return;
 360         }
 361
 362         if not(e.monster_attackfunc)
 363                 return;
 364
 365         if(e.monster_delayedattack && e.delay != -1)
 366         {
 367                 if(time < e.delay)
 368                         return;
 369
 370                 e.monster_delayedattack();
 371
 372                 return;
 373         }
 374
 375         if(time < e.attack_finished_single)
 376                 return;
 377
 378         if(vlen(targ.origin - e.origin) <= e.attack_range)
 379         if(e.monster_attackfunc(MONSTER_ATTACK_MELEE))
 380         {
 381                 monster_sound(e.msound_attack_melee, 0, FALSE);
 382                 return;
 383         }
 384
 385         if(e.monster_attackfunc(MONSTER_ATTACK_RANGED))
 386         {
 387                 monster_sound(e.msound_attack_ranged, 0, FALSE);
 388                 return;
 389         }
 390 }
 391
 392 void monster_makevectors(entity e)
 393 {
 394         vector v;
 395
 396         v = e.origin + (e.mins + e.maxs) * 0.5;
 397         self.v_angle = vectoangles(v - (self.origin + self.view_ofs));
 398         self.v_angle_x = -self.v_angle_x;
 399
 400         makevectors(self.v_angle);
 401 }
 402
 403 void monster_use ()
 404 {
 405         if (self.enemy)
 406                 return;
 407         if (self.health <= 0)
 408                 return;
 409
 410         if(!monster_isvalidtarget(activator, self))
 411                 return;
 412
 413         self.enemy = activator;
 414 }
 415
 416 float trace_path(vector from, vector to)
 417 {
 418         vector dir = normalize(to - from) * 15, offset = '0 0 0';
 419         float trace1 = trace_fraction;
 420
 421         offset_x = dir_y;
 422         offset_y = -dir_x;
 423         traceline (from+offset, to+offset, TRUE, self);
 424
 425         traceline(from-offset, to-offset, TRUE, self);
 426
 427         return ((trace1 < trace_fraction) ? trace1 : trace_fraction);
 428 }
 429
 430 .float last_trace;
 431 vector monster_pickmovetarget(entity targ)
 432 {
 433         // enemy is always preferred target
 434         if(self.enemy)
 435         {
 436                 self.monster_movestate = MONSTER_MOVE_ENEMY;
 437                 self.last_trace = time + 0.1;
 438                 return self.enemy.origin;
 439         }
 440
 441         switch(self.monster_moveflags)
 442         {
 443                 case MONSTER_MOVE_OWNER:
 444                 {
 445                         self.monster_movestate = MONSTER_MOVE_OWNER;
 446                         self.last_trace = time + 0.3;
 447                         if(self.monster_owner && self.monster_owner.classname != "monster_swarm")
 448                                 return self.monster_owner.origin;
 449                 }
 450                 case MONSTER_MOVE_SPAWNLOC:
 451                 {
 452                         self.monster_movestate = MONSTER_MOVE_SPAWNLOC;
 453                         self.last_trace = time + 2;
 454                         return self.pos1;
 455                 }
 456                 case MONSTER_MOVE_NOMOVE:
 457                 {
 458                         self.monster_movestate = MONSTER_MOVE_NOMOVE;
 459                         self.last_trace = time + 2;
 460                         return self.origin;
 461                 }
 462                 default:
 463                 case MONSTER_MOVE_WANDER:
 464                 {
 465                         vector pos;
 466                         self.monster_movestate = MONSTER_MOVE_WANDER;
 467                         self.last_trace = time + 2;
 468
 469                         self.angles_y = random() * 500;
 470                         makevectors(self.angles);
 471                         pos = self.origin + v_forward * 600;
 472
 473                         if(self.flags & FL_FLY || self.flags & FL_SWIM)
 474                         {
 475                                 pos_z = random() * 200;
 476                                 if(random() >= 0.5)
 477                                         pos_z *= -1;
 478                         }
 479
 480                         if(targ)
 481                         {
 482                                 self.last_trace = time + 0.5;
 483                                 pos = targ.origin;
 484                         }
 485
 486                         return pos;
 487                 }
 488         }
 489 }
 490
 491 void monster_move(float runspeed, float walkspeed, float stopspeed, float manim_run, float manim_walk, float manim_idle)
 492 {
 493         if(self.target2)
 494                 self.goalentity = find(world, targetname, self.target2);
 495
 496         entity targ;
 497
 498         if(self.frozen)
 499         {
 500                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
 501                 self.health = max(1, self.max_health * self.revive_progress);
 502
 503                 if(self.sprite) WaypointSprite_UpdateHealth(self.sprite, self.health);
 504
 505                 movelib_beak_simple(stopspeed);
 506
 507                 self.velocity = '0 0 0';
 508                 self.enemy = world;
 509                 self.nextthink = time + 0.1;
 510
 511                 if(self.revive_progress >= 1)
 512                         Unfreeze(self); // wait for next think before attacking
 513
 514                 self.SendFlags |= MSF_MOVE;
 515
 516                 return; // no moving while frozen
 517         }
 518
 519         if(self.flags & FL_SWIM)
 520         {
 521                 if(self.waterlevel < WATERLEVEL_WETFEET)
 522                 {
 523                         if(time >= self.last_trace)
 524                         {
 525                                 self.last_trace = time + 0.4;
 526
 527                                 Damage (self, world, world, 2, DEATH_DROWN, self.origin, '0 0 0');
 528                                 self.angles = '90 90 0';
 529                                 if(random() < 0.5)
 530                                 {
 531                                         self.velocity_y += random() * 50;
 532                                         self.velocity_x -= random() * 50;
 533                                 }
 534                                 else
 535                                 {
 536                                         self.velocity_y -= random() * 50;
 537                                         self.velocity_x += random() * 50;
 538                                 }
 539                                 self.velocity_z += random() * 150;
 540                         }
 541
 542
 543                         self.movetype = MOVETYPE_BOUNCE;
 544                         //self.velocity_z = -200;
 545
 546                         self.SendFlags |= MSF_MOVE | MSF_ANG;
 547
 548                         return;
 549                 }
 550                 else
 551                 {
 552                         self.angles = '0 0 0';
 553                         self.movetype = MOVETYPE_WALK;
 554                 }
 555         }
 556
 557         targ = self.goalentity;
 558
 559         monster_target = targ;
 560         monster_speed_run = runspeed;
 561         monster_speed_walk = walkspeed;
 562
 563         if(MUTATOR_CALLHOOK(MonsterMove) || gameover || (round_handler_IsActive() && !round_handler_IsRoundStarted()) || time < game_starttime || (autocvar_g_campaign && !campaign_bots_may_start) || time < self.spawn_time)
 564         {
 565                 runspeed = walkspeed = 0;
 566                 if(time >= self.spawn_time)
 567                         monsters_setframe(manim_idle);
 568                 movelib_beak_simple(stopspeed);
 569                 self.SendFlags |= MSF_MOVE;
 570                 return;
 571         }
 572
 573         targ = monster_target;
 574         runspeed = monster_speed_run;
 575         walkspeed = monster_speed_walk;
 576
 577         if(IsDifferentTeam(self.monster_owner, self))
 578                 self.monster_owner = world;
 579
 580         if not(monster_isvalidtarget(self.enemy, self))
 581                 self.enemy = world; // check enemy each think frame?
 582
 583         if not(self.enemy)
 584         {
 585                 self.enemy = FindTarget(self);
 586                 if(self.enemy)
 587                         monster_sound(self.msound_sight, 0, FALSE);
 588         }
 589
 590         if(self.state == MONSTER_STATE_ATTACK_MELEE && time >= self.attack_finished_single)
 591                 self.state = 0;
 592
 593         if(self.state != MONSTER_STATE_ATTACK_MELEE) // don't move if set
 594         if(time >= self.last_trace || self.enemy) // update enemy instantly
 595                 self.moveto = monster_pickmovetarget(targ);
 596
 597         if not(self.enemy)
 598                 monster_sound(self.msound_idle, 5, TRUE);
 599
 600         vector angles_face = vectoangles(self.moveto - self.origin);
 601         vector owner_face = vectoangles(self.monster_owner.origin - self.origin);
 602         vector enemy_face = vectoangles(self.enemy.origin - self.origin);
 603
 604         if(!(self.flags & FL_FLY || self.flags & FL_SWIM))
 605                 self.moveto_z = self.origin_z;
 606
 607         if(self.state != MONSTER_STATE_ATTACK_LEAP)
 608                 self.angles_y = angles_face_y;
 609
 610         if(self.state == MONSTER_STATE_ATTACK_LEAP && (self.flags & FL_ONGROUND))
 611         {
 612                 self.state = 0;
 613                 self.touch = MonsterTouch;
 614         }
 615
 616         v_forward = normalize(self.moveto - self.origin);
 617
 618         float l = vlen(self.moveto - self.origin);
 619         float t1 = trace_path(self.origin+'0 0 10', self.moveto+'0 0 10');
 620         float t2 = trace_path(self.origin-'0 0 15', self.moveto-'0 0 15');
 621
 622         if(t1*l-t2*l>50 && (t1*l > 100 || t1 > 0.8))
 623         if(self.flags & FL_ONGROUND)
 624                 movelib_jump_simple(100);
 625
 626         if(vlen(self.origin - self.moveto) > 64)
 627         {
 628                 if(self.flags & FL_FLY || self.flags & FL_SWIM)
 629                         movelib_move_simple(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 630                 else
 631                         movelib_move_simple_gravity(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 632                 if(time > self.pain_finished)
 633                 if(time > self.attack_finished_single)
 634                         monsters_setframe((self.enemy) ? manim_run : manim_walk);
 635         }
 636         else
 637         {
 638                 if(targ.target)
 639                         self.target2 = targ.target;
 640                 else if(targ.target2)
 641                         self.target2 = targ.target2;
 642                 else
 643                 {
 644                         movelib_beak_simple(stopspeed);
 645                         if(time > self.attack_finished_single)
 646                         if(time > self.pain_finished)
 647                         if (vlen(self.velocity) <= 30)
 648                         {
 649                                 monsters_setframe(manim_idle);
 650                                 if(self.enemy)
 651                                         self.angles_y = enemy_face_y;
 652                                 else
 653                                         self.angles_y = ((self.monster_owner) ? owner_face_y : self.pos2_y); // reset looking angle now?
 654                         }
 655                 }
 656         }
 657
 658         if(self.enemy)
 659                 monster_checkattack(self, self.enemy);
 660
 661         self.SendFlags |= MSF_ANG;
 662         self.SendFlags |= MSF_MOVE;
 663 }
 664
 665 void monster_dead_think()
 666 {
 667         self.think = monster_dead_think;
 668         self.nextthink = time + 0.3; // don't need to update so often now
 669
 670         self.deadflag = DEAD_DEAD;
 671
 672         if(time >= self.ltime)
 673         {
 674                 Monster_Fade();
 675                 return;
 676         }
 677
 678         self.SendFlags |= MSF_MOVE; // keep up to date on the monster's location
 679 }
 680
 681 void monsters_setstatus()
 682 {
 683         self.stat_monsters_total = monsters_total;
 684         self.stat_monsters_killed = monsters_killed;
 685 }
 686
 687 void Monster_Appear()
 688 {
 689         self.enemy = activator;
 690         self.spawnflags &~= MONSTERFLAG_APPEAR;
 691         self.monster_spawnfunc();
 692 }
 693
 694 float Monster_CheckAppearFlags(entity ent)
 695 {
 696         if not(ent.spawnflags & MONSTERFLAG_APPEAR)
 697                 return FALSE;
 698
 699         ent.think = func_null;
 700         ent.nextthink = 0;
 701         ent.use = Monster_Appear;
 702         ent.flags = FL_MONSTER; // set so this monster can get butchered
 703
 704         return TRUE;
 705 }
 706
 707 void monsters_reset()
 708 {
 709         setorigin(self, self.pos1);
 710         self.angles = self.pos2;
 711
 712         self.health = self.max_health;
 713         self.velocity = '0 0 0';
 714         self.enemy = world;
 715         self.goalentity = world;
 716         self.attack_finished_single = 0;
 717         self.moveto = self.origin;
 718
 719         WaypointSprite_UpdateHealth(self.sprite, self.health);
 720 }
 721
 722 float monster_send(entity to, float sf)
 723 {
 724         WriteByte(MSG_ENTITY, ENT_CLIENT_MONSTER);
 725         WriteByte(MSG_ENTITY, sf);
 726         if(sf & MSF_SETUP)
 727         {
 728             WriteByte(MSG_ENTITY, self.monsterid);
 729
 730             WriteCoord(MSG_ENTITY, self.origin_x);
 731             WriteCoord(MSG_ENTITY, self.origin_y);
 732             WriteCoord(MSG_ENTITY, self.origin_z);
 733
 734             WriteAngle(MSG_ENTITY, self.angles_x);
 735             WriteAngle(MSG_ENTITY, self.angles_y);
 736
 737                 WriteByte(MSG_ENTITY, self.skin);
 738                 WriteByte(MSG_ENTITY, self.team);
 739     }
 740
 741     if(sf & MSF_ANG)
 742     {
 743         WriteShort(MSG_ENTITY, rint(self.angles_x));
 744         WriteShort(MSG_ENTITY, rint(self.angles_y));
 745     }
 746
 747     if(sf & MSF_MOVE)
 748     {
 749         WriteShort(MSG_ENTITY, rint(self.origin_x));
 750         WriteShort(MSG_ENTITY, rint(self.origin_y));
 751         WriteShort(MSG_ENTITY, rint(self.origin_z));
 752
 753         WriteShort(MSG_ENTITY, rint(self.velocity_x));
 754         WriteShort(MSG_ENTITY, rint(self.velocity_y));
 755         WriteShort(MSG_ENTITY, rint(self.velocity_z));
 756
 757         WriteShort(MSG_ENTITY, rint(self.angles_y));
 758     }
 759
 760     if(sf & MSF_ANIM)
 761     {
 762         WriteCoord(MSG_ENTITY, self.anim_start_time);
 763         WriteByte(MSG_ENTITY, self.frame);
 764     }
 765
 766     if(sf & MSF_STATUS)
 767     {
 768                 WriteByte(MSG_ENTITY, self.skin);
 769
 770         WriteByte(MSG_ENTITY, self.team);
 771
 772                 WriteByte(MSG_ENTITY, self.deadflag);
 773
 774         if(self.health <= 0)
 775             WriteByte(MSG_ENTITY, 0);
 776         else
 777             WriteByte(MSG_ENTITY, ceil((self.health / self.max_health) * 255));
 778     }
 779
 780         return TRUE;
 781 }
 782
 783 void monster_link(void() spawnproc)
 784 {
 785     Net_LinkEntity(self, TRUE, 0, monster_send);
 786     self.think      = spawnproc;
 787     self.nextthink  = time;
 788 }
 789
 790 void monsters_corpse_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 791 {
 792         self.health -= damage;
 793
 794         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 795
 796         if(self.health <= -100) // 100 health until gone?
 797         {
 798                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 799
 800                 self.think = SUB_Remove;
 801                 self.nextthink = time + 0.1;
 802         }
 803 }
 804
 805 void monsters_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 806 {
 807         if(self.frozen && deathtype != DEATH_KILL)
 808                 return;
 809
 810         if(time < self.pain_finished && deathtype != DEATH_KILL)
 811                 return;
 812
 813         if(time < self.spawnshieldtime)
 814                 return;
 815
 816         if((ignore_turrets && !(attacker.turrcaps_flags & TFL_TURRCAPS_ISTURRET)) || !ignore_turrets)
 817         if(monster_isvalidtarget(attacker, self))
 818                 self.enemy = attacker;
 819
 820         if(deathtype != DEATH_KILL)
 821                 damage *= self.armorvalue;
 822
 823         if(self.weaponentity && self.weaponentity.classname == "shield")
 824                 self.weaponentity.health -= damage;
 825
 826         self.health -= damage;
 827
 828         if(self.sprite)
 829                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 830
 831         self.dmg_time = time;
 832
 833         if(sound_allowed(MSG_BROADCAST, attacker) && deathtype != DEATH_DROWN)
 834                 spamsound (self, CH_PAIN, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);  // FIXME: PLACEHOLDER
 835
 836         self.velocity += force * self.damageforcescale;
 837
 838         if(deathtype != DEATH_DROWN)
 839         {
 840                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 841                 if (damage > 50)
 842                         Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 843                 if (damage > 100)
 844                         Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 845         }
 846
 847         if(self.health <= 0)
 848         {
 849                 if(self.sprite)
 850                 {
 851                         // Update one more time to avoid waypoint fading without emptying healthbar
 852                         WaypointSprite_UpdateHealth(self.sprite, 0);
 853                 }
 854
 855                 if(deathtype == DEATH_KILL)
 856                         self.candrop = FALSE; // killed by mobkill command
 857
 858                 // TODO: fix this?
 859                 activator = attacker;
 860                 other = self.enemy;
 861                 SUB_UseTargets();
 862                 self.target2 = self.oldtarget2; // reset to original target on death, incase we respawn
 863
 864                 self.monster_die();
 865
 866                 frag_attacker = attacker;
 867                 frag_target = self;
 868                 MUTATOR_CALLHOOK(MonsterDies);
 869
 870                 if(self.health <= -100) // check if we're already gibbed
 871                 {
 872                         Violence_GibSplash(self, 1, 0.5, attacker);
 873
 874                         self.think = SUB_Remove;
 875                         self.nextthink = time + 0.1;
 876                 }
 877         }
 878
 879         self.SendFlags |= MSF_STATUS;
 880 }
 881
 882 // used to hook into monster post death functions without a mutator
 883 void monster_hook_death()
 884 {
 885         WaypointSprite_Kill(self.sprite);
 886
 887         if(self.weaponentity)
 888         {
 889                 remove(self.weaponentity);
 890                 self.weaponentity = world;
 891         }
 892
 893         monster_sound(self.msound_death, 0, FALSE);
 894
 895         if(!(self.spawnflags & MONSTERFLAG_SPAWNED) && !self.monster_respawned)
 896                 monsters_killed += 1;
 897
 898         if(self.candrop && self.weapon)
 899                 W_ThrowNewWeapon(self, self.weapon, 0, self.origin, randomvec() * 150 + '0 0 325');
 900
 901         if(IS_CLIENT(self.realowner))
 902                 self.realowner.monstercount -= 1;
 903
 904         self.event_damage       = monsters_corpse_damage;
 905         self.solid                      = SOLID_CORPSE;
 906         self.takedamage         = DAMAGE_AIM;
 907         self.enemy                      = world;
 908         self.movetype           = MOVETYPE_TOSS;
 909         self.moveto                     = self.origin;
 910         self.touch                      = MonsterTouch; // reset incase monster was pouncing
 911
 912         if not(self.flags & FL_FLY)
 913                 self.velocity = '0 0 0';
 914
 915         self.SendFlags |= MSF_MOVE;
 916
 917         totalspawned -= 1;
 918 }
 919
 920 // used to hook into monster post spawn functions without a mutator
 921 void monster_hook_spawn()
 922 {
 923         if not(self.monster_respawned)
 924                 Monster_CheckMinibossFlag();
 925
 926         self.max_health = self.health;
 927         self.pain_finished = self.nextthink;
 928         self.anim_start_time = time;
 929
 930         if not(self.noalign)
 931         {
 932                 setorigin(self, self.origin + '0 0 20');
 933                 tracebox(self.origin + '0 0 100', self.mins, self.maxs, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
 934                 setorigin(self, trace_endpos);
 935         }
 936
 937         if not(self.monster_respawned)
 938                 self.skin = rint(random() * 4);
 939
 940         self.pos1 = self.origin;
 941
 942         monster_precachesounds(self);
 943
 944         if(teamplay)
 945                 self.monster_attack = TRUE; // we can have monster enemies in team games
 946
 947         if(autocvar_g_monsters_healthbars)
 948         {
 949                 WaypointSprite_Spawn(strzone(strdecolorize(self.netname)), 0, 600, self, '0 0 1' * (self.maxs_z + 15), world, 0, self, sprite, FALSE, RADARICON_DANGER, ((self.team) ? Team_ColorRGB(self.team) : '1 0 0'));
 950                 WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
 951                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 952         }
 953
 954         monster_sound(self.msound_spawn, 0, FALSE);
 955
 956         MUTATOR_CALLHOOK(MonsterSpawn);
 957
 958         self.SendFlags = MSF_SETUP;
 959 }
 960
 961 float monster_initialize(string  net_name, float mon_id,
 962                                                  vector  min_s,
 963                                                  vector  max_s,
 964                                                  float   nodrop,
 965                                                  void() dieproc,
 966                                                  void() spawnproc)
 967 {
 968         if not(autocvar_g_monsters)
 969                 return FALSE;
 970
 971         // support for quake style removing monsters based on skill
 972         if(monster_skill <= autocvar_g_monsters_skill_easy && (self.spawnflags & MONSTERSKILL_NOTEASY)) { return FALSE; }
 973         if(monster_skill == autocvar_g_monsters_skill_normal && (self.spawnflags & MONSTERSKILL_NOTMEDIUM)) { return FALSE; }
 974         if(monster_skill == autocvar_g_monsters_skill_hard && (self.spawnflags & MONSTERSKILL_NOTHARD)) { return FALSE; }
 975         if(monster_skill == autocvar_g_monsters_skill_insane && (self.spawnflags & MONSTERSKILL_NOTINSANE)) { return FALSE; }
 976         if(monster_skill >= autocvar_g_monsters_skill_nightmare && (self.spawnflags & MONSTERSKILL_NOTNIGHTMARE)) { return FALSE; }
 977
 978         if(self.netname == "")
 979                 self.netname = ((net_name == "") ? self.classname : net_name);
 980
 981         if(self.team && !teamplay)
 982                 self.team = 0;
 983
 984         self.flags = FL_MONSTER;
 985
 986         if not(self.spawnflags & MONSTERFLAG_SPAWNED) // naturally spawned monster
 987         if not(self.monster_respawned)
 988                 monsters_total += 1;
 989
 990         setsize(self, min_s, max_s);
 991         self.takedamage                 = DAMAGE_AIM;
 992         self.bot_attack                 = TRUE;
 993         self.iscreature                 = TRUE;
 994         self.teleportable               = TRUE;
 995         self.damagedbycontents  = TRUE;
 996         self.monsterid                  = mon_id;
 997         self.damageforcescale   = 0.003;
 998         self.monster_die                = dieproc;
 999         self.event_damage               = monsters_damage;
1000         self.touch                              = MonsterTouch;
1001         self.use                                = monster_use;
1002         self.solid                              = SOLID_BBOX;
1003         self.scale                              = 1;
1004         self.movetype                   = MOVETYPE_WALK;
1005         self.delay                              = -1; // used in attack delay code
1006         self.spawnshieldtime    = time + autocvar_g_monster_spawnshieldtime;
1007         monsters_spawned           += 1;
1008         self.enemy                              = world;
1009         self.velocity                   = '0 0 0';
1010         self.moveto                             = self.origin;
1011         self.pos2                               = self.angles;
1012         self.reset                              = monsters_reset;
1013         self.candrop                    = TRUE;
1014         self.view_ofs                   = '0 0 1' * (self.maxs_z * 0.5);
1015         self.oldtarget2                 = self.target2;
1016         self.deadflag                   = DEAD_NO; // UNDEAD
1017         self.noalign                    = nodrop;
1018         self.spawn_time                 = time;
1019         self.dphitcontentsmask  = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
1020
1021         if not(self.attack_range)
1022                 self.attack_range = 120;
1023
1024         if not(self.ticrate)
1025                 self.ticrate = autocvar_g_monsters_think_delay;
1026
1027         self.ticrate = bound(sys_frametime, self.ticrate, 60);
1028
1029         if not(self.armorvalue)
1030                 self.armorvalue = 1; // multiplier
1031
1032         if not(self.target_range)
1033                 self.target_range = autocvar_g_monsters_target_range;
1034
1035         if not(self.respawntime)
1036                 self.respawntime = autocvar_g_monsters_respawn_delay;
1037
1038         if not(self.monster_moveflags)
1039                 self.monster_moveflags = MONSTER_MOVE_WANDER;
1040
1041         monster_link(spawnproc);
1042
1043         return TRUE;
1044 }