qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50 float headshot;
  51 float damage_headshotbonus; // bonus multiplier for head shots, set to 0 after use
  52
  53 .float dmg_team;
  54 .float teamkill_complain;
  55 .float teamkill_soundtime;
  56 .entity teamkill_soundsource;
  57 .entity pusher;
  58 .float istypefrag;
  59 .float taunt_soundtime;
  60
  61
  62 float IsDifferentTeam(entity a, entity b)
  63 {
  64         if(teamplay)
  65         {
  66                 if(a.team == b.team)
  67                         return 0;
  68         }
  69         else
  70         {
  71                 if(a == b)
  72                         return 0;
  73         }
  74         return 1;
  75 }
  76
  77 float IsFlying(entity a)
  78 {
  79         if(a.flags & FL_ONGROUND)
  80                 return 0;
  81         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  82                 return 0;
  83         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  84         if(trace_fraction < 1)
  85                 return 0;
  86         return 1;
  87 }
  88
  89 vector GetHeadshotMins(entity targ)
  90 {
  91         return '-0.5 0 0' * PL_HEAD_x + '0 -0.5 0' * PL_HEAD_y + '0 0 1' * (targ.maxs_z - PL_HEAD_z);
  92 }
  93 vector GetHeadshotMaxs(entity targ)
  94 {
  95         return '0.5 0 0' * PL_HEAD_x + '0 0.5 0' * PL_HEAD_y + '0 0 1' * targ.maxs_z;
  96 }
  97
  98 void UpdateFrags(entity player, float f)
  99 {
 100         PlayerTeamScore_AddScore(player, f);
 101 }
 102
 103 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
 104 void W_SwitchWeapon_Force(entity e, float w);
 105 entity GiveFrags_randomweapons;
 106 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
 107 {
 108         // TODO route through PlayerScores instead
 109         if(gameover) return;
 110
 111         if(f < 0)
 112         {
 113                 if(targ == attacker)
 114                 {
 115                         // suicide
 116                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 117                 }
 118                 else
 119                 {
 120                         // teamkill
 121                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 122                 }
 123         }
 124         else
 125         {
 126                 // regular frag
 127                 PlayerScore_Add(attacker, SP_KILLS, 1);
 128                 if(targ.playerid)
 129                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 130         }
 131
 132         PlayerScore_Add(targ, SP_DEATHS, 1);
 133
 134         if(g_arena || g_ca)
 135                 if(autocvar_g_arena_roundbased)
 136                         return;
 137
 138         if(targ != attacker) // not for suicides
 139         if(g_weaponarena_random)
 140         {
 141                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 142                 float culprit;
 143                 culprit = DEATH_WEAPONOF(deathtype);
 144                 if(!culprit)
 145                         culprit = attacker.weapon;
 146                 else if(!WEPSET_CONTAINS_EW(attacker, culprit))
 147                         culprit = attacker.weapon;
 148
 149                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
 150                 {
 151                         // no exchange
 152                 }
 153                 else
 154                 {
 155                         if(!GiveFrags_randomweapons)
 156                         {
 157                                 GiveFrags_randomweapons = spawn();
 158                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 159                         }
 160
 161                         if(inWarmupStage)
 162                                 WEPSET_COPY_EA(GiveFrags_randomweapons, warmup_start_weapons);
 163                         else
 164                                 WEPSET_COPY_EA(GiveFrags_randomweapons, start_weapons);
 165
 166                         // all others (including the culprit): remove
 167                         WEPSET_ANDNOT_EE(GiveFrags_randomweapons, attacker);
 168                         WEPSET_ANDNOT_EW(GiveFrags_randomweapons, culprit);
 169
 170                         // among the remaining ones, choose one by random
 171                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 172
 173                         if(!WEPSET_EMPTY_E(GiveFrags_randomweapons))
 174                         {
 175                                 WEPSET_OR_EE(attacker, GiveFrags_randomweapons);
 176                                 WEPSET_ANDNOT_EW(attacker, culprit);
 177                         }
 178                 }
 179
 180                 // after a frag, choose another random weapon set
 181                 if not(WEPSET_CONTAINS_EW(attacker, attacker.weapon))
 182                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 183         }
 184
 185         // FIXME fix the mess this is (we have REAL points now!)
 186         entity oldself;
 187         oldself = self;
 188         self = attacker;
 189         frag_attacker = attacker;
 190         frag_target = targ;
 191         frag_score = f;
 192         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 193         {
 194                 f = frag_score;
 195                 self = oldself;
 196         }
 197         else
 198         {
 199                 self = oldself;
 200                 if(g_runematch)
 201                 {
 202                         f = RunematchHandleFrags(attacker, targ, f);
 203                 }
 204                 else if(g_lms)
 205                 {
 206                         // remove a life
 207                         float tl;
 208                         tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
 209                         if(tl < lms_lowest_lives)
 210                                 lms_lowest_lives = tl;
 211                         if(tl <= 0)
 212                         {
 213                                 if(!lms_next_place)
 214                                         lms_next_place = player_count;
 215                                 else
 216                                         lms_next_place = min(lms_next_place, player_count);
 217                                 PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 218                                 --lms_next_place;
 219                         }
 220                         f = 0;
 221                 }
 222         }
 223
 224         attacker.totalfrags += f;
 225
 226         if(f)
 227                 UpdateFrags(attacker, f);
 228 }
 229
 230 string Obituary_ExtraFragInfo(entity player) // Extra fragmessage information
 231 {
 232         string health_output = string_null;
 233         string ping_output = string_null;
 234         string handicap_output = string_null;
 235         string output = string_null;
 236
 237         if(autocvar_sv_fraginfo && ((autocvar_sv_fraginfo == 2) || inWarmupStage))
 238         {
 239                 // health/armor of attacker (person who killed you)
 240                 if(autocvar_sv_fraginfo_stats && (player.health >= 1))
 241                         health_output = strcat("^7(Health ^1", ftos(rint(player.health)), "^7 / Armor ^2", ftos(rint(player.armorvalue)), "^7)");
 242
 243                 // ping display
 244                 if(autocvar_sv_fraginfo_ping)
 245                         ping_output = ((clienttype(player) == CLIENTTYPE_BOT) ? "^2Bot" : strcat("Ping ", ((player.ping >= 150) ? "^1" : "^2"), ftos(rint(player.ping)), "ms"));
 246
 247                 // handicap display
 248                 if(autocvar_sv_fraginfo_handicap)
 249                 {
 250                         if(autocvar_sv_fraginfo_handicap == 2)
 251                                 handicap_output = strcat(output, strcat("Handicap ^2", ((player.cvar_cl_handicap <= 1) ? "Off" : ftos(rint(player.cvar_cl_handicap)))));
 252                         else if(player.cvar_cl_handicap) // with _handicap 1, only show this if there actually is a handicap enabled.
 253                                 handicap_output = strcat("Handicap ^2", ftos(rint(player.cvar_cl_handicap)));
 254                 }
 255
 256                 // format the string
 257                 output = strcat(health_output, (health_output ? ((ping_output || handicap_output) ? " ^7(" : "") : ((ping_output || handicap_output) ? "^7(" : "")),
 258                         ping_output, (handicap_output ? "^7 / " : ""),
 259                         handicap_output, ((ping_output || handicap_output) ? "^7)" : ""));
 260
 261                 // add new line to the beginning if there is a message
 262                 if(output) { output = strcat("\n", output); }
 263         }
 264
 265         return output;
 266 }
 267
 268 string AppendItemcodes(string s, entity player)
 269 {
 270         float w;
 271         w = player.weapon;
 272         //if(w == 0)
 273         //      w = player.switchweapon;
 274         if(w == 0)
 275                 w = player.cnt; // previous weapon!
 276         s = strcat(s, ftos(w));
 277         if(time < player.strength_finished)
 278                 s = strcat(s, "S");
 279         if(time < player.invincible_finished)
 280                 s = strcat(s, "I");
 281         if(player.flagcarried != world)
 282                 s = strcat(s, "F");
 283         if(player.BUTTON_CHAT)
 284                 s = strcat(s, "T");
 285         if(player.kh_next)
 286                 s = strcat(s, "K");
 287         if(player.runes)
 288                 s = strcat(s, "|", ftos(player.runes));
 289         return s;
 290 }
 291
 292 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 293 {
 294         string s;
 295         if(!autocvar_sv_eventlog)
 296                 return;
 297         s = strcat(":kill:", mode);
 298         s = strcat(s, ":", ftos(killer.playerid));
 299         s = strcat(s, ":", ftos(killed.playerid));
 300         s = strcat(s, ":type=", Deathtype_Name(deathtype));
 301         s = strcat(s, ":items=");
 302         s = AppendItemcodes(s, killer);
 303         if(killed != killer)
 304         {
 305                 s = strcat(s, ":victimitems=");
 306                 s = AppendItemcodes(s, killed);
 307         }
 308         GameLogEcho(s);
 309 }
 310
 311 void Obituary_SpecialDeath(entity notif_target, float deathtype, string s1, string s2, float f1, float f2, float f3)
 312 {
 313         float handled, hits;
 314         if(DEATH_ISSPECIAL(deathtype))
 315         {
 316                 #define DEATHTYPE(name,msg_info,msg_center,position) \
 317                         { if(deathtype == max(0, name)) \
 318                         { \
 319                                 if(max(0, msg_info)) { Send_Notification(world, MSG_ALL, MSG_INFO, msg_info, s1, s2, f1, f2, f3); ++handled; } \
 320                                 if(max(0, msg_center)) { Send_Notification(notif_target, MSG_ONE, MSG_CENTER, msg_center, s1, s2, f1, f2, f3); ++handled; } \
 321                                 ++hits; \
 322                         } }
 323
 324                 DEATHTYPES
 325                 if not(hits)
 326                 {
 327                         backtrace("Unhandled deathtype. Please notify Samual!\n");
 328                         return;
 329                 }
 330                 if not(handled)
 331                 {
 332                         print(sprintf("Obituary_SpecialDeath(): ^1Deathtype ^7(%s-%d)^1 has no notification!\n", Deathtype_Name(deathtype), deathtype));
 333                         return;
 334                 }
 335         }
 336 }
 337
 338 .float FRAG_VERBOSE;
 339
 340 void Obituary(entity attacker, entity inflictor, entity targ, float deathtype)
 341 {
 342         // Sanity check
 343         if not(targ.classname == "player") { backtrace("Obituary called on non-player?!\n"); return; }
 344
 345         // Declarations
 346         string  s, a, msg;
 347         float w, type;
 348
 349         string s1, s2 = NO_STR_ARG;
 350         float f1, f2, f3 = NO_FL_ARG;
 351         float notif_firstblood;
 352
 353
 354         print(sprintf("Obituary(): Deathtype = %s (%d), Attacker = %s, Inflictor = %s, Target = %s...\n", Deathtype_Name(deathtype), deathtype, attacker.netname, inflictor.netname, targ.netname));
 355
 356
 357         // =======
 358         // SUICIDE
 359         // =======
 360         if(targ == attacker)
 361         {
 362                 if(DEATH_ISSPECIAL(deathtype))
 363                 {
 364                         if(deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 365                         {
 366                                 s1 = targ.netname;
 367                                 f1 = targ.team;
 368                                 f2 = NO_FL_ARG;
 369                         }
 370                         else
 371                         {
 372                                 if(deathtype == DEATH_MIRRORDAMAGE)
 373                                 {
 374                                         s1 = targ.netname;
 375                                         f1 = targ.team;
 376                                         f2 = targ.killcount;
 377                                 }
 378                                 else
 379                                 {
 380                                         s1 = targ.netname;
 381                                         f1 = targ.killcount;
 382                                         f2 = NO_FL_ARG;
 383                                 }
 384
 385                                 // Do this manually inside of each if statement where necessary,
 386                                 // DEATH_TEAMCHANGE and such are not supposed to have this.
 387                                 LogDeath("suicide", deathtype, targ, targ);
 388                                 GiveFrags(attacker, targ, -1, deathtype);
 389                         }
 390                         Obituary_SpecialDeath(targ, deathtype, s1, NO_STR_ARG, f1, f2, NO_FL_ARG);
 391                 }
 392                 else if(DEATH_WEAPONOF(deathtype))
 393                 {
 394                         print("death was a weapon!\n");
 395                 }
 396                 else
 397                 {
 398                         backtrace("what the hell happened here?\n");
 399                 }
 400         }
 401
 402
 403         // ======
 404         // MURDER
 405         // ======
 406         else if(attacker.classname == "player")
 407         {
 408                 if(!IsDifferentTeam(attacker, targ))
 409                 {
 410                         if(DEATH_ISSPECIAL(deathtype))
 411                         {
 412                                 print("hmm death was special?\n");
 413                         }
 414                         else if(DEATH_WEAPONOF(deathtype))
 415                         {
 416                                 print("death was a weapon!\n");
 417                         }
 418                         else
 419                         {
 420                                 backtrace("what the hell happened here?\n");
 421                         }
 422
 423                         LogDeath("tk", deathtype, attacker, targ);
 424                         GiveFrags(attacker, targ, -1, deathtype);
 425                 }
 426                 else
 427                 {
 428                         s1 = attacker.netname;
 429                         s2 = targ.netname;
 430
 431                         attacker.FRAG_VERBOSE = TRUE;
 432                         targ.FRAG_VERBOSE = TRUE;
 433
 434                         LogDeath("frag", deathtype, attacker, targ);
 435                         GiveFrags(attacker, targ, 1, deathtype);
 436
 437                         attacker.taunt_soundtime = time + 1;
 438                         attacker.killcount = attacker.killcount + 1;
 439                         if(targ.killcount > 2) { Send_KillNotification(s, ftos(targ.killcount), a, KILL_END_SPREE, MSG_SPREE); }
 440
 441                         #define ADD_ACHIEVEMENT_CASE(numa,numb) \
 442                                 case numa: \
 443                                 { \
 444                                         AnnounceTo(attacker, strcat(#numb, "kills")); \
 445                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_##numa, 1); \
 446                                         break; \
 447                                 }
 448                         switch(attacker.killcount)
 449                         {
 450                                 ADD_ACHIEVEMENT_CASE(3, 03)
 451                                 ADD_ACHIEVEMENT_CASE(5, 05)
 452                                 ADD_ACHIEVEMENT_CASE(10, 10)
 453                                 ADD_ACHIEVEMENT_CASE(15, 15)
 454                                 ADD_ACHIEVEMENT_CASE(20, 20)
 455                                 ADD_ACHIEVEMENT_CASE(25, 25)
 456                                 ADD_ACHIEVEMENT_CASE(30, 30)
 457                                 default: break;
 458                         }
 459                         #undef ADD_ACHIEVEMENT_CASE
 460
 461                         if(!checkrules_firstblood)
 462                         {
 463                                 checkrules_firstblood = TRUE;
 464                                 notif_firstblood = TRUE; // modify the current messages so that they too show firstblood information
 465                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 466                                 PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 467                         }
 468
 469                         if(notif_firstblood) // first blood, no kill sprees yet
 470                         {
 471                                 if(targ.istypefrag)
 472                                 {
 473                                         Send_Notification(attacker, MSG_ONE, MSG_CENTER, (attacker.FRAG_VERBOSE ? CENTER_DEATH_TYPEFRAG_FIRST_VERBOSE : CENTER_DEATH_TYPEFRAG_FIRST),
 474                                                 s2, NO_STR_ARG, (attacker.FRAG_VERBOSE ? ((clienttype(targ) == CLIENTTYPE_BOT) ? BOT_PING : targ.ping) : NO_FL_ARG), NO_FL_ARG, NO_FL_ARG);
 475
 476                                         Send_Notification(targ, MSG_ONE, MSG_CENTER, (targ.FRAG_VERBOSE ? CENTER_DEATH_TYPEFRAGGED_FIRST_VERBOSE : CENTER_DEATH_TYPEFRAGGED_FIRST),
 477                                                 s1, NO_STR_ARG, (targ.FRAG_VERBOSE ? attacker.health : NO_FL_ARG), (targ.FRAG_VERBOSE ? attacker.armorvalue : NO_FL_ARG), (targ.FRAG_VERBOSE ? ((clienttype(attacker) == CLIENTTYPE_BOT) ? BOT_PING : attacker.ping) : NO_FL_ARG));
 478                                 }
 479                                 else
 480                                 {
 481                                         Send_Notification(attacker, MSG_ONE, MSG_CENTER, (attacker.FRAG_VERBOSE ? CENTER_DEATH_FRAG_FIRST_VERBOSE : CENTER_DEATH_FRAG_FIRST),
 482                                                 s2, NO_STR_ARG, (attacker.FRAG_VERBOSE ? ((clienttype(targ) == CLIENTTYPE_BOT) ? BOT_PING : targ.ping) : NO_FL_ARG), NO_FL_ARG, NO_FL_ARG);
 483
 484                                         Send_Notification(targ, MSG_ONE, MSG_CENTER, (targ.FRAG_VERBOSE ? CENTER_DEATH_FRAGGED_FIRST_VERBOSE : CENTER_DEATH_FRAGGED_FIRST),
 485                                                 s1, NO_STR_ARG, (targ.FRAG_VERBOSE ? attacker.health : NO_FL_ARG), (targ.FRAG_VERBOSE ? attacker.armorvalue : NO_FL_ARG), (targ.FRAG_VERBOSE ? ((clienttype(attacker) == CLIENTTYPE_BOT) ? BOT_PING : attacker.ping) : NO_FL_ARG));
 486                                 }
 487                                 //Send_Notification(world, MSG_INFO, INFO_DEATH_FRAG_FIRSTBLOOD, s1, s2, attacker.team, NO_FL_ARG, NO_FL_ARG);
 488                         }
 489                         else // normal frags, kill sprees listed
 490                         {
 491                                 if(targ.istypefrag)
 492                                 {
 493                                         Send_Notification(attacker, MSG_ONE, MSG_CENTER, (attacker.FRAG_VERBOSE ? CENTER_DEATH_TYPEFRAG_VERBOSE : CENTER_DEATH_TYPEFRAG),
 494                                                 s2, NO_STR_ARG, attacker.killcount, (attacker.FRAG_VERBOSE ? ((clienttype(targ) == CLIENTTYPE_BOT) ? BOT_PING : targ.ping) : NO_FL_ARG), NO_FL_ARG);
 495
 496                                         Send_Notification(targ, MSG_ONE, MSG_CENTER, (targ.FRAG_VERBOSE ? CENTER_DEATH_TYPEFRAGGED_VERBOSE : CENTER_DEATH_TYPEFRAGGED),
 497                                                 s1, NO_STR_ARG, (targ.FRAG_VERBOSE ? attacker.health : NO_FL_ARG), (targ.FRAG_VERBOSE ? attacker.armorvalue : NO_FL_ARG), (targ.FRAG_VERBOSE ? ((clienttype(attacker) == CLIENTTYPE_BOT) ? BOT_PING : attacker.ping) : NO_FL_ARG));
 498                                 }
 499                                 else
 500                                 {
 501                                         Send_Notification(attacker, MSG_ONE, MSG_CENTER, (attacker.FRAG_VERBOSE ? CENTER_DEATH_FRAG_VERBOSE : CENTER_DEATH_FRAG),
 502                                                 s2, NO_STR_ARG, attacker.killcount, (attacker.FRAG_VERBOSE ? ((clienttype(targ) == CLIENTTYPE_BOT) ? BOT_PING : targ.ping) : NO_FL_ARG), NO_FL_ARG);
 503
 504                                         Send_Notification(targ, MSG_ONE, MSG_CENTER, (targ.FRAG_VERBOSE ? CENTER_DEATH_FRAGGED_VERBOSE : CENTER_DEATH_FRAGGED),
 505                                                 s1, NO_STR_ARG, (targ.FRAG_VERBOSE ? attacker.health : NO_FL_ARG), (targ.FRAG_VERBOSE ? attacker.armorvalue : NO_FL_ARG), (targ.FRAG_VERBOSE ? ((clienttype(attacker) == CLIENTTYPE_BOT) ? BOT_PING : attacker.ping) : NO_FL_ARG));
 506                                 }
 507                                 //if(DEATH_WEAPONOF(deathtype)) { Send_Notification(world, MSG_WEAPON, 50, s1, s2, attacker.killcount, targ.killcount, Obituary_Score_Position); }
 508                                 //else { Obituary_SpecialDeath(world, deathtype, s1, s2, attacker.killcount, targ.killcount, Obituary_Score_Position); }
 509                         }
 510                 }
 511         }
 512
 513         // =============
 514         // ACCIDENT/TRAP
 515         // =============
 516         else
 517         {
 518                 Send_CSQC_KillCenterprint(targ, "", "", deathtype, MSG_KILL_ACTION);
 519                 if (deathtype == DEATH_HURTTRIGGER && inflictor.message != "")
 520                         msg = inflictor.message;
 521                 else if (deathtype == DEATH_CUSTOM)
 522                         msg = deathmessage;
 523                 else
 524                         msg = "";
 525                 if(strstrofs(msg, "%", 0) < 0)
 526                         msg = strcat("%s ", msg);
 527
 528                 GiveFrags(targ, targ, -1, deathtype);
 529                 if(PlayerScore_Add(targ, SP_SCORE, 0) == -5) {
 530                         AnnounceTo(targ, "botlike");
 531                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 532                 }
 533                 Send_KillNotification(s, msg, "", deathtype, MSG_KILL_ACTION);
 534
 535                 if (targ.killcount > 2)
 536                         Send_KillNotification(s, ftos(targ.killcount), "", 0, MSG_KILL_ACTION_SPREE);
 537
 538                 LogDeath("accident", deathtype, targ, targ);
 539         }
 540
 541         targ.death_origin = targ.origin;
 542         if(targ != attacker)
 543                 targ.killer_origin = attacker.origin;
 544
 545         // FIXME: this should go in PutClientInServer
 546         if (targ.killcount)
 547                 targ.killcount = 0;
 548 }
 549
 550 // these are updated by each Damage call for use in button triggering and such
 551 entity damage_targ;
 552 entity damage_inflictor;
 553 entity damage_attacker;
 554
 555 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 556 {
 557         float mirrordamage;
 558         float mirrorforce;
 559         float teamdamage0;
 560         entity attacker_save;
 561         mirrordamage = 0;
 562         mirrorforce = 0;
 563
 564         if (gameover || targ.killcount == -666)
 565                 return;
 566
 567         entity oldself;
 568         oldself = self;
 569         self = targ;
 570         damage_targ = targ;
 571         damage_inflictor = inflictor;
 572         damage_attacker = attacker;
 573                 attacker_save = attacker;
 574
 575         if(targ.classname == "player")
 576                 if(targ.hook)
 577                         if(targ.hook.aiment)
 578                                 if(targ.hook.aiment == attacker)
 579                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 580
 581         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 582         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 583         {
 584                 if(targ.classname == "player")
 585                         if not(IsDifferentTeam(targ, attacker))
 586                         {
 587                                 self = oldself;
 588                                 return;
 589                         }
 590         }
 591
 592         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 593         {
 594                 // These are ALWAYS lethal
 595                 // No damage modification here
 596                 // Instead, prepare the victim for his death...
 597                 targ.armorvalue = 0;
 598                 targ.spawnshieldtime = 0;
 599                 targ.health = 0.9; // this is < 1
 600                 targ.flags -= targ.flags & FL_GODMODE;
 601                 damage = 100000;
 602         }
 603         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 604         {
 605                 // no processing
 606         }
 607         else
 608         {
 609                 /*
 610                 skill based bot damage? gtfo. (tZork)
 611                 if (targ.classname == "player")
 612                 if (attacker.classname == "player")
 613                 if (!targ.isbot)
 614                 if (attacker.isbot)
 615                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 616         */
 617
 618                 // nullify damage if teamplay is on
 619                 if(deathtype != DEATH_TELEFRAG)
 620                 if(attacker.classname == "player")
 621                 {
 622                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 623                         {
 624                                 damage = 0;
 625                                 force = '0 0 0';
 626                         }
 627                         else if(!IsDifferentTeam(attacker, targ))
 628                         {
 629                                 if(autocvar_teamplay_mode == 1)
 630                                         damage = 0;
 631                                 else if(attacker != targ)
 632                                 {
 633                                         if(autocvar_teamplay_mode == 3)
 634                                                 damage = 0;
 635                                         else if(autocvar_teamplay_mode == 4)
 636                                         {
 637                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 638                                                 {
 639                                                         teamdamage0 = max(attacker.dmg_team, autocvar_g_teamdamage_threshold);
 640                                                         attacker.dmg_team = attacker.dmg_team + damage;
 641                                                         if(attacker.dmg_team > teamdamage0 && !g_ca)
 642                                                                 mirrordamage = autocvar_g_mirrordamage * (attacker.dmg_team - teamdamage0);
 643                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 644                                                         if(g_minstagib)
 645                                                         {
 646                                                                 if(autocvar_g_friendlyfire == 0)
 647                                                                         damage = 0;
 648                                                         }
 649                                                         else if(g_ca)
 650                                                                 damage = 0;
 651                                                         else
 652                                                                 damage = autocvar_g_friendlyfire * damage;
 653                                                         // mirrordamage will be used LATER
 654
 655                                                         if(autocvar_g_mirrordamage_virtual)
 656                                                         {
 657                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 658                                                                 attacker.dmg_take += v_x;
 659                                                                 attacker.dmg_save += v_y;
 660                                                                 attacker.dmg_inflictor = inflictor;
 661                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
 662                                                                 mirrorforce = 0;
 663                                                         }
 664
 665                                                         if(autocvar_g_friendlyfire_virtual)
 666                                                         {
 667                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 668                                                                 targ.dmg_take += v_x;
 669                                                                 targ.dmg_save += v_y;
 670                                                                 targ.dmg_inflictor = inflictor;
 671                                                                 damage = 0;
 672                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 673                                                                         force = '0 0 0';
 674                                                         }
 675                                                 }
 676                                                 else
 677                                                         damage = 0;
 678                                         }
 679                                 }
 680                         }
 681                 }
 682
 683                 if(targ.classname == "player")
 684                 if(attacker.classname == "player")
 685                 if(attacker != targ)
 686                 {
 687                         targ.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 688                         attacker.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 689                 }
 690
 691                 if(targ.classname == "player")
 692                 if (g_minstagib)
 693                 {
 694                         if ((deathtype == DEATH_FALL)  ||
 695                                 (deathtype == DEATH_DROWN) ||
 696                                 (deathtype == DEATH_SLIME) ||
 697                                 (deathtype == DEATH_LAVA)  ||
 698                                 (!DEATH_ISWEAPON(deathtype, WEP_LASER) && damage > 0 && damage < 100))
 699                         {
 700                                 self = oldself;
 701                                 return;
 702                         }
 703                         if(damage > 0)
 704                             damage = 10000;
 705                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
 706                         {
 707                                 targ.armorvalue -= 1;
 708                                 centerprint(targ, strcat("^3Remaining extra lives: ",ftos(targ.armorvalue)));
 709                                 damage = 0;
 710                                 targ.hitsound += 1;
 711                                 attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 712                         }
 713                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
 714                         {
 715                                 damage = 0;
 716                                 mirrordamage = 0;
 717                                 if (targ != attacker)
 718                                 {
 719                                         if ((targ.health >= 1) && (targ.classname == "player"))
 720                                                 centerprint(attacker, "Secondary fire inflicts no damage!");
 721                                         force = '0 0 0';
 722                                         // keep mirrorforce
 723                                         attacker = targ;
 724                                 }
 725                         }
 726                 }
 727
 728                 if not(DEATH_ISSPECIAL(deathtype))
 729                 {
 730                         damage *= g_weapondamagefactor;
 731                         mirrordamage *= g_weapondamagefactor;
 732                         force = force * g_weaponforcefactor;
 733                         mirrorforce *= g_weaponforcefactor;
 734                 }
 735
 736                 // should this be changed at all? If so, in what way?
 737                 frag_attacker = attacker;
 738                 frag_target = targ;
 739                 frag_damage = damage;
 740                 frag_force = force;
 741         frag_deathtype = deathtype;
 742                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 743                 damage = frag_damage;
 744                 force = frag_force;
 745
 746                 // apply strength multiplier
 747                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
 748                 {
 749                         if(targ == attacker)
 750                         {
 751                                 damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 752                                 force = force * autocvar_g_balance_powerup_strength_selfforce;
 753                         }
 754                         else
 755                         {
 756                                 damage = damage * autocvar_g_balance_powerup_strength_damage;
 757                                 force = force * autocvar_g_balance_powerup_strength_force;
 758                         }
 759                 }
 760
 761                 // apply invincibility multiplier
 762                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
 763                         damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 764
 765                 if (targ == attacker)
 766                 {
 767                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
 768                                 damage = 0;
 769                         else
 770                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 771                 }
 772
 773                 if(g_runematch)
 774                 {
 775                         // apply strength rune
 776                         if (attacker.runes & RUNE_STRENGTH)
 777                         {
 778                                 if(attacker.runes & CURSE_WEAK) // have both curse & rune
 779                                 {
 780                                         damage = damage * autocvar_g_balance_rune_strength_combo_damage;
 781                                         force = force * autocvar_g_balance_rune_strength_combo_force;
 782                                 }
 783                                 else
 784                                 {
 785                                         damage = damage * autocvar_g_balance_rune_strength_damage;
 786                                         force = force * autocvar_g_balance_rune_strength_force;
 787                                 }
 788                         }
 789                         else if (attacker.runes & CURSE_WEAK)
 790                         {
 791                                 damage = damage * autocvar_g_balance_curse_weak_damage;
 792                                 force = force * autocvar_g_balance_curse_weak_force;
 793                         }
 794
 795                         // apply defense rune
 796                         if (targ.runes & RUNE_DEFENSE)
 797                         {
 798                                 if (targ.runes & CURSE_VULNER) // have both curse & rune
 799                                         damage = damage * autocvar_g_balance_rune_defense_combo_takedamage;
 800                                 else
 801                                         damage = damage * autocvar_g_balance_rune_defense_takedamage;
 802                         }
 803                         else if (targ.runes & CURSE_VULNER)
 804                                 damage = damage * autocvar_g_balance_curse_vulner_takedamage;
 805                 }
 806
 807                 // count the damage
 808                 if(attacker)
 809                 if(!targ.deadflag)
 810                 if(targ.takedamage == DAMAGE_AIM)
 811                 if(targ != attacker)
 812                 {
 813                         if(damage_headshotbonus)
 814                         {
 815                                 if(targ.classname == "player")
 816                                 {
 817                                         // HEAD SHOT:
 818                                         // find height of hit on player axis
 819                                         // if above view_ofs and below maxs, and also in the middle half of the bbox, it is head shot
 820                                         vector headmins, headmaxs, org;
 821                                         org = antilag_takebackorigin(targ, time - ANTILAG_LATENCY(attacker));
 822                                         headmins = org + GetHeadshotMins(targ);
 823                                         headmaxs = org + GetHeadshotMaxs(targ);
 824                                         if(trace_hits_box(railgun_start, railgun_end, headmins, headmaxs))
 825                                         {
 826                                                 deathtype |= HITTYPE_HEADSHOT;
 827                                         }
 828                                 }
 829                                 else if(targ.classname == "turret_head")
 830                                 {
 831                                         deathtype |= HITTYPE_HEADSHOT;
 832                                 }
 833                                 if(deathtype & HITTYPE_HEADSHOT)
 834                                         if(damage_headshotbonus > 0)
 835                                                 damage *= 1 + damage_headshotbonus;
 836                         }
 837
 838                         entity victim;
 839                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 840                                 victim = targ.owner;
 841                         else
 842                                 victim = targ;
 843
 844                         if(victim.classname == "player" || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 845                         {
 846                                 if(IsDifferentTeam(victim, attacker))
 847                                 {
 848                                         if(damage > 0)
 849                                         {
 850                                                 if(deathtype != DEATH_FIRE)
 851                                                 {
 852                                                         if(victim.BUTTON_CHAT)
 853                                                                 attacker.typehitsound += 1;
 854                                                         else
 855                                                                 attacker.hitsound += 1;
 856                                                 }
 857
 858                                                 damage_goodhits += 1;
 859                                                 damage_gooddamage += damage;
 860
 861                                                 if not(DEATH_ISSPECIAL(deathtype))
 862                                                 {
 863                                                         if(targ.classname == "player") // don't do this for vehicles
 864                                                         if(!g_minstagib)
 865                                                         if(IsFlying(victim))
 866                                                                 yoda = 1;
 867
 868                                                         if(g_minstagib)
 869                                                         if(victim.items & IT_STRENGTH)
 870                                                                 yoda = 1;
 871
 872                                                         if(deathtype & HITTYPE_HEADSHOT)
 873                                                                 headshot = 1;
 874                                                 }
 875                                                 if(g_ca)
 876                                                         PlayerScore_Add(attacker, SP_SCORE, damage * autocvar_g_ca_damage2score_multiplier);
 877                                         }
 878                                 }
 879                                 else
 880                                 {
 881                                         if(deathtype != DEATH_FIRE)
 882                                         {
 883                                                 attacker.typehitsound += 1;
 884                                         }
 885                                         if(mirrordamage > 0)
 886                                                 if(time > attacker.teamkill_complain)
 887                                                 {
 888                                                         attacker.teamkill_complain = time + 5;
 889                                                         attacker.teamkill_soundtime = time + 0.4;
 890                                                         attacker.teamkill_soundsource = targ;
 891                                                 }
 892                                 }
 893                         }
 894                 }
 895         }
 896
 897         // apply push
 898         if (self.damageforcescale)
 899         if (vlen(force))
 900         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 901         {
 902                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 903                 if(self.movetype == MOVETYPE_PHYSICS)
 904                 {
 905                         entity farcent;
 906                         farcent = spawn();
 907                         farcent.classname = "farce";
 908                         farcent.enemy = self;
 909                         farcent.movedir = farce * 10;
 910                         if(self.mass)
 911                                 farcent.movedir = farcent.movedir * self.mass;
 912                         farcent.origin = hitloc;
 913                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 914                         farcent.nextthink = time + 0.1;
 915                         farcent.think = SUB_Remove;
 916                 }
 917                 else
 918                         self.velocity = self.velocity + farce;
 919                 self.flags &~= FL_ONGROUND;
 920                 UpdateCSQCProjectile(self);
 921         }
 922         // apply damage
 923         if (damage != 0 || (self.damageforcescale && vlen(force)))
 924         if (self.event_damage)
 925                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 926         self = oldself;
 927
 928         if(targ.classname == "player" && attacker.classname == "player" && attacker != targ && attacker.health > 2)
 929         {
 930                 if(g_runematch)
 931                 {
 932                         if (attacker.runes & RUNE_VAMPIRE)
 933                         {
 934                         // apply vampire rune
 935                                 if (attacker.runes & CURSE_EMPATHY) // have the curse too
 936                                 {
 937                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb;
 938                                         attacker.health = bound(
 939                                                 autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 40
 940                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb,
 941                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 942                                 }
 943                                 else
 944                                 {
 945                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_absorb;
 946                                         attacker.health = bound(
 947                                                 attacker.health,        // LA: was 3, but changed so that you can't lose health
 948                                                                                         // empathy won't let you gain health in the same way...
 949                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_absorb,
 950                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 951                                         }
 952                         }
 953                         // apply empathy curse
 954                         else if (attacker.runes & CURSE_EMPATHY)
 955                         {
 956                                 attacker.health = bound(
 957                                         autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 20
 958                                         attacker.health + damage * autocvar_g_balance_curse_empathy_takedamage,
 959                                         attacker.health);
 960                         }
 961                 }
 962         }
 963
 964         // apply mirror damage if any
 965         if(mirrordamage > 0 || mirrorforce > 0)
 966         {
 967                 attacker = attacker_save;
 968                 if(g_minstagib)
 969                 if(mirrordamage > 0)
 970                 {
 971                         // just lose extra LIVES, don't kill the player for mirror damage
 972                         if(attacker.armorvalue > 0)
 973                         {
 974                                 attacker.armorvalue = attacker.armorvalue - 1;
 975                                 centerprint(attacker, strcat("^3Remaining extra lives: ",ftos(attacker.armorvalue)));
 976                                 attacker.hitsound += 1;
 977                         }
 978                         mirrordamage = 0;
 979                 }
 980
 981                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 982                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 983         }
 984 }
 985
 986 float RadiusDamage_running;
 987 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
 988         // Returns total damage applies to creatures
 989 {
 990         entity  targ;
 991         vector  blastorigin;
 992         vector  force;
 993         float   total_damage_to_creatures;
 994         entity  next;
 995         float   tfloordmg;
 996         float   tfloorforce;
 997
 998         float stat_damagedone;
 999
1000         if(RadiusDamage_running)
1001         {
1002                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
1003                 return 0;
1004         }
1005
1006         RadiusDamage_running = 1;
1007
1008         tfloordmg = autocvar_g_throughfloor_damage;
1009         tfloorforce = autocvar_g_throughfloor_force;
1010
1011         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
1012         total_damage_to_creatures = 0;
1013
1014         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
1015                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
1016                 {
1017                         force = inflictor.velocity;
1018                         if(vlen(force) == 0)
1019                                 force = '0 0 -1';
1020                         else
1021                                 force = normalize(force);
1022                         if(forceintensity >= 0)
1023                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
1024                         else
1025                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
1026                 }
1027
1028         stat_damagedone = 0;
1029
1030         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
1031         while (targ)
1032         {
1033                 next = targ.chain;
1034                 if (targ != inflictor)
1035                         if (ignore != targ) if(targ.takedamage)
1036                         {
1037                                 vector nearest;
1038                                 vector diff;
1039                                 float power;
1040
1041                                 // LordHavoc: measure distance to nearest point on target (not origin)
1042                                 // (this guarentees 100% damage on a touch impact)
1043                                 nearest = targ.WarpZone_findradius_nearest;
1044                                 diff = targ.WarpZone_findradius_dist;
1045                                 // round up a little on the damage to ensure full damage on impacts
1046                                 // and turn the distance into a fraction of the radius
1047                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
1048                                 //bprint(" ");
1049                                 //bprint(ftos(power));
1050                                 //if (targ == attacker)
1051                                 //      print(ftos(power), "\n");
1052                                 if (power > 0)
1053                                 {
1054                                         float finaldmg;
1055                                         if (power > 1)
1056                                                 power = 1;
1057                                         finaldmg = coredamage * power + edgedamage * (1 - power);
1058                                         if (finaldmg > 0)
1059                                         {
1060                                                 float a;
1061                                                 float c;
1062                                                 vector hitloc;
1063                                                 vector myblastorigin;
1064                                                 vector center;
1065
1066                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
1067
1068                                                 // if it's a player, use the view origin as reference
1069                                                 center = CENTER_OR_VIEWOFS(targ);
1070
1071                                                 force = normalize(center - myblastorigin);
1072                                                 force = force * (finaldmg / coredamage) * forceintensity;
1073                                                 hitloc = nearest;
1074
1075                                                 if(targ != directhitentity)
1076                                                 {
1077                                                         float hits;
1078                                                         float total;
1079                                                         float hitratio;
1080                                                         float mininv_f, mininv_d;
1081
1082                                                         // test line of sight to multiple positions on box,
1083                                                         // and do damage if any of them hit
1084                                                         hits = 0;
1085
1086                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
1087                                                         // so for a given max stddev:
1088                                                         // n = (1 / (2 * max stddev of hitratio))^2
1089
1090                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
1091                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
1092
1093                                                         if(autocvar_g_throughfloor_debug)
1094                                                                 print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
1095
1096                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
1097
1098                                                         if(autocvar_g_throughfloor_debug)
1099                                                                 print(sprintf(" steps=%f", total));
1100
1101                                                         if (targ.classname == "player")
1102                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
1103                                                         else
1104                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
1105
1106                                                         if(autocvar_g_throughfloor_debug)
1107                                                                 print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
1108
1109                                                         for(c = 0; c < total; ++c)
1110                                                         {
1111                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
1112                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
1113                                                                 if (trace_fraction == 1 || trace_ent == targ)
1114                                                                 {
1115                                                                         ++hits;
1116                                                                         if (hits > 1)
1117                                                                                 hitloc = hitloc + nearest;
1118                                                                         else
1119                                                                                 hitloc = nearest;
1120                                                                 }
1121                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
1122                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
1123                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
1124                                                         }
1125
1126                                                         nearest = hitloc * (1 / max(1, hits));
1127                                                         hitratio = (hits / total);
1128                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
1129                                                         finaldmg = finaldmg * a;
1130                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1131                                                         force = force * a;
1132
1133                                                         if(autocvar_g_throughfloor_debug)
1134                                                                 print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
1135                                                 }
1136
1137                                                 // laser force adjustments :P
1138                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1139                                                 {
1140                                                         if (targ == attacker)
1141                                                         {
1142                                                                 vector vel;
1143
1144                                                                 float force_zscale;
1145                                                                 float force_velocitybiasramp;
1146                                                                 float force_velocitybias;
1147
1148                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
1149                                                                 if(deathtype & HITTYPE_SECONDARY)
1150                                                                 {
1151                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1152                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1153                                                                 }
1154                                                                 else
1155                                                                 {
1156                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1157                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1158                                                                 }
1159
1160                                                                 vel = targ.velocity;
1161                                                                 vel_z = 0;
1162                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1163                                                                 force =
1164                                                                         vlen(force)
1165                                                                         *
1166                                                                         normalize(normalize(force) + vel);
1167
1168                                                                 force_z *= force_zscale;
1169                                                         }
1170                                                         else
1171                                                         {
1172                                                                 if(deathtype & HITTYPE_SECONDARY)
1173                                                                 {
1174                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
1175                                                                 }
1176                                                                 else
1177                                                                 {
1178                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1179                                                                 }
1180                                                         }
1181                                                 }
1182
1183                                                 //if (targ == attacker)
1184                                                 //{
1185                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1186                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1187                                                 //      print(" (", ftos(a), ")\n");
1188                                                 //}
1189                                                 if(finaldmg || vlen(force))
1190                                                 {
1191                                                         if(targ.iscreature)
1192                                                         {
1193                                                                 total_damage_to_creatures += finaldmg;
1194
1195                                                                 if(accuracy_isgooddamage(attacker, targ))
1196                                                                         stat_damagedone += finaldmg;
1197                                                         }
1198
1199                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1200                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1201                                                         else
1202                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1203                                                 }
1204                                         }
1205                                 }
1206                         }
1207                 targ = next;
1208         }
1209
1210         RadiusDamage_running = 0;
1211
1212         if(!DEATH_ISSPECIAL(deathtype))
1213                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1214
1215         return total_damage_to_creatures;
1216 }
1217
1218 .float fire_damagepersec;
1219 .float fire_endtime;
1220 .float fire_deathtype;
1221 .entity fire_owner;
1222 .float fire_hitsound;
1223 .entity fire_burner;
1224
1225 void fireburner_think();
1226
1227 float Fire_IsBurning(entity e)
1228 {
1229         return (time < e.fire_endtime);
1230 }
1231
1232 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1233 {
1234         float dps;
1235         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1236
1237         if(e.classname == "player")
1238         {
1239                 if(e.deadflag)
1240                         return -1;
1241         }
1242         else
1243         {
1244                 if(!e.fire_burner)
1245                 {
1246                         // print("adding a fire burner to ", e.classname, "\n");
1247                         e.fire_burner = spawn();
1248                         e.fire_burner.classname = "fireburner";
1249                         e.fire_burner.think = fireburner_think;
1250                         e.fire_burner.nextthink = time;
1251                         e.fire_burner.owner = e;
1252                 }
1253         }
1254
1255         t = max(t, 0.1);
1256         dps = d / t;
1257         if(Fire_IsBurning(e))
1258         {
1259                 mintime = e.fire_endtime - time;
1260                 maxtime = max(mintime, t);
1261
1262                 mindps = e.fire_damagepersec;
1263                 maxdps = max(mindps, dps);
1264
1265                 if(maxtime > mintime || maxdps > mindps)
1266                 {
1267                         // Constraints:
1268
1269                         // damage we have right now
1270                         mindamage = mindps * mintime;
1271
1272                         // damage we want to get
1273                         maxdamage = mindamage + d;
1274
1275                         // but we can't exceed maxtime * maxdps!
1276                         totaldamage = min(maxdamage, maxtime * maxdps);
1277
1278                         // LEMMA:
1279                         // Look at:
1280                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1281                         // We see:
1282                         // totaldamage <= maxtime * maxdps
1283                         // ==> totaldamage / maxdps <= maxtime.
1284                         // We also see:
1285                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1286                         //                     >= min(mintime, maxtime)
1287                         // ==> totaldamage / maxdps >= mintime.
1288
1289                         /*
1290                         // how long do we damage then?
1291                         // at least as long as before
1292                         // but, never exceed maxdps
1293                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1294                         */
1295
1296                         // alternate:
1297                         // at most as long as maximum allowed
1298                         // but, never below mindps
1299                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1300
1301                         // assuming t > mintime, dps > mindps:
1302                         // we get d = t * dps = maxtime * maxdps
1303                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1304                         // totaldamage / maxdps = maxtime
1305                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1306                         // FROM THIS:
1307                         // a) totaltime = max(mintime, maxtime) = maxtime
1308                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1309
1310                         // assuming t <= mintime:
1311                         // we get maxtime = mintime
1312                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1313                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1314
1315                         // assuming dps <= mindps:
1316                         // we get mindps = maxdps.
1317                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1318                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1319                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1320
1321                         e.fire_damagepersec = totaldamage / totaltime;
1322                         e.fire_endtime = time + totaltime;
1323                         if(totaldamage > 1.2 * mindamage)
1324                         {
1325                                 e.fire_deathtype = dt;
1326                                 if(e.fire_owner != o)
1327                                 {
1328                                         e.fire_owner = o;
1329                                         e.fire_hitsound = FALSE;
1330                                 }
1331                         }
1332                         if(accuracy_isgooddamage(o, e))
1333                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1334                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1335                 }
1336                 else
1337                         return 0;
1338         }
1339         else
1340         {
1341                 e.fire_damagepersec = dps;
1342                 e.fire_endtime = time + t;
1343                 e.fire_deathtype = dt;
1344                 e.fire_owner = o;
1345                 e.fire_hitsound = FALSE;
1346                 if(accuracy_isgooddamage(o, e))
1347                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1348                 return d;
1349         }
1350 }
1351
1352 void Fire_ApplyDamage(entity e)
1353 {
1354         float t, d, hi, ty;
1355         entity o;
1356
1357         if not(Fire_IsBurning(e))
1358                 return;
1359
1360         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1361         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1362                 o = e.fire_owner;
1363
1364         // water and slime stop fire
1365         if(e.waterlevel)
1366         if(e.watertype != CONTENT_LAVA)
1367                 e.fire_endtime = 0;
1368
1369         // ice stops fire
1370         if(e.freezetag_frozen)
1371                 e.fire_endtime = 0;
1372
1373         t = min(frametime, e.fire_endtime - time);
1374         d = e.fire_damagepersec * t;
1375
1376         hi = e.fire_owner.hitsound;
1377         ty = e.fire_owner.typehitsound;
1378         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1379         if(e.fire_hitsound && e.fire_owner)
1380         {
1381                 e.fire_owner.hitsound = hi;
1382                 e.fire_owner.typehitsound = ty;
1383         }
1384         e.fire_hitsound = TRUE;
1385
1386         if not(IS_INDEPENDENT_PLAYER(e))
1387         FOR_EACH_PLAYER(other) if(e != other)
1388         {
1389                 if(other.classname == "player")
1390                 if(other.deadflag == DEAD_NO)
1391                 if not(IS_INDEPENDENT_PLAYER(other))
1392                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1393                 {
1394                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1395                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1396                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1397                 }
1398         }
1399 }
1400
1401 void Fire_ApplyEffect(entity e)
1402 {
1403         if(Fire_IsBurning(e))
1404                 e.effects |= EF_FLAME;
1405         else
1406                 e.effects &~= EF_FLAME;
1407 }
1408
1409 void fireburner_think()
1410 {
1411         // for players, this is done in the regular loop
1412         if(wasfreed(self.owner))
1413         {
1414                 remove(self);
1415                 return;
1416         }
1417         Fire_ApplyEffect(self.owner);
1418         if(!Fire_IsBurning(self.owner))
1419         {
1420                 self.owner.fire_burner = world;
1421                 remove(self);
1422                 return;
1423         }
1424         Fire_ApplyDamage(self.owner);
1425         self.nextthink = time;
1426 }