qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "impulse.qh"
   5 #include "player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21 #include "scores_rules.qh"
  22
  23 #include "bot/api.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include "../common/wepent.qh"
  27 #include <common/state.qh>
  28
  29 #include <common/effects/qc/globalsound.qh>
  30
  31 #include "../common/triggers/func/conveyor.qh"
  32 #include "../common/triggers/teleporters.qh"
  33
  34 #include "../common/vehicles/all.qh"
  35
  36 #include "weapons/hitplot.qh"
  37 #include "weapons/weaponsystem.qh"
  38
  39 #include "../common/net_notice.qh"
  40 #include "../common/net_linked.qh"
  41 #include "../common/physics/player.qh"
  42
  43 #include "../common/items/_mod.qh"
  44
  45 #include "../common/mutators/mutator/waypoints/all.qh"
  46
  47 #include "../common/triggers/subs.qh"
  48 #include "../common/triggers/triggers.qh"
  49 #include "../common/triggers/trigger/secret.qh"
  50
  51 #include "../common/minigames/sv_minigames.qh"
  52
  53 #include "../common/items/inventory.qh"
  54
  55 #include "../common/monsters/sv_monsters.qh"
  56
  57 #include "../lib/warpzone/server.qh"
  58
  59 STATIC_METHOD(Client, Add, void(Client this, int _team))
  60 {
  61     ClientConnect(this);
  62     TRANSMUTE(Player, this);
  63     this.frame = 12; // 7
  64     this.team = _team;
  65     PutClientInServer(this);
  66 }
  67
  68 void PutObserverInServer(entity this);
  69
  70 STATIC_METHOD(Client, Remove, void(Client this))
  71 {
  72     TRANSMUTE(Observer, this);
  73     PutClientInServer(this);
  74     ClientDisconnect(this);
  75 }
  76
  77 void send_CSQC_teamnagger() {
  78         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  79 }
  80
  81 int CountSpectators(entity player, entity to)
  82 {
  83         if(!player) { return 0; } // not sure how, but best to be safe
  84
  85         int spec_count = 0;
  86
  87         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  88         {
  89                 spec_count++;
  90         });
  91
  92         return spec_count;
  93 }
  94
  95 void WriteSpectators(entity player, entity to)
  96 {
  97         if(!player) { return; } // not sure how, but best to be safe
  98
  99         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 100         {
 101                 WriteByte(MSG_ENTITY, num_for_edict(it));
 102         });
 103 }
 104
 105 bool ClientData_Send(entity this, entity to, int sf)
 106 {
 107         assert(to == this.owner, return false);
 108
 109         entity e = to;
 110         if (IS_SPEC(e)) e = e.enemy;
 111
 112         sf = 0;
 113         if (e.race_completed)       sf |= 1; // forced scoreboard
 114         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
 115         if (e.zoomstate)            sf |= 4; // zoomed
 116         if (autocvar_sv_showspectators) sf |= 16; // show spectators
 117
 118         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 119         WriteByte(MSG_ENTITY, sf);
 120
 121         if (sf & 2)
 122         {
 123                 WriteByte(MSG_ENTITY, to.spectatee_status);
 124         }
 125
 126         if(sf & 16)
 127         {
 128                 float specs = CountSpectators(e, to);
 129                 WriteByte(MSG_ENTITY, specs);
 130                 WriteSpectators(e, to);
 131         }
 132
 133         return true;
 134 }
 135
 136 void ClientData_Attach(entity this)
 137 {
 138         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 139         this.clientdata.drawonlytoclient = this;
 140         this.clientdata.owner = this;
 141 }
 142
 143 void ClientData_Detach(entity this)
 144 {
 145         delete(this.clientdata);
 146         this.clientdata = NULL;
 147 }
 148
 149 void ClientData_Touch(entity e)
 150 {
 151         e.clientdata.SendFlags = 1;
 152
 153         // make it spectatable
 154         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
 155 }
 156
 157 .string netname_previous;
 158
 159 void SetSpectatee(entity this, entity spectatee);
 160 void SetSpectatee_status(entity this, int spectatee_num);
 161
 162
 163 /*
 164 =============
 165 CheckPlayerModel
 166
 167 Checks if the argument string can be a valid playermodel.
 168 Returns a valid one in doubt.
 169 =============
 170 */
 171 string FallbackPlayerModel;
 172 string CheckPlayerModel(string plyermodel) {
 173         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 174         {
 175                 // note: we cannot summon Don Strunzone here, some player may
 176                 // still have the model string set. In case anyone manages how
 177                 // to change a cvar default, we'll have a small leak here.
 178                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 179         }
 180         // only in right path
 181         if( substring(plyermodel,0,14) != "models/player/")
 182                 return FallbackPlayerModel;
 183         // only good file extensions
 184         if(substring(plyermodel,-4,4) != ".zym")
 185         if(substring(plyermodel,-4,4) != ".dpm")
 186         if(substring(plyermodel,-4,4) != ".iqm")
 187         if(substring(plyermodel,-4,4) != ".md3")
 188         if(substring(plyermodel,-4,4) != ".psk")
 189                 return FallbackPlayerModel;
 190         // forbid the LOD models
 191         if(substring(plyermodel, -9,5) == "_lod1")
 192                 return FallbackPlayerModel;
 193         if(substring(plyermodel, -9,5) == "_lod2")
 194                 return FallbackPlayerModel;
 195         if(plyermodel != strtolower(plyermodel))
 196                 return FallbackPlayerModel;
 197         // also, restrict to server models
 198         if(autocvar_sv_servermodelsonly)
 199         {
 200                 if(!fexists(plyermodel))
 201                         return FallbackPlayerModel;
 202         }
 203         return plyermodel;
 204 }
 205
 206 void setplayermodel(entity e, string modelname)
 207 {
 208         precache_model(modelname);
 209         _setmodel(e, modelname);
 210         player_setupanimsformodel(e);
 211         if(!autocvar_g_debug_globalsounds)
 212                 UpdatePlayerSounds(e);
 213 }
 214
 215 void FixPlayermodel(entity player);
 216 /** putting a client as observer in the server */
 217 void PutObserverInServer(entity this)
 218 {
 219     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 220         PlayerState_detach(this);
 221
 222         if (IS_PLAYER(this) && this.health >= 1) {
 223         // despawn effect
 224                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 225     }
 226
 227     {
 228         entity spot = SelectSpawnPoint(this, true);
 229         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 230         this.angles = spot.angles;
 231         this.angles_z = 0;
 232         this.fixangle = true;
 233         // offset it so that the spectator spawns higher off the ground, looks better this way
 234         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 235         this.prevorigin = this.origin;
 236         if (IS_REAL_CLIENT(this))
 237         {
 238             msg_entity = this;
 239             WriteByte(MSG_ONE, SVC_SETVIEW);
 240             WriteEntity(MSG_ONE, this);
 241         }
 242         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 243         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 244         if(!autocvar_g_debug_globalsounds)
 245         {
 246                 // needed for player sounds
 247                 this.model = "";
 248                 FixPlayermodel(this);
 249         }
 250         setmodel(this, MDL_Null);
 251         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 252         this.view_ofs = '0 0 0';
 253     }
 254
 255     RemoveGrapplingHooks(this);
 256         Portal_ClearAll(this);
 257         Unfreeze(this);
 258         SetSpectatee(this, NULL);
 259
 260         if (this.alivetime)
 261         {
 262                 if (!warmup_stage)
 263                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 264                 this.alivetime = 0;
 265         }
 266
 267         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 268
 269         WaypointSprite_PlayerDead(this);
 270
 271         if (mutator_returnvalue) {
 272             // mutator prevents resetting teams+score
 273         } else {
 274                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 275         this.frags = FRAGS_SPECTATOR;
 276         PlayerScore_Clear(this);  // clear scores when needed
 277     }
 278
 279         if (this.killcount != FRAGS_SPECTATOR)
 280         {
 281                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 282                 if(!gameover)
 283                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 284                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 285
 286                 if(this.just_joined == false) {
 287                         LogTeamchange(this.playerid, -1, 4);
 288                 } else
 289                         this.just_joined = false;
 290         }
 291
 292         accuracy_resend(this);
 293
 294         this.spectatortime = time;
 295         if(this.bot_attack)
 296                 IL_REMOVE(g_bot_targets, this);
 297         this.bot_attack = false;
 298     this.hud = HUD_NORMAL;
 299         TRANSMUTE(Observer, this);
 300         this.iscreature = false;
 301         this.teleportable = TELEPORT_SIMPLE;
 302         if(this.damagedbycontents)
 303                 IL_REMOVE(g_damagedbycontents, this);
 304         this.damagedbycontents = false;
 305         this.health = FRAGS_SPECTATOR;
 306         SetSpectatee_status(this, etof(this));
 307         this.takedamage = DAMAGE_NO;
 308         this.solid = SOLID_NOT;
 309         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 310         this.flags = FL_CLIENT | FL_NOTARGET;
 311         this.armorvalue = 666;
 312         this.effects = 0;
 313         this.armorvalue = autocvar_g_balance_armor_start;
 314         this.pauserotarmor_finished = 0;
 315         this.pauserothealth_finished = 0;
 316         this.pauseregen_finished = 0;
 317         this.damageforcescale = 0;
 318         this.death_time = 0;
 319         this.respawn_flags = 0;
 320         this.respawn_time = 0;
 321         this.stat_respawn_time = 0;
 322         this.alpha = 0;
 323         this.scale = 0;
 324         this.fade_time = 0;
 325         this.pain_frame = 0;
 326         this.pain_finished = 0;
 327         this.strength_finished = 0;
 328         this.invincible_finished = 0;
 329         this.superweapons_finished = 0;
 330         this.pushltime = 0;
 331         this.istypefrag = 0;
 332         setthink(this, func_null);
 333         this.nextthink = 0;
 334         this.deadflag = DEAD_NO;
 335         this.crouch = false;
 336         this.revive_progress = 0;
 337         this.revival_time = 0;
 338
 339         this.items = 0;
 340         this.weapons = '0 0 0';
 341         this.drawonlytoclient = this;
 342
 343         this.weaponmodel = "";
 344         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 345         {
 346                 this.weaponentities[slot] = NULL;
 347         }
 348         this.exteriorweaponentity = NULL;
 349         this.killcount = FRAGS_SPECTATOR;
 350         this.velocity = '0 0 0';
 351         this.avelocity = '0 0 0';
 352         this.punchangle = '0 0 0';
 353         this.punchvector = '0 0 0';
 354         this.oldvelocity = this.velocity;
 355         this.fire_endtime = -1;
 356         this.event_damage = func_null;
 357 }
 358
 359 int player_getspecies(entity this)
 360 {
 361         get_model_parameters(this.model, this.skin);
 362         int s = get_model_parameters_species;
 363         get_model_parameters(string_null, 0);
 364         if (s < 0) return SPECIES_HUMAN;
 365         return s;
 366 }
 367
 368 .float model_randomizer;
 369 void FixPlayermodel(entity player)
 370 {
 371         string defaultmodel = "";
 372         int defaultskin = 0;
 373         if(autocvar_sv_defaultcharacter)
 374         {
 375                 if(teamplay)
 376                 {
 377                         string s = Static_Team_ColorName_Lower(player.team);
 378                         if (s != "neutral")
 379                         {
 380                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 381                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 382                         }
 383                 }
 384
 385                 if(defaultmodel == "")
 386                 {
 387                         defaultmodel = autocvar_sv_defaultplayermodel;
 388                         defaultskin = autocvar_sv_defaultplayerskin;
 389                 }
 390
 391                 int n = tokenize_console(defaultmodel);
 392                 if(n > 0)
 393                 {
 394                         defaultmodel = argv(floor(n * player.model_randomizer));
 395                         // However, do NOT randomize if the player-selected model is in the list.
 396                         for (int i = 0; i < n; ++i)
 397                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 398                                         defaultmodel = argv(i);
 399                 }
 400
 401                 int i = strstrofs(defaultmodel, ":", 0);
 402                 if(i >= 0)
 403                 {
 404                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 405                         defaultmodel = substring(defaultmodel, 0, i);
 406                 }
 407         }
 408         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 409         {
 410                 if(teamplay)
 411                 {
 412                         string s = Static_Team_ColorName_Lower(player.team);
 413                         if (s != "neutral")
 414                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 415                 }
 416
 417                 if(!defaultskin)
 418                         defaultskin = autocvar_sv_defaultplayerskin;
 419         }
 420
 421         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 422         defaultmodel = M_ARGV(0, string);
 423         defaultskin = M_ARGV(1, int);
 424
 425         bool chmdl = false;
 426         int oldskin;
 427         if(defaultmodel != "")
 428         {
 429                 if (defaultmodel != player.model)
 430                 {
 431                         vector m1 = player.mins;
 432                         vector m2 = player.maxs;
 433                         setplayermodel (player, defaultmodel);
 434                         setsize (player, m1, m2);
 435                         chmdl = true;
 436                 }
 437
 438                 oldskin = player.skin;
 439                 player.skin = defaultskin;
 440         } else {
 441                 if (player.playermodel != player.model || player.playermodel == "")
 442                 {
 443                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 444                         vector m1 = player.mins;
 445                         vector m2 = player.maxs;
 446                         setplayermodel (player, player.playermodel);
 447                         setsize (player, m1, m2);
 448                         chmdl = true;
 449                 }
 450
 451                 if(!autocvar_sv_defaultcharacterskin)
 452                 {
 453                         oldskin = player.skin;
 454                         player.skin = stof(player.playerskin);
 455                 }
 456                 else
 457                 {
 458                         oldskin = player.skin;
 459                         player.skin = defaultskin;
 460                 }
 461         }
 462
 463         if(chmdl || oldskin != player.skin) // model or skin has changed
 464         {
 465                 player.species = player_getspecies(player); // update species
 466                 if(!autocvar_g_debug_globalsounds)
 467                         UpdatePlayerSounds(player); // update skin sounds
 468         }
 469
 470         if(!teamplay)
 471                 if(strlen(autocvar_sv_defaultplayercolors))
 472                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 473                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 474 }
 475
 476
 477 /** Called when a client spawns in the server */
 478 void PutClientInServer(entity this)
 479 {
 480         if (IS_BOT_CLIENT(this)) {
 481                 TRANSMUTE(Player, this);
 482         } else if (IS_REAL_CLIENT(this)) {
 483                 msg_entity = this;
 484                 WriteByte(MSG_ONE, SVC_SETVIEW);
 485                 WriteEntity(MSG_ONE, this);
 486         }
 487         if (gameover) {
 488                 TRANSMUTE(Observer, this);
 489         }
 490
 491         SetSpectatee(this, NULL);
 492
 493         // reset player keys
 494         this.itemkeys = 0;
 495
 496         MUTATOR_CALLHOOK(PutClientInServer, this);
 497
 498         if (IS_OBSERVER(this)) {
 499                 PutObserverInServer(this);
 500         } else if (IS_PLAYER(this)) {
 501                 if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 502
 503                 PlayerState_attach(this);
 504                 accuracy_resend(this);
 505
 506                 if (this.team < 0)
 507                         JoinBestTeam(this, false, true);
 508
 509                 entity spot = SelectSpawnPoint(this, false);
 510                 if (!spot) {
 511                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 512                         return; // spawn failed
 513                 }
 514
 515                 TRANSMUTE(Player, this);
 516
 517                 this.wasplayer = true;
 518                 this.iscreature = true;
 519                 this.teleportable = TELEPORT_NORMAL;
 520                 if(!this.damagedbycontents)
 521                         IL_PUSH(g_damagedbycontents, this);
 522                 this.damagedbycontents = true;
 523                 set_movetype(this, MOVETYPE_WALK);
 524                 this.solid = SOLID_SLIDEBOX;
 525                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 526                 if (autocvar_g_playerclip_collisions)
 527                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 528                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 529                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 530                 this.frags = FRAGS_PLAYER;
 531                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 532                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 533                 if (autocvar__notarget)
 534                         this.flags |= FL_NOTARGET;
 535                 this.takedamage = DAMAGE_AIM;
 536                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 537                 this.dmg = 2; // WTF
 538
 539                 if (warmup_stage) {
 540                         this.ammo_shells = warmup_start_ammo_shells;
 541                         this.ammo_nails = warmup_start_ammo_nails;
 542                         this.ammo_rockets = warmup_start_ammo_rockets;
 543                         this.ammo_cells = warmup_start_ammo_cells;
 544                         this.ammo_plasma = warmup_start_ammo_plasma;
 545                         this.ammo_fuel = warmup_start_ammo_fuel;
 546                         this.health = warmup_start_health;
 547                         this.armorvalue = warmup_start_armorvalue;
 548                         this.weapons = WARMUP_START_WEAPONS;
 549                 } else {
 550                         this.ammo_shells = start_ammo_shells;
 551                         this.ammo_nails = start_ammo_nails;
 552                         this.ammo_rockets = start_ammo_rockets;
 553                         this.ammo_cells = start_ammo_cells;
 554                         this.ammo_plasma = start_ammo_plasma;
 555                         this.ammo_fuel = start_ammo_fuel;
 556                         this.health = start_health;
 557                         this.armorvalue = start_armorvalue;
 558                         this.weapons = start_weapons;
 559                 }
 560                 SetSpectatee_status(this, 0);
 561
 562                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 563
 564                 this.items = start_items;
 565
 566                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 567                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 568                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 569                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 570                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 571                 // extend the pause of rotting if client was reset at the beginning of the countdown
 572                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 573                         float f = game_starttime - time;
 574                         this.spawnshieldtime += f;
 575                         this.pauserotarmor_finished += f;
 576                         this.pauserothealth_finished += f;
 577                         this.pauseregen_finished += f;
 578                 }
 579                 this.damageforcescale = 2;
 580                 this.death_time = 0;
 581                 this.respawn_flags = 0;
 582                 this.respawn_time = 0;
 583                 this.stat_respawn_time = 0;
 584                 this.scale = autocvar_sv_player_scale;
 585                 this.fade_time = 0;
 586                 this.pain_frame = 0;
 587                 this.pain_finished = 0;
 588                 this.pushltime = 0;
 589                 setthink(this, func_null); // players have no think function
 590                 this.nextthink = 0;
 591                 this.dmg_team = 0;
 592                 this.ballistics_density = autocvar_g_ballistics_density_player;
 593
 594                 this.deadflag = DEAD_NO;
 595
 596                 this.angles = spot.angles;
 597                 this.angles_z = 0; // never spawn tilted even if the spot says to
 598                 if (IS_BOT_CLIENT(this))
 599                         this.v_angle = this.angles;
 600                 this.fixangle = true; // turn this way immediately
 601                 this.oldvelocity = this.velocity = '0 0 0';
 602                 this.avelocity = '0 0 0';
 603                 this.punchangle = '0 0 0';
 604                 this.punchvector = '0 0 0';
 605
 606                 this.strength_finished = 0;
 607                 this.invincible_finished = 0;
 608                 this.fire_endtime = -1;
 609                 this.revive_progress = 0;
 610                 this.revival_time = 0;
 611                 this.air_finished = time + 12;
 612
 613                 entity spawnevent = new_pure(spawnevent);
 614                 spawnevent.owner = this;
 615                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 616
 617                 // Cut off any still running player sounds.
 618                 stopsound(this, CH_PLAYER_SINGLE);
 619
 620                 this.model = "";
 621                 FixPlayermodel(this);
 622                 this.drawonlytoclient = NULL;
 623
 624                 this.viewloc = NULL;
 625
 626                 this.crouch = false;
 627                 this.view_ofs = STAT(PL_VIEW_OFS, this);
 628                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 629                 this.spawnorigin = spot.origin;
 630                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 631                 // don't reset back to last position, even if new position is stuck in solid
 632                 this.oldorigin = this.origin;
 633                 this.prevorigin = this.origin;
 634                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 635                 if(this.conveyor)
 636                         IL_REMOVE(g_conveyed, this);
 637                 this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 638                 this.hud = HUD_NORMAL;
 639
 640                 this.event_damage = PlayerDamage;
 641
 642                 if(!this.bot_attack)
 643                         IL_PUSH(g_bot_targets, this);
 644                 this.bot_attack = true;
 645                 this.monster_attack = true;
 646
 647                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 648
 649                 if (this.killcount == FRAGS_SPECTATOR) {
 650                         PlayerScore_Clear(this);
 651                         this.killcount = 0;
 652                 }
 653
 654                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 655                 {
 656                         .entity weaponentity = weaponentities[slot];
 657                         CL_SpawnWeaponentity(this, weaponentity);
 658                 }
 659                 this.alpha = default_player_alpha;
 660                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 661                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 662
 663                 this.speedrunning = false;
 664
 665                 target_voicescript_clear(this);
 666
 667                 // reset fields the weapons may use
 668                 FOREACH(Weapons, true, LAMBDA(
 669                         it.wr_resetplayer(it, this);
 670                         // reload all reloadable weapons
 671                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 672                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 673                                 {
 674                                         .entity weaponentity = weaponentities[slot];
 675                                         this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 676                                 }
 677                         }
 678                 ));
 679
 680                 {
 681                         string s = spot.target;
 682                         spot.target = string_null;
 683                         SUB_UseTargets(spot, this, NULL);
 684                         spot.target = s;
 685                 }
 686
 687                 Unfreeze(this);
 688
 689                 MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 690
 691                 if (autocvar_spawn_debug)
 692                 {
 693                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 694                         delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 695                 }
 696
 697                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 698                 {
 699                         .entity weaponentity = weaponentities[slot];
 700                         if(slot == 0)
 701                                 this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 702                         else
 703                                 this.(weaponentity).m_switchweapon = WEP_Null;
 704                         this.(weaponentity).m_weapon = WEP_Null;
 705                         this.(weaponentity).weaponname = "";
 706                         this.(weaponentity).m_switchingweapon = WEP_Null;
 707                         this.(weaponentity).cnt = -1;
 708                 }
 709
 710                 if (!warmup_stage && !this.alivetime)
 711                         this.alivetime = time;
 712
 713                 antilag_clear(this, CS(this));
 714         }
 715 }
 716
 717 void ClientInit_misc(entity this);
 718
 719 // TODO do we need all these fields, or should we stop autodetecting runtime
 720 // changes and just have a console command to update this?
 721 bool ClientInit_SendEntity(entity this, entity to, int sf)
 722 {
 723         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 724         return = true;
 725         msg_entity = to;
 726         // MSG_INIT replacement
 727         // TODO: make easier to use
 728         Registry_send_all();
 729         W_PROP_reload(MSG_ONE, to);
 730         ClientInit_misc(this);
 731         MUTATOR_CALLHOOK(Ent_Init);
 732 }
 733 void ClientInit_misc(entity this)
 734 {
 735         int channel = MSG_ONE;
 736         WriteHeader(channel, ENT_CLIENT_INIT);
 737         WriteByte(channel, g_nexball_meter_period * 32);
 738         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 739         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 740         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 741         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 742         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 743         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 744         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 745         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 746
 747         if(sv_foginterval && world.fog != "")
 748                 WriteString(channel, world.fog);
 749         else
 750                 WriteString(channel, "");
 751         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 752         WriteByte(channel, serverflags);
 753         WriteCoord(channel, autocvar_g_trueaim_minrange);
 754 }
 755
 756 void ClientInit_CheckUpdate(entity this)
 757 {
 758         this.nextthink = time;
 759         if(this.count != autocvar_g_balance_armor_blockpercent)
 760         {
 761                 this.count = autocvar_g_balance_armor_blockpercent;
 762                 this.SendFlags |= 1;
 763         }
 764 }
 765
 766 void ClientInit_Spawn()
 767 {
 768         entity e = new_pure(clientinit);
 769         setthink(e, ClientInit_CheckUpdate);
 770         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 771
 772         ClientInit_CheckUpdate(e);
 773 }
 774
 775 /*
 776 =============
 777 SetNewParms
 778 =============
 779 */
 780 void SetNewParms ()
 781 {
 782         // initialize parms for a new player
 783         parm1 = -(86400 * 366);
 784
 785         MUTATOR_CALLHOOK(SetNewParms);
 786 }
 787
 788 /*
 789 =============
 790 SetChangeParms
 791 =============
 792 */
 793 void SetChangeParms (entity this)
 794 {
 795         // save parms for level change
 796         parm1 = this.parm_idlesince - time;
 797
 798         MUTATOR_CALLHOOK(SetChangeParms);
 799 }
 800
 801 /*
 802 =============
 803 DecodeLevelParms
 804 =============
 805 */
 806 void DecodeLevelParms(entity this)
 807 {
 808         // load parms
 809         this.parm_idlesince = parm1;
 810         if (this.parm_idlesince == -(86400 * 366))
 811                 this.parm_idlesince = time;
 812
 813         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 814         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
 815
 816         MUTATOR_CALLHOOK(DecodeLevelParms);
 817 }
 818
 819 /*
 820 =============
 821 ClientKill
 822
 823 Called when a client types 'kill' in the console
 824 =============
 825 */
 826
 827 .float clientkill_nexttime;
 828 void ClientKill_Now_TeamChange(entity this)
 829 {
 830         if(this.killindicator_teamchange == -1)
 831         {
 832                 JoinBestTeam( this, false, true );
 833         }
 834         else if(this.killindicator_teamchange == -2)
 835         {
 836                 if(blockSpectators)
 837                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 838                 PutObserverInServer(this);
 839         }
 840         else
 841                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 842         this.killindicator_teamchange = 0;
 843 }
 844
 845 void ClientKill_Now(entity this)
 846 {
 847         if(this.vehicle)
 848         {
 849             vehicles_exit(this.vehicle, VHEF_RELEASE);
 850             if(!this.killindicator_teamchange)
 851             {
 852             this.vehicle_health = -1;
 853             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 854             }
 855         }
 856
 857         if(this.killindicator && !wasfreed(this.killindicator))
 858                 delete(this.killindicator);
 859
 860         this.killindicator = NULL;
 861
 862         if(this.killindicator_teamchange)
 863                 ClientKill_Now_TeamChange(this);
 864
 865         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 866                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 867
 868         // now I am sure the player IS dead
 869 }
 870 void KillIndicator_Think(entity this)
 871 {
 872         if (gameover)
 873         {
 874                 this.owner.killindicator = NULL;
 875                 delete(this);
 876                 return;
 877         }
 878
 879         if (this.owner.alpha < 0 && !this.owner.vehicle)
 880         {
 881                 this.owner.killindicator = NULL;
 882                 delete(this);
 883                 return;
 884         }
 885
 886         if(this.cnt <= 0)
 887         {
 888                 ClientKill_Now(this.owner);
 889                 return;
 890         }
 891     else if(g_cts && this.health == 1) // health == 1 means that it's silent
 892     {
 893         this.nextthink = time + 1;
 894         this.cnt -= 1;
 895     }
 896         else
 897         {
 898                 if(this.cnt <= 10)
 899                         setmodel(this, MDL_NUM(this.cnt));
 900                 if(IS_REAL_CLIENT(this.owner))
 901                 {
 902                         if(this.cnt <= 10)
 903                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 904                 }
 905                 this.nextthink = time + 1;
 906                 this.cnt -= 1;
 907         }
 908 }
 909
 910 float clientkilltime;
 911 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 912 {
 913         float killtime;
 914         float starttime;
 915
 916         if (gameover)
 917                 return;
 918
 919         killtime = autocvar_g_balance_kill_delay;
 920
 921         if(g_race_qualifying || g_cts)
 922                 killtime = 0;
 923
 924     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 925         return;
 926
 927         this.killindicator_teamchange = targetteam;
 928
 929     if(!this.killindicator)
 930         {
 931                 if(!IS_DEAD(this))
 932                 {
 933                         killtime = max(killtime, this.clientkill_nexttime - time);
 934                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 935                 }
 936
 937                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 938                 {
 939                         ClientKill_Now(this);
 940                 }
 941                 else
 942                 {
 943                         starttime = max(time, clientkilltime);
 944
 945                         this.killindicator = spawn();
 946                         this.killindicator.owner = this;
 947                         this.killindicator.scale = 0.5;
 948                         setattachment(this.killindicator, this, "");
 949                         setorigin(this.killindicator, '0 0 52');
 950                         setthink(this.killindicator, KillIndicator_Think);
 951                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 952                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 953                         this.killindicator.cnt = ceil(killtime);
 954                         this.killindicator.count = bound(0, ceil(killtime), 10);
 955                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 956
 957                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
 958                         {
 959                                 it.killindicator = spawn();
 960                                 it.killindicator.owner = it;
 961                                 it.killindicator.scale = 0.5;
 962                                 setattachment(it.killindicator, it, "");
 963                                 setorigin(it.killindicator, '0 0 52');
 964                                 setthink(it.killindicator, KillIndicator_Think);
 965                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 966                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 967                                 it.killindicator.cnt = ceil(killtime);
 968                         });
 969                         this.lip = 0;
 970                 }
 971         }
 972         if(this.killindicator)
 973         {
 974                 if(targetteam == 0) // just die
 975                 {
 976                         this.killindicator.colormod = '0 0 0';
 977                         if(IS_REAL_CLIENT(this))
 978                         if(this.killindicator.cnt > 0)
 979                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
 980                 }
 981                 else if(targetteam == -1) // auto
 982                 {
 983                         this.killindicator.colormod = '0 1 0';
 984                         if(IS_REAL_CLIENT(this))
 985                         if(this.killindicator.cnt > 0)
 986                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
 987                 }
 988                 else if(targetteam == -2) // spectate
 989                 {
 990                         this.killindicator.colormod = '0.5 0.5 0.5';
 991                         if(IS_REAL_CLIENT(this))
 992                         if(this.killindicator.cnt > 0)
 993                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
 994                 }
 995                 else
 996                 {
 997                         this.killindicator.colormod = Team_ColorRGB(targetteam);
 998                         if(IS_REAL_CLIENT(this))
 999                         if(this.killindicator.cnt > 0)
1000                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1001                 }
1002         }
1003
1004 }
1005
1006 void ClientKill (entity this)
1007 {
1008         if(gameover) return;
1009         if(this.player_blocked) return;
1010         if(STAT(FROZEN, this)) return;
1011
1012         ClientKill_TeamChange(this, 0);
1013 }
1014
1015 void FixClientCvars(entity e)
1016 {
1017         // send prediction settings to the client
1018         stuffcmd(e, "\nin_bindmap 0 0\n");
1019         if(autocvar_g_antilag == 3) // client side hitscan
1020                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1021         if(autocvar_sv_gentle)
1022                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1023
1024         MUTATOR_CALLHOOK(FixClientCvars, e);
1025 }
1026
1027 float PlayerInIDList(entity p, string idlist)
1028 {
1029         float n, i;
1030         string s;
1031
1032         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1033         if (!p.crypto_idfp)
1034                 return 0;
1035
1036         // this function allows abbreviated player IDs too!
1037         n = tokenize_console(idlist);
1038         for(i = 0; i < n; ++i)
1039         {
1040                 s = argv(i);
1041                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1042                         return 1;
1043         }
1044
1045         return 0;
1046 }
1047
1048 #ifdef DP_EXT_PRECONNECT
1049 /*
1050 =============
1051 ClientPreConnect
1052
1053 Called once (not at each match start) when a client begins a connection to the server
1054 =============
1055 */
1056 void ClientPreConnect(entity this)
1057 {
1058         if(autocvar_sv_eventlog)
1059         {
1060                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1061                         this.playerid,
1062                         etof(this),
1063                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1064                 ));
1065         }
1066 }
1067 #endif
1068
1069 /**
1070 =============
1071 ClientConnect
1072
1073 Called when a client connects to the server
1074 =============
1075 */
1076 void ClientConnect(entity this)
1077 {
1078         if (Ban_MaybeEnforceBanOnce(this)) return;
1079         assert(!IS_CLIENT(this), return);
1080         this.flags |= FL_CLIENT;
1081         assert(player_count >= 0, player_count = 0);
1082
1083 #ifdef WATERMARK
1084         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1085 #endif
1086         this.version_nagtime = time + 10 + random() * 10;
1087         TRANSMUTE(Client, this);
1088
1089         // identify the right forced team
1090         if (autocvar_g_campaign)
1091         {
1092                 if (IS_REAL_CLIENT(this)) // only players, not bots
1093                 {
1094                         switch (autocvar_g_campaign_forceteam)
1095                         {
1096                                 case 1: this.team_forced = NUM_TEAM_1; break;
1097                                 case 2: this.team_forced = NUM_TEAM_2; break;
1098                                 case 3: this.team_forced = NUM_TEAM_3; break;
1099                                 case 4: this.team_forced = NUM_TEAM_4; break;
1100                                 default: this.team_forced = 0;
1101                         }
1102                 }
1103         }
1104         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1105         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1106         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1107         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1108         else switch (autocvar_g_forced_team_otherwise)
1109         {
1110                 default: this.team_forced = 0; break;
1111                 case "red": this.team_forced = NUM_TEAM_1; break;
1112                 case "blue": this.team_forced = NUM_TEAM_2; break;
1113                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1114                 case "pink": this.team_forced = NUM_TEAM_4; break;
1115                 case "spectate":
1116                 case "spectator":
1117                         this.team_forced = -1;
1118                         break;
1119         }
1120         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1121
1122     {
1123         int id = this.playerid;
1124         this.playerid = 0; // silent
1125             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1126             this.playerid = id;
1127     }
1128
1129         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1130                 TRANSMUTE(Observer, this);
1131         } else {
1132                 if (!teamplay || autocvar_g_balance_teams) {
1133                         TRANSMUTE(Player, this);
1134                         campaign_bots_may_start = true;
1135                 } else {
1136                         TRANSMUTE(Observer, this); // do it anyway
1137                 }
1138         }
1139
1140         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1141
1142         // always track bots, don't ask for cl_allow_uidtracking
1143     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1144
1145         if (autocvar_sv_eventlog)
1146                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", this.netname));
1147
1148         LogTeamchange(this.playerid, this.team, 1);
1149
1150         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1151
1152         this.netname_previous = strzone(this.netname);
1153
1154         if(teamplay && IS_PLAYER(this))
1155                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1156         else
1157                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1158
1159         stuffcmd(this, clientstuff, "\n");
1160         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1161
1162         FixClientCvars(this);
1163
1164         // get version info from player
1165         stuffcmd(this, "cmd clientversion $gameversion\n");
1166
1167         // notify about available teams
1168         if (teamplay)
1169         {
1170                 CheckAllowedTeams(this);
1171                 int t = 0;
1172                 if (c1 >= 0) t |= BIT(0);
1173                 if (c2 >= 0) t |= BIT(1);
1174                 if (c3 >= 0) t |= BIT(2);
1175                 if (c4 >= 0) t |= BIT(3);
1176                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1177         }
1178         else
1179         {
1180                 stuffcmd(this, "set _teams_available 0\n");
1181         }
1182
1183         bot_relinkplayerlist();
1184
1185         this.spectatortime = time;
1186         if (blockSpectators)
1187         {
1188                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1189         }
1190
1191         this.jointime = time;
1192         this.allowed_timeouts = autocvar_sv_timeout_number;
1193
1194         if (IS_REAL_CLIENT(this))
1195         {
1196                 if (g_weaponarena_weapons == WEPSET(TUBA))
1197                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1198         }
1199
1200         if (!sv_foginterval && world.fog != "")
1201                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1202
1203         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1204                 if (!g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1205                         send_CSQC_teamnagger();
1206
1207         CSQCMODEL_AUTOINIT(this);
1208
1209         this.model_randomizer = random();
1210
1211         if (IS_REAL_CLIENT(this))
1212                 sv_notice_join(this);
1213
1214         // update physics stats (players can spawn before physics runs)
1215         Physics_UpdateStats(this, PHYS_HIGHSPEED(this));
1216
1217         IL_EACH(g_initforplayer, it.init_for_player, {
1218                 it.init_for_player(it, this);
1219         });
1220
1221         MUTATOR_CALLHOOK(ClientConnect, this);
1222
1223         if (IS_REAL_CLIENT(this))
1224         {
1225                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1226                 {
1227                         this.motd_actived_time = -1;
1228                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1229                 }
1230         }
1231 }
1232 /*
1233 =============
1234 ClientDisconnect
1235
1236 Called when a client disconnects from the server
1237 =============
1238 */
1239 .entity chatbubbleentity;
1240 void ReadyCount();
1241 void ClientDisconnect(entity this)
1242 {
1243         assert(IS_CLIENT(this), return);
1244
1245         PlayerStats_GameReport_FinalizePlayer(this);
1246         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1247         if (this.active_minigame) part_minigame(this);
1248         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1249
1250         if (autocvar_sv_eventlog)
1251                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1252
1253         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1254
1255         SetSpectatee(this, NULL);
1256
1257     MUTATOR_CALLHOOK(ClientDisconnect, this);
1258
1259         ClientState_detach(this);
1260
1261         Portal_ClearAll(this);
1262
1263         Unfreeze(this);
1264
1265         RemoveGrapplingHooks(this);
1266
1267         // Here, everything has been done that requires this player to be a client.
1268
1269         this.flags &= ~FL_CLIENT;
1270
1271         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1272         if (this.killindicator) delete(this.killindicator);
1273
1274         WaypointSprite_PlayerGone(this);
1275
1276         bot_relinkplayerlist();
1277
1278         if (this.netname_previous) strunzone(this.netname_previous);
1279         if (this.clientstatus) strunzone(this.clientstatus);
1280         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1281         if (this.personal) delete(this.personal);
1282
1283         this.playerid = 0;
1284         ReadyCount();
1285         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1286
1287         ONREMOVE(this);
1288 }
1289
1290 void ChatBubbleThink(entity this)
1291 {
1292         this.nextthink = time;
1293         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1294         {
1295                 if(this.owner) // but why can that ever be NULL?
1296                         this.owner.chatbubbleentity = NULL;
1297                 delete(this);
1298                 return;
1299         }
1300
1301         this.mdl = "";
1302
1303         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1304         {
1305                 if ( this.owner.active_minigame )
1306                         this.mdl = "models/sprites/minigame_busy.iqm";
1307                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1308                         this.mdl = "models/misc/chatbubble.spr";
1309         }
1310
1311         if ( this.model != this.mdl )
1312                 _setmodel(this, this.mdl);
1313
1314 }
1315
1316 void UpdateChatBubble(entity this)
1317 {
1318         if (this.alpha < 0)
1319                 return;
1320         // spawn a chatbubble entity if needed
1321         if (!this.chatbubbleentity)
1322         {
1323                 this.chatbubbleentity = new(chatbubbleentity);
1324                 this.chatbubbleentity.owner = this;
1325                 this.chatbubbleentity.exteriormodeltoclient = this;
1326                 setthink(this.chatbubbleentity, ChatBubbleThink);
1327                 this.chatbubbleentity.nextthink = time;
1328                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1329                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1330                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1331                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1332                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1333                 //this.chatbubbleentity.model = "";
1334                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1335         }
1336 }
1337
1338
1339 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1340 // added to the model skins
1341 /*void UpdateColorModHack()
1342 {
1343         float c;
1344         c = this.clientcolors & 15;
1345         // LordHavoc: only bothering to support white, green, red, yellow, blue
1346              if (!teamplay) this.colormod = '0 0 0';
1347         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1348         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1349         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1350         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1351         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1352         else this.colormod = '1 1 1';
1353 }*/
1354
1355 void respawn(entity this)
1356 {
1357         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1358         {
1359                 this.solid = SOLID_NOT;
1360                 this.takedamage = DAMAGE_NO;
1361                 set_movetype(this, MOVETYPE_FLY);
1362                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1363                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1364                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1365                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1366                 if(autocvar_g_respawn_ghosts_maxtime)
1367                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1368         }
1369
1370         CopyBody(this, 1);
1371
1372         this.effects |= EF_NODRAW; // prevent another CopyBody
1373         PutClientInServer(this);
1374 }
1375
1376 void play_countdown(entity this, float finished, Sound samp)
1377 {
1378     TC(Sound, samp);
1379         if(IS_REAL_CLIENT(this))
1380                 if(floor(finished - time - frametime) != floor(finished - time))
1381                         if(finished - time < 6)
1382                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1383 }
1384
1385 void player_powerups(entity this)
1386 {
1387         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1388         int items_prev = this.items;
1389
1390         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !gameover)
1391                 this.modelflags |= MF_ROCKET;
1392         else
1393                 this.modelflags &= ~MF_ROCKET;
1394
1395         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1396
1397         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1398                 return;
1399
1400         Fire_ApplyDamage(this);
1401         Fire_ApplyEffect(this);
1402
1403         if (!g_instagib)
1404         {
1405                 if (this.items & ITEM_Strength.m_itemid)
1406                 {
1407                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1408                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1409                         if (time > this.strength_finished)
1410                         {
1411                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1412                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1413                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1414                         }
1415                 }
1416                 else
1417                 {
1418                         if (time < this.strength_finished)
1419                         {
1420                                 this.items = this.items | ITEM_Strength.m_itemid;
1421                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1422                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1423                         }
1424                 }
1425                 if (this.items & ITEM_Shield.m_itemid)
1426                 {
1427                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1428                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1429                         if (time > this.invincible_finished)
1430                         {
1431                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1432                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1433                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1434                         }
1435                 }
1436                 else
1437                 {
1438                         if (time < this.invincible_finished)
1439                         {
1440                                 this.items = this.items | ITEM_Shield.m_itemid;
1441                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1442                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1443                         }
1444                 }
1445                 if (this.items & IT_SUPERWEAPON)
1446                 {
1447                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1448                         {
1449                                 this.superweapons_finished = 0;
1450                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1451                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1452                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1453                         }
1454                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1455                         {
1456                                 // don't let them run out
1457                         }
1458                         else
1459                         {
1460                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1461                                 if (time > this.superweapons_finished)
1462                                 {
1463                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1464                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1465                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1466                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1467                                 }
1468                         }
1469                 }
1470                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1471                 {
1472                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1473                         {
1474                                 this.items = this.items | IT_SUPERWEAPON;
1475                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1476                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1477                         }
1478                         else
1479                         {
1480                                 this.superweapons_finished = 0;
1481                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1482                         }
1483                 }
1484                 else
1485                 {
1486                         this.superweapons_finished = 0;
1487                 }
1488         }
1489
1490         if(autocvar_g_nodepthtestplayers)
1491                 this.effects = this.effects | EF_NODEPTHTEST;
1492
1493         if(autocvar_g_fullbrightplayers)
1494                 this.effects = this.effects | EF_FULLBRIGHT;
1495
1496         if (time >= game_starttime)
1497         if (time < this.spawnshieldtime)
1498                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1499
1500         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1501 }
1502
1503 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1504 {
1505         if(current > stable)
1506                 return current;
1507         else if(current > stable - 0.25) // when close enough, "snap"
1508                 return stable;
1509         else
1510                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1511 }
1512
1513 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1514 {
1515         if(current < stable)
1516                 return current;
1517         else if(current < stable + 0.25) // when close enough, "snap"
1518                 return stable;
1519         else
1520                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1521 }
1522
1523 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1524 {
1525         if(current > rotstable)
1526         {
1527                 if(rotframetime > 0)
1528                 {
1529                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1530                         current = max(rotstable, current - rotlinear * rotframetime);
1531                 }
1532         }
1533         else if(current < regenstable)
1534         {
1535                 if(regenframetime > 0)
1536                 {
1537                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1538                         current = min(regenstable, current + regenlinear * regenframetime);
1539                 }
1540         }
1541
1542         if(current > limit)
1543                 current = limit;
1544
1545         return current;
1546 }
1547
1548 void player_regen(entity this)
1549 {
1550         float max_mod, regen_mod, rot_mod, limit_mod;
1551         max_mod = regen_mod = rot_mod = limit_mod = 1;
1552
1553         float regen_health = autocvar_g_balance_health_regen;
1554         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1555         float regen_health_rot = autocvar_g_balance_health_rot;
1556         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1557         float regen_health_stable = autocvar_g_balance_health_regenstable;
1558         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1559         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1560                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1561         max_mod = M_ARGV(1, float);
1562         regen_mod = M_ARGV(2, float);
1563         rot_mod = M_ARGV(3, float);
1564         limit_mod = M_ARGV(4, float);
1565         regen_health = M_ARGV(5, float);
1566         regen_health_linear = M_ARGV(6, float);
1567         regen_health_rot = M_ARGV(7, float);
1568         regen_health_rotlinear = M_ARGV(8, float);
1569         regen_health_stable = M_ARGV(9, float);
1570         regen_health_rotstable = M_ARGV(10, float);
1571
1572
1573         if(!mutator_returnvalue)
1574         if(!STAT(FROZEN, this))
1575         {
1576                 float mina, maxa, limith, limita;
1577                 maxa = autocvar_g_balance_armor_rotstable;
1578                 mina = autocvar_g_balance_armor_regenstable;
1579                 limith = autocvar_g_balance_health_limit;
1580                 limita = autocvar_g_balance_armor_limit;
1581
1582                 regen_health_rotstable = regen_health_rotstable * max_mod;
1583                 regen_health_stable = regen_health_stable * max_mod;
1584                 limith = limith * limit_mod;
1585                 limita = limita * limit_mod;
1586
1587                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1588                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1589         }
1590
1591         // if player rotted to death...  die!
1592         // check this outside above checks, as player may still be able to rot to death
1593         if(this.health < 1)
1594         {
1595                 if(this.vehicle)
1596                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1597                 if(this.event_damage)
1598                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1599         }
1600
1601         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1602         {
1603                 float minf, maxf, limitf;
1604
1605                 maxf = autocvar_g_balance_fuel_rotstable;
1606                 minf = autocvar_g_balance_fuel_regenstable;
1607                 limitf = autocvar_g_balance_fuel_limit;
1608
1609                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1610         }
1611 }
1612
1613 bool zoomstate_set;
1614 void SetZoomState(entity this, float newzoom)
1615 {
1616         if(newzoom != this.zoomstate)
1617         {
1618                 this.zoomstate = newzoom;
1619                 ClientData_Touch(this);
1620         }
1621         zoomstate_set = true;
1622 }
1623
1624 void GetPressedKeys(entity this)
1625 {
1626         MUTATOR_CALLHOOK(GetPressedKeys, this);
1627         int keys = STAT(PRESSED_KEYS, this);
1628         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1629         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1630         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1631         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1632
1633         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1634         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1635         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1636         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1637         this.pressedkeys = keys; // store for other users
1638
1639         STAT(PRESSED_KEYS, this) = keys;
1640 }
1641
1642 /*
1643 ======================
1644 spectate mode routines
1645 ======================
1646 */
1647
1648 void SpectateCopy(entity this, entity spectatee)
1649 {
1650     TC(Client, this); TC(Client, spectatee);
1651
1652         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1653         PS(this) = PS(spectatee);
1654         this.armortype = spectatee.armortype;
1655         this.armorvalue = spectatee.armorvalue;
1656         this.ammo_cells = spectatee.ammo_cells;
1657         this.ammo_plasma = spectatee.ammo_plasma;
1658         this.ammo_shells = spectatee.ammo_shells;
1659         this.ammo_nails = spectatee.ammo_nails;
1660         this.ammo_rockets = spectatee.ammo_rockets;
1661         this.ammo_fuel = spectatee.ammo_fuel;
1662         this.clip_load = spectatee.clip_load;
1663         this.clip_size = spectatee.clip_size;
1664         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1665         this.health = spectatee.health;
1666         this.impulse = 0;
1667         this.items = spectatee.items;
1668         this.last_pickup = spectatee.last_pickup;
1669         this.hit_time = spectatee.hit_time;
1670         this.strength_finished = spectatee.strength_finished;
1671         this.invincible_finished = spectatee.invincible_finished;
1672         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1673         this.weapons = spectatee.weapons;
1674         this.vortex_charge = spectatee.vortex_charge;
1675         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1676         this.hagar_load = spectatee.hagar_load;
1677         this.arc_heat_percent = spectatee.arc_heat_percent;
1678         this.minelayer_mines = spectatee.minelayer_mines;
1679         this.punchangle = spectatee.punchangle;
1680         this.view_ofs = spectatee.view_ofs;
1681         this.velocity = spectatee.velocity;
1682         this.dmg_take = spectatee.dmg_take;
1683         this.dmg_save = spectatee.dmg_save;
1684         this.dmg_inflictor = spectatee.dmg_inflictor;
1685         this.v_angle = spectatee.v_angle;
1686         this.angles = spectatee.v_angle;
1687         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1688         this.revive_progress = spectatee.revive_progress;
1689         this.viewloc = spectatee.viewloc;
1690         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1691                 this.fixangle = true;
1692         setorigin(this, spectatee.origin);
1693         setsize(this, spectatee.mins, spectatee.maxs);
1694         SetZoomState(this, spectatee.zoomstate);
1695
1696         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1697         {
1698                 .entity weaponentity = weaponentities[slot];
1699                 this.(weaponentity) = spectatee.(weaponentity);
1700         }
1701
1702     anticheat_spectatecopy(this, spectatee);
1703         this.hud = spectatee.hud;
1704         if(spectatee.vehicle)
1705     {
1706         this.angles = spectatee.v_angle;
1707
1708         //this.fixangle = false;
1709         //this.velocity = spectatee.vehicle.velocity;
1710         this.vehicle_health = spectatee.vehicle_health;
1711         this.vehicle_shield = spectatee.vehicle_shield;
1712         this.vehicle_energy = spectatee.vehicle_energy;
1713         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1714         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1715         this.vehicle_reload1 = spectatee.vehicle_reload1;
1716         this.vehicle_reload2 = spectatee.vehicle_reload2;
1717
1718         //msg_entity = this;
1719
1720        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1721             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1722            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1723            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1724
1725         //WriteByte (MSG_ONE, SVC_SETVIEW);
1726         //    WriteEntity(MSG_ONE, this);
1727         //makevectors(spectatee.v_angle);
1728         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1729     }
1730 }
1731
1732 bool SpectateUpdate(entity this)
1733 {
1734         if(!this.enemy)
1735                 return false;
1736
1737         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1738         {
1739                 SetSpectatee(this, NULL);
1740                 return false;
1741         }
1742
1743         SpectateCopy(this, this.enemy);
1744
1745         return true;
1746 }
1747
1748 bool SpectateSet(entity this)
1749 {
1750         if(!IS_PLAYER(this.enemy))
1751                 return false;
1752
1753         ClientData_Touch(this.enemy);
1754
1755         msg_entity = this;
1756         WriteByte(MSG_ONE, SVC_SETVIEW);
1757         WriteEntity(MSG_ONE, this.enemy);
1758         set_movetype(this, MOVETYPE_NONE);
1759         accuracy_resend(this);
1760
1761         if(!SpectateUpdate(this))
1762                 PutObserverInServer(this);
1763
1764         return true;
1765 }
1766
1767 void SetSpectatee_status(entity this, int spectatee_num)
1768 {
1769         int oldspectatee_status = this.spectatee_status;
1770         this.spectatee_status = spectatee_num;
1771
1772         if (this.spectatee_status != oldspectatee_status)
1773         {
1774                 ClientData_Touch(this);
1775                 if (g_race || g_cts) race_InitSpectator();
1776         }
1777 }
1778
1779 void SetSpectatee(entity this, entity spectatee)
1780 {
1781         entity old_spectatee = this.enemy;
1782
1783         this.enemy = spectatee;
1784
1785         // WEAPONTODO
1786         // these are required to fix the spectator bug with arc
1787         if(old_spectatee)
1788         {
1789                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1790                 {
1791                         .entity weaponentity = weaponentities[slot];
1792                         if(old_spectatee.(weaponentity).arc_beam)
1793                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1794                 }
1795         }
1796         if(this.enemy)
1797         {
1798                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1799                 {
1800                         .entity weaponentity = weaponentities[slot];
1801                         if(this.enemy.(weaponentity).arc_beam)
1802                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1803                 }
1804         }
1805
1806         if (this.enemy)
1807                 SetSpectatee_status(this, etof(this.enemy));
1808
1809         // needed to update spectator list
1810         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1811 }
1812
1813 bool Spectate(entity this, entity pl)
1814 {
1815         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1816                 return false;
1817         pl = M_ARGV(1, entity);
1818
1819         SetSpectatee(this, pl);
1820         return SpectateSet(this);
1821 }
1822
1823 bool SpectateNext(entity this)
1824 {
1825         entity ent = find(this.enemy, classname, STR_PLAYER);
1826
1827         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1828                 ent = M_ARGV(1, entity);
1829         else if (!ent)
1830                 ent = find(ent, classname, STR_PLAYER);
1831
1832         if(ent) { SetSpectatee(this, ent); }
1833
1834         return SpectateSet(this);
1835 }
1836
1837 bool SpectatePrev(entity this)
1838 {
1839         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1840         entity ent = findchain(classname, STR_PLAYER);
1841         if (!ent) // no player
1842                 return false;
1843
1844         entity first = ent;
1845         // skip players until current spectated player
1846         if(this.enemy)
1847         while(ent && ent != this.enemy)
1848                 ent = ent.chain;
1849
1850         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1851         {
1852                 case MUT_SPECPREV_FOUND:
1853                     ent = M_ARGV(1, entity);
1854                     break;
1855                 case MUT_SPECPREV_RETURN:
1856                     return true;
1857                 case MUT_SPECPREV_CONTINUE:
1858                 default:
1859                 {
1860                         if(ent.chain)
1861                                 ent = ent.chain;
1862                         else
1863                                 ent = first;
1864                         break;
1865                 }
1866         }
1867
1868         SetSpectatee(this, ent);
1869         return SpectateSet(this);
1870 }
1871
1872 /*
1873 =============
1874 ShowRespawnCountdown()
1875
1876 Update a respawn countdown display.
1877 =============
1878 */
1879 void ShowRespawnCountdown(entity this)
1880 {
1881         float number;
1882         if(!IS_DEAD(this)) // just respawned?
1883                 return;
1884         else
1885         {
1886                 number = ceil(this.respawn_time - time);
1887                 if(number <= 0)
1888                         return;
1889                 if(number <= this.respawn_countdown)
1890                 {
1891                         this.respawn_countdown = number - 1;
1892                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1893                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1894                 }
1895         }
1896 }
1897
1898 .bool team_selected;
1899 bool ShowTeamSelection(entity this)
1900 {
1901         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1902                 return false;
1903         stuffcmd(this, "menu_showteamselect\n");
1904         return true;
1905 }
1906 void Join(entity this)
1907 {
1908         TRANSMUTE(Player, this);
1909
1910         if(!this.team_selected)
1911         if(autocvar_g_campaign || autocvar_g_balance_teams)
1912                 JoinBestTeam(this, false, true);
1913
1914         if(autocvar_g_campaign)
1915                 campaign_bots_may_start = true;
1916
1917         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1918
1919         PutClientInServer(this);
1920
1921         if(teamplay && this.team != -1)
1922                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
1923         else
1924                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1925         this.team_selected = false;
1926 }
1927
1928 /**
1929  * Determines whether the player is allowed to join. This depends on cvar
1930  * g_maxplayers, if it isn't used this function always return true, otherwise
1931  * it checks whether the number of currently playing players exceeds g_maxplayers.
1932  * @return int number of free slots for players, 0 if none
1933  */
1934 int nJoinAllowed(entity this, entity ignore)
1935 {
1936         if(!ignore)
1937         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1938         // so report 0 free slots if restricted
1939         {
1940                 if(autocvar_g_forced_team_otherwise == "spectate")
1941                         return 0;
1942                 if(autocvar_g_forced_team_otherwise == "spectator")
1943                         return 0;
1944         }
1945
1946         if(this && this.team_forced < 0)
1947                 return 0; // forced spectators can never join
1948
1949         // TODO simplify this
1950         int totalClients = 0;
1951         int currentlyPlaying = 0;
1952         FOREACH_CLIENT(true, LAMBDA(
1953                 if(it != ignore)
1954                         ++totalClients;
1955                 if(IS_REAL_CLIENT(it))
1956                 if(IS_PLAYER(it) || it.caplayer)
1957                         ++currentlyPlaying;
1958         ));
1959
1960         float free_slots = 0;
1961         if (!autocvar_g_maxplayers)
1962                 free_slots = maxclients - totalClients;
1963         else if(currentlyPlaying < autocvar_g_maxplayers)
1964                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1965
1966         static float join_prevent_msg_time = 0;
1967         if(this && ignore && !free_slots && time > join_prevent_msg_time)
1968         {
1969                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1970                 join_prevent_msg_time = time + 3;
1971         }
1972
1973         return free_slots;
1974 }
1975
1976 /**
1977  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1978  * g_maxplayers_spectator_blocktime seconds
1979  */
1980 void checkSpectatorBlock(entity this)
1981 {
1982         if(IS_SPEC(this) || IS_OBSERVER(this))
1983         if(!this.caplayer)
1984         if(IS_REAL_CLIENT(this))
1985         {
1986                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1987                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1988                         dropclient(this);
1989                 }
1990         }
1991 }
1992
1993 void PrintWelcomeMessage(entity this)
1994 {
1995         if(this.motd_actived_time == 0)
1996         {
1997                 if (autocvar_g_campaign) {
1998                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
1999                                 this.motd_actived_time = time;
2000                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2001                         }
2002                 } else {
2003                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2004                                 this.motd_actived_time = time;
2005                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2006                         }
2007                 }
2008         }
2009         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
2010         {
2011                 if (autocvar_g_campaign) {
2012                         if (PHYS_INPUT_BUTTON_INFO(this))
2013                                 this.motd_actived_time = time;
2014                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2015                                 this.motd_actived_time = 0;
2016                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2017                         }
2018                 } else {
2019                         if (PHYS_INPUT_BUTTON_INFO(this))
2020                                 this.motd_actived_time = time;
2021                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2022                                 this.motd_actived_time = 0;
2023                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2024                         }
2025                 }
2026         }
2027         else //if(this.motd_actived_time < 0) // just connected, motd is active
2028         {
2029                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2030                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2031                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2032                 {
2033                         // instanctly hide MOTD
2034                         this.motd_actived_time = 0;
2035                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2036                 }
2037         }
2038 }
2039
2040 bool joinAllowed(entity this)
2041 {
2042         if (this.version_mismatch) return false;
2043         if (!nJoinAllowed(this, this)) return false;
2044         if (teamplay && lockteams) return false;
2045         if (ShowTeamSelection(this)) return false;
2046         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2047         return true;
2048 }
2049
2050 void ObserverThink(entity this)
2051 {
2052         if ( this.impulse )
2053         {
2054                 MinigameImpulse(this, this.impulse);
2055                 this.impulse = 0;
2056         }
2057
2058         if (this.flags & FL_JUMPRELEASED) {
2059                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2060                         this.flags &= ~FL_JUMPRELEASED;
2061                         this.flags |= FL_SPAWNING;
2062                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
2063                         this.flags &= ~FL_JUMPRELEASED;
2064                         if(SpectateNext(this)) {
2065                                 TRANSMUTE(Spectator, this);
2066                         }
2067                 } else {
2068                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2069                         set_movetype(this, preferred_movetype);
2070                 }
2071         } else {
2072                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2073                         this.flags |= FL_JUMPRELEASED;
2074                         if(this.flags & FL_SPAWNING)
2075                         {
2076                                 this.flags &= ~FL_SPAWNING;
2077                                 Join(this);
2078                                 return;
2079                         }
2080                 }
2081         }
2082 }
2083
2084 void SpectatorThink(entity this)
2085 {
2086         if ( this.impulse )
2087         {
2088                 if(MinigameImpulse(this, this.impulse))
2089                         this.impulse = 0;
2090
2091                 if (this.impulse == IMP_weapon_drop.impulse)
2092                 {
2093                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2094                         this.impulse = 0;
2095                         return;
2096                 }
2097         }
2098
2099         if (this.flags & FL_JUMPRELEASED) {
2100                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2101                         this.flags &= ~FL_JUMPRELEASED;
2102                         this.flags |= FL_SPAWNING;
2103                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
2104                         this.flags &= ~FL_JUMPRELEASED;
2105                         if(SpectateNext(this)) {
2106                                 TRANSMUTE(Spectator, this);
2107                         } else {
2108                                 TRANSMUTE(Observer, this);
2109                                 PutClientInServer(this);
2110                         }
2111                         this.impulse = 0;
2112                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
2113                         this.flags &= ~FL_JUMPRELEASED;
2114                         if(SpectatePrev(this)) {
2115                                 TRANSMUTE(Spectator, this);
2116                         } else {
2117                                 TRANSMUTE(Observer, this);
2118                                 PutClientInServer(this);
2119                         }
2120                         this.impulse = 0;
2121                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2122                         this.flags &= ~FL_JUMPRELEASED;
2123                         TRANSMUTE(Observer, this);
2124                         PutClientInServer(this);
2125                 } else {
2126                         if(!SpectateUpdate(this))
2127                                 PutObserverInServer(this);
2128                 }
2129         } else {
2130                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2131                         this.flags |= FL_JUMPRELEASED;
2132                         if(this.flags & FL_SPAWNING)
2133                         {
2134                                 this.flags &= ~FL_SPAWNING;
2135                                 Join(this);
2136                                 return;
2137                         }
2138                 }
2139                 if(!SpectateUpdate(this))
2140                         PutObserverInServer(this);
2141         }
2142
2143         this.flags |= FL_CLIENT | FL_NOTARGET;
2144 }
2145
2146 void vehicles_enter (entity pl, entity veh);
2147 void PlayerUseKey(entity this)
2148 {
2149         if (!IS_PLAYER(this))
2150                 return;
2151
2152         if(this.vehicle)
2153         {
2154                 if(!gameover)
2155                 {
2156                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2157                         return;
2158                 }
2159         }
2160         else if(autocvar_g_vehicles_enter)
2161         {
2162                 if(!STAT(FROZEN, this))
2163                 if(!IS_DEAD(this))
2164                 if(!gameover)
2165                 {
2166                         entity head, closest_target = NULL;
2167                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2168
2169                         while(head) // find the closest acceptable target to enter
2170                         {
2171                                 if(IS_VEHICLE(head))
2172                                 if(!IS_DEAD(head))
2173                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2174                                 if(head.takedamage != DAMAGE_NO)
2175                                 {
2176                                         if(closest_target)
2177                                         {
2178                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2179                                                 { closest_target = head; }
2180                                         }
2181                                         else { closest_target = head; }
2182                                 }
2183
2184                                 head = head.chain;
2185                         }
2186
2187                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2188                 }
2189         }
2190
2191         // a use key was pressed; call handlers
2192         MUTATOR_CALLHOOK(PlayerUseKey, this);
2193 }
2194
2195
2196 /*
2197 =============
2198 PlayerPreThink
2199
2200 Called every frame for each client before the physics are run
2201 =============
2202 */
2203 .float usekeypressed;
2204 .float last_vehiclecheck;
2205 .int items_added;
2206 void PlayerPreThink (entity this)
2207 {
2208         WarpZone_PlayerPhysics_FixVAngle(this);
2209
2210     STAT(GAMESTARTTIME, this) = game_starttime;
2211         STAT(ROUNDSTARTTIME, this) = round_starttime;
2212         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2213         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2214
2215         STAT(WEAPONSINMAP, this) = weaponsInMap;
2216
2217         if (frametime) {
2218                 // physics frames: update anticheat stuff
2219                 anticheat_prethink(this);
2220         }
2221
2222         if (blockSpectators && frametime) {
2223                 // WORKAROUND: only use dropclient in server frames (frametime set).
2224                 // Never use it in cl_movement frames (frametime zero).
2225                 checkSpectatorBlock(this);
2226     }
2227
2228         zoomstate_set = false;
2229
2230         // Check for nameless players
2231         if (isInvisibleString(this.netname)) {
2232                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2233                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2234         }
2235         if (this.netname != this.netname_previous) {
2236                 if (autocvar_sv_eventlog) {
2237                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", this.netname));
2238         }
2239                 if (this.netname_previous) strunzone(this.netname_previous);
2240                 this.netname_previous = strzone(this.netname);
2241         }
2242
2243         // version nagging
2244         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2245         this.version_nagtime = 0;
2246         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2247             // git client
2248         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2249             // git server
2250             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2251         } else {
2252             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2253             if (r < 0) { // old client
2254                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2255             } else if (r > 0) { // old server
2256                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2257             }
2258         }
2259     }
2260
2261         // GOD MODE info
2262         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2263         {
2264                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2265                 this.max_armorvalue = 0;
2266         }
2267
2268         if (STAT(FROZEN, this) == 2)
2269         {
2270                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2271                 this.health = max(1, this.revive_progress * start_health);
2272                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2273
2274                 if (this.revive_progress >= 1)
2275                         Unfreeze(this);
2276         }
2277         else if (STAT(FROZEN, this) == 3)
2278         {
2279                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2280                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2281
2282                 if (this.health < 1)
2283                 {
2284                         if (this.vehicle)
2285                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2286                         if(this.event_damage)
2287                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2288                 }
2289                 else if (this.revive_progress <= 0)
2290                         Unfreeze(this);
2291         }
2292
2293         MUTATOR_CALLHOOK(PlayerPreThink, this);
2294
2295         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !gameover && !this.vehicle)
2296         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2297         {
2298                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2299                 {
2300                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2301                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2302                         {
2303                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2304                         }
2305                         else if(!it.owner)
2306                         {
2307                                 if(!it.team || SAME_TEAM(this, it))
2308                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2309                                 else if(autocvar_g_vehicles_steal)
2310                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2311                         }
2312                 });
2313
2314                 this.last_vehiclecheck = time + 1;
2315         }
2316
2317         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2318         {
2319                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2320                         PlayerUseKey(this);
2321                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2322         }
2323
2324         if (IS_REAL_CLIENT(this))
2325                 PrintWelcomeMessage(this);
2326
2327         if (IS_PLAYER(this)) {
2328                 CheckRules_Player(this);
2329
2330                 if (gameover || intermission_running) {
2331                         if(intermission_running)
2332                                 IntermissionThink(this);
2333                         return;
2334                 }
2335
2336                 if (timeout_status == TIMEOUT_ACTIVE) {
2337             // don't allow the player to turn around while game is paused
2338                         // FIXME turn this into CSQC stuff
2339                         this.v_angle = this.lastV_angle;
2340                         this.angles = this.lastV_angle;
2341                         this.fixangle = true;
2342                 }
2343
2344                 if (frametime) player_powerups(this);
2345
2346                 if (IS_DEAD(this)) {
2347                         if (this.personal && g_race_qualifying) {
2348                                 if (time > this.respawn_time) {
2349                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2350                                         respawn(this);
2351                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2352                                 }
2353                         } else {
2354                                 if (frametime) player_anim(this);
2355                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2356
2357                                 switch(this.deadflag)
2358                                 {
2359                                         case DEAD_DYING:
2360                                         {
2361                                                 if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2362                                                         this.deadflag = DEAD_RESPAWNING;
2363                                                 else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2364                                                         this.deadflag = DEAD_DEAD;
2365                                                 break;
2366                                         }
2367                                         case DEAD_DEAD:
2368                                         {
2369                                                 if (button_pressed)
2370                                                         this.deadflag = DEAD_RESPAWNABLE;
2371                                                 else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2372                                                         this.deadflag = DEAD_RESPAWNING;
2373                                                 break;
2374                                         }
2375                                         case DEAD_RESPAWNABLE:
2376                                         {
2377                                                 if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2378                                                         this.deadflag = DEAD_RESPAWNING;
2379                                                 break;
2380                                         }
2381                                         case DEAD_RESPAWNING:
2382                                         {
2383                                                 if (time > this.respawn_time)
2384                                                 {
2385                                                         this.respawn_time = time + 1; // only retry once a second
2386                                                         this.respawn_time_max = this.respawn_time;
2387                                                         respawn(this);
2388                                                 }
2389                                                 break;
2390                                         }
2391                                 }
2392
2393                                 ShowRespawnCountdown(this);
2394
2395                                 if (this.respawn_flags & RESPAWN_SILENT)
2396                                         STAT(RESPAWN_TIME, this) = 0;
2397                                 else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2398                                 {
2399                                         if (time < this.respawn_time)
2400                                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2401                                         else if (this.deadflag != DEAD_RESPAWNING)
2402                                                 STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2403                                 }
2404                                 else
2405                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2406                         }
2407
2408                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2409                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2410                                 STAT(RESPAWN_TIME, this) *= -1;
2411
2412                         return;
2413                 }
2414
2415                 this.prevorigin = this.origin;
2416
2417                 bool have_hook = false;
2418                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2419                 {
2420                         .entity weaponentity = weaponentities[slot];
2421                         if(this.(weaponentity).hook.state)
2422                         {
2423                                 have_hook = true;
2424                                 break;
2425                         }
2426                 }
2427                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2428                 if (have_hook) {
2429                         do_crouch = false;
2430                 } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2431                         do_crouch = false;
2432                 } else if (this.vehicle) {
2433                         do_crouch = false;
2434                 } else if (STAT(FROZEN, this)) {
2435                         do_crouch = false;
2436         }
2437
2438                 if (do_crouch) {
2439                         if (!this.crouch) {
2440                                 this.crouch = true;
2441                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2442                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2443                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2444                         }
2445                 } else if (this.crouch) {
2446             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2447             if (!trace_startsolid) {
2448                 this.crouch = false;
2449                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2450                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2451             }
2452                 }
2453
2454                 FixPlayermodel(this);
2455
2456                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2457                 //if(frametime)
2458                 {
2459                         this.items &= ~this.items_added;
2460
2461                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2462                         {
2463                                 .entity weaponentity = weaponentities[slot];
2464                                 W_WeaponFrame(this, weaponentity);
2465
2466                                 if(slot == 0)
2467                                 {
2468                                         this.clip_load = this.(weaponentity).clip_load;
2469                                         this.clip_size = this.(weaponentity).clip_size;
2470                                 }
2471                         }
2472
2473                         this.items_added = 0;
2474                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2475                 this.items_added |= IT_FUEL;
2476
2477                         this.items |= this.items_added;
2478                 }
2479
2480                 player_regen(this);
2481
2482                 // WEAPONTODO: Add a weapon request for this
2483                 // rot vortex charge to the charge limit
2484                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2485                 {
2486                         .entity weaponentity = weaponentities[slot];
2487                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2488                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2489                 }
2490
2491                 if (frametime) player_anim(this);
2492
2493                 // secret status
2494                 secrets_setstatus(this);
2495
2496                 // monsters status
2497                 monsters_setstatus(this);
2498
2499                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2500         }
2501         else if (gameover || intermission_running) {
2502                 if(intermission_running)
2503                         IntermissionThink(this);
2504                 return;
2505         }
2506         else if (IS_OBSERVER(this)) {
2507                 ObserverThink(this);
2508         }
2509         else if (IS_SPEC(this)) {
2510                 SpectatorThink(this);
2511         }
2512
2513         // WEAPONTODO: Add weapon request for this
2514         if (!zoomstate_set) {
2515                 bool wep_zoomed = false;
2516                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2517                 {
2518                         .entity weaponentity = weaponentities[slot];
2519                         Weapon thiswep = this.(weaponentity).m_weapon;
2520                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2521                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2522                 }
2523                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2524     }
2525
2526         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2527         {
2528                 this.teamkill_soundtime = 0;
2529
2530                 entity e = this.teamkill_soundsource;
2531                 entity oldpusher = e.pusher;
2532                 e.pusher = this;
2533                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2534                 e.pusher = oldpusher;
2535         }
2536
2537         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2538                 this.taunt_soundtime = 0;
2539                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2540         }
2541
2542         target_voicescript_next(this);
2543
2544         // WEAPONTODO: Move into weaponsystem somehow
2545         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2546         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2547         {
2548                 .entity weaponentity = weaponentities[slot];
2549                 if(this.(weaponentity).m_weapon == WEP_Null)
2550                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2551         }
2552 }
2553
2554 void DrownPlayer(entity this)
2555 {
2556         if(IS_DEAD(this))
2557                 return;
2558
2559         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2560         {
2561                 if(this.air_finished < time)
2562                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2563                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2564                 this.dmg = 2;
2565         }
2566         else if (this.air_finished < time)
2567         {       // drown!
2568                 if (this.pain_finished < time)
2569                 {
2570                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2571                         this.pain_finished = time + 0.5;
2572                 }
2573         }
2574 }
2575
2576 .bool move_qcphysics;
2577
2578 void Player_Physics(entity this)
2579 {
2580         set_movetype(this, this.move_movetype);
2581
2582         if(!this.move_qcphysics)
2583                 return;
2584
2585         if(!frametime && !this.pm_frametime)
2586                 return;
2587
2588         Movetype_Physics_NoMatchTicrate(this, this.pm_frametime, true);
2589
2590         this.pm_frametime = 0;
2591 }
2592
2593 /*
2594 =============
2595 PlayerPostThink
2596
2597 Called every frame for each client after the physics are run
2598 =============
2599 */
2600 .float idlekick_lasttimeleft;
2601 void PlayerPostThink (entity this)
2602 {
2603         Player_Physics(this);
2604
2605         if (sv_maxidle > 0)
2606         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2607         if (IS_REAL_CLIENT(this))
2608         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2609         {
2610                 int totalClients = 0;
2611                 if(sv_maxidle_slots > 0)
2612                 {
2613                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2614                         {
2615                                 ++totalClients;
2616                         });
2617                 }
2618
2619                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2620                 { /* do nothing */ }
2621                 else if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2622                 {
2623                         if (this.idlekick_lasttimeleft)
2624                         {
2625                                 this.idlekick_lasttimeleft = 0;
2626                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2627                         }
2628                 }
2629                 else
2630                 {
2631                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2632                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2633                                 if (!this.idlekick_lasttimeleft)
2634                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2635                         }
2636                         if (timeleft <= 0) {
2637                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2638                                 dropclient(this);
2639                                 return;
2640                         }
2641                         else if (timeleft <= 10) {
2642                                 if (timeleft != this.idlekick_lasttimeleft) {
2643                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2644                 }
2645                                 this.idlekick_lasttimeleft = timeleft;
2646                         }
2647                 }
2648         }
2649
2650         CheatFrame(this);
2651
2652         //CheckPlayerJump();
2653         if (gameover)
2654         {
2655                 this.solid = SOLID_NOT;
2656                 this.takedamage = DAMAGE_NO;
2657                 set_movetype(this, MOVETYPE_NONE);
2658         }
2659
2660         if (IS_PLAYER(this)) {
2661                 DrownPlayer(this);
2662                 CheckRules_Player(this);
2663                 UpdateChatBubble(this);
2664                 if (this.impulse) ImpulseCommands(this);
2665                 if (gameover)
2666                 {
2667                         CSQCMODEL_AUTOUPDATE(this);
2668                         return;
2669                 }
2670                 GetPressedKeys(this);
2671         }
2672
2673         if (this.waypointsprite_attachedforcarrier) {
2674             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2675                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2676     }
2677
2678         playerdemo_write(this);
2679
2680         CSQCMODEL_AUTOUPDATE(this);
2681 }