qcsrc/server/command/vote.qc

   1 #include "vote.qh"
   2
   3 #include <common/command/_mod.qh>
   4 #include <common/constants.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/items/inventory.qh>
   7 #include <common/mapinfo.qh>
   8 #include <common/net_linked.qh>
   9 #include <common/notifications/all.qh>
  10 #include <common/playerstats.qh>
  11 #include <common/stats.qh>
  12 #include <common/util.qh>
  13 #include <common/weapons/_all.qh>
  14 #include <server/campaign.qh>
  15 #include <server/client.qh>
  16 #include <server/command/banning.qh>
  17 #include <server/command/common.qh>
  18 #include <server/command/vote.qh>
  19 #include <server/damage.qh>
  20 #include <server/gamelog.qh>
  21 #include <server/intermission.qh>
  22 #include <server/mutators/_mod.qh>
  23 #include <server/race.qh>
  24 #include <server/round_handler.qh>
  25 #include <server/scores.qh>
  26 #include <server/teamplay.qh>
  27 #include <server/weapons/accuracy.qh>
  28 #include <server/world.qh>
  29
  30 // =============================================
  31 //  Server side voting code, reworked by Samual
  32 //  Last updated: December 27th, 2011
  33 // =============================================
  34
  35 //  Nagger for players to know status of voting
  36 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  37 {
  38         int nags = 0;
  39         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  40
  41         // bits:
  42         //   1 = ready
  43         //   2 = player needs to ready up
  44         //   4 = vote
  45         //   8 = player needs to vote
  46         //  16 = warmup
  47         // sendflags:
  48         //  64 = vote counts
  49         // 128 = vote string
  50
  51         if (warmup_stage)
  52         {
  53                 if (readycount)
  54                 {
  55                         nags |= BIT(0);
  56                         if (!to.ready) nags |= BIT(1);
  57                 }
  58                 nags |= BIT(4);
  59         }
  60
  61         if (vote_called)
  62         {
  63                 nags |= BIT(2);
  64                 if (to.vote_selection == 0) nags |= BIT(3);
  65                 nags |= sendflags & BIT(6);
  66                 nags |= sendflags & BIT(7);
  67         }
  68
  69         WriteByte(MSG_ENTITY, nags);
  70
  71         if (nags & BIT(6))
  72         {
  73                 WriteByte(MSG_ENTITY, vote_accept_count);
  74                 WriteByte(MSG_ENTITY, vote_reject_count);
  75                 WriteByte(MSG_ENTITY, vote_needed_overall);
  76                 WriteChar(MSG_ENTITY, to.vote_selection);
  77         }
  78
  79         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  80
  81         if (nags & BIT(0))
  82         {
  83                 for (int i = 1; i <= maxclients;)
  84                 {
  85                         int f = 0;
  86                         for (int b = 0; b < 8 && i <= maxclients; ++b, ++i)
  87                                 if (edict_num(i).ready)
  88                                         f |= BIT(b);
  89                         WriteByte(MSG_ENTITY, f);
  90                 }
  91         }
  92
  93         return true;
  94 }
  95
  96 void Nagger_Init()
  97 {
  98         Net_LinkEntity(nagger = new_pure(nagger), false, 0, Nagger_SendEntity);
  99 }
 100
 101 void Nagger_VoteChanged()
 102 {
 103         if (nagger) nagger.SendFlags |= BIT(7);
 104 }
 105
 106 void Nagger_VoteCountChanged()
 107 {
 108         if (nagger) nagger.SendFlags |= BIT(6);
 109 }
 110
 111 void Nagger_ReadyCounted()
 112 {
 113         if (nagger) nagger.SendFlags |= BIT(0);
 114 }
 115
 116 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 117 string OriginalCallerName()
 118 {
 119         if (IS_REAL_CLIENT(vote_caller)) return playername(vote_caller.netname, vote_caller.team, false);
 120         return vote_caller_name;
 121 }
 122
 123 // =======================
 124 //  Game logic for voting
 125 // =======================
 126
 127 void VoteReset()
 128 {
 129         FOREACH_CLIENT(true, { it.vote_selection = 0; });
 130
 131         if (vote_called)
 132         {
 133                 strfree(vote_called_command);
 134                 strfree(vote_called_display);
 135                 strfree(vote_caller_name);
 136         }
 137
 138         vote_called = VOTE_NULL;
 139         vote_caller = NULL;
 140         vote_endtime = 0;
 141
 142         vote_parsed_command = string_null;
 143         vote_parsed_display = string_null;
 144
 145         Nagger_VoteChanged();
 146 }
 147
 148 void VoteStop(entity stopper)
 149 {
 150         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 151         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 152         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 153         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 154         VoteReset();
 155 }
 156
 157 void VoteAccept()
 158 {
 159         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 160
 161         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = true;
 162         else localcmd(strcat(vote_called_command, "\n"));
 163
 164         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 165
 166         VoteReset();
 167         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 168 }
 169
 170 void VoteReject()
 171 {
 172         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 173         VoteReset();
 174         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 175 }
 176
 177 void VoteTimeout()
 178 {
 179         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 180         VoteReset();
 181         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 182 }
 183
 184 void VoteSpam(float notvoters, float mincount, string result)
 185 {
 186         bprint(strcat(
 187                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 188                 strcat("^2:^1", ftos(vote_reject_count)),
 189                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 190                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 191                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 192
 193         if (autocvar_sv_eventlog)
 194         {
 195                 GameLogEcho(strcat(
 196                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 197                         strcat(":", ftos(vote_reject_count)),
 198                         strcat(":", ftos(vote_abstain_count)),
 199                         strcat(":", ftos(notvoters)),
 200                         strcat(":", ftos(mincount))));
 201         }
 202 }
 203
 204 #define spectators_allowed (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || intermission_running)))
 205
 206 void VoteCount(float first_count)
 207 {
 208         // declarations
 209         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 210
 211         float vote_player_count = 0, notvoters = 0;
 212         float vote_real_player_count = 0, vote_real_accept_count = 0;
 213         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 214         float vote_needed_of_voted, final_needed_votes;
 215         float vote_factor_overall, vote_factor_of_voted;
 216
 217         Nagger_VoteCountChanged();
 218
 219         // add up all the votes from each connected client
 220         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 221                 ++vote_player_count;
 222                 if (IS_PLAYER(it) || INGAME(it)) ++vote_real_player_count;
 223                 switch (it.vote_selection)
 224                 {
 225                         case VOTE_SELECT_REJECT:
 226                                 ++vote_reject_count;
 227                                 if (IS_PLAYER(it) || INGAME(it)) ++vote_real_reject_count;
 228                                 break;
 229                         case VOTE_SELECT_ACCEPT:
 230                                 ++vote_accept_count;
 231                                 if (IS_PLAYER(it) || INGAME(it)) ++vote_real_accept_count;
 232                                 break;
 233                         case VOTE_SELECT_ABSTAIN:
 234                                 ++vote_abstain_count;
 235                                 if (IS_PLAYER(it) || INGAME(it)) ++vote_real_abstain_count;
 236                                 break;
 237                         default: break;
 238                 }
 239         });
 240
 241         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 242         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 243         {
 244                 if (vote_caller)   vote_caller.vote_waittime = 0;
 245                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 246                 VoteReset();
 247                 return;
 248         }
 249
 250         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 251         if (!spectators_allowed && (vote_real_player_count > 0))
 252         {
 253                 vote_accept_count = vote_real_accept_count;
 254                 vote_reject_count = vote_real_reject_count;
 255                 vote_abstain_count = vote_real_abstain_count;
 256                 vote_player_count = vote_real_player_count;
 257         }
 258
 259         // people who have no opinion in any way :D
 260         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 261
 262         // determine the goal for the vote to be passed or rejected normally
 263         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 264         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 265
 266         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 267         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 268         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 269
 270         // are there any players at all on the server? it could be an admin vote
 271         if (vote_player_count == 0 && first_count)
 272         {
 273                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 274                 VoteAccept();
 275                 return;
 276         }
 277
 278         // since there ARE players, finally calculate the result of the vote
 279         if (vote_accept_count >= vote_needed_overall)
 280         {
 281                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 282                 VoteAccept();
 283                 return;
 284         }
 285
 286         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 287         {
 288                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 289                 VoteReject();
 290                 return;
 291         }
 292
 293         // there is not enough votes in either direction, now lets just calculate what the voters have said
 294         if (time > vote_endtime)
 295         {
 296                 final_needed_votes = vote_needed_overall;
 297
 298                 if (autocvar_sv_vote_majority_factor_of_voted)
 299                 {
 300                         if (vote_accept_count >= vote_needed_of_voted)
 301                         {
 302                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 303                                 VoteAccept();
 304                                 return;
 305                         }
 306
 307                         if (vote_accept_count + vote_reject_count > 0)
 308                         {
 309                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 310                                 VoteReject();
 311                                 return;
 312                         }
 313
 314                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 315                 }
 316
 317                 // it didn't pass or fail, so not enough votes to even make a decision.
 318                 VoteSpam(notvoters, final_needed_votes, "timeout");
 319                 VoteTimeout();
 320         }
 321 }
 322
 323 void VoteThink()
 324 {
 325         if (vote_endtime > 0)        // a vote was called
 326         {
 327                 if (time > vote_endtime) // time is up
 328                         VoteCount(false);
 329         }
 330 }
 331
 332
 333 // =======================
 334 //  Game logic for warmup
 335 // =======================
 336
 337 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 338 void reset_map(bool is_fake_round_start)
 339 {
 340         if (time <= game_starttime)
 341         {
 342                 if (game_stopped)
 343                         return;
 344
 345                 if (!is_fake_round_start)
 346                 {
 347                         Score_ClearAll();
 348                         PlayerStats_GameReport_Reset_All();
 349                 }
 350
 351                 if (round_handler_IsActive())
 352                         round_handler_Reset(game_starttime);
 353         }
 354
 355         if (shuffleteams_on_reset_map)
 356         {
 357                 shuffleteams();
 358                 shuffleteams_on_reset_map = false;
 359         }
 360
 361         FOREACH_CLIENT(true, {
 362                 if (time <= game_starttime)
 363                         accuracy_reset(it); // for spectators too because weapon accuracy is persistent
 364                 if (!IS_PLAYER(it))
 365                         continue;
 366                 if (STAT(FROZEN, it))
 367                         Unfreeze(it, false);
 368                 player_powerups_remove_all(it);
 369                 entity store = PS(it);
 370                 if (store)
 371                 {
 372                         Inventory_clear(store.inventory);
 373                         Inventory_update(store);
 374                 }
 375         });
 376
 377         MUTATOR_CALLHOOK(reset_map_global);
 378
 379         FOREACH_ENTITY_FLOAT_ORDERED(pure_data, false,
 380         {
 381                 if(IS_CLIENT(it))
 382                         continue;
 383                 if (it.reset)
 384                 {
 385                         it.reset(it);
 386                         continue;
 387                 }
 388                 if (it.team_saved) it.team = it.team_saved;
 389                 if (it.flags & FL_PROJECTILE) delete(it);  // remove any projectiles left
 390         });
 391
 392         // Waypoints and assault start come LAST
 393         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 394                 if (it.reset2) it.reset2(it);
 395         });
 396
 397         // Moving the player reset code here since the player-reset depends
 398         // on spawnpoint entities which have to be reset first --blub
 399         if (!MUTATOR_CALLHOOK(reset_map_players))
 400         {
 401                 FOREACH_CLIENT(IS_PLAYER(it),
 402                 {
 403                         // PlayerScore_Clear(it);
 404                         CS(it).killcount = 0;
 405                         // stop the player from moving so that they stand still once they get respawned
 406                         it.velocity = '0 0 0';
 407                         it.avelocity = '0 0 0';
 408                         CS(it).movement = '0 0 0';
 409                         PutClientInServer(it);
 410                 });
 411         }
 412 }
 413
 414 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 415 void ReadyRestart_think(entity this)
 416 {
 417         if (!warmup_stage) // if the countdown was not aborted
 418                 reset_map(false);
 419         delete(this);
 420 }
 421
 422 // Forces a restart of the game without actually reloading the map // this is a mess...
 423 void ReadyRestart_force(bool is_fake_round_start)
 424 {
 425         if (time <= game_starttime && game_stopped)
 426                 return;
 427         if (!is_fake_round_start && !autocvar_g_campaign)
 428                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_COUNTDOWN_RESTART);
 429
 430         VoteReset();
 431
 432         // clear overtime, we have to decrease timelimit to its original value again.
 433         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
 434                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 435         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = overtimes = 0;
 436
 437         if(warmup_stage)
 438                 game_starttime = time; // Warmup: No countdown in warmup
 439         else if (autocvar_g_campaign)
 440                 game_starttime = time + 3;
 441         else
 442                 game_starttime = time + RESTART_COUNTDOWN; // Go into match mode
 443
 444         // clear player attributes
 445         FOREACH_CLIENT(IS_PLAYER(it), {
 446                 it.alivetime = 0;
 447                 CS(it).killcount = 0;
 448         });
 449
 450         // if we're ending the warmup stage call the corresponding hook
 451         if(!is_fake_round_start && !warmup_stage)
 452                 localcmd("\nsv_hook_warmupend\n");
 453
 454         // reset the .ready status of all clients (including spectators and bots)
 455         FOREACH_CLIENT(true, { it.ready = false; });
 456         readycount = 0;
 457         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 458
 459         // lock teams with lockonrestart
 460         if (autocvar_teamplay_lockonrestart && teamplay)
 461                 lockteams = !warmup_stage;
 462
 463         // initiate the restart-countdown-announcer entity
 464         if (!is_fake_round_start && sv_ready_restart_after_countdown && !warmup_stage)
 465         {
 466                 entity restart_timer = new_pure(restart_timer);
 467                 setthink(restart_timer, ReadyRestart_think);
 468                 restart_timer.nextthink = game_starttime;
 469         }
 470
 471         // after a restart every players number of allowed timeouts gets reset, too
 472         if (autocvar_sv_timeout)
 473         {
 474                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), { CS(it).allowed_timeouts = autocvar_sv_timeout_number; });
 475         }
 476
 477         if (!sv_ready_restart_after_countdown || warmup_stage)
 478                 reset_map(is_fake_round_start);
 479
 480         if (autocvar_sv_eventlog) GameLogEcho(":restart");
 481 }
 482
 483 void ReadyRestart(bool forceWarmupEnd)
 484 {
 485         if (MUTATOR_CALLHOOK(ReadyRestart_Deny) || intermission_running || race_completing)
 486         {
 487                 // NOTE: ReadyRestart support is mandatory in campaign
 488                 if (autocvar_g_campaign)
 489                         error("ReadyRestart must be supported in campaign mode!");
 490                 localcmd("restart\n"); // if ReadyRestart is denied, restart the server
 491         }
 492         else localcmd("\nsv_hook_readyrestart\n");
 493
 494         if(forceWarmupEnd || autocvar_g_campaign)
 495                 warmup_stage = 0; // forcefully end warmup and go to match stage
 496         else
 497                 warmup_stage = autocvar_g_warmup; // go into warmup if it's enabled, otherwise restart into match stage
 498
 499         ReadyRestart_force(false);
 500 }
 501
 502 /* Count the players who are ready and determine whether or not to restart the match when:
 503  * a player presses F4                      server/command/cmd.qc  ClientCommand_ready()
 504  * a player switches from players to specs  server/client.qc       PutObserverInServer()
 505  * a player joins (from specs or directly)  server/client.qc       PutPlayerInServer()
 506  * a player disconnects                     server/client.qc       ClientDisconnect()   */
 507 void ReadyCount()
 508 {
 509         // cannot reset the game while a timeout is active or pending
 510         if (timeout_status) return;
 511
 512         int total_players = 0, human_players = 0, humans_ready = 0;
 513         readycount = 0;
 514
 515         FOREACH_CLIENT(IS_PLAYER(it) || INGAME_JOINED(it), {
 516                 ++total_players;
 517                 if (it.ready) ++readycount;
 518                 if (IS_REAL_CLIENT(it))
 519                 {
 520                         ++human_players;
 521                         if (it.ready) ++humans_ready;
 522                 }
 523         });
 524
 525         Nagger_ReadyCounted();
 526
 527         // can't read warmup_stage here as it could have been set to 0 by ReadyRestart()
 528         // and we need to use this when checking if we should abort the countdown
 529         // map_minplayers can only be > 0 if g_warmup was -1 at worldspawn
 530         int minplayers = autocvar_g_warmup > 1 ? autocvar_g_warmup : map_minplayers;
 531
 532         if (total_players < minplayers)
 533         {
 534                 if (game_starttime > time) // someone bailed during countdown, back to warmup
 535                 {
 536                         warmup_stage = autocvar_g_warmup; // CAN change it AFTER calling Nagger_ReadyCounted() this frame
 537                         game_starttime = time;
 538                         Send_Notification(NOTIF_ALL, NULL, MSG_MULTI, COUNTDOWN_STOP, minplayers);
 539                         if (!sv_ready_restart_after_countdown) // if we ran reset_map() at start of countdown
 540                                 FOREACH_CLIENT(IS_PLAYER(it), { GiveWarmupResources(it); });
 541                 }
 542                 if (warmup_limit > 0)
 543                         warmup_limit = -1;
 544                 return; // don't ReadyRestart if players are ready but too few
 545         }
 546         else if (minplayers && warmup_limit <= 0)
 547         {
 548                 // there's enough players now but we're still in infinite warmup
 549                 warmup_limit = cvar("g_warmup_limit");
 550                 if (warmup_limit == 0)
 551                         warmup_limit = autocvar_timelimit * 60;
 552                 if (warmup_limit > 0)
 553                         game_starttime = time;
 554                 // implicit else: g_warmup -1 && g_warmup_limit -1 means
 555                 // warmup continues until enough players AND enough RUPs (no time limit)
 556         }
 557
 558         if (humans_ready && humans_ready >= rint(human_players * bound(0.5, cvar("g_warmup_majority_factor"), 1)))
 559                 ReadyRestart(true);
 560 }
 561
 562
 563 // ======================================
 564 //  Supporting functions for VoteCommand
 565 // ======================================
 566
 567 bool Votecommand_check_assignment(entity caller, float assignment)
 568 {
 569         bool from_server = (!caller);
 570
 571         if ((assignment == VC_ASGNMNT_BOTH)
 572             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 573             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 574
 575         return false;
 576 }
 577
 578 string VoteCommand_extractcommand(string input, float startpos, int argc)
 579 {
 580         string output;
 581
 582         if ((argc - 1) < startpos) output = "";
 583         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 584
 585         return output;
 586 }
 587
 588 bool VoteCommand_checknasty(string vote_command)
 589 {
 590         return !((strstrofs(vote_command, ";", 0) >= 0)
 591             || (strstrofs(vote_command, "\n", 0) >= 0)
 592             || (strstrofs(vote_command, "\r", 0) >= 0)
 593             || (strstrofs(vote_command, "$", 0) >= 0));
 594 }
 595
 596 // NOTE: requires input to be surrounded by spaces
 597 string VoteCommand_checkreplacements(string input)
 598 {
 599         // add a space around the input so the start and end of the list is captured
 600         string output = strcat(" ", input, " ");
 601         // allow gotomap replacements
 602         output = strreplace(" map ", " gotomap ", output);
 603         output = strreplace(" chmap ", " gotomap ", output);
 604         return output;
 605 }
 606
 607 bool VoteCommand_checkinlist(string vote_command, string list)
 608 {
 609         if (vote_command == "" || list == "")
 610                 return false;
 611
 612         string l = VoteCommand_checkreplacements(list);
 613         return (strstrofs(l, VoteCommand_checkreplacements(vote_command), 0) >= 0);
 614 }
 615
 616 string ValidateMap(string validated_map, entity caller)
 617 {
 618         validated_map = MapInfo_FixName(validated_map);
 619
 620         if (!validated_map)
 621         {
 622                 print_to(caller, "This map is not available on this server.");
 623                 return string_null;
 624         }
 625
 626         if (!autocvar_sv_vote_override_mostrecent && caller)
 627         {
 628                 if (Map_IsRecent(validated_map))
 629                 {
 630                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 631                         return string_null;
 632                 }
 633         }
 634
 635         if (!MapInfo_CheckMap(validated_map))
 636         {
 637                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 638                 return string_null;
 639         }
 640
 641         return validated_map;
 642 }
 643
 644 float VoteCommand_checkargs(float startpos, int argc)
 645 {
 646         float p, q, check, minargs;
 647         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 648         string cmdrestriction = "";  // No we don't.
 649         string charlist, arg;
 650         float checkmate;
 651
 652         if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
 653                 cmdrestriction = cvar_string(cvarname);
 654         else
 655                 LOG_INFO("NOTE: ", cvarname, " does not exist, no restrictions will be applied.");
 656
 657         if (cmdrestriction == "") return true;
 658
 659         ++startpos;  // skip command name
 660
 661         // check minimum arg count
 662
 663         // 0 args: argc == startpos
 664         // 1 args: argc == startpos + 1
 665         // ...
 666
 667         minargs = stof(cmdrestriction);
 668         if (argc - startpos < minargs) return false;
 669
 670         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 671
 672         for ( ; ; )
 673         {
 674                 // we know that at any time, startpos <= argc - minargs
 675                 // so this means: argc-minargs >= startpos >= argc, thus
 676                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 677                 // have been seen already
 678
 679                 if (startpos >= argc) // all args checked? GOOD
 680                         break;
 681
 682                 if (p < 0)            // no more args? FAIL
 683                 {
 684                         // exception: exactly minargs left, this one included
 685                         if (argc - startpos == minargs) break;
 686
 687                         // otherwise fail
 688                         return false;
 689                 }
 690
 691                 // cut to next semicolon
 692                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 693                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 694                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 695
 696                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 697                 // charlist = strreplace("^^", ";", charlist);
 698
 699                 if (charlist != "")
 700                 {
 701                         // verify the arg only contains allowed chars
 702                         arg = argv(startpos);
 703                         checkmate = strlen(arg);
 704                         for (check = 0; check < checkmate; ++check)
 705                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 706                         // not allowed character
 707                         // all characters are allowed. FINE.
 708                 }
 709
 710                 ++startpos;
 711                 --minargs;
 712                 p = q;
 713         }
 714
 715         return true;
 716 }
 717
 718 int VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, int argc)
 719 {
 720         string first_command = argv(startpos);
 721         int missing_chars = argv_start_index(startpos);
 722
 723         if (autocvar_sv_vote_limit > 0 && strlen(vote_command) > autocvar_sv_vote_limit)
 724                 return 0;
 725
 726         if (!VoteCommand_checkinlist(first_command, vote_list)) return 0;
 727
 728         if (!VoteCommand_checkargs(startpos, argc)) return 0;
 729
 730         switch (MUTATOR_CALLHOOK(VoteCommand_Parse, caller, first_command, vote_command, startpos, argc))
 731         {
 732                 case MUT_VOTEPARSE_CONTINUE: { break; }
 733                 case MUT_VOTEPARSE_SUCCESS: { return 1; }
 734                 case MUT_VOTEPARSE_INVALID: { return -1; }
 735                 case MUT_VOTEPARSE_UNACCEPTABLE: { return 0; }
 736         }
 737
 738         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 739         {
 740                 case "kick":
 741                 case "kickban":    // catch all kick/kickban commands
 742                 {
 743                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 744                         float accepted = VerifyClientEntity(victim, true, false);
 745
 746                         if (accepted > 0)
 747                         {
 748                                 string reason = "No reason provided";
 749                                 if(argc > next_token)
 750                                         reason = substring(vote_command, argv_start_index(next_token) - missing_chars, -1);
 751
 752                                 string command_arguments = reason;
 753                                 if (first_command == "kickban")
 754                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 755
 756                                 vote_parsed_command = strcat(first_command, " # ", ftos(etof(victim)), " ", command_arguments);
 757                                 vote_parsed_display = sprintf("^1%s #%d ^7%s^1 %s", first_command, etof(victim), victim.netname, reason);
 758                         }
 759                         else
 760                         {
 761                                 print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n"));
 762                                 return 0;
 763                         }
 764
 765                         break;
 766                 }
 767
 768                 case "map":
 769                 case "chmap":
 770                 case "gotomap":  // re-direct all map selection commands to gotomap
 771                 {
 772                         vote_command = ValidateMap(argv(startpos + 1), caller);
 773                         if (!vote_command)  return -1;
 774                         vote_parsed_command = strcat("gotomap ", vote_command);
 775                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 776
 777                         break;
 778                 }
 779
 780                 // TODO: replicate the old behaviour of being able to vote for maps from different modes on multimode servers (possibly support it in gotomap too)
 781                 // maybe fallback instead of aborting if map name is invalid?
 782                 case "nextmap":
 783                 {
 784                         vote_command = ValidateMap(argv(startpos + 1), caller);
 785                         if (!vote_command)  return -1;
 786                         vote_parsed_command = strcat("nextmap ", vote_command);
 787                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 788
 789                         break;
 790                 }
 791
 792                 case "timelimit": // include restrictions on the maximum votable time limit
 793                 {
 794                         float timelimit_vote = stof(argv(startpos + 1));
 795                         if(timelimit_vote > autocvar_timelimit_max || timelimit_vote < autocvar_timelimit_min)
 796                         {
 797                                 print_to(caller, strcat("Invalid timelimit vote, accepted values are between ", ftos(autocvar_timelimit_min), " and ", ftos(autocvar_timelimit_max), "."));
 798                                 return -1;
 799                         }
 800                         timelimit_vote = bound(autocvar_timelimit_min, timelimit_vote, autocvar_timelimit_max);
 801                         vote_parsed_command = strcat("timelimit ", ftos(timelimit_vote));
 802                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 803
 804                         break;
 805                 }
 806
 807                 case "restart":
 808                 {
 809                         // add a delay so that vote result can be seen and announcer can be heard
 810                         // if the vote is accepted
 811                         vote_parsed_command = strcat("defer 1 ", vote_command);
 812                         vote_parsed_display = strzone(strcat("^1", vote_command));
 813
 814                         break;
 815                 }
 816
 817                 case "allready":
 818                 {
 819                         if(!warmup_stage) {
 820                                 print_to(caller, "Game already started. Use the resetmatch command to restart the match.");
 821                                 return -1;
 822                         }
 823
 824                         vote_parsed_command = vote_command;
 825                         vote_parsed_display = strzone(strcat("^1", vote_command));
 826                         break;
 827                 }
 828
 829                 default:
 830                 {
 831                         vote_parsed_command = vote_command;
 832                         vote_parsed_display = strzone(strcat("^1", vote_command));
 833
 834                         break;
 835                 }
 836         }
 837
 838         return 1;
 839 }
 840
 841
 842 // =======================
 843 //  Command Sub-Functions
 844 // =======================
 845
 846 void VoteCommand_abstain(int request, entity caller)  // CLIENT ONLY
 847 {
 848         switch (request)
 849         {
 850                 case CMD_REQUEST_COMMAND:
 851                 {
 852                         if (PlayerInList(caller, autocvar_g_voteban_list)) // voteban
 853                         {
 854                                 print_to(caller, "^1You are banned from voting.");
 855                                 Send_Notification(NOTIF_ONE, caller, MSG_CENTER, CENTER_VOTEBANYN);
 856                                 return;
 857                         }
 858
 859                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 860                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 861                         {
 862                                 print_to(caller, "^1You have already voted.");
 863                         }
 864
 865                         else  // everything went okay, continue changing vote
 866                         {
 867                                 print_to(caller, "^1You abstained from your vote.");
 868                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 869                                 msg_entity = caller;
 870                                 if (!autocvar_sv_vote_singlecount)
 871                                         VoteCount(false);
 872                         }
 873
 874                         return;
 875                 }
 876
 877                 default:
 878                 case CMD_REQUEST_USAGE:
 879                 {
 880                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 881                         print_to(caller, "  No arguments required.");
 882                         return;
 883                 }
 884         }
 885 }
 886
 887 void print_available_commands_to(entity caller)
 888 {
 889         print_to(caller, strcat("You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
 890 }
 891
 892 void VoteCommand_call(int request, entity caller, int argc, string vote_command)  // BOTH
 893 {
 894         switch (request)
 895         {
 896                 case CMD_REQUEST_COMMAND:
 897                 {
 898                         float tmp_playercount = 0;
 899                         int parse_error;
 900
 901                         if (PlayerInList(caller, autocvar_g_voteban_list)) // voteban
 902                         {
 903                                 print_to(caller, "^1You are banned from calling a vote.");
 904                                 Send_Notification(NOTIF_ONE, caller, MSG_CENTER, CENTER_VOTEBAN);
 905                                 return;
 906                         }
 907
 908                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 909
 910                         if (!autocvar_sv_vote_call && caller)
 911                         {
 912                                 print_to(caller, "^1Vote calling is not allowed.");
 913                         }
 914                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 915                         {
 916                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 917                         }
 918                         else if (vote_called)
 919                         {
 920                                 print_to(caller, "^1There is already a vote called.");
 921                         }
 922                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 923                         {
 924                                 print_to(caller, "^1Only players can call a vote.");
 925                         }
 926                         else if (caller && !IS_CLIENT(caller))
 927                         {
 928                                 print_to(caller, "^1Only connected clients can vote.");
 929                         }
 930                         else if (timeout_status && vote_command != "timein")
 931                         {
 932                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 933                         }
 934                         else if (caller && (time < caller.vote_waittime))
 935                         {
 936                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 937                         }
 938                         else if (!VoteCommand_checknasty(vote_command))
 939                         {
 940                                 print_to(caller, "^1Syntax error in command.");
 941                         }
 942                         else if ((parse_error = VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) <= 0)
 943                         {
 944                                 if(parse_error == 0)
 945                                 {
 946                                         if (vote_called_command == "")
 947                                                 VoteCommand_call(CMD_REQUEST_USAGE, caller, argc, vote_command);
 948                                         else
 949                                                 print_to(caller, "^1This command is not acceptable or not available.");
 950                                 }
 951                         }
 952                         else  // everything went okay, continue with calling the vote
 953                         {
 954                                 vote_caller = caller;  // remember who called the vote
 955                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 956                                 vote_called = VOTE_NORMAL;
 957                                 vote_called_command = strzone(vote_parsed_command);
 958                                 vote_called_display = strzone(vote_parsed_display);
 959                                 vote_endtime = time + autocvar_sv_vote_timeout;
 960
 961                                 if (caller)
 962                                 {
 963                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 964                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 965                                         msg_entity = caller;
 966                                 }
 967
 968                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++tmp_playercount; });
 969
 970                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 971                                 if (autocvar_sv_eventlog)
 972                                         GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 973                                 Nagger_VoteChanged();
 974                                 VoteCount(true);  // needed if you are the only one
 975
 976                                 if (tmp_playercount > 1 && vote_called != VOTE_NULL)
 977                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_CALL);
 978                         }
 979
 980                         return;
 981                 }
 982
 983                 default:
 984                 case CMD_REQUEST_USAGE:
 985                 {
 986                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call <command>"));
 987                         print_to(caller, "  Where <command> is the command to request a vote upon.");
 988                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 989                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 990                         print_available_commands_to(caller);
 991                         print_to(caller, "Shortcuts: ^2vcall <command>, vend, vmap, vkick, ...");
 992                         return;
 993                 }
 994         }
 995 }
 996
 997 void VoteCommand_master(int request, entity caller, int argc, string vote_command)  // CLIENT ONLY
 998 {
 999         switch (request)
1000         {
1001                 case CMD_REQUEST_COMMAND:
1002                 {
1003                         if (autocvar_sv_vote_master)
1004                         {
1005                                 switch (strtolower(argv(2)))
1006                                 {
1007                                         case "do":
1008                                         {
1009                                                 int parse_error;
1010                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
1011
1012                                                 if (!caller.vote_master)
1013                                                         print_to(caller, "^1You do not have vote master privileges.");
1014                                                 else if (!VoteCommand_checknasty(vote_command))
1015                                                 {
1016                                                         print_to(caller, "^1Syntax error in command.");
1017                                                 }
1018                                                 else if ((parse_error = VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) <= 0)
1019                                                 {
1020                                                         if(parse_error == 0)
1021                                                         {
1022                                                                 if (vote_called_command == "")
1023                                                                         VoteCommand_master(CMD_REQUEST_USAGE, caller, argc, vote_command);
1024                                                                 else
1025                                                                         print_to(caller, "^1This command is not acceptable or not available.");
1026                                                         }
1027                                                 }
1028                                                 else  // everything went okay, proceed with command
1029                                                 {
1030                                                         localcmd(strcat(vote_parsed_command, "\n"));
1031                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
1032                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
1033                                                         if (autocvar_sv_eventlog)
1034                                                                 GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display));
1035                                                 }
1036
1037                                                 return;
1038                                         }
1039
1040                                         case "login":
1041                                         {
1042                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
1043                                                 else if (caller.vote_master)
1044                                                 {
1045                                                         print_to(caller, "^1You are already logged in as vote master.");
1046                                                 }
1047                                                 else if (autocvar_sv_vote_master_password != argv(3))
1048                                                 {
1049                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
1050                                                 }
1051                                                 else  // everything went okay, proceed with giving this player master privilages
1052                                                 {
1053                                                         caller.vote_master = true;
1054                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
1055                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
1056                                                         if (autocvar_sv_eventlog)
1057                                                                 GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid)));
1058                                                 }
1059
1060                                                 return;
1061                                         }
1062
1063                                         default:  // calling a vote for master
1064                                         {
1065                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
1066                                                 else if (vote_called)
1067                                                 {
1068                                                         print_to(caller, "^1There is already a vote called.");
1069                                                 }
1070                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
1071                                                 {
1072                                                         print_to(caller, "^1Only players can call a vote.");
1073                                                 }
1074                                                 else if (timeout_status)
1075                                                 {
1076                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
1077                                                 }
1078                                                 else  // everything went okay, continue with creating vote
1079                                                 {
1080                                                         vote_caller = caller;
1081                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
1082                                                         vote_called = VOTE_MASTER;
1083                                                         vote_called_command = strzone("XXX");
1084                                                         vote_called_display = strzone("^3master");
1085                                                         vote_endtime = time + autocvar_sv_vote_timeout;
1086
1087                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
1088                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
1089
1090                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
1091                                                         if (autocvar_sv_eventlog)
1092                                                                 GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
1093                                                         Nagger_VoteChanged();
1094                                                         VoteCount(true);  // needed if you are the only one
1095                                                 }
1096
1097                                                 return;
1098                                         }
1099                                 }
1100                         }
1101                         else { print_to(caller, "^1Master control of voting is not allowed."); }
1102
1103                         return;
1104                 }
1105
1106                 default:
1107                 case CMD_REQUEST_USAGE:
1108                 {
1109                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [<action> [<command> | <password>]]"));
1110                         print_to(caller, "  If <action> is left blank, it calls a vote for you to become master.");
1111                         print_to(caller, "  Otherwise it can be either 'do' (to run <command>) or 'login' as master.");
1112                         return;
1113                 }
1114         }
1115 }
1116
1117 void VoteCommand_no(int request, entity caller)  // CLIENT ONLY
1118 {
1119         switch (request)
1120         {
1121                 case CMD_REQUEST_COMMAND:
1122                 {
1123                         if (PlayerInList(caller, autocvar_g_voteban_list)) // voteban
1124                         {
1125                                 print_to(caller, "^1You are banned from voting.");
1126                                 Send_Notification(NOTIF_ONE, caller, MSG_CENTER, CENTER_VOTEBANYN);
1127                                 return;
1128                         }
1129
1130                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1131                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1132                         {
1133                                 print_to(caller, "^1You have already voted.");
1134                         }
1135                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
1136                         {
1137                                 VoteStop(caller);
1138                         }
1139
1140                         else  // everything went okay, continue changing vote
1141                         {
1142                                 print_to(caller, "^1You rejected the vote.");
1143                                 caller.vote_selection = VOTE_SELECT_REJECT;
1144                                 msg_entity = caller;
1145                                 if (!autocvar_sv_vote_singlecount)
1146                                         VoteCount(false);
1147                         }
1148
1149                         return;
1150                 }
1151
1152                 default:
1153                 case CMD_REQUEST_USAGE:
1154                 {
1155                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
1156                         print_to(caller, "  No arguments required.");
1157                         return;
1158                 }
1159         }
1160 }
1161
1162 void VoteCommand_status(int request, entity caller)  // BOTH
1163 {
1164         switch (request)
1165         {
1166                 case CMD_REQUEST_COMMAND:
1167                 {
1168                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
1169                         else print_to(caller, "^1No vote called.");
1170
1171                         return;
1172                 }
1173
1174                 default:
1175                 case CMD_REQUEST_USAGE:
1176                 {
1177                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1178                         print_to(caller, "  No arguments required.");
1179                         return;
1180                 }
1181         }
1182 }
1183
1184 void VoteCommand_stop(int request, entity caller)  // BOTH
1185 {
1186         switch (request)
1187         {
1188                 case CMD_REQUEST_COMMAND:
1189                 {
1190                         if (!vote_called)   print_to(caller, "^1No vote called.");
1191                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller);
1192                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1193                         return;
1194                 }
1195
1196                 default:
1197                 case CMD_REQUEST_USAGE:
1198                 {
1199                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1200                         print_to(caller, "  No arguments required.");
1201                         return;
1202                 }
1203         }
1204 }
1205
1206 void VoteCommand_yes(int request, entity caller)  // CLIENT ONLY
1207 {
1208         switch (request)
1209         {
1210                 case CMD_REQUEST_COMMAND:
1211                 {
1212                         if (PlayerInList(caller, autocvar_g_voteban_list)) // voteban
1213                         {
1214                                 print_to(caller, "^1You are banned from voting.");
1215                                 Send_Notification(NOTIF_ONE, caller, MSG_CENTER, CENTER_VOTEBANYN);
1216                                 return;
1217                         }
1218
1219                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1220                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1221                         {
1222                                 print_to(caller, "^1You have already voted.");
1223                         }
1224                         else  // everything went okay, continue changing vote
1225                         {
1226                                 print_to(caller, "^1You accepted the vote.");
1227                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1228                                 msg_entity = caller;
1229                                 if (!autocvar_sv_vote_singlecount)
1230                                         VoteCount(false);
1231                         }
1232
1233                         return;
1234                 }
1235
1236                 default:
1237                 case CMD_REQUEST_USAGE:
1238                 {
1239                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1240                         print_to(caller, "  No arguments required.");
1241                         return;
1242                 }
1243         }
1244 }
1245
1246 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1247 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1248 void VoteCommand_(int request)
1249 {
1250     switch(request)
1251     {
1252         case CMD_REQUEST_COMMAND:
1253         {
1254
1255             return;
1256         }
1257
1258         default:
1259         case CMD_REQUEST_USAGE:
1260         {
1261             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1262             print_to(caller, "  No arguments required.");
1263             return;
1264         }
1265     }
1266 }
1267 */
1268
1269
1270 // ================================
1271 //  Macro system for vote commands
1272 // ================================
1273
1274 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1275 #define VOTE_COMMANDS(request, caller, arguments, command) \
1276         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1277         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1278         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1279         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1280         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1281         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1282         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1283         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1284         /* nothing */
1285
1286 void VoteCommand_macro_help(entity caller, int argc)
1287 {
1288         string command_origin = GetCommandPrefix(caller);
1289
1290         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1291         {
1292                 print_to(caller, "\nVoting commands:\n");
1293                 #define VOTE_COMMAND(name, function, description, assignment) \
1294                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1295
1296                 VOTE_COMMANDS(0, caller, 0, "");
1297                 #undef VOTE_COMMAND
1298
1299                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote <command>^7, where possible commands are listed above.\n"));
1300                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help <command>"));
1301                 print_available_commands_to(caller);
1302         }
1303         else  // usage for individual command
1304         {
1305                 #define VOTE_COMMAND(name, function, description, assignment) \
1306                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1307
1308                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1309                 #undef VOTE_COMMAND
1310
1311                 string cvarname = strcat("sv_vote_command_help_", argv(2));
1312                 if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
1313                         wordwrap_sprint(caller, cvar_string(cvarname), 1000);
1314                 else if (argv(2) != "")
1315                         print_to(caller, "No documentation exists for this vote");
1316         }
1317 }
1318
1319 float VoteCommand_macro_command(entity caller, int argc, string vote_command)
1320 {
1321         #define VOTE_COMMAND(name, function, description, assignment) \
1322                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1323
1324         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1325         #undef VOTE_COMMAND
1326
1327         return false;
1328 }
1329
1330
1331 // ======================================
1332 //  Main function handling vote commands
1333 // ======================================
1334
1335 void VoteCommand(int request, entity caller, int argc, string vote_command)
1336 {
1337         // Guide for working with argc arguments by example:
1338         // argc:   1    - 2      - 3     - 4
1339         // argv:   0    - 1      - 2     - 3
1340         // cmd     vote - master - login - password
1341
1342         switch (request)
1343         {
1344                 case CMD_REQUEST_COMMAND:
1345                 {
1346                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1347                 }
1348
1349                 default:
1350                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1351                 case CMD_REQUEST_USAGE:
1352                 {
1353                         VoteCommand_macro_help(caller, argc);
1354                         return;
1355                 }
1356         }
1357 }