qcsrc/server/miscfunctions.qc

   1 #include "miscfunctions.qh"
   2
   3 #include "antilag.qh"
   4 #include "command/common.qh"
   5 #include "constants.qh"
   6 #include "g_hook.qh"
   7 #include "ipban.qh"
   8 #include <server/mutators/_mod.qh>
   9 #include "../common/t_items.qh"
  10 #include "resources.qh"
  11 #include "items.qh"
  12 #include "player.qh"
  13 #include "weapons/accuracy.qh"
  14 #include "weapons/csqcprojectile.qh"
  15 #include "weapons/selection.qh"
  16 #include "../common/command/_mod.qh"
  17 #include "../common/constants.qh"
  18 #include <common/net_linked.qh>
  19 #include <common/weapons/weapon/crylink.qh>
  20 #include "../common/deathtypes/all.qh"
  21 #include "../common/mapinfo.qh"
  22 #include "../common/notifications/all.qh"
  23 #include "../common/playerstats.qh"
  24 #include "../common/teams.qh"
  25 #include "../common/mapobjects/subs.qh"
  26 #include "../common/util.qh"
  27 #include "../common/turrets/sv_turrets.qh"
  28 #include <common/weapons/_all.qh>
  29 #include "../common/vehicles/sv_vehicles.qh"
  30 #include "../common/vehicles/vehicle.qh"
  31 #include "../common/items/_mod.qh"
  32 #include "../common/state.qh"
  33 #include "../common/effects/qc/globalsound.qh"
  34 #include "../common/wepent.qh"
  35 #include "../lib/csqcmodel/sv_model.qh"
  36 #include "../lib/warpzone/anglestransform.qh"
  37 #include "../lib/warpzone/server.qh"
  38
  39 void crosshair_trace(entity pl)
  40 {
  41         traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  42 }
  43 .bool ctrace_solidchanged;
  44 void crosshair_trace_plusvisibletriggers(entity pl)
  45 {
  46         FOREACH_ENTITY_FLOAT(solid, SOLID_TRIGGER,
  47         {
  48                 if(it.model != "")
  49                 {
  50                         it.solid = SOLID_BSP;
  51                         it.ctrace_solidchanged = true;
  52                         IL_PUSH(g_ctrace_changed, it);
  53                 }
  54         });
  55
  56         crosshair_trace(pl);
  57
  58         IL_EACH(g_ctrace_changed, it.ctrace_solidchanged,
  59         {
  60                 it.solid = SOLID_TRIGGER;
  61                 it.ctrace_solidchanged = false;
  62         });
  63
  64         IL_CLEAR(g_ctrace_changed);
  65 }
  66 void WarpZone_crosshair_trace(entity pl)
  67 {
  68         WarpZone_traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  69 }
  70
  71 void dedicated_print(string input)
  72 {
  73         if (server_is_dedicated) print(input);
  74 }
  75
  76 void GameLogEcho(string s)
  77 {
  78     string fn;
  79     int matches;
  80
  81     if (autocvar_sv_eventlog_files)
  82     {
  83         if (!logfile_open)
  84         {
  85             logfile_open = true;
  86             matches = autocvar_sv_eventlog_files_counter + 1;
  87             cvar_set("sv_eventlog_files_counter", itos(matches));
  88             fn = ftos(matches);
  89             if (strlen(fn) < 8)
  90                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
  91             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
  92             logfile = fopen(fn, FILE_APPEND);
  93             fputs(logfile, ":logversion:3\n");
  94         }
  95         if (logfile >= 0)
  96         {
  97             if (autocvar_sv_eventlog_files_timestamps)
  98                 fputs(logfile, strcat(":time:", strftime(true, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
  99             else
 100                 fputs(logfile, strcat(s, "\n"));
 101         }
 102     }
 103     if (autocvar_sv_eventlog_console)
 104     {
 105         dedicated_print(strcat(s, "\n"));
 106     }
 107 }
 108
 109 void GameLogInit()
 110 {
 111     logfile_open = 0;
 112     // will be opened later
 113 }
 114
 115 void GameLogClose()
 116 {
 117     if (logfile_open && logfile >= 0)
 118     {
 119         fclose(logfile);
 120         logfile = -1;
 121     }
 122 }
 123
 124 entity findnearest(vector point, bool checkitems, vector axismod)
 125 {
 126     vector dist;
 127     int num_nearest = 0;
 128
 129     IL_EACH(((checkitems) ? g_items : g_locations), ((checkitems) ? (it.target == "###item###") : (it.classname == "target_location")),
 130     {
 131         if ((it.items == IT_KEY1 || it.items == IT_KEY2) && it.target == "###item###")
 132             dist = it.oldorigin;
 133         else
 134             dist = it.origin;
 135         dist = dist - point;
 136         dist = dist.x * axismod.x * '1 0 0' + dist.y * axismod.y * '0 1 0' + dist.z * axismod.z * '0 0 1';
 137         float len = vlen2(dist);
 138
 139         int l;
 140         for (l = 0; l < num_nearest; ++l)
 141         {
 142             if (len < nearest_length[l])
 143                 break;
 144         }
 145
 146         // now i tells us where to insert at
 147         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 148         if (l < NUM_NEAREST_ENTITIES)
 149         {
 150             for (int j = NUM_NEAREST_ENTITIES - 1; j >= l; --j)
 151             {
 152                 nearest_length[j + 1] = nearest_length[j];
 153                 nearest_entity[j + 1] = nearest_entity[j];
 154             }
 155             nearest_length[l] = len;
 156             nearest_entity[l] = it;
 157             if (num_nearest < NUM_NEAREST_ENTITIES)
 158                 num_nearest = num_nearest + 1;
 159         }
 160     });
 161
 162     // now use the first one from our list that we can see
 163     for (int j = 0; j < num_nearest; ++j)
 164     {
 165         traceline(point, nearest_entity[j].origin, true, NULL);
 166         if (trace_fraction == 1)
 167         {
 168             if (j != 0)
 169                 LOG_TRACEF("Nearest point (%s) is not visible, using a visible one.", nearest_entity[0].netname);
 170             return nearest_entity[j];
 171         }
 172     }
 173
 174     if (num_nearest == 0)
 175         return NULL;
 176
 177     LOG_TRACE("Not seeing any location point, using nearest as fallback.");
 178     /* DEBUGGING CODE:
 179     dprint("Candidates were: ");
 180     for(j = 0; j < num_nearest; ++j)
 181     {
 182         if(j != 0)
 183                 dprint(", ");
 184         dprint(nearest_entity[j].netname);
 185     }
 186     dprint("\n");
 187     */
 188
 189     return nearest_entity[0];
 190 }
 191
 192 string NearestLocation(vector p)
 193 {
 194     string ret = "somewhere";
 195     entity loc = findnearest(p, false, '1 1 1');
 196     if (loc)
 197         ret = loc.message;
 198     else
 199     {
 200         loc = findnearest(p, true, '1 1 4');
 201         if (loc)
 202             ret = loc.netname;
 203     }
 204     return ret;
 205 }
 206
 207 string AmmoNameFromWeaponentity(Weapon wep)
 208 {
 209         string ammoitems = "batteries";
 210         switch (wep.ammo_type)
 211         {
 212                 case RESOURCE_SHELLS:  ammoitems = ITEM_Shells.m_name;      break;
 213                 case RESOURCE_BULLETS: ammoitems = ITEM_Bullets.m_name;     break;
 214                 case RESOURCE_ROCKETS: ammoitems = ITEM_Rockets.m_name;     break;
 215                 case RESOURCE_CELLS:   ammoitems = ITEM_Cells.m_name;       break;
 216                 case RESOURCE_PLASMA:  ammoitems = ITEM_Plasma.m_name;      break;
 217                 case RESOURCE_FUEL:    ammoitems = ITEM_JetpackFuel.m_name; break;
 218         }
 219         return ammoitems;
 220 }
 221
 222 .float old_solid;
 223 string formatmessage(entity this, string msg)
 224 {
 225         float p, p1, p2;
 226         float n;
 227         vector cursor;
 228         entity cursor_ent;
 229         string escape;
 230         string replacement;
 231         p = 0;
 232         n = 7;
 233
 234         IL_EACH(g_items, true,
 235         {
 236                 it.old_solid = it.solid;
 237                 it.solid = SOLID_BSP;
 238         });
 239         WarpZone_crosshair_trace(this);
 240         IL_EACH(g_items, true,
 241         {
 242                 it.solid = it.old_solid;
 243         });
 244         cursor = trace_endpos;
 245         cursor_ent = trace_ent;
 246
 247         MUTATOR_CALLHOOK(PreFormatMessage, this, msg);
 248         msg = M_ARGV(1, string);
 249
 250         while (1) {
 251                 if (n < 1)
 252                         break; // too many replacements
 253
 254                 n = n - 1;
 255                 p1 = strstrofs(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 256                 p2 = strstrofs(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 257
 258                 if (p1 < 0)
 259                         p1 = p2;
 260
 261                 if (p2 < 0)
 262                         p2 = p1;
 263
 264                 p = min(p1, p2);
 265
 266                 if (p < 0)
 267                         break;
 268
 269                 replacement = substring(msg, p, 2);
 270                 escape = substring(msg, p + 1, 1);
 271
 272                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 273
 274                 switch(escape)
 275                 {
 276                         case "%": replacement = "%"; break;
 277                         case "\\":replacement = "\\"; break;
 278                         case "n": replacement = "\n"; break;
 279                         case "a": replacement = ftos(floor(GetResourceAmount(this, RESOURCE_ARMOR))); break;
 280                         case "h": replacement = ftos(floor(GetResourceAmount(this, RESOURCE_HEALTH))); break;
 281                         case "l": replacement = NearestLocation(this.origin); break;
 282                         case "y": replacement = NearestLocation(cursor); break;
 283                         case "d": replacement = NearestLocation(this.death_origin); break;
 284                         case "w": replacement = ((this.(weaponentity).m_weapon == WEP_Null) ? ((this.(weaponentity).m_switchweapon == WEP_Null) ? Weapons_from(this.(weaponentity).cnt) : this.(weaponentity).m_switchweapon) : this.(weaponentity).m_weapon).m_name; break;
 285                         case "W": replacement = AmmoNameFromWeaponentity(this.(weaponentity).m_weapon); break;
 286                         case "x": replacement = ((cursor_ent.netname == "" || !cursor_ent) ? "nothing" : cursor_ent.netname); break;
 287                         case "s": replacement = ftos(vlen(this.velocity - this.velocity_z * '0 0 1')); break;
 288                         case "S": replacement = ftos(vlen(this.velocity)); break;
 289                         case "t": replacement = seconds_tostring(ceil(max(0, autocvar_timelimit * 60 + game_starttime - time))); break;
 290                         case "T": replacement = seconds_tostring(floor(time - game_starttime)); break;
 291                         default:
 292                         {
 293                                 MUTATOR_CALLHOOK(FormatMessage, this, escape, replacement, msg);
 294                                 replacement = M_ARGV(2, string);
 295                                 break;
 296                         }
 297                 }
 298
 299                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 300                 p = p + strlen(replacement);
 301         }
 302         return msg;
 303 }
 304
 305 /*
 306 =============
 307 GetCvars
 308 =============
 309 Called with:
 310   0:  sends the request
 311   >0: receives a cvar from name=argv(f) value=argv(f+1)
 312 */
 313 void GetCvars_handleString(entity this, entity store, string thisname, float f, .string field, string name)
 314 {
 315         if (f < 0)
 316         {
 317                 strfree(store.(field));
 318         }
 319         else if (f > 0)
 320         {
 321                 if (thisname == name)
 322                 {
 323                         strcpy(store.(field), argv(f + 1));
 324                 }
 325         }
 326         else
 327                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 328 }
 329 void GetCvars_handleString_Fixup(entity this, entity store, string thisname, float f, .string field, string name, string(entity, string) func)
 330 {
 331         GetCvars_handleString(this, store, thisname, f, field, name);
 332         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 333                 if (thisname == name)
 334                 {
 335                         string s = func(this, strcat1(store.(field)));
 336                         if (s != store.(field))
 337                         {
 338                                 strcpy(store.(field), s);
 339                         }
 340                 }
 341 }
 342 void GetCvars_handleFloat(entity this, entity store, string thisname, float f, .float field, string name)
 343 {
 344         if (f < 0)
 345         {
 346         }
 347         else if (f > 0)
 348         {
 349                 if (thisname == name)
 350                         store.(field) = stof(argv(f + 1));
 351         }
 352         else
 353                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 354 }
 355 void GetCvars_handleFloatOnce(entity this, entity store, string thisname, float f, .float field, string name)
 356 {
 357         if (f < 0)
 358         {
 359         }
 360         else if (f > 0)
 361         {
 362                 if (thisname == name)
 363                 {
 364                         if (!store.(field))
 365                         {
 366                                 store.(field) = stof(argv(f + 1));
 367                                 if (!store.(field))
 368                                         store.(field) = -1;
 369                         }
 370                 }
 371         }
 372         else
 373         {
 374                 if (!store.(field))
 375                         stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 376         }
 377 }
 378 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(entity this, string wo)
 379 {
 380         string o = W_FixWeaponOrder_ForceComplete(wo);
 381         strcpy(CS(this).weaponorder_byimpulse, W_FixWeaponOrder_BuildImpulseList(o));
 382         return o;
 383 }
 384
 385 REPLICATE(autoswitch, bool, "cl_autoswitch");
 386
 387 REPLICATE(cvar_cl_allow_uid2name, bool, "cl_allow_uid2name");
 388
 389 REPLICATE(cvar_cl_autoscreenshot, int, "cl_autoscreenshot");
 390
 391 REPLICATE(cvar_cl_autotaunt, float, "cl_autotaunt");
 392
 393 REPLICATE(cvar_cl_clippedspectating, bool, "cl_clippedspectating");
 394
 395 REPLICATE(cvar_cl_handicap, float, "cl_handicap");
 396
 397 REPLICATE(cvar_cl_jetpack_jump, bool, "cl_jetpack_jump");
 398
 399 REPLICATE(cvar_cl_movement_track_canjump, bool, "cl_movement_track_canjump");
 400
 401 REPLICATE(cvar_cl_newusekeysupported, bool, "cl_newusekeysupported");
 402
 403 REPLICATE(cvar_cl_noantilag, bool, "cl_noantilag");
 404
 405 REPLICATE(cvar_cl_physics, string, "cl_physics");
 406
 407 REPLICATE(cvar_cl_voice_directional, int, "cl_voice_directional");
 408
 409 REPLICATE(cvar_cl_voice_directional_taunt_attenuation, float, "cl_voice_directional_taunt_attenuation");
 410
 411 REPLICATE(cvar_cl_weaponimpulsemode, int, "cl_weaponimpulsemode");
 412
 413 REPLICATE(cvar_g_xonoticversion, string, "g_xonoticversion");
 414
 415 /**
 416  * @param f -1: cleanup, 0: request, 1: receive
 417  */
 418 void GetCvars(entity this, entity store, int f)
 419 {
 420         string s = string_null;
 421
 422         if (f > 0)
 423                 s = strcat1(argv(f));
 424
 425         get_cvars_f = f;
 426         get_cvars_s = s;
 427         MUTATOR_CALLHOOK(GetCvars);
 428
 429         Notification_GetCvars(this);
 430
 431         ReplicateVars(this, store, s, f);
 432
 433         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 434         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 435         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 436         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 437         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 438         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 439         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 440         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 441         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 442         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 443         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 444
 445         GetCvars_handleFloat(this, store, s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 446
 447         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 448         if (f > 0)
 449         {
 450                 if (s == "cl_weaponpriority")
 451                 {
 452                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 453                         {
 454                                 .entity weaponentity = weaponentities[slot];
 455                                 if (this.(weaponentity) && (this.(weaponentity).m_weapon != WEP_Null || slot == 0))
 456                                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 457                         }
 458                 }
 459                 if (s == "cl_allow_uidtracking")
 460                         PlayerStats_GameReport_AddPlayer(this);
 461         }
 462 }
 463
 464 // decolorizes and team colors the player name when needed
 465 string playername(entity p, bool team_colorize)
 466 {
 467     string t;
 468     if (team_colorize && teamplay && !intermission_running && IS_PLAYER(p))
 469     {
 470         t = Team_ColorCode(p.team);
 471         return strcat(t, strdecolorize(p.netname));
 472     }
 473     else
 474         return p.netname;
 475 }
 476
 477 float want_weapon(entity weaponinfo, float allguns) // WEAPONTODO: what still needs done?
 478 {
 479         int i = weaponinfo.m_id;
 480         int d = 0;
 481         bool allow_mutatorblocked = false;
 482
 483         if(!i)
 484                 return 0;
 485
 486         bool mutator_returnvalue = MUTATOR_CALLHOOK(WantWeapon, weaponinfo, d, allguns, allow_mutatorblocked);
 487         d = M_ARGV(1, float);
 488         allguns = M_ARGV(2, bool);
 489         allow_mutatorblocked = M_ARGV(3, bool);
 490
 491         if(allguns)
 492         {
 493                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 494                         d = true;
 495                 else
 496                         d = false;
 497         }
 498         else if(!mutator_returnvalue)
 499                 d = !(!weaponinfo.weaponstart);
 500
 501         if(!allow_mutatorblocked && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
 502                 d = 0;
 503
 504         float t = weaponinfo.weaponstartoverride;
 505
 506         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 507
 508         // bit order in t:
 509         // 1: want or not
 510         // 2: is default?
 511         // 4: is set by default?
 512         if(t < 0)
 513                 t = 4 | (3 * d);
 514         else
 515                 t |= (2 * d);
 516
 517         return t;
 518 }
 519
 520 void readplayerstartcvars()
 521 {
 522         float i, t;
 523         string s;
 524
 525         // initialize starting values for players
 526         start_weapons = '0 0 0';
 527         start_weapons_default = '0 0 0';
 528         start_weapons_defaultmask = '0 0 0';
 529         start_items = 0;
 530         start_ammo_shells = 0;
 531         start_ammo_nails = 0;
 532         start_ammo_rockets = 0;
 533         start_ammo_cells = 0;
 534         start_ammo_plasma = 0;
 535         if (random_start_ammo == NULL)
 536         {
 537                 random_start_ammo = spawn();
 538         }
 539         start_health = cvar("g_balance_health_start");
 540         start_armorvalue = cvar("g_balance_armor_start");
 541
 542         g_weaponarena = 0;
 543         g_weaponarena_weapons = '0 0 0';
 544
 545         s = cvar_string("g_weaponarena");
 546
 547         MUTATOR_CALLHOOK(SetWeaponArena, s);
 548         s = M_ARGV(0, string);
 549
 550         if (s == "0" || s == "")
 551         {
 552                 // no arena
 553         }
 554         else if (s == "off")
 555         {
 556                 // forcibly turn off weaponarena
 557         }
 558         else if (s == "all" || s == "1")
 559         {
 560                 g_weaponarena = 1;
 561                 g_weaponarena_list = "All Weapons";
 562                 FOREACH(Weapons, it != WEP_Null, {
 563                         if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 564                                 g_weaponarena_weapons |= (it.m_wepset);
 565                 });
 566         }
 567         else if (s == "devall")
 568         {
 569                 g_weaponarena = 1;
 570                 g_weaponarena_list = "All Weapons"; // TODO: report as more than just all weapons?
 571                 FOREACH(Weapons, it != WEP_Null,
 572                 {
 573                         g_weaponarena_weapons |= (it.m_wepset);
 574                 });
 575         }
 576         else if (s == "most")
 577         {
 578                 g_weaponarena = 1;
 579                 g_weaponarena_list = "Most Weapons";
 580                 FOREACH(Weapons, it != WEP_Null, {
 581                         if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 582                                 if(it.spawnflags & WEP_FLAG_NORMAL)
 583                                         g_weaponarena_weapons |= (it.m_wepset);
 584                 });
 585         }
 586         else if (s == "none")
 587         {
 588                 g_weaponarena = 1;
 589                 g_weaponarena_list = "No Weapons";
 590         }
 591         else
 592         {
 593                 g_weaponarena = 1;
 594                 t = tokenize_console(s);
 595                 g_weaponarena_list = "";
 596                 for (i = 0; i < t; ++i)
 597                 {
 598                         s = argv(i);
 599                         FOREACH(Weapons, it != WEP_Null, {
 600                                 if(it.netname == s)
 601                                 {
 602                                         g_weaponarena_weapons |= (it.m_wepset);
 603                                         g_weaponarena_list = strcat(g_weaponarena_list, it.m_name, " & ");
 604                                         break;
 605                                 }
 606                         });
 607                 }
 608                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 609         }
 610
 611         if (g_weaponarena)
 612         {
 613                 g_weapon_stay = 0; // incompatible
 614                 start_weapons = g_weaponarena_weapons;
 615                 start_items |= IT_UNLIMITED_AMMO;
 616         }
 617         else
 618         {
 619                 FOREACH(Weapons, it != WEP_Null, {
 620                         int w = want_weapon(it, false);
 621                         WepSet s = it.m_wepset;
 622                         if(w & 1)
 623                                 start_weapons |= s;
 624                         if(w & 2)
 625                                 start_weapons_default |= s;
 626                         if(w & 4)
 627                                 start_weapons_defaultmask |= s;
 628                 });
 629         }
 630
 631         if(!cvar("g_use_ammunition"))
 632                 start_items |= IT_UNLIMITED_AMMO;
 633
 634         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 635         {
 636                 start_ammo_shells = 999;
 637                 start_ammo_nails = 999;
 638                 start_ammo_rockets = 999;
 639                 start_ammo_cells = 999;
 640                 start_ammo_plasma = 999;
 641                 start_ammo_fuel = 999;
 642         }
 643         else
 644         {
 645                 start_ammo_shells = cvar("g_start_ammo_shells");
 646                 start_ammo_nails = cvar("g_start_ammo_nails");
 647                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 648                 start_ammo_cells = cvar("g_start_ammo_cells");
 649                 start_ammo_plasma = cvar("g_start_ammo_plasma");
 650                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 651                 random_start_weapons_count = cvar("g_random_start_weapons_count");
 652                 SetResourceAmount(random_start_ammo, RESOURCE_SHELLS, cvar(
 653                         "g_random_start_shells"));
 654                 SetResourceAmount(random_start_ammo, RESOURCE_BULLETS, cvar(
 655                         "g_random_start_bullets"));
 656                 SetResourceAmount(random_start_ammo, RESOURCE_ROCKETS,
 657                         cvar("g_random_start_rockets"));
 658                 SetResourceAmount(random_start_ammo, RESOURCE_CELLS, cvar(
 659                         "g_random_start_cells"));
 660                 SetResourceAmount(random_start_ammo, RESOURCE_PLASMA, cvar(
 661                         "g_random_start_plasma"));
 662         }
 663
 664         if (warmup_stage)
 665         {
 666                 warmup_start_ammo_shells = start_ammo_shells;
 667                 warmup_start_ammo_nails = start_ammo_nails;
 668                 warmup_start_ammo_rockets = start_ammo_rockets;
 669                 warmup_start_ammo_cells = start_ammo_cells;
 670                 warmup_start_ammo_plasma = start_ammo_plasma;
 671                 warmup_start_ammo_fuel = start_ammo_fuel;
 672                 warmup_start_health = start_health;
 673                 warmup_start_armorvalue = start_armorvalue;
 674                 warmup_start_weapons = start_weapons;
 675                 warmup_start_weapons_default = start_weapons_default;
 676                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 677
 678                 if (!g_weaponarena && !g_ca && !g_freezetag)
 679                 {
 680                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 681                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 682                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 683                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 684                         warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
 685                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 686                         warmup_start_health = cvar("g_warmup_start_health");
 687                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 688                         warmup_start_weapons = '0 0 0';
 689                         warmup_start_weapons_default = '0 0 0';
 690                         warmup_start_weapons_defaultmask = '0 0 0';
 691                         FOREACH(Weapons, it != WEP_Null, {
 692                                 int w = want_weapon(it, g_warmup_allguns);
 693                                 WepSet s = (it.m_wepset);
 694                                 if(w & 1)
 695                                         warmup_start_weapons |= s;
 696                                 if(w & 2)
 697                                         warmup_start_weapons_default |= s;
 698                                 if(w & 4)
 699                                         warmup_start_weapons_defaultmask |= s;
 700                         });
 701                 }
 702         }
 703
 704         if (g_jetpack)
 705                 start_items |= ITEM_Jetpack.m_itemid;
 706
 707         MUTATOR_CALLHOOK(SetStartItems);
 708
 709         if (start_items & ITEM_Jetpack.m_itemid)
 710         {
 711                 start_items |= ITEM_JetpackRegen.m_itemid;
 712                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 713                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 714         }
 715
 716         WepSet precache_weapons = start_weapons;
 717         if (g_warmup_allguns != 1)
 718                 precache_weapons |= warmup_start_weapons;
 719         FOREACH(Weapons, it != WEP_Null, {
 720                 if(precache_weapons & (it.m_wepset))
 721                         it.wr_init(it);
 722         });
 723
 724         start_ammo_shells = max(0, start_ammo_shells);
 725         start_ammo_nails = max(0, start_ammo_nails);
 726         start_ammo_rockets = max(0, start_ammo_rockets);
 727         start_ammo_cells = max(0, start_ammo_cells);
 728         start_ammo_plasma = max(0, start_ammo_plasma);
 729         start_ammo_fuel = max(0, start_ammo_fuel);
 730         SetResourceAmount(random_start_ammo, RESOURCE_SHELLS, max(0,
 731                 GetResourceAmount(random_start_ammo, RESOURCE_SHELLS)));
 732         SetResourceAmount(random_start_ammo, RESOURCE_BULLETS, max(0,
 733                 GetResourceAmount(random_start_ammo, RESOURCE_BULLETS)));
 734         SetResourceAmount(random_start_ammo, RESOURCE_ROCKETS, max(0,
 735                 GetResourceAmount(random_start_ammo, RESOURCE_ROCKETS)));
 736         SetResourceAmount(random_start_ammo, RESOURCE_CELLS, max(0,
 737                 GetResourceAmount(random_start_ammo, RESOURCE_CELLS)));
 738         SetResourceAmount(random_start_ammo, RESOURCE_PLASMA, max(0,
 739                 GetResourceAmount(random_start_ammo, RESOURCE_PLASMA)));
 740
 741         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 742         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 743         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 744         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 745         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
 746         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 747 }
 748
 749 void precache_playermodel(string m)
 750 {
 751         float globhandle, i, n;
 752         string f;
 753
 754         if(substring(m, -9,5) == "_lod1")
 755                 return;
 756         if(substring(m, -9,5) == "_lod2")
 757                 return;
 758         precache_model(m);
 759         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
 760         if(fexists(f))
 761                 precache_model(f);
 762         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
 763         if(fexists(f))
 764                 precache_model(f);
 765
 766         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
 767         if (globhandle < 0)
 768                 return;
 769         n = search_getsize(globhandle);
 770         for (i = 0; i < n; ++i)
 771         {
 772                 //print(search_getfilename(globhandle, i), "\n");
 773                 f = search_getfilename(globhandle, i);
 774                 PrecachePlayerSounds(f);
 775         }
 776         search_end(globhandle);
 777 }
 778 void precache_all_playermodels(string pattern)
 779 {
 780         int globhandle = search_begin(pattern, true, false);
 781         if (globhandle < 0) return;
 782         int n = search_getsize(globhandle);
 783         for (int i = 0; i < n; ++i)
 784         {
 785                 string s = search_getfilename(globhandle, i);
 786                 precache_playermodel(s);
 787         }
 788         search_end(globhandle);
 789 }
 790
 791 void precache_playermodels(string s)
 792 {
 793         FOREACH_WORD(s, true, { precache_playermodel(it); });
 794 }
 795
 796 void precache()
 797 {
 798     // gamemode related things
 799
 800     // Precache all player models if desired
 801     if (autocvar_sv_precacheplayermodels)
 802     {
 803         PrecachePlayerSounds("sound/player/default.sounds");
 804         precache_all_playermodels("models/player/*.zym");
 805         precache_all_playermodels("models/player/*.dpm");
 806         precache_all_playermodels("models/player/*.md3");
 807         precache_all_playermodels("models/player/*.psk");
 808         precache_all_playermodels("models/player/*.iqm");
 809     }
 810
 811     if (autocvar_sv_defaultcharacter)
 812     {
 813                 precache_playermodels(autocvar_sv_defaultplayermodel_red);
 814                 precache_playermodels(autocvar_sv_defaultplayermodel_blue);
 815                 precache_playermodels(autocvar_sv_defaultplayermodel_yellow);
 816                 precache_playermodels(autocvar_sv_defaultplayermodel_pink);
 817                 precache_playermodels(autocvar_sv_defaultplayermodel);
 818     }
 819
 820 #if 0
 821     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
 822
 823     if (!this.noise && this.music) // quake 3 uses the music field
 824         this.noise = this.music;
 825
 826     // plays music for the level if there is any
 827     if (this.noise)
 828     {
 829         precache_sound (this.noise);
 830         ambientsound ('0 0 0', this.noise, VOL_BASE, ATTEN_NONE);
 831     }
 832 #endif
 833 }
 834
 835
 836 void make_safe_for_remove(entity e)
 837 {
 838     if (e.initialize_entity)
 839     {
 840         entity ent, prev = NULL;
 841         for (ent = initialize_entity_first; ent; )
 842         {
 843             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
 844             {
 845                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
 846                 // skip it in linked list
 847                 if (prev)
 848                 {
 849                     prev.initialize_entity_next = ent.initialize_entity_next;
 850                     ent = prev.initialize_entity_next;
 851                 }
 852                 else
 853                 {
 854                     initialize_entity_first = ent.initialize_entity_next;
 855                     ent = initialize_entity_first;
 856                 }
 857             }
 858             else
 859             {
 860                 prev = ent;
 861                 ent = ent.initialize_entity_next;
 862             }
 863         }
 864     }
 865 }
 866
 867 .float remove_except_protected_forbidden;
 868 void remove_except_protected(entity e)
 869 {
 870         if(e.remove_except_protected_forbidden)
 871                 error("not allowed to remove this at this point");
 872         builtin_remove(e);
 873 }
 874
 875 void remove_unsafely(entity e)
 876 {
 877     if(e.classname == "spike")
 878         error("Removing spikes is forbidden (crylink bug), please report");
 879     builtin_remove(e);
 880 }
 881
 882 void remove_safely(entity e)
 883 {
 884     make_safe_for_remove(e);
 885     builtin_remove(e);
 886 }
 887
 888 void InitializeEntity(entity e, void(entity this) func, float order)
 889 {
 890     entity prev, cur;
 891
 892     if (!e || e.initialize_entity)
 893     {
 894         // make a proxy initializer entity
 895         entity e_old = e;
 896         e = new(initialize_entity);
 897         e.enemy = e_old;
 898     }
 899
 900     e.initialize_entity = func;
 901     e.initialize_entity_order = order;
 902
 903     cur = initialize_entity_first;
 904     prev = NULL;
 905     for (;;)
 906     {
 907         if (!cur || cur.initialize_entity_order > order)
 908         {
 909             // insert between prev and cur
 910             if (prev)
 911                 prev.initialize_entity_next = e;
 912             else
 913                 initialize_entity_first = e;
 914             e.initialize_entity_next = cur;
 915             return;
 916         }
 917         prev = cur;
 918         cur = cur.initialize_entity_next;
 919     }
 920 }
 921 void InitializeEntitiesRun()
 922 {
 923     entity startoflist = initialize_entity_first;
 924     initialize_entity_first = NULL;
 925     delete_fn = remove_except_protected;
 926     for (entity e = startoflist; e; e = e.initialize_entity_next)
 927     {
 928                 e.remove_except_protected_forbidden = 1;
 929     }
 930     for (entity e = startoflist; e; )
 931     {
 932                 e.remove_except_protected_forbidden = 0;
 933         e.initialize_entity_order = 0;
 934         entity next = e.initialize_entity_next;
 935         e.initialize_entity_next = NULL;
 936         var void(entity this) func = e.initialize_entity;
 937         e.initialize_entity = func_null;
 938         if (e.classname == "initialize_entity")
 939         {
 940             entity wrappee = e.enemy;
 941             builtin_remove(e);
 942             e = wrappee;
 943         }
 944         //dprint("Delayed initialization: ", e.classname, "\n");
 945         if (func)
 946         {
 947                 func(e);
 948         }
 949         else
 950         {
 951             eprint(e);
 952             backtrace(strcat("Null function in: ", e.classname, "\n"));
 953         }
 954         e = next;
 955     }
 956     delete_fn = remove_unsafely;
 957 }
 958
 959 .float(entity) isEliminated;
 960 bool EliminatedPlayers_SendEntity(entity this, entity to, float sendflags)
 961 {
 962         Stream out = MSG_ENTITY;
 963         WriteHeader(out, ENT_CLIENT_ELIMINATEDPLAYERS);
 964         serialize(byte, out, sendflags);
 965         if (sendflags & 1) {
 966                 for (int i = 1; i <= maxclients; i += 8) {
 967                         int f = 0;
 968                         entity e = edict_num(i);
 969                         for (int b = 0; b < 8; ++b, e = nextent(e)) {
 970                                 if (eliminatedPlayers.isEliminated(e)) {
 971                                         f |= BIT(b);
 972                                 }
 973                         }
 974                         serialize(byte, out, f);
 975                 }
 976         }
 977         return true;
 978 }
 979
 980 void EliminatedPlayers_Init(float(entity) isEliminated_func)
 981 {
 982         if(eliminatedPlayers)
 983         {
 984                 backtrace("Can't spawn eliminatedPlayers again!");
 985                 return;
 986         }
 987         Net_LinkEntity(eliminatedPlayers = spawn(), false, 0, EliminatedPlayers_SendEntity);
 988         eliminatedPlayers.isEliminated = isEliminated_func;
 989 }
 990
 991
 992
 993
 994 void adaptor_think2use_hittype_splash(entity this) // for timed projectile detonation
 995 {
 996         if(!(IS_ONGROUND(this))) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
 997                 this.projectiledeathtype |= HITTYPE_SPLASH;
 998         adaptor_think2use(this);
 999 }
1000
1001 // deferred dropping
1002 void DropToFloor_Handler(entity this)
1003 {
1004     WITHSELF(this, builtin_droptofloor());
1005     this.dropped_origin = this.origin;
1006 }
1007
1008 void droptofloor(entity this)
1009 {
1010     InitializeEntity(this, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1011 }
1012
1013
1014
1015 float trace_hits_box_a0, trace_hits_box_a1;
1016
1017 float trace_hits_box_1d(float end, float thmi, float thma)
1018 {
1019     if (end == 0)
1020     {
1021         // just check if x is in range
1022         if (0 < thmi)
1023             return false;
1024         if (0 > thma)
1025             return false;
1026     }
1027     else
1028     {
1029         // do the trace with respect to x
1030         // 0 -> end has to stay in thmi -> thma
1031         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1032         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1033         if (trace_hits_box_a0 > trace_hits_box_a1)
1034             return false;
1035     }
1036     return true;
1037 }
1038
1039 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1040 {
1041     end -= start;
1042     thmi -= start;
1043     thma -= start;
1044     // now it is a trace from 0 to end
1045
1046     trace_hits_box_a0 = 0;
1047     trace_hits_box_a1 = 1;
1048
1049     if (!trace_hits_box_1d(end.x, thmi.x, thma.x))
1050         return false;
1051     if (!trace_hits_box_1d(end.y, thmi.y, thma.y))
1052         return false;
1053     if (!trace_hits_box_1d(end.z, thmi.z, thma.z))
1054         return false;
1055
1056     return true;
1057 }
1058
1059 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1060 {
1061     return trace_hits_box(start, end, thmi - ma, thma - mi);
1062 }
1063
1064 bool SUB_NoImpactCheck(entity this, entity toucher)
1065 {
1066         // zero hitcontents = this is not the real impact, but either the
1067         // mirror-impact of something hitting the projectile instead of the
1068         // projectile hitting the something, or a touchareagrid one. Neither of
1069         // these stop the projectile from moving, so...
1070         if(trace_dphitcontents == 0)
1071         {
1072                 LOG_TRACEF("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct. (edict: %i, classname: %s, origin: %v)", this, this.classname, this.origin);
1073                 checkclient(this); // TODO: .health is checked in the engine with this, possibly replace with a QC function?
1074         }
1075     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1076         return true;
1077     if (toucher == NULL && this.size != '0 0 0')
1078     {
1079         vector tic;
1080         tic = this.velocity * sys_frametime;
1081         tic = tic + normalize(tic) * vlen(this.maxs - this.mins);
1082         traceline(this.origin - tic, this.origin + tic, MOVE_NORMAL, this);
1083         if (trace_fraction >= 1)
1084         {
1085             LOG_TRACE("Odd... did not hit...?");
1086         }
1087         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1088         {
1089             LOG_TRACE("Detected and prevented the sky-grapple bug.");
1090             return true;
1091         }
1092     }
1093
1094     return false;
1095 }
1096
1097 #define SUB_OwnerCheck(ent,oth) ((oth) && ((oth) == (ent).owner))
1098
1099 bool WarpZone_Projectile_Touch_ImpactFilter_Callback(entity this, entity toucher)
1100 {
1101         if(SUB_OwnerCheck(this, toucher))
1102                 return true;
1103         if(SUB_NoImpactCheck(this, toucher))
1104         {
1105                 if(this.classname == "nade")
1106                         return false; // no checks here
1107                 else if(this.classname == "grapplinghook")
1108                         RemoveHook(this);
1109                 else if(this.classname == "spike")
1110                 {
1111                         W_Crylink_Dequeue(this);
1112                         delete(this);
1113                 }
1114                 else
1115                         delete(this);
1116                 return true;
1117         }
1118         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1119                 UpdateCSQCProjectile(this);
1120         return false;
1121 }
1122
1123 /** engine callback */
1124 void URI_Get_Callback(float id, float status, string data)
1125 {
1126         if(url_URI_Get_Callback(id, status, data))
1127         {
1128                 // handled
1129         }
1130         else if (id == URI_GET_DISCARD)
1131         {
1132                 // discard
1133         }
1134         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1135         {
1136                 // sv_cmd curl
1137                 Curl_URI_Get_Callback(id, status, data);
1138         }
1139         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1140         {
1141                 // online ban list
1142                 OnlineBanList_URI_Get_Callback(id, status, data);
1143         }
1144         else if (MUTATOR_CALLHOOK(URI_GetCallback, id, status, data))
1145         {
1146                 // handled by a mutator
1147         }
1148         else
1149         {
1150                 LOG_INFO("Received HTTP request data for an invalid id ", ftos(id), ".");
1151         }
1152 }
1153
1154 string uid2name(string myuid) {
1155         string s;
1156         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1157
1158         // FIXME remove this later after 0.6 release
1159         // convert old style broken records to correct style
1160         if(s == "")
1161         {
1162                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1163                 if(s != "")
1164                 {
1165                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1166                         db_remove(ServerProgsDB, strcat("uid2name", myuid));
1167                 }
1168         }
1169
1170         if(s == "")
1171                 s = "^1Unregistered Player";
1172         return s;
1173 }
1174
1175 float MoveToRandomLocationWithinBounds(entity e, vector boundmin, vector boundmax, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1176 {
1177     float m, i;
1178     vector start, org, delta, end, enddown, mstart;
1179
1180     m = e.dphitcontentsmask;
1181     e.dphitcontentsmask = goodcontents | badcontents;
1182
1183     org = boundmin;
1184     delta = boundmax - boundmin;
1185
1186     start = end = org;
1187
1188     for (i = 0; i < attempts; ++i)
1189     {
1190         start.x = org.x + random() * delta.x;
1191         start.y = org.y + random() * delta.y;
1192         start.z = org.z + random() * delta.z;
1193
1194         // rule 1: start inside world bounds, and outside
1195         // solid, and don't start from somewhere where you can
1196         // fall down to evil
1197         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1198         if (trace_fraction >= 1)
1199             continue;
1200         if (trace_startsolid)
1201             continue;
1202         if (trace_dphitcontents & badcontents)
1203             continue;
1204         if (trace_dphitq3surfaceflags & badsurfaceflags)
1205             continue;
1206
1207         // rule 2: if we are too high, lower the point
1208         if (trace_fraction * delta.z > maxaboveground)
1209             start = trace_endpos + '0 0 1' * maxaboveground;
1210         enddown = trace_endpos;
1211
1212         // rule 3: make sure we aren't outside the map. This only works
1213         // for somewhat well formed maps. A good rule of thumb is that
1214         // the map should have a convex outside hull.
1215         // these can be traceLINES as we already verified the starting box
1216         mstart = start + 0.5 * (e.mins + e.maxs);
1217         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1218         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1219             continue;
1220         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1221         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1222             continue;
1223         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1224         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1225             continue;
1226         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1227         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1228             continue;
1229         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1230         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1231             continue;
1232
1233         // rule 4: we must "see" some spawnpoint or item
1234     entity sp = NULL;
1235     IL_EACH(g_spawnpoints, checkpvs(mstart, it),
1236     {
1237         if((traceline(mstart, it.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1238         {
1239                 sp = it;
1240                 break;
1241         }
1242     });
1243         if(!sp)
1244         {
1245                 int items_checked = 0;
1246                 IL_EACH(g_items, checkpvs(mstart, it),
1247                 {
1248                         if((traceline(mstart, it.origin + (it.mins + it.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1249                         {
1250                                 sp = it;
1251                                 break;
1252                         }
1253
1254                         ++items_checked;
1255                         if(items_checked >= attempts)
1256                                 break; // sanity
1257                 });
1258
1259                 if(!sp)
1260                         continue;
1261         }
1262
1263         // find a random vector to "look at"
1264         end.x = org.x + random() * delta.x;
1265         end.y = org.y + random() * delta.y;
1266         end.z = org.z + random() * delta.z;
1267         end = start + normalize(end - start) * vlen(delta);
1268
1269         // rule 4: start TO end must not be too short
1270         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1271         if (trace_startsolid)
1272             continue;
1273         if (trace_fraction < minviewdistance / vlen(delta))
1274             continue;
1275
1276         // rule 5: don't want to look at sky
1277         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1278             continue;
1279
1280         // rule 6: we must not end up in trigger_hurt
1281         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1282             continue;
1283
1284         break;
1285     }
1286
1287     e.dphitcontentsmask = m;
1288
1289     if (i < attempts)
1290     {
1291         setorigin(e, start);
1292         e.angles = vectoangles(end - start);
1293         LOG_DEBUG("Needed ", ftos(i + 1), " attempts");
1294         return true;
1295     }
1296     else
1297         return false;
1298 }
1299
1300 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1301 {
1302         return MoveToRandomLocationWithinBounds(e, world.mins, world.maxs, goodcontents, badcontents, badsurfaceflags, attempts, maxaboveground, minviewdistance);
1303 }
1304
1305 void write_recordmarker(entity pl, float tstart, float dt)
1306 {
1307     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1308
1309     // also write a marker into demo files for demotc-race-record-extractor to find
1310     stuffcmd(pl,
1311              strcat(
1312                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1313                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1314 }
1315
1316 void attach_sameorigin(entity e, entity to, string tag)
1317 {
1318     vector org, t_forward, t_left, t_up, e_forward, e_up;
1319     float tagscale;
1320
1321     org = e.origin - gettaginfo(to, gettagindex(to, tag));
1322     tagscale = (vlen(v_forward) ** -2); // undo a scale on the tag
1323     t_forward = v_forward * tagscale;
1324     t_left = v_right * -tagscale;
1325     t_up = v_up * tagscale;
1326
1327     e.origin_x = org * t_forward;
1328     e.origin_y = org * t_left;
1329     e.origin_z = org * t_up;
1330
1331     // current forward and up directions
1332     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1333                 e.angles = AnglesTransform_FromVAngles(e.angles);
1334         else
1335                 e.angles = AnglesTransform_FromAngles(e.angles);
1336     fixedmakevectors(e.angles);
1337
1338     // untransform forward, up!
1339     e_forward.x = v_forward * t_forward;
1340     e_forward.y = v_forward * t_left;
1341     e_forward.z = v_forward * t_up;
1342     e_up.x = v_up * t_forward;
1343     e_up.y = v_up * t_left;
1344     e_up.z = v_up * t_up;
1345
1346     e.angles = fixedvectoangles2(e_forward, e_up);
1347     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1348                 e.angles = AnglesTransform_ToVAngles(e.angles);
1349         else
1350                 e.angles = AnglesTransform_ToAngles(e.angles);
1351
1352     setattachment(e, to, tag);
1353     setorigin(e, e.origin);
1354 }
1355
1356 void detach_sameorigin(entity e)
1357 {
1358     vector org;
1359     org = gettaginfo(e, 0);
1360     e.angles = fixedvectoangles2(v_forward, v_up);
1361     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1362                 e.angles = AnglesTransform_ToVAngles(e.angles);
1363         else
1364                 e.angles = AnglesTransform_ToAngles(e.angles);
1365     setorigin(e, org);
1366     setattachment(e, NULL, "");
1367     setorigin(e, e.origin);
1368 }
1369
1370 void follow_sameorigin(entity e, entity to)
1371 {
1372     set_movetype(e, MOVETYPE_FOLLOW); // make the hole follow
1373     e.aiment = to; // make the hole follow bmodel
1374     e.punchangle = to.angles; // the original angles of bmodel
1375     e.view_ofs = e.origin - to.origin; // relative origin
1376     e.v_angle = e.angles - to.angles; // relative angles
1377 }
1378
1379 void unfollow_sameorigin(entity e)
1380 {
1381     set_movetype(e, MOVETYPE_NONE);
1382 }
1383
1384 entity gettaginfo_relative_ent;
1385 vector gettaginfo_relative(entity e, float tag)
1386 {
1387     if (!gettaginfo_relative_ent)
1388     {
1389         gettaginfo_relative_ent = spawn();
1390         gettaginfo_relative_ent.effects = EF_NODRAW;
1391     }
1392     gettaginfo_relative_ent.model = e.model;
1393     gettaginfo_relative_ent.modelindex = e.modelindex;
1394     gettaginfo_relative_ent.frame = e.frame;
1395     return gettaginfo(gettaginfo_relative_ent, tag);
1396 }
1397
1398 .string aiment_classname;
1399 .float aiment_deadflag;
1400 void SetMovetypeFollow(entity ent, entity e)
1401 {
1402         // FIXME this may not be warpzone aware
1403         set_movetype(ent, MOVETYPE_FOLLOW); // make the hole follow
1404         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
1405         ent.aiment = e; // make the hole follow bmodel
1406         ent.punchangle = e.angles; // the original angles of bmodel
1407         ent.view_ofs = ent.origin - e.origin; // relative origin
1408         ent.v_angle = ent.angles - e.angles; // relative angles
1409         ent.aiment_classname = strzone(e.classname);
1410         ent.aiment_deadflag = e.deadflag;
1411 }
1412 void UnsetMovetypeFollow(entity ent)
1413 {
1414         set_movetype(ent, MOVETYPE_FLY);
1415         PROJECTILE_MAKETRIGGER(ent);
1416         ent.aiment = NULL;
1417 }
1418 float LostMovetypeFollow(entity ent)
1419 {
1420 /*
1421         if(ent.move_movetype != MOVETYPE_FOLLOW)
1422                 if(ent.aiment)
1423                         error("???");
1424 */
1425         if(ent.aiment)
1426         {
1427                 if(ent.aiment.classname != ent.aiment_classname)
1428                         return 1;
1429                 if(ent.aiment.deadflag != ent.aiment_deadflag)
1430                         return 1;
1431         }
1432         return 0;
1433 }
1434
1435 .bool pushable;
1436 bool isPushable(entity e)
1437 {
1438         if(e.pushable)
1439                 return true;
1440         if(IS_VEHICLE(e))
1441                 return false;
1442         if(e.iscreature)
1443                 return true;
1444         if (Item_IsLoot(e))
1445         {
1446                 return true;
1447         }
1448         switch(e.classname)
1449         {
1450                 case "body":
1451                         return true;
1452                 case "bullet": // antilagged bullets can't hit this either
1453                         return false;
1454         }
1455         if (e.projectiledeathtype)
1456                 return true;
1457         return false;
1458 }