qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(clienttype(e) == CLIENTTYPE_REAL)
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetMapname();
  59 string GetGametype();
  60 void GotoNextMap(float reinit);
  61 void ShuffleMaplist();
  62 float(float reinit) DoNextMapOverride;
  63
  64 void SetDefaultAlpha()
  65 {
  66         if(autocvar_g_running_guns)
  67         {
  68                 default_player_alpha = -1;
  69                 default_weapon_alpha = +1;
  70         }
  71         else if(g_cloaked)
  72         {
  73                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  74                 default_weapon_alpha = default_player_alpha;
  75         }
  76         else
  77         {
  78                 default_player_alpha = autocvar_g_player_alpha;
  79                 if(default_player_alpha == 0)
  80                         default_player_alpha = 1;
  81                 default_weapon_alpha = default_player_alpha;
  82         }
  83 }
  84
  85 void fteqcc_testbugs()
  86 {
  87         float a, b;
  88
  89         if(!autocvar_developer_fteqccbugs)
  90                 return;
  91
  92         dprint("*** fteqcc test: checking for bugs...\n");
  93
  94         a = 1;
  95         b = 5;
  96         if(sqrt(a) - sqrt(b - a) == 0)
  97                 dprint("*** fteqcc test: found same-function-twice bug\n");
  98         else
  99                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
 100
 101         world.cnt = -10;
 102         world.enemy = world;
 103         world.enemy.cnt += 10;
 104         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 105                 dprint("*** fteqcc test: found += bug\n");
 106         else
 107                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 108         world.cnt = 0;
 109 }
 110
 111 void GotoFirstMap()
 112 {
 113         float n;
 114         if(autocvar__sv_init)
 115         {
 116                 // cvar_set("_sv_init", "0");
 117                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 118                 // to this "init" map on a dedicated server will cause no permanent
 119                 // harm
 120                 if(autocvar_g_maplist_shuffle)
 121                         ShuffleMaplist();
 122                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 123                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 124
 125                 MapInfo_Enumerate();
 126                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 127
 128                 if(!DoNextMapOverride(1))
 129                         GotoNextMap(1);
 130
 131                 return;
 132         }
 133
 134         if(time < 5)
 135         {
 136                 self.nextthink = time;
 137         }
 138         else
 139         {
 140                 self.nextthink = time + 1;
 141                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 142         }
 143 }
 144
 145 void cvar_changes_init()
 146 {
 147         float h;
 148         string k, v, d;
 149         float n, i, adding, pureadding;
 150
 151         if(cvar_changes)
 152                 strunzone(cvar_changes);
 153         cvar_changes = string_null;
 154         if(cvar_purechanges)
 155                 strunzone(cvar_purechanges);
 156         cvar_purechanges = string_null;
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = TRUE;
 164         pureadding = TRUE;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173
 174                 // general excludes and namespaces for server admin used cvars
 175                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 176
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215
 216                 // private
 217                 BADCVAR("developer");
 218                 BADCVAR("log_dest_udp");
 219                 BADCVAR("log_file");
 220                 BADCVAR("net_address");
 221                 BADCVAR("net_address_ipv6");
 222                 BADCVAR("port");
 223                 BADCVAR("savedgamecfg");
 224                 BADCVAR("serverconfig");
 225                 BADCVAR("sv_autoscreenshot");
 226                 BADCVAR("sv_heartbeatperiod");
 227                 BADCVAR("sv_vote_master_password");
 228                 BADCVAR("sys_colortranslation");
 229                 BADCVAR("sys_specialcharactertranslation");
 230                 BADCVAR("timeformat");
 231                 BADCVAR("timestamps");
 232                 BADPREFIX("developer_");
 233                 BADPREFIX("g_ban_");
 234                 BADPREFIX("g_banned_list");
 235                 BADPREFIX("g_chat_flood_");
 236                 BADPREFIX("g_ghost_items");
 237                 BADPREFIX("g_playerstats_");
 238                 BADPREFIX("g_respawn_ghosts");
 239                 BADPREFIX("g_voice_flood_");
 240                 BADPREFIX("rcon_");
 241                 BADPREFIX("sv_allowdownloads");
 242                 BADPREFIX("sv_autodemo");
 243                 BADPREFIX("sv_curl_");
 244                 BADPREFIX("sv_eventlog");
 245                 BADPREFIX("sv_logscores_");
 246                 BADPREFIX("sv_master");
 247                 BADPREFIX("sv_weaponstats_");
 248                 BADPREFIX("sv_waypointsprite_");
 249                 BADCVAR("rescan_pending");
 250
 251                 // these can contain player IDs, so better hide
 252                 BADPREFIX("g_forced_team_");
 253
 254                 // mapinfo
 255                 BADCVAR("fraglimit");
 256                 BADCVAR("g_arena");
 257                 BADCVAR("g_assault");
 258                 BADCVAR("g_ca");
 259                 BADCVAR("g_ctf");
 260                 BADCVAR("g_cts");
 261                 BADCVAR("g_dm");
 262                 BADCVAR("g_domination");
 263                 BADCVAR("g_domination_default_teams");
 264                 BADCVAR("g_freezetag");
 265                 BADCVAR("g_keepaway");
 266                 BADCVAR("g_keyhunt");
 267                 BADCVAR("g_keyhunt_teams");
 268                 BADCVAR("g_keyhunt_teams");
 269                 BADCVAR("g_lms");
 270                 BADCVAR("g_nexball");
 271                 BADCVAR("g_onslaught");
 272                 BADCVAR("g_race");
 273                 BADCVAR("g_race_qualifying_timelimit");
 274                 BADCVAR("g_runematch");
 275                 BADCVAR("g_tdm");
 276                 BADCVAR("g_tdm_teams");
 277                 BADCVAR("leadlimit");
 278                 BADCVAR("nextmap");
 279                 BADCVAR("teamplay");
 280                 BADCVAR("timelimit");
 281
 282                 // long
 283                 BADCVAR("hostname");
 284                 BADCVAR("g_maplist");
 285                 BADCVAR("g_maplist_mostrecent");
 286                 BADCVAR("sv_motd");
 287
 288                 v = cvar_string(k);
 289                 d = cvar_defstring(k);
 290                 if(v == d)
 291                         continue;
 292
 293                 if(adding)
 294                 {
 295                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 296                         if(strlen(cvar_changes) > 16384)
 297                         {
 298                                 cvar_changes = "// too many settings have been changed to show them here\n";
 299                                 adding = 0;
 300                         }
 301                 }
 302
 303                 // now check if the changes are actually gameplay relevant
 304
 305                 // does nothing visible
 306                 BADCVAR("captureleadlimit_override");
 307                 BADCVAR("g_arena_point_leadlimit");
 308                 BADCVAR("g_balance_kill_delay");
 309                 BADCVAR("g_ca_point_leadlimit");
 310                 BADCVAR("g_ctf_captimerecord_always");
 311                 BADCVAR("g_ctf_flag_glowtrails");
 312                 BADCVAR("g_ctf_flag_pickup_verbosename");
 313                 BADCVAR("g_domination_point_leadlimit");
 314                 BADCVAR("g_forced_respawn");
 315                 BADCVAR("g_keyhunt_point_leadlimit");
 316                 BADPREFIX("g_mod_");
 317                 BADCVAR("g_nexball_goalleadlimit");
 318                 BADCVAR("g_runematch_point_leadlimit");
 319                 BADCVAR("leadlimit_and_fraglimit");
 320                 BADCVAR("leadlimit_override");
 321                 BADCVAR("pausable");
 322                 BADCVAR("sv_allow_fullbright");
 323                 BADCVAR("sv_checkforpacketsduringsleep");
 324                 BADCVAR("sv_fraginfo");
 325                 BADCVAR("sv_timeout");
 326                 BADPREFIX("sv_timeout_");
 327                 BADCVAR("welcome_message_time");
 328                 BADPREFIX("crypto_");
 329                 BADPREFIX("g_chat_");
 330                 BADPREFIX("g_ctf_captimerecord_");
 331                 BADPREFIX("g_maplist_votable_");
 332                 BADPREFIX("net_");
 333                 BADPREFIX("prvm_");
 334                 BADPREFIX("skill_");
 335                 BADPREFIX("sv_cullentities_");
 336                 BADPREFIX("sv_fraginfo_");
 337                 BADPREFIX("sv_maxidle_");
 338                 BADPREFIX("sv_vote_");
 339                 BADPREFIX("timelimit_");
 340                 BADCVAR("gameversion");
 341                 BADPREFIX("gameversion_");
 342                 BADCVAR("sv_namechangetimer");
 343
 344                 // allowed changes to server admins (please sync this to server.cfg)
 345                 // vi commands:
 346                 //   :/"impure"/,$d
 347                 //   :g!,^\/\/[^ /],d
 348                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 349                 //   :%!sort
 350                 // yes, this does contain some redundant stuff, don't really care
 351                 BADCVAR("bot_config_file");
 352                 BADCVAR("bot_number");
 353                 BADCVAR("bot_prefix");
 354                 BADCVAR("bot_suffix");
 355                 BADCVAR("capturelimit_override");
 356                 BADCVAR("fraglimit_override");
 357                 BADCVAR("gametype");
 358                 BADCVAR("g_antilag");
 359                 BADCVAR("g_balance_teams");
 360                 BADCVAR("g_balance_teams_prevent_imbalance");
 361                 BADCVAR("g_balance_teams_scorefactor");
 362                 BADCVAR("g_ban_sync_trusted_servers");
 363                 BADCVAR("g_ban_sync_uri");
 364                 BADCVAR("g_ctf_ignore_frags");
 365                 BADCVAR("g_domination_point_limit");
 366                 BADCVAR("g_friendlyfire");
 367                 BADCVAR("g_fullbrightitems");
 368                 BADCVAR("g_fullbrightplayers");
 369                 BADCVAR("g_keyhunt_point_limit");
 370                 BADCVAR("g_keyhunt_teams_override");
 371                 BADCVAR("g_lms_lives_override");
 372                 BADCVAR("g_maplist");
 373                 BADCVAR("g_maplist_check_waypoints");
 374                 BADCVAR("g_maplist_mostrecent_count");
 375                 BADCVAR("g_maplist_shuffle");
 376                 BADCVAR("g_maplist_votable");
 377                 BADCVAR("g_maplist_votable_abstain");
 378                 BADCVAR("g_maplist_votable_nodetail");
 379                 BADCVAR("g_maplist_votable_suggestions");
 380                 BADCVAR("g_maxplayers");
 381                 BADCVAR("g_mirrordamage");
 382                 BADCVAR("g_nexball_goallimit");
 383                 BADCVAR("g_powerups");
 384                 BADCVAR("g_runematch_point_limit");
 385                 BADCVAR("g_start_delay");
 386                 BADCVAR("g_warmup");
 387                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 388                 BADCVAR("hostname");
 389                 BADCVAR("log_file");
 390                 BADCVAR("maxplayers");
 391                 BADCVAR("minplayers");
 392                 BADCVAR("net_address");
 393                 BADCVAR("port");
 394                 BADCVAR("rcon_password");
 395                 BADCVAR("rcon_restricted_commands");
 396                 BADCVAR("rcon_restricted_password");
 397                 BADCVAR("skill");
 398                 BADCVAR("sv_adminnick");
 399                 BADCVAR("sv_autoscreenshot");
 400                 BADCVAR("sv_autotaunt");
 401                 BADCVAR("sv_curl_defaulturl");
 402                 BADCVAR("sv_defaultcharacter");
 403                 BADCVAR("sv_defaultplayercolors");
 404                 BADCVAR("sv_defaultplayermodel");
 405                 BADCVAR("sv_defaultplayerskin");
 406                 BADCVAR("sv_maxidle");
 407                 BADCVAR("sv_maxrate");
 408                 BADCVAR("sv_motd");
 409                 BADCVAR("sv_public");
 410                 BADCVAR("sv_ready_restart");
 411                 BADCVAR("sv_status_privacy");
 412                 BADCVAR("sv_taunt");
 413                 BADCVAR("sv_vote_call");
 414                 BADCVAR("sv_vote_commands");
 415                 BADCVAR("sv_vote_majority_factor");
 416                 BADCVAR("sv_vote_master");
 417                 BADCVAR("sv_vote_master_commands");
 418                 BADCVAR("sv_vote_master_password");
 419                 BADCVAR("sv_vote_simple_majority_factor");
 420                 BADCVAR("sys_ticrate");
 421                 BADCVAR("teamplay_mode");
 422                 BADCVAR("timelimit_override");
 423                 BADCVAR("g_spawnshieldtime");
 424                 BADPREFIX("g_warmup_");
 425                 BADPREFIX("sv_ready_restart_");
 426
 427                 // mutators that announce themselves properly to the server browser
 428                 BADCVAR("g_minstagib");
 429                 BADCVAR("g_new_toys");
 430                 BADCVAR("g_nix");
 431
 432                 if(autocvar_g_minstagib)
 433                 {
 434                         BADCVAR("g_grappling_hook");
 435                         BADCVAR("g_jetpack");
 436                 }
 437 #undef BADPREFIX
 438 #undef BADCVAR
 439
 440                 if(pureadding)
 441                 {
 442                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 443                         if(strlen(cvar_purechanges) > 16384)
 444                         {
 445                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 446                                 pureadding = 0;
 447                         }
 448                 }
 449                 ++cvar_purechanges_count;
 450                 // WARNING: this variable is used for the server list
 451                 // NEVER dare to skip this code!
 452                 // Hacks to intentionally appearing as "pure server" even though you DO have
 453                 // modified settings may be punished by removal from the server list.
 454                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 455                 // though.
 456         }
 457         buf_del(h);
 458         if(cvar_changes == "")
 459                 cvar_changes = "// this server runs at default server settings\n";
 460         else
 461                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 462         cvar_changes = strzone(cvar_changes);
 463         if(cvar_purechanges == "")
 464                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 465         else
 466                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 467         cvar_purechanges = strzone(cvar_purechanges);
 468 }
 469
 470 void detect_maptype()
 471 {
 472 #if 0
 473         vector o, v;
 474         float i;
 475
 476         for(;;)
 477         {
 478                 o = world.mins;
 479                 o_x += random() * (world.maxs_x - world.mins_x);
 480                 o_y += random() * (world.maxs_y - world.mins_y);
 481                 o_z += random() * (world.maxs_z - world.mins_z);
 482
 483                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 484                 if(trace_fraction == 1)
 485                         continue;
 486
 487                 v = trace_endpos;
 488
 489                 for(i = 0; i < 64; i += 4)
 490                 {
 491                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 492         if(trace_fraction == 1)
 493                 continue;
 494                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 495                 }
 496
 497                 break;
 498         }
 499 #endif
 500 }
 501
 502 entity randomseed;
 503 float RandomSeed_Send(entity to, float sf)
 504 {
 505         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 506         WriteShort(MSG_ENTITY, self.cnt);
 507         return TRUE;
 508 }
 509 void RandomSeed_Think()
 510 {
 511         self.cnt = bound(0, floor(random() * 65536), 65535);
 512         self.nextthink = time + 5;
 513
 514         self.SendFlags |= 1;
 515 }
 516 void RandomSeed_Spawn()
 517 {
 518         randomseed = spawn();
 519         randomseed.think = RandomSeed_Think;
 520         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 521
 522         entity oldself;
 523         oldself = self;
 524         self = randomseed;
 525         self.think(); // sets random seed and nextthink
 526         self = oldself;
 527 }
 528
 529 void spawnfunc___init_dedicated_server(void)
 530 {
 531         // handler for _init/_init map (only for dedicated server initialization)
 532
 533         world_initialized = -1; // don't complain
 534         cvar = cvar_normal;
 535         cvar_string = cvar_string_normal;
 536         cvar_set = cvar_set_normal;
 537
 538         remove = remove_unsafely;
 539
 540         entity e;
 541         e = spawn();
 542         e.think = GotoFirstMap;
 543         e.nextthink = time; // this is usually 1 at this point
 544
 545         e = spawn();
 546         e.classname = "info_player_deathmatch"; // safeguard against player joining
 547
 548         self.classname = "worldspawn"; // safeguard against various stuff ;)
 549
 550         // needs to be done so early because of the constants they create
 551         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 552         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 553
 554         MapInfo_Enumerate();
 555         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 556 }
 557
 558 void Map_MarkAsRecent(string m);
 559 float world_already_spawned;
 560 void Nagger_Init();
 561 void ClientInit_Spawn();
 562 void WeaponStats_Init();
 563 void WeaponStats_Shutdown();
 564 void spawnfunc_worldspawn (void)
 565 {
 566         float fd, l, i, j, n;
 567         string s, col;
 568
 569         cvar = cvar_normal;
 570         cvar_string = cvar_string_normal;
 571         cvar_set = cvar_set_normal;
 572
 573         if(world_already_spawned)
 574                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 575         world_already_spawned = TRUE;
 576
 577         remove = remove_safely; // during spawning, watch what you remove!
 578
 579         check_unacceptable_compiler_bugs();
 580
 581         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 582
 583         compressShortVector_init();
 584
 585         allowed_to_spawn = TRUE;
 586
 587         entity head;
 588         head = nextent(world);
 589         maxclients = 0;
 590         while(head)
 591         {
 592                 ++maxclients;
 593                 head = nextent(head);
 594         }
 595
 596         // needs to be done so early because of the constants they create
 597         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 598         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 599
 600         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 601
 602         TemporaryDB = db_create();
 603
 604         // 0 normal
 605         lightstyle(0, "m");
 606
 607         // 1 FLICKER (first variety)
 608         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 609
 610         // 2 SLOW STRONG PULSE
 611         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 612
 613         // 3 CANDLE (first variety)
 614         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 615
 616         // 4 FAST STROBE
 617         lightstyle(4, "mamamamamama");
 618
 619         // 5 GENTLE PULSE 1
 620         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 621
 622         // 6 FLICKER (second variety)
 623         lightstyle(6, "nmonqnmomnmomomno");
 624
 625         // 7 CANDLE (second variety)
 626         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 627
 628         // 8 CANDLE (third variety)
 629         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 630
 631         // 9 SLOW STROBE (fourth variety)
 632         lightstyle(9, "aaaaaaaazzzzzzzz");
 633
 634         // 10 FLUORESCENT FLICKER
 635         lightstyle(10, "mmamammmmammamamaaamammma");
 636
 637         // 11 SLOW PULSE NOT FADE TO BLACK
 638         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 639
 640         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 641
 642         // 63 testing
 643         lightstyle(63, "a");
 644
 645         if(autocvar_g_campaign)
 646                 CampaignPreInit();
 647
 648         Map_MarkAsRecent(mapname);
 649
 650         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 651
 652         precache_model ("null"); // we need this one before InitGameplayMode
 653         InitGameplayMode();
 654         readlevelcvars();
 655         GrappleHookInit();
 656         ElectroInit();
 657         LaserInit();
 658
 659         player_count = 0;
 660         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 661         if(bot_waypoints_for_items == 1)
 662                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 663                         bot_waypoints_for_items = 0;
 664
 665         precache();
 666
 667         WaypointSprite_Init();
 668
 669         GameLogInit(); // prepare everything
 670         // NOTE for matchid:
 671         // changing the logic generating it is okay. But:
 672         // it HAS to stay <= 64 chars
 673         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 674         if(autocvar_sv_eventlog)
 675         {
 676                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 677                 matchid = strzone(s);
 678
 679                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 680                 s = ":gameinfo:mutators:LIST";
 681
 682                 ret_string = s;
 683                 MUTATOR_CALLHOOK(BuildMutatorsString);
 684                 s = ret_string;
 685
 686                 // simple, probably not good in the mutator system
 687                 if(autocvar_g_grappling_hook)
 688                         s = strcat(s, ":grappling_hook");
 689
 690                 // initialiation stuff, not good in the mutator system
 691                 if(!autocvar_g_use_ammunition)
 692                         s = strcat(s, ":no_use_ammunition");
 693
 694                 // initialiation stuff, not good in the mutator system
 695                 if(autocvar_g_pickup_items == 0)
 696                         s = strcat(s, ":no_pickup_items");
 697                 if(autocvar_g_pickup_items > 0)
 698                         s = strcat(s, ":pickup_items");
 699
 700                 // initialiation stuff, not good in the mutator system
 701                 if(autocvar_g_weaponarena != "0")
 702                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 703
 704                 // TODO to mutator system
 705                 if(autocvar_g_norecoil)
 706                         s = strcat(s, ":norecoil");
 707
 708                 // TODO to mutator system
 709                 if(autocvar_g_midair)
 710                         s = strcat(s, ":midair");
 711
 712                 // TODO to mutator system
 713                 if(autocvar_g_minstagib)
 714                         s = strcat(s, ":minstagib");
 715
 716                 // TODO to mutator system
 717                 if(autocvar_g_powerups == 0)
 718                         s = strcat(s, ":no_powerups");
 719                 if(autocvar_g_powerups > 0)
 720                         s = strcat(s, ":powerups");
 721
 722                 GameLogEcho(s);
 723                 GameLogEcho(":gameinfo:end");
 724         }
 725         else
 726                 matchid = strzone(ftos(random()));
 727
 728         cvar_set("nextmap", "");
 729
 730         SetDefaultAlpha();
 731
 732         if(autocvar_g_campaign)
 733                 CampaignPostInit();
 734
 735         fteqcc_testbugs();
 736
 737         Ban_LoadBans();
 738
 739         MapInfo_Enumerate();
 740         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 741
 742         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 743         {
 744                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 745                 if(fd != -1)
 746                 {
 747                         while((s = fgets(fd)))
 748                         {
 749                                 l = tokenize_console(s);
 750                                 if(l < 2)
 751                                         continue;
 752                                 if(argv(0) == "cd")
 753                                 {
 754                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 755                                         print("  cdtrack ", argv(2), "\n");
 756                                 }
 757                                 else if(argv(0) == "fog")
 758                                 {
 759                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 760                                         print("  \"fog\" \"", s, "\"\n");
 761                                 }
 762                                 else if(argv(0) == "set")
 763                                 {
 764                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 765                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 766                                 }
 767                                 else if(argv(0) != "//")
 768                                 {
 769                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 770                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 771                                 }
 772                         }
 773                         fclose(fd);
 774                 }
 775         }
 776
 777         WeaponStats_Init();
 778
 779         WEPSET_ADDSTAT();
 780         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 781         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 782         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 783         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 784         Nagger_Init();
 785
 786         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 787         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 788         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 789         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 790         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 791         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 792         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 793         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 794         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 795         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 796         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 797         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 798         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 799
 800         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 801         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 802
 803         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 804
 805         if(g_ca || g_freezetag)
 806         {
 807                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 808                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 809                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 810                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 811         }
 812         if(g_freezetag)
 813         {
 814                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 815                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 816         }
 817
 818         // g_movementspeed hack
 819         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 820         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 821         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 822         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 823
 824         // secrets
 825         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 826         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 827
 828         // misc
 829         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 830
 831         next_pingtime = time + 5;
 832
 833         detect_maptype();
 834
 835         // set up information replies for clients and server to use
 836         lsmaps_reply = "^7Maps available: ";
 837         lsnewmaps_reply = "^7Maps without a record set: ";
 838         for(i = 0, j = 0; i < MapInfo_count; ++i)
 839         {
 840                 if(MapInfo_Get_ByID(i))
 841                         if not(MapInfo_Map_flags & MapInfo_ForbiddenFlags())
 842                         {
 843                                 if(mod(i, 2))
 844                                         col = "^2";
 845                                 else
 846                                         col = "^3";
 847
 848                                 ++j;
 849
 850                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 851
 852                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 853                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 854                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 855                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 856                         }
 857         }
 858
 859         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 860         lsnewmaps_reply = strzone(strcat(((!g_race && !g_cts) ? "Need to be playing race or CTS for lsnewmaps to work." : lsnewmaps_reply), "\n"));
 861
 862         maplist_reply = "^7Maps in list: ";
 863         n = tokenize_console(autocvar_g_maplist);
 864         for(i = 0, j = 0; i < n; ++i)
 865         {
 866                 if(MapInfo_CheckMap(argv(i)))
 867                 {
 868                         if(mod(j, 2))
 869                                 col = "^2";
 870                         else
 871                                 col = "^3";
 872                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 873                         ++j;
 874                 }
 875         }
 876         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 877         MapInfo_ClearTemps();
 878
 879         for(i = 0; i < 10; ++i)
 880         {
 881                 s = getrecords(i);
 882                 if (s)
 883                         records_reply[i] = strzone(s);
 884         }
 885
 886         ladder_reply = strzone(getladder());
 887
 888         rankings_reply = strzone(getrankings());
 889
 890         // begin other init
 891         ClientInit_Spawn();
 892         RandomSeed_Spawn();
 893         PingPLReport_Spawn();
 894
 895         CheatInit();
 896
 897         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 898
 899         // fill sv_curl_serverpackages from .serverpackage files
 900         if(autocvar_sv_curl_serverpackages_auto)
 901         {
 902                 s = "";
 903                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 904                 for(i = 0; i < n; ++i)
 905                         if(substring(argv(i), -14, -1) != "-serverpackage.txt")
 906                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 907                                 s = strcat(s, " ", argv(i));
 908                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 909                 if(fd >= 0)
 910                 {
 911                         j = search_getsize(fd);
 912                         for(i = 0; i < j; ++i)
 913                                 s = strcat(s, " ", search_getfilename(fd, i));
 914                         search_end(fd);
 915                 }
 916                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 917                 if(fd >= 0)
 918                 {
 919                         j = search_getsize(fd);
 920                         for(i = 0; i < j; ++i)
 921                                 s = strcat(s, " ", search_getfilename(fd, i));
 922                         search_end(fd);
 923                 }
 924                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 925         }
 926
 927         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 928         modname = "Xonotic";
 929         // physics/balance/config changes that count as mod
 930         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 931                 modname = cvar_string("g_mod_physics");
 932         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 933                 modname = cvar_string("g_mod_balance");
 934         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 935                 modname = cvar_string("g_mod_config");
 936         // weird mutators that deserve to count as mod
 937         if(autocvar_g_minstagib)
 938                 modname = "MinstaGib";
 939         // extra mutators that deserve to count as mod
 940         MUTATOR_CALLHOOK(SetModname);
 941
 942         // save it for later
 943         modname = strzone(modname);
 944
 945         WinningConditionHelper(); // set worldstatus
 946
 947         world_initialized = 1;
 948 }
 949
 950 void spawnfunc_light (void)
 951 {
 952         //makestatic (self); // Who the f___ did that?
 953         remove(self);
 954 }
 955
 956 string GetGametype()
 957 {
 958         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 959 }
 960
 961 string getmapname_stored;
 962 string GetMapname()
 963 {
 964         return mapname;
 965 }
 966
 967 float Map_Count, Map_Current;
 968 string Map_Current_Name;
 969
 970 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 971 float GetMaplistPosition()
 972 {
 973         float pos, idx;
 974         string map;
 975
 976         map = GetMapname();
 977         idx = autocvar_g_maplist_index;
 978
 979         if(idx >= 0)
 980                 if(idx < Map_Count)
 981                         if(map == argv(idx))
 982                                 return idx;
 983
 984         for(pos = 0; pos < Map_Count; ++pos)
 985                 if(map == argv(pos))
 986                         return pos;
 987
 988         // resume normal maplist rotation if current map is not in g_maplist
 989         return idx;
 990 }
 991
 992 float MapHasRightSize(string map)
 993 {
 994         float fh;
 995         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 996         if(autocvar_g_maplist_check_waypoints)
 997         {
 998                 dprint("checkwp "); dprint(map);
 999                 if(!fexists(strcat("maps/", map, ".waypoints")))
1000                 {
1001                         dprint(": no waypoints\n");
1002                         return FALSE;
1003                 }
1004                 dprint(": has waypoints\n");
1005         }
1006
1007         // open map size restriction file
1008         dprint("opensize "); dprint(map);
1009         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1010         if(fh >= 0)
1011         {
1012                 float mapmin, mapmax;
1013                 dprint(": ok, ");
1014                 mapmin = stof(fgets(fh));
1015                 mapmax = stof(fgets(fh));
1016                 fclose(fh);
1017                 if(player_count < mapmin)
1018                 {
1019                         dprint("not enough\n");
1020                         return FALSE;
1021                 }
1022                 if(player_count > mapmax)
1023                 {
1024                         dprint("too many\n");
1025                         return FALSE;
1026                 }
1027                 dprint("right size\n");
1028                 return TRUE;
1029         }
1030         dprint(": not found\n");
1031         return TRUE;
1032 }
1033
1034 string Map_Filename(float position)
1035 {
1036         return strcat("maps/", argv(position), ".bsp");
1037 }
1038
1039 string strwords(string s, float w)
1040 {
1041         float endpos;
1042         for(endpos = 0; w && endpos >= 0; --w)
1043                 endpos = strstrofs(s, " ", endpos + 1);
1044         if(endpos < 0)
1045                 return s;
1046         else
1047                 return substring(s, 0, endpos);
1048 }
1049
1050 float strhasword(string s, string w)
1051 {
1052         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1053 }
1054
1055 void Map_MarkAsRecent(string m)
1056 {
1057         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1058 }
1059
1060 float Map_IsRecent(string m)
1061 {
1062         return strhasword(autocvar_g_maplist_mostrecent, m);
1063 }
1064
1065 float Map_Check(float position, float pass)
1066 {
1067         string filename;
1068         string map_next;
1069         map_next = argv(position);
1070         if(pass <= 1)
1071         {
1072                 if(Map_IsRecent(map_next))
1073                         return 0;
1074         }
1075         filename = Map_Filename(position);
1076         if(MapInfo_CheckMap(map_next))
1077         {
1078                 if(pass == 2)
1079                         return 1;
1080                 if(MapHasRightSize(map_next))
1081                         return 1;
1082                 return 0;
1083         }
1084         else
1085                 dprint( "Couldn't select '", filename, "'..\n" );
1086
1087         return 0;
1088 }
1089
1090 void Map_Goto_SetStr(string nextmapname)
1091 {
1092         if(getmapname_stored != "")
1093                 strunzone(getmapname_stored);
1094         if(nextmapname == "")
1095                 getmapname_stored = "";
1096         else
1097                 getmapname_stored = strzone(nextmapname);
1098 }
1099
1100 void Map_Goto_SetFloat(float position)
1101 {
1102         cvar_set("g_maplist_index", ftos(position));
1103         Map_Goto_SetStr(argv(position));
1104 }
1105
1106 void Map_Goto(float reinit)
1107 {
1108         MapInfo_LoadMap(getmapname_stored, reinit);
1109 }
1110
1111 // return codes of map selectors:
1112 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1113 //   -2 = permanent failure
1114 float() MaplistMethod_Iterate = // usual method
1115 {
1116         float pass, i;
1117
1118         for(pass = 1; pass <= 2; ++pass)
1119         {
1120                 for(i = 1; i < Map_Count; ++i)
1121                 {
1122                         float mapindex;
1123                         mapindex = mod(i + Map_Current, Map_Count);
1124                         if(Map_Check(mapindex, pass))
1125                                 return mapindex;
1126                 }
1127         }
1128         return -1;
1129 }
1130
1131 float() MaplistMethod_Repeat = // fallback method
1132 {
1133         if(Map_Check(Map_Current, 2))
1134                 return Map_Current;
1135         return -2;
1136 }
1137
1138 float() MaplistMethod_Random = // random map selection
1139 {
1140         float i, imax;
1141
1142         imax = 42;
1143
1144         for(i = 0; i <= imax; ++i)
1145         {
1146                 float mapindex;
1147                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1148                 if(Map_Check(mapindex, 1))
1149                         return mapindex;
1150         }
1151         return -1;
1152 }
1153
1154 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1155 // the exponent sets a bias on the map selection:
1156 // the higher the exponent, the less likely "shortly repeated" same maps are
1157 {
1158         float i, j, imax, insertpos;
1159
1160         imax = 42;
1161
1162         for(i = 0; i <= imax; ++i)
1163         {
1164                 string newlist;
1165
1166                 // now reinsert this at another position
1167                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1168                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1169                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1170                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1171
1172                 // insert the current map there
1173                 newlist = "";
1174                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1175                         newlist = strcat(newlist, " ", argv(j));
1176                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1177                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1178                         newlist = strcat(newlist, " ", argv(j));
1179                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1180                 cvar_set("g_maplist", newlist);
1181                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1182
1183                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1184                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1185                 if(Map_Check(Map_Current, 1))
1186                         return Map_Current;
1187         }
1188         return -1;
1189 }
1190
1191 void Maplist_Init()
1192 {
1193         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1194         if(Map_Count == 0)
1195         {
1196                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1197                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1198                 if(autocvar_g_maplist_shuffle)
1199                         ShuffleMaplist();
1200                 localcmd("\nmenu_cmd sync\n");
1201                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1202         }
1203         if(Map_Count == 0)
1204                 error("empty maplist, cannot select a new map");
1205         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1206
1207         if(Map_Current_Name)
1208                 strunzone(Map_Current_Name);
1209         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1210         // this may or may not be correct, but who cares, in the worst case a map
1211         // isn't chosen in the first pass that should have been
1212 }
1213
1214 string GetNextMap()
1215 {
1216         float nextMap;
1217
1218         Maplist_Init();
1219         nextMap = -1;
1220
1221         if(nextMap == -1)
1222                 if(autocvar_g_maplist_shuffle > 0)
1223                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1224
1225         if(nextMap == -1)
1226                 if(autocvar_g_maplist_selectrandom)
1227                         nextMap = MaplistMethod_Random();
1228
1229         if(nextMap == -1)
1230                 nextMap = MaplistMethod_Iterate();
1231
1232         if(nextMap == -1)
1233                 nextMap = MaplistMethod_Repeat();
1234
1235         if(nextMap >= 0)
1236         {
1237                 Map_Goto_SetFloat(nextMap);
1238                 return getmapname_stored;
1239         }
1240
1241         return "";
1242 }
1243
1244 float DoNextMapOverride(float reinit)
1245 {
1246         if(autocvar_g_campaign)
1247         {
1248                 CampaignPostIntermission();
1249                 alreadychangedlevel = TRUE;
1250                 return TRUE;
1251         }
1252         if(autocvar_quit_when_empty)
1253         {
1254                 if(player_count <= currentbots)
1255                 {
1256                         localcmd("quit\n");
1257                         alreadychangedlevel = TRUE;
1258                         return TRUE;
1259                 }
1260         }
1261         if(autocvar_quit_and_redirect != "")
1262         {
1263                 redirection_target = strzone(autocvar_quit_and_redirect);
1264                 alreadychangedlevel = TRUE;
1265                 return TRUE;
1266         }
1267         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1268         {
1269                 localcmd("restart\n");
1270                 alreadychangedlevel = TRUE;
1271                 return TRUE;
1272         }
1273         if(autocvar_nextmap != "")
1274                 if(MapInfo_CheckMap(autocvar_nextmap))
1275                 {
1276                         Map_Goto_SetStr(autocvar_nextmap);
1277                         Map_Goto(reinit);
1278                         alreadychangedlevel = TRUE;
1279                         return TRUE;
1280                 }
1281         if(!reinit && autocvar_lastlevel)
1282         {
1283                 cvar_settemp_restore();
1284                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1285                 alreadychangedlevel = TRUE;
1286                 return TRUE;
1287         }
1288         return FALSE;
1289 }
1290
1291 void GotoNextMap(float reinit)
1292 {
1293         //string nextmap;
1294         //float n, nummaps;
1295         //string s;
1296         if (alreadychangedlevel)
1297                 return;
1298         alreadychangedlevel = TRUE;
1299
1300         {
1301                 string nextMap;
1302                 float allowReset;
1303
1304                 for(allowReset = 1; allowReset >= 0; --allowReset)
1305                 {
1306                         nextMap = GetNextMap();
1307                         if(nextMap != "")
1308                                 break;
1309
1310                         if(allowReset)
1311                         {
1312                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1313                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1314                                 if(autocvar_g_maplist_shuffle)
1315                                         ShuffleMaplist();
1316                                 localcmd("\nmenu_cmd sync\n");
1317                         }
1318                         else
1319                         {
1320                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1321                         }
1322                 }
1323                 Map_Goto(reinit);
1324         }
1325 }
1326
1327
1328 /*
1329 ============
1330 IntermissionThink
1331
1332 When the player presses attack or jump, change to the next level
1333 ============
1334 */
1335 .float autoscreenshot;
1336 void() MapVote_Start;
1337 void() MapVote_Think;
1338 float mapvote_initialized;
1339 void IntermissionThink()
1340 {
1341         FixIntermissionClient(self);
1342
1343         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1344         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1345
1346         if( (server_screenshot || client_screenshot)
1347                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1348         {
1349                 self.autoscreenshot = -1;
1350                 if(clienttype(self) == CLIENTTYPE_REAL) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"", GetMapname(), strftime(FALSE, "%s"))); }
1351                 return;
1352         }
1353
1354         if (time < intermission_exittime)
1355                 return;
1356
1357         if(!mapvote_initialized)
1358                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1359                         return;
1360
1361         MapVote_Start();
1362 }
1363
1364 /*
1365 ============
1366 FindIntermission
1367
1368 Returns the entity to view from
1369 ============
1370 */
1371 /*
1372 entity FindIntermission()
1373 {
1374         local   entity spot;
1375         local   float cyc;
1376
1377 // look for info_intermission first
1378         spot = find (world, classname, "info_intermission");
1379         if (spot)
1380         {       // pick a random one
1381                 cyc = random() * 4;
1382                 while (cyc > 1)
1383                 {
1384                         spot = find (spot, classname, "info_intermission");
1385                         if (!spot)
1386                                 spot = find (spot, classname, "info_intermission");
1387                         cyc = cyc - 1;
1388                 }
1389                 return spot;
1390         }
1391
1392 // then look for the start position
1393         spot = find (world, classname, "info_player_start");
1394         if (spot)
1395                 return spot;
1396
1397 // testinfo_player_start is only found in regioned levels
1398         spot = find (world, classname, "testplayerstart");
1399         if (spot)
1400                 return spot;
1401
1402 // then look for the start position
1403         spot = find (world, classname, "info_player_deathmatch");
1404         if (spot)
1405                 return spot;
1406
1407         //objerror ("FindIntermission: no spot");
1408         return world;
1409 }
1410 */
1411
1412 /*
1413 ===============================================================================
1414
1415 RULES
1416
1417 ===============================================================================
1418 */
1419
1420 void DumpStats(float final)
1421 {
1422         float file;
1423         string s;
1424         float to_console;
1425         float to_eventlog;
1426         float to_file;
1427         float i;
1428
1429         to_console = autocvar_sv_logscores_console;
1430         to_eventlog = autocvar_sv_eventlog;
1431         to_file = autocvar_sv_logscores_file;
1432
1433         if(!final)
1434         {
1435                 to_console = TRUE; // always print printstats replies
1436                 to_eventlog = FALSE; // but never print them to the event log
1437         }
1438
1439         if(to_eventlog)
1440                 if(autocvar_sv_eventlog_console)
1441                         to_console = FALSE; // otherwise we get the output twice
1442
1443         if(final)
1444                 s = ":scores:";
1445         else
1446                 s = ":status:";
1447         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1448
1449         if(to_console)
1450                 print(s, "\n");
1451         if(to_eventlog)
1452                 GameLogEcho(s);
1453
1454         file = -1;
1455         if(to_file)
1456         {
1457                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1458                 if(file == -1)
1459                         to_file = FALSE;
1460                 else
1461                         fputs(file, strcat(s, "\n"));
1462         }
1463
1464         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1465         if(to_console)
1466                 print(s, "\n");
1467         if(to_eventlog)
1468                 GameLogEcho(s);
1469         if(to_file)
1470                 fputs(file, strcat(s, "\n"));
1471
1472         FOR_EACH_CLIENT(other)
1473         {
1474                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1475                 {
1476                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1477                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1478                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1479                                 s = strcat(s, ftos(other.team), ":");
1480                         else
1481                                 s = strcat(s, "spectator:");
1482
1483                         if(to_console)
1484                                 print(s, other.netname, "\n");
1485                         if(to_eventlog)
1486                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1487                         if(to_file)
1488                                 fputs(file, strcat(s, other.netname, "\n"));
1489                 }
1490         }
1491
1492         if(teamplay)
1493         {
1494                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1495                 if(to_console)
1496                         print(s, "\n");
1497                 if(to_eventlog)
1498                         GameLogEcho(s);
1499                 if(to_file)
1500                         fputs(file, strcat(s, "\n"));
1501
1502                 for(i = 1; i < 16; ++i)
1503                 {
1504                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1505                         s = strcat(s, ":", ftos(i));
1506                         if(to_console)
1507                                 print(s, "\n");
1508                         if(to_eventlog)
1509                                 GameLogEcho(s);
1510                         if(to_file)
1511                                 fputs(file, strcat(s, "\n"));
1512                 }
1513         }
1514
1515         if(to_console)
1516                 print(":end\n");
1517         if(to_eventlog)
1518                 GameLogEcho(":end");
1519         if(to_file)
1520         {
1521                 fputs(file, ":end\n");
1522                 fclose(file);
1523         }
1524 }
1525
1526 void FixIntermissionClient(entity e)
1527 {
1528         string s;
1529         if(!e.autoscreenshot) // initial call
1530         {
1531                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1532                 e.health = -2342;
1533                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1534                 e.solid = SOLID_NOT;
1535                 e.movetype = MOVETYPE_NONE;
1536                 e.takedamage = DAMAGE_NO;
1537                 if(e.weaponentity)
1538                 {
1539                         e.weaponentity.effects = EF_NODRAW;
1540                         if (e.weaponentity.weaponentity)
1541                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1542                 }
1543                 if(clienttype(e) == CLIENTTYPE_REAL)
1544                 {
1545                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1546                         s = autocvar_sv_intermission_cdtrack;
1547                         if(s != "")
1548                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1549                         msg_entity = e;
1550                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1551                 }
1552         }
1553 }
1554
1555 void minstagib_stop_countdown(entity e);
1556 /*
1557 go to the next level for deathmatch
1558 only called if a time or frag limit has expired
1559 */
1560 void NextLevel()
1561 {
1562         gameover = TRUE;
1563
1564         intermission_running = 1;
1565
1566 // enforce a wait time before allowing changelevel
1567         if(player_count > 0)
1568                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1569         else
1570                 intermission_exittime = -1;
1571
1572         /*
1573         WriteByte (MSG_ALL, SVC_CDTRACK);
1574         WriteByte (MSG_ALL, 3);
1575         WriteByte (MSG_ALL, 3);
1576         // done in FixIntermission
1577         */
1578
1579         //pos = FindIntermission ();
1580
1581         VoteReset();
1582
1583         DumpStats(TRUE);
1584
1585         // send statistics
1586         entity e;
1587         PlayerStats_EndMatch(1);
1588         FOR_EACH_CLIENT(e)
1589                 PlayerStats_AddGlobalInfo(e);
1590         PlayerStats_Shutdown();
1591         WeaponStats_Shutdown();
1592
1593         if(autocvar_sv_eventlog)
1594                 GameLogEcho(":gameover");
1595
1596         GameLogClose();
1597
1598         FOR_EACH_PLAYER(other) {
1599                 minstagib_stop_countdown(other);
1600                 FixIntermissionClient(other);
1601                 if(other.winning)
1602                         bprint(other.netname, " ^7wins.\n");
1603         }
1604
1605         if(autocvar_g_campaign)
1606                 CampaignPreIntermission();
1607
1608         MUTATOR_CALLHOOK(MatchEnd);
1609
1610         localcmd("\nsv_hook_gameend\n");
1611 }
1612
1613 /*
1614 ============
1615 CheckRules_Player
1616
1617 Exit deathmatch games upon conditions
1618 ============
1619 */
1620 void CheckRules_Player()
1621 {
1622         if (gameover)   // someone else quit the game already
1623                 return;
1624
1625         if(self.deadflag == DEAD_NO)
1626                 self.play_time += frametime;
1627
1628         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1629         //   (div0: and that in CheckRules_World please)
1630 }
1631
1632 float checkrules_equality;
1633 float checkrules_suddendeathwarning;
1634 float checkrules_suddendeathend;
1635 float checkrules_overtimesadded; //how many overtimes have been already added
1636
1637 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1638 float WINNING_YES = 1; // winner found
1639 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1640 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1641
1642 float InitiateSuddenDeath()
1643 {
1644         // Check first whether normal overtimes could be added before initiating suddendeath mode
1645         // - for this timelimit_overtime needs to be >0 of course
1646         // - also check the winning condition calculated in the previous frame and only add normal overtime
1647         //   again, if at the point at which timelimit would be extended again, still no winner was found
1648         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1649         {
1650                 return 1; // need to call InitiateOvertime later
1651         }
1652         else
1653         {
1654                 if(!checkrules_suddendeathend)
1655                 {
1656                         if(autocvar_g_campaign)
1657                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1658                         else
1659                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1660                         if(g_race && !g_race_qualifying)
1661                                 race_StartCompleting();
1662                 }
1663                 return 0;
1664         }
1665 }
1666
1667 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1668 {
1669         ++checkrules_overtimesadded;
1670         //add one more overtime by simply extending the timelimit
1671         float tl;
1672         tl = autocvar_timelimit;
1673         tl += autocvar_timelimit_overtime;
1674         cvar_set("timelimit", ftos(tl));
1675         string minutesPlural;
1676         if (autocvar_timelimit_overtime == 1)
1677                 minutesPlural = " ^3minute";
1678         else
1679                 minutesPlural = " ^3minutes";
1680
1681         bcenterprint(
1682                 strcat(
1683                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1684                         ftos(autocvar_timelimit_overtime),
1685                         minutesPlural,
1686                         " to the game!"
1687                 )
1688         );
1689 }
1690
1691 float GetWinningCode(float fraglimitreached, float equality)
1692 {
1693         if(autocvar_g_campaign == 1)
1694                 if(fraglimitreached)
1695                         return WINNING_YES;
1696                 else
1697                         return WINNING_NO;
1698
1699         else
1700                 if(equality)
1701                         if(fraglimitreached)
1702                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1703                         else
1704                                 return WINNING_NEVER;
1705                 else
1706                         if(fraglimitreached)
1707                                 return WINNING_YES;
1708                         else
1709                                 return WINNING_NO;
1710 }
1711
1712 // set the .winning flag for exactly those players with a given field value
1713 void SetWinners(.float field, float value)
1714 {
1715         entity head;
1716         FOR_EACH_PLAYER(head)
1717                 head.winning = (head.field == value);
1718 }
1719
1720 // set the .winning flag for those players with a given field value
1721 void AddWinners(.float field, float value)
1722 {
1723         entity head;
1724         FOR_EACH_PLAYER(head)
1725                 if(head.field == value)
1726                         head.winning = 1;
1727 }
1728
1729 // clear the .winning flags
1730 void ClearWinners(void)
1731 {
1732         entity head;
1733         FOR_EACH_PLAYER(head)
1734                 head.winning = 0;
1735 }
1736
1737 // Onslaught winning condition:
1738 // game terminates if only one team has a working generator (or none)
1739 float WinningCondition_Onslaught()
1740 {
1741         entity head;
1742         float t1, t2, t3, t4;
1743
1744         WinningConditionHelper(); // set worldstatus
1745
1746         if(inWarmupStage)
1747                 return WINNING_NO;
1748
1749         // first check if the game has ended
1750         t1 = t2 = t3 = t4 = 0;
1751         head = find(world, classname, "onslaught_generator");
1752         while (head)
1753         {
1754                 if (head.health > 0)
1755                 {
1756                         if (head.team == COLOR_TEAM1) t1 = 1;
1757                         if (head.team == COLOR_TEAM2) t2 = 1;
1758                         if (head.team == COLOR_TEAM3) t3 = 1;
1759                         if (head.team == COLOR_TEAM4) t4 = 1;
1760                 }
1761                 head = find(head, classname, "onslaught_generator");
1762         }
1763         if (t1 + t2 + t3 + t4 < 2)
1764         {
1765                 // game over, only one team remains (or none)
1766                 ClearWinners();
1767                 if (t1) SetWinners(team, COLOR_TEAM1);
1768                 if (t2) SetWinners(team, COLOR_TEAM2);
1769                 if (t3) SetWinners(team, COLOR_TEAM3);
1770                 if (t4) SetWinners(team, COLOR_TEAM4);
1771                 dprint("Have a winner, ending game.\n");
1772                 return WINNING_YES;
1773         }
1774
1775         // Two or more teams remain
1776         return WINNING_NO;
1777 }
1778
1779 float LMS_NewPlayerLives()
1780 {
1781         float fl;
1782         fl = autocvar_fraglimit;
1783         if(fl == 0)
1784                 fl = 999;
1785
1786         // first player has left the game for dying too much? Nobody else can get in.
1787         if(lms_lowest_lives < 1)
1788                 return 0;
1789
1790         if(!autocvar_g_lms_join_anytime)
1791                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1792                         return 0;
1793
1794         return bound(1, lms_lowest_lives, fl);
1795 }
1796
1797 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1798 // they win. Otherwise the defending team wins once the timelimit passes.
1799 void assault_new_round();
1800 float WinningCondition_Assault()
1801 {
1802         float status;
1803
1804         WinningConditionHelper(); // set worldstatus
1805
1806         status = WINNING_NO;
1807         // as the timelimit has not yet passed just assume the defending team will win
1808         if(assault_attacker_team == COLOR_TEAM1)
1809         {
1810                 SetWinners(team, COLOR_TEAM2);
1811         }
1812         else
1813         {
1814                 SetWinners(team, COLOR_TEAM1);
1815         }
1816
1817         entity ent;
1818         ent = find(world, classname, "target_assault_roundend");
1819         if(ent)
1820         {
1821                 if(ent.winning) // round end has been triggered by attacking team
1822                 {
1823                         bprint("ASSAULT: round completed...\n");
1824                         SetWinners(team, assault_attacker_team);
1825
1826                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1827
1828                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1829                         {
1830                                 status = WINNING_YES;
1831                         }
1832                         else
1833                         {
1834                                 entity oldself;
1835                                 oldself = self;
1836                                 self = ent;
1837                                 assault_new_round();
1838                                 self = oldself;
1839                         }
1840                 }
1841         }
1842
1843         return status;
1844 }
1845
1846 // LMS winning condition: game terminates if and only if there's at most one
1847 // one player who's living lives. Top two scores being equal cancels the time
1848 // limit.
1849 float WinningCondition_LMS()
1850 {
1851         entity head, head2;
1852         float have_player;
1853         float have_players;
1854         float l;
1855
1856         have_player = FALSE;
1857         have_players = FALSE;
1858         l = LMS_NewPlayerLives();
1859
1860         head = find(world, classname, "player");
1861         if(head)
1862                 have_player = TRUE;
1863         head2 = find(head, classname, "player");
1864         if(head2)
1865                 have_players = TRUE;
1866
1867         if(have_player)
1868         {
1869                 // we have at least one player
1870                 if(have_players)
1871                 {
1872                         // two or more active players - continue with the game
1873                 }
1874                 else
1875                 {
1876                         // exactly one player?
1877
1878                         ClearWinners();
1879                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1880
1881                         if(l)
1882                         {
1883                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1884                                 return WINNING_NO;
1885                         }
1886                         else
1887                         {
1888                                 // a winner!
1889                                 // and assign him his first place
1890                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1891                                 return WINNING_YES;
1892                         }
1893                 }
1894         }
1895         else
1896         {
1897                 // nobody is playing at all...
1898                 if(l)
1899                 {
1900                         // wait for players...
1901                 }
1902                 else
1903                 {
1904                         // SNAFU (maybe a draw game?)
1905                         ClearWinners();
1906                         dprint("No players, ending game.\n");
1907                         return WINNING_YES;
1908                 }
1909         }
1910
1911         // When we get here, we have at least two players who are actually LIVING,
1912         // now check if the top two players have equal score.
1913         WinningConditionHelper();
1914
1915         ClearWinners();
1916         if(WinningConditionHelper_winner)
1917                 WinningConditionHelper_winner.winning = TRUE;
1918         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1919                 return WINNING_NEVER;
1920
1921         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1922         return WINNING_NO;
1923 }
1924
1925 void ShuffleMaplist()
1926 {
1927         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1928 }
1929
1930 float leaderfrags;
1931 float WinningCondition_Scores(float limit, float leadlimit)
1932 {
1933         float limitreached;
1934
1935         // TODO make everything use THIS winning condition (except LMS)
1936         WinningConditionHelper();
1937
1938         if(teamplay)
1939         {
1940                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1941                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1942                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1943                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1944         }
1945
1946         ClearWinners();
1947         if(WinningConditionHelper_winner)
1948                 WinningConditionHelper_winner.winning = 1;
1949         if(WinningConditionHelper_winnerteam >= 0)
1950                 SetWinners(team, WinningConditionHelper_winnerteam);
1951
1952         if(WinningConditionHelper_lowerisbetter)
1953         {
1954                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1955                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1956                 limit = -limit;
1957         }
1958
1959         if(WinningConditionHelper_zeroisworst)
1960                 leadlimit = 0; // not supported in this mode
1961
1962         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1963         // these modes always score in increments of 1, thus this makes sense
1964         {
1965                 if(leaderfrags != WinningConditionHelper_topscore)
1966                 {
1967                         leaderfrags = WinningConditionHelper_topscore;
1968
1969                         if (limit)
1970                         if (leaderfrags == limit - 1)
1971                                 Announce("1fragleft");
1972                         else if (leaderfrags == limit - 2)
1973                                 Announce("2fragsleft");
1974                         else if (leaderfrags == limit - 3)
1975                                 Announce("3fragsleft");
1976                 }
1977         }
1978
1979         limitreached = FALSE;
1980         if(limit)
1981                 if(WinningConditionHelper_topscore >= limit)
1982                         limitreached = TRUE;
1983         if(leadlimit)
1984         {
1985                 float leadlimitreached;
1986                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1987                 if(autocvar_leadlimit_and_fraglimit)
1988                         limitreached = (limitreached && leadlimitreached);
1989                 else
1990                         limitreached = (limitreached || leadlimitreached);
1991         }
1992
1993         if(limit)
1994                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1995
1996         return GetWinningCode(
1997                 WinningConditionHelper_topscore && limitreached,
1998                 WinningConditionHelper_equality
1999         );
2000 }
2001
2002 float WinningCondition_Race(float fraglimit)
2003 {
2004         float wc;
2005         entity p;
2006         float n, c;
2007
2008         n = 0;
2009         c = 0;
2010         FOR_EACH_PLAYER(p)
2011         {
2012                 ++n;
2013                 if(p.race_completed)
2014                         ++c;
2015         }
2016         if(n && (n == c))
2017                 return WINNING_YES;
2018         wc = WinningCondition_Scores(fraglimit, 0);
2019
2020         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2021         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2022         // do NOT support equality when the laps are all raced!
2023                 return WINNING_STARTSUDDENDEATHOVERTIME;
2024         else
2025                 return WINNING_NEVER;
2026 }
2027
2028 float WinningCondition_QualifyingThenRace(float limit)
2029 {
2030         float wc;
2031         wc = WinningCondition_Scores(limit, 0);
2032
2033         // NEVER initiate overtime
2034         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2035         {
2036                 return WINNING_YES;
2037         }
2038
2039         return wc;
2040 }
2041
2042 float WinningCondition_RanOutOfSpawns()
2043 {
2044         entity head;
2045
2046         if(have_team_spawns <= 0)
2047                 return WINNING_NO;
2048
2049         if(autocvar_g_spawn_useallspawns <= 0)
2050                 return WINNING_NO;
2051
2052         if(!some_spawn_has_been_used)
2053                 return WINNING_NO;
2054
2055         team1_score = team2_score = team3_score = team4_score = 0;
2056
2057         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2058         {
2059                 if(head.team == COLOR_TEAM1)
2060                         team1_score = 1;
2061                 else if(head.team == COLOR_TEAM2)
2062                         team2_score = 1;
2063                 else if(head.team == COLOR_TEAM3)
2064                         team3_score = 1;
2065                 else if(head.team == COLOR_TEAM4)
2066                         team4_score = 1;
2067         }
2068
2069         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2070         {
2071                 if(head.team == COLOR_TEAM1)
2072                         team1_score = 1;
2073                 else if(head.team == COLOR_TEAM2)
2074                         team2_score = 1;
2075                 else if(head.team == COLOR_TEAM3)
2076                         team3_score = 1;
2077                 else if(head.team == COLOR_TEAM4)
2078                         team4_score = 1;
2079         }
2080
2081         ClearWinners();
2082         if(team1_score + team2_score + team3_score + team4_score == 0)
2083         {
2084                 checkrules_equality = TRUE;
2085                 return WINNING_YES;
2086         }
2087         else if(team1_score + team2_score + team3_score + team4_score == 1)
2088         {
2089                 float t, i;
2090                 if(team1_score)
2091                         t = COLOR_TEAM1;
2092                 else if(team2_score)
2093                         t = COLOR_TEAM2;
2094                 else if(team3_score)
2095                         t = COLOR_TEAM3;
2096                 else // if(team4_score)
2097                         t = COLOR_TEAM4;
2098                 CheckAllowedTeams(world);
2099                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2100                 {
2101                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2102                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2103                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2104                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2105                 }
2106
2107                 AddWinners(team, t);
2108                 return WINNING_YES;
2109         }
2110         else
2111                 return WINNING_NO;
2112 }
2113
2114 /*
2115 ============
2116 CheckRules_World
2117
2118 Exit deathmatch games upon conditions
2119 ============
2120 */
2121 void ReadyRestart();
2122 void CheckRules_World()
2123 {
2124         float timelimit;
2125         float fraglimit;
2126         float leadlimit;
2127
2128         VoteThink();
2129         MapVote_Think();
2130
2131         SetDefaultAlpha();
2132
2133         /*
2134         MapVote_Think should now do that part
2135         if (intermission_running)
2136                 if (time >= intermission_exittime + 60)
2137                 {
2138                         if(!DoNextMapOverride())
2139                                 GotoNextMap();
2140                         return;
2141                 }
2142         */
2143
2144         if (gameover)   // someone else quit the game already
2145         {
2146                 if(player_count == 0) // Nobody there? Then let's go to the next map
2147                         MapVote_Start();
2148                         // this will actually check the player count in the next frame
2149                         // again, but this shouldn't hurt
2150                 return;
2151         }
2152
2153         timelimit = autocvar_timelimit * 60;
2154         fraglimit = autocvar_fraglimit;
2155         leadlimit = autocvar_leadlimit;
2156
2157         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2158         {
2159                 if(timelimit > 0)
2160                         timelimit = 0; // timelimit is not made for warmup
2161                 if(fraglimit > 0)
2162                         fraglimit = 0; // no fraglimit for now
2163                 leadlimit = 0; // no leadlimit for now
2164         }
2165
2166         if(timelimit > 0)
2167         {
2168                 timelimit += game_starttime;
2169         }
2170         else if (timelimit < 0)
2171         {
2172                 // endmatch
2173                 NextLevel();
2174                 return;
2175         }
2176
2177         if(g_onslaught)
2178                 timelimit = 0; // ONS has its own overtime rule
2179
2180         float wantovertime;
2181         wantovertime = 0;
2182
2183         if(timelimit > game_starttime)
2184                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2185         else
2186                 game_completion_ratio = 0;
2187
2188         if(checkrules_suddendeathend)
2189         {
2190                 if(!checkrules_suddendeathwarning)
2191                 {
2192                         checkrules_suddendeathwarning = TRUE;
2193                         if(g_race && !g_race_qualifying)
2194                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2195                         else
2196                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2197                 }
2198         }
2199         else
2200         {
2201                 if (timelimit && time >= timelimit)
2202                 {
2203                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2204                         {
2205                                 float totalplayers;
2206                                 float playerswithlaps;
2207                                 float readyplayers;
2208                                 entity head;
2209                                 totalplayers = playerswithlaps = readyplayers = 0;
2210                                 FOR_EACH_PLAYER(head)
2211                                 {
2212                                         ++totalplayers;
2213                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2214                                                 ++playerswithlaps;
2215                                         if(head.ready)
2216                                                 ++readyplayers;
2217                                 }
2218
2219                                 // at least 2 of the players have completed a lap: start the RACE
2220                                 // otherwise, the players should end the qualifying on their own
2221                                 if(readyplayers || playerswithlaps >= 2)
2222                                 {
2223                                         checkrules_suddendeathend = 0;
2224                                         ReadyRestart(); // go to race
2225                                         return;
2226                                 }
2227                                 else
2228                                         wantovertime |= InitiateSuddenDeath();
2229                         }
2230                         else
2231                                 wantovertime |= InitiateSuddenDeath();
2232                 }
2233         }
2234
2235         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2236         {
2237                 NextLevel();
2238                 return;
2239         }
2240
2241         float checkrules_status;
2242         checkrules_status = WinningCondition_RanOutOfSpawns();
2243         if(checkrules_status == WINNING_YES)
2244         {
2245                 bprint("Hey! Someone ran out of spawns!\n");
2246         }
2247         else if(g_race && !g_race_qualifying && timelimit >= 0)
2248         {
2249                 checkrules_status = WinningCondition_Race(fraglimit);
2250                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2251         }
2252         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2253         {
2254                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2255                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2256         }
2257         else if(g_assault)
2258         {
2259                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2260         }
2261         else if(g_lms)
2262         {
2263                 checkrules_status = WinningCondition_LMS();
2264         }
2265         else if (g_onslaught)
2266         {
2267                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2268         }
2269         else
2270         {
2271                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2272                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2273         }
2274
2275         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2276         {
2277                 checkrules_status = WINNING_NEVER;
2278                 checkrules_overtimesadded = -1;
2279                 wantovertime |= InitiateSuddenDeath();
2280         }
2281
2282         if(checkrules_status == WINNING_NEVER)
2283                 // equality cases! Nobody wins if the overtime ends in a draw.
2284                 ClearWinners();
2285
2286         if(wantovertime)
2287         {
2288                 if(checkrules_status == WINNING_NEVER)
2289                         InitiateOvertime();
2290                 else
2291                         checkrules_status = WINNING_YES;
2292         }
2293
2294         if(checkrules_suddendeathend)
2295                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2296                         checkrules_status = WINNING_YES;
2297
2298         if(checkrules_status == WINNING_YES)
2299         {
2300                 //print("WINNING\n");
2301                 NextLevel();
2302         }
2303 }
2304
2305 float mapvote_nextthink;
2306 float mapvote_initialized;
2307 float mapvote_keeptwotime;
2308 float mapvote_timeout;
2309 string mapvote_message;
2310 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2311 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2312 float mapvote_screenshot_dirs_count;
2313
2314 float mapvote_count;
2315 float mapvote_count_real;
2316 string mapvote_maps[MAPVOTE_COUNT];
2317 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2318 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2319 float mapvote_maps_suggested[MAPVOTE_COUNT];
2320 string mapvote_suggestions[MAPVOTE_COUNT];
2321 float mapvote_suggestion_ptr;
2322 float mapvote_voters;
2323 float mapvote_selections[MAPVOTE_COUNT];
2324 float mapvote_run;
2325 float mapvote_detail;
2326 float mapvote_abstain;
2327 .float mapvote;
2328
2329 void MapVote_ClearAllVotes()
2330 {
2331         FOR_EACH_CLIENT(other)
2332                 other.mapvote = 0;
2333 }
2334
2335 string MapVote_Suggest(string m)
2336 {
2337         float i;
2338         if(m == "")
2339                 return "That's not how to use this command.";
2340         if(!autocvar_g_maplist_votable_suggestions)
2341                 return "Suggestions are not accepted on this server.";
2342         if(mapvote_initialized)
2343                 return "Can't suggest - voting is already in progress!";
2344         m = MapInfo_FixName(m);
2345         if not(m)
2346                 return "The map you suggested is not available on this server.";
2347         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2348                 if(Map_IsRecent(m))
2349                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2350
2351         if(!MapInfo_CheckMap(m))
2352                 return "The map you suggested does not support the current game mode.";
2353         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2354                 if(mapvote_suggestions[i] == m)
2355                         return "This map was already suggested.";
2356         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2357         {
2358                 i = floor(random() * mapvote_suggestion_ptr);
2359         }
2360         else
2361         {
2362                 i = mapvote_suggestion_ptr;
2363                 mapvote_suggestion_ptr += 1;
2364         }
2365         if(mapvote_suggestions[i] != "")
2366                 strunzone(mapvote_suggestions[i]);
2367         mapvote_suggestions[i] = strzone(m);
2368         if(autocvar_sv_eventlog)
2369                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2370         return strcat("Suggestion of ", m, " accepted.");
2371 }
2372
2373 void MapVote_AddVotable(string nextMap, float isSuggestion)
2374 {
2375         float j, i, o;
2376         string pakfile, mapfile;
2377
2378         if(nextMap == "")
2379                 return;
2380         for(j = 0; j < mapvote_count; ++j)
2381                 if(mapvote_maps[j] == nextMap)
2382                         return;
2383         // suggestions might be no longer valid/allowed after gametype switch!
2384         if(isSuggestion)
2385                 if(!MapInfo_CheckMap(nextMap))
2386                         return;
2387         mapvote_maps[mapvote_count] = strzone(nextMap);
2388         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2389
2390         pakfile = string_null;
2391         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2392         {
2393                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2394                 pakfile = whichpack(strcat(mapfile, ".tga"));
2395                 if(pakfile == "")
2396                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2397                 if(pakfile == "")
2398                         pakfile = whichpack(strcat(mapfile, ".png"));
2399                 if(pakfile != "")
2400                         break;
2401         }
2402         if(i >= mapvote_screenshot_dirs_count)
2403                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2404         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2405                 pakfile = substring(pakfile, o, -1);
2406
2407         mapvote_maps_screenshot_dir[mapvote_count] = i;
2408         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2409
2410         mapvote_count += 1;
2411 }
2412
2413 void MapVote_Spawn();
2414 void MapVote_Init()
2415 {
2416         float i;
2417         float nmax, smax;
2418
2419         MapVote_ClearAllVotes();
2420
2421         mapvote_count = 0;
2422         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2423         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2424
2425         if(mapvote_abstain)
2426                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2427         else
2428                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2429         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2430
2431         // we need this for AddVotable, as that cycles through the screenshot dirs
2432         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2433         if(mapvote_screenshot_dirs_count == 0)
2434                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2435         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2436         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2437                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2438
2439         if(mapvote_suggestion_ptr)
2440                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2441                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2442
2443         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2444                 MapVote_AddVotable(GetNextMap(), FALSE);
2445
2446         if(mapvote_count == 0)
2447         {
2448                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2449                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2450                 if(autocvar_g_maplist_shuffle)
2451                         ShuffleMaplist();
2452                 localcmd("\nmenu_cmd sync\n");
2453                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2454                         MapVote_AddVotable(GetNextMap(), FALSE);
2455         }
2456
2457         mapvote_count_real = mapvote_count;
2458         if(mapvote_abstain)
2459                 MapVote_AddVotable("don't care", 0);
2460
2461         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2462
2463         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2464         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2465         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2466                 mapvote_keeptwotime = 0;
2467         mapvote_message = "Choose a map and press its key!";
2468
2469         MapVote_Spawn();
2470 }
2471
2472 void MapVote_SendPicture(float id)
2473 {
2474         msg_entity = self;
2475         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2476         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2477         WriteByte(MSG_ONE, id);
2478         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2479 }
2480
2481 float MapVote_GetMapMask()
2482 {
2483         float mask, i, power;
2484         mask = 0;
2485         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2486                 if(mapvote_maps[i] != "")
2487                         mask |= power;
2488         return mask;
2489 }
2490
2491 entity mapvote_ent;
2492 float MapVote_SendEntity(entity to, float sf)
2493 {
2494         float i;
2495
2496         if(sf & 1)
2497                 sf &~= 2; // if we send 1, we don't need to also send 2
2498
2499         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2500         WriteByte(MSG_ENTITY, sf);
2501
2502         if(sf & 1)
2503         {
2504                 // flag 1 == initialization
2505                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2506                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2507                 WriteString(MSG_ENTITY, "");
2508                 WriteByte(MSG_ENTITY, mapvote_count);
2509                 WriteByte(MSG_ENTITY, mapvote_abstain);
2510                 WriteByte(MSG_ENTITY, mapvote_detail);
2511                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2512                 if(mapvote_count <= 8)
2513                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2514                 else
2515                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2516                 for(i = 0; i < mapvote_count; ++i)
2517                         if(mapvote_maps[i] != "")
2518                         {
2519                                 if(mapvote_abstain && i == mapvote_count - 1)
2520                                 {
2521                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2522                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2523                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2524                                 }
2525                                 else
2526                                 {
2527                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2528                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2529                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2530                                 }
2531                         }
2532         }
2533
2534         if(sf & 2)
2535         {
2536                 // flag 2 == update of mask
2537                 if(mapvote_count <= 8)
2538                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2539                 else
2540                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2541         }
2542
2543         if(sf & 4)
2544         {
2545                 if(mapvote_detail)
2546                         for(i = 0; i < mapvote_count; ++i)
2547                                 if(mapvote_maps[i] != "")
2548                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2549
2550                 WriteByte(MSG_ENTITY, to.mapvote);
2551         }
2552
2553         return TRUE;
2554 }
2555
2556 void MapVote_Spawn()
2557 {
2558         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2559 }
2560
2561 void MapVote_TouchMask()
2562 {
2563         mapvote_ent.SendFlags |= 2;
2564 }
2565
2566 void MapVote_TouchVotes(entity voter)
2567 {
2568         mapvote_ent.SendFlags |= 4;
2569 }
2570
2571 float MapVote_Finished(float mappos)
2572 {
2573         string result;
2574         float i;
2575         float didntvote;
2576
2577         if(autocvar_sv_eventlog)
2578         {
2579                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2580                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2581                 didntvote = mapvote_voters;
2582                 for(i = 0; i < mapvote_count; ++i)
2583                         if(mapvote_maps[i] != "")
2584                         {
2585                                 didntvote -= mapvote_selections[i];
2586                                 if(i != mappos)
2587                                 {
2588                                         result = strcat(result, ":", mapvote_maps[i]);
2589                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2590                                 }
2591                         }
2592                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2593
2594                 GameLogEcho(result);
2595                 if(mapvote_maps_suggested[mappos])
2596                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2597         }
2598
2599         FOR_EACH_REALCLIENT(other)
2600                 FixClientCvars(other);
2601
2602         Map_Goto_SetStr(mapvote_maps[mappos]);
2603         Map_Goto(0);
2604         alreadychangedlevel = TRUE;
2605         return TRUE;
2606 }
2607 void MapVote_CheckRules_1()
2608 {
2609         float i;
2610
2611         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2612         {
2613                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2614                 mapvote_selections[i] = 0;
2615         }
2616
2617         mapvote_voters = 0;
2618         FOR_EACH_REALCLIENT(other)
2619         {
2620                 ++mapvote_voters;
2621                 if(other.mapvote)
2622                 {
2623                         i = other.mapvote - 1;
2624                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2625                         mapvote_selections[i] = mapvote_selections[i] + 1;
2626                 }
2627         }
2628 }
2629
2630 float MapVote_CheckRules_2()
2631 {
2632         float i;
2633         float firstPlace, secondPlace;
2634         float firstPlaceVotes, secondPlaceVotes;
2635         float mapvote_voters_real;
2636         string result;
2637
2638         if(mapvote_count_real == 1)
2639                 return MapVote_Finished(0);
2640
2641         mapvote_voters_real = mapvote_voters;
2642         if(mapvote_abstain)
2643                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2644
2645         RandomSelection_Init();
2646         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2647                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2648         firstPlace = RandomSelection_chosen_float;
2649         firstPlaceVotes = RandomSelection_best_priority;
2650         //dprint("First place: ", ftos(firstPlace), "\n");
2651         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2652
2653         RandomSelection_Init();
2654         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2655                 if(i != firstPlace)
2656                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2657         secondPlace = RandomSelection_chosen_float;
2658         secondPlaceVotes = RandomSelection_best_priority;
2659         //dprint("Second place: ", ftos(secondPlace), "\n");
2660         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2661
2662         if(firstPlace == -1)
2663                 error("No first place in map vote... WTF?");
2664
2665         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2666                 return MapVote_Finished(firstPlace);
2667
2668         if(mapvote_keeptwotime)
2669                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2670                 {
2671                         float didntvote;
2672                         MapVote_TouchMask();
2673                         mapvote_message = "Now decide between the TOP TWO!";
2674                         mapvote_keeptwotime = 0;
2675                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2676                         result = strcat(result, ":", ftos(firstPlaceVotes));
2677                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2678                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2679                         didntvote = mapvote_voters;
2680                         for(i = 0; i < mapvote_count; ++i)
2681                                 if(mapvote_maps[i] != "")
2682                                 {
2683                                         didntvote -= mapvote_selections[i];
2684                                         if(i != firstPlace)
2685                                                 if(i != secondPlace)
2686                                                 {
2687                                                         result = strcat(result, ":", mapvote_maps[i]);
2688                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2689                                                         if(i < mapvote_count_real)
2690                                                         {
2691                                                                 strunzone(mapvote_maps[i]);
2692                                                                 mapvote_maps[i] = "";
2693                                                                 strunzone(mapvote_maps_pakfile[i]);
2694                                                                 mapvote_maps_pakfile[i] = "";
2695                                                         }
2696                                                 }
2697                                 }
2698                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2699                         if(autocvar_sv_eventlog)
2700                                 GameLogEcho(result);
2701                 }
2702
2703         return FALSE;
2704 }
2705 void MapVote_Tick()
2706 {
2707         float keeptwo;
2708         float totalvotes;
2709
2710         keeptwo = mapvote_keeptwotime;
2711         MapVote_CheckRules_1(); // count
2712         if(MapVote_CheckRules_2()) // decide
2713                 return;
2714
2715         totalvotes = 0;
2716         FOR_EACH_REALCLIENT(other)
2717         {
2718                 // hide scoreboard again
2719                 if(other.health != 2342)
2720                 {
2721                         other.health = 2342;
2722                         other.impulse = 0;
2723                         if(clienttype(other) == CLIENTTYPE_REAL)
2724                         {
2725                                 msg_entity = other;
2726                                 WriteByte(MSG_ONE, SVC_FINALE);
2727                                 WriteString(MSG_ONE, "");
2728                         }
2729                 }
2730
2731                 // clear possibly invalid votes
2732                 if(mapvote_maps[other.mapvote - 1] == "")
2733                         other.mapvote = 0;
2734                 // use impulses as new vote
2735                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2736                         if(mapvote_maps[other.impulse - 1] != "")
2737                         {
2738                                 other.mapvote = other.impulse;
2739                                 MapVote_TouchVotes(other);
2740                         }
2741                 other.impulse = 0;
2742
2743                 if(other.mapvote)
2744                         ++totalvotes;
2745         }
2746
2747         MapVote_CheckRules_1(); // just count
2748 }
2749 void MapVote_Start()
2750 {
2751         if(mapvote_run)
2752                 return;
2753
2754         // wait for stats to be sent first
2755         if(!playerstats_waitforme)
2756                 return;
2757
2758         MapInfo_Enumerate();
2759         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2760                 mapvote_run = TRUE;
2761 }
2762 void MapVote_Think()
2763 {
2764         if(!mapvote_run)
2765                 return;
2766
2767         if(alreadychangedlevel)
2768                 return;
2769
2770         if(time < mapvote_nextthink)
2771                 return;
2772         //dprint("tick\n");
2773
2774         mapvote_nextthink = time + 0.5;
2775
2776         if(!mapvote_initialized)
2777         {
2778                 if(autocvar_rescan_pending == 1)
2779                 {
2780                         cvar_set("rescan_pending", "2");
2781                         localcmd("fs_rescan\nrescan_pending 3\n");
2782                         return;
2783                 }
2784                 else if(autocvar_rescan_pending == 2)
2785                 {
2786                         return;
2787                 }
2788                 else if(autocvar_rescan_pending == 3)
2789                 {
2790                         // now build missing mapinfo files
2791                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2792                                 return;
2793
2794                         // we're done, start the timer
2795                         cvar_set("rescan_pending", "0");
2796                 }
2797
2798                 mapvote_initialized = TRUE;
2799                 if(DoNextMapOverride(0))
2800                         return;
2801                 if(!autocvar_g_maplist_votable || player_count <= 0)
2802                 {
2803                         GotoNextMap(0);
2804                         return;
2805                 }
2806                 MapVote_Init();
2807         }
2808
2809         MapVote_Tick();
2810 }
2811
2812 string GotoMap(string m)
2813 {
2814         if(!MapInfo_CheckMap(m))
2815                 return "The map you chose is not available on this server.";
2816         cvar_set("nextmap", m);
2817         cvar_set("timelimit", "-1");
2818         if(mapvote_initialized || alreadychangedlevel)
2819         {
2820                 if(DoNextMapOverride(0))
2821                         return "Map switch initiated.";
2822                 else
2823                         return "Hm... no. For some reason I like THIS map more.";
2824         }
2825         else
2826                 return "Map switch will happen after scoreboard.";
2827 }
2828
2829
2830 void EndFrame()
2831 {
2832         float altime;
2833         FOR_EACH_REALCLIENT(self)
2834         {
2835                 if(self.classname == "spectator")
2836                 {
2837                         if(self.enemy.typehitsound)
2838                                 self.typehit_time = time;
2839                         else if(self.enemy.hitsound)
2840                                 self.hit_time = time;
2841                 }
2842                 else
2843                 {
2844                         if(self.typehitsound)
2845                                 self.typehit_time = time;
2846                         else if(self.hitsound)
2847                                 self.hit_time = time;
2848                 }
2849         }
2850         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2851         // add 1 frametime because after this, engine SV_Physics
2852         // increases time by a frametime and then networks the frame
2853         // add another frametime because client shows everything with
2854         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2855         // needed!
2856         FOR_EACH_CLIENT(self)
2857         {
2858                 self.hitsound = FALSE;
2859                 self.typehitsound = FALSE;
2860                 antilag_record(self, altime);
2861         }
2862 }
2863
2864
2865 /*
2866  * RedirectionThink:
2867  * returns TRUE if redirecting
2868  */
2869 float redirection_timeout;
2870 float redirection_nextthink;
2871 float RedirectionThink()
2872 {
2873         float clients_found;
2874
2875         if(redirection_target == "")
2876                 return FALSE;
2877
2878         if(!redirection_timeout)
2879         {
2880                 cvar_set("sv_public", "-2");
2881                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2882                 if(redirection_target == "self")
2883                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2884                 else
2885                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2886         }
2887
2888         if(time < redirection_nextthink)
2889                 return TRUE;
2890
2891         redirection_nextthink = time + 1;
2892
2893         clients_found = 0;
2894         FOR_EACH_REALCLIENT(self)
2895         {
2896                 // TODO add timer
2897                 print("Redirecting: sending connect command to ", self.netname, "\n");
2898                 if(redirection_target == "self")
2899                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2900                 else
2901                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2902                 ++clients_found;
2903         }
2904
2905         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2906
2907         if(time > redirection_timeout || clients_found == 0)
2908                 localcmd("\nwait; wait; wait; quit\n");
2909
2910         return TRUE;
2911 }
2912
2913 void TargetMusic_RestoreGame();
2914 void RestoreGame()
2915 {
2916         // Loaded from a save game
2917         // some things then break, so let's work around them...
2918
2919         // Progs DB (capture records)
2920         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2921
2922         // Mapinfo
2923         MapInfo_Shutdown();
2924         MapInfo_Enumerate();
2925         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2926         WeaponStats_Init();
2927
2928         TargetMusic_RestoreGame();
2929 }
2930
2931 void Shutdown()
2932 {
2933         entity e;
2934
2935         gameover = 2;
2936
2937         if(world_initialized > 0)
2938         {
2939                 world_initialized = 0;
2940                 print("Saving persistent data...\n");
2941                 Ban_SaveBans();
2942
2943                 PlayerStats_EndMatch(0);
2944                 FOR_EACH_CLIENT(e)
2945                         PlayerStats_AddGlobalInfo(e);
2946                 PlayerStats_Shutdown();
2947
2948                 if(!cheatcount_total)
2949                 {
2950                         if(autocvar_sv_db_saveasdump)
2951                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2952                         else
2953                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2954                 }
2955                 if(autocvar_developer)
2956                 {
2957                         if(autocvar_sv_db_saveasdump)
2958                                 db_dump(TemporaryDB, "server-temp.db");
2959                         else
2960                                 db_save(TemporaryDB, "server-temp.db");
2961                 }
2962                 CheatShutdown(); // must be after cheatcount check
2963                 db_close(ServerProgsDB);
2964                 db_close(TemporaryDB);
2965                 print("done!\n");
2966                 // tell the bot system the game is ending now
2967                 bot_endgame();
2968
2969                 WeaponStats_Shutdown();
2970                 MapInfo_Shutdown();
2971         }
2972         else if(world_initialized == 0)
2973         {
2974                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2975         }
2976 }