qcsrc/server/cl_weapons.qc

   1 void W_TriggerReload()
   2 {
   3     weapon_action(self.weapon, WR_RELOAD);
   4 }
   5
   6 // switch between weapons
   7 void W_SwitchWeapon(float imp)
   8 {
   9         if (self.switchweapon != imp)
  10         {
  11                 if (client_hasweapon(self, imp, TRUE, TRUE))
  12                         W_SwitchWeapon_Force(self, imp);
  13                 else
  14                         self.selectweapon = imp; // update selectweapon ANYWAY
  15         }
  16         else
  17         {
  18                 W_TriggerReload();
  19         }
  20 }
  21
  22 .float weaponcomplainindex;
  23 float W_GetCycleWeapon(entity pl, string weaponorder, float dir, float imp, float complain, float skipmissing)
  24 {
  25         // We cannot tokenize in this function, as GiveItems calls this
  26         // function. Thus we must use car/cdr.
  27         float weaponwant, first_valid, prev_valid, switchtonext, switchtolast, c;
  28         string rest;
  29         switchtonext = switchtolast = 0;
  30         first_valid = prev_valid = 0;
  31         float weaponcur;
  32
  33         if(skipmissing || pl.selectweapon == 0)
  34                 weaponcur = pl.switchweapon;
  35         else
  36                 weaponcur = pl.selectweapon;
  37
  38         if(dir == 0)
  39                 switchtonext = 1;
  40
  41         c = 0;
  42
  43         rest = weaponorder;
  44         while(rest != "")
  45         {
  46                 weaponwant = stof(car(rest)); rest = cdr(rest);
  47                 if(imp >= 0)
  48                         if((get_weaponinfo(weaponwant)).impulse != imp)
  49                                 continue;
  50
  51                 ++c;
  52
  53                 if(!skipmissing || client_hasweapon(pl, weaponwant, TRUE, FALSE))
  54                 {
  55                         if(switchtonext)
  56                                 return weaponwant;
  57                         if(!first_valid)
  58                                 first_valid = weaponwant;
  59                         if(weaponwant == weaponcur)
  60                         {
  61                                 if(dir >= 0)
  62                                         switchtonext = 1;
  63                                 else if(prev_valid)
  64                                         return prev_valid;
  65                                 else
  66                                         switchtolast = 1;
  67                         }
  68                         prev_valid = weaponwant;
  69                 }
  70         }
  71         if(first_valid)
  72         {
  73                 if(switchtolast)
  74                         return prev_valid;
  75                 else
  76                         return first_valid;
  77         }
  78         // complain (but only for one weapon on the button that has been pressed)
  79         if(complain)
  80         {
  81                 self.weaponcomplainindex += 1;
  82                 c = mod(self.weaponcomplainindex, c) + 1;
  83                 rest = weaponorder;
  84                 while(rest != "")
  85                 {
  86                         weaponwant = stof(car(rest)); rest = cdr(rest);
  87                         if(imp >= 0)
  88                                 if((get_weaponinfo(weaponwant)).impulse != imp)
  89                                         continue;
  90
  91                         --c;
  92                         if(c == 0)
  93                         {
  94                                 client_hasweapon(pl, weaponwant, TRUE, TRUE);
  95                                 break;
  96                         }
  97                 }
  98         }
  99         return 0;
 100 }
 101
 102 void W_CycleWeapon(string weaponorder, float dir)
 103 {
 104         float w;
 105         w = W_GetCycleWeapon(self, weaponorder, dir, -1, 1, TRUE);
 106         if(w > 0)
 107                 W_SwitchWeapon(w);
 108 }
 109
 110 void W_NextWeaponOnImpulse(float imp)
 111 {
 112         float w;
 113         w = W_GetCycleWeapon(self, self.cvar_cl_weaponpriority, +1, imp, 1, (self.cvar_cl_weaponimpulsemode == 0));
 114         if(w > 0)
 115                 W_SwitchWeapon(w);
 116 }
 117
 118 // next weapon
 119 void W_NextWeapon(float list)
 120 {
 121         if(list == 0)
 122                 W_CycleWeapon(weaponorder_byid, -1);
 123         else if(list == 1)
 124                 W_CycleWeapon(self.weaponorder_byimpulse, -1);
 125         else if(list == 2)
 126                 W_CycleWeapon(self.cvar_cl_weaponpriority, -1);
 127 }
 128
 129 // prev weapon
 130 void W_PreviousWeapon(float list)
 131 {
 132         if(list == 0)
 133                 W_CycleWeapon(weaponorder_byid, +1);
 134         else if(list == 1)
 135                 W_CycleWeapon(self.weaponorder_byimpulse, +1);
 136         else if(list == 2)
 137                 W_CycleWeapon(self.cvar_cl_weaponpriority, +1);
 138 }
 139
 140 // previously used if exists and has ammo, (second) best otherwise
 141 void W_LastWeapon()
 142 {
 143         if(client_hasweapon(self, self.cnt, TRUE, FALSE))
 144                 W_SwitchWeapon(self.cnt);
 145         else
 146                 W_SwitchToOtherWeapon(self);
 147 }
 148
 149 float w_getbestweapon(entity e)
 150 {
 151         return W_GetCycleWeapon(e, e.cvar_cl_weaponpriority, 0, -1, FALSE, TRUE);
 152 }
 153
 154 // generic weapons table
 155 // TODO should they be macros instead?
 156 float weapon_action(float wpn, float wrequest)
 157 {
 158         return (get_weaponinfo(wpn)).weapon_func(wrequest);
 159 }
 160
 161 string W_Name(float weaponid)
 162 {
 163         return (get_weaponinfo(weaponid)).message;
 164 }
 165
 166 float W_WeaponBit(float wpn)
 167 {
 168         return (get_weaponinfo(wpn)).weapons;
 169 }
 170
 171 float W_AmmoItemCode(float wpn)
 172 {
 173         return (get_weaponinfo(wpn)).items & IT_AMMO;
 174 }
 175
 176 void thrown_wep_think()
 177 {
 178         self.solid = SOLID_TRIGGER;
 179         self.owner = world;
 180         SUB_SetFade(self, time + 20, 1);
 181 }
 182
 183 // returns amount of ammo used as string, or -1 for failure, or 0 for no ammo count
 184 string W_ThrowNewWeapon(entity own, float wpn, float doreduce, vector org, vector velo)
 185 {
 186         entity oldself, wep;
 187         float wa, thisammo, i, j;
 188         string s;
 189         var .float ammofield;
 190
 191         wep = spawn();
 192
 193         setorigin(wep, org);
 194         wep.classname = "droppedweapon";
 195         wep.velocity = velo;
 196         wep.owner = wep.enemy = own;
 197         wep.flags |= FL_TOSSED;
 198         wep.colormap = own.colormap;
 199
 200         wa = W_AmmoItemCode(wpn);
 201         if(wa == 0)
 202         {
 203                 oldself = self;
 204                 self = wep;
 205                 weapon_defaultspawnfunc(wpn);
 206                 self = oldself;
 207                 if(startitem_failed)
 208                         return string_null;
 209                 wep.glowmod = own.weaponentity_glowmod;
 210                 wep.think = thrown_wep_think;
 211                 wep.nextthink = time + 0.5;
 212                 return "";
 213         }
 214         else
 215         {
 216                 s = "";
 217                 oldself = self;
 218                 self = wep;
 219                 weapon_defaultspawnfunc(wpn);
 220                 self = oldself;
 221                 if(startitem_failed)
 222                         return string_null;
 223                 if(doreduce && g_weapon_stay == 2)
 224                 {
 225                         for(i = 0, j = 1; i < 24; ++i, j *= 2)
 226                         {
 227                                 if(wa & j)
 228                                 {
 229                                         ammofield = Item_CounterField(j);
 230                                         wep.ammofield = 0;
 231
 232                                         // if our weapon is loaded, give its load back to the player
 233                                         if(self.(weapon_load[self.weapon]) > 0)
 234                                         {
 235                                                 own.ammofield += self.(weapon_load[self.weapon]);
 236                                                 self.(weapon_load[self.weapon]) = -1; // schedule the weapon for reloading
 237                                         }
 238                                 }
 239                         }
 240                 }
 241                 else if(doreduce)
 242                 {
 243                         for(i = 0, j = 1; i < 24; ++i, j *= 2)
 244                         {
 245                                 if(wa & j)
 246                                 {
 247                                         ammofield = Item_CounterField(j);
 248                                         thisammo = min(own.ammofield, wep.ammofield);
 249                                         wep.ammofield = thisammo;
 250                                         own.ammofield -= thisammo;
 251                                         s = strcat(s, " and ", ftos(thisammo), " ", Item_CounterFieldName(j));
 252
 253                                         // if our weapon is loaded, give its load back to the player
 254                                         if(self.(weapon_load[self.weapon]) > 0)
 255                                         {
 256                                                 own.ammofield += self.(weapon_load[self.weapon]);
 257                                                 self.(weapon_load[self.weapon]) = -1; // schedule the weapon for reloading
 258                                         }
 259                                 }
 260                         }
 261                         s = substring(s, 5, -1);
 262                 }
 263                 wep.glowmod = own.weaponentity_glowmod;
 264                 wep.think = thrown_wep_think;
 265                 wep.nextthink = time + 0.5;
 266                 wep.pickup_anyway = TRUE; // these are ALWAYS pickable
 267                 return s;
 268         }
 269 }
 270
 271 float W_IsWeaponThrowable(float w)
 272 {
 273         float wb, wa;
 274
 275         if (!autocvar_g_pickup_items)
 276                 return 0;
 277         if (g_weaponarena)
 278                 return 0;
 279         if (g_lms)
 280                 return 0;
 281         if (g_ca)
 282                 return 0;
 283         if (g_cts)
 284                 return 0;
 285         if (g_nexball && w == WEP_GRENADE_LAUNCHER)
 286                 return 0;
 287
 288         wb = W_WeaponBit(w);
 289         if(!wb)
 290                 return 0;
 291         if(!g_minstagib)
 292                 if(wb & WEPBIT_SUPERWEAPONS) // can't throw a superweapon, they don't work
 293                         return 0;
 294         wa = W_AmmoItemCode(w);
 295         if(start_weapons & wb)
 296         {
 297                 // start weapons that take no ammo can't be dropped (this prevents dropping the laser, as long as it continues to use no ammo)
 298                 if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 299                         return 0;
 300                 if(wa == 0)
 301                         return 0;
 302         }
 303
 304         return 1;
 305 }
 306
 307 // toss current weapon
 308 void W_ThrowWeapon(vector velo, vector delta, float doreduce)
 309 {
 310         float w, wb;
 311         string a;
 312
 313         w = self.weapon;
 314         if (w == 0)
 315                 return; // just in case
 316         if(MUTATOR_CALLHOOK(ForbidThrowCurrentWeapon))
 317                 return;
 318         if(!autocvar_g_weapon_throwable)
 319                 return;
 320         if(self.weaponentity.state != WS_READY)
 321                 return;
 322         if(!W_IsWeaponThrowable(w))
 323                 return;
 324
 325         wb = W_WeaponBit(w);
 326         if(self.weapons & wb != wb)
 327                 return;
 328
 329         self.weapons &~= wb;
 330         W_SwitchWeapon_Force(self, w_getbestweapon(self));
 331         a = W_ThrowNewWeapon(self, w, doreduce, self.origin + delta, velo);
 332         if not(a)
 333                 return;
 334         if(a == "")
 335                 sprint(self, strcat("You dropped the ^2", W_Name(w), "\n"));
 336         else
 337                 sprint(self, strcat("You dropped the ^2", W_Name(w), " with ", a, "\n"));
 338 }
 339
 340 // Bringed back weapon frame
 341 void W_WeaponFrame()
 342 {
 343         vector fo, ri, up;
 344
 345         if (frametime)
 346                 self.weapon_frametime = frametime;
 347
 348         if(((arena_roundbased || g_ca || g_freezetag) && time < warmup) || ((time < game_starttime) && !autocvar_sv_ready_restart_after_countdown))
 349                 return;
 350
 351         if(self.freezetag_frozen == 1)
 352                 return;
 353
 354         if (!self.weaponentity || self.health < 1)
 355                 return; // Dead player can't use weapons and injure impulse commands
 356
 357         if(!self.switchweapon)
 358         {
 359                 self.weapon = 0;
 360                 self.switchingweapon = 0;
 361                 self.weaponentity.state = WS_CLEAR;
 362                 self.weaponname = "";
 363                 self.items &~= IT_AMMO;
 364                 return;
 365         }
 366
 367         makevectors(self.v_angle);
 368         fo = v_forward; // save them in case the weapon think functions change it
 369         ri = v_right;
 370         up = v_up;
 371
 372         // Change weapon
 373         if (self.weapon != self.switchweapon)
 374         {
 375                 if (self.weaponentity.state == WS_CLEAR)
 376                 {
 377                         // end switching!
 378                         self.switchingweapon = self.switchweapon;
 379
 380                         //setanim(self, self.anim_draw, FALSE, TRUE, TRUE);
 381                         self.weaponentity.state = WS_RAISE;
 382                         weapon_action(self.switchweapon, WR_SETUP);
 383
 384                         // set our clip load to the load of the weapon we switched to, if it's reloadable
 385                         entity e;
 386                         e = get_weaponinfo(self.switchweapon);
 387                         if(e.spawnflags & WEP_FLAG_RELOADABLE && cvar(strcat("g_balance_", e.netname, "_reload_ammo"))) // prevent accessing undefined cvars
 388                         {
 389                                 self.clip_load = self.(weapon_load[self.switchweapon]);
 390                                 self.clip_size = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 391                         }
 392                         else
 393                                 self.clip_load = self.clip_size = 0;
 394
 395                         // VorteX: add player model weapon select frame here
 396                         // setcustomframe(PlayerWeaponRaise);
 397                         weapon_thinkf(WFRAME_IDLE, autocvar_g_balance_weaponswitchdelay, w_ready);
 398                         weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, '0 0 0');
 399                 }
 400                 else if (self.weaponentity.state == WS_DROP)
 401                 {
 402                         // in dropping phase we can switch at any time
 403                         self.switchingweapon = self.switchweapon;
 404                 }
 405                 else if (self.weaponentity.state == WS_READY)
 406                 {
 407                         // start switching!
 408                         self.switchingweapon = self.switchweapon;
 409
 410 #ifndef INDEPENDENT_ATTACK_FINISHED
 411                         if(ATTACK_FINISHED(self) <= time + self.weapon_frametime * 0.5)
 412                         {
 413 #endif
 414                         sound (self, CH_WEAPON_SINGLE, "weapons/weapon_switch.wav", VOL_BASE, ATTN_NORM);
 415                         self.weaponentity.state = WS_DROP;
 416                         // set up weapon switch think in the future, and start drop anim
 417                         weapon_thinkf(WFRAME_DONTCHANGE, autocvar_g_balance_weaponswitchdelay, w_clear);
 418                         weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, PLAYER_WEAPONSELECTION_RANGE);
 419 #ifndef INDEPENDENT_ATTACK_FINISHED
 420                         }
 421 #endif
 422                 }
 423         }
 424
 425         // LordHavoc: network timing test code
 426         //if (self.button0)
 427         //      print(ftos(frametime), " ", ftos(time), " >= ", ftos(ATTACK_FINISHED(self)), " >= ", ftos(self.weapon_nextthink), "\n");
 428
 429         float wb;
 430         wb = W_WeaponBit(self.weapon);
 431
 432         // call the think code which may fire the weapon
 433         // and do so multiple times to resolve framerate dependency issues if the
 434         // server framerate is very low and the weapon fire rate very high
 435         float c;
 436         c = 0;
 437         while (c < W_TICSPERFRAME)
 438         {
 439                 c = c + 1;
 440                 if(wb && ((self.weapons & wb) == 0))
 441                 {
 442                         if(self.weapon == self.switchweapon)
 443                                 W_SwitchWeapon_Force(self, w_getbestweapon(self));
 444                         wb = 0;
 445                 }
 446
 447                 v_forward = fo;
 448                 v_right = ri;
 449                 v_up = up;
 450
 451                 if(wb)
 452                         weapon_action(self.weapon, WR_THINK);
 453                 else
 454                         weapon_action(self.weapon, WR_GONETHINK);
 455
 456                 if (time + self.weapon_frametime * 0.5 >= self.weapon_nextthink)
 457                 {
 458                         if(self.weapon_think)
 459                         {
 460                                 v_forward = fo;
 461                                 v_right = ri;
 462                                 v_up = up;
 463                                 self.weapon_think();
 464                         }
 465                         else
 466                                 bprint("\{1}^1ERROR: undefined weapon think function for ", self.netname, "\n");
 467                 }
 468         }
 469
 470         // don't let attack_finished fall behind when not firing (must be after weapon_setup calls!)
 471         //if (ATTACK_FINISHED(self) < time)
 472         //      ATTACK_FINISHED(self) = time;
 473
 474         //if (self.weapon_nextthink < time)
 475         //      self.weapon_nextthink = time;
 476
 477         // update currentammo incase it has changed
 478 #if 0
 479         if (self.items & IT_CELLS)
 480                 self.currentammo = self.ammo_cells;
 481         else if (self.items & IT_ROCKETS)
 482                 self.currentammo = self.ammo_rockets;
 483         else if (self.items & IT_NAILS)
 484                 self.currentammo = self.ammo_nails;
 485         else if (self.items & IT_SHELLS)
 486                 self.currentammo = self.ammo_shells;
 487         else
 488                 self.currentammo = 1;
 489 #endif
 490 }