qcsrc/server/monsters/lib/monsters.qc

   1 // TODO: clean up this file?
   2
   3 void M_Item_Touch ()
   4 {
   5         if(self && IS_PLAYER(other) && other.deadflag == DEAD_NO)
   6         {
   7                 Item_Touch();
   8                 self.think = SUB_Remove;
   9                 self.nextthink = time + 0.1;
  10         }
  11 }
  12
  13 void monster_item_spawn()
  14 {
  15         self.monster_delayedattack();
  16
  17         self.think = SUB_Remove;
  18         self.nextthink = time + 5;
  19         self.gravity = 1;
  20         self.velocity = randomvec() * 175 + '0 0 325';
  21         self.touch = M_Item_Touch;
  22
  23         SUB_SetFade(self, time + 5, 1);
  24 }
  25
  26 void Monster_DropItem (string itype, string itemsize)
  27 {
  28         vector org = self.origin + ((self.mins + self.maxs) * 0.5);
  29         entity e = spawn();
  30
  31         setorigin(e, org);
  32
  33         switch(itype)
  34         {
  35                 case "armor":
  36                 {
  37                         switch(itemsize)
  38                         {
  39                                 case "mega": e.monster_delayedattack = spawnfunc_item_armor_large; break;
  40                                 case "large": e.monster_delayedattack = spawnfunc_item_armor_big; break;
  41                                 case "medium": e.monster_delayedattack = spawnfunc_item_armor_medium; break;
  42                                 case "small": e.monster_delayedattack = spawnfunc_item_armor_small; break;
  43                         }
  44                         break; // break here?
  45                 }
  46                 case "health":
  47                 {
  48                         switch(itemsize)
  49                         {
  50                                 case "mega": e.monster_delayedattack = spawnfunc_item_health_mega; break;
  51                                 case "large": e.monster_delayedattack = spawnfunc_item_health_large; break;
  52                                 case "medium": e.monster_delayedattack = spawnfunc_item_health_medium; break;
  53                                 case "small": e.monster_delayedattack = spawnfunc_item_health_small; break;
  54                         }
  55                         break; // break here?
  56                 }
  57                 case "ammo":
  58                 {
  59                         switch(itemsize)
  60                         {
  61                                 case "shells": e.monster_delayedattack = spawnfunc_item_shells; break;
  62                                 case "cells": e.monster_delayedattack = spawnfunc_item_cells; break;
  63                                 case "rockets": e.monster_delayedattack = spawnfunc_item_rockets; break;
  64                                 case "bullets":
  65                                 case "nails": e.monster_delayedattack = spawnfunc_item_bullets; break;
  66                         }
  67                         break;
  68                 }
  69         }
  70
  71         if(g_minstagib)
  72                 e.monster_delayedattack = spawnfunc_item_minst_cells;
  73
  74         e.think = monster_item_spawn;
  75         e.nextthink = time + 0.1;
  76 }
  77
  78 void monsters_setframe(float _frame)
  79 {
  80         if(self.frame == _frame)
  81                 return;
  82
  83         self.anim_start_time = time;
  84         self.frame = _frame;
  85         self.SendFlags |= MSF_ANIM;
  86 }
  87
  88 float monster_isvalidtarget (entity targ, entity ent)
  89 {
  90         if(!targ || !ent)
  91                 return FALSE; // someone doesn't exist
  92
  93         if(time < game_starttime)
  94                 return FALSE; // monsters do nothing before the match has started
  95
  96         WarpZone_TraceLine(ent.origin, targ.origin, MOVE_NORMAL, ent);
  97
  98         if(vlen(targ.origin - ent.origin) >= ent.target_range)
  99                 return FALSE; // enemy is too far away
 100
 101         if not(targ.vehicle_flags & VHF_ISVEHICLE)
 102         if(trace_ent != targ)
 103                 return FALSE; // we can't see the enemy
 104
 105         if(targ.takedamage == DAMAGE_NO)
 106                 return FALSE; // enemy can't be damaged
 107
 108         if(targ.items & IT_INVISIBILITY)
 109                 return FALSE; // enemy is invisible
 110
 111         if(IS_SPEC(targ) || IS_OBSERVER(targ))
 112                 return FALSE; // enemy is a spectator
 113
 114         if not(targ.vehicle_flags & VHF_ISVEHICLE) // vehicles dont count as alive?
 115         if(targ.deadflag != DEAD_NO || ent.deadflag != DEAD_NO || targ.health <= 0 || ent.health <= 0)
 116                 return FALSE; // enemy/self is dead
 117
 118         if(targ.monster_owner == ent || ent.monster_owner == targ)
 119                 return FALSE; // enemy owns us, or we own them
 120
 121         if not(targ.vehicle_flags & VHF_ISVEHICLE)
 122         if(targ.flags & FL_NOTARGET)
 123                 return FALSE; // enemy can't be targetted
 124
 125         if not(autocvar_g_monsters_typefrag)
 126         if(targ.BUTTON_CHAT)
 127                 return FALSE; // no typefragging!
 128
 129         if not(IsDifferentTeam(targ, ent))
 130                 return FALSE; // enemy is on our team
 131
 132         return TRUE;
 133 }
 134
 135 entity FindTarget (entity ent)
 136 {
 137         if(MUTATOR_CALLHOOK(MonsterFindTarget)) { return ent.enemy; } // Handled by a mutator
 138         entity e;
 139
 140         for(e = world; (e = findflags(e, monster_attack, TRUE)); )
 141         if(monster_isvalidtarget(e, ent))
 142                 return e;
 143
 144         return world;
 145 }
 146
 147 void MonsterTouch ()
 148 {
 149         if(other == world)
 150                 return;
 151
 152         if(self.enemy != other)
 153         if not(other.flags & FL_MONSTER)
 154         if(monster_isvalidtarget(other, self))
 155                 self.enemy = other;
 156 }
 157
 158 void monster_sound(string msound, float sound_delay, float delaytoo)
 159 {
 160         if(delaytoo && time < self.msound_delay)
 161                 return; // too early
 162
 163         if(msound == "")
 164                 return; // sound doesn't exist
 165
 166         sound(self, CHAN_AUTO, msound, VOL_BASE, ATTN_NORM);
 167
 168         self.msound_delay = time + sound_delay;
 169 }
 170
 171 void monster_precachesounds(entity e)
 172 {
 173         precache_sound(e.msound_idle);
 174         precache_sound(e.msound_death);
 175         precache_sound(e.msound_attack_melee);
 176         precache_sound(e.msound_attack_ranged);
 177         precache_sound(e.msound_sight);
 178         precache_sound(e.msound_pain);
 179 }
 180
 181 void monster_setupsounds(string mon)
 182 {
 183         if(self.msound_idle == "") self.msound_idle = strzone(strcat("monsters/", mon, "_idle.wav"));
 184         if(self.msound_death == "") self.msound_death = strzone(strcat("monsters/", mon, "_death.wav"));
 185         if(self.msound_pain == "") self.msound_pain = strzone(strcat("monsters/", mon, "_pain.wav"));
 186         if(self.msound_attack_melee == "") self.msound_attack_melee = strzone(strcat("monsters/", mon, "_melee.wav"));
 187         if(self.msound_attack_ranged == "") self.msound_attack_ranged = strzone(strcat("monsters/", mon, "_attack.wav"));
 188         if(self.msound_sight == "") self.msound_sight = strzone(strcat("monsters/", mon, "_sight.wav"));
 189 }
 190
 191 void monster_melee (entity targ, float damg, float er, float deathtype, float dostop)
 192 {
 193         float bigdmg, dot, rdmg = damg * random();
 194
 195         if (self.health <= 0)
 196                 return;
 197         if (targ == world)
 198                 return;
 199
 200         if(dostop)
 201         {
 202                 self.velocity_x = 0;
 203                 self.velocity_y = 0;
 204                 self.state = MONSTER_STATE_ATTACK_MELEE;
 205                 self.SendFlags |= MSF_MOVE;
 206         }
 207
 208         makevectors (self.angles);
 209         dot = normalize (targ.origin - self.origin) * v_forward;
 210
 211         bigdmg = rdmg * self.scale;
 212
 213         if(dot > er)
 214                 Damage(targ, self, self, bigdmg * monster_skill, deathtype, targ.origin, normalize(targ.origin - self.origin));
 215 }
 216
 217 void Monster_CheckDropCvars (string mon)
 218 {
 219         if not(self.candrop)
 220                 return; // forced off
 221
 222         string dropitem;
 223         string dropsize;
 224
 225         dropitem = cvar_string(strcat("g_monster_", mon, "_drop"));
 226         dropsize = cvar_string(strcat("g_monster_", mon, "_drop_size"));
 227
 228         monster_dropitem = dropitem;
 229         monster_dropsize = dropsize;
 230         MUTATOR_CALLHOOK(MonsterDropItem);
 231         dropitem = monster_dropitem;
 232         dropsize = monster_dropsize;
 233
 234         if(autocvar_g_monsters_forcedrop)
 235                 Monster_DropItem(autocvar_g_monsters_drop_type, autocvar_g_monsters_drop_size);
 236         else if(dropitem != "")
 237                 Monster_DropItem(dropitem, dropsize);
 238         else
 239                 Monster_DropItem("armor", "medium");
 240 }
 241
 242 void ScaleMonster (float scle, vector min_s, vector max_s)
 243 {
 244         // this should prevent monster from falling through floor when scale changes
 245         self.scale = scle;
 246         setsize(self, min_s * scle, max_s * scle);
 247         setorigin(self, self.origin + ('0 0 30' * scle));
 248         self.SendFlags |= MSF_SIZE | MSF_MOVE;
 249 }
 250
 251 void Monster_CheckMinibossFlag ()
 252 {
 253         if(MUTATOR_CALLHOOK(MonsterCheckBossFlag))
 254                 return;
 255
 256         if(self.spawnflags & MONSTERFLAG_GIANT)
 257                 return; // 1 size modifier at a time
 258
 259         float chance = random() * 100;
 260
 261         // g_monsters_miniboss_chance cvar or spawnflags 64 causes a monster to be a miniboss
 262         if ((self.spawnflags & MONSTERFLAG_MINIBOSS) || (chance < autocvar_g_monsters_miniboss_chance))
 263         {
 264                 self.health += autocvar_g_monsters_miniboss_healthboost;
 265                 ScaleMonster(1.5, self.mins, self.maxs);
 266                 self.flags |= MONSTERFLAG_MINIBOSS;
 267                 if not(self.weapon)
 268                         self.weapon = WEP_NEX;
 269         }
 270 }
 271
 272 float Monster_CanRespawn(entity ent)
 273 {
 274         other = ent;
 275         if(MUTATOR_CALLHOOK(MonsterRespawn))
 276                 return TRUE; // enabled by a mutator
 277
 278         if(ent.spawnflags & MONSTERFLAG_NORESPAWN)
 279                 return FALSE;
 280
 281         if not(autocvar_g_monsters_respawn)
 282                 return FALSE;
 283
 284         return TRUE;
 285 }
 286
 287 void Monster_Fade ()
 288 {
 289         if(Monster_CanRespawn(self))
 290         {
 291                 self.monster_respawned = TRUE;
 292                 self.think = self.monster_spawnfunc;
 293                 self.nextthink = time + self.respawntime;
 294                 self.deadflag = DEAD_RESPAWNING;
 295                 if(self.spawnflags & MONSTER_RESPAWN_DEATHPOINT)
 296                 {
 297                         self.pos1 = self.origin;
 298                         self.pos2 = self.angles;
 299                 }
 300                 self.event_damage = func_null;
 301                 self.takedamage = DAMAGE_NO;
 302                 setorigin(self, self.pos1);
 303                 self.angles = self.pos2;
 304                 self.health = self.max_health; // TODO: check if resetting to max_health is wise here
 305
 306                 self.SendFlags |= MSF_MOVE;
 307                 self.SendFlags |= MSF_STATUS;
 308
 309                 return;
 310         }
 311         SUB_SetFade(self, time + 3, 1);
 312 }
 313
 314 float Monster_CanJump (vector vel)
 315 {
 316         if(self.state)
 317                 return FALSE; // already attacking
 318         if not(self.flags & FL_ONGROUND)
 319                 return FALSE; // not on the ground
 320         if(self.health <= 0)
 321                 return FALSE; // called when dead?
 322         if(time < self.attack_finished_single)
 323                 return FALSE; // still attacking
 324
 325         vector old = self.velocity;
 326
 327         self.velocity = vel;
 328         tracetoss(self, self);
 329         self.velocity = old;
 330         if (trace_ent != self.enemy)
 331                 return FALSE;
 332
 333         return TRUE;
 334 }
 335
 336 float monster_leap (float anm, void() touchfunc, vector vel, float anim_finished)
 337 {
 338         if(!Monster_CanJump(vel))
 339                 return FALSE;
 340
 341         monsters_setframe(anm);
 342         self.state = MONSTER_STATE_ATTACK_LEAP;
 343         self.touch = touchfunc;
 344         self.origin_z += 1;
 345         self.velocity = vel;
 346         self.flags &~= FL_ONGROUND;
 347
 348         self.attack_finished_single = time + anim_finished;
 349
 350         return TRUE;
 351 }
 352
 353 float GenericCheckAttack ()
 354 {
 355         // checking attack while dead?
 356         if (self.health <= 0)
 357                 return FALSE;
 358
 359         // reset delays when we have no enemy
 360         if not(self.enemy)
 361         {
 362                 self.monster_delayedattack = func_null;
 363                 self.delay = -1;
 364         }
 365
 366         if(self.monster_delayedattack && self.delay != -1)
 367         {
 368                 if(time < self.delay)
 369                         return FALSE;
 370
 371                 self.monster_delayedattack();
 372         }
 373
 374         if (time < self.attack_finished_single)
 375                 return FALSE;
 376
 377         if(self.attack_melee)
 378         if(vlen(self.enemy.origin - self.origin) <= 100 * self.scale)
 379         {
 380                 monster_sound(self.msound_attack_melee, 0, FALSE); // no delay for attack sounds
 381                 self.attack_melee(); // don't wait for nextthink - too slow
 382                 return TRUE;
 383         }
 384
 385         // monster doesn't have a ranged attack function, so stop here
 386         if not(self.attack_ranged)
 387                 return FALSE;
 388
 389         // see if any entities are in the way of the shot
 390         if not(findtrajectorywithleading(self.origin, '0 0 0', '0 0 0', self.enemy, 800, 0, 2.5, 0, self))
 391                 return FALSE;
 392
 393         if(self.attack_ranged())
 394         {
 395                 monster_sound(self.msound_attack_ranged, 0, FALSE); // no delay for attack sounds
 396                 return TRUE;
 397         }
 398
 399         return FALSE;
 400 }
 401
 402 void monster_use ()
 403 {
 404         if (self.enemy)
 405                 return;
 406         if (self.health <= 0)
 407                 return;
 408
 409         if(!monster_isvalidtarget(activator, self))
 410                 return;
 411
 412         self.enemy = activator;
 413 }
 414
 415 float trace_path(vector from, vector to)
 416 {
 417         vector dir = normalize(to - from) * 15, offset = '0 0 0';
 418         float trace1 = trace_fraction;
 419
 420         offset_x = dir_y;
 421         offset_y = -dir_x;
 422         traceline (from+offset, to+offset, TRUE, self);
 423
 424         traceline(from-offset, to-offset, TRUE, self);
 425
 426         return ((trace1 < trace_fraction) ? trace1 : trace_fraction);
 427 }
 428
 429 .float last_trace;
 430 vector monster_pickmovetarget(entity targ)
 431 {
 432         // enemy is always preferred target
 433         if(self.enemy)
 434         {
 435                 self.monster_movestate = MONSTER_MOVE_ENEMY;
 436                 self.last_trace = time + 0.1;
 437                 return self.enemy.origin;
 438         }
 439         if(targ)
 440         {
 441                 self.monster_movestate = MONSTER_MOVE_WANDER;
 442                 self.last_trace = time + 0.5;
 443                 return targ.origin;
 444         }
 445
 446         switch(self.monster_moveflags)
 447         {
 448                 case MONSTER_MOVE_OWNER:
 449                 {
 450                         self.monster_movestate = MONSTER_MOVE_OWNER;
 451                         self.last_trace = time + 0.3;
 452                         if(self.monster_owner && self.monster_owner.classname != "monster_swarm")
 453                                 return self.monster_owner.origin;
 454                 }
 455                 case MONSTER_MOVE_WANDER:
 456                 {
 457                         vector pos;
 458                         self.monster_movestate = MONSTER_MOVE_WANDER;
 459                         self.last_trace = time + 2;
 460
 461                         self.angles_y = random() * 500;
 462                         makevectors(self.angles);
 463                         pos = self.origin + v_forward * 600;
 464
 465                         if(self.flags & FL_FLY || self.flags & FL_SWIM)
 466                         {
 467                                 pos_z = random() * 200;
 468                                 if(random() >= 0.5)
 469                                         pos_z *= -1;
 470                         }
 471
 472                         return pos;
 473                 }
 474                 case MONSTER_MOVE_SPAWNLOC:
 475                 {
 476                         self.monster_movestate = MONSTER_MOVE_SPAWNLOC;
 477                         self.last_trace = time + 2;
 478                         return self.pos1;
 479                 }
 480                 default:
 481                 case MONSTER_MOVE_NOMOVE:
 482                 {
 483                         self.monster_movestate = MONSTER_MOVE_NOMOVE;
 484                         self.last_trace = time + 2;
 485                         return self.origin;
 486                 }
 487         }
 488 }
 489
 490 void monster_move(float runspeed, float walkspeed, float stopspeed, float manim_run, float manim_walk, float manim_idle)
 491 {
 492         if(self.target2)
 493                 self.goalentity = find(world, targetname, self.target2);
 494
 495         entity targ;
 496
 497         if(self.frozen)
 498         {
 499                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
 500                 self.health = max(1, self.max_health * self.revive_progress);
 501
 502                 if(self.sprite) WaypointSprite_UpdateHealth(self.sprite, self.health);
 503
 504                 movelib_beak_simple(stopspeed);
 505
 506                 self.velocity = '0 0 0';
 507                 self.enemy = world;
 508                 self.nextthink = time + 0.1;
 509
 510                 if(self.revive_progress >= 1)
 511                         Unfreeze(self); // wait for next think before attacking
 512
 513                 self.SendFlags |= MSF_MOVE;
 514
 515                 return; // no moving while frozen
 516         }
 517
 518         if(self.flags & FL_SWIM)
 519         {
 520                 if(self.waterlevel < WATERLEVEL_WETFEET)
 521                 {
 522                         if(time >= self.last_trace)
 523                         {
 524                                 self.last_trace = time + 0.4;
 525
 526                                 Damage (self, world, world, 2, DEATH_DROWN, self.origin, '0 0 0');
 527                                 self.angles = '90 90 0';
 528                                 if(random() < 0.5)
 529                                 {
 530                                         self.velocity_y += random() * 50;
 531                                         self.velocity_x -= random() * 50;
 532                                 }
 533                                 else
 534                                 {
 535                                         self.velocity_y -= random() * 50;
 536                                         self.velocity_x += random() * 50;
 537                                 }
 538                                 self.velocity_z += random() * 150;
 539                         }
 540
 541
 542                         self.movetype = MOVETYPE_BOUNCE;
 543                         //self.velocity_z = -200;
 544
 545                         self.SendFlags |= MSF_MOVE | MSF_ANG;
 546
 547                         return;
 548                 }
 549                 else
 550                 {
 551                         self.angles = '0 0 0';
 552                         self.movetype = MOVETYPE_WALK;
 553                 }
 554         }
 555
 556         if(gameover || time < game_starttime || (autocvar_g_campaign && !campaign_bots_may_start) || time < self.spawn_time)
 557         {
 558                 runspeed = walkspeed = 0;
 559                 if(time >= self.spawn_time)
 560                         monsters_setframe(manim_idle);
 561                 movelib_beak_simple(stopspeed);
 562                 self.SendFlags |= MSF_MOVE;
 563                 return;
 564         }
 565
 566         targ = self.goalentity;
 567
 568         monster_target = targ;
 569         monster_speed_run = runspeed;
 570         monster_speed_walk = walkspeed;
 571         MUTATOR_CALLHOOK(MonsterMove);
 572         targ = monster_target;
 573         runspeed = monster_speed_run;
 574         walkspeed = monster_speed_walk;
 575
 576         if(IsDifferentTeam(self.monster_owner, self))
 577                 self.monster_owner = world;
 578
 579         if not(monster_isvalidtarget(self.enemy, self))
 580                 self.enemy = world; // check enemy each think frame?
 581
 582         if not(self.enemy)
 583         {
 584                 self.enemy = FindTarget(self);
 585                 if(self.enemy)
 586                         monster_sound(self.msound_sight, 0, FALSE);
 587         }
 588
 589         if(self.state == MONSTER_STATE_ATTACK_MELEE && time >= self.attack_finished_single)
 590                 self.state = 0;
 591
 592         if(self.state != MONSTER_STATE_ATTACK_MELEE) // don't move if set
 593         if(time >= self.last_trace || self.enemy) // update enemy instantly
 594                 self.moveto = monster_pickmovetarget(targ);
 595
 596         if not(self.enemy)
 597                 monster_sound(self.msound_idle, 5, TRUE);
 598
 599         vector angles_face = vectoangles(self.moveto - self.origin);
 600         vector owner_face = vectoangles(self.monster_owner.origin - self.origin);
 601         vector enemy_face = vectoangles(self.enemy.origin - self.origin);
 602
 603         if(!(self.flags & FL_FLY || self.flags & FL_SWIM))
 604                 self.moveto_z = self.origin_z;
 605
 606         if(self.state != MONSTER_STATE_ATTACK_LEAP)
 607         {
 608                 self.angles_y = angles_face_y;
 609                 self.v_angle = self.angles;
 610         }
 611
 612         if(self.state == MONSTER_STATE_ATTACK_LEAP && (self.flags & FL_ONGROUND))
 613         {
 614                 self.state = 0;
 615                 self.touch = MonsterTouch;
 616         }
 617
 618         v_forward = normalize(self.moveto - self.origin);
 619
 620         float l = vlen(self.moveto - self.origin);
 621         float t1 = trace_path(self.origin+'0 0 10', self.moveto+'0 0 10');
 622         float t2 = trace_path(self.origin-'0 0 15', self.moveto-'0 0 15');
 623
 624         if(t1*l-t2*l>50 && (t1*l > 100 || t1 > 0.8))
 625         if(self.flags & FL_ONGROUND)
 626                 movelib_jump_simple(100);
 627
 628         if(vlen(self.origin - self.moveto) > 64 * self.scale)
 629         {
 630                 if(self.flags & FL_FLY || self.flags & FL_SWIM)
 631                         movelib_move_simple(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 632                 else
 633                         movelib_move_simple_gravity(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 634                 if(time > self.pain_finished)
 635                 if(time > self.attack_finished_single)
 636                         monsters_setframe((self.enemy) ? manim_run : manim_walk);
 637         }
 638         else
 639         {
 640                 if(targ.target)
 641                         self.target2 = targ.target;
 642                 else if(targ.target2)
 643                         self.target2 = targ.target2;
 644                 else
 645                 {
 646                         movelib_beak_simple(stopspeed);
 647                         if(time > self.attack_finished_single)
 648                         if(time > self.pain_finished)
 649                         if (vlen(self.velocity) <= 30)
 650                         {
 651                                 monsters_setframe(manim_idle);
 652                                 if(self.enemy)
 653                                         self.angles_y = enemy_face_y;
 654                                 else
 655                                         self.angles_y = ((self.monster_owner) ? owner_face_y : self.pos2_y); // reset looking angle now?
 656                         }
 657                 }
 658         }
 659
 660         if(self.enemy && self.checkattack)
 661                 self.checkattack();
 662
 663         self.SendFlags |= MSF_ANG;
 664         self.SendFlags |= MSF_MOVE;
 665 }
 666
 667 void monster_dead_think()
 668 {
 669         self.think = monster_dead_think;
 670         self.nextthink = time + 0.3; // don't need to update so often now
 671
 672         self.deadflag = DEAD_DEAD;
 673
 674         if(time >= self.ltime)
 675         {
 676                 Monster_Fade();
 677                 return;
 678         }
 679
 680         self.SendFlags |= MSF_MOVE; // keep up to date on the monster's location
 681 }
 682
 683 void monsters_setstatus()
 684 {
 685         self.stat_monsters_total = monsters_total;
 686         self.stat_monsters_killed = monsters_killed;
 687 }
 688
 689 void Monster_Appear()
 690 {
 691         self.enemy = activator;
 692         self.spawnflags &~= MONSTERFLAG_APPEAR;
 693         self.monster_spawnfunc();
 694 }
 695
 696 float Monster_CheckAppearFlags(entity ent)
 697 {
 698         if not(ent.spawnflags & MONSTERFLAG_APPEAR)
 699                 return FALSE;
 700
 701         ent.think = func_null;
 702         ent.nextthink = 0;
 703         ent.use = Monster_Appear;
 704         ent.flags = FL_MONSTER; // set so this monster can get butchered
 705
 706         return TRUE;
 707 }
 708
 709 void monsters_reset()
 710 {
 711         setorigin(self, self.pos1);
 712         self.angles = self.pos2;
 713
 714         self.health = self.max_health;
 715         self.velocity = '0 0 0';
 716         self.enemy = world;
 717         self.goalentity = world;
 718         self.attack_finished_single = 0;
 719         self.moveto = self.origin;
 720
 721         WaypointSprite_UpdateHealth(self.sprite, self.health);
 722 }
 723
 724 float monster_send(entity to, float sf)
 725 {
 726         WriteByte(MSG_ENTITY, ENT_CLIENT_MONSTER);
 727         WriteByte(MSG_ENTITY, sf);
 728         if(sf & MSF_SETUP)
 729         {
 730             WriteByte(MSG_ENTITY, self.monsterid);
 731
 732             WriteCoord(MSG_ENTITY, self.origin_x);
 733             WriteCoord(MSG_ENTITY, self.origin_y);
 734             WriteCoord(MSG_ENTITY, self.origin_z);
 735
 736             WriteAngle(MSG_ENTITY, self.angles_x);
 737             WriteAngle(MSG_ENTITY, self.angles_y);
 738
 739                 WriteByte(MSG_ENTITY, self.scale);
 740                 WriteByte(MSG_ENTITY, self.skin);
 741     }
 742
 743         if(sf & MSF_SIZE)
 744         {
 745                 WriteByte(MSG_ENTITY, self.scale);
 746
 747                 WriteCoord(MSG_ENTITY, self.mins_x);
 748             WriteCoord(MSG_ENTITY, self.mins_y);
 749             WriteCoord(MSG_ENTITY, self.mins_z);
 750
 751                 WriteCoord(MSG_ENTITY, self.maxs_x);
 752             WriteCoord(MSG_ENTITY, self.maxs_y);
 753             WriteCoord(MSG_ENTITY, self.maxs_z);
 754         }
 755
 756     if(sf & MSF_ANG)
 757     {
 758         WriteShort(MSG_ENTITY, rint(self.angles_x));
 759         WriteShort(MSG_ENTITY, rint(self.angles_y));
 760     }
 761
 762     if(sf & MSF_MOVE)
 763     {
 764         WriteShort(MSG_ENTITY, rint(self.origin_x));
 765         WriteShort(MSG_ENTITY, rint(self.origin_y));
 766         WriteShort(MSG_ENTITY, rint(self.origin_z));
 767
 768         WriteShort(MSG_ENTITY, rint(self.velocity_x));
 769         WriteShort(MSG_ENTITY, rint(self.velocity_y));
 770         WriteShort(MSG_ENTITY, rint(self.velocity_z));
 771
 772         WriteShort(MSG_ENTITY, rint(self.angles_y));
 773     }
 774
 775     if(sf & MSF_ANIM)
 776     {
 777         WriteCoord(MSG_ENTITY, self.anim_start_time);
 778         WriteByte(MSG_ENTITY, self.frame);
 779     }
 780
 781     if(sf & MSF_STATUS)
 782     {
 783                 WriteByte(MSG_ENTITY, self.skin);
 784
 785         WriteByte(MSG_ENTITY, self.team);
 786
 787                 WriteByte(MSG_ENTITY, self.deadflag);
 788
 789         if(self.health <= 0)
 790             WriteByte(MSG_ENTITY, 0);
 791         else
 792             WriteByte(MSG_ENTITY, ceil((self.health / self.max_health) * 255));
 793     }
 794
 795         return TRUE;
 796 }
 797
 798 void monster_link(void() spawnproc)
 799 {
 800     Net_LinkEntity(self, TRUE, 0, monster_send);
 801     self.think      = spawnproc;
 802     self.nextthink  = time;
 803 }
 804
 805 void monsters_corpse_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 806 {
 807         self.health -= damage;
 808
 809         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 810
 811         if(self.health <= -100) // 100 health until gone?
 812         {
 813                 Violence_GibSplash(self, 1, 0.5, attacker);
 814
 815                 self.think = SUB_Remove;
 816                 self.nextthink = time + 0.1;
 817         }
 818 }
 819
 820 void monsters_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 821 {
 822         if(self.frozen && deathtype != DEATH_KILL)
 823                 return;
 824
 825         if(time < self.pain_finished && deathtype != DEATH_KILL)
 826                 return;
 827
 828         if((ignore_turrets && !(attacker.turrcaps_flags & TFL_TURRCAPS_ISTURRET)) || !ignore_turrets)
 829         if(monster_isvalidtarget(attacker, self))
 830                 self.enemy = attacker;
 831
 832         if(deathtype != DEATH_KILL)
 833                 damage *= self.armorvalue;
 834
 835         if(self.weaponentity && self.weaponentity.classname == "shield")
 836                 self.weaponentity.health -= damage;
 837
 838         self.health -= damage;
 839
 840         if(self.sprite)
 841                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 842
 843         self.dmg_time = time;
 844
 845         if(sound_allowed(MSG_BROADCAST, attacker) && deathtype != DEATH_DROWN)
 846                 spamsound (self, CH_PAIN, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);  // FIXME: PLACEHOLDER
 847
 848         self.velocity += force * self.damageforcescale;
 849
 850         if(deathtype != DEATH_DROWN)
 851         {
 852                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 853                 if (damage > 50)
 854                         Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 855                 if (damage > 100)
 856                         Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 857         }
 858
 859         if(self.health <= 0)
 860         {
 861                 if(self.sprite)
 862                 {
 863                         // Update one more time to avoid waypoint fading without emptying healthbar
 864                         WaypointSprite_UpdateHealth(self.sprite, 0);
 865                 }
 866
 867                 if(deathtype == DEATH_KILL)
 868                         self.candrop = FALSE; // killed by mobkill command
 869
 870                 // TODO: fix this?
 871                 activator = attacker;
 872                 other = self.enemy;
 873                 SUB_UseTargets();
 874                 self.target2 = self.oldtarget2; // reset to original target on death, incase we respawn
 875
 876                 self.monster_die();
 877
 878                 frag_attacker = attacker;
 879                 frag_target = self;
 880                 MUTATOR_CALLHOOK(MonsterDies);
 881
 882                 if(self.health <= -100) // check if we're already gibbed
 883                 {
 884                         Violence_GibSplash(self, 1, 0.5, attacker);
 885
 886                         self.think = SUB_Remove;
 887                         self.nextthink = time + 0.1;
 888                 }
 889         }
 890
 891         self.SendFlags |= MSF_STATUS;
 892 }
 893
 894 // used to hook into monster post death functions without a mutator
 895 void monster_hook_death()
 896 {
 897         WaypointSprite_Kill(self.sprite);
 898
 899         if(self.weaponentity)
 900         {
 901                 remove(self.weaponentity);
 902                 self.weaponentity = world;
 903         }
 904
 905         monster_sound(self.msound_death, 0, FALSE);
 906
 907         if(!(self.spawnflags & MONSTERFLAG_SPAWNED) && !self.monster_respawned)
 908                 monsters_killed += 1;
 909
 910         if(self.candrop && self.weapon)
 911                 W_ThrowNewWeapon(self, self.weapon, 0, self.origin, randomvec() * 150 + '0 0 325');
 912
 913         if(IS_CLIENT(self.realowner))
 914                 self.realowner.monstercount -= 1;
 915
 916         self.event_damage       = monsters_corpse_damage;
 917         self.solid                      = SOLID_CORPSE;
 918         self.takedamage         = DAMAGE_AIM;
 919         self.enemy                      = world;
 920         self.movetype           = MOVETYPE_TOSS;
 921         self.moveto                     = self.origin;
 922
 923         if not(self.flags & FL_FLY)
 924                 self.velocity = '0 0 0';
 925
 926         self.SendFlags |= MSF_MOVE;
 927
 928         totalspawned -= 1;
 929 }
 930
 931 // used to hook into monster post spawn functions without a mutator
 932 void monster_hook_spawn()
 933 {
 934         if not(self.monster_respawned)
 935                 Monster_CheckMinibossFlag();
 936
 937         self.max_health = self.health;
 938         self.pain_finished = self.nextthink;
 939         self.anim_start_time = time;
 940
 941         if not(self.noalign)
 942         {
 943                 setorigin(self, self.origin + '0 0 20');
 944                 tracebox(self.origin + '0 0 100', self.mins, self.maxs, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
 945                 setorigin(self, trace_endpos);
 946         }
 947
 948         self.pos1 = self.origin;
 949
 950         monster_precachesounds(self);
 951
 952         if(teamplay)
 953                 self.monster_attack = TRUE; // we can have monster enemies in team games
 954
 955         if(autocvar_g_monsters_healthbars)
 956         {
 957                 WaypointSprite_Spawn(strzone(strdecolorize(self.netname)), 0, 600, self, '0 0 1' * (self.maxs_z + 15), world, 0, self, sprite, FALSE, RADARICON_DANGER, ((self.team) ? Team_ColorRGB(self.team) : '1 0 0'));
 958                 WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
 959                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 960         }
 961
 962         monster_sound(self.msound_spawn, 0, FALSE);
 963
 964         MUTATOR_CALLHOOK(MonsterSpawn);
 965
 966         self.SendFlags = MSF_SETUP;
 967 }
 968
 969 float monster_initialize(string  net_name, float mon_id,
 970                                                  vector  min_s,
 971                                                  vector  max_s,
 972                                                  float   nodrop,
 973                                                  void() dieproc,
 974                                                  void() spawnproc)
 975 {
 976         if not(autocvar_g_monsters)
 977                 return FALSE;
 978
 979         // support for quake style removing monsters based on skill
 980         if(monster_skill <= autocvar_g_monsters_skill_easy && (self.spawnflags & MONSTERSKILL_NOTEASY)) { return FALSE; }
 981         if(monster_skill == autocvar_g_monsters_skill_normal && (self.spawnflags & MONSTERSKILL_NOTMEDIUM)) { return FALSE; }
 982         if(monster_skill == autocvar_g_monsters_skill_hard && (self.spawnflags & MONSTERSKILL_NOTHARD)) { return FALSE; }
 983         if(monster_skill == autocvar_g_monsters_skill_insane && (self.spawnflags & MONSTERSKILL_NOTINSANE)) { return FALSE; }
 984         if(monster_skill >= autocvar_g_monsters_skill_nightmare && (self.spawnflags & MONSTERSKILL_NOTNIGHTMARE)) { return FALSE; }
 985
 986         if(self.netname == "")
 987                 self.netname = ((net_name == "") ? self.classname : net_name);
 988
 989         if(autocvar_g_monsters_giants_only)
 990                 self.spawnflags |= MONSTERFLAG_GIANT;
 991
 992         if not(self.scale)
 993                 self.scale = 1;
 994
 995         if(self.spawnflags & MONSTERFLAG_GIANT && !autocvar_g_monsters_nogiants)
 996                 self.scale = 5;
 997
 998         if(self.team && !teamplay)
 999                 self.team = 0;
1000
1001         self.flags = FL_MONSTER;
1002
1003         if not(self.spawnflags & MONSTERFLAG_SPAWNED) // naturally spawned monster
1004         if not(self.monster_respawned)
1005                 monsters_total += 1;
1006
1007         ScaleMonster(self.scale, min_s, max_s);
1008
1009         self.takedamage                 = DAMAGE_AIM;
1010         self.bot_attack                 = TRUE;
1011         self.iscreature                 = TRUE;
1012         self.teleportable               = TRUE;
1013         self.damagedbycontents  = TRUE;
1014         self.monsterid                  = mon_id;
1015         self.damageforcescale   = 0.003;
1016         self.monster_die                = dieproc;
1017         self.event_damage               = monsters_damage;
1018         self.touch                              = MonsterTouch;
1019         self.use                                = monster_use;
1020         self.solid                              = SOLID_BBOX;
1021         self.movetype                   = MOVETYPE_WALK;
1022         self.delay                              = -1; // used in attack delay code
1023         monsters_spawned           += 1;
1024         self.enemy                              = world;
1025         self.velocity                   = '0 0 0';
1026         self.moveto                             = self.origin;
1027         self.pos2                               = self.angles;
1028         self.reset                              = monsters_reset;
1029         self.candrop                    = TRUE;
1030         self.view_ofs                   = '0 0 1' * (self.maxs_z * 0.5);
1031         self.oldtarget2                 = self.target2;
1032         self.deadflag                   = DEAD_NO; // UNDEAD
1033         self.noalign                    = nodrop;
1034         self.spawn_time                 = time;
1035         self.dphitcontentsmask  = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
1036
1037         if not(self.ticrate)
1038                 self.ticrate = autocvar_g_monsters_think_delay;
1039
1040         self.ticrate = bound(sys_frametime, self.ticrate, 60);
1041
1042         if not(self.armorvalue)
1043                 self.armorvalue = 1; // multiplier
1044
1045         if not(self.target_range)
1046                 self.target_range = autocvar_g_monsters_target_range;
1047
1048         if not(self.respawntime)
1049                 self.respawntime = autocvar_g_monsters_respawn_delay;
1050
1051         if not(self.monster_moveflags)
1052                 self.monster_moveflags = MONSTER_MOVE_WANDER;
1053
1054         monster_link(spawnproc);
1055
1056         return TRUE;
1057 }