qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35
  36 string admin_name(void)
  37 {
  38         if(autocvar_sv_adminnick != "")
  39                 return autocvar_sv_adminnick;
  40         else
  41                 return "SERVER ADMIN";
  42 }
  43
  44 float DistributeEvenly_amount;
  45 float DistributeEvenly_totalweight;
  46 void DistributeEvenly_Init(float amount, float totalweight)
  47 {
  48     if (DistributeEvenly_amount)
  49     {
  50         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  51         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  52     }
  53     if (totalweight == 0)
  54         DistributeEvenly_amount = 0;
  55     else
  56         DistributeEvenly_amount = amount;
  57     DistributeEvenly_totalweight = totalweight;
  58 }
  59 float DistributeEvenly_Get(float weight)
  60 {
  61     float f;
  62     if (weight <= 0)
  63         return 0;
  64     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  65     DistributeEvenly_totalweight -= weight;
  66     DistributeEvenly_amount -= f;
  67     return f;
  68 }
  69 float DistributeEvenly_GetRandomized(float weight)
  70 {
  71     float f;
  72     if (weight <= 0)
  73         return 0;
  74     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  75     DistributeEvenly_totalweight -= weight;
  76     DistributeEvenly_amount -= f;
  77     return f;
  78 }
  79
  80 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  81
  82 string STR_PLAYER = "player";
  83 string STR_SPECTATOR = "spectator";
  84 string STR_OBSERVER = "observer";
  85
  86 #define IS_PLAYER(v)                    (v.classname == STR_PLAYER)
  87 #define IS_SPEC(v)                              (v.classname == STR_SPECTATOR)
  88 #define IS_OBSERVER(v)                  (v.classname == STR_OBSERVER)
  89 #define IS_CLIENT(v)                    (v.flags & FL_CLIENT)
  90 #define IS_BOT_CLIENT(v)                (clienttype(v) == CLIENTTYPE_BOT)
  91 #define IS_REAL_CLIENT(v)               (clienttype(v) == CLIENTTYPE_REAL)
  92 #define IS_NOT_A_CLIENT(v)              (clienttype(v) == CLIENTTYPE_NOTACLIENT)
  93
  94 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  95 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(IS_CLIENT(v))
  96 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(IS_REAL_CLIENT(v))
  97
  98 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(IS_PLAYER(v))
  99 #define FOR_EACH_SPEC(v) FOR_EACH_CLIENT(v) if not(IS_PLAYER(v)) // Samual: shouldn't this be IS_SPEC(v)? and rather create a separate macro to include observers too
 100 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(IS_PLAYER(v))
 101
 102 #define FOR_EACH_MONSTER(v) for(v = world; (v = findflags(v, flags, FL_MONSTER)) != world; )
 103
 104 #define CENTER_OR_VIEWOFS(ent) (ent.origin + (IS_PLAYER(ent) ? ent.view_ofs : ((ent.mins + ent.maxs) * 0.5)))
 105
 106 // copies a string to a tempstring (so one can strunzone it)
 107 string strcat1(string s) = #115; // FRIK_FILE
 108
 109 float logfile_open;
 110 float logfile;
 111
 112 void GameLogEcho(string s)
 113 {
 114     string fn;
 115     float matches;
 116
 117     if (autocvar_sv_eventlog_files)
 118     {
 119         if (!logfile_open)
 120         {
 121             logfile_open = TRUE;
 122             matches = autocvar_sv_eventlog_files_counter + 1;
 123             cvar_set("sv_eventlog_files_counter", ftos(matches));
 124             fn = ftos(matches);
 125             if (strlen(fn) < 8)
 126                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 127             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 128             logfile = fopen(fn, FILE_APPEND);
 129             fputs(logfile, ":logversion:3\n");
 130         }
 131         if (logfile >= 0)
 132         {
 133             if (autocvar_sv_eventlog_files_timestamps)
 134                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 135             else
 136                 fputs(logfile, strcat(s, "\n"));
 137         }
 138     }
 139     if (autocvar_sv_eventlog_console)
 140     {
 141         print(s, "\n");
 142     }
 143 }
 144
 145 void GameLogInit()
 146 {
 147     logfile_open = 0;
 148     // will be opened later
 149 }
 150
 151 void GameLogClose()
 152 {
 153     if (logfile_open && logfile >= 0)
 154     {
 155         fclose(logfile);
 156         logfile = -1;
 157     }
 158 }
 159
 160 #define strstr strstrofs
 161 /*
 162 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 163 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 164 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 165 // BE CONSTANT OR strzoneD!
 166 float strstr(string haystack, string needle, float offset)
 167 {
 168         float len, endpos;
 169         string found;
 170         len = strlen(needle);
 171         endpos = strlen(haystack) - len;
 172         while(offset <= endpos)
 173         {
 174                 found = substring(haystack, offset, len);
 175                 if(found == needle)
 176                         return offset;
 177                 offset = offset + 1;
 178         }
 179         return -1;
 180 }
 181 */
 182
 183 float NUM_NEAREST_ENTITIES = 4;
 184 entity nearest_entity[NUM_NEAREST_ENTITIES];
 185 float nearest_length[NUM_NEAREST_ENTITIES];
 186 entity findnearest(vector point, .string field, string value, vector axismod)
 187 {
 188     entity localhead;
 189     float i;
 190     float j;
 191     float len;
 192     vector dist;
 193
 194     float num_nearest;
 195     num_nearest = 0;
 196
 197     localhead = find(world, field, value);
 198     while (localhead)
 199     {
 200         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 201             dist = localhead.oldorigin;
 202         else
 203             dist = localhead.origin;
 204         dist = dist - point;
 205         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 206         len = vlen(dist);
 207
 208         for (i = 0; i < num_nearest; ++i)
 209         {
 210             if (len < nearest_length[i])
 211                 break;
 212         }
 213
 214         // now i tells us where to insert at
 215         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 216         if (i < NUM_NEAREST_ENTITIES)
 217         {
 218             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 219             {
 220                 nearest_length[j + 1] = nearest_length[j];
 221                 nearest_entity[j + 1] = nearest_entity[j];
 222             }
 223             nearest_length[i] = len;
 224             nearest_entity[i] = localhead;
 225             if (num_nearest < NUM_NEAREST_ENTITIES)
 226                 num_nearest = num_nearest + 1;
 227         }
 228
 229         localhead = find(localhead, field, value);
 230     }
 231
 232     // now use the first one from our list that we can see
 233     for (i = 0; i < num_nearest; ++i)
 234     {
 235         traceline(point, nearest_entity[i].origin, TRUE, world);
 236         if (trace_fraction == 1)
 237         {
 238             if (i != 0)
 239             {
 240                 dprint("Nearest point (");
 241                 dprint(nearest_entity[0].netname);
 242                 dprint(") is not visible, using a visible one.\n");
 243             }
 244             return nearest_entity[i];
 245         }
 246     }
 247
 248     if (num_nearest == 0)
 249         return world;
 250
 251     dprint("Not seeing any location point, using nearest as fallback.\n");
 252     /* DEBUGGING CODE:
 253     dprint("Candidates were: ");
 254     for(j = 0; j < num_nearest; ++j)
 255     {
 256         if(j != 0)
 257                 dprint(", ");
 258         dprint(nearest_entity[j].netname);
 259     }
 260     dprint("\n");
 261     */
 262
 263     return nearest_entity[0];
 264 }
 265
 266 void spawnfunc_target_location()
 267 {
 268     self.classname = "target_location";
 269     // location name in netname
 270     // eventually support: count, teamgame selectors, line of sight?
 271 }
 272
 273 void spawnfunc_info_location()
 274 {
 275     self.classname = "target_location";
 276     self.message = self.netname;
 277 }
 278
 279 string NearestLocation(vector p)
 280 {
 281     entity loc;
 282     string ret;
 283     ret = "somewhere";
 284     loc = findnearest(p, classname, "target_location", '1 1 1');
 285     if (loc)
 286     {
 287         ret = loc.message;
 288     }
 289     else
 290     {
 291         loc = findnearest(p, target, "###item###", '1 1 4');
 292         if (loc)
 293             ret = loc.netname;
 294     }
 295     return ret;
 296 }
 297
 298 string formatmessage(string msg)
 299 {
 300         float p, p1, p2;
 301         float n;
 302         vector cursor;
 303         entity cursor_ent;
 304         string escape;
 305         string replacement;
 306         p = 0;
 307         n = 7;
 308
 309         WarpZone_crosshair_trace(self);
 310         cursor = trace_endpos;
 311         cursor_ent = trace_ent;
 312
 313         while (1) {
 314                 if (n < 1)
 315                         break; // too many replacements
 316
 317                 n = n - 1;
 318                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 319                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 320
 321                 if (p1 < 0)
 322                         p1 = p2;
 323
 324                 if (p2 < 0)
 325                         p2 = p1;
 326
 327                 p = min(p1, p2);
 328
 329                 if (p < 0)
 330                         break;
 331
 332                 replacement = substring(msg, p, 2);
 333                 escape = substring(msg, p + 1, 1);
 334
 335                 if (escape == "%")
 336                         replacement = "%";
 337                 else if (escape == "\\")
 338                         replacement = "\\";
 339                 else if (escape == "n")
 340                         replacement = "\n";
 341                 else if (escape == "a")
 342                         replacement = ftos(floor(self.armorvalue));
 343                 else if (escape == "h")
 344                         replacement = ftos(floor(self.health));
 345                 else if (escape == "l")
 346                         replacement = NearestLocation(self.origin);
 347                 else if (escape == "y")
 348                         replacement = NearestLocation(cursor);
 349                 else if (escape == "d")
 350                         replacement = NearestLocation(self.death_origin);
 351                 else if (escape == "w") {
 352                         float wep;
 353                         wep = self.weapon;
 354                         if (!wep)
 355                                 wep = self.switchweapon;
 356                         if (!wep)
 357                                 wep = self.cnt;
 358                         replacement = W_Name(wep);
 359                 } else if (escape == "W") {
 360                         if (self.items & IT_SHELLS) replacement = "shells";
 361                         else if (self.items & IT_NAILS) replacement = "bullets";
 362                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 363                         else if (self.items & IT_CELLS) replacement = "cells";
 364                         else replacement = "batteries"; // ;)
 365                 } else if (escape == "x") {
 366                         replacement = cursor_ent.netname;
 367                         if (replacement == "" || !cursor_ent)
 368                                 replacement = "nothing";
 369                 } else if (escape == "s")
 370                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 371                 else if (escape == "S")
 372                         replacement = ftos(vlen(self.velocity));
 373
 374                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 375                 p = p + strlen(replacement);
 376         }
 377         return msg;
 378 }
 379
 380 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 381         return (value == 0) ? FALSE : TRUE;
 382 }
 383
 384 /*
 385 =============
 386 GetCvars
 387 =============
 388 Called with:
 389   0:  sends the request
 390   >0: receives a cvar from name=argv(f) value=argv(f+1)
 391 */
 392 void GetCvars_handleString(string thisname, float f, .string field, string name)
 393 {
 394         if (f < 0)
 395         {
 396                 if (self.field)
 397                         strunzone(self.field);
 398                 self.field = string_null;
 399         }
 400         else if (f > 0)
 401         {
 402                 if (thisname == name)
 403                 {
 404                         if (self.field)
 405                                 strunzone(self.field);
 406                         self.field = strzone(argv(f + 1));
 407                 }
 408         }
 409         else
 410                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 411 }
 412 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 413 {
 414         GetCvars_handleString(thisname, f, field, name);
 415         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 416                 if (thisname == name)
 417                 {
 418                         string s;
 419                         s = func(strcat1(self.field));
 420                         if (s != self.field)
 421                         {
 422                                 strunzone(self.field);
 423                                 self.field = strzone(s);
 424                         }
 425                 }
 426 }
 427 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 428 {
 429         if (f < 0)
 430         {
 431         }
 432         else if (f > 0)
 433         {
 434                 if (thisname == name)
 435                         self.field = stof(argv(f + 1));
 436         }
 437         else
 438                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 439 }
 440 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 441 {
 442         if (f < 0)
 443         {
 444         }
 445         else if (f > 0)
 446         {
 447                 if (thisname == name)
 448                 {
 449                         if(!self.field)
 450                         {
 451                                 self.field = stof(argv(f + 1));
 452                                 if(!self.field)
 453                                         self.field = -1;
 454                         }
 455                 }
 456         }
 457         else
 458         {
 459                 if(!self.field)
 460                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 461         }
 462 }
 463 float w_getbestweapon(entity e);
 464 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 465 {
 466         string o;
 467         o = W_FixWeaponOrder_ForceComplete(wo);
 468         if(self.weaponorder_byimpulse)
 469         {
 470                 strunzone(self.weaponorder_byimpulse);
 471                 self.weaponorder_byimpulse = string_null;
 472         }
 473         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 474         return o;
 475 }
 476 void GetCvars(float f)
 477 {
 478         string s = string_null;
 479
 480         if (f > 0)
 481                 s = strcat1(argv(f));
 482
 483         get_cvars_f = f;
 484         get_cvars_s = s;
 485
 486         MUTATOR_CALLHOOK(GetCvars);
 487
 488         Notification_GetCvars();
 489
 490         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 491         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 492         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 493         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 494         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 495         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 496         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 497         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 498         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 499         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 500         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 501         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 502         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 503         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 504         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 505         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 506         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 507         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 508         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 509         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 510         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 511         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 512         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 513
 514         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 515         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 516
 517         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 518         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 519         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 520         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 521         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 522
 523         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 524         if (f > 0)
 525         {
 526                 if (s == "cl_weaponpriority")
 527                         self.switchweapon = w_getbestweapon(self);
 528                 if (s == "cl_allow_uidtracking")
 529                         PlayerStats_AddPlayer(self);
 530         }
 531 }
 532
 533 // decolorizes and team colors the player name when needed
 534 string playername(entity p)
 535 {
 536     string t;
 537     if (teamplay && !intermission_running && IS_PLAYER(p))
 538     {
 539         t = Team_ColorCode(p.team);
 540         return strcat(t, strdecolorize(p.netname));
 541     }
 542     else
 543         return p.netname;
 544 }
 545
 546 vector randompos(vector m1, vector m2)
 547 {
 548     vector v;
 549     m2 = m2 - m1;
 550     v_x = m2_x * random() + m1_x;
 551     v_y = m2_y * random() + m1_y;
 552     v_z = m2_z * random() + m1_z;
 553     return  v;
 554 }
 555
 556 //#NO AUTOCVARS START
 557
 558 float g_pickup_shells;
 559 float g_pickup_shells_max;
 560 float g_pickup_nails;
 561 float g_pickup_nails_max;
 562 float g_pickup_rockets;
 563 float g_pickup_rockets_max;
 564 float g_pickup_cells;
 565 float g_pickup_cells_max;
 566 float g_pickup_fuel;
 567 float g_pickup_fuel_jetpack;
 568 float g_pickup_fuel_max;
 569 float g_pickup_armorsmall;
 570 float g_pickup_armorsmall_max;
 571 float g_pickup_armorsmall_anyway;
 572 float g_pickup_armormedium;
 573 float g_pickup_armormedium_max;
 574 float g_pickup_armormedium_anyway;
 575 float g_pickup_armorbig;
 576 float g_pickup_armorbig_max;
 577 float g_pickup_armorbig_anyway;
 578 float g_pickup_armorlarge;
 579 float g_pickup_armorlarge_max;
 580 float g_pickup_armorlarge_anyway;
 581 float g_pickup_healthsmall;
 582 float g_pickup_healthsmall_max;
 583 float g_pickup_healthsmall_anyway;
 584 float g_pickup_healthmedium;
 585 float g_pickup_healthmedium_max;
 586 float g_pickup_healthmedium_anyway;
 587 float g_pickup_healthlarge;
 588 float g_pickup_healthlarge_max;
 589 float g_pickup_healthlarge_anyway;
 590 float g_pickup_healthmega;
 591 float g_pickup_healthmega_max;
 592 float g_pickup_healthmega_anyway;
 593 float g_pickup_ammo_anyway;
 594 float g_pickup_weapons_anyway;
 595 float g_weaponarena;
 596 WEPSET_DECLARE_A(g_weaponarena_weapons);
 597 float g_weaponarena_random;
 598 float g_weaponarena_random_with_laser;
 599 string g_weaponarena_list;
 600 float g_weaponspeedfactor;
 601 float g_weaponratefactor;
 602 float g_weapondamagefactor;
 603 float g_weaponforcefactor;
 604 float g_weaponspreadfactor;
 605
 606 WEPSET_DECLARE_A(start_weapons);
 607 WEPSET_DECLARE_A(start_weapons_default);
 608 WEPSET_DECLARE_A(start_weapons_defaultmask);
 609 float start_items;
 610 float start_ammo_shells;
 611 float start_ammo_nails;
 612 float start_ammo_rockets;
 613 float start_ammo_cells;
 614 float start_ammo_fuel;
 615 float start_health;
 616 float start_armorvalue;
 617 WEPSET_DECLARE_A(warmup_start_weapons);
 618 WEPSET_DECLARE_A(warmup_start_weapons_default);
 619 WEPSET_DECLARE_A(warmup_start_weapons_defaultmask);
 620 float warmup_start_ammo_shells;
 621 float warmup_start_ammo_nails;
 622 float warmup_start_ammo_rockets;
 623 float warmup_start_ammo_cells;
 624 float warmup_start_ammo_fuel;
 625 float warmup_start_health;
 626 float warmup_start_armorvalue;
 627 float g_weapon_stay;
 628
 629 entity get_weaponinfo(float w);
 630
 631 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 632 {
 633         var float i = weaponinfo.weapon;
 634         var float d = 0;
 635
 636         if (!i)
 637                 return 0;
 638
 639         if (g_lms || g_ca || allguns)
 640         {
 641                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 642                         d = TRUE;
 643                 else
 644                         d = FALSE;
 645         }
 646         else if (g_cts)
 647                 d = (i == WEP_SHOTGUN);
 648         else if (g_nexball)
 649                 d = 0; // weapon is set a few lines later
 650         else
 651                 d = (i == WEP_LASER || i == WEP_SHOTGUN);
 652
 653         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 654                 d |= (i == WEP_HOOK);
 655         if(weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED) // never default mutator blocked guns
 656                 d = 0;
 657
 658         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 659
 660         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 661
 662         // bit order in t:
 663         // 1: want or not
 664         // 2: is default?
 665         // 4: is set by default?
 666         if(t < 0)
 667                 t = 4 | (3 * d);
 668         else
 669                 t |= (2 * d);
 670
 671         return t;
 672 }
 673
 674 void readplayerstartcvars()
 675 {
 676         entity e;
 677         float i, j, t;
 678         string s;
 679
 680         // initialize starting values for players
 681         WEPSET_CLEAR_A(start_weapons);
 682         WEPSET_CLEAR_A(start_weapons_default);
 683         WEPSET_CLEAR_A(start_weapons_defaultmask);
 684         start_items = 0;
 685         start_ammo_shells = 0;
 686         start_ammo_nails = 0;
 687         start_ammo_rockets = 0;
 688         start_ammo_cells = 0;
 689         start_health = cvar("g_balance_health_start");
 690         start_armorvalue = cvar("g_balance_armor_start");
 691
 692         g_weaponarena = 0;
 693         WEPSET_CLEAR_A(g_weaponarena_weapons);
 694
 695         s = cvar_string("g_weaponarena");
 696         if (s == "0" || s == "")
 697         {
 698                 if(g_ca)
 699                         s = "most";
 700         }
 701
 702         if (s == "0" || s == "")
 703         {
 704                 // no arena
 705         }
 706         else if (s == "off")
 707         {
 708                 // forcibly turn off weaponarena
 709         }
 710         else if (s == "all")
 711         {
 712                 g_weaponarena = 1;
 713                 g_weaponarena_list = "All Weapons";
 714                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 715                 {
 716                         e = get_weaponinfo(j);
 717                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 718                                 WEPSET_OR_AW(g_weaponarena_weapons, j);
 719                 }
 720         }
 721         else if (s == "most")
 722         {
 723                 g_weaponarena = 1;
 724                 g_weaponarena_list = "Most Weapons";
 725                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 726                 {
 727                         e = get_weaponinfo(j);
 728                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 729                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 730                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 731                 }
 732         }
 733         else if (s == "none")
 734         {
 735                 g_weaponarena = 1;
 736                 g_weaponarena_list = "No Weapons";
 737         }
 738         else
 739         {
 740                 g_weaponarena = 1;
 741                 t = tokenize_console(s);
 742                 g_weaponarena_list = "";
 743                 for (i = 0; i < t; ++i)
 744                 {
 745                         s = argv(i);
 746                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 747                         {
 748                                 e = get_weaponinfo(j);
 749                                 if (e.netname == s)
 750                                 {
 751                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 752                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 753                                         break;
 754                                 }
 755                         }
 756                         if (j > WEP_LAST)
 757                         {
 758                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 759                         }
 760                 }
 761                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 762         }
 763
 764         if(g_weaponarena)
 765                 g_weaponarena_random = cvar("g_weaponarena_random");
 766         else
 767                 g_weaponarena_random = 0;
 768         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 769
 770         if (g_weaponarena)
 771         {
 772                 g_pinata = 0; // incompatible
 773                 g_weapon_stay = 0; // incompatible
 774                 WEPSET_COPY_AA(start_weapons, g_weaponarena_weapons);
 775                 start_items |= IT_UNLIMITED_AMMO;
 776         }
 777         else
 778         {
 779                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 780                 {
 781                         e = get_weaponinfo(i);
 782                         float w = want_weapon("g_start_weapon_", e, FALSE);
 783                         if(w & 1)
 784                                 WEPSET_OR_AW(start_weapons, i);
 785                         if(w & 2)
 786                                 WEPSET_OR_AW(start_weapons_default, i);
 787                         if(w & 4)
 788                                 WEPSET_OR_AW(start_weapons_defaultmask, i);
 789                 }
 790         }
 791
 792         if(!cvar("g_use_ammunition"))
 793                 start_items |= IT_UNLIMITED_AMMO;
 794
 795         if(cvar("g_nexball"))
 796                 start_items |= IT_UNLIMITED_SUPERWEAPONS; // FIXME BAD BAD BAD BAD HACK, NEXBALL SHOULDN'T ABUSE PORTO'S WEAPON SLOT
 797
 798         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 799         {
 800                 start_ammo_rockets = 999;
 801                 start_ammo_shells = 999;
 802                 start_ammo_cells = 999;
 803                 start_ammo_nails = 999;
 804                 start_ammo_fuel = 999;
 805         }
 806         else
 807         {
 808                 start_ammo_shells = cvar("g_start_ammo_shells");
 809                 start_ammo_nails = cvar("g_start_ammo_nails");
 810                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 811                 start_ammo_cells = cvar("g_start_ammo_cells");
 812                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 813         }
 814
 815         if (inWarmupStage)
 816         {
 817                 warmup_start_ammo_shells = start_ammo_shells;
 818                 warmup_start_ammo_nails = start_ammo_nails;
 819                 warmup_start_ammo_rockets = start_ammo_rockets;
 820                 warmup_start_ammo_cells = start_ammo_cells;
 821                 warmup_start_ammo_fuel = start_ammo_fuel;
 822                 warmup_start_health = start_health;
 823                 warmup_start_armorvalue = start_armorvalue;
 824                 WEPSET_COPY_AA(warmup_start_weapons, start_weapons);
 825                 WEPSET_COPY_AA(warmup_start_weapons_default, start_weapons_default);
 826                 WEPSET_COPY_AA(warmup_start_weapons_defaultmask, start_weapons_defaultmask);
 827
 828                 if (!g_weaponarena && !g_ca)
 829                 {
 830                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 831                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 832                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 833                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 834                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 835                         warmup_start_health = cvar("g_warmup_start_health");
 836                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 837                         WEPSET_CLEAR_A(warmup_start_weapons);
 838                         WEPSET_CLEAR_A(warmup_start_weapons_default);
 839                         WEPSET_CLEAR_A(warmup_start_weapons_defaultmask);
 840                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 841                         {
 842                                 e = get_weaponinfo(i);
 843                                 float w = want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns"));
 844                                 if(w & 1)
 845                                         WEPSET_OR_AW(warmup_start_weapons, i);
 846                                 if(w & 2)
 847                                         WEPSET_OR_AW(warmup_start_weapons_default, i);
 848                                 if(w & 4)
 849                                         WEPSET_OR_AW(warmup_start_weapons_defaultmask, i);
 850                         }
 851                 }
 852         }
 853
 854         if (g_jetpack)
 855                 start_items |= IT_JETPACK;
 856
 857         MUTATOR_CALLHOOK(SetStartItems);
 858
 859         if ((start_items & IT_JETPACK) || (g_grappling_hook && WEPSET_CONTAINS_AW(start_weapons, WEP_HOOK)))
 860         {
 861                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
 862                 start_items |= IT_FUEL_REGEN;
 863                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 864                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 865         }
 866
 867         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 868         {
 869                 e = get_weaponinfo(i);
 870                 if(WEPSET_CONTAINS_AW(start_weapons, i) || WEPSET_CONTAINS_AW(warmup_start_weapons, i))
 871                         weapon_action(i, WR_PRECACHE);
 872         }
 873
 874         start_ammo_shells = max(0, start_ammo_shells);
 875         start_ammo_nails = max(0, start_ammo_nails);
 876         start_ammo_cells = max(0, start_ammo_cells);
 877         start_ammo_rockets = max(0, start_ammo_rockets);
 878         start_ammo_fuel = max(0, start_ammo_fuel);
 879
 880         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 881         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 882         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 883         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 884         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 885 }
 886
 887 float g_bugrigs;
 888 float g_bugrigs_planar_movement;
 889 float g_bugrigs_planar_movement_car_jumping;
 890 float g_bugrigs_reverse_spinning;
 891 float g_bugrigs_reverse_speeding;
 892 float g_bugrigs_reverse_stopping;
 893 float g_bugrigs_air_steering;
 894 float g_bugrigs_angle_smoothing;
 895 float g_bugrigs_friction_floor;
 896 float g_bugrigs_friction_brake;
 897 float g_bugrigs_friction_air;
 898 float g_bugrigs_accel;
 899 float g_bugrigs_speed_ref;
 900 float g_bugrigs_speed_pow;
 901 float g_bugrigs_steer;
 902
 903 float sv_autotaunt;
 904 float sv_taunt;
 905
 906 string GetGametype(); // g_world.qc
 907 void readlevelcvars(void)
 908 {
 909         // load mutators
 910         #define CHECK_MUTATOR_ADD(mut_cvar,mut_name,dependence) \
 911                 { if(cvar(mut_cvar) && dependence) { MUTATOR_ADD(mut_name); } }
 912
 913         CHECK_MUTATOR_ADD("g_dodging", mutator_dodging, 1);
 914         CHECK_MUTATOR_ADD("g_spawn_near_teammate", mutator_spawn_near_teammate, 1);
 915         CHECK_MUTATOR_ADD("g_physical_items", mutator_physical_items, 1);
 916         CHECK_MUTATOR_ADD("g_touchexplode", mutator_touchexplode, 1);
 917         CHECK_MUTATOR_ADD("g_minstagib", mutator_minstagib, 1);
 918         CHECK_MUTATOR_ADD("g_invincible_projectiles", mutator_invincibleprojectiles, !cvar("g_minstagib"));
 919         CHECK_MUTATOR_ADD("g_new_toys", mutator_new_toys, !cvar("g_minstagib"));
 920         CHECK_MUTATOR_ADD("g_nix", mutator_nix, !cvar("g_minstagib"));
 921         CHECK_MUTATOR_ADD("g_rocket_flying", mutator_rocketflying, !cvar("g_minstagib"));
 922         CHECK_MUTATOR_ADD("g_vampire", mutator_vampire, !cvar("g_minstagib"));
 923         CHECK_MUTATOR_ADD("g_superspectate", mutator_superspec, 1);
 924         CHECK_MUTATOR_ADD("g_sandbox", sandbox, 1);
 925
 926         #undef CHECK_MUTATOR_ADD
 927
 928         if(cvar("sv_allow_fullbright"))
 929                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
 930
 931     g_bugrigs = cvar("g_bugrigs");
 932     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
 933     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
 934     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
 935     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
 936     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
 937     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
 938     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
 939     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
 940     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
 941     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
 942     g_bugrigs_accel = cvar("g_bugrigs_accel");
 943     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
 944     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
 945     g_bugrigs_steer = cvar("g_bugrigs_steer");
 946
 947         monster_skill = cvar("g_monsters_skill");
 948
 949         g_minstagib = cvar("g_minstagib");
 950
 951         sv_clones = cvar("sv_clones");
 952         sv_foginterval = cvar("sv_foginterval");
 953         g_cloaked = cvar("g_cloaked");
 954     if(g_cts)
 955         g_cloaked = 1; // always enable cloak in CTS
 956         g_jump_grunt = cvar("g_jump_grunt");
 957         g_footsteps = cvar("g_footsteps");
 958         g_grappling_hook = cvar("g_grappling_hook");
 959         g_jetpack = cvar("g_jetpack");
 960         g_midair = cvar("g_midair");
 961         g_norecoil = cvar("g_norecoil");
 962         g_bloodloss = cvar("g_bloodloss");
 963         sv_maxidle = cvar("sv_maxidle");
 964         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
 965         sv_autotaunt = cvar("sv_autotaunt");
 966         sv_taunt = cvar("sv_taunt");
 967
 968         inWarmupStage = cvar("g_warmup");
 969         g_warmup_limit = cvar("g_warmup_limit");
 970         g_warmup_allguns = cvar("g_warmup_allguns");
 971         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
 972
 973         if ((g_race && g_race_qualifying == 2) || g_arena || g_minstagib || g_assault || cvar("g_campaign"))
 974                 inWarmupStage = 0; // these modes cannot work together, sorry
 975
 976         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
 977         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
 978         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
 979         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
 980         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
 981         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
 982         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
 983         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
 984         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
 985         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
 986         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
 987         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
 988         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
 989         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
 990
 991         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
 992         g_weaponratefactor = cvar("g_weaponratefactor");
 993         g_weapondamagefactor = cvar("g_weapondamagefactor");
 994         g_weaponforcefactor = cvar("g_weaponforcefactor");
 995         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
 996
 997         g_pickup_shells = cvar("g_pickup_shells");
 998         g_pickup_shells_max = cvar("g_pickup_shells_max");
 999         g_pickup_nails = cvar("g_pickup_nails");
1000         g_pickup_nails_max = cvar("g_pickup_nails_max");
1001         g_pickup_rockets = cvar("g_pickup_rockets");
1002         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1003         g_pickup_cells = cvar("g_pickup_cells");
1004         g_pickup_cells_max = cvar("g_pickup_cells_max");
1005         g_pickup_fuel = cvar("g_pickup_fuel");
1006         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1007         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1008         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1009         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1010         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1011         g_pickup_armormedium = cvar("g_pickup_armormedium");
1012         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1013         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1014         g_pickup_armorbig = cvar("g_pickup_armorbig");
1015         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1016         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1017         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1018         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1019         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1020         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1021         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1022         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1023         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1024         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1025         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1026         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1027         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1028         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1029         g_pickup_healthmega = cvar("g_pickup_healthmega");
1030         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1031         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1032
1033         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1034         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1035
1036         g_pinata = cvar("g_pinata");
1037
1038     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1039     if(!g_weapon_stay)
1040         g_weapon_stay = cvar("g_weapon_stay");
1041
1042         if not(inWarmupStage)
1043                 game_starttime = time + cvar("g_start_delay");
1044
1045         readplayerstartcvars();
1046 }
1047
1048 //#NO AUTOCVARS END
1049
1050 // Sound functions
1051 string precache_sound (string s) = #19;
1052 float precache_sound_index (string s) = #19;
1053
1054 #define SND_VOLUME      1
1055 #define SND_ATTENUATION 2
1056 #define SND_LARGEENTITY 8
1057 #define SND_LARGESOUND  16
1058
1059 float sound_allowed(float dest, entity e)
1060 {
1061     // sounds from world may always pass
1062     for (;;)
1063     {
1064         if (e.classname == "body")
1065             e = e.enemy;
1066         else if (e.realowner && e.realowner != e)
1067             e = e.realowner;
1068         else if (e.owner && e.owner != e)
1069             e = e.owner;
1070         else
1071             break;
1072     }
1073     // sounds to self may always pass
1074     if (dest == MSG_ONE)
1075         if (e == msg_entity)
1076             return TRUE;
1077     // sounds by players can be removed
1078     if (autocvar_bot_sound_monopoly)
1079         if (IS_REAL_CLIENT(e))
1080             return FALSE;
1081     // anything else may pass
1082     return TRUE;
1083 }
1084
1085 #ifdef COMPAT_XON010_CHANNELS
1086 void(entity e, float chan, string samp, float vol, float atten) builtin_sound = #8;
1087 void sound(entity e, float chan, string samp, float vol, float atten)
1088 {
1089     if (!sound_allowed(MSG_BROADCAST, e))
1090         return;
1091     builtin_sound(e, chan, samp, vol, atten);
1092 }
1093 #else
1094 #undef sound
1095 void sound(entity e, float chan, string samp, float vol, float atten)
1096 {
1097     if (!sound_allowed(MSG_BROADCAST, e))
1098         return;
1099     sound7(e, chan, samp, vol, atten, 0, 0);
1100 }
1101 #endif
1102
1103 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1104 {
1105     float entno, idx;
1106
1107     if (!sound_allowed(dest, e))
1108         return;
1109
1110     entno = num_for_edict(e);
1111     idx = precache_sound_index(samp);
1112
1113     float sflags;
1114     sflags = 0;
1115
1116     atten = floor(atten * 64);
1117     vol = floor(vol * 255);
1118
1119     if (vol != 255)
1120         sflags |= SND_VOLUME;
1121     if (atten != 64)
1122         sflags |= SND_ATTENUATION;
1123     if (entno >= 8192 || chan < 0 || chan > 7)
1124         sflags |= SND_LARGEENTITY;
1125     if (idx >= 256)
1126         sflags |= SND_LARGESOUND;
1127
1128     WriteByte(dest, SVC_SOUND);
1129     WriteByte(dest, sflags);
1130     if (sflags & SND_VOLUME)
1131         WriteByte(dest, vol);
1132     if (sflags & SND_ATTENUATION)
1133         WriteByte(dest, atten);
1134     if (sflags & SND_LARGEENTITY)
1135     {
1136         WriteShort(dest, entno);
1137         WriteByte(dest, chan);
1138     }
1139     else
1140     {
1141         WriteShort(dest, entno * 8 + chan);
1142     }
1143     if (sflags & SND_LARGESOUND)
1144         WriteShort(dest, idx);
1145     else
1146         WriteByte(dest, idx);
1147
1148     WriteCoord(dest, o_x);
1149     WriteCoord(dest, o_y);
1150     WriteCoord(dest, o_z);
1151 }
1152 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1153 {
1154     vector o;
1155
1156     if (!sound_allowed(dest, e))
1157         return;
1158
1159     o = e.origin + 0.5 * (e.mins + e.maxs);
1160     soundtoat(dest, e, o, chan, samp, vol, atten);
1161 }
1162 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1163 {
1164     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1165 }
1166 void stopsoundto(float dest, entity e, float chan)
1167 {
1168     float entno;
1169
1170     if (!sound_allowed(dest, e))
1171         return;
1172
1173     entno = num_for_edict(e);
1174
1175     if (entno >= 8192 || chan < 0 || chan > 7)
1176     {
1177         float idx, sflags;
1178         idx = precache_sound_index("misc/null.wav");
1179         sflags = SND_LARGEENTITY;
1180         if (idx >= 256)
1181             sflags |= SND_LARGESOUND;
1182         WriteByte(dest, SVC_SOUND);
1183         WriteByte(dest, sflags);
1184         WriteShort(dest, entno);
1185         WriteByte(dest, chan);
1186         if (sflags & SND_LARGESOUND)
1187             WriteShort(dest, idx);
1188         else
1189             WriteByte(dest, idx);
1190         WriteCoord(dest, e.origin_x);
1191         WriteCoord(dest, e.origin_y);
1192         WriteCoord(dest, e.origin_z);
1193     }
1194     else
1195     {
1196         WriteByte(dest, SVC_STOPSOUND);
1197         WriteShort(dest, entno * 8 + chan);
1198     }
1199 }
1200 void stopsound(entity e, float chan)
1201 {
1202     if (!sound_allowed(MSG_BROADCAST, e))
1203         return;
1204
1205     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1206     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1207 }
1208
1209 void play2(entity e, string filename)
1210 {
1211     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1212     msg_entity = e;
1213     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTN_NONE);
1214 }
1215
1216 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1217 .float spamtime;
1218 float spamsound(entity e, float chan, string samp, float vol, float atten)
1219 {
1220     if (!sound_allowed(MSG_BROADCAST, e))
1221         return FALSE;
1222
1223     if (time > e.spamtime)
1224     {
1225         e.spamtime = time;
1226         sound(e, chan, samp, vol, atten);
1227         return TRUE;
1228     }
1229     return FALSE;
1230 }
1231
1232 void play2team(float t, string filename)
1233 {
1234     entity head;
1235
1236     if (autocvar_bot_sound_monopoly)
1237         return;
1238
1239     FOR_EACH_REALPLAYER(head)
1240     {
1241         if (head.team == t)
1242             play2(head, filename);
1243     }
1244 }
1245
1246 void play2all(string samp)
1247 {
1248     if (autocvar_bot_sound_monopoly)
1249         return;
1250
1251     sound(world, CH_INFO, samp, VOL_BASE, ATTN_NONE);
1252 }
1253
1254 void PrecachePlayerSounds(string f);
1255 void precache_playermodel(string m)
1256 {
1257         float globhandle, i, n;
1258         string f;
1259
1260         if(substring(m, -9,5) == "_lod1")
1261                 return;
1262         if(substring(m, -9,5) == "_lod2")
1263                 return;
1264         precache_model(m);
1265         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1266         if(fexists(f))
1267                 precache_model(f);
1268         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1269         if(fexists(f))
1270                 precache_model(f);
1271
1272         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1273         if (globhandle < 0)
1274                 return;
1275         n = search_getsize(globhandle);
1276         for (i = 0; i < n; ++i)
1277         {
1278                 //print(search_getfilename(globhandle, i), "\n");
1279                 f = search_getfilename(globhandle, i);
1280                 PrecachePlayerSounds(f);
1281         }
1282         search_end(globhandle);
1283 }
1284 void precache_all_playermodels(string pattern)
1285 {
1286         float globhandle, i, n;
1287         string f;
1288
1289         globhandle = search_begin(pattern, TRUE, FALSE);
1290         if (globhandle < 0)
1291                 return;
1292         n = search_getsize(globhandle);
1293         for (i = 0; i < n; ++i)
1294         {
1295                 //print(search_getfilename(globhandle, i), "\n");
1296                 f = search_getfilename(globhandle, i);
1297                 precache_playermodel(f);
1298         }
1299         search_end(globhandle);
1300 }
1301
1302 void precache()
1303 {
1304     // gamemode related things
1305     precache_model ("models/misc/chatbubble.spr");
1306
1307 #ifdef TTURRETS_ENABLED
1308     if (autocvar_g_turrets)
1309         turrets_precash();
1310 #endif
1311
1312     // Precache all player models if desired
1313     if (autocvar_sv_precacheplayermodels)
1314     {
1315         PrecachePlayerSounds("sound/player/default.sounds");
1316         precache_all_playermodels("models/player/*.zym");
1317         precache_all_playermodels("models/player/*.dpm");
1318         precache_all_playermodels("models/player/*.md3");
1319         precache_all_playermodels("models/player/*.psk");
1320         precache_all_playermodels("models/player/*.iqm");
1321     }
1322
1323     if (autocvar_sv_defaultcharacter)
1324     {
1325         string s;
1326         s = autocvar_sv_defaultplayermodel_red;
1327         if (s != "")
1328             precache_playermodel(s);
1329         s = autocvar_sv_defaultplayermodel_blue;
1330         if (s != "")
1331             precache_playermodel(s);
1332         s = autocvar_sv_defaultplayermodel_yellow;
1333         if (s != "")
1334             precache_playermodel(s);
1335         s = autocvar_sv_defaultplayermodel_pink;
1336         if (s != "")
1337             precache_playermodel(s);
1338         s = autocvar_sv_defaultplayermodel;
1339         if (s != "")
1340             precache_playermodel(s);
1341     }
1342
1343     if (g_footsteps)
1344     {
1345         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1346         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1347     }
1348
1349     // gore and miscellaneous sounds
1350     //precache_sound ("misc/h2ohit.wav");
1351     precache_model ("models/hook.md3");
1352     precache_sound ("misc/armorimpact.wav");
1353     precache_sound ("misc/bodyimpact1.wav");
1354     precache_sound ("misc/bodyimpact2.wav");
1355     precache_sound ("misc/gib.wav");
1356     precache_sound ("misc/gib_splat01.wav");
1357     precache_sound ("misc/gib_splat02.wav");
1358     precache_sound ("misc/gib_splat03.wav");
1359     precache_sound ("misc/gib_splat04.wav");
1360     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1361     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1362     precache_sound ("misc/null.wav");
1363     precache_sound ("misc/spawn.wav");
1364     precache_sound ("misc/talk.wav");
1365     precache_sound ("misc/teleport.wav");
1366     precache_sound ("misc/poweroff.wav");
1367     precache_sound ("player/lava.wav");
1368     precache_sound ("player/slime.wav");
1369
1370     precache_model ("models/sprites/0.spr32");
1371     precache_model ("models/sprites/1.spr32");
1372     precache_model ("models/sprites/2.spr32");
1373     precache_model ("models/sprites/3.spr32");
1374     precache_model ("models/sprites/4.spr32");
1375     precache_model ("models/sprites/5.spr32");
1376     precache_model ("models/sprites/6.spr32");
1377     precache_model ("models/sprites/7.spr32");
1378     precache_model ("models/sprites/8.spr32");
1379     precache_model ("models/sprites/9.spr32");
1380     precache_model ("models/sprites/10.spr32");
1381
1382     // common weapon precaches
1383         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1384     precache_sound ("weapons/weapon_switch.wav");
1385     precache_sound ("weapons/weaponpickup.wav");
1386     precache_sound ("weapons/unavailable.wav");
1387     precache_sound ("weapons/dryfire.wav");
1388     if (g_grappling_hook)
1389     {
1390         precache_sound ("weapons/hook_fire.wav"); // hook
1391         precache_sound ("weapons/hook_impact.wav"); // hook
1392     }
1393
1394     if(autocvar_sv_precacheweapons)
1395     {
1396         //precache weapon models/sounds
1397         float wep;
1398         wep = WEP_FIRST;
1399         while (wep <= WEP_LAST)
1400         {
1401             weapon_action(wep, WR_PRECACHE);
1402             wep = wep + 1;
1403         }
1404     }
1405
1406     precache_model("models/elaser.mdl");
1407     precache_model("models/laser.mdl");
1408     precache_model("models/ebomb.mdl");
1409
1410 #if 0
1411     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1412
1413     if (!self.noise && self.music) // quake 3 uses the music field
1414         self.noise = self.music;
1415
1416     // plays music for the level if there is any
1417     if (self.noise)
1418     {
1419         precache_sound (self.noise);
1420         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1421     }
1422 #endif
1423
1424 #include "precache-for-csqc.inc"
1425 }
1426
1427 // WARNING: this kills the trace globals
1428 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1429 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1430
1431 #define INITPRIO_FIRST              0
1432 #define INITPRIO_GAMETYPE           0
1433 #define INITPRIO_GAMETYPE_FALLBACK  1
1434 #define INITPRIO_FINDTARGET        10
1435 #define INITPRIO_DROPTOFLOOR       20
1436 #define INITPRIO_SETLOCATION       90
1437 #define INITPRIO_LINKDOORS         91
1438 #define INITPRIO_LAST              99
1439
1440 .void(void) initialize_entity;
1441 .float initialize_entity_order;
1442 .entity initialize_entity_next;
1443 entity initialize_entity_first;
1444
1445 void make_safe_for_remove(entity e)
1446 {
1447     if (e.initialize_entity)
1448     {
1449         entity ent, prev = world;
1450         for (ent = initialize_entity_first; ent; )
1451         {
1452             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1453             {
1454                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1455                 // skip it in linked list
1456                 if (prev)
1457                 {
1458                     prev.initialize_entity_next = ent.initialize_entity_next;
1459                     ent = prev.initialize_entity_next;
1460                 }
1461                 else
1462                 {
1463                     initialize_entity_first = ent.initialize_entity_next;
1464                     ent = initialize_entity_first;
1465                 }
1466             }
1467             else
1468             {
1469                 prev = ent;
1470                 ent = ent.initialize_entity_next;
1471             }
1472         }
1473     }
1474 }
1475
1476 void objerror(string s)
1477 {
1478     make_safe_for_remove(self);
1479     builtin_objerror(s);
1480 }
1481
1482 .float remove_except_protected_forbidden;
1483 void remove_except_protected(entity e)
1484 {
1485         if(e.remove_except_protected_forbidden)
1486                 error("not allowed to remove this at this point");
1487         builtin_remove(e);
1488 }
1489
1490 void remove_unsafely(entity e)
1491 {
1492     if(e.classname == "spike")
1493         error("Removing spikes is forbidden (crylink bug), please report");
1494     builtin_remove(e);
1495 }
1496
1497 void remove_safely(entity e)
1498 {
1499     make_safe_for_remove(e);
1500     builtin_remove(e);
1501 }
1502
1503 void InitializeEntity(entity e, void(void) func, float order)
1504 {
1505     entity prev, cur;
1506
1507     if (!e || e.initialize_entity)
1508     {
1509         // make a proxy initializer entity
1510         entity e_old;
1511         e_old = e;
1512         e = spawn();
1513         e.classname = "initialize_entity";
1514         e.enemy = e_old;
1515     }
1516
1517     e.initialize_entity = func;
1518     e.initialize_entity_order = order;
1519
1520     cur = initialize_entity_first;
1521     prev = world;
1522     for (;;)
1523     {
1524         if (!cur || cur.initialize_entity_order > order)
1525         {
1526             // insert between prev and cur
1527             if (prev)
1528                 prev.initialize_entity_next = e;
1529             else
1530                 initialize_entity_first = e;
1531             e.initialize_entity_next = cur;
1532             return;
1533         }
1534         prev = cur;
1535         cur = cur.initialize_entity_next;
1536     }
1537 }
1538 void InitializeEntitiesRun()
1539 {
1540     entity startoflist;
1541     startoflist = initialize_entity_first;
1542     initialize_entity_first = world;
1543     remove = remove_except_protected;
1544     for (self = startoflist; self; self = self.initialize_entity_next)
1545     {
1546         self.remove_except_protected_forbidden = 1;
1547     }
1548     for (self = startoflist; self; )
1549     {
1550         entity e;
1551         var void(void) func;
1552         e = self.initialize_entity_next;
1553         func = self.initialize_entity;
1554         self.initialize_entity_order = 0;
1555         self.initialize_entity = func_null;
1556         self.initialize_entity_next = world;
1557         self.remove_except_protected_forbidden = 0;
1558         if (self.classname == "initialize_entity")
1559         {
1560             entity e_old;
1561             e_old = self.enemy;
1562             builtin_remove(self);
1563             self = e_old;
1564         }
1565         //dprint("Delayed initialization: ", self.classname, "\n");
1566         if(func)
1567             func();
1568         else
1569         {
1570             eprint(self);
1571             backtrace(strcat("Null function in: ", self.classname, "\n"));
1572         }
1573         self = e;
1574     }
1575     remove = remove_unsafely;
1576 }
1577
1578 .float uncustomizeentityforclient_set;
1579 .void(void) uncustomizeentityforclient;
1580 void UncustomizeEntitiesRun()
1581 {
1582     entity oldself;
1583     oldself = self;
1584     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1585         self.uncustomizeentityforclient();
1586     self = oldself;
1587 }
1588 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1589 {
1590     e.customizeentityforclient = customizer;
1591     e.uncustomizeentityforclient = uncustomizer;
1592     e.uncustomizeentityforclient_set = !!uncustomizer;
1593 }
1594
1595 .float nottargeted;
1596 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1597
1598 void() SUB_Remove;
1599 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1600 {
1601     vector mi, ma;
1602
1603     if (e.classname == "")
1604         e.classname = "net_linked";
1605
1606     if (e.model == "" || self.modelindex == 0)
1607     {
1608         mi = e.mins;
1609         ma = e.maxs;
1610         setmodel(e, "null");
1611         setsize(e, mi, ma);
1612     }
1613
1614     e.SendEntity = sendfunc;
1615     e.SendFlags = 0xFFFFFF;
1616
1617     if (!docull)
1618         e.effects |= EF_NODEPTHTEST;
1619
1620     if (dt)
1621     {
1622         e.nextthink = time + dt;
1623         e.think = SUB_Remove;
1624     }
1625 }
1626
1627 void adaptor_think2touch()
1628 {
1629     entity o;
1630     o = other;
1631     other = world;
1632     self.touch();
1633     other = o;
1634 }
1635
1636 void adaptor_think2use()
1637 {
1638     entity o, a;
1639     o = other;
1640     a = activator;
1641     activator = world;
1642     other = world;
1643     self.use();
1644     other = o;
1645     activator = a;
1646 }
1647
1648 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1649 {
1650         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1651                 self.projectiledeathtype |= HITTYPE_SPLASH;
1652         adaptor_think2use();
1653 }
1654
1655 // deferred dropping
1656 void DropToFloor_Handler()
1657 {
1658     builtin_droptofloor();
1659     self.dropped_origin = self.origin;
1660 }
1661
1662 void droptofloor()
1663 {
1664     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1665 }
1666
1667
1668
1669 float trace_hits_box_a0, trace_hits_box_a1;
1670
1671 float trace_hits_box_1d(float end, float thmi, float thma)
1672 {
1673     if (end == 0)
1674     {
1675         // just check if x is in range
1676         if (0 < thmi)
1677             return FALSE;
1678         if (0 > thma)
1679             return FALSE;
1680     }
1681     else
1682     {
1683         // do the trace with respect to x
1684         // 0 -> end has to stay in thmi -> thma
1685         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1686         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1687         if (trace_hits_box_a0 > trace_hits_box_a1)
1688             return FALSE;
1689     }
1690     return TRUE;
1691 }
1692
1693 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1694 {
1695     end -= start;
1696     thmi -= start;
1697     thma -= start;
1698     // now it is a trace from 0 to end
1699
1700     trace_hits_box_a0 = 0;
1701     trace_hits_box_a1 = 1;
1702
1703     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1704         return FALSE;
1705     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1706         return FALSE;
1707     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1708         return FALSE;
1709
1710     return TRUE;
1711 }
1712
1713 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1714 {
1715     return trace_hits_box(start, end, thmi - ma, thma - mi);
1716 }
1717
1718 float SUB_NoImpactCheck()
1719 {
1720         // zero hitcontents = this is not the real impact, but either the
1721         // mirror-impact of something hitting the projectile instead of the
1722         // projectile hitting the something, or a touchareagrid one. Neither of
1723         // these stop the projectile from moving, so...
1724         if(trace_dphitcontents == 0)
1725         {
1726                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1727                 dprint(sprintf(_("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n"), num_for_edict(self), self.classname, vtos(self.origin)));
1728                 checkclient();
1729         }
1730     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1731         return 1;
1732     if (other == world && self.size != '0 0 0')
1733     {
1734         vector tic;
1735         tic = self.velocity * sys_frametime;
1736         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1737         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1738         if (trace_fraction >= 1)
1739         {
1740             dprint("Odd... did not hit...?\n");
1741         }
1742         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1743         {
1744             dprint("Detected and prevented the sky-grapple bug.\n");
1745             return 1;
1746         }
1747     }
1748
1749     return 0;
1750 }
1751
1752 #define SUB_OwnerCheck() (other && (other == self.owner))
1753
1754 void RemoveGrapplingHook(entity pl);
1755 void W_Crylink_Dequeue(entity e);
1756 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1757 {
1758         if(SUB_OwnerCheck())
1759                 return TRUE;
1760         if(SUB_NoImpactCheck())
1761         {
1762                 if(self.classname == "grapplinghook")
1763                         RemoveGrapplingHook(self.realowner);
1764                 else if(self.classname == "spike")
1765                 {
1766                         W_Crylink_Dequeue(self);
1767                         remove(self);
1768                 }
1769                 else
1770                         remove(self);
1771                 return TRUE;
1772         }
1773         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1774                 UpdateCSQCProjectile(self);
1775         return FALSE;
1776 }
1777 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1778
1779 #define ITEM_TOUCH_NEEDKILL() (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
1780 #define ITEM_DAMAGE_NEEDKILL(dt) (((dt) == DEATH_HURTTRIGGER) || ((dt) == DEATH_SLIME) || ((dt) == DEATH_LAVA) || ((dt) == DEATH_SWAMP))
1781
1782 void URI_Get_Callback(float id, float status, string data)
1783 {
1784         if(url_URI_Get_Callback(id, status, data))
1785         {
1786                 // handled
1787         }
1788         else if (id == URI_GET_DISCARD)
1789         {
1790                 // discard
1791         }
1792         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1793         {
1794                 // sv_cmd curl
1795                 Curl_URI_Get_Callback(id, status, data);
1796         }
1797         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1798         {
1799                 // online ban list
1800                 OnlineBanList_URI_Get_Callback(id, status, data);
1801         }
1802         else
1803         {
1804                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1805         }
1806 }
1807
1808 string uid2name(string myuid) {
1809         string s;
1810         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1811
1812         // FIXME remove this later after 0.6 release
1813         // convert old style broken records to correct style
1814         if(s == "")
1815         {
1816                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1817                 if(s != "")
1818                 {
1819                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1820                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1821                 }
1822         }
1823
1824         if(s == "")
1825                 s = "^1Unregistered Player";
1826         return s;
1827 }
1828
1829 float race_readTime(string map, float pos)
1830 {
1831         string rr;
1832         if(g_cts)
1833                 rr = CTS_RECORD;
1834         else
1835                 rr = RACE_RECORD;
1836
1837         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
1838 }
1839
1840 string race_readUID(string map, float pos)
1841 {
1842         string rr;
1843         if(g_cts)
1844                 rr = CTS_RECORD;
1845         else
1846                 rr = RACE_RECORD;
1847
1848         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
1849 }
1850
1851 float race_readPos(string map, float t) {
1852         float i;
1853         for (i = 1; i <= RANKINGS_CNT; ++i)
1854                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
1855                         return i;
1856
1857         return 0; // pos is zero if unranked
1858 }
1859
1860 void race_writeTime(string map, float t, string myuid)
1861 {
1862         string rr;
1863         if(g_cts)
1864                 rr = CTS_RECORD;
1865         else
1866                 rr = RACE_RECORD;
1867
1868         float newpos;
1869         newpos = race_readPos(map, t);
1870
1871         float i, prevpos = 0;
1872         for(i = 1; i <= RANKINGS_CNT; ++i)
1873         {
1874                 if(race_readUID(map, i) == myuid)
1875                         prevpos = i;
1876         }
1877         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
1878                 for (i = prevpos; i > newpos; --i) {
1879                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1880                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1881                 }
1882         } else { // player has no ranked record yet
1883                 for (i = RANKINGS_CNT; i > newpos; --i) {
1884                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1885                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1886                 }
1887         }
1888
1889         // store new time itself
1890         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
1891         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
1892 }
1893
1894 string race_readName(string map, float pos)
1895 {
1896         string rr;
1897         if(g_cts)
1898                 rr = CTS_RECORD;
1899         else
1900                 rr = RACE_RECORD;
1901
1902         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
1903 }
1904
1905 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1906 {
1907     float m, i;
1908     vector start, org, delta, end, enddown, mstart;
1909     entity sp;
1910
1911     m = e.dphitcontentsmask;
1912     e.dphitcontentsmask = goodcontents | badcontents;
1913
1914     org = world.mins;
1915     delta = world.maxs - world.mins;
1916
1917     start = end = org;
1918
1919     for (i = 0; i < attempts; ++i)
1920     {
1921         start_x = org_x + random() * delta_x;
1922         start_y = org_y + random() * delta_y;
1923         start_z = org_z + random() * delta_z;
1924
1925         // rule 1: start inside world bounds, and outside
1926         // solid, and don't start from somewhere where you can
1927         // fall down to evil
1928         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
1929         if (trace_fraction >= 1)
1930             continue;
1931         if (trace_startsolid)
1932             continue;
1933         if (trace_dphitcontents & badcontents)
1934             continue;
1935         if (trace_dphitq3surfaceflags & badsurfaceflags)
1936             continue;
1937
1938         // rule 2: if we are too high, lower the point
1939         if (trace_fraction * delta_z > maxaboveground)
1940             start = trace_endpos + '0 0 1' * maxaboveground;
1941         enddown = trace_endpos;
1942
1943         // rule 3: make sure we aren't outside the map. This only works
1944         // for somewhat well formed maps. A good rule of thumb is that
1945         // the map should have a convex outside hull.
1946         // these can be traceLINES as we already verified the starting box
1947         mstart = start + 0.5 * (e.mins + e.maxs);
1948         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
1949         if (trace_fraction >= 1)
1950             continue;
1951         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
1952         if (trace_fraction >= 1)
1953             continue;
1954         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
1955         if (trace_fraction >= 1)
1956             continue;
1957         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
1958         if (trace_fraction >= 1)
1959             continue;
1960         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
1961         if (trace_fraction >= 1)
1962             continue;
1963
1964         // rule 4: we must "see" some spawnpoint
1965         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
1966                 if(checkpvs(mstart, sp))
1967                         break;
1968         if(!sp)
1969         {
1970                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
1971                         if(checkpvs(mstart, sp))
1972                                 break;
1973                 if(!sp)
1974                         continue;
1975         }
1976
1977         // find a random vector to "look at"
1978         end_x = org_x + random() * delta_x;
1979         end_y = org_y + random() * delta_y;
1980         end_z = org_z + random() * delta_z;
1981         end = start + normalize(end - start) * vlen(delta);
1982
1983         // rule 4: start TO end must not be too short
1984         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1985         if (trace_startsolid)
1986             continue;
1987         if (trace_fraction < minviewdistance / vlen(delta))
1988             continue;
1989
1990         // rule 5: don't want to look at sky
1991         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1992             continue;
1993
1994         // rule 6: we must not end up in trigger_hurt
1995         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1996             continue;
1997
1998         break;
1999     }
2000
2001     e.dphitcontentsmask = m;
2002
2003     if (i < attempts)
2004     {
2005         setorigin(e, start);
2006         e.angles = vectoangles(end - start);
2007         dprint("Needed ", ftos(i + 1), " attempts\n");
2008         return TRUE;
2009     }
2010     else
2011         return FALSE;
2012 }
2013
2014 float zcurveparticles_effectno;
2015 vector zcurveparticles_start;
2016 float zcurveparticles_spd;
2017
2018 void endzcurveparticles()
2019 {
2020         if(zcurveparticles_effectno)
2021         {
2022                 // terminator
2023                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2024         }
2025         zcurveparticles_effectno = 0;
2026 }
2027
2028 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2029 {
2030         spd = bound(0, floor(spd / 16), 32767);
2031         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2032         {
2033                 endzcurveparticles();
2034                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2035                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2036                 WriteShort(MSG_BROADCAST, effectno);
2037                 WriteCoord(MSG_BROADCAST, start_x);
2038                 WriteCoord(MSG_BROADCAST, start_y);
2039                 WriteCoord(MSG_BROADCAST, start_z);
2040                 zcurveparticles_effectno = effectno;
2041                 zcurveparticles_start = start;
2042         }
2043         else
2044                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2045         WriteCoord(MSG_BROADCAST, end_x);
2046         WriteCoord(MSG_BROADCAST, end_y);
2047         WriteCoord(MSG_BROADCAST, end_z);
2048         WriteCoord(MSG_BROADCAST, end_dz);
2049         zcurveparticles_spd = spd;
2050 }
2051
2052 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2053 {
2054         float end_dz;
2055         vector vecxy, velxy;
2056
2057         vecxy = end - start;
2058         vecxy_z = 0;
2059         velxy = vel;
2060         velxy_z = 0;
2061
2062         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2063         {
2064                 endzcurveparticles();
2065                 trailparticles(world, effectno, start, end);
2066                 return;
2067         }
2068
2069         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2070         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2071 }
2072
2073 void write_recordmarker(entity pl, float tstart, float dt)
2074 {
2075     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2076
2077     // also write a marker into demo files for demotc-race-record-extractor to find
2078     stuffcmd(pl,
2079              strcat(
2080                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2081                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2082 }
2083
2084 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2085 {
2086         switch(algn)
2087         {
2088                 default:
2089                 case 3: // right
2090                         break;
2091
2092                 case 4: // left
2093                         vecs_y = -vecs_y;
2094                         break;
2095
2096                 case 1:
2097                         if(allowcenter) // 2: allow center handedness
2098                         {
2099                                 // center
2100                                 vecs_y = 0;
2101                                 vecs_z -= 2;
2102                         }
2103                         else
2104                         {
2105                                 // right
2106                         }
2107                         break;
2108
2109                 case 2:
2110                         if(allowcenter) // 2: allow center handedness
2111                         {
2112                                 // center
2113                                 vecs_y = 0;
2114                                 vecs_z -= 2;
2115                         }
2116                         else
2117                         {
2118                                 // left
2119                                 vecs_y = -vecs_y;
2120                         }
2121                         break;
2122         }
2123         return vecs;
2124 }
2125
2126 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2127 {
2128         string s;
2129         vector v;
2130
2131         if (autocvar_g_shootfromeye)
2132         {
2133                 if (visual)
2134                 {
2135                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
2136                         else { vecs_y = 0; vecs_z -= 2; }
2137                 }
2138                 else
2139                 {
2140                         vecs_y = 0;
2141                         vecs_z = 0;
2142                 }
2143         }
2144         else if (autocvar_g_shootfromcenter)
2145         {
2146                 vecs_y = 0;
2147                 vecs_z -= 2;
2148         }
2149         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2150         {
2151                 v = stov(s);
2152                 if (y_is_right)
2153                         v_y = -v_y;
2154                 if (v_x != 0)
2155                         vecs_x = v_x;
2156                 vecs_y = v_y;
2157                 vecs_z = v_z;
2158         }
2159         else if (autocvar_g_shootfromclient)
2160         {
2161                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2162         }
2163         return vecs;
2164 }
2165
2166 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2167 {
2168         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2169 }
2170
2171
2172 void attach_sameorigin(entity e, entity to, string tag)
2173 {
2174     vector org, t_forward, t_left, t_up, e_forward, e_up;
2175     float tagscale;
2176
2177     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2178     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2179     t_forward = v_forward * tagscale;
2180     t_left = v_right * -tagscale;
2181     t_up = v_up * tagscale;
2182
2183     e.origin_x = org * t_forward;
2184     e.origin_y = org * t_left;
2185     e.origin_z = org * t_up;
2186
2187     // current forward and up directions
2188     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2189                 e.angles = AnglesTransform_FromVAngles(e.angles);
2190         else
2191                 e.angles = AnglesTransform_FromAngles(e.angles);
2192     fixedmakevectors(e.angles);
2193
2194     // untransform forward, up!
2195     e_forward_x = v_forward * t_forward;
2196     e_forward_y = v_forward * t_left;
2197     e_forward_z = v_forward * t_up;
2198     e_up_x = v_up * t_forward;
2199     e_up_y = v_up * t_left;
2200     e_up_z = v_up * t_up;
2201
2202     e.angles = fixedvectoangles2(e_forward, e_up);
2203     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2204                 e.angles = AnglesTransform_ToVAngles(e.angles);
2205         else
2206                 e.angles = AnglesTransform_ToAngles(e.angles);
2207
2208     setattachment(e, to, tag);
2209     setorigin(e, e.origin);
2210 }
2211
2212 void detach_sameorigin(entity e)
2213 {
2214     vector org;
2215     org = gettaginfo(e, 0);
2216     e.angles = fixedvectoangles2(v_forward, v_up);
2217     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2218                 e.angles = AnglesTransform_ToVAngles(e.angles);
2219         else
2220                 e.angles = AnglesTransform_ToAngles(e.angles);
2221     setorigin(e, org);
2222     setattachment(e, world, "");
2223     setorigin(e, e.origin);
2224 }
2225
2226 void follow_sameorigin(entity e, entity to)
2227 {
2228     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2229     e.aiment = to; // make the hole follow bmodel
2230     e.punchangle = to.angles; // the original angles of bmodel
2231     e.view_ofs = e.origin - to.origin; // relative origin
2232     e.v_angle = e.angles - to.angles; // relative angles
2233 }
2234
2235 void unfollow_sameorigin(entity e)
2236 {
2237     e.movetype = MOVETYPE_NONE;
2238 }
2239
2240 entity gettaginfo_relative_ent;
2241 vector gettaginfo_relative(entity e, float tag)
2242 {
2243     if (!gettaginfo_relative_ent)
2244     {
2245         gettaginfo_relative_ent = spawn();
2246         gettaginfo_relative_ent.effects = EF_NODRAW;
2247     }
2248     gettaginfo_relative_ent.model = e.model;
2249     gettaginfo_relative_ent.modelindex = e.modelindex;
2250     gettaginfo_relative_ent.frame = e.frame;
2251     return gettaginfo(gettaginfo_relative_ent, tag);
2252 }
2253
2254 .float scale2;
2255
2256 float modeleffect_SendEntity(entity to, float sf)
2257 {
2258         float f;
2259         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2260
2261         f = 0;
2262         if(self.velocity != '0 0 0')
2263                 f |= 1;
2264         if(self.angles != '0 0 0')
2265                 f |= 2;
2266         if(self.avelocity != '0 0 0')
2267                 f |= 4;
2268
2269         WriteByte(MSG_ENTITY, f);
2270         WriteShort(MSG_ENTITY, self.modelindex);
2271         WriteByte(MSG_ENTITY, self.skin);
2272         WriteByte(MSG_ENTITY, self.frame);
2273         WriteCoord(MSG_ENTITY, self.origin_x);
2274         WriteCoord(MSG_ENTITY, self.origin_y);
2275         WriteCoord(MSG_ENTITY, self.origin_z);
2276         if(f & 1)
2277         {
2278                 WriteCoord(MSG_ENTITY, self.velocity_x);
2279                 WriteCoord(MSG_ENTITY, self.velocity_y);
2280                 WriteCoord(MSG_ENTITY, self.velocity_z);
2281         }
2282         if(f & 2)
2283         {
2284                 WriteCoord(MSG_ENTITY, self.angles_x);
2285                 WriteCoord(MSG_ENTITY, self.angles_y);
2286                 WriteCoord(MSG_ENTITY, self.angles_z);
2287         }
2288         if(f & 4)
2289         {
2290                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2291                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2292                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2293         }
2294         WriteShort(MSG_ENTITY, self.scale * 256.0);
2295         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2296         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2297         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2298         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2299
2300         return TRUE;
2301 }
2302
2303 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2304 {
2305         entity e;
2306         float sz;
2307         e = spawn();
2308         e.classname = "modeleffect";
2309         setmodel(e, m);
2310         e.frame = f;
2311         setorigin(e, o);
2312         e.velocity = v;
2313         e.angles = ang;
2314         e.avelocity = angv;
2315         e.alpha = a;
2316         e.teleport_time = t1;
2317         e.fade_time = t2;
2318         e.skin = s;
2319         if(s0 >= 0)
2320                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2321         else
2322                 e.scale = -s0;
2323         if(s2 >= 0)
2324                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2325         else
2326                 e.scale2 = -s2;
2327         sz = max(e.scale, e.scale2);
2328         setsize(e, e.mins * sz, e.maxs * sz);
2329         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2330 }
2331
2332 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2333 {
2334         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2335 }
2336
2337 float randombit(float bits)
2338 {
2339         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2340                 return bits;
2341
2342         float n, f, b, r;
2343
2344         r = random();
2345         b = 0;
2346         n = 0;
2347
2348         for(f = 1; f <= bits; f *= 2)
2349         {
2350                 if(bits & f)
2351                 {
2352                         ++n;
2353                         r *= n;
2354                         if(r <= 1)
2355                                 b = f;
2356                         else
2357                                 r = (r - 1) / (n - 1);
2358                 }
2359         }
2360
2361         return b;
2362 }
2363
2364 float randombits(float bits, float k, float error_return)
2365 {
2366         float r;
2367         r = 0;
2368         while(k > 0 && bits != r)
2369         {
2370                 r += randombit(bits - r);
2371                 --k;
2372         }
2373         if(error_return)
2374                 if(k > 0)
2375                         return -1; // all
2376         return r;
2377 }
2378
2379 void randombit_test(float bits, float iter)
2380 {
2381         while(iter > 0)
2382         {
2383                 print(ftos(randombit(bits)), "\n");
2384                 --iter;
2385         }
2386 }
2387
2388 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2389 {
2390         if(halflifedist > 0)
2391                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2392         else if(halflifedist < 0)
2393                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2394         else
2395                 return 1;
2396 }
2397
2398
2399
2400
2401 #ifdef RELEASE
2402 #define cvar_string_normal builtin_cvar_string
2403 #define cvar_normal builtin_cvar
2404 #else
2405 string cvar_string_normal(string n)
2406 {
2407         if not(cvar_type(n) & 1)
2408                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2409         return builtin_cvar_string(n);
2410 }
2411
2412 float cvar_normal(string n)
2413 {
2414         return stof(cvar_string_normal(n));
2415 }
2416 #endif
2417 #define cvar_set_normal builtin_cvar_set
2418
2419 void defer_think()
2420 {
2421     entity oself;
2422
2423     oself           = self;
2424     self            = self.owner;
2425     oself.think     = SUB_Remove;
2426     oself.nextthink = time;
2427
2428     oself.use();
2429 }
2430
2431 /*
2432     Execute func() after time + fdelay.
2433     self when func is executed = self when defer is called
2434 */
2435 void defer(float fdelay, void() func)
2436 {
2437     entity e;
2438
2439     e           = spawn();
2440     e.owner     = self;
2441     e.use       = func;
2442     e.think     = defer_think;
2443     e.nextthink = time + fdelay;
2444 }
2445
2446 .string aiment_classname;
2447 .float aiment_deadflag;
2448 void SetMovetypeFollow(entity ent, entity e)
2449 {
2450         // FIXME this may not be warpzone aware
2451         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2452         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2453         ent.aiment = e; // make the hole follow bmodel
2454         ent.punchangle = e.angles; // the original angles of bmodel
2455         ent.view_ofs = ent.origin - e.origin; // relative origin
2456         ent.v_angle = ent.angles - e.angles; // relative angles
2457         ent.aiment_classname = strzone(e.classname);
2458         ent.aiment_deadflag = e.deadflag;
2459 }
2460 void UnsetMovetypeFollow(entity ent)
2461 {
2462         ent.movetype = MOVETYPE_FLY;
2463         PROJECTILE_MAKETRIGGER(ent);
2464         ent.aiment = world;
2465 }
2466 float LostMovetypeFollow(entity ent)
2467 {
2468 /*
2469         if(ent.movetype != MOVETYPE_FOLLOW)
2470                 if(ent.aiment)
2471                         error("???");
2472 */
2473         if(ent.aiment)
2474         {
2475                 if(ent.aiment.classname != ent.aiment_classname)
2476                         return 1;
2477                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2478                         return 1;
2479         }
2480         return 0;
2481 }
2482
2483 float isPushable(entity e)
2484 {
2485         if(e.iscreature)
2486                 return TRUE;
2487         if(e.pushable)
2488                 return TRUE;
2489         switch(e.classname)
2490         {
2491                 case "body":
2492                 case "droppedweapon":
2493                 case "keepawayball":
2494                 case "nexball_basketball":
2495                 case "nexball_football":
2496                         return TRUE;
2497                 case "bullet": // antilagged bullets can't hit this either
2498                         return FALSE;
2499         }
2500         if (e.projectiledeathtype)
2501                 return TRUE;
2502         return FALSE;
2503 }