qcsrc/server/miscfunctions.qc

   1 #include "miscfunctions.qh"
   2
   3 #include "antilag.qh"
   4 #include "command/common.qh"
   5 #include "constants.qh"
   6 #include "g_hook.qh"
   7 #include "ipban.qh"
   8 #include <server/mutators/_mod.qh>
   9 #include "../common/t_items.qh"
  10 #include "resources.qh"
  11 #include "items.qh"
  12 #include "player.qh"
  13 #include "weapons/accuracy.qh"
  14 #include "weapons/csqcprojectile.qh"
  15 #include "weapons/selection.qh"
  16 #include "../common/command/_mod.qh"
  17 #include "../common/constants.qh"
  18 #include <common/net_linked.qh>
  19 #include <common/weapons/weapon/crylink.qh>
  20 #include "../common/deathtypes/all.qh"
  21 #include "../common/mapinfo.qh"
  22 #include "../common/notifications/all.qh"
  23 #include "../common/playerstats.qh"
  24 #include "../common/teams.qh"
  25 #include "../common/mapobjects/subs.qh"
  26 #include "../common/util.qh"
  27 #include "../common/turrets/sv_turrets.qh"
  28 #include <common/weapons/_all.qh>
  29 #include "../common/vehicles/sv_vehicles.qh"
  30 #include "../common/vehicles/vehicle.qh"
  31 #include "../common/items/_mod.qh"
  32 #include "../common/state.qh"
  33 #include "../common/effects/qc/globalsound.qh"
  34 #include "../common/wepent.qh"
  35 #include "../lib/csqcmodel/sv_model.qh"
  36 #include "../lib/warpzone/anglestransform.qh"
  37 #include "../lib/warpzone/server.qh"
  38
  39 void crosshair_trace(entity pl)
  40 {
  41         traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  42 }
  43
  44 void crosshair_trace_plusvisibletriggers(entity pl)
  45 {
  46         crosshair_trace_plusvisibletriggers__is_wz(pl, false);
  47 }
  48
  49 void WarpZone_crosshair_trace_plusvisibletriggers(entity pl)
  50 {
  51         crosshair_trace_plusvisibletriggers__is_wz(pl, true);
  52 }
  53
  54 void crosshair_trace_plusvisibletriggers__is_wz(entity pl, bool is_wz)
  55 {
  56         FOREACH_ENTITY_FLOAT(solid, SOLID_TRIGGER,
  57         {
  58                 if(it.model != "")
  59                 {
  60                         it.solid = SOLID_BSP;
  61                         IL_PUSH(g_ctrace_changed, it);
  62                 }
  63         });
  64
  65         if (is_wz)
  66                 WarpZone_crosshair_trace(pl);
  67         else
  68                 crosshair_trace(pl);
  69
  70         IL_EACH(g_ctrace_changed, true, { it.solid = SOLID_TRIGGER; });
  71
  72         IL_CLEAR(g_ctrace_changed);
  73 }
  74
  75 void WarpZone_crosshair_trace(entity pl)
  76 {
  77         WarpZone_traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  78 }
  79
  80 void dedicated_print(string input)
  81 {
  82         if (server_is_dedicated) print(input);
  83 }
  84
  85 void GameLogEcho(string s)
  86 {
  87     string fn;
  88     int matches;
  89
  90     if (autocvar_sv_eventlog_files)
  91     {
  92         if (!logfile_open)
  93         {
  94             logfile_open = true;
  95             matches = autocvar_sv_eventlog_files_counter + 1;
  96             cvar_set("sv_eventlog_files_counter", itos(matches));
  97             fn = ftos(matches);
  98             if (strlen(fn) < 8)
  99                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 100             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 101             logfile = fopen(fn, FILE_APPEND);
 102             fputs(logfile, ":logversion:3\n");
 103         }
 104         if (logfile >= 0)
 105         {
 106             if (autocvar_sv_eventlog_files_timestamps)
 107                 fputs(logfile, strcat(":time:", strftime(true, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 108             else
 109                 fputs(logfile, strcat(s, "\n"));
 110         }
 111     }
 112     if (autocvar_sv_eventlog_console)
 113     {
 114         dedicated_print(strcat(s, "\n"));
 115     }
 116 }
 117
 118 void GameLogInit()
 119 {
 120     logfile_open = 0;
 121     // will be opened later
 122 }
 123
 124 void GameLogClose()
 125 {
 126     if (logfile_open && logfile >= 0)
 127     {
 128         fclose(logfile);
 129         logfile = -1;
 130     }
 131 }
 132
 133 entity findnearest(vector point, bool checkitems, vector axismod)
 134 {
 135     vector dist;
 136     int num_nearest = 0;
 137
 138     IL_EACH(((checkitems) ? g_items : g_locations), ((checkitems) ? (it.target == "###item###") : (it.classname == "target_location")),
 139     {
 140         if ((it.items == IT_KEY1 || it.items == IT_KEY2) && it.target == "###item###")
 141             dist = it.oldorigin;
 142         else
 143             dist = it.origin;
 144         dist = dist - point;
 145         dist = dist.x * axismod.x * '1 0 0' + dist.y * axismod.y * '0 1 0' + dist.z * axismod.z * '0 0 1';
 146         float len = vlen2(dist);
 147
 148         int l;
 149         for (l = 0; l < num_nearest; ++l)
 150         {
 151             if (len < nearest_length[l])
 152                 break;
 153         }
 154
 155         // now i tells us where to insert at
 156         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 157         if (l < NUM_NEAREST_ENTITIES)
 158         {
 159             for (int j = NUM_NEAREST_ENTITIES - 1; j >= l; --j)
 160             {
 161                 nearest_length[j + 1] = nearest_length[j];
 162                 nearest_entity[j + 1] = nearest_entity[j];
 163             }
 164             nearest_length[l] = len;
 165             nearest_entity[l] = it;
 166             if (num_nearest < NUM_NEAREST_ENTITIES)
 167                 num_nearest = num_nearest + 1;
 168         }
 169     });
 170
 171     // now use the first one from our list that we can see
 172     for (int j = 0; j < num_nearest; ++j)
 173     {
 174         traceline(point, nearest_entity[j].origin, true, NULL);
 175         if (trace_fraction == 1)
 176         {
 177             if (j != 0)
 178                 LOG_TRACEF("Nearest point (%s) is not visible, using a visible one.", nearest_entity[0].netname);
 179             return nearest_entity[j];
 180         }
 181     }
 182
 183     if (num_nearest == 0)
 184         return NULL;
 185
 186     LOG_TRACE("Not seeing any location point, using nearest as fallback.");
 187     /* DEBUGGING CODE:
 188     dprint("Candidates were: ");
 189     for(j = 0; j < num_nearest; ++j)
 190     {
 191         if(j != 0)
 192                 dprint(", ");
 193         dprint(nearest_entity[j].netname);
 194     }
 195     dprint("\n");
 196     */
 197
 198     return nearest_entity[0];
 199 }
 200
 201 string NearestLocation(vector p)
 202 {
 203     string ret = "somewhere";
 204     entity loc = findnearest(p, false, '1 1 1');
 205     if (loc)
 206         ret = loc.message;
 207     else
 208     {
 209         loc = findnearest(p, true, '1 1 4');
 210         if (loc)
 211             ret = loc.netname;
 212     }
 213     return ret;
 214 }
 215
 216 string AmmoNameFromWeaponentity(Weapon wep)
 217 {
 218         string ammoitems = "batteries";
 219         switch (wep.ammo_type)
 220         {
 221                 case RES_SHELLS:  ammoitems = ITEM_Shells.m_name;      break;
 222                 case RES_BULLETS: ammoitems = ITEM_Bullets.m_name;     break;
 223                 case RES_ROCKETS: ammoitems = ITEM_Rockets.m_name;     break;
 224                 case RES_CELLS:   ammoitems = ITEM_Cells.m_name;       break;
 225                 case RES_PLASMA:  ammoitems = ITEM_Plasma.m_name;      break;
 226                 case RES_FUEL:    ammoitems = ITEM_JetpackFuel.m_name; break;
 227         }
 228         return ammoitems;
 229 }
 230
 231 string formatmessage(entity this, string msg)
 232 {
 233         float p, p1, p2;
 234         float n;
 235         vector cursor = '0 0 0';
 236         entity cursor_ent = NULL;
 237         string escape;
 238         string replacement;
 239         p = 0;
 240         n = 7;
 241         bool traced = false;
 242
 243         MUTATOR_CALLHOOK(PreFormatMessage, this, msg);
 244         msg = M_ARGV(1, string);
 245
 246         while (1) {
 247                 if (n < 1)
 248                         break; // too many replacements
 249
 250                 n = n - 1;
 251                 p1 = strstrofs(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 252                 p2 = strstrofs(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 253
 254                 if (p1 < 0)
 255                         p1 = p2;
 256
 257                 if (p2 < 0)
 258                         p2 = p1;
 259
 260                 p = min(p1, p2);
 261
 262                 if (p < 0)
 263                         break;
 264
 265                 if(!traced)
 266                 {
 267                         WarpZone_crosshair_trace_plusvisibletriggers(this);
 268                         cursor = trace_endpos;
 269                         cursor_ent = trace_ent;
 270                         traced = true;
 271                 }
 272
 273                 replacement = substring(msg, p, 2);
 274                 escape = substring(msg, p + 1, 1);
 275
 276                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 277
 278                 switch(escape)
 279                 {
 280                         case "%": replacement = "%"; break;
 281                         case "\\":replacement = "\\"; break;
 282                         case "n": replacement = "\n"; break;
 283                         case "a": replacement = ftos(floor(GetResource(this, RES_ARMOR))); break;
 284                         case "h": replacement = ftos(floor(GetResource(this, RES_HEALTH))); break;
 285                         case "l": replacement = NearestLocation(this.origin); break;
 286                         case "y": replacement = NearestLocation(cursor); break;
 287                         case "d": replacement = NearestLocation(this.death_origin); break;
 288                         case "w": replacement = ((this.(weaponentity).m_weapon == WEP_Null) ? ((this.(weaponentity).m_switchweapon == WEP_Null) ? Weapons_from(this.(weaponentity).cnt) : this.(weaponentity).m_switchweapon) : this.(weaponentity).m_weapon).m_name; break;
 289                         case "W": replacement = AmmoNameFromWeaponentity(this.(weaponentity).m_weapon); break;
 290                         case "x": replacement = ((cursor_ent.netname == "" || !cursor_ent) ? "nothing" : cursor_ent.netname); break;
 291                         case "s": replacement = ftos(vlen(this.velocity - this.velocity_z * '0 0 1')); break;
 292                         case "S": replacement = ftos(vlen(this.velocity)); break;
 293                         case "t": replacement = seconds_tostring(ceil(max(0, autocvar_timelimit * 60 + game_starttime - time))); break;
 294                         case "T": replacement = seconds_tostring(floor(time - game_starttime)); break;
 295                         default:
 296                         {
 297                                 MUTATOR_CALLHOOK(FormatMessage, this, escape, replacement, msg);
 298                                 replacement = M_ARGV(2, string);
 299                                 break;
 300                         }
 301                 }
 302
 303                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 304                 p = p + strlen(replacement);
 305         }
 306         return msg;
 307 }
 308
 309 /*
 310 =============
 311 GetCvars
 312 =============
 313 Called with:
 314   0:  sends the request
 315   >0: receives a cvar from name=argv(f) value=argv(f+1)
 316 */
 317 void GetCvars_handleString(entity this, entity store, string thisname, float f, .string field, string name)
 318 {
 319         if (f < 0)
 320         {
 321                 strfree(store.(field));
 322         }
 323         else if (f > 0)
 324         {
 325                 if (thisname == name)
 326                 {
 327                         strcpy(store.(field), argv(f + 1));
 328                 }
 329         }
 330         else
 331                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 332 }
 333 void GetCvars_handleString_Fixup(entity this, entity store, string thisname, float f, .string field, string name, string(entity, string) func)
 334 {
 335         GetCvars_handleString(this, store, thisname, f, field, name);
 336         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 337                 if (thisname == name)
 338                 {
 339                         string s = func(this, strcat1(store.(field)));
 340                         if (s != store.(field))
 341                         {
 342                                 strcpy(store.(field), s);
 343                         }
 344                 }
 345 }
 346 void GetCvars_handleFloat(entity this, entity store, string thisname, float f, .float field, string name)
 347 {
 348         if (f < 0)
 349         {
 350         }
 351         else if (f > 0)
 352         {
 353                 if (thisname == name)
 354                         store.(field) = stof(argv(f + 1));
 355         }
 356         else
 357                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 358 }
 359 void GetCvars_handleFloatOnce(entity this, entity store, string thisname, float f, .float field, string name)
 360 {
 361         if (f < 0)
 362         {
 363         }
 364         else if (f > 0)
 365         {
 366                 if (thisname == name)
 367                 {
 368                         if (!store.(field))
 369                         {
 370                                 store.(field) = stof(argv(f + 1));
 371                                 if (!store.(field))
 372                                         store.(field) = -1;
 373                         }
 374                 }
 375         }
 376         else
 377         {
 378                 if (!store.(field))
 379                         stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 380         }
 381 }
 382 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(entity this, string wo)
 383 {
 384         string o = W_FixWeaponOrder_ForceComplete(wo);
 385         strcpy(CS(this).weaponorder_byimpulse, W_FixWeaponOrder_BuildImpulseList(o));
 386         return o;
 387 }
 388
 389 REPLICATE(autoswitch, bool, "cl_autoswitch");
 390
 391 REPLICATE(cvar_cl_allow_uid2name, bool, "cl_allow_uid2name");
 392
 393 REPLICATE(cvar_cl_autoscreenshot, int, "cl_autoscreenshot");
 394
 395 REPLICATE(cvar_cl_autotaunt, float, "cl_autotaunt");
 396
 397 REPLICATE(cvar_cl_clippedspectating, bool, "cl_clippedspectating");
 398
 399 REPLICATE(cvar_cl_handicap, float, "cl_handicap");
 400
 401 REPLICATE(cvar_cl_jetpack_jump, bool, "cl_jetpack_jump");
 402
 403 REPLICATE(cvar_cl_movement_track_canjump, bool, "cl_movement_track_canjump");
 404
 405 REPLICATE(cvar_cl_newusekeysupported, bool, "cl_newusekeysupported");
 406
 407 REPLICATE(cvar_cl_noantilag, bool, "cl_noantilag");
 408
 409 REPLICATE(cvar_cl_physics, string, "cl_physics");
 410
 411 REPLICATE(cvar_cl_voice_directional, int, "cl_voice_directional");
 412
 413 REPLICATE(cvar_cl_voice_directional_taunt_attenuation, float, "cl_voice_directional_taunt_attenuation");
 414
 415 REPLICATE(cvar_cl_weaponimpulsemode, int, "cl_weaponimpulsemode");
 416
 417 REPLICATE(cvar_g_xonoticversion, string, "g_xonoticversion");
 418
 419 REPLICATE(cvar_cl_cts_noautoswitch, bool, "cl_cts_noautoswitch");
 420
 421 REPLICATE(cvar_cl_weapon_switch_reload, bool, "cl_weapon_switch_reload");
 422
 423 REPLICATE(cvar_cl_weapon_switch_fallback_to_impulse, bool, "cl_weapon_switch_fallback_to_impulse");
 424
 425 /**
 426  * @param f -1: cleanup, 0: request, 1: receive
 427  */
 428 void GetCvars(entity this, entity store, int f)
 429 {
 430         string s = string_null;
 431
 432         if (f > 0)
 433                 s = strcat1(argv(f));
 434
 435         get_cvars_f = f;
 436         get_cvars_s = s;
 437         MUTATOR_CALLHOOK(GetCvars);
 438
 439         Notification_GetCvars(this);
 440
 441         ReplicateVars(this, store, s, f);
 442
 443         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 444         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 445         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 446         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 447         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 448         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 449         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 450         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 451         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 452         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 453         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 454
 455         GetCvars_handleFloat(this, store, s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 456
 457         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 458         if (f > 0)
 459         {
 460                 if (s == "cl_weaponpriority")
 461                 {
 462                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 463                         {
 464                                 .entity weaponentity = weaponentities[slot];
 465                                 if (this.(weaponentity) && (this.(weaponentity).m_weapon != WEP_Null || slot == 0))
 466                                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 467                         }
 468                 }
 469                 if (s == "cl_allow_uidtracking")
 470                         PlayerStats_GameReport_AddPlayer(this);
 471         }
 472 }
 473
 474 // decolorizes and team colors the player name when needed
 475 string playername(entity p, bool team_colorize)
 476 {
 477     string t;
 478     if (team_colorize && teamplay && !intermission_running && IS_PLAYER(p))
 479     {
 480         t = Team_ColorCode(p.team);
 481         return strcat(t, strdecolorize(p.netname));
 482     }
 483     else
 484         return p.netname;
 485 }
 486
 487 float want_weapon(entity weaponinfo, float allguns) // WEAPONTODO: what still needs done?
 488 {
 489         int i = weaponinfo.m_id;
 490         int d = 0;
 491         bool allow_mutatorblocked = false;
 492
 493         if(!i)
 494                 return 0;
 495
 496         bool mutator_returnvalue = MUTATOR_CALLHOOK(WantWeapon, weaponinfo, d, allguns, allow_mutatorblocked);
 497         d = M_ARGV(1, float);
 498         allguns = M_ARGV(2, bool);
 499         allow_mutatorblocked = M_ARGV(3, bool);
 500
 501         if(allguns)
 502                 d = boolean((weaponinfo.spawnflags & WEP_FLAG_NORMAL) && !(weaponinfo.spawnflags & WEP_FLAG_HIDDEN) && !(weaponinfo.spawnflags & WEP_FLAG_SPECIALATTACK));
 503         else if(!mutator_returnvalue)
 504                 d = !(!weaponinfo.weaponstart);
 505
 506         if(!allow_mutatorblocked && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
 507                 d = 0;
 508
 509         float t = weaponinfo.weaponstartoverride;
 510
 511         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 512
 513         // bit order in t:
 514         // 1: want or not
 515         // 2: is default?
 516         // 4: is set by default?
 517         if(t < 0)
 518                 t = 4 | (3 * d);
 519         else
 520                 t |= (2 * d);
 521
 522         return t;
 523 }
 524
 525 void readplayerstartcvars()
 526 {
 527         float i, t;
 528         string s;
 529
 530         // initialize starting values for players
 531         start_weapons = '0 0 0';
 532         start_weapons_default = '0 0 0';
 533         start_weapons_defaultmask = '0 0 0';
 534         start_items = 0;
 535         start_ammo_shells = 0;
 536         start_ammo_nails = 0;
 537         start_ammo_rockets = 0;
 538         start_ammo_cells = 0;
 539         start_ammo_plasma = 0;
 540         if (random_start_ammo == NULL)
 541         {
 542                 random_start_ammo = spawn();
 543         }
 544         start_health = cvar("g_balance_health_start");
 545         start_armorvalue = cvar("g_balance_armor_start");
 546
 547         g_weaponarena = 0;
 548         g_weaponarena_weapons = '0 0 0';
 549
 550         s = cvar_string("g_weaponarena");
 551
 552         MUTATOR_CALLHOOK(SetWeaponArena, s);
 553         s = M_ARGV(0, string);
 554
 555         if (s == "0" || s == "")
 556         {
 557                 // no arena
 558         }
 559         else if (s == "off")
 560         {
 561                 // forcibly turn off weaponarena
 562         }
 563         else if (s == "all" || s == "1")
 564         {
 565                 g_weaponarena = 1;
 566                 g_weaponarena_list = "All Weapons";
 567                 FOREACH(Weapons, it != WEP_Null, {
 568                         if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED) && !(it.spawnflags & WEP_FLAG_SPECIALATTACK))
 569                                 g_weaponarena_weapons |= (it.m_wepset);
 570                 });
 571         }
 572         else if (s == "devall")
 573         {
 574                 g_weaponarena = 1;
 575                 g_weaponarena_list = "All Weapons"; // TODO: report as more than just all weapons?
 576                 FOREACH(Weapons, it != WEP_Null,
 577                 {
 578                         g_weaponarena_weapons |= (it.m_wepset);
 579                 });
 580         }
 581         else if (s == "most")
 582         {
 583                 g_weaponarena = 1;
 584                 g_weaponarena_list = "Most Weapons";
 585                 FOREACH(Weapons, it != WEP_Null, {
 586                         if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED) && (it.spawnflags & WEP_FLAG_NORMAL) && !(it.spawnflags & WEP_FLAG_HIDDEN) && !(it.spawnflags & WEP_FLAG_SPECIALATTACK))
 587                                 g_weaponarena_weapons |= (it.m_wepset);
 588                 });
 589         }
 590         else if (s == "none")
 591         {
 592                 g_weaponarena = 1;
 593                 g_weaponarena_list = "No Weapons";
 594         }
 595         else
 596         {
 597                 g_weaponarena = 1;
 598                 t = tokenize_console(s);
 599                 g_weaponarena_list = "";
 600                 for (i = 0; i < t; ++i)
 601                 {
 602                         s = argv(i);
 603                         Weapon wep = Weapons_fromstr(s);
 604                         if(wep != WEP_Null)
 605                         {
 606                                 g_weaponarena_weapons |= (wep.m_wepset);
 607                                 g_weaponarena_list = strcat(g_weaponarena_list, wep.m_name, " & ");
 608                         }
 609                 }
 610                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 611         }
 612
 613         if (g_weaponarena)
 614         {
 615                 g_weapon_stay = 0; // incompatible
 616                 start_weapons = g_weaponarena_weapons;
 617                 start_items |= IT_UNLIMITED_AMMO;
 618         }
 619         else
 620         {
 621                 FOREACH(Weapons, it != WEP_Null, {
 622                         int w = want_weapon(it, false);
 623                         WepSet s = it.m_wepset;
 624                         if(w & 1)
 625                                 start_weapons |= s;
 626                         if(w & 2)
 627                                 start_weapons_default |= s;
 628                         if(w & 4)
 629                                 start_weapons_defaultmask |= s;
 630                 });
 631         }
 632
 633         if(cvar("g_balance_superweapons_time") < 0)
 634                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
 635
 636         if(!cvar("g_use_ammunition"))
 637                 start_items |= IT_UNLIMITED_AMMO;
 638
 639         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 640         {
 641                 start_ammo_shells = 999;
 642                 start_ammo_nails = 999;
 643                 start_ammo_rockets = 999;
 644                 start_ammo_cells = 999;
 645                 start_ammo_plasma = 999;
 646                 start_ammo_fuel = 999;
 647         }
 648         else
 649         {
 650                 start_ammo_shells = cvar("g_start_ammo_shells");
 651                 start_ammo_nails = cvar("g_start_ammo_nails");
 652                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 653                 start_ammo_cells = cvar("g_start_ammo_cells");
 654                 start_ammo_plasma = cvar("g_start_ammo_plasma");
 655                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 656                 random_start_weapons_count = cvar("g_random_start_weapons_count");
 657                 SetResource(random_start_ammo, RES_SHELLS, cvar(
 658                         "g_random_start_shells"));
 659                 SetResource(random_start_ammo, RES_BULLETS, cvar(
 660                         "g_random_start_bullets"));
 661                 SetResource(random_start_ammo, RES_ROCKETS,
 662                         cvar("g_random_start_rockets"));
 663                 SetResource(random_start_ammo, RES_CELLS, cvar(
 664                         "g_random_start_cells"));
 665                 SetResource(random_start_ammo, RES_PLASMA, cvar(
 666                         "g_random_start_plasma"));
 667         }
 668
 669         if (warmup_stage)
 670         {
 671                 warmup_start_ammo_shells = start_ammo_shells;
 672                 warmup_start_ammo_nails = start_ammo_nails;
 673                 warmup_start_ammo_rockets = start_ammo_rockets;
 674                 warmup_start_ammo_cells = start_ammo_cells;
 675                 warmup_start_ammo_plasma = start_ammo_plasma;
 676                 warmup_start_ammo_fuel = start_ammo_fuel;
 677                 warmup_start_health = start_health;
 678                 warmup_start_armorvalue = start_armorvalue;
 679                 warmup_start_weapons = start_weapons;
 680                 warmup_start_weapons_default = start_weapons_default;
 681                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 682
 683                 if (!g_weaponarena && !g_ca && !g_freezetag)
 684                 {
 685                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 686                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 687                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 688                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 689                         warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
 690                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 691                         warmup_start_health = cvar("g_warmup_start_health");
 692                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 693                         warmup_start_weapons = '0 0 0';
 694                         warmup_start_weapons_default = '0 0 0';
 695                         warmup_start_weapons_defaultmask = '0 0 0';
 696                         FOREACH(Weapons, it != WEP_Null, {
 697                                 int w = want_weapon(it, g_warmup_allguns);
 698                                 WepSet s = (it.m_wepset);
 699                                 if(w & 1)
 700                                         warmup_start_weapons |= s;
 701                                 if(w & 2)
 702                                         warmup_start_weapons_default |= s;
 703                                 if(w & 4)
 704                                         warmup_start_weapons_defaultmask |= s;
 705                         });
 706                 }
 707         }
 708
 709         if (g_jetpack)
 710                 start_items |= ITEM_Jetpack.m_itemid;
 711
 712         MUTATOR_CALLHOOK(SetStartItems);
 713
 714         if (start_items & ITEM_Jetpack.m_itemid)
 715         {
 716                 start_items |= ITEM_JetpackRegen.m_itemid;
 717                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 718                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 719         }
 720
 721         start_ammo_shells = max(0, start_ammo_shells);
 722         start_ammo_nails = max(0, start_ammo_nails);
 723         start_ammo_rockets = max(0, start_ammo_rockets);
 724         start_ammo_cells = max(0, start_ammo_cells);
 725         start_ammo_plasma = max(0, start_ammo_plasma);
 726         start_ammo_fuel = max(0, start_ammo_fuel);
 727         SetResource(random_start_ammo, RES_SHELLS, max(0,
 728                 GetResource(random_start_ammo, RES_SHELLS)));
 729         SetResource(random_start_ammo, RES_BULLETS, max(0,
 730                 GetResource(random_start_ammo, RES_BULLETS)));
 731         SetResource(random_start_ammo, RES_ROCKETS, max(0,
 732                 GetResource(random_start_ammo, RES_ROCKETS)));
 733         SetResource(random_start_ammo, RES_CELLS, max(0,
 734                 GetResource(random_start_ammo, RES_CELLS)));
 735         SetResource(random_start_ammo, RES_PLASMA, max(0,
 736                 GetResource(random_start_ammo, RES_PLASMA)));
 737
 738         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 739         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 740         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 741         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 742         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
 743         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 744 }
 745
 746 void precache_playermodel(string m)
 747 {
 748         float globhandle, i, n;
 749         string f;
 750
 751         if(substring(m, -9,5) == "_lod1")
 752                 return;
 753         if(substring(m, -9,5) == "_lod2")
 754                 return;
 755         precache_model(m);
 756         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
 757         if(fexists(f))
 758                 precache_model(f);
 759         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
 760         if(fexists(f))
 761                 precache_model(f);
 762
 763         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
 764         if (globhandle < 0)
 765                 return;
 766         n = search_getsize(globhandle);
 767         for (i = 0; i < n; ++i)
 768         {
 769                 //print(search_getfilename(globhandle, i), "\n");
 770                 f = search_getfilename(globhandle, i);
 771                 PrecachePlayerSounds(f);
 772         }
 773         search_end(globhandle);
 774 }
 775 void precache_all_playermodels(string pattern)
 776 {
 777         int globhandle = search_begin(pattern, true, false);
 778         if (globhandle < 0) return;
 779         int n = search_getsize(globhandle);
 780         for (int i = 0; i < n; ++i)
 781         {
 782                 string s = search_getfilename(globhandle, i);
 783                 precache_playermodel(s);
 784         }
 785         search_end(globhandle);
 786 }
 787
 788 void precache_playermodels(string s)
 789 {
 790         FOREACH_WORD(s, true, { precache_playermodel(it); });
 791 }
 792
 793 void precache()
 794 {
 795     // gamemode related things
 796
 797     // Precache all player models if desired
 798     if (autocvar_sv_precacheplayermodels)
 799     {
 800         PrecachePlayerSounds("sound/player/default.sounds");
 801         precache_all_playermodels("models/player/*.zym");
 802         precache_all_playermodels("models/player/*.dpm");
 803         precache_all_playermodels("models/player/*.md3");
 804         precache_all_playermodels("models/player/*.psk");
 805         precache_all_playermodels("models/player/*.iqm");
 806     }
 807
 808     if (autocvar_sv_defaultcharacter)
 809     {
 810                 precache_playermodels(autocvar_sv_defaultplayermodel_red);
 811                 precache_playermodels(autocvar_sv_defaultplayermodel_blue);
 812                 precache_playermodels(autocvar_sv_defaultplayermodel_yellow);
 813                 precache_playermodels(autocvar_sv_defaultplayermodel_pink);
 814                 precache_playermodels(autocvar_sv_defaultplayermodel);
 815     }
 816
 817 #if 0
 818     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
 819
 820     if (!this.noise && this.music) // quake 3 uses the music field
 821         this.noise = this.music;
 822
 823     // plays music for the level if there is any
 824     if (this.noise)
 825     {
 826         precache_sound (this.noise);
 827         ambientsound ('0 0 0', this.noise, VOL_BASE, ATTEN_NONE);
 828     }
 829 #endif
 830 }
 831
 832
 833 void make_safe_for_remove(entity e)
 834 {
 835     if (e.initialize_entity)
 836     {
 837         entity ent, prev = NULL;
 838         for (ent = initialize_entity_first; ent; )
 839         {
 840             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
 841             {
 842                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
 843                 // skip it in linked list
 844                 if (prev)
 845                 {
 846                     prev.initialize_entity_next = ent.initialize_entity_next;
 847                     ent = prev.initialize_entity_next;
 848                 }
 849                 else
 850                 {
 851                     initialize_entity_first = ent.initialize_entity_next;
 852                     ent = initialize_entity_first;
 853                 }
 854             }
 855             else
 856             {
 857                 prev = ent;
 858                 ent = ent.initialize_entity_next;
 859             }
 860         }
 861     }
 862 }
 863
 864 .float remove_except_protected_forbidden;
 865 void remove_except_protected(entity e)
 866 {
 867         if(e.remove_except_protected_forbidden)
 868                 error("not allowed to remove this at this point");
 869         builtin_remove(e);
 870 }
 871
 872 void remove_unsafely(entity e)
 873 {
 874     if(e.classname == "spike")
 875         error("Removing spikes is forbidden (crylink bug), please report");
 876     builtin_remove(e);
 877 }
 878
 879 void remove_safely(entity e)
 880 {
 881     make_safe_for_remove(e);
 882     builtin_remove(e);
 883 }
 884
 885 void InitializeEntity(entity e, void(entity this) func, int order)
 886 {
 887     entity prev, cur;
 888
 889     if (!e || e.initialize_entity)
 890     {
 891         // make a proxy initializer entity
 892         entity e_old = e;
 893         e = new(initialize_entity);
 894         e.enemy = e_old;
 895     }
 896
 897     e.initialize_entity = func;
 898     e.initialize_entity_order = order;
 899
 900     cur = initialize_entity_first;
 901     prev = NULL;
 902     for (;;)
 903     {
 904         if (!cur || cur.initialize_entity_order > order)
 905         {
 906             // insert between prev and cur
 907             if (prev)
 908                 prev.initialize_entity_next = e;
 909             else
 910                 initialize_entity_first = e;
 911             e.initialize_entity_next = cur;
 912             return;
 913         }
 914         prev = cur;
 915         cur = cur.initialize_entity_next;
 916     }
 917 }
 918 void InitializeEntitiesRun()
 919 {
 920     entity startoflist = initialize_entity_first;
 921     initialize_entity_first = NULL;
 922     delete_fn = remove_except_protected;
 923     for (entity e = startoflist; e; e = e.initialize_entity_next)
 924     {
 925                 e.remove_except_protected_forbidden = 1;
 926     }
 927     for (entity e = startoflist; e; )
 928     {
 929                 e.remove_except_protected_forbidden = 0;
 930         e.initialize_entity_order = 0;
 931         entity next = e.initialize_entity_next;
 932         e.initialize_entity_next = NULL;
 933         var void(entity this) func = e.initialize_entity;
 934         e.initialize_entity = func_null;
 935         if (e.classname == "initialize_entity")
 936         {
 937             entity wrappee = e.enemy;
 938             builtin_remove(e);
 939             e = wrappee;
 940         }
 941         //dprint("Delayed initialization: ", e.classname, "\n");
 942         if (func)
 943         {
 944                 func(e);
 945         }
 946         else
 947         {
 948             eprint(e);
 949             backtrace(strcat("Null function in: ", e.classname, "\n"));
 950         }
 951         e = next;
 952     }
 953     delete_fn = remove_unsafely;
 954 }
 955
 956 .float(entity) isEliminated;
 957 bool EliminatedPlayers_SendEntity(entity this, entity to, float sendflags)
 958 {
 959         Stream out = MSG_ENTITY;
 960         WriteHeader(out, ENT_CLIENT_ELIMINATEDPLAYERS);
 961         serialize(byte, out, sendflags);
 962         if (sendflags & 1) {
 963                 for (int i = 1; i <= maxclients; i += 8) {
 964                         int f = 0;
 965                         entity e = edict_num(i);
 966                         for (int b = 0; b < 8; ++b, e = nextent(e)) {
 967                                 if (eliminatedPlayers.isEliminated(e)) {
 968                                         f |= BIT(b);
 969                                 }
 970                         }
 971                         serialize(byte, out, f);
 972                 }
 973         }
 974         return true;
 975 }
 976
 977 void EliminatedPlayers_Init(float(entity) isEliminated_func)
 978 {
 979         if(eliminatedPlayers)
 980         {
 981                 backtrace("Can't spawn eliminatedPlayers again!");
 982                 return;
 983         }
 984         Net_LinkEntity(eliminatedPlayers = spawn(), false, 0, EliminatedPlayers_SendEntity);
 985         eliminatedPlayers.isEliminated = isEliminated_func;
 986 }
 987
 988
 989
 990
 991 void adaptor_think2use_hittype_splash(entity this) // for timed projectile detonation
 992 {
 993         if(!(IS_ONGROUND(this))) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
 994                 this.projectiledeathtype |= HITTYPE_SPLASH;
 995         adaptor_think2use(this);
 996 }
 997
 998 // deferred dropping
 999 void DropToFloor_Handler(entity this)
1000 {
1001     WITHSELF(this, builtin_droptofloor());
1002     this.dropped_origin = this.origin;
1003 }
1004
1005 void droptofloor(entity this)
1006 {
1007     InitializeEntity(this, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1008 }
1009
1010
1011
1012 float trace_hits_box_a0, trace_hits_box_a1;
1013
1014 float trace_hits_box_1d(float end, float thmi, float thma)
1015 {
1016     if (end == 0)
1017     {
1018         // just check if x is in range
1019         if (0 < thmi)
1020             return false;
1021         if (0 > thma)
1022             return false;
1023     }
1024     else
1025     {
1026         // do the trace with respect to x
1027         // 0 -> end has to stay in thmi -> thma
1028         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1029         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1030         if (trace_hits_box_a0 > trace_hits_box_a1)
1031             return false;
1032     }
1033     return true;
1034 }
1035
1036 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1037 {
1038     end -= start;
1039     thmi -= start;
1040     thma -= start;
1041     // now it is a trace from 0 to end
1042
1043     trace_hits_box_a0 = 0;
1044     trace_hits_box_a1 = 1;
1045
1046     if (!trace_hits_box_1d(end.x, thmi.x, thma.x))
1047         return false;
1048     if (!trace_hits_box_1d(end.y, thmi.y, thma.y))
1049         return false;
1050     if (!trace_hits_box_1d(end.z, thmi.z, thma.z))
1051         return false;
1052
1053     return true;
1054 }
1055
1056 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1057 {
1058     return trace_hits_box(start, end, thmi - ma, thma - mi);
1059 }
1060
1061 bool SUB_NoImpactCheck(entity this, entity toucher)
1062 {
1063         // zero hitcontents = this is not the real impact, but either the
1064         // mirror-impact of something hitting the projectile instead of the
1065         // projectile hitting the something, or a touchareagrid one. Neither of
1066         // these stop the projectile from moving, so...
1067         if(trace_dphitcontents == 0)
1068         {
1069                 LOG_TRACEF("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct. (edict: %i, classname: %s, origin: %v)", this, this.classname, this.origin);
1070                 checkclient(this); // TODO: .health is checked in the engine with this, possibly replace with a QC function?
1071         }
1072     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1073         return true;
1074     if (toucher == NULL && this.size != '0 0 0')
1075     {
1076         vector tic;
1077         tic = this.velocity * sys_frametime;
1078         tic = tic + normalize(tic) * vlen(this.maxs - this.mins);
1079         traceline(this.origin - tic, this.origin + tic, MOVE_NORMAL, this);
1080         if (trace_fraction >= 1)
1081         {
1082             LOG_TRACE("Odd... did not hit...?");
1083         }
1084         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1085         {
1086             LOG_TRACE("Detected and prevented the sky-grapple bug.");
1087             return true;
1088         }
1089     }
1090
1091     return false;
1092 }
1093
1094 #define SUB_OwnerCheck(ent,oth) ((oth) && ((oth) == (ent).owner))
1095
1096 bool WarpZone_Projectile_Touch_ImpactFilter_Callback(entity this, entity toucher)
1097 {
1098         if(SUB_OwnerCheck(this, toucher))
1099                 return true;
1100         if(SUB_NoImpactCheck(this, toucher))
1101         {
1102                 if(this.classname == "nade")
1103                         return false; // no checks here
1104                 else if(this.classname == "grapplinghook")
1105                         RemoveHook(this);
1106                 else if(this.classname == "spike")
1107                 {
1108                         W_Crylink_Dequeue(this);
1109                         delete(this);
1110                 }
1111                 else
1112                         delete(this);
1113                 return true;
1114         }
1115         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1116                 UpdateCSQCProjectile(this);
1117         return false;
1118 }
1119
1120 /** engine callback */
1121 void URI_Get_Callback(float id, float status, string data)
1122 {
1123         if(url_URI_Get_Callback(id, status, data))
1124         {
1125                 // handled
1126         }
1127         else if (id == URI_GET_DISCARD)
1128         {
1129                 // discard
1130         }
1131         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1132         {
1133                 // sv_cmd curl
1134                 Curl_URI_Get_Callback(id, status, data);
1135         }
1136         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1137         {
1138                 // online ban list
1139                 OnlineBanList_URI_Get_Callback(id, status, data);
1140         }
1141         else if (MUTATOR_CALLHOOK(URI_GetCallback, id, status, data))
1142         {
1143                 // handled by a mutator
1144         }
1145         else
1146         {
1147                 LOG_INFO("Received HTTP request data for an invalid id ", ftos(id), ".");
1148         }
1149 }
1150
1151 string uid2name(string myuid) {
1152         string s;
1153         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1154
1155         // FIXME remove this later after 0.6 release
1156         // convert old style broken records to correct style
1157         if(s == "")
1158         {
1159                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1160                 if(s != "")
1161                 {
1162                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1163                         db_remove(ServerProgsDB, strcat("uid2name", myuid));
1164                 }
1165         }
1166
1167         if(s == "")
1168                 s = "^1Unregistered Player";
1169         return s;
1170 }
1171
1172 float MoveToRandomLocationWithinBounds(entity e, vector boundmin, vector boundmax, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1173 {
1174     float m, i;
1175     vector start, org, delta, end, enddown, mstart;
1176
1177     m = e.dphitcontentsmask;
1178     e.dphitcontentsmask = goodcontents | badcontents;
1179
1180     org = boundmin;
1181     delta = boundmax - boundmin;
1182
1183     start = end = org;
1184
1185     for (i = 0; i < attempts; ++i)
1186     {
1187         start.x = org.x + random() * delta.x;
1188         start.y = org.y + random() * delta.y;
1189         start.z = org.z + random() * delta.z;
1190
1191         // rule 1: start inside world bounds, and outside
1192         // solid, and don't start from somewhere where you can
1193         // fall down to evil
1194         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1195         if (trace_fraction >= 1)
1196             continue;
1197         if (trace_startsolid)
1198             continue;
1199         if (trace_dphitcontents & badcontents)
1200             continue;
1201         if (trace_dphitq3surfaceflags & badsurfaceflags)
1202             continue;
1203
1204         // rule 2: if we are too high, lower the point
1205         if (trace_fraction * delta.z > maxaboveground)
1206             start = trace_endpos + '0 0 1' * maxaboveground;
1207         enddown = trace_endpos;
1208
1209         // rule 3: make sure we aren't outside the map. This only works
1210         // for somewhat well formed maps. A good rule of thumb is that
1211         // the map should have a convex outside hull.
1212         // these can be traceLINES as we already verified the starting box
1213         mstart = start + 0.5 * (e.mins + e.maxs);
1214         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1215         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1216             continue;
1217         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1218         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1219             continue;
1220         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1221         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1222             continue;
1223         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1224         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1225             continue;
1226         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1227         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1228             continue;
1229
1230         // rule 4: we must "see" some spawnpoint or item
1231     entity sp = NULL;
1232     IL_EACH(g_spawnpoints, checkpvs(mstart, it),
1233     {
1234         if((traceline(mstart, it.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1235         {
1236                 sp = it;
1237                 break;
1238         }
1239     });
1240         if(!sp)
1241         {
1242                 int items_checked = 0;
1243                 IL_EACH(g_items, checkpvs(mstart, it),
1244                 {
1245                         if((traceline(mstart, it.origin + (it.mins + it.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1246                         {
1247                                 sp = it;
1248                                 break;
1249                         }
1250
1251                         ++items_checked;
1252                         if(items_checked >= attempts)
1253                                 break; // sanity
1254                 });
1255
1256                 if(!sp)
1257                         continue;
1258         }
1259
1260         // find a random vector to "look at"
1261         end.x = org.x + random() * delta.x;
1262         end.y = org.y + random() * delta.y;
1263         end.z = org.z + random() * delta.z;
1264         end = start + normalize(end - start) * vlen(delta);
1265
1266         // rule 4: start TO end must not be too short
1267         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1268         if (trace_startsolid)
1269             continue;
1270         if (trace_fraction < minviewdistance / vlen(delta))
1271             continue;
1272
1273         // rule 5: don't want to look at sky
1274         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1275             continue;
1276
1277         // rule 6: we must not end up in trigger_hurt
1278         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1279             continue;
1280
1281         break;
1282     }
1283
1284     e.dphitcontentsmask = m;
1285
1286     if (i < attempts)
1287     {
1288         setorigin(e, start);
1289         e.angles = vectoangles(end - start);
1290         LOG_DEBUG("Needed ", ftos(i + 1), " attempts");
1291         return true;
1292     }
1293     else
1294         return false;
1295 }
1296
1297 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1298 {
1299         return MoveToRandomLocationWithinBounds(e, world.mins, world.maxs, goodcontents, badcontents, badsurfaceflags, attempts, maxaboveground, minviewdistance);
1300 }
1301
1302 void write_recordmarker(entity pl, float tstart, float dt)
1303 {
1304     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1305
1306     // also write a marker into demo files for demotc-race-record-extractor to find
1307     stuffcmd(pl,
1308              strcat(
1309                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1310                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1311 }
1312
1313 void attach_sameorigin(entity e, entity to, string tag)
1314 {
1315     vector org, t_forward, t_left, t_up, e_forward, e_up;
1316     float tagscale;
1317
1318     org = e.origin - gettaginfo(to, gettagindex(to, tag));
1319     tagscale = (vlen(v_forward) ** -2); // undo a scale on the tag
1320     t_forward = v_forward * tagscale;
1321     t_left = v_right * -tagscale;
1322     t_up = v_up * tagscale;
1323
1324     e.origin_x = org * t_forward;
1325     e.origin_y = org * t_left;
1326     e.origin_z = org * t_up;
1327
1328     // current forward and up directions
1329     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1330                 e.angles = AnglesTransform_FromVAngles(e.angles);
1331         else
1332                 e.angles = AnglesTransform_FromAngles(e.angles);
1333     fixedmakevectors(e.angles);
1334
1335     // untransform forward, up!
1336     e_forward.x = v_forward * t_forward;
1337     e_forward.y = v_forward * t_left;
1338     e_forward.z = v_forward * t_up;
1339     e_up.x = v_up * t_forward;
1340     e_up.y = v_up * t_left;
1341     e_up.z = v_up * t_up;
1342
1343     e.angles = fixedvectoangles2(e_forward, e_up);
1344     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1345                 e.angles = AnglesTransform_ToVAngles(e.angles);
1346         else
1347                 e.angles = AnglesTransform_ToAngles(e.angles);
1348
1349     setattachment(e, to, tag);
1350     setorigin(e, e.origin);
1351 }
1352
1353 void detach_sameorigin(entity e)
1354 {
1355     vector org;
1356     org = gettaginfo(e, 0);
1357     e.angles = fixedvectoangles2(v_forward, v_up);
1358     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1359                 e.angles = AnglesTransform_ToVAngles(e.angles);
1360         else
1361                 e.angles = AnglesTransform_ToAngles(e.angles);
1362     setorigin(e, org);
1363     setattachment(e, NULL, "");
1364     setorigin(e, e.origin);
1365 }
1366
1367 void follow_sameorigin(entity e, entity to)
1368 {
1369     set_movetype(e, MOVETYPE_FOLLOW); // make the hole follow
1370     e.aiment = to; // make the hole follow bmodel
1371     e.punchangle = to.angles; // the original angles of bmodel
1372     e.view_ofs = e.origin - to.origin; // relative origin
1373     e.v_angle = e.angles - to.angles; // relative angles
1374 }
1375
1376 void unfollow_sameorigin(entity e)
1377 {
1378     set_movetype(e, MOVETYPE_NONE);
1379 }
1380
1381 entity gettaginfo_relative_ent;
1382 vector gettaginfo_relative(entity e, float tag)
1383 {
1384     if (!gettaginfo_relative_ent)
1385     {
1386         gettaginfo_relative_ent = spawn();
1387         gettaginfo_relative_ent.effects = EF_NODRAW;
1388     }
1389     gettaginfo_relative_ent.model = e.model;
1390     gettaginfo_relative_ent.modelindex = e.modelindex;
1391     gettaginfo_relative_ent.frame = e.frame;
1392     return gettaginfo(gettaginfo_relative_ent, tag);
1393 }
1394
1395 .string aiment_classname;
1396 .float aiment_deadflag;
1397 void SetMovetypeFollow(entity ent, entity e)
1398 {
1399         // FIXME this may not be warpzone aware
1400         set_movetype(ent, MOVETYPE_FOLLOW); // make the hole follow
1401         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
1402         ent.aiment = e; // make the hole follow bmodel
1403         ent.punchangle = e.angles; // the original angles of bmodel
1404         ent.view_ofs = ent.origin - e.origin; // relative origin
1405         ent.v_angle = ent.angles - e.angles; // relative angles
1406         ent.aiment_classname = strzone(e.classname);
1407         ent.aiment_deadflag = e.deadflag;
1408 }
1409 void UnsetMovetypeFollow(entity ent)
1410 {
1411         set_movetype(ent, MOVETYPE_FLY);
1412         PROJECTILE_MAKETRIGGER(ent);
1413         ent.aiment = NULL;
1414 }
1415 float LostMovetypeFollow(entity ent)
1416 {
1417 /*
1418         if(ent.move_movetype != MOVETYPE_FOLLOW)
1419                 if(ent.aiment)
1420                         error("???");
1421 */
1422         if(ent.aiment)
1423         {
1424                 if(ent.aiment.classname != ent.aiment_classname)
1425                         return 1;
1426                 if(ent.aiment.deadflag != ent.aiment_deadflag)
1427                         return 1;
1428         }
1429         return 0;
1430 }
1431
1432 .bool pushable;
1433 bool isPushable(entity e)
1434 {
1435         if(e.pushable)
1436                 return true;
1437         if(IS_VEHICLE(e))
1438                 return false;
1439         if(e.iscreature)
1440                 return true;
1441         if (Item_IsLoot(e))
1442         {
1443                 return true;
1444         }
1445         switch(e.classname)
1446         {
1447                 case "body":
1448                         return true;
1449                 case "bullet": // antilagged bullets can't hit this either
1450                         return false;
1451         }
1452         if (e.projectiledeathtype)
1453                 return true;
1454         return false;
1455 }