qcsrc/server/command/cmd.qc

   1 // =========================================================
   2 //  Server side networked commands code, reworked by Samual
   3 //  Last updated: December 28th, 2011
   4 // =========================================================
   5
   6 float SV_ParseClientCommand_floodcheck()
   7 {
   8         if (!timeout_status) // not while paused
   9         {
  10                 if(time <= (self.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  11                 {
  12                         self.cmd_floodcount += 1;
  13                         if(self.cmd_floodcount > autocvar_sv_clientcommand_antispam_count) { return FALSE; } // too much spam, halt
  14                 }
  15                 else
  16                 {
  17                         self.cmd_floodtime = time;
  18                         self.cmd_floodcount = 1;
  19                 }
  20         }
  21         return TRUE; // continue, as we're not flooding yet
  22 }
  23
  24
  25 // =======================
  26 //  Command Sub-Functions
  27 // =======================
  28
  29 void ClientCommand_autoswitch(float request, float argc)
  30 {
  31         switch(request)
  32         {
  33                 case CMD_REQUEST_COMMAND:
  34                 {
  35                         if(argv(1) != "")
  36                         {
  37                                 self.autoswitch = InterpretBoolean(argv(1));
  38                                 sprint(self, strcat("^1autoswitch is currently turned ", (self.autoswitch ? "on" : "off"), ".\n"));
  39                                 return;
  40                         }
  41                 }
  42
  43                 default:
  44                         sprint(self, "Incorrect parameters for ^2autoswitch^7\n");
  45                 case CMD_REQUEST_USAGE:
  46                 {
  47                         sprint(self, "\nUsage:^3 cmd autoswitch selection\n");
  48                         sprint(self, "  Where 'selection' controls if autoswitch is on or off.\n");
  49                         return;
  50                 }
  51         }
  52 }
  53
  54 void ClientCommand_checkfail(float request, string command) // internal command, used only by code
  55 {
  56         switch(request)
  57         {
  58                 case CMD_REQUEST_COMMAND:
  59                 {
  60                         printf("CHECKFAIL: %s (%s) epically failed check %s\n", self.netname, self.netaddress, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  61                         self.checkfail = 1;
  62                         return; // never fall through to usage
  63                 }
  64
  65                 default:
  66                         sprint(self, "Incorrect parameters for ^2checkfail^7\n");
  67                 case CMD_REQUEST_USAGE:
  68                 {
  69                         sprint(self, "\nUsage:^3 cmd checkfail <message>\n");
  70                         sprint(self, "  Where 'message' is the message reported by client about the fail.\n");
  71                         return;
  72                 }
  73         }
  74 }
  75
  76 void ClientCommand_clientversion(float request, float argc) // internal command, used only by code
  77 {
  78         switch(request)
  79         {
  80                 case CMD_REQUEST_COMMAND:
  81                 {
  82                         if(argv(1) != "")
  83                         {
  84                                 if(IS_CLIENT(self))
  85                                 {
  86                                         self.version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
  87
  88                                         if(self.version < autocvar_gameversion_min || self.version > autocvar_gameversion_max)
  89                                         {
  90                                                 self.version_mismatch = 1;
  91                                                 ClientKill_TeamChange(-2); // observe
  92                                         }
  93                                         else if(autocvar_g_campaign || autocvar_g_balance_teams)
  94                                         {
  95                                                 //JoinBestTeam(self, FALSE, TRUE);
  96                                         }
  97                                         else if(teamplay && !autocvar_sv_spectate && !(self.team_forced > 0))
  98                                         {
  99                                                 self.classname = "observer"; // really?
 100                                                 stuffcmd(self, "menu_showteamselect\n");
 101                                         }
 102                                 }
 103
 104                                 return;
 105                         }
 106                 }
 107
 108                 default:
 109                         sprint(self, "Incorrect parameters for ^2clientversion^7\n");
 110                 case CMD_REQUEST_USAGE:
 111                 {
 112                         sprint(self, "\nUsage:^3 cmd clientversion version\n");
 113                         sprint(self, "  Where 'version' is the game version reported by self.\n");
 114                         return;
 115                 }
 116         }
 117 }
 118
 119 void ClientCommand_mv_getpicture(float request, float argc) // internal command, used only by code
 120 {
 121         switch(request)
 122         {
 123                 case CMD_REQUEST_COMMAND:
 124                 {
 125                         if(argv(1) != "")
 126                         {
 127                                 if(intermission_running)
 128                                         MapVote_SendPicture(stof(argv(1)));
 129
 130                                 return;
 131                         }
 132                 }
 133
 134                 default:
 135                         sprint(self, "Incorrect parameters for ^2mv_getpicture^7\n");
 136                 case CMD_REQUEST_USAGE:
 137                 {
 138                         sprint(self, "\nUsage:^3 cmd mv_getpicture mapid\n");
 139                         sprint(self, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 140                         return;
 141                 }
 142         }
 143 }
 144
 145 void ClientCommand_join(float request)
 146 {
 147         switch(request)
 148         {
 149                 case CMD_REQUEST_COMMAND:
 150                 {
 151                         if(IS_CLIENT(self))
 152                         {
 153                                 if(!IS_PLAYER(self) && !lockteams)
 154                                 {
 155                                         if(nJoinAllowed(self))
 156                                         {
 157                                                 if(autocvar_g_campaign) { campaign_bots_may_start = 1; }
 158
 159                                                 self.classname = "player";
 160                                                 PlayerScore_Clear(self);
 161                                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
 162                                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname);
 163                                                 PutClientInServer();
 164                                         }
 165                                         else
 166                                         {
 167                                                 //player may not join because of g_maxplayers is set
 168                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
 169                                         }
 170                                 }
 171                         }
 172                         return; // never fall through to usage
 173                 }
 174
 175                 default:
 176                 case CMD_REQUEST_USAGE:
 177                 {
 178                         sprint(self, "\nUsage:^3 cmd join\n");
 179                         sprint(self, "  No arguments required.\n");
 180                         return;
 181                 }
 182         }
 183 }
 184
 185 void ClientCommand_mobedit(float request, float argc)
 186 {
 187         switch(request)
 188         {
 189                 case CMD_REQUEST_COMMAND:
 190                 {
 191                         if(argv(1) && argv(2))
 192                         {
 193                                 makevectors(self.v_angle);
 194                                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
 195
 196                                 if(!autocvar_g_monsters_edit) { sprint(self, "Monster property editing is not enabled.\n"); return; }
 197                                 if(trace_ent.flags & FL_MONSTER)
 198                                 {
 199                                         if(trace_ent.realowner != self) { sprint(self, "That monster does not belong to you.\n"); return; }
 200                                         switch(argv(1))
 201                                         {
 202                                                 case "skin":
 203                                                 {
 204                                                         if(trace_ent.monsterid != MON_MAGE)
 205                                                                 trace_ent.skin = stof(argv(2));
 206                                                         return;
 207                                                 }
 208                                                 case "movetarget":
 209                                                 {
 210                                                         trace_ent.monster_moveflags = stof(argv(2));
 211                                                         return;
 212                                                 }
 213                                         }
 214                                 }
 215                         }
 216                 }
 217                 default:
 218                         sprint(self, "Incorrect parameters for ^2mobedit^7\n");
 219                 case CMD_REQUEST_USAGE:
 220                 {
 221                         sprint(self, "\nUsage:^3 cmd mobedit [argument]\n");
 222                         sprint(self, "  Where 'argument' can be skin or movetarget.\n");
 223                         sprint(self, "  Aim at your monster to edit its properties.\n");
 224                         return;
 225                 }
 226         }
 227 }
 228
 229 void ClientCommand_mobkill(float request)
 230 {
 231         switch(request)
 232         {
 233                 case CMD_REQUEST_COMMAND:
 234                 {
 235                         makevectors(self.v_angle);
 236                         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
 237
 238                         if(trace_ent.flags & FL_MONSTER)
 239                         {
 240                                 if(trace_ent.realowner != self)
 241                                 {
 242                                         sprint(self, "That monster does not belong to you.\n");
 243                                         return;
 244                                 }
 245                                 sprint(self, strcat("Your pet '", trace_ent.monster_name, "' has been brutally mutilated.\n"));
 246                                 Damage (trace_ent, world, world, trace_ent.health + trace_ent.max_health + 200, DEATH_KILL, trace_ent.origin, '0 0 0');
 247                                 return;
 248                         }
 249                 }
 250
 251                 default:
 252                         sprint(self, "Incorrect parameters for ^2mobkill^7\n");
 253                 case CMD_REQUEST_USAGE:
 254                 {
 255                         sprint(self, "\nUsage:^3 cmd mobkill\n");
 256                         sprint(self, "  Aim at your monster to kill it.\n");
 257                         return;
 258                 }
 259         }
 260 }
 261
 262 void ClientCommand_mobspawn(float request, float argc)
 263 {
 264         switch(request)
 265         {
 266                 case CMD_REQUEST_COMMAND:
 267                 {
 268                         entity e;
 269                         string tospawn;
 270                         float moveflag;
 271
 272                         moveflag = (argv(2) ? stof(argv(2)) : 1); // follow owner if not defined
 273                         tospawn = strtolower(argv(1));
 274
 275                         if(tospawn == "list")
 276                         {
 277                                 sprint(self, monsterlist_reply);
 278                                 return;
 279                         }
 280
 281                         if(autocvar_g_monsters_max <= 0 || autocvar_g_monsters_max_perplayer <= 0) { sprint(self, "Monster spawning is disabled.\n"); return; }
 282                         else if(!IS_PLAYER(self)) { sprint(self, "You can't spawn monsters while spectating.\n"); return; }
 283                         else if(MUTATOR_CALLHOOK(AllowMobSpawning)) { sprint(self, "Monster spawning is currently disabled by a mutator.\n"); return; }
 284                         else if(!autocvar_g_monsters) { Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_MONSTERS_DISABLED); return; }
 285                         else if(self.vehicle) { sprint(self, "You can't spawn monsters while driving a vehicle.\n"); return; }
 286                         else if(autocvar_g_campaign) { sprint(self, "You can't spawn monsters in campaign mode.\n"); return; }
 287                         else if(self.deadflag != DEAD_NO) { sprint(self, "You can't spawn monsters while dead.\n"); return; }
 288                         else if(self.monstercount >= autocvar_g_monsters_max_perplayer) { sprint(self, "You have spawned too many monsters, kill some before trying to spawn any more.\n"); return; }
 289                         else if(totalspawned >= autocvar_g_monsters_max) { sprint(self, "The global maximum monster count has been reached, kill some before trying to spawn any more.\n"); return; }
 290                         else if(tospawn != "")
 291                         {
 292                                 float found = 0, i;
 293                                 entity mon;
 294
 295                                 for(i = MON_FIRST; i <= MON_LAST; ++i)
 296                                 {
 297                                         mon = get_monsterinfo(i);
 298                                         if(mon.netname == tospawn)
 299                                         {
 300                                                 found = TRUE;
 301                                                 break;
 302                                         }
 303                                 }
 304
 305                                 if(found)
 306                                 {
 307                                         self.monstercount += 1;
 308                                         totalspawned += 1;
 309
 310                                         makevectors(self.v_angle);
 311                                         WarpZone_TraceBox (CENTER_OR_VIEWOFS(self), PL_MIN, PL_MAX, CENTER_OR_VIEWOFS(self) + v_forward * 150, TRUE, self);
 312                                         //WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 150, MOVE_NORMAL, self);
 313
 314                                         e = spawnmonster(tospawn, 0, self, self, trace_endpos, FALSE, moveflag);
 315
 316                                         sprint(self, strcat("Spawned ", e.monster_name, "\n"));
 317
 318                                         return;
 319                                 }
 320                         }
 321                 }
 322
 323                 default:
 324                         sprint(self, "Incorrect parameters for ^2mobspawn^7\n");
 325                 case CMD_REQUEST_USAGE:
 326                 {
 327                         sprint(self, "\nUsage:^3 cmd mobspawn <random> <monster> [movetype]\n");
 328                         sprint(self, "  See 'cmd mobspawn list' for available monsters.\n");
 329                         sprint(self, "  Argument 'random' spawns a random monster.\n");
 330                         sprint(self, "  Monster will follow the owner if second argument is not defined.\n");
 331                         return;
 332                 }
 333         }
 334 }
 335
 336 void ClientCommand_ready(float request) // todo: anti-spam for toggling readyness
 337 {
 338         switch(request)
 339         {
 340                 case CMD_REQUEST_COMMAND:
 341                 {
 342                         if(IS_CLIENT(self))
 343                         {
 344                                 if(warmup_stage || autocvar_sv_ready_restart || g_race_qualifying == 2)
 345                                 {
 346                                         if(!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
 347                                         {
 348                                                 if(time < game_starttime) // game is already restarting
 349                                                         return;
 350                                                 if (self.ready) // toggle
 351                                                 {
 352                                                         self.ready = FALSE;
 353                                                         bprint(self.netname, "^2 is ^1NOT^2 ready\n");
 354                                                 }
 355                                                 else
 356                                                 {
 357                                                         self.ready = TRUE;
 358                                                         bprint(self.netname, "^2 is ready\n");
 359                                                 }
 360
 361                                                 // cannot reset the game while a timeout is active!
 362                                                 if (!timeout_status)
 363                                                         ReadyCount();
 364                                         } else {
 365                                                 sprint(self, "^1Game has already been restarted\n");
 366                                         }
 367                                 }
 368                         }
 369                         return; // never fall through to usage
 370                 }
 371
 372                 default:
 373                 case CMD_REQUEST_USAGE:
 374                 {
 375                         sprint(self, "\nUsage:^3 cmd ready\n");
 376                         sprint(self, "  No arguments required.\n");
 377                         return;
 378                 }
 379         }
 380 }
 381
 382 void ClientCommand_say(float request, float argc, string command)
 383 {
 384         switch(request)
 385         {
 386                 case CMD_REQUEST_COMMAND:
 387                 {
 388                         if(argc >= 2) { Say(self, FALSE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 389                         return; // never fall through to usage
 390                 }
 391
 392                 default:
 393                 case CMD_REQUEST_USAGE:
 394                 {
 395                         sprint(self, "\nUsage:^3 cmd say <message>\n");
 396                         sprint(self, "  Where 'message' is the string of text to say.\n");
 397                         return;
 398                 }
 399         }
 400 }
 401
 402 void ClientCommand_say_team(float request, float argc, string command)
 403 {
 404         switch(request)
 405         {
 406                 case CMD_REQUEST_COMMAND:
 407                 {
 408                         if(argc >= 2) { Say(self, TRUE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 409                         return; // never fall through to usage
 410                 }
 411
 412                 default:
 413                 case CMD_REQUEST_USAGE:
 414                 {
 415                         sprint(self, "\nUsage:^3 cmd say_team <message>\n");
 416                         sprint(self, "  Where 'message' is the string of text to say.\n");
 417                         return;
 418                 }
 419         }
 420 }
 421
 422 void ClientCommand_selectteam(float request, float argc)
 423 {
 424         switch(request)
 425         {
 426                 case CMD_REQUEST_COMMAND:
 427                 {
 428                         if(argv(1) != "")
 429                         {
 430                                 if(IS_CLIENT(self))
 431                                 {
 432                                         if(teamplay)
 433                                                 if(self.team_forced <= 0)
 434                                                         if (!lockteams)
 435                                                         {
 436                                                                 float selection;
 437
 438                                                                 switch(argv(1))
 439                                                                 {
 440                                                                         case "red": selection = NUM_TEAM_1; break;
 441                                                                         case "blue": selection = NUM_TEAM_2; break;
 442                                                                         case "yellow": selection = NUM_TEAM_3; break;
 443                                                                         case "pink": selection = NUM_TEAM_4; break;
 444                                                                         case "auto": selection = (-1); break;
 445
 446                                                                         default: selection = 0; break;
 447                                                                 }
 448
 449                                                                 if(selection)
 450                                                                 {
 451                                                                         if(self.team == selection && self.deadflag == DEAD_NO)
 452                                                                                 sprint(self, "^7You already are on that team.\n");
 453                                                                         else if(self.wasplayer && autocvar_g_changeteam_banned)
 454                                                                                 sprint(self, "^1You cannot change team, forbidden by the server.\n");
 455                                                                         else
 456                                                                                 ClientKill_TeamChange(selection);
 457                                                                 }
 458                                                         }
 459                                                         else
 460                                                                 sprint(self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 461                                                 else
 462                                                         sprint(self, "^7selectteam can not be used as your team is forced\n");
 463                                         else
 464                                                 sprint(self, "^7selectteam can only be used in teamgames\n");
 465                                 }
 466                                 return;
 467                         }
 468                 }
 469
 470                 default:
 471                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 472                 case CMD_REQUEST_USAGE:
 473                 {
 474                         sprint(self, "\nUsage:^3 cmd selectteam team\n");
 475                         sprint(self, "  Where 'team' is the prefered team to try and join.\n");
 476                         sprint(self, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 477                         return;
 478                 }
 479         }
 480 }
 481
 482 void ClientCommand_selfstuff(float request, string command)
 483 {
 484         switch(request)
 485         {
 486                 case CMD_REQUEST_COMMAND:
 487                 {
 488                         if(argv(1) != "")
 489                         {
 490                                 stuffcmd(self, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 491                                 return;
 492                         }
 493                 }
 494
 495                 default:
 496                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 497                 case CMD_REQUEST_USAGE:
 498                 {
 499                         sprint(self, "\nUsage:^3 cmd selfstuff <command>\n");
 500                         sprint(self, "  Where 'command' is the string to be stuffed to your client.\n");
 501                         return;
 502                 }
 503         }
 504 }
 505
 506 void ClientCommand_sentcvar(float request, float argc, string command)
 507 {
 508         switch(request)
 509         {
 510                 case CMD_REQUEST_COMMAND:
 511                 {
 512                         if(argv(1) != "")
 513                         {
 514                                 //float tokens;
 515                                 string s;
 516
 517                                 if(argc == 2) // undefined cvar: use the default value on the server then
 518                                 {
 519                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 520                                         tokenize_console(s);
 521                                 }
 522
 523                                 GetCvars(1);
 524
 525                                 return;
 526                         }
 527                 }
 528
 529                 default:
 530                         sprint(self, "Incorrect parameters for ^2sentcvar^7\n");
 531                 case CMD_REQUEST_USAGE:
 532                 {
 533                         sprint(self, "\nUsage:^3 cmd sentcvar <cvar>\n");
 534                         sprint(self, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 535                         return;
 536                 }
 537         }
 538 }
 539
 540 void ClientCommand_spectate(float request)
 541 {
 542         switch(request)
 543         {
 544                 case CMD_REQUEST_COMMAND:
 545                 {
 546                         if(IS_CLIENT(self))
 547                         {
 548                                 if(g_lms)
 549                                 {
 550                                         if(self.lms_spectate_warning)
 551                                         {
 552                                                 // for the forfeit message...
 553                                                 self.lms_spectate_warning = 2;
 554                                                 // mark player as spectator
 555                                                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 556                                         }
 557                                         else
 558                                         {
 559                                                 self.lms_spectate_warning = 1;
 560                                                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 561                                                 return;
 562                                         }
 563                                 }
 564
 565                                 if(IS_PLAYER(self) && autocvar_sv_spectate == 1)
 566                                         ClientKill_TeamChange(-2); // observe
 567
 568                                 // in CA, allow a dead player to move to spectators (without that, caplayer!=0 will be moved back to the player list)
 569                                 // note: if arena game mode is ever done properly, this needs to be removed.
 570                                 if(self.caplayer && (IS_SPEC(self) || IS_OBSERVER(self)))
 571                                 {
 572                                         sprint(self, "WARNING: you will spectate in the next round.\n");
 573                                         self.caplayer = 0;
 574                                 }
 575                         }
 576                         return; // never fall through to usage
 577                 }
 578
 579                 default:
 580                 case CMD_REQUEST_USAGE:
 581                 {
 582                         sprint(self, "\nUsage:^3 cmd spectate\n");
 583                         sprint(self, "  No arguments required.\n");
 584                         return;
 585                 }
 586         }
 587 }
 588
 589 void ClientCommand_suggestmap(float request, float argc)
 590 {
 591         switch(request)
 592         {
 593                 case CMD_REQUEST_COMMAND:
 594                 {
 595                         if(argv(1) != "")
 596                         {
 597                                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 598                                 return;
 599                         }
 600                 }
 601
 602                 default:
 603                         sprint(self, "Incorrect parameters for ^2suggestmap^7\n");
 604                 case CMD_REQUEST_USAGE:
 605                 {
 606                         sprint(self, "\nUsage:^3 cmd suggestmap map\n");
 607                         sprint(self, "  Where 'map' is the name of the map to suggest.\n");
 608                         return;
 609                 }
 610         }
 611 }
 612
 613 void ClientCommand_tell(float request, float argc, string command)
 614 {
 615         switch(request)
 616         {
 617                 case CMD_REQUEST_COMMAND:
 618                 {
 619                         if(argc >= 3)
 620                         {
 621                                 entity tell_to = GetIndexedEntity(argc, 1);
 622                                 float tell_accepted = VerifyClientEntity(tell_to, TRUE, FALSE);
 623
 624                                 if(tell_accepted > 0) // the target is a real client
 625                                 {
 626                                         if(tell_to != self) // and we're allowed to send to them :D
 627                                         {
 628                                                 Say(self, FALSE, tell_to, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)), TRUE);
 629                                                 return;
 630                                         }
 631                                         else { print_to(self, "You can't ^2tell^7 a message to yourself."); return; }
 632                                 }
 633                                 else if(argv(1) == "#0")
 634                                 {
 635                                         trigger_magicear_processmessage_forallears(self, -1, world, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 636                                         return;
 637                                 }
 638                                 else { print_to(self, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 639                         }
 640                 }
 641
 642                 default:
 643                         sprint(self, "Incorrect parameters for ^2tell^7\n");
 644                 case CMD_REQUEST_USAGE:
 645                 {
 646                         sprint(self, "\nUsage:^3 cmd tell client <message>\n");
 647                         sprint(self, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 648                         return;
 649                 }
 650         }
 651 }
 652
 653 void ClientCommand_voice(float request, float argc, string command)
 654 {
 655         switch(request)
 656         {
 657                 case CMD_REQUEST_COMMAND:
 658                 {
 659                         if(argv(1) != "")
 660                         {
 661                                 if(argc >= 3)
 662                                         VoiceMessage(argv(1), substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 663                                 else
 664                                         VoiceMessage(argv(1), "");
 665
 666                                 return;
 667                         }
 668                 }
 669
 670                 default:
 671                         sprint(self, "Incorrect parameters for ^2voice^7\n");
 672                 case CMD_REQUEST_USAGE:
 673                 {
 674                         sprint(self, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 675                         sprint(self, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 676                         sprint(self, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 677                         return;
 678                 }
 679         }
 680 }
 681
 682 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 683 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 684 void ClientCommand_(float request)
 685 {
 686         switch(request)
 687         {
 688                 case CMD_REQUEST_COMMAND:
 689                 {
 690
 691                         return; // never fall through to usage
 692                 }
 693
 694                 default:
 695                 case CMD_REQUEST_USAGE:
 696                 {
 697                         sprint(self, "\nUsage:^3 cmd \n");
 698                         sprint(self, "  No arguments required.\n");
 699                         return;
 700                 }
 701         }
 702 }
 703 */
 704
 705
 706 // =====================================
 707 //  Macro system for networked commands
 708 // =====================================
 709
 710 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 711 #define CLIENT_COMMANDS(request,arguments,command) \
 712         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 713         CLIENT_COMMAND("checkfail", ClientCommand_checkfail(request, command), "Report if a client-side check failed") \
 714         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(request, arguments), "Release version of the game") \
 715         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(request, arguments), "Retrieve mapshot picture from the server") \
 716         CLIENT_COMMAND("join", ClientCommand_join(request), "Become a player in the game") \
 717         CLIENT_COMMAND("mobedit", ClientCommand_mobedit(request, arguments), "Edit your monster's properties") \
 718         CLIENT_COMMAND("mobkill", ClientCommand_mobkill(request), "Kills your monster") \
 719         CLIENT_COMMAND("mobspawn", ClientCommand_mobspawn(request, arguments), "Spawn monsters infront of yourself") \
 720         CLIENT_COMMAND("ready", ClientCommand_ready(request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 721         CLIENT_COMMAND("say", ClientCommand_say(request, arguments, command), "Print a message to chat to all players") \
 722         CLIENT_COMMAND("say_team", ClientCommand_say_team(request, arguments, command), "Print a message to chat to all team mates") \
 723         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(request, arguments), "Attempt to choose a team to join into") \
 724         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(request, command), "Stuffcmd a command to your own client") \
 725         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(request, arguments, command), "New system for sending a client cvar to the server") \
 726         CLIENT_COMMAND("spectate", ClientCommand_spectate(request), "Become an observer") \
 727         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(request, arguments), "Suggest a map to the mapvote at match end") \
 728         CLIENT_COMMAND("tell", ClientCommand_tell(request, arguments, command), "Send a message directly to a player") \
 729         CLIENT_COMMAND("voice", ClientCommand_voice(request, arguments, command), "Send voice message via sound") \
 730         /* nothing */
 731
 732 void ClientCommand_macro_help()
 733 {
 734         #define CLIENT_COMMAND(name,function,description) \
 735                 { sprint(self, "  ^2", name, "^7: ", description, "\n"); }
 736
 737         CLIENT_COMMANDS(0, 0, "")
 738         #undef CLIENT_COMMAND
 739
 740         return;
 741 }
 742
 743 float ClientCommand_macro_command(float argc, string command)
 744 {
 745         #define CLIENT_COMMAND(name,function,description) \
 746                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
 747
 748         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
 749         #undef CLIENT_COMMAND
 750
 751         return FALSE;
 752 }
 753
 754 float ClientCommand_macro_usage(float argc)
 755 {
 756         #define CLIENT_COMMAND(name,function,description) \
 757                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
 758
 759         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc, "")
 760         #undef CLIENT_COMMAND
 761
 762         return FALSE;
 763 }
 764
 765 void ClientCommand_macro_write_aliases(float fh)
 766 {
 767         #define CLIENT_COMMAND(name,function,description) \
 768                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 769
 770         CLIENT_COMMANDS(0, 0, "")
 771         #undef CLIENT_COMMAND
 772
 773         return;
 774 }
 775
 776 // ======================================
 777 //  Main Function Called By Engine (cmd)
 778 // ======================================
 779 // If this function exists, server game code parses clientcommand before the engine code gets it.
 780
 781 void SV_ParseClientCommand(string command)
 782 {
 783         // if we're banned, don't even parse the command
 784         if(Ban_MaybeEnforceBanOnce(self))
 785                 return;
 786
 787         float argc = tokenize_console(command);
 788
 789         // for the mutator hook system
 790         cmd_name = strtolower(argv(0));
 791         cmd_argc = argc;
 792         cmd_string = command;
 793
 794         // Guide for working with argc arguments by example:
 795         // argc:   1    - 2      - 3     - 4
 796         // argv:   0    - 1      - 2     - 3
 797         // cmd     vote - master - login - password
 798
 799         // for floodcheck
 800         switch(strtolower(argv(0)))
 801         {
 802                 // exempt commands which are not subject to floodcheck
 803                 case "begin": break; // handled by engine in host_cmd.c
 804                 case "download": break; // handled by engine in cl_parse.c
 805                 case "mv_getpicture": break; // handled by server in this file
 806                 case "pause": break; // handled by engine in host_cmd.c
 807                 case "prespawn": break; // handled by engine in host_cmd.c
 808                 case "sentcvar": break; // handled by server in this file
 809                 case "spawn": break; // handled by engine in host_cmd.c
 810
 811                 default:
 812                         if(SV_ParseClientCommand_floodcheck())
 813                                 break; // "TRUE": continue, as we're not flooding yet
 814                         else
 815                                 return; // "FALSE": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 816         }
 817
 818         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 819         if(argv(0) == "help")
 820         {
 821                 if(argc == 1)
 822                 {
 823                         sprint(self, "\nClient networked commands:\n");
 824                         ClientCommand_macro_help();
 825
 826                         sprint(self, "\nCommon networked commands:\n");
 827                         CommonCommand_macro_help(self);
 828
 829                         sprint(self, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 830                         sprint(self, "For help about a specific command, type cmd help COMMAND\n");
 831                         return;
 832                 }
 833                 else if(CommonCommand_macro_usage(argc, self)) // Instead of trying to call a command, we're going to see detailed information about it
 834                 {
 835                         return;
 836                 }
 837                 else if(ClientCommand_macro_usage(argc)) // same, but for normal commands now
 838                 {
 839                         return;
 840                 }
 841         }
 842         else if(MUTATOR_CALLHOOK(SV_ParseClientCommand))
 843         {
 844                 return; // handled by a mutator
 845         }
 846         else if(CheatCommand(argc))
 847         {
 848                 return; // handled by server/cheats.qc
 849         }
 850         else if(CommonCommand_macro_command(argc, self, command))
 851         {
 852                 return; // handled by server/command/common.qc
 853         }
 854         else if(ClientCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
 855         {
 856                 return; // handled by one of the above ClientCommand_* functions
 857         }
 858         else
 859                 clientcommand(self, command);
 860 }