qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(IS_REAL_CLIENT(e))
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetGametype();
  59 void GotoNextMap(float reinit);
  60 void ShuffleMaplist();
  61 float(float reinit) DoNextMapOverride;
  62
  63 void SetDefaultAlpha()
  64 {
  65         if(autocvar_g_running_guns)
  66         {
  67                 default_player_alpha = -1;
  68                 default_weapon_alpha = +1;
  69         }
  70         else if(g_cloaked)
  71         {
  72                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  73                 default_weapon_alpha = default_player_alpha;
  74         }
  75         else
  76         {
  77                 default_player_alpha = autocvar_g_player_alpha;
  78                 if(default_player_alpha == 0)
  79                         default_player_alpha = 1;
  80                 default_weapon_alpha = default_player_alpha;
  81         }
  82 }
  83
  84 void fteqcc_testbugs()
  85 {
  86         float a, b;
  87
  88         if(!autocvar_developer_fteqccbugs)
  89                 return;
  90
  91         dprint("*** fteqcc test: checking for bugs...\n");
  92
  93         a = 1;
  94         b = 5;
  95         if(sqrt(a) - sqrt(b - a) == 0)
  96                 dprint("*** fteqcc test: found same-function-twice bug\n");
  97         else
  98                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  99
 100         world.cnt = -10;
 101         world.enemy = world;
 102         world.enemy.cnt += 10;
 103         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 104                 dprint("*** fteqcc test: found += bug\n");
 105         else
 106                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 107         world.cnt = 0;
 108 }
 109
 110 void GotoFirstMap()
 111 {
 112         float n;
 113         if(autocvar__sv_init)
 114         {
 115                 // cvar_set("_sv_init", "0");
 116                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 117                 // to this "init" map on a dedicated server will cause no permanent
 118                 // harm
 119                 if(autocvar_g_maplist_shuffle)
 120                         ShuffleMaplist();
 121                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 122                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 123
 124                 MapInfo_Enumerate();
 125                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 126
 127                 if(!DoNextMapOverride(1))
 128                         GotoNextMap(1);
 129
 130                 return;
 131         }
 132
 133         if(time < 5)
 134         {
 135                 self.nextthink = time;
 136         }
 137         else
 138         {
 139                 self.nextthink = time + 1;
 140                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 141         }
 142 }
 143
 144 void cvar_changes_init()
 145 {
 146         float h;
 147         string k, v, d;
 148         float n, i, adding, pureadding;
 149
 150         if(cvar_changes)
 151                 strunzone(cvar_changes);
 152         cvar_changes = string_null;
 153         if(cvar_purechanges)
 154                 strunzone(cvar_purechanges);
 155         cvar_purechanges = string_null;
 156         cvar_purechanges_count = 0;
 157
 158         h = buf_create();
 159         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 160         n = buf_getsize(h);
 161
 162         adding = TRUE;
 163         pureadding = TRUE;
 164
 165         for(i = 0; i < n; ++i)
 166         {
 167                 k = bufstr_get(h, i);
 168
 169 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 170 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 171 #define BADCVAR(p) if(k == p) continue
 172
 173                 // general excludes and namespaces for server admin used cvars
 174                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 175
 176                 // internal
 177                 BADPREFIX("csqc_");
 178                 BADPREFIX("cvar_check_");
 179                 BADCVAR("gamecfg");
 180                 BADCVAR("g_configversion");
 181                 BADCVAR("g_maplist_index");
 182                 BADCVAR("halflifebsp");
 183                 BADPREFIX("sv_world");
 184
 185                 // client
 186                 BADPREFIX("chase_");
 187                 BADPREFIX("cl_");
 188                 BADPREFIX("con_");
 189                 BADPREFIX("scoreboard_");
 190                 BADPREFIX("g_campaign");
 191                 BADPREFIX("g_waypointsprite_");
 192                 BADPREFIX("gl_");
 193                 BADPREFIX("joy");
 194                 BADPREFIX("hud_");
 195                 BADPREFIX("m_");
 196                 BADPREFIX("menu_");
 197                 BADPREFIX("net_slist_");
 198                 BADPREFIX("r_");
 199                 BADPREFIX("sbar_");
 200                 BADPREFIX("scr_");
 201                 BADPREFIX("snd_");
 202                 BADPREFIX("show");
 203                 BADPREFIX("sensitivity");
 204                 BADPREFIX("userbind");
 205                 BADPREFIX("v_");
 206                 BADPREFIX("vid_");
 207                 BADPREFIX("crosshair");
 208                 BADCVAR("mod_q3bsp_lightmapmergepower");
 209                 BADCVAR("mod_q3bsp_nolightmaps");
 210                 BADCVAR("fov");
 211                 BADCVAR("mastervolume");
 212                 BADCVAR("volume");
 213                 BADCVAR("bgmvolume");
 214
 215                 // private
 216                 BADCVAR("developer");
 217                 BADCVAR("log_dest_udp");
 218                 BADCVAR("net_address");
 219                 BADCVAR("net_address_ipv6");
 220                 BADCVAR("port");
 221                 BADCVAR("savedgamecfg");
 222                 BADCVAR("serverconfig");
 223                 BADCVAR("sv_autoscreenshot");
 224                 BADCVAR("sv_heartbeatperiod");
 225                 BADCVAR("sv_vote_master_password");
 226                 BADCVAR("sys_colortranslation");
 227                 BADCVAR("sys_specialcharactertranslation");
 228                 BADCVAR("timeformat");
 229                 BADCVAR("timestamps");
 230                 BADPREFIX("developer_");
 231                 BADPREFIX("g_ban_");
 232                 BADPREFIX("g_banned_list");
 233                 BADPREFIX("g_chat_flood_");
 234                 BADPREFIX("g_ghost_items");
 235                 BADPREFIX("g_playerstats_");
 236                 BADPREFIX("g_respawn_ghosts");
 237                 BADPREFIX("g_voice_flood_");
 238                 BADPREFIX("log_file");
 239                 BADPREFIX("rcon_");
 240                 BADPREFIX("sv_allowdownloads");
 241                 BADPREFIX("sv_autodemo");
 242                 BADPREFIX("sv_curl_");
 243                 BADPREFIX("sv_eventlog");
 244                 BADPREFIX("sv_logscores_");
 245                 BADPREFIX("sv_master");
 246                 BADPREFIX("sv_weaponstats_");
 247                 BADPREFIX("sv_waypointsprite_");
 248                 BADCVAR("rescan_pending");
 249
 250                 // these can contain player IDs, so better hide
 251                 BADPREFIX("g_forced_team_");
 252
 253                 // mapinfo
 254                 BADCVAR("fraglimit");
 255                 BADCVAR("g_assault");
 256                 BADCVAR("g_ca");
 257                 BADCVAR("g_ca_teams");
 258                 BADCVAR("g_ctf");
 259                 BADCVAR("g_cts");
 260                 BADCVAR("g_dm");
 261                 BADCVAR("g_domination");
 262                 BADCVAR("g_domination_default_teams");
 263                 BADCVAR("g_freezetag");
 264                 BADCVAR("g_freezetag_teams");
 265                 BADCVAR("g_keepaway");
 266                 BADCVAR("g_keyhunt");
 267                 BADCVAR("g_keyhunt_teams");
 268                 BADCVAR("g_lms");
 269                 BADCVAR("g_nexball");
 270                 BADCVAR("g_onslaught");
 271                 BADCVAR("g_race");
 272                 BADCVAR("g_race_qualifying_timelimit");
 273                 BADCVAR("g_tdm");
 274                 BADCVAR("g_tdm_teams");
 275                 BADCVAR("leadlimit");
 276                 BADCVAR("nextmap");
 277                 BADCVAR("teamplay");
 278                 BADCVAR("timelimit");
 279
 280                 // long
 281                 BADCVAR("hostname");
 282                 BADCVAR("g_maplist");
 283                 BADCVAR("g_maplist_mostrecent");
 284                 BADCVAR("sv_motd");
 285
 286                 v = cvar_string(k);
 287                 d = cvar_defstring(k);
 288                 if(v == d)
 289                         continue;
 290
 291                 if(adding)
 292                 {
 293                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 294                         if(strlen(cvar_changes) > 16384)
 295                         {
 296                                 cvar_changes = "// too many settings have been changed to show them here\n";
 297                                 adding = 0;
 298                         }
 299                 }
 300
 301                 // now check if the changes are actually gameplay relevant
 302
 303                 // does nothing visible
 304                 BADCVAR("captureleadlimit_override");
 305                 BADCVAR("g_balance_kill_delay");
 306                 BADCVAR("g_ca_point_leadlimit");
 307                 BADCVAR("g_ctf_captimerecord_always");
 308                 BADCVAR("g_ctf_flag_glowtrails");
 309                 BADCVAR("g_ctf_flag_pickup_verbosename");
 310                 BADCVAR("g_domination_point_leadlimit");
 311                 BADCVAR("g_forced_respawn");
 312                 BADCVAR("g_keyhunt_point_leadlimit");
 313                 BADPREFIX("g_mod_");
 314                 BADCVAR("g_nexball_goalleadlimit");
 315                 BADCVAR("leadlimit_and_fraglimit");
 316                 BADCVAR("leadlimit_override");
 317                 BADCVAR("pausable");
 318                 BADCVAR("sv_allow_fullbright");
 319                 BADCVAR("sv_checkforpacketsduringsleep");
 320                 BADCVAR("sv_fraginfo");
 321                 BADCVAR("sv_timeout");
 322                 BADPREFIX("sv_timeout_");
 323                 BADPREFIX("crypto_");
 324                 BADPREFIX("g_chat_");
 325                 BADPREFIX("g_ctf_captimerecord_");
 326                 BADPREFIX("g_maplist_votable_");
 327                 BADPREFIX("net_");
 328                 BADPREFIX("prvm_");
 329                 BADPREFIX("skill_");
 330                 BADPREFIX("sv_cullentities_");
 331                 BADPREFIX("sv_fraginfo_");
 332                 BADPREFIX("sv_maxidle_");
 333                 BADPREFIX("sv_vote_");
 334                 BADPREFIX("timelimit_");
 335                 BADCVAR("gameversion");
 336                 BADPREFIX("gameversion_");
 337                 BADCVAR("sv_namechangetimer");
 338
 339                 // allowed changes to server admins (please sync this to server.cfg)
 340                 // vi commands:
 341                 //   :/"impure"/,$d
 342                 //   :g!,^\/\/[^ /],d
 343                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 344                 //   :%!sort
 345                 // yes, this does contain some redundant stuff, don't really care
 346                 BADCVAR("bot_config_file");
 347                 BADCVAR("bot_number");
 348                 BADCVAR("bot_prefix");
 349                 BADCVAR("bot_suffix");
 350                 BADCVAR("capturelimit_override");
 351                 BADCVAR("fraglimit_override");
 352                 BADCVAR("gametype");
 353                 BADCVAR("g_antilag");
 354                 BADCVAR("g_balance_teams");
 355                 BADCVAR("g_balance_teams_prevent_imbalance");
 356                 BADCVAR("g_balance_teams_scorefactor");
 357                 BADCVAR("g_ban_sync_trusted_servers");
 358                 BADCVAR("g_ban_sync_uri");
 359                 BADCVAR("g_ca_teams_override");
 360                 BADCVAR("g_ctf_ignore_frags");
 361                 BADCVAR("g_domination_point_limit");
 362                 BADCVAR("g_freezetag_teams_override");
 363                 BADCVAR("g_friendlyfire");
 364                 BADCVAR("g_fullbrightitems");
 365                 BADCVAR("g_fullbrightplayers");
 366                 BADCVAR("g_keyhunt_point_limit");
 367                 BADCVAR("g_keyhunt_teams_override");
 368                 BADCVAR("g_lms_lives_override");
 369                 BADCVAR("g_maplist");
 370                 BADCVAR("g_maplist_check_waypoints");
 371                 BADCVAR("g_maplist_mostrecent_count");
 372                 BADCVAR("g_maplist_shuffle");
 373                 BADCVAR("g_maplist_votable");
 374                 BADCVAR("g_maplist_votable_abstain");
 375                 BADCVAR("g_maplist_votable_nodetail");
 376                 BADCVAR("g_maplist_votable_suggestions");
 377                 BADCVAR("g_maxplayers");
 378                 BADCVAR("g_mirrordamage");
 379                 BADCVAR("g_nexball_goallimit");
 380                 BADCVAR("g_powerups");
 381                 BADCVAR("g_start_delay");
 382                 BADCVAR("g_warmup");
 383                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 384                 BADCVAR("hostname");
 385                 BADCVAR("log_file");
 386                 BADCVAR("maxplayers");
 387                 BADCVAR("minplayers");
 388                 BADCVAR("net_address");
 389                 BADCVAR("port");
 390                 BADCVAR("rcon_password");
 391                 BADCVAR("rcon_restricted_commands");
 392                 BADCVAR("rcon_restricted_password");
 393                 BADCVAR("skill");
 394                 BADCVAR("sv_adminnick");
 395                 BADCVAR("sv_autoscreenshot");
 396                 BADCVAR("sv_autotaunt");
 397                 BADCVAR("sv_curl_defaulturl");
 398                 BADCVAR("sv_defaultcharacter");
 399                 BADCVAR("sv_defaultplayercolors");
 400                 BADCVAR("sv_defaultplayermodel");
 401                 BADCVAR("sv_defaultplayerskin");
 402                 BADCVAR("sv_maxidle");
 403                 BADCVAR("sv_maxrate");
 404                 BADCVAR("sv_motd");
 405                 BADCVAR("sv_public");
 406                 BADCVAR("sv_ready_restart");
 407                 BADCVAR("sv_status_privacy");
 408                 BADCVAR("sv_taunt");
 409                 BADCVAR("sv_vote_call");
 410                 BADCVAR("sv_vote_commands");
 411                 BADCVAR("sv_vote_majority_factor");
 412                 BADCVAR("sv_vote_master");
 413                 BADCVAR("sv_vote_master_commands");
 414                 BADCVAR("sv_vote_master_password");
 415                 BADCVAR("sv_vote_simple_majority_factor");
 416                 BADCVAR("teamplay_mode");
 417                 BADCVAR("timelimit_override");
 418                 BADCVAR("g_spawnshieldtime");
 419                 BADPREFIX("g_warmup_");
 420                 BADPREFIX("sv_ready_restart_");
 421
 422                 // mutators that announce themselves properly to the server browser
 423                 BADCVAR("g_instagib");
 424                 BADCVAR("g_new_toys");
 425                 BADCVAR("g_nix");
 426                 BADCVAR("g_grappling_hook");
 427                 BADCVAR("g_jetpack");
 428
 429 #undef BADPREFIX
 430 #undef BADCVAR
 431
 432                 if(pureadding)
 433                 {
 434                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 435                         if(strlen(cvar_purechanges) > 16384)
 436                         {
 437                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 438                                 pureadding = 0;
 439                         }
 440                 }
 441                 ++cvar_purechanges_count;
 442                 // WARNING: this variable is used for the server list
 443                 // NEVER dare to skip this code!
 444                 // Hacks to intentionally appearing as "pure server" even though you DO have
 445                 // modified settings may be punished by removal from the server list.
 446                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 447                 // though.
 448         }
 449         buf_del(h);
 450         if(cvar_changes == "")
 451                 cvar_changes = "// this server runs at default server settings\n";
 452         else
 453                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 454         cvar_changes = strzone(cvar_changes);
 455         if(cvar_purechanges == "")
 456                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 457         else
 458                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 459         cvar_purechanges = strzone(cvar_purechanges);
 460 }
 461
 462 void detect_maptype()
 463 {
 464 #if 0
 465         vector o, v;
 466         float i;
 467
 468         for(;;)
 469         {
 470                 o = world.mins;
 471                 o_x += random() * (world.maxs_x - world.mins_x);
 472                 o_y += random() * (world.maxs_y - world.mins_y);
 473                 o_z += random() * (world.maxs_z - world.mins_z);
 474
 475                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 476                 if(trace_fraction == 1)
 477                         continue;
 478
 479                 v = trace_endpos;
 480
 481                 for(i = 0; i < 64; i += 4)
 482                 {
 483                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 484         if(trace_fraction == 1)
 485                 continue;
 486                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 487                 }
 488
 489                 break;
 490         }
 491 #endif
 492 }
 493
 494 entity randomseed;
 495 float RandomSeed_Send(entity to, float sf)
 496 {
 497         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 498         WriteShort(MSG_ENTITY, self.cnt);
 499         return TRUE;
 500 }
 501 void RandomSeed_Think()
 502 {
 503         self.cnt = bound(0, floor(random() * 65536), 65535);
 504         self.nextthink = time + 5;
 505
 506         self.SendFlags |= 1;
 507 }
 508 void RandomSeed_Spawn()
 509 {
 510         randomseed = spawn();
 511         randomseed.think = RandomSeed_Think;
 512         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 513
 514         entity oldself;
 515         oldself = self;
 516         self = randomseed;
 517         self.think(); // sets random seed and nextthink
 518         self = oldself;
 519 }
 520
 521 void spawnfunc___init_dedicated_server(void)
 522 {
 523         // handler for _init/_init map (only for dedicated server initialization)
 524
 525         world_initialized = -1; // don't complain
 526         cvar = cvar_normal;
 527         cvar_string = cvar_string_normal;
 528         cvar_set = cvar_set_normal;
 529
 530         remove = remove_unsafely;
 531
 532         entity e;
 533         e = spawn();
 534         e.think = GotoFirstMap;
 535         e.nextthink = time; // this is usually 1 at this point
 536
 537         e = spawn();
 538         e.classname = "info_player_deathmatch"; // safeguard against player joining
 539
 540         self.classname = "worldspawn"; // safeguard against various stuff ;)
 541
 542         // needs to be done so early because of the constants they create
 543         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 544         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 545         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 546         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 547         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 548         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 549
 550         MapInfo_Enumerate();
 551         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 552 }
 553
 554 void Map_MarkAsRecent(string m);
 555 float world_already_spawned;
 556 void Nagger_Init();
 557 void ClientInit_Spawn();
 558 void WeaponStats_Init();
 559 void WeaponStats_Shutdown();
 560 void spawnfunc_worldspawn (void)
 561 {
 562         float fd, l, i, j, n;
 563         string s;
 564
 565         cvar = cvar_normal;
 566         cvar_string = cvar_string_normal;
 567         cvar_set = cvar_set_normal;
 568
 569         if(world_already_spawned)
 570                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 571         world_already_spawned = TRUE;
 572
 573         remove = remove_safely; // during spawning, watch what you remove!
 574
 575         check_unacceptable_compiler_bugs();
 576
 577         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 578
 579         compressShortVector_init();
 580
 581         entity head;
 582         head = nextent(world);
 583         maxclients = 0;
 584         while(head)
 585         {
 586                 ++maxclients;
 587                 head = nextent(head);
 588         }
 589
 590         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? TRUE : FALSE);
 591
 592         // needs to be done so early because of the constants they create
 593         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 594         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 595         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 596         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 597         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 598         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 599
 600         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 601
 602         TemporaryDB = db_create();
 603
 604         // 0 normal
 605         lightstyle(0, "m");
 606
 607         // 1 FLICKER (first variety)
 608         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 609
 610         // 2 SLOW STRONG PULSE
 611         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 612
 613         // 3 CANDLE (first variety)
 614         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 615
 616         // 4 FAST STROBE
 617         lightstyle(4, "mamamamamama");
 618
 619         // 5 GENTLE PULSE 1
 620         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 621
 622         // 6 FLICKER (second variety)
 623         lightstyle(6, "nmonqnmomnmomomno");
 624
 625         // 7 CANDLE (second variety)
 626         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 627
 628         // 8 CANDLE (third variety)
 629         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 630
 631         // 9 SLOW STROBE (fourth variety)
 632         lightstyle(9, "aaaaaaaazzzzzzzz");
 633
 634         // 10 FLUORESCENT FLICKER
 635         lightstyle(10, "mmamammmmammamamaaamammma");
 636
 637         // 11 SLOW PULSE NOT FADE TO BLACK
 638         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 639
 640         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 641
 642         // 63 testing
 643         lightstyle(63, "a");
 644
 645         if(autocvar_g_campaign)
 646                 CampaignPreInit();
 647
 648         Map_MarkAsRecent(mapname);
 649
 650         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 651
 652         precache_model ("null"); // we need this one before InitGameplayMode
 653         InitGameplayMode();
 654         readlevelcvars();
 655         GrappleHookInit();
 656         ElectroInit();
 657         LaserInit();
 658
 659         player_count = 0;
 660         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 661         if(bot_waypoints_for_items == 1)
 662                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 663                         bot_waypoints_for_items = 0;
 664
 665         precache();
 666
 667         WaypointSprite_Init();
 668
 669         GameLogInit(); // prepare everything
 670         // NOTE for matchid:
 671         // changing the logic generating it is okay. But:
 672         // it HAS to stay <= 64 chars
 673         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 674         if(autocvar_sv_eventlog)
 675         {
 676                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 677                 matchid = strzone(s);
 678
 679                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 680                 s = ":gameinfo:mutators:LIST";
 681
 682                 ret_string = s;
 683                 MUTATOR_CALLHOOK(BuildMutatorsString);
 684                 s = ret_string;
 685
 686                 // simple, probably not good in the mutator system
 687                 if(autocvar_g_grappling_hook)
 688                         s = strcat(s, ":grappling_hook");
 689
 690                 // initialiation stuff, not good in the mutator system
 691                 if(!autocvar_g_use_ammunition)
 692                         s = strcat(s, ":no_use_ammunition");
 693
 694                 // initialiation stuff, not good in the mutator system
 695                 if(autocvar_g_pickup_items == 0)
 696                         s = strcat(s, ":no_pickup_items");
 697                 if(autocvar_g_pickup_items > 0)
 698                         s = strcat(s, ":pickup_items");
 699
 700                 // initialiation stuff, not good in the mutator system
 701                 if(autocvar_g_weaponarena != "0")
 702                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 703
 704                 // TODO to mutator system
 705                 if(autocvar_g_norecoil)
 706                         s = strcat(s, ":norecoil");
 707
 708                 // TODO to mutator system
 709                 if(autocvar_g_powerups == 0)
 710                         s = strcat(s, ":no_powerups");
 711                 if(autocvar_g_powerups > 0)
 712                         s = strcat(s, ":powerups");
 713
 714                 GameLogEcho(s);
 715                 GameLogEcho(":gameinfo:end");
 716         }
 717         else
 718                 matchid = strzone(ftos(random()));
 719
 720         cvar_set("nextmap", "");
 721
 722         SetDefaultAlpha();
 723
 724         if(autocvar_g_campaign)
 725                 CampaignPostInit();
 726
 727         fteqcc_testbugs();
 728
 729         Ban_LoadBans();
 730
 731         MapInfo_Enumerate();
 732         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 733
 734         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 735         {
 736                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 737                 if(fd != -1)
 738                 {
 739                         while((s = fgets(fd)))
 740                         {
 741                                 l = tokenize_console(s);
 742                                 if(l < 2)
 743                                         continue;
 744                                 if(argv(0) == "cd")
 745                                 {
 746                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 747                                         print("  cdtrack ", argv(2), "\n");
 748                                 }
 749                                 else if(argv(0) == "fog")
 750                                 {
 751                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 752                                         print("  \"fog\" \"", s, "\"\n");
 753                                 }
 754                                 else if(argv(0) == "set")
 755                                 {
 756                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 757                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 758                                 }
 759                                 else if(argv(0) != "//")
 760                                 {
 761                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 762                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 763                                 }
 764                         }
 765                         fclose(fd);
 766                 }
 767         }
 768
 769         WeaponStats_Init();
 770
 771         WepSet_AddStat();
 772         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 773         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 774         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 775         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 776         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 777         Nagger_Init();
 778
 779         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 780         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 781         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 782         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 783         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 784         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 785         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 786         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 787         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 788         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 789         addstat(STAT_DAMAGE_DEALT_TOTAL, AS_INT, damage_dealt_total);
 790         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 791         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 792
 793         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 794         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 795
 796         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 797
 798         // freeze attacks
 799         addstat(STAT_FROZEN, AS_INT, frozen);
 800         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 801
 802         // g_movementspeed hack
 803         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 804         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 805         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 806         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 807         addstat(STAT_MOVEVARS_HIGHSPEED, AS_FLOAT, stat_movement_highspeed);
 808
 809         // jet pack
 810         addstat(STAT_JETPACK_ACCEL_SIDE, AS_FLOAT, stat_jetpack_accel_side);
 811         addstat(STAT_JETPACK_ACCEL_UP, AS_FLOAT, stat_jetpack_accel_up);
 812         addstat(STAT_JETPACK_ANTIGRAVITY, AS_FLOAT, stat_jetpack_antigravity);
 813         addstat(STAT_JETPACK_FUEL, AS_FLOAT, stat_jetpack_fuel);
 814         addstat(STAT_JETPACK_MAXSPEED_UP, AS_FLOAT, stat_jetpack_maxspeed_up);
 815         addstat(STAT_JETPACK_MAXSPEED_SIDE, AS_FLOAT, stat_jetpack_maxspeed_side);
 816
 817         // secrets
 818         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 819         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 820
 821         // monsters
 822         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 823         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 824
 825         // misc
 826         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 827
 828         next_pingtime = time + 5;
 829
 830         detect_maptype();
 831
 832         // set up information replies for clients and server to use
 833         maplist_reply = strzone(getmaplist());
 834         lsmaps_reply = strzone(getlsmaps());
 835         monsterlist_reply = strzone(getmonsterlist());
 836         for(i = 0; i < 10; ++i)
 837         {
 838                 s = getrecords(i);
 839                 if (s)
 840                         records_reply[i] = strzone(s);
 841         }
 842         ladder_reply = strzone(getladder());
 843         rankings_reply = strzone(getrankings());
 844
 845         // begin other init
 846         ClientInit_Spawn();
 847         RandomSeed_Spawn();
 848         PingPLReport_Spawn();
 849
 850         CheatInit();
 851
 852         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 853
 854         // fill sv_curl_serverpackages from .serverpackage files
 855         if(autocvar_sv_curl_serverpackages_auto)
 856         {
 857                 s = "";
 858                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 859                 for(i = 0; i < n; ++i)
 860                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 861                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 862                                 s = strcat(s, " ", argv(i));
 863                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 864                 if(fd >= 0)
 865                 {
 866                         j = search_getsize(fd);
 867                         for(i = 0; i < j; ++i)
 868                                 s = strcat(s, " ", search_getfilename(fd, i));
 869                         search_end(fd);
 870                 }
 871                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 872                 if(fd >= 0)
 873                 {
 874                         j = search_getsize(fd);
 875                         for(i = 0; i < j; ++i)
 876                                 s = strcat(s, " ", search_getfilename(fd, i));
 877                         search_end(fd);
 878                 }
 879                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 880         }
 881
 882         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 883         modname = "Xonotic";
 884         // physics/balance/config changes that count as mod
 885         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 886                 modname = cvar_string("g_mod_physics");
 887         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 888                 modname = cvar_string("g_mod_balance");
 889         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 890                 modname = cvar_string("g_mod_config");
 891         // extra mutators that deserve to count as mod
 892         MUTATOR_CALLHOOK(SetModname);
 893
 894         // save it for later
 895         modname = strzone(modname);
 896
 897         WinningConditionHelper(); // set worldstatus
 898
 899         world_initialized = 1;
 900 }
 901
 902 void spawnfunc_light (void)
 903 {
 904         //makestatic (self); // Who the f___ did that?
 905         remove(self);
 906 }
 907
 908 string GetGametype()
 909 {
 910         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 911 }
 912
 913 string GetMapname()
 914 {
 915         return mapname;
 916 }
 917
 918 float Map_Count, Map_Current;
 919 string Map_Current_Name;
 920
 921 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 922 float GetMaplistPosition()
 923 {
 924         float pos, idx;
 925         string map;
 926
 927         map = GetMapname();
 928         idx = autocvar_g_maplist_index;
 929
 930         if(idx >= 0)
 931                 if(idx < Map_Count)
 932                         if(map == argv(idx))
 933                                 return idx;
 934
 935         for(pos = 0; pos < Map_Count; ++pos)
 936                 if(map == argv(pos))
 937                         return pos;
 938
 939         // resume normal maplist rotation if current map is not in g_maplist
 940         return idx;
 941 }
 942
 943 float MapHasRightSize(string map)
 944 {
 945         float fh;
 946         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 947         if(autocvar_g_maplist_check_waypoints)
 948         {
 949                 dprint("checkwp "); dprint(map);
 950                 if(!fexists(strcat("maps/", map, ".waypoints")))
 951                 {
 952                         dprint(": no waypoints\n");
 953                         return FALSE;
 954                 }
 955                 dprint(": has waypoints\n");
 956         }
 957
 958         // open map size restriction file
 959         dprint("opensize "); dprint(map);
 960         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 961         if(fh >= 0)
 962         {
 963                 float mapmin, mapmax;
 964                 dprint(": ok, ");
 965                 mapmin = stof(fgets(fh));
 966                 mapmax = stof(fgets(fh));
 967                 fclose(fh);
 968                 if(player_count < mapmin)
 969                 {
 970                         dprint("not enough\n");
 971                         return FALSE;
 972                 }
 973                 if(player_count > mapmax)
 974                 {
 975                         dprint("too many\n");
 976                         return FALSE;
 977                 }
 978                 dprint("right size\n");
 979                 return TRUE;
 980         }
 981         dprint(": not found\n");
 982         return TRUE;
 983 }
 984
 985 string Map_Filename(float position)
 986 {
 987         return strcat("maps/", argv(position), ".bsp");
 988 }
 989
 990 string strwords(string s, float w)
 991 {
 992         float endpos;
 993         for(endpos = 0; w && endpos >= 0; --w)
 994                 endpos = strstrofs(s, " ", endpos + 1);
 995         if(endpos < 0)
 996                 return s;
 997         else
 998                 return substring(s, 0, endpos);
 999 }
1000
1001 float strhasword(string s, string w)
1002 {
1003         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1004 }
1005
1006 void Map_MarkAsRecent(string m)
1007 {
1008         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1009 }
1010
1011 float Map_IsRecent(string m)
1012 {
1013         return strhasword(autocvar_g_maplist_mostrecent, m);
1014 }
1015
1016 float Map_Check(float position, float pass)
1017 {
1018         string filename;
1019         string map_next;
1020         map_next = argv(position);
1021         if(pass <= 1)
1022         {
1023                 if(Map_IsRecent(map_next))
1024                         return 0;
1025         }
1026         filename = Map_Filename(position);
1027         if(MapInfo_CheckMap(map_next))
1028         {
1029                 if(pass == 2)
1030                         return 1;
1031                 if(MapHasRightSize(map_next))
1032                         return 1;
1033                 return 0;
1034         }
1035         else
1036                 dprint( "Couldn't select '", filename, "'..\n" );
1037
1038         return 0;
1039 }
1040
1041 void Map_Goto_SetStr(string nextmapname)
1042 {
1043         if(getmapname_stored != "")
1044                 strunzone(getmapname_stored);
1045         if(nextmapname == "")
1046                 getmapname_stored = "";
1047         else
1048                 getmapname_stored = strzone(nextmapname);
1049 }
1050
1051 void Map_Goto_SetFloat(float position)
1052 {
1053         cvar_set("g_maplist_index", ftos(position));
1054         Map_Goto_SetStr(argv(position));
1055 }
1056
1057 void Map_Goto(float reinit)
1058 {
1059         MapInfo_LoadMap(getmapname_stored, reinit);
1060 }
1061
1062 // return codes of map selectors:
1063 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1064 //   -2 = permanent failure
1065 float() MaplistMethod_Iterate = // usual method
1066 {
1067         float pass, i;
1068
1069         dprint("Trying MaplistMethod_Iterate\n");
1070
1071         for(pass = 1; pass <= 2; ++pass)
1072         {
1073                 for(i = 1; i < Map_Count; ++i)
1074                 {
1075                         float mapindex;
1076                         mapindex = mod(i + Map_Current, Map_Count);
1077                         if(Map_Check(mapindex, pass))
1078                                 return mapindex;
1079                 }
1080         }
1081         return -1;
1082 }
1083
1084 float() MaplistMethod_Repeat = // fallback method
1085 {
1086         dprint("Trying MaplistMethod_Repeat\n");
1087
1088         if(Map_Check(Map_Current, 2))
1089                 return Map_Current;
1090         return -2;
1091 }
1092
1093 float() MaplistMethod_Random = // random map selection
1094 {
1095         float i, imax;
1096
1097         dprint("Trying MaplistMethod_Random\n");
1098
1099         imax = 42;
1100
1101         for(i = 0; i <= imax; ++i)
1102         {
1103                 float mapindex;
1104                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1105                 if(Map_Check(mapindex, 1))
1106                         return mapindex;
1107         }
1108         return -1;
1109 }
1110
1111 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1112 // the exponent sets a bias on the map selection:
1113 // the higher the exponent, the less likely "shortly repeated" same maps are
1114 {
1115         float i, j, imax, insertpos;
1116
1117         dprint("Trying MaplistMethod_Shuffle\n");
1118
1119         imax = 42;
1120
1121         for(i = 0; i <= imax; ++i)
1122         {
1123                 string newlist;
1124
1125                 // now reinsert this at another position
1126                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1127                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1128                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1129                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1130
1131                 // insert the current map there
1132                 newlist = "";
1133                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1134                         newlist = strcat(newlist, " ", argv(j));
1135                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1136                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1137                         newlist = strcat(newlist, " ", argv(j));
1138                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1139                 cvar_set("g_maplist", newlist);
1140                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1141
1142                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1143                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1144                 if(Map_Check(Map_Current, 1))
1145                         return Map_Current;
1146         }
1147         return -1;
1148 }
1149
1150 void Maplist_Init()
1151 {
1152         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1153         float i;
1154         for (i = 0; i < Map_Count; ++i)
1155                 if (Map_Check(i, 2))
1156                         break;
1157         if (i == Map_Count)
1158         {
1159                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1160                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1161                 if(autocvar_g_maplist_shuffle)
1162                         ShuffleMaplist();
1163                 localcmd("\nmenu_cmd sync\n");
1164                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1165         }
1166         if(Map_Count == 0)
1167                 error("empty maplist, cannot select a new map");
1168         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1169
1170         if(Map_Current_Name)
1171                 strunzone(Map_Current_Name);
1172         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1173         // this may or may not be correct, but who cares, in the worst case a map
1174         // isn't chosen in the first pass that should have been
1175 }
1176
1177 string GetNextMap()
1178 {
1179         float nextMap;
1180
1181         Maplist_Init();
1182         nextMap = -1;
1183
1184         if(nextMap == -1)
1185                 if(autocvar_g_maplist_shuffle > 0)
1186                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1187
1188         if(nextMap == -1)
1189                 if(autocvar_g_maplist_selectrandom)
1190                         nextMap = MaplistMethod_Random();
1191
1192         if(nextMap == -1)
1193                 nextMap = MaplistMethod_Iterate();
1194
1195         if(nextMap == -1)
1196                 nextMap = MaplistMethod_Repeat();
1197
1198         if(nextMap >= 0)
1199         {
1200                 Map_Goto_SetFloat(nextMap);
1201                 return getmapname_stored;
1202         }
1203
1204         return "";
1205 }
1206
1207 float DoNextMapOverride(float reinit)
1208 {
1209         if(autocvar_g_campaign)
1210         {
1211                 CampaignPostIntermission();
1212                 alreadychangedlevel = TRUE;
1213                 return TRUE;
1214         }
1215         if(autocvar_quit_when_empty)
1216         {
1217                 if(player_count <= currentbots)
1218                 {
1219                         localcmd("quit\n");
1220                         alreadychangedlevel = TRUE;
1221                         return TRUE;
1222                 }
1223         }
1224         if(autocvar_quit_and_redirect != "")
1225         {
1226                 redirection_target = strzone(autocvar_quit_and_redirect);
1227                 alreadychangedlevel = TRUE;
1228                 return TRUE;
1229         }
1230         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1231         {
1232                 localcmd("restart\n");
1233                 alreadychangedlevel = TRUE;
1234                 return TRUE;
1235         }
1236         if(autocvar_nextmap != "")
1237         {
1238                 string m;
1239                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1240                 cvar_set("nextmap",m);
1241
1242                 if(!m || gametypevote)
1243                         return FALSE;
1244                 if(autocvar_sv_vote_gametype)
1245                 {
1246                         Map_Goto_SetStr(m);
1247                         return FALSE;
1248                 }
1249
1250                 if(MapInfo_CheckMap(m))
1251                 {
1252                         Map_Goto_SetStr(m);
1253                         Map_Goto(reinit);
1254                         alreadychangedlevel = TRUE;
1255                         return TRUE;
1256                 }
1257         }
1258         if(!reinit && autocvar_lastlevel)
1259         {
1260                 cvar_settemp_restore();
1261                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1262                 alreadychangedlevel = TRUE;
1263                 return TRUE;
1264         }
1265         return FALSE;
1266 }
1267
1268 void GotoNextMap(float reinit)
1269 {
1270         //string nextmap;
1271         //float n, nummaps;
1272         //string s;
1273         if (alreadychangedlevel)
1274                 return;
1275         alreadychangedlevel = TRUE;
1276
1277         string nextMap;
1278
1279         nextMap = GetNextMap();
1280         if(nextMap == "")
1281                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1282         Map_Goto(reinit);
1283 }
1284
1285
1286 /*
1287 ============
1288 IntermissionThink
1289
1290 When the player presses attack or jump, change to the next level
1291 ============
1292 */
1293 .float autoscreenshot;
1294 void IntermissionThink()
1295 {
1296         FixIntermissionClient(self);
1297
1298         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1299         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1300
1301         if( (server_screenshot || client_screenshot)
1302                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1303         {
1304                 self.autoscreenshot = -1;
1305                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(FALSE, "%s"))); }
1306                 return;
1307         }
1308
1309         if (time < intermission_exittime)
1310                 return;
1311
1312         if(!mapvote_initialized)
1313                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1314                         return;
1315
1316         MapVote_Start();
1317 }
1318
1319 /*
1320 ============
1321 FindIntermission
1322
1323 Returns the entity to view from
1324 ============
1325 */
1326 /*
1327 entity FindIntermission()
1328 {
1329         local   entity spot;
1330         local   float cyc;
1331
1332 // look for info_intermission first
1333         spot = find (world, classname, "info_intermission");
1334         if (spot)
1335         {       // pick a random one
1336                 cyc = random() * 4;
1337                 while (cyc > 1)
1338                 {
1339                         spot = find (spot, classname, "info_intermission");
1340                         if (!spot)
1341                                 spot = find (spot, classname, "info_intermission");
1342                         cyc = cyc - 1;
1343                 }
1344                 return spot;
1345         }
1346
1347 // then look for the start position
1348         spot = find (world, classname, "info_player_start");
1349         if (spot)
1350                 return spot;
1351
1352 // testinfo_player_start is only found in regioned levels
1353         spot = find (world, classname, "testplayerstart");
1354         if (spot)
1355                 return spot;
1356
1357 // then look for the start position
1358         spot = find (world, classname, "info_player_deathmatch");
1359         if (spot)
1360                 return spot;
1361
1362         //objerror ("FindIntermission: no spot");
1363         return world;
1364 }
1365 */
1366
1367 /*
1368 ===============================================================================
1369
1370 RULES
1371
1372 ===============================================================================
1373 */
1374
1375 void DumpStats(float final)
1376 {
1377         float file;
1378         string s;
1379         float to_console;
1380         float to_eventlog;
1381         float to_file;
1382         float i;
1383
1384         to_console = autocvar_sv_logscores_console;
1385         to_eventlog = autocvar_sv_eventlog;
1386         to_file = autocvar_sv_logscores_file;
1387
1388         if(!final)
1389         {
1390                 to_console = TRUE; // always print printstats replies
1391                 to_eventlog = FALSE; // but never print them to the event log
1392         }
1393
1394         if(to_eventlog)
1395                 if(autocvar_sv_eventlog_console)
1396                         to_console = FALSE; // otherwise we get the output twice
1397
1398         if(final)
1399                 s = ":scores:";
1400         else
1401                 s = ":status:";
1402         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1403
1404         if(to_console)
1405                 print(s, "\n");
1406         if(to_eventlog)
1407                 GameLogEcho(s);
1408
1409         file = -1;
1410         if(to_file)
1411         {
1412                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1413                 if(file == -1)
1414                         to_file = FALSE;
1415                 else
1416                         fputs(file, strcat(s, "\n"));
1417         }
1418
1419         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1420         if(to_console)
1421                 print(s, "\n");
1422         if(to_eventlog)
1423                 GameLogEcho(s);
1424         if(to_file)
1425                 fputs(file, strcat(s, "\n"));
1426
1427         FOR_EACH_CLIENT(other)
1428         {
1429                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1430                 {
1431                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1432                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1433                         if(IS_PLAYER(other) || other.caplayer == 1 || g_lms)
1434                                 s = strcat(s, ftos(other.team), ":");
1435                         else
1436                                 s = strcat(s, "spectator:");
1437
1438                         if(to_console)
1439                                 print(s, other.netname, "\n");
1440                         if(to_eventlog)
1441                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1442                         if(to_file)
1443                                 fputs(file, strcat(s, other.netname, "\n"));
1444                 }
1445         }
1446
1447         if(teamplay)
1448         {
1449                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1450                 if(to_console)
1451                         print(s, "\n");
1452                 if(to_eventlog)
1453                         GameLogEcho(s);
1454                 if(to_file)
1455                         fputs(file, strcat(s, "\n"));
1456
1457                 for(i = 1; i < 16; ++i)
1458                 {
1459                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1460                         s = strcat(s, ":", ftos(i));
1461                         if(to_console)
1462                                 print(s, "\n");
1463                         if(to_eventlog)
1464                                 GameLogEcho(s);
1465                         if(to_file)
1466                                 fputs(file, strcat(s, "\n"));
1467                 }
1468         }
1469
1470         if(to_console)
1471                 print(":end\n");
1472         if(to_eventlog)
1473                 GameLogEcho(":end");
1474         if(to_file)
1475         {
1476                 fputs(file, ":end\n");
1477                 fclose(file);
1478         }
1479 }
1480
1481 void FixIntermissionClient(entity e)
1482 {
1483         string s;
1484         if(!e.autoscreenshot) // initial call
1485         {
1486                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1487                 e.health = -2342;
1488                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1489                 e.solid = SOLID_NOT;
1490                 e.movetype = MOVETYPE_NONE;
1491                 e.takedamage = DAMAGE_NO;
1492                 if(e.weaponentity)
1493                 {
1494                         e.weaponentity.effects = EF_NODRAW;
1495                         if (e.weaponentity.weaponentity)
1496                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1497                 }
1498                 if(IS_REAL_CLIENT(e))
1499                 {
1500                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1501                         s = autocvar_sv_intermission_cdtrack;
1502                         if(s != "")
1503                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1504                         msg_entity = e;
1505                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1506                 }
1507         }
1508 }
1509
1510 /*
1511 go to the next level for deathmatch
1512 only called if a time or frag limit has expired
1513 */
1514 void NextLevel()
1515 {
1516         gameover = TRUE;
1517
1518         intermission_running = 1;
1519
1520 // enforce a wait time before allowing changelevel
1521         if(player_count > 0)
1522                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1523         else
1524                 intermission_exittime = -1;
1525
1526         /*
1527         WriteByte (MSG_ALL, SVC_CDTRACK);
1528         WriteByte (MSG_ALL, 3);
1529         WriteByte (MSG_ALL, 3);
1530         // done in FixIntermission
1531         */
1532
1533         //pos = FindIntermission ();
1534
1535         VoteReset();
1536
1537         DumpStats(TRUE);
1538
1539         // send statistics
1540         entity e;
1541         PlayerStats_EndMatch(1);
1542         FOR_EACH_CLIENT(e)
1543                 PlayerStats_AddGlobalInfo(e);
1544         PlayerStats_Shutdown();
1545         WeaponStats_Shutdown();
1546
1547         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1548
1549         if(autocvar_sv_eventlog)
1550                 GameLogEcho(":gameover");
1551
1552         GameLogClose();
1553
1554         FOR_EACH_PLAYER(other) {
1555                 FixIntermissionClient(other);
1556                 if(other.winning)
1557                         bprint(other.netname, " ^7wins.\n");
1558         }
1559
1560         if(autocvar_g_campaign)
1561                 CampaignPreIntermission();
1562
1563         MUTATOR_CALLHOOK(MatchEnd);
1564
1565         localcmd("\nsv_hook_gameend\n");
1566 }
1567
1568 /*
1569 ============
1570 CheckRules_Player
1571
1572 Exit deathmatch games upon conditions
1573 ============
1574 */
1575 void CheckRules_Player()
1576 {
1577         if (gameover)   // someone else quit the game already
1578                 return;
1579
1580         if(self.deadflag == DEAD_NO)
1581                 self.play_time += frametime;
1582
1583         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1584         //   (div0: and that in CheckRules_World please)
1585 }
1586
1587 float checkrules_equality;
1588 float checkrules_suddendeathwarning;
1589 float checkrules_suddendeathend;
1590 float checkrules_overtimesadded; //how many overtimes have been already added
1591
1592 const float WINNING_NO = 0; // no winner, but time limits may terminate the game
1593 const float WINNING_YES = 1; // winner found
1594 const float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1595 const float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1596
1597 float InitiateSuddenDeath()
1598 {
1599         // Check first whether normal overtimes could be added before initiating suddendeath mode
1600         // - for this timelimit_overtime needs to be >0 of course
1601         // - also check the winning condition calculated in the previous frame and only add normal overtime
1602         //   again, if at the point at which timelimit would be extended again, still no winner was found
1603         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1604         {
1605                 return 1; // need to call InitiateOvertime later
1606         }
1607         else
1608         {
1609                 if(!checkrules_suddendeathend)
1610                 {
1611                         if(autocvar_g_campaign)
1612                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1613                         else
1614                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1615                         if(g_race && !g_race_qualifying)
1616                                 race_StartCompleting();
1617                 }
1618                 return 0;
1619         }
1620 }
1621
1622 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1623 {
1624         ++checkrules_overtimesadded;
1625         //add one more overtime by simply extending the timelimit
1626         float tl;
1627         tl = autocvar_timelimit;
1628         tl += autocvar_timelimit_overtime;
1629         cvar_set("timelimit", ftos(tl));
1630
1631         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1632 }
1633
1634 float GetWinningCode(float fraglimitreached, float equality)
1635 {
1636         if(autocvar_g_campaign == 1)
1637                 if(fraglimitreached)
1638                         return WINNING_YES;
1639                 else
1640                         return WINNING_NO;
1641
1642         else
1643                 if(equality)
1644                         if(fraglimitreached)
1645                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1646                         else
1647                                 return WINNING_NEVER;
1648                 else
1649                         if(fraglimitreached)
1650                                 return WINNING_YES;
1651                         else
1652                                 return WINNING_NO;
1653 }
1654
1655 // set the .winning flag for exactly those players with a given field value
1656 void SetWinners(.float field, float value)
1657 {
1658         entity head;
1659         FOR_EACH_PLAYER(head)
1660                 head.winning = (head.field == value);
1661 }
1662
1663 // set the .winning flag for those players with a given field value
1664 void AddWinners(.float field, float value)
1665 {
1666         entity head;
1667         FOR_EACH_PLAYER(head)
1668                 if(head.field == value)
1669                         head.winning = 1;
1670 }
1671
1672 // clear the .winning flags
1673 void ClearWinners(void)
1674 {
1675         entity head;
1676         FOR_EACH_PLAYER(head)
1677                 head.winning = 0;
1678 }
1679
1680 // Onslaught winning condition:
1681 // game terminates if only one team has a working generator (or none)
1682 float WinningCondition_Onslaught()
1683 {
1684         entity head;
1685         float t1, t2, t3, t4;
1686
1687         WinningConditionHelper(); // set worldstatus
1688
1689         if(warmup_stage)
1690                 return WINNING_NO;
1691
1692         // first check if the game has ended
1693         t1 = t2 = t3 = t4 = 0;
1694         head = find(world, classname, "onslaught_generator");
1695         while (head)
1696         {
1697                 if (head.health > 0)
1698                 {
1699                         if (head.team == NUM_TEAM_1) t1 = 1;
1700                         if (head.team == NUM_TEAM_2) t2 = 1;
1701                         if (head.team == NUM_TEAM_3) t3 = 1;
1702                         if (head.team == NUM_TEAM_4) t4 = 1;
1703                 }
1704                 head = find(head, classname, "onslaught_generator");
1705         }
1706         if (t1 + t2 + t3 + t4 < 2)
1707         {
1708                 // game over, only one team remains (or none)
1709                 ClearWinners();
1710                 if (t1) SetWinners(team, NUM_TEAM_1);
1711                 if (t2) SetWinners(team, NUM_TEAM_2);
1712                 if (t3) SetWinners(team, NUM_TEAM_3);
1713                 if (t4) SetWinners(team, NUM_TEAM_4);
1714                 dprint("Have a winner, ending game.\n");
1715                 return WINNING_YES;
1716         }
1717
1718         // Two or more teams remain
1719         return WINNING_NO;
1720 }
1721
1722 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1723 // they win. Otherwise the defending team wins once the timelimit passes.
1724 void assault_new_round();
1725 float WinningCondition_Assault()
1726 {
1727         float status;
1728
1729         WinningConditionHelper(); // set worldstatus
1730
1731         status = WINNING_NO;
1732         // as the timelimit has not yet passed just assume the defending team will win
1733         if(assault_attacker_team == NUM_TEAM_1)
1734         {
1735                 SetWinners(team, NUM_TEAM_2);
1736         }
1737         else
1738         {
1739                 SetWinners(team, NUM_TEAM_1);
1740         }
1741
1742         entity ent;
1743         ent = find(world, classname, "target_assault_roundend");
1744         if(ent)
1745         {
1746                 if(ent.winning) // round end has been triggered by attacking team
1747                 {
1748                         bprint("ASSAULT: round completed...\n");
1749                         SetWinners(team, assault_attacker_team);
1750
1751                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1752
1753                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1754                         {
1755                                 status = WINNING_YES;
1756                         }
1757                         else
1758                         {
1759                                 entity oldself;
1760                                 oldself = self;
1761                                 self = ent;
1762                                 assault_new_round();
1763                                 self = oldself;
1764                         }
1765                 }
1766         }
1767
1768         return status;
1769 }
1770
1771 // LMS winning condition: game terminates if and only if there's at most one
1772 // one player who's living lives. Top two scores being equal cancels the time
1773 // limit.
1774 float WinningCondition_LMS()
1775 {
1776         entity head, head2;
1777         float have_player;
1778         float have_players;
1779         float l;
1780
1781         have_player = FALSE;
1782         have_players = FALSE;
1783         l = LMS_NewPlayerLives();
1784
1785         head = find(world, classname, "player");
1786         if(head)
1787                 have_player = TRUE;
1788         head2 = find(head, classname, "player");
1789         if(head2)
1790                 have_players = TRUE;
1791
1792         if(have_player)
1793         {
1794                 // we have at least one player
1795                 if(have_players)
1796                 {
1797                         // two or more active players - continue with the game
1798                 }
1799                 else
1800                 {
1801                         // exactly one player?
1802
1803                         ClearWinners();
1804                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1805
1806                         if(l)
1807                         {
1808                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1809                                 return WINNING_NO;
1810                         }
1811                         else
1812                         {
1813                                 // a winner!
1814                                 // and assign him his first place
1815                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1816                                 return WINNING_YES;
1817                         }
1818                 }
1819         }
1820         else
1821         {
1822                 // nobody is playing at all...
1823                 if(l)
1824                 {
1825                         // wait for players...
1826                 }
1827                 else
1828                 {
1829                         // SNAFU (maybe a draw game?)
1830                         ClearWinners();
1831                         dprint("No players, ending game.\n");
1832                         return WINNING_YES;
1833                 }
1834         }
1835
1836         // When we get here, we have at least two players who are actually LIVING,
1837         // now check if the top two players have equal score.
1838         WinningConditionHelper();
1839
1840         ClearWinners();
1841         if(WinningConditionHelper_winner)
1842                 WinningConditionHelper_winner.winning = TRUE;
1843         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1844                 return WINNING_NEVER;
1845
1846         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1847         return WINNING_NO;
1848 }
1849
1850 void ShuffleMaplist()
1851 {
1852         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1853 }
1854
1855 float leaderfrags;
1856 float WinningCondition_Scores(float limit, float leadlimit)
1857 {
1858         float limitreached;
1859
1860         // TODO make everything use THIS winning condition (except LMS)
1861         WinningConditionHelper();
1862
1863         if(teamplay)
1864         {
1865                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1866                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1867                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1868                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1869         }
1870
1871         ClearWinners();
1872         if(WinningConditionHelper_winner)
1873                 WinningConditionHelper_winner.winning = 1;
1874         if(WinningConditionHelper_winnerteam >= 0)
1875                 SetWinners(team, WinningConditionHelper_winnerteam);
1876
1877         if(WinningConditionHelper_lowerisbetter)
1878         {
1879                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1880                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1881                 limit = -limit;
1882         }
1883
1884         if(WinningConditionHelper_zeroisworst)
1885                 leadlimit = 0; // not supported in this mode
1886
1887         if(g_dm || g_tdm || g_ca || g_freezetag || (g_race && !g_race_qualifying) || g_nexball)
1888         // these modes always score in increments of 1, thus this makes sense
1889         {
1890                 if(leaderfrags != WinningConditionHelper_topscore)
1891                 {
1892                         leaderfrags = WinningConditionHelper_topscore;
1893
1894                         if (limit)
1895                         if (leaderfrags == limit - 1)
1896                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1897                         else if (leaderfrags == limit - 2)
1898                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1899                         else if (leaderfrags == limit - 3)
1900                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1901                 }
1902         }
1903
1904         limitreached = FALSE;
1905         if(limit)
1906                 if(WinningConditionHelper_topscore >= limit)
1907                         limitreached = TRUE;
1908         if(leadlimit)
1909         {
1910                 float leadlimitreached;
1911                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1912                 if(autocvar_leadlimit_and_fraglimit)
1913                         limitreached = (limitreached && leadlimitreached);
1914                 else
1915                         limitreached = (limitreached || leadlimitreached);
1916         }
1917
1918         if(limit)
1919                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1920
1921         return GetWinningCode(
1922                 WinningConditionHelper_topscore && limitreached,
1923                 WinningConditionHelper_equality
1924         );
1925 }
1926
1927 float WinningCondition_Race(float fraglimit)
1928 {
1929         float wc;
1930         entity p;
1931         float n, c;
1932
1933         n = 0;
1934         c = 0;
1935         FOR_EACH_PLAYER(p)
1936         {
1937                 ++n;
1938                 if(p.race_completed)
1939                         ++c;
1940         }
1941         if(n && (n == c))
1942                 return WINNING_YES;
1943         wc = WinningCondition_Scores(fraglimit, 0);
1944
1945         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1946         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1947         // do NOT support equality when the laps are all raced!
1948                 return WINNING_STARTSUDDENDEATHOVERTIME;
1949         else
1950                 return WINNING_NEVER;
1951 }
1952
1953 float WinningCondition_QualifyingThenRace(float limit)
1954 {
1955         float wc;
1956         wc = WinningCondition_Scores(limit, 0);
1957
1958         // NEVER initiate overtime
1959         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1960         {
1961                 return WINNING_YES;
1962         }
1963
1964         return wc;
1965 }
1966
1967 float WinningCondition_RanOutOfSpawns()
1968 {
1969         entity head;
1970
1971         if(have_team_spawns <= 0)
1972                 return WINNING_NO;
1973
1974         if(autocvar_g_spawn_useallspawns <= 0)
1975                 return WINNING_NO;
1976
1977         if(!some_spawn_has_been_used)
1978                 return WINNING_NO;
1979
1980         team1_score = team2_score = team3_score = team4_score = 0;
1981
1982         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1983         {
1984                 if(head.team == NUM_TEAM_1)
1985                         team1_score = 1;
1986                 else if(head.team == NUM_TEAM_2)
1987                         team2_score = 1;
1988                 else if(head.team == NUM_TEAM_3)
1989                         team3_score = 1;
1990                 else if(head.team == NUM_TEAM_4)
1991                         team4_score = 1;
1992         }
1993
1994         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1995         {
1996                 if(head.team == NUM_TEAM_1)
1997                         team1_score = 1;
1998                 else if(head.team == NUM_TEAM_2)
1999                         team2_score = 1;
2000                 else if(head.team == NUM_TEAM_3)
2001                         team3_score = 1;
2002                 else if(head.team == NUM_TEAM_4)
2003                         team4_score = 1;
2004         }
2005
2006         ClearWinners();
2007         if(team1_score + team2_score + team3_score + team4_score == 0)
2008         {
2009                 checkrules_equality = TRUE;
2010                 return WINNING_YES;
2011         }
2012         else if(team1_score + team2_score + team3_score + team4_score == 1)
2013         {
2014                 float t, i;
2015                 if(team1_score)
2016                         t = NUM_TEAM_1;
2017                 else if(team2_score)
2018                         t = NUM_TEAM_2;
2019                 else if(team3_score)
2020                         t = NUM_TEAM_3;
2021                 else // if(team4_score)
2022                         t = NUM_TEAM_4;
2023                 CheckAllowedTeams(world);
2024                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2025                 {
2026                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2027                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2028                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2029                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2030                 }
2031
2032                 AddWinners(team, t);
2033                 return WINNING_YES;
2034         }
2035         else
2036                 return WINNING_NO;
2037 }
2038
2039 /*
2040 ============
2041 CheckRules_World
2042
2043 Exit deathmatch games upon conditions
2044 ============
2045 */
2046 void ReadyRestart();
2047 void CheckRules_World()
2048 {
2049         float timelimit;
2050         float fraglimit;
2051         float leadlimit;
2052
2053         VoteThink();
2054         MapVote_Think();
2055
2056         SetDefaultAlpha();
2057
2058         if (gameover)   // someone else quit the game already
2059         {
2060                 if(player_count == 0) // Nobody there? Then let's go to the next map
2061                         MapVote_Start();
2062                         // this will actually check the player count in the next frame
2063                         // again, but this shouldn't hurt
2064                 return;
2065         }
2066
2067         timelimit = autocvar_timelimit * 60;
2068         fraglimit = autocvar_fraglimit;
2069         leadlimit = autocvar_leadlimit;
2070
2071         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2072         {
2073                 if(timelimit > 0)
2074                         timelimit = 0; // timelimit is not made for warmup
2075                 if(fraglimit > 0)
2076                         fraglimit = 0; // no fraglimit for now
2077                 leadlimit = 0; // no leadlimit for now
2078         }
2079
2080         if(timelimit > 0)
2081         {
2082                 timelimit += game_starttime;
2083         }
2084         else if (timelimit < 0)
2085         {
2086                 // endmatch
2087                 NextLevel();
2088                 return;
2089         }
2090
2091         if(g_onslaught)
2092                 timelimit = 0; // ONS has its own overtime rule
2093
2094         float wantovertime;
2095         wantovertime = 0;
2096
2097         if(timelimit > game_starttime)
2098                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2099         else
2100                 game_completion_ratio = 0;
2101
2102         if(checkrules_suddendeathend)
2103         {
2104                 if(!checkrules_suddendeathwarning)
2105                 {
2106                         checkrules_suddendeathwarning = TRUE;
2107                         if(g_race && !g_race_qualifying)
2108                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2109                         else
2110                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2111                 }
2112         }
2113         else
2114         {
2115                 if (timelimit && time >= timelimit)
2116                 {
2117                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2118                         {
2119                                 float totalplayers;
2120                                 float playerswithlaps;
2121                                 float readyplayers;
2122                                 entity head;
2123                                 totalplayers = playerswithlaps = readyplayers = 0;
2124                                 FOR_EACH_PLAYER(head)
2125                                 {
2126                                         ++totalplayers;
2127                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2128                                                 ++playerswithlaps;
2129                                         if(head.ready)
2130                                                 ++readyplayers;
2131                                 }
2132
2133                                 // at least 2 of the players have completed a lap: start the RACE
2134                                 // otherwise, the players should end the qualifying on their own
2135                                 if(readyplayers || playerswithlaps >= 2)
2136                                 {
2137                                         checkrules_suddendeathend = 0;
2138                                         ReadyRestart(); // go to race
2139                                         return;
2140                                 }
2141                                 else
2142                                         wantovertime |= InitiateSuddenDeath();
2143                         }
2144                         else
2145                                 wantovertime |= InitiateSuddenDeath();
2146                 }
2147         }
2148
2149         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2150         {
2151                 NextLevel();
2152                 return;
2153         }
2154
2155         float checkrules_status;
2156         checkrules_status = WinningCondition_RanOutOfSpawns();
2157         if(checkrules_status == WINNING_YES)
2158         {
2159                 bprint("Hey! Someone ran out of spawns!\n");
2160         }
2161         else if(g_race && !g_race_qualifying && timelimit >= 0)
2162         {
2163                 checkrules_status = WinningCondition_Race(fraglimit);
2164                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2165         }
2166         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2167         {
2168                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2169                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2170         }
2171         else if(g_assault)
2172         {
2173                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2174         }
2175         else if(g_lms)
2176         {
2177                 checkrules_status = WinningCondition_LMS();
2178         }
2179         else if (g_onslaught)
2180         {
2181                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2182         }
2183         else
2184         {
2185                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2186                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2187         }
2188
2189         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2190         {
2191                 checkrules_status = WINNING_NEVER;
2192                 checkrules_overtimesadded = -1;
2193                 wantovertime |= InitiateSuddenDeath();
2194         }
2195
2196         if(checkrules_status == WINNING_NEVER)
2197                 // equality cases! Nobody wins if the overtime ends in a draw.
2198                 ClearWinners();
2199
2200         if(wantovertime)
2201         {
2202                 if(checkrules_status == WINNING_NEVER)
2203                         InitiateOvertime();
2204                 else
2205                         checkrules_status = WINNING_YES;
2206         }
2207
2208         if(checkrules_suddendeathend)
2209                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2210                         checkrules_status = WINNING_YES;
2211
2212         if(checkrules_status == WINNING_YES)
2213         {
2214                 //print("WINNING\n");
2215                 NextLevel();
2216         }
2217 }
2218
2219 string GotoMap(string m)
2220 {
2221         m = GameTypeVote_MapInfo_FixName(m);
2222         if (!m)
2223                 return "The map you suggested is not available on this server.";
2224         if (!autocvar_sv_vote_gametype)
2225         if(!MapInfo_CheckMap(m))
2226                 return "The map you suggested does not support the current game mode.";
2227         cvar_set("nextmap", m);
2228         cvar_set("timelimit", "-1");
2229         if(mapvote_initialized || alreadychangedlevel)
2230         {
2231                 if(DoNextMapOverride(0))
2232                         return "Map switch initiated.";
2233                 else
2234                         return "Hm... no. For some reason I like THIS map more.";
2235         }
2236         else
2237                 return "Map switch will happen after scoreboard.";
2238 }
2239
2240
2241 void EndFrame()
2242 {
2243         anticheat_endframe();
2244
2245         float altime;
2246         FOR_EACH_REALCLIENT(self)
2247         {
2248                 self.damage_dealt_total = 0;
2249
2250                 if(IS_SPEC(self))
2251                 {
2252                         if(self.enemy.typehitsound)
2253                                 self.typehit_time = time;
2254                         else if(self.enemy.damage_dealt)
2255                                 self.damage_dealt_total = ceil(self.enemy.damage_dealt);
2256                 }
2257                 else
2258                 {
2259                         if(self.typehitsound)
2260                                 self.typehit_time = time;
2261                         else if(self.damage_dealt)
2262                                 self.damage_dealt_total = ceil(self.damage_dealt);
2263                 }
2264         }
2265         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2266         // add 1 frametime because after this, engine SV_Physics
2267         // increases time by a frametime and then networks the frame
2268         // add another frametime because client shows everything with
2269         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2270         // needed!
2271         FOR_EACH_CLIENT(self)
2272         {
2273                 self.typehitsound = FALSE;
2274                 self.damage_dealt = 0;
2275                 antilag_record(self, altime);
2276         }
2277         FOR_EACH_MONSTER(self)
2278                 antilag_record(self, altime);
2279 }
2280
2281
2282 /*
2283  * RedirectionThink:
2284  * returns TRUE if redirecting
2285  */
2286 float redirection_timeout;
2287 float redirection_nextthink;
2288 float RedirectionThink()
2289 {
2290         float clients_found;
2291
2292         if(redirection_target == "")
2293                 return FALSE;
2294
2295         if(!redirection_timeout)
2296         {
2297                 cvar_set("sv_public", "-2");
2298                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2299                 if(redirection_target == "self")
2300                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2301                 else
2302                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2303         }
2304
2305         if(time < redirection_nextthink)
2306                 return TRUE;
2307
2308         redirection_nextthink = time + 1;
2309
2310         clients_found = 0;
2311         FOR_EACH_REALCLIENT(self)
2312         {
2313                 // TODO add timer
2314                 print("Redirecting: sending connect command to ", self.netname, "\n");
2315                 if(redirection_target == "self")
2316                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2317                 else
2318                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2319                 ++clients_found;
2320         }
2321
2322         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2323
2324         if(time > redirection_timeout || clients_found == 0)
2325                 localcmd("\nwait; wait; wait; quit\n");
2326
2327         return TRUE;
2328 }
2329
2330 void TargetMusic_RestoreGame();
2331 void RestoreGame()
2332 {
2333         // Loaded from a save game
2334         // some things then break, so let's work around them...
2335
2336         // Progs DB (capture records)
2337         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2338
2339         // Mapinfo
2340         MapInfo_Shutdown();
2341         MapInfo_Enumerate();
2342         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2343         WeaponStats_Init();
2344
2345         TargetMusic_RestoreGame();
2346 }
2347
2348 void Shutdown()
2349 {
2350         entity e;
2351
2352         gameover = 2;
2353
2354         if(world_initialized > 0)
2355         {
2356                 world_initialized = 0;
2357                 print("Saving persistent data...\n");
2358                 Ban_SaveBans();
2359
2360                 PlayerStats_EndMatch(0);
2361                 FOR_EACH_CLIENT(e)
2362                         PlayerStats_AddGlobalInfo(e);
2363                 PlayerStats_Shutdown();
2364
2365                 if(!cheatcount_total)
2366                 {
2367                         if(autocvar_sv_db_saveasdump)
2368                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2369                         else
2370                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2371                 }
2372                 if(autocvar_developer)
2373                 {
2374                         if(autocvar_sv_db_saveasdump)
2375                                 db_dump(TemporaryDB, "server-temp.db");
2376                         else
2377                                 db_save(TemporaryDB, "server-temp.db");
2378                 }
2379                 CheatShutdown(); // must be after cheatcount check
2380                 db_close(ServerProgsDB);
2381                 db_close(TemporaryDB);
2382                 print("done!\n");
2383                 // tell the bot system the game is ending now
2384                 bot_endgame();
2385
2386                 WeaponStats_Shutdown();
2387                 MapInfo_Shutdown();
2388         }
2389         else if(world_initialized == 0)
2390         {
2391                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2392         }
2393 }