qcsrc/server/bot/havocbot/havocbot.qc

   1 #include "havocbot.qh"
   2 #include "role_onslaught.qc"
   3 #include "role_keyhunt.qc"
   4 #include "role_freezetag.qc"
   5 #include "role_assault.qc"
   6 #include "roles.qc"
   7
   8 void havocbot_ai()
   9 {
  10         if(self.draggedby)
  11                 return;
  12
  13         if(bot_execute_commands())
  14                 return;
  15
  16         if (bot_strategytoken == self)
  17         if (!bot_strategytoken_taken)
  18         {
  19                 if(self.havocbot_blockhead)
  20                 {
  21                         self.havocbot_blockhead = FALSE;
  22                 }
  23                 else
  24                 {
  25                         if not(self.jumppadcount)
  26                                 self.havocbot_role();
  27                 }
  28
  29                 // TODO: tracewalk() should take care of this job (better path finding under water)
  30                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
  31                 if(self.deadflag != DEAD_NO)
  32                 if(self.goalcurrent==world)
  33                 if(self.waterlevel==WATERLEVEL_SWIMMING || self.aistatus & AI_STATUS_OUT_WATER)
  34                 {
  35                         // Look for the closest waypoint out of water
  36                         entity newgoal, head;
  37                         float bestdistance, distance;
  38
  39                         newgoal = world;
  40                         bestdistance = 10000;
  41                         for (head = findchain(classname, "waypoint"); head; head = head.chain)
  42                         {
  43                                 distance = vlen(head.origin - self.origin);
  44                                 if(distance>10000)
  45                                         continue;
  46
  47                                 if(head.origin_z < self.origin_z)
  48                                         continue;
  49
  50                                 if(head.origin_z - self.origin_z - self.view_ofs_z > 100)
  51                                         continue;
  52
  53                                 if (pointcontents(head.origin + head.maxs + '0 0 1') != CONTENT_EMPTY)
  54                                         continue;
  55
  56                                 traceline(self.origin + self.view_ofs , head.origin, TRUE, head);
  57
  58                                 if(trace_fraction<1)
  59                                         continue;
  60
  61                                 if(distance<bestdistance)
  62                                 {
  63                                         newgoal = head;
  64                                         bestdistance = distance;
  65                                 }
  66                         }
  67
  68                         if(newgoal)
  69                         {
  70                         //      te_wizspike(newgoal.origin);
  71                                 navigation_pushroute(newgoal);
  72                         }
  73                 }
  74
  75                 // token has been used this frame
  76                 bot_strategytoken_taken = TRUE;
  77         }
  78
  79         if(self.deadflag != DEAD_NO)
  80                 return;
  81
  82         havocbot_chooseenemy();
  83         if (self.bot_chooseweapontime < time )
  84         {
  85                 self.bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
  86                 havocbot_chooseweapon();
  87         }
  88         havocbot_aim();
  89         lag_update();
  90         if (self.bot_aimtarg)
  91         {
  92                 self.aistatus |= AI_STATUS_ATTACKING;
  93                 self.aistatus &~= AI_STATUS_ROAMING;
  94
  95                 if(!WEPSET_EMPTY_E(self))
  96                 {
  97                         weapon_action(self.weapon, WR_AIM);
  98                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(self))
  99                         {
 100                                 self.BUTTON_ATCK = FALSE;
 101                                 self.BUTTON_ATCK2 = FALSE;
 102                         }
 103                         else
 104                         {
 105                                 if(self.BUTTON_ATCK||self.BUTTON_ATCK2)
 106                                         self.lastfiredweapon = self.weapon;
 107                         }
 108                 }
 109                 else
 110                 {
 111                         if(self.bot_aimtarg.classname=="player")
 112                                 bot_aimdir(self.bot_aimtarg.origin + self.bot_aimtarg.view_ofs - self.origin - self.view_ofs , -1);
 113                 }
 114         }
 115         else if (self.goalcurrent)
 116         {
 117                 self.aistatus |= AI_STATUS_ROAMING;
 118                 self.aistatus &~= AI_STATUS_ATTACKING;
 119
 120                 vector now,v,next;//,heading;
 121                 float aimdistance,skillblend,distanceblend,blend;
 122                 next = now = ( (self.goalcurrent.absmin + self.goalcurrent.absmax) * 0.5) - (self.origin + self.view_ofs);
 123                 aimdistance = vlen(now);
 124                 //heading = self.velocity;
 125                 //dprint(self.goalstack01.classname,etos(self.goalstack01),"\n");
 126                 if(
 127                         self.goalstack01 != self && self.goalstack01 != world && self.aistatus & AI_STATUS_RUNNING == 0 &&
 128                         !(self.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 129                 )
 130                         next = ((self.goalstack01.absmin + self.goalstack01.absmax) * 0.5) - (self.origin + self.view_ofs);
 131
 132                 skillblend=bound(0,(skill+self.bot_moveskill-2.5)*0.5,1); //lower skill player can't preturn
 133                 distanceblend=bound(0,aimdistance/autocvar_bot_ai_keyboard_distance,1);
 134                 blend = skillblend * (1-distanceblend);
 135                 //v = (now * (distanceblend) + next * (1-distanceblend)) * (skillblend) + now * (1-skillblend);
 136                 //v = now * (distanceblend) * (skillblend) + next * (1-distanceblend) * (skillblend) + now * (1-skillblend);
 137                 //v = now * ((1-skillblend) + (distanceblend) * (skillblend)) + next * (1-distanceblend) * (skillblend);
 138                 v = now + blend * (next - now);
 139                 //dprint(etos(self), " ");
 140                 //dprint(vtos(now), ":", vtos(next), "=", vtos(v), " (blend ", ftos(blend), ")\n");
 141                 //v = now * (distanceblend) + next * (1-distanceblend);
 142                 if (self.waterlevel < WATERLEVEL_SWIMMING)
 143                         v_z = 0;
 144                 //dprint("walk at:", vtos(v), "\n");
 145                 //te_lightning2(world, self.origin, self.goalcurrent.origin);
 146                 bot_aimdir(v, -1);
 147         }
 148         havocbot_movetogoal();
 149
 150         // if the bot is not attacking, consider reloading weapons
 151         if not(self.aistatus & AI_STATUS_ATTACKING)
 152         {
 153                 float i;
 154                 entity e;
 155
 156                 // we are currently holding a weapon that's not fully loaded, reload it
 157                 if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
 158                 if(self.clip_load < self.clip_size)
 159                         self.impulse = 20; // "press" the reload button, not sure if this is done right
 160
 161                 // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
 162                 // the code above executes next frame, starting the reloading then
 163                 if(skill >= 5) // bots can only look for unloaded weapons past this skill
 164                 if(self.clip_load >= 0) // only if we're not reloading a weapon already
 165                 {
 166                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 167                         {
 168                                 e = get_weaponinfo(i);
 169                                 if (WEPSET_CONTAINS_EW(self, i) && (e.spawnflags & WEP_FLAG_RELOADABLE) && (self.weapon_load[i] < cvar(strcat("g_balance_", e.netname, "_reload_ammo"))))
 170                                         self.switchweapon = i;
 171                         }
 172                 }
 173         }
 174 }
 175
 176 void havocbot_keyboard_movement(vector destorg)
 177 {
 178         vector keyboard;
 179         float blend, maxspeed;
 180         float sk;
 181
 182         sk = skill + self.bot_moveskill;
 183
 184         maxspeed = autocvar_sv_maxspeed;
 185
 186         if (time < self.havocbot_keyboardtime)
 187                 return;
 188
 189         self.havocbot_keyboardtime =
 190                 max(
 191                         self.havocbot_keyboardtime
 192                                 + 0.05/max(1, sk+self.havocbot_keyboardskill)
 193                                 + random()*0.025/max(0.00025, skill+self.havocbot_keyboardskill)
 194                 , time);
 195         keyboard = self.movement * (1.0 / maxspeed);
 196
 197         float trigger, trigger1;
 198         blend = bound(0,sk*0.1,1);
 199         trigger = autocvar_bot_ai_keyboard_threshold;
 200         trigger1 = 0 - trigger;
 201
 202         // categorize forward movement
 203         // at skill < 1.5 only forward
 204         // at skill < 2.5 only individual directions
 205         // at skill < 4.5 only individual directions, and forward diagonals
 206         // at skill >= 4.5, all cases allowed
 207         if (keyboard_x > trigger)
 208         {
 209                 keyboard_x = 1;
 210                 if (sk < 2.5)
 211                         keyboard_y = 0;
 212         }
 213         else if (keyboard_x < trigger1 && sk > 1.5)
 214         {
 215                 keyboard_x = -1;
 216                 if (sk < 4.5)
 217                         keyboard_y = 0;
 218         }
 219         else
 220         {
 221                 keyboard_x = 0;
 222                 if (sk < 1.5)
 223                         keyboard_y = 0;
 224         }
 225         if (sk < 4.5)
 226                 keyboard_z = 0;
 227
 228         if (keyboard_y > trigger)
 229                 keyboard_y = 1;
 230         else if (keyboard_y < trigger1)
 231                 keyboard_y = -1;
 232         else
 233                 keyboard_y = 0;
 234
 235         if (keyboard_z > trigger)
 236                 keyboard_z = 1;
 237         else if (keyboard_z < trigger1)
 238                 keyboard_z = -1;
 239         else
 240                 keyboard_z = 0;
 241
 242         self.havocbot_keyboard = keyboard * maxspeed;
 243         if (self.havocbot_ducktime>time) self.BUTTON_CROUCH=TRUE;
 244
 245         keyboard = self.havocbot_keyboard;
 246         blend = bound(0,vlen(destorg-self.origin)/autocvar_bot_ai_keyboard_distance,1); // When getting close move with 360 degree
 247         //dprint("movement ", vtos(self.movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 248         self.movement = self.movement + (keyboard - self.movement) * blend;
 249 }
 250
 251 void havocbot_bunnyhop(vector dir)
 252 {
 253         float bunnyhopdistance;
 254         vector deviation;
 255         float maxspeed;
 256         vector gco, gno;
 257
 258         if(autocvar_g_midair)
 259                 return;
 260
 261         // Don't jump when attacking
 262         if(self.aistatus & AI_STATUS_ATTACKING)
 263                 return;
 264
 265         if(self.goalcurrent.classname == "player")
 266                 return;
 267
 268         maxspeed = autocvar_sv_maxspeed;
 269
 270         if(self.aistatus & AI_STATUS_DANGER_AHEAD)
 271         {
 272                 self.aistatus &~= AI_STATUS_RUNNING;
 273                 self.BUTTON_JUMP = FALSE;
 274                 self.bot_canruntogoal = 0;
 275                 self.bot_timelastseengoal = 0;
 276                 return;
 277         }
 278
 279         if(self.waterlevel > WATERLEVEL_WETFEET)
 280         {
 281                 self.aistatus &~= AI_STATUS_RUNNING;
 282                 return;
 283         }
 284
 285         if(self.bot_lastseengoal != self.goalcurrent && !(self.aistatus & AI_STATUS_RUNNING))
 286         {
 287                 self.bot_canruntogoal = 0;
 288                 self.bot_timelastseengoal = 0;
 289         }
 290
 291         gco = (self.goalcurrent.absmin + self.goalcurrent.absmax) * 0.5;
 292         bunnyhopdistance = vlen(self.origin - gco);
 293
 294         // Run only to visible goals
 295         if(self.flags & FL_ONGROUND)
 296         if(self.speed==maxspeed)
 297         if(checkpvs(self.origin + self.view_ofs, self.goalcurrent))
 298         {
 299                         self.bot_lastseengoal = self.goalcurrent;
 300
 301                         // seen it before
 302                         if(self.bot_timelastseengoal)
 303                         {
 304                                 // for a period of time
 305                                 if(time - self.bot_timelastseengoal > autocvar_bot_ai_bunnyhop_firstjumpdelay)
 306                                 {
 307                                         float checkdistance;
 308                                         checkdistance = TRUE;
 309
 310                                         // don't run if it is too close
 311                                         if(self.bot_canruntogoal==0)
 312                                         {
 313                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_startdistance)
 314                                                         self.bot_canruntogoal = 1;
 315                                                 else
 316                                                         self.bot_canruntogoal = -1;
 317                                         }
 318
 319                                         if(self.bot_canruntogoal != 1)
 320                                                 return;
 321
 322                                         if(self.aistatus & AI_STATUS_ROAMING)
 323                                         if(self.goalcurrent.classname=="waypoint")
 324                                         if not(self.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL)
 325                                         if(fabs(gco_z - self.origin_z) < self.maxs_z - self.mins_z)
 326                                         if(self.goalstack01!=world)
 327                                         {
 328                                                 gno = (self.goalstack01.absmin + self.goalstack01.absmax) * 0.5;
 329                                                 deviation = vectoangles(gno - self.origin) - vectoangles(gco - self.origin);
 330                                                 while (deviation_y < -180) deviation_y = deviation_y + 360;
 331                                                 while (deviation_y > 180) deviation_y = deviation_y - 360;
 332
 333                                                 if(fabs(deviation_y) < 20)
 334                                                 if(bunnyhopdistance < vlen(self.origin - gno))
 335                                                 if(fabs(gno_z - gco_z) < self.maxs_z - self.mins_z)
 336                                                 {
 337                                                         if(vlen(gco - gno) > autocvar_bot_ai_bunnyhop_startdistance)
 338                                                         if(checkpvs(self.origin + self.view_ofs, self.goalstack01))
 339                                                         {
 340                                                                 checkdistance = FALSE;
 341                                                         }
 342                                                 }
 343                                         }
 344
 345                                         if(checkdistance)
 346                                         {
 347                                                 self.aistatus &~= AI_STATUS_RUNNING;
 348                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_stopdistance)
 349                                                         self.BUTTON_JUMP = TRUE;
 350                                         }
 351                                         else
 352                                         {
 353                                                 self.aistatus |= AI_STATUS_RUNNING;
 354                                                 self.BUTTON_JUMP = TRUE;
 355                                         }
 356                                 }
 357                         }
 358                         else
 359                         {
 360                                 self.bot_timelastseengoal = time;
 361                         }
 362         }
 363         else
 364         {
 365                 self.bot_timelastseengoal = 0;
 366         }
 367
 368 #if 0
 369         // Release jump button
 370         if(!cvar("sv_pogostick"))
 371         if(self.flags & FL_ONGROUND == 0)
 372         {
 373                 if(self.velocity_z < 0 || vlen(self.velocity)<maxspeed)
 374                         self.BUTTON_JUMP = FALSE;
 375
 376                 // Strafe
 377                 if(self.aistatus & AI_STATUS_RUNNING)
 378                 if(vlen(self.velocity)>maxspeed)
 379                 {
 380                         deviation = vectoangles(dir) - vectoangles(self.velocity);
 381                         while (deviation_y < -180) deviation_y = deviation_y + 360;
 382                         while (deviation_y > 180) deviation_y = deviation_y - 360;
 383
 384                         if(fabs(deviation_y)>10)
 385                                 self.movement_x = 0;
 386
 387                         if(deviation_y>10)
 388                                 self.movement_y = maxspeed * -1;
 389                         else if(deviation_y<10)
 390                                 self.movement_y = maxspeed;
 391
 392                 }
 393         }
 394 #endif
 395 }
 396
 397 void havocbot_movetogoal()
 398 {
 399         vector destorg;
 400         vector diff;
 401         vector dir;
 402         vector flatdir;
 403         vector m1;
 404         vector m2;
 405         vector evadeobstacle;
 406         vector evadelava;
 407         float s;
 408         float maxspeed;
 409         vector gco;
 410         //float dist;
 411         vector dodge;
 412         //if (self.goalentity)
 413         //      te_lightning2(self, self.origin, (self.goalentity.absmin + self.goalentity.absmax) * 0.5);
 414         self.movement = '0 0 0';
 415         maxspeed = autocvar_sv_maxspeed;
 416
 417         // Jetpack navigation
 418         if(self.goalcurrent)
 419         if(self.navigation_jetpack_goal)
 420         if(self.goalcurrent==self.navigation_jetpack_goal)
 421         if(self.ammo_fuel)
 422         {
 423                 if(autocvar_bot_debug_goalstack)
 424                 {
 425                         debuggoalstack();
 426                         te_wizspike(self.navigation_jetpack_point);
 427                 }
 428
 429                 // Take off
 430                 if not(self.aistatus & AI_STATUS_JETPACK_FLYING)
 431                 {
 432                         // Brake almost completely so it can get a good direction
 433                         if(vlen(self.velocity)>10)
 434                                 return;
 435                         self.aistatus |= AI_STATUS_JETPACK_FLYING;
 436                 }
 437
 438                 makevectors(self.v_angle_y * '0 1 0');
 439                 dir = normalize(self.navigation_jetpack_point - self.origin);
 440
 441                 // Landing
 442                 if(self.aistatus & AI_STATUS_JETPACK_LANDING)
 443                 {
 444                         // Calculate brake distance in xy
 445                         float db, v, d;
 446                         vector dxy;
 447
 448                         dxy = self.origin - ( ( self.goalcurrent.absmin + self.goalcurrent.absmax ) * 0.5 ); dxy_z = 0;
 449                         d = vlen(dxy);
 450                         v = vlen(self.velocity -  self.velocity_z * '0 0 1');
 451                         db = (pow(v,2) / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
 452                 //      dprint("distance ", ftos(ceil(d)), " velocity ", ftos(ceil(v)), " brake at ", ftos(ceil(db)), "\n");
 453                         if(d < db || d < 500)
 454                         {
 455                                 // Brake
 456                                 if(fabs(self.velocity_x)>maxspeed*0.3)
 457                                 {
 458                                         self.movement_x = dir * v_forward * -maxspeed;
 459                                         return;
 460                                 }
 461                                 // Switch to normal mode
 462                                 self.navigation_jetpack_goal = world;
 463                                 self.aistatus &~= AI_STATUS_JETPACK_LANDING;
 464                                 self.aistatus &~= AI_STATUS_JETPACK_FLYING;
 465                                 return;
 466                         }
 467                 }
 468                 else if(checkpvs(self.origin,self.goalcurrent))
 469                 {
 470                         // If I can see the goal switch to landing code
 471                         self.aistatus &~= AI_STATUS_JETPACK_FLYING;
 472                         self.aistatus |= AI_STATUS_JETPACK_LANDING;
 473                         return;
 474                 }
 475
 476                 // Flying
 477                 self.BUTTON_HOOK = TRUE;
 478                 if(self.navigation_jetpack_point_z - PL_MAX_z + PL_MIN_z < self.origin_z)
 479                 {
 480                         self.movement_x = dir * v_forward * maxspeed;
 481                         self.movement_y = dir * v_right * maxspeed;
 482                 }
 483                 return;
 484         }
 485
 486         // Handling of jump pads
 487         if(self.jumppadcount)
 488         {
 489                 // If got stuck on the jump pad try to reach the farthest visible waypoint
 490                 if(self.aistatus & AI_STATUS_OUT_JUMPPAD)
 491                 {
 492                         if(fabs(self.velocity_z)<50)
 493                         {
 494                                 entity head, newgoal = world;
 495                                 float distance, bestdistance = 0;
 496
 497                                 for (head = findchain(classname, "waypoint"); head; head = head.chain)
 498                                 {
 499
 500                                         distance = vlen(head.origin - self.origin);
 501                                         if(distance>1000)
 502                                                 continue;
 503
 504                                         traceline(self.origin + self.view_ofs , ( ( head.absmin + head.absmax ) * 0.5 ), TRUE, world);
 505
 506                                         if(trace_fraction<1)
 507                                                 continue;
 508
 509                                         if(distance>bestdistance)
 510                                         {
 511                                                 newgoal = head;
 512                                                 bestdistance = distance;
 513                                         }
 514                                 }
 515
 516                                 if(newgoal)
 517                                 {
 518                                         self.ignoregoal = self.goalcurrent;
 519                                         self.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 520                                         navigation_clearroute();
 521                                         navigation_routetogoal(newgoal, self.origin);
 522                                         self.aistatus &~= AI_STATUS_OUT_JUMPPAD;
 523                                 }
 524                         }
 525                         else
 526                                 return;
 527                 }
 528                 else
 529                 {
 530                         if(self.velocity_z>0)
 531                         {
 532                                 float threshold, sxy;
 533                                 vector velxy = self.velocity; velxy_z = 0;
 534                                 sxy = vlen(velxy);
 535                                 threshold = maxspeed * 0.2;
 536                                 if(sxy < threshold)
 537                                 {
 538                                         dprint("Warning: ", self.netname, " got stuck on a jumppad (velocity in xy is ", ftos(sxy), "), trying to get out of it now\n");
 539                                         self.aistatus |= AI_STATUS_OUT_JUMPPAD;
 540                                 }
 541                                 return;
 542                         }
 543
 544                         // Don't chase players while using a jump pad
 545                         if(self.goalcurrent.classname=="player" || self.goalstack01.classname=="player")
 546                                 return;
 547                 }
 548         }
 549         else if(self.aistatus & AI_STATUS_OUT_JUMPPAD)
 550                 self.aistatus &~= AI_STATUS_OUT_JUMPPAD;
 551
 552         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 553         if(skill>6)
 554         if not(self.flags & FL_ONGROUND)
 555         {
 556                 tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 -65536', MOVE_NOMONSTERS, self);
 557                 if(tracebox_hits_trigger_hurt(self.origin, self.mins, self.maxs, trace_endpos ))
 558                 if(self.items & IT_JETPACK)
 559                 {
 560                         tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 65536', MOVE_NOMONSTERS, self);
 561                         if(tracebox_hits_trigger_hurt(self.origin, self.mins, self.maxs, trace_endpos + '0 0 1' ))
 562                         {
 563                                 if(self.velocity_z<0)
 564                                 {
 565                                         self.BUTTON_HOOK = TRUE;
 566                                 }
 567                         }
 568                         else
 569                                 self.BUTTON_HOOK = TRUE;
 570
 571                         // If there is no goal try to move forward
 572
 573                         if(self.goalcurrent==world)
 574                                 dir = v_forward;
 575                         else
 576                                 dir = normalize(( ( self.goalcurrent.absmin + self.goalcurrent.absmax ) * 0.5 ) - self.origin);
 577
 578                         vector xyvelocity = self.velocity; xyvelocity_z = 0;
 579                         float xyspeed = xyvelocity * dir;
 580
 581                         if(xyspeed < (maxspeed / 2))
 582                         {
 583                                 makevectors(self.v_angle_y * '0 1 0');
 584                                 tracebox(self.origin, self.mins, self.maxs, self.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, self);
 585                                 if(trace_fraction==1)
 586                                 {
 587                                         self.movement_x = dir * v_forward * maxspeed;
 588                                         self.movement_y = dir * v_right * maxspeed;
 589                                         if (skill < 10)
 590                                                 havocbot_keyboard_movement(self.origin + dir * 100);
 591                                 }
 592                         }
 593
 594                         self.havocbot_blockhead = TRUE;
 595
 596                         return;
 597                 }
 598                 else if(self.health>autocvar_g_balance_rocketlauncher_damage*0.5)
 599                 {
 600                         if(self.velocity_z < 0)
 601                         if(client_hasweapon(self, WEP_ROCKET_LAUNCHER, TRUE, FALSE))
 602                         {
 603                                 self.movement_x = maxspeed;
 604
 605                                 if(self.rocketjumptime)
 606                                 {
 607                                         if(time > self.rocketjumptime)
 608                                         {
 609                                                 self.BUTTON_ATCK2 = TRUE;
 610                                                 self.rocketjumptime = 0;
 611                                         }
 612                                         return;
 613                                 }
 614
 615                                 self.switchweapon = WEP_ROCKET_LAUNCHER;
 616                                 self.v_angle_x = 90;
 617                                 self.BUTTON_ATCK = TRUE;
 618                                 self.rocketjumptime = time + autocvar_g_balance_rocketlauncher_detonatedelay;
 619                                 return;
 620                         }
 621                 }
 622                 else
 623                 {
 624                         // If there is no goal try to move forward
 625                         if(self.goalcurrent==world)
 626                                 self.movement_x = maxspeed;
 627                 }
 628         }
 629
 630         // If we are under water with no goals, swim up
 631         if(self.waterlevel)
 632         if(self.goalcurrent==world)
 633         {
 634                 dir = '0 0 0';
 635                 if(self.waterlevel>WATERLEVEL_SWIMMING)
 636                         dir_z = 1;
 637                 else if(self.velocity_z >= 0 && !(self.waterlevel == WATERLEVEL_WETFEET && self.watertype == CONTENT_WATER))
 638                         self.BUTTON_JUMP = TRUE;
 639                 else
 640                         self.BUTTON_JUMP = FALSE;
 641                 makevectors(self.v_angle_y * '0 1 0');
 642                 self.movement_x = dir * v_forward * maxspeed;
 643                 self.movement_y = dir * v_right * maxspeed;
 644                 self.movement_z = dir * v_up * maxspeed;
 645         }
 646
 647         // if there is nowhere to go, exit
 648         if (self.goalcurrent == world)
 649                 return;
 650
 651         if (self.goalcurrent)
 652                 navigation_poptouchedgoals();
 653
 654         // if ran out of goals try to use an alternative goal or get a new strategy asap
 655         if(self.goalcurrent == world)
 656         {
 657                 self.bot_strategytime = 0;
 658                 return;
 659         }
 660
 661
 662         if(autocvar_bot_debug_goalstack)
 663                 debuggoalstack();
 664
 665         m1 = self.goalcurrent.origin + self.goalcurrent.mins;
 666         m2 = self.goalcurrent.origin + self.goalcurrent.maxs;
 667         destorg = self.origin;
 668         destorg_x = bound(m1_x, destorg_x, m2_x);
 669         destorg_y = bound(m1_y, destorg_y, m2_y);
 670         destorg_z = bound(m1_z, destorg_z, m2_z);
 671         diff = destorg - self.origin;
 672         //dist = vlen(diff);
 673         dir = normalize(diff);
 674         flatdir = diff;flatdir_z = 0;
 675         flatdir = normalize(flatdir);
 676         gco = (self.goalcurrent.absmin + self.goalcurrent.absmax) * 0.5;
 677
 678         //if (self.bot_dodgevector_time < time)
 679         {
 680         //      self.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 681         //      self.bot_dodgevector_jumpbutton = 1;
 682                 evadeobstacle = '0 0 0';
 683                 evadelava = '0 0 0';
 684
 685                 if (self.waterlevel)
 686                 {
 687                         if(self.waterlevel>WATERLEVEL_SWIMMING)
 688                         {
 689                         //      flatdir_z = 1;
 690                                 self.aistatus |= AI_STATUS_OUT_WATER;
 691                         }
 692                         else
 693                         {
 694                                 if(self.velocity_z >= 0 && !(self.watertype == CONTENT_WATER && gco_z < self.origin_z) &&
 695                                         ( !(self.waterlevel == WATERLEVEL_WETFEET && self.watertype == CONTENT_WATER) || self.aistatus & AI_STATUS_OUT_WATER))
 696                                         self.BUTTON_JUMP = TRUE;
 697                                 else
 698                                         self.BUTTON_JUMP = FALSE;
 699                         }
 700                         dir = normalize(flatdir);
 701                         makevectors(self.v_angle_y * '0 1 0');
 702                 }
 703                 else
 704                 {
 705                         if(self.aistatus & AI_STATUS_OUT_WATER)
 706                                 self.aistatus &~= AI_STATUS_OUT_WATER;
 707
 708                         // jump if going toward an obstacle that doesn't look like stairs we
 709                         // can walk up directly
 710                         tracebox(self.origin, self.mins, self.maxs, self.origin + self.velocity * 0.2, FALSE, self);
 711                         if (trace_fraction < 1)
 712                         if (trace_plane_normal_z < 0.7)
 713                         {
 714                                 s = trace_fraction;
 715                                 tracebox(self.origin + stepheightvec, self.mins, self.maxs, self.origin + self.velocity * 0.2 + stepheightvec, FALSE, self);
 716                                 if (trace_fraction < s + 0.01)
 717                                 if (trace_plane_normal_z < 0.7)
 718                                 {
 719                                         s = trace_fraction;
 720                                         tracebox(self.origin + jumpstepheightvec, self.mins, self.maxs, self.origin + self.velocity * 0.2 + jumpstepheightvec, FALSE, self);
 721                                         if (trace_fraction > s)
 722                                                 self.BUTTON_JUMP = 1;
 723                                 }
 724                         }
 725
 726                         // avoiding dangers and obstacles
 727                         vector dst_ahead, dst_down;
 728                         makevectors(self.v_angle_y * '0 1 0');
 729                         dst_ahead = self.origin + self.view_ofs + (self.velocity * 0.4) + (v_forward * 32 * 3);
 730                         dst_down = dst_ahead + '0 0 -1500';
 731
 732                         // Look ahead
 733                         traceline(self.origin + self.view_ofs , dst_ahead, TRUE, world);
 734
 735                         // Check head-banging against walls
 736                         if(vlen(self.origin + self.view_ofs - trace_endpos) < 25 && !(self.aistatus & AI_STATUS_OUT_WATER))
 737                         {
 738                                 self.BUTTON_JUMP = TRUE;
 739                                 if(self.facingwalltime && time > self.facingwalltime)
 740                                 {
 741                                         self.ignoregoal = self.goalcurrent;
 742                                         self.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 743                                         self.bot_strategytime = 0;
 744                                         return;
 745                                 }
 746                                 else
 747                                 {
 748                                         self.facingwalltime = time + 0.05;
 749                                 }
 750                         }
 751                         else
 752                         {
 753                                 self.facingwalltime = 0;
 754
 755                                 if(self.ignoregoal != world && time > self.ignoregoaltime)
 756                                 {
 757                                         self.ignoregoal = world;
 758                                         self.ignoregoaltime = 0;
 759                                 }
 760                         }
 761
 762                         // Check for water/slime/lava and dangerous edges
 763                         // (only when the bot is on the ground or jumping intentionally)
 764                         self.aistatus &~= AI_STATUS_DANGER_AHEAD;
 765
 766                         if(trace_fraction == 1 && self.jumppadcount == 0 && !self.goalcurrent.wphardwired )
 767                         if(self.flags & FL_ONGROUND || self.aistatus & AI_STATUS_RUNNING || self.BUTTON_JUMP == TRUE)
 768                         {
 769                                 // Look downwards
 770                                 traceline(dst_ahead , dst_down, TRUE, world);
 771                         //      te_lightning2(world, self.origin, dst_ahead);   // Draw "ahead" look
 772                         //      te_lightning2(world, dst_ahead, dst_down);              // Draw "downwards" look
 773                                 if(trace_endpos_z < self.origin_z + self.mins_z)
 774                                 {
 775                                         s = pointcontents(trace_endpos + '0 0 1');
 776                                         if (s != CONTENT_SOLID)
 777                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
 778                                                 evadelava = normalize(self.velocity) * -1;
 779                                         else if (s == CONTENT_SKY)
 780                                                 evadeobstacle = normalize(self.velocity) * -1;
 781                                         else if (!boxesoverlap(dst_ahead - self.view_ofs + self.mins, dst_ahead - self.view_ofs + self.maxs,
 782                                                                 self.goalcurrent.absmin, self.goalcurrent.absmax))
 783                                         {
 784                                                 // if ain't a safe goal with "holes" (like the jumpad on soylent)
 785                                                 // and there is a trigger_hurt below
 786                                                 if(tracebox_hits_trigger_hurt(dst_ahead, self.mins, self.maxs, trace_endpos))
 787                                                 {
 788                                                         // Remove dangerous dynamic goals from stack
 789                                                         dprint("bot ", self.netname, " avoided the goal ", self.goalcurrent.classname, " ", etos(self.goalcurrent), " because it led to a dangerous path; goal stack cleared\n");
 790                                                         navigation_clearroute();
 791                                                         return;
 792                                                 }
 793                                         }
 794                                 }
 795                         }
 796
 797                         dir = flatdir;
 798                         evadeobstacle_z = 0;
 799                         evadelava_z = 0;
 800                         makevectors(self.v_angle_y * '0 1 0');
 801
 802                         if(evadeobstacle!='0 0 0'||evadelava!='0 0 0')
 803                                 self.aistatus |= AI_STATUS_DANGER_AHEAD;
 804                 }
 805
 806                 dodge = havocbot_dodge();
 807                 dodge = dodge * bound(0,0.5+(skill+self.bot_dodgeskill)*0.1,1);
 808                 evadelava = evadelava * bound(1,3-(skill+self.bot_dodgeskill),3); //Noobs fear lava a lot and take more distance from it
 809                 traceline(self.origin, ( ( self.enemy.absmin + self.enemy.absmax ) * 0.5 ), TRUE, world);
 810                 if(trace_ent.classname == "player")
 811                         dir = dir * bound(0,(skill+self.bot_dodgeskill)/7,1);
 812
 813                 dir = normalize(dir + dodge + evadeobstacle + evadelava);
 814         //      self.bot_dodgevector = dir;
 815         //      self.bot_dodgevector_jumpbutton = self.BUTTON_JUMP;
 816         }
 817
 818         if(time < self.ladder_time)
 819         {
 820                 if(self.goalcurrent.origin_z + self.goalcurrent.mins_z > self.origin_z + self.mins_z)
 821                 {
 822                         if(self.origin_z + self.mins_z  < self.ladder_entity.origin_z + self.ladder_entity.maxs_z)
 823                                 dir_z = 1;
 824                 }
 825                 else
 826                 {
 827                         if(self.origin_z + self.mins_z  > self.ladder_entity.origin_z + self.ladder_entity.mins_z)
 828                                 dir_z = -1;
 829                 }
 830         }
 831
 832         //dir = self.bot_dodgevector;
 833         //if (self.bot_dodgevector_jumpbutton)
 834         //      self.BUTTON_JUMP = 1;
 835         self.movement_x = dir * v_forward * maxspeed;
 836         self.movement_y = dir * v_right * maxspeed;
 837         self.movement_z = dir * v_up * maxspeed;
 838
 839         // Emulate keyboard interface
 840         if (skill < 10)
 841                 havocbot_keyboard_movement(destorg);
 842
 843         // Bunnyhop!
 844 //      if(self.aistatus & AI_STATUS_ROAMING)
 845         if(self.goalcurrent)
 846         if(skill+self.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
 847                 havocbot_bunnyhop(dir);
 848
 849         if ((dir * v_up) >= autocvar_sv_jumpvelocity*0.5 && (self.flags & FL_ONGROUND)) self.BUTTON_JUMP=1;
 850         if (((dodge * v_up) > 0) && random()*frametime >= 0.2*bound(0,(10-skill-self.bot_dodgeskill)*0.1,1)) self.BUTTON_JUMP=TRUE;
 851         if (((dodge * v_up) < 0) && random()*frametime >= 0.5*bound(0,(10-skill-self.bot_dodgeskill)*0.1,1)) self.havocbot_ducktime=time+0.3/bound(0.1,skill+self.bot_dodgeskill,10);
 852 }
 853
 854 void havocbot_chooseenemy()
 855 {
 856         entity head, best, head2;
 857         float rating, bestrating, i, hf;
 858         vector eye, v;
 859         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(self))
 860         {
 861                 self.enemy = world;
 862                 return;
 863         }
 864         if (self.enemy)
 865         {
 866                 if (!bot_shouldattack(self.enemy))
 867                 {
 868                         // enemy died or something, find a new target
 869                         self.enemy = world;
 870                         self.havocbot_chooseenemy_finished = time;
 871                 }
 872                 else if (self.havocbot_stickenemy)
 873                 {
 874                         // tracking last chosen enemy
 875                         // if enemy is visible
 876                         // and not really really far away
 877                         // and we're not severely injured
 878                         // then keep tracking for a half second into the future
 879                         traceline(self.origin+self.view_ofs, ( self.enemy.absmin + self.enemy.absmax ) * 0.5,FALSE,world);
 880                         if (trace_ent == self.enemy || trace_fraction == 1)
 881                         if (vlen((( self.enemy.absmin + self.enemy.absmax ) * 0.5) - self.origin) < 1000)
 882                         if (self.health > 30)
 883                         {
 884                                 // remain tracking him for a shot while (case he went after a small corner or pilar
 885                                 self.havocbot_chooseenemy_finished = time + 0.5;
 886                                 return;
 887                         }
 888                         // enemy isn't visible, or is far away, or we're injured severely
 889                         // so stop preferring this enemy
 890                         // (it will still take a half second until a new one is chosen)
 891                         self.havocbot_stickenemy = 0;
 892                 }
 893         }
 894         if (time < self.havocbot_chooseenemy_finished)
 895                 return;
 896         self.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
 897         eye = self.origin + self.view_ofs;
 898         best = world;
 899         bestrating = 100000000;
 900         head = head2 = findchainfloat(bot_attack, TRUE);
 901
 902         // Backup hit flags
 903         hf = self.dphitcontentsmask;
 904
 905         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
 906
 907         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 908
 909         for(i = 0; ; ++i)
 910         {
 911                 while (head)
 912                 {
 913                         v = (head.absmin + head.absmax) * 0.5;
 914                         rating = vlen(v - eye);
 915                         if (rating<autocvar_bot_ai_enemydetectionradius)
 916                         if (bestrating > rating)
 917                         if (bot_shouldattack(head))
 918                         {
 919                                 traceline(eye, v, TRUE, self);
 920                                 if (trace_ent == head || trace_fraction >= 1)
 921                                 {
 922                                         best = head;
 923                                         bestrating = rating;
 924                                 }
 925                         }
 926                         head = head.chain;
 927                 }
 928
 929                 // I want to do a second scan if no enemy was found or I don't have weapons
 930                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
 931                 if(best || !WEPSET_EMPTY_E(self)) // || self.weapon == WEP_RIFLE
 932                         break;
 933                 if(i)
 934                         break;
 935
 936                 // Set flags to see through transparent objects
 937                 self.dphitcontentsmask |= DPCONTENTS_OPAQUE;
 938
 939                 head = head2;
 940         }
 941
 942         // Restore hit flags
 943         self.dphitcontentsmask = hf;
 944
 945         self.enemy = best;
 946         self.havocbot_stickenemy = TRUE;
 947 }
 948
 949 float havocbot_chooseweapon_checkreload(float new_weapon)
 950 {
 951         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
 952         // so skip this for them, or they'll never get to reload their weapons at all.
 953         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
 954         if(skill < 5)
 955                 return FALSE;
 956
 957         // if this weapon is scheduled for reloading, don't switch to it during combat
 958         if (self.weapon_load[new_weapon] < 0)
 959         {
 960                 float i, other_weapon_available = FALSE;
 961                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 962                 {
 963                         // if we are out of ammo for all other weapons, it's an emergency to switch to anything else
 964                         if (weapon_action(i, WR_CHECKAMMO1) + weapon_action(i, WR_CHECKAMMO2))
 965                                 other_weapon_available = TRUE;
 966                 }
 967                 if(other_weapon_available)
 968                         return TRUE;
 969         }
 970
 971         return FALSE;
 972 }
 973
 974 void havocbot_chooseweapon()
 975 {
 976         float i;
 977
 978         // ;)
 979         if(WEPSET_EQ_AW(g_weaponarena_weapons, WEP_TUBA))
 980         {
 981                 self.switchweapon = WEP_TUBA;
 982                 return;
 983         }
 984
 985         // TODO: clean this up by moving it to weapon code
 986         if(self.enemy==world)
 987         {
 988                 // If no weapon was chosen get the first available weapon
 989                 if(self.weapon==0)
 990                 for(i=WEP_LASER + 1; i < WEP_COUNT ; ++i)
 991                 {
 992                         if(client_hasweapon(self, i, TRUE, FALSE))
 993                         {
 994                                 self.switchweapon = i;
 995                                 return;
 996                         }
 997                 }
 998                 return;
 999         }
1000
1001         // Do not change weapon during the next second after a combo
1002         i = time - self.lastcombotime;
1003         if(i < 1)
1004                 return;
1005
1006         float w;
1007         float distance; distance=bound(10,vlen(self.origin-self.enemy.origin)-200,10000);
1008
1009         // Should it do a weapon combo?
1010         float af, ct, combo_time, combo;
1011
1012         af = ATTACK_FINISHED(self);
1013         ct = autocvar_bot_ai_weapon_combo_threshold;
1014
1015         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1016         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1017         combo_time = time + ct + (ct * ((-0.3*(skill+self.bot_weaponskill))+3));
1018
1019         combo = FALSE;
1020
1021         if(autocvar_bot_ai_weapon_combo)
1022         if(self.weapon == self.lastfiredweapon)
1023         if(af > combo_time)
1024         {
1025                 combo = TRUE;
1026                 self.lastcombotime = time;
1027         }
1028
1029         distance *= pow(2, self.bot_rangepreference);
1030
1031         // Custom weapon list based on distance to the enemy
1032         if(bot_custom_weapon){
1033
1034                 // Choose weapons for far distance
1035                 if ( distance > bot_distance_far ) {
1036                         for(i=0; i < WEP_COUNT && bot_weapons_far[i] != -1 ; ++i){
1037                                 w = bot_weapons_far[i];
1038                                 if ( client_hasweapon(self, w, TRUE, FALSE) )
1039                                 {
1040                                         if ((self.weapon == w && combo) || havocbot_chooseweapon_checkreload(w))
1041                                                 continue;
1042                                         self.switchweapon = w;
1043                                         return;
1044                                 }
1045                         }
1046                 }
1047
1048                 // Choose weapons for mid distance
1049                 if ( distance > bot_distance_close) {
1050                         for(i=0; i < WEP_COUNT && bot_weapons_mid[i] != -1 ; ++i){
1051                                 w = bot_weapons_mid[i];
1052                                 if ( client_hasweapon(self, w, TRUE, FALSE) )
1053                                 {
1054                                         if ((self.weapon == w && combo) || havocbot_chooseweapon_checkreload(w))
1055                                                 continue;
1056                                         self.switchweapon = w;
1057                                         return;
1058                                 }
1059                         }
1060                 }
1061
1062                 // Choose weapons for close distance
1063                 for(i=0; i < WEP_COUNT && bot_weapons_close[i] != -1 ; ++i){
1064                         w = bot_weapons_close[i];
1065                         if ( client_hasweapon(self, w, TRUE, FALSE) )
1066                         {
1067                                 if ((self.weapon == w && combo) || havocbot_chooseweapon_checkreload(w))
1068                                         continue;
1069                                 self.switchweapon = w;
1070                                 return;
1071                         }
1072                 }
1073         }
1074 }
1075
1076 void havocbot_aim()
1077 {
1078         vector selfvel, enemyvel;
1079 //      if(self.flags & FL_INWATER)
1080 //              return;
1081         if (time < self.nextaim)
1082                 return;
1083         self.nextaim = time + 0.1;
1084         selfvel = self.velocity;
1085         if (!self.waterlevel)
1086                 selfvel_z = 0;
1087         if (self.enemy)
1088         {
1089                 enemyvel = self.enemy.velocity;
1090                 if (!self.enemy.waterlevel)
1091                         enemyvel_z = 0;
1092                 lag_additem(time + self.ping, 0, 0, self.enemy, self.origin, selfvel, (self.enemy.absmin + self.enemy.absmax) * 0.5, enemyvel);
1093         }
1094         else
1095                 lag_additem(time + self.ping, 0, 0, world, self.origin, selfvel, ( self.goalcurrent.absmin + self.goalcurrent.absmax ) * 0.5, '0 0 0');
1096 }
1097
1098 float havocbot_moveto_refresh_route()
1099 {
1100         // Refresh path to goal if necessary
1101         entity wp;
1102         wp = self.havocbot_personal_waypoint;
1103         navigation_goalrating_start();
1104         navigation_routerating(wp, 10000, 10000);
1105         navigation_goalrating_end();
1106         return self.navigation_hasgoals;
1107 }
1108
1109 float havocbot_moveto(vector pos)
1110 {
1111         entity wp;
1112
1113         if(self.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1114         {
1115                 // Step 4: Move to waypoint
1116                 if(self.havocbot_personal_waypoint==world)
1117                 {
1118                         dprint("Error: ", self.netname, " trying to walk to a non existent personal waypoint\n");
1119                         self.aistatus &~= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1120                         return CMD_STATUS_ERROR;
1121                 }
1122
1123                 if (!bot_strategytoken_taken)
1124                 if(self.havocbot_personal_waypoint_searchtime<time)
1125                 {
1126                         bot_strategytoken_taken = TRUE;
1127                         if(havocbot_moveto_refresh_route())
1128                         {
1129                                 dprint(self.netname, " walking to its personal waypoint (after ", ftos(self.havocbot_personal_waypoint_failcounter), " failed attempts)\n");
1130                                 self.havocbot_personal_waypoint_searchtime = time + 10;
1131                                 self.havocbot_personal_waypoint_failcounter = 0;
1132                         }
1133                         else
1134                         {
1135                                 self.havocbot_personal_waypoint_failcounter += 1;
1136                                 self.havocbot_personal_waypoint_searchtime = time + 2;
1137                                 if(self.havocbot_personal_waypoint_failcounter >= 30)
1138                                 {
1139                                         dprint("Warning: can't walk to the personal waypoint located at ", vtos(self.havocbot_personal_waypoint.origin),"\n");
1140                                         self.aistatus &~= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1141                                         remove(self.havocbot_personal_waypoint);
1142                                         return CMD_STATUS_ERROR;
1143                                 }
1144                                 else
1145                                         dprint(self.netname, " can't walk to its personal waypoint (after ", ftos(self.havocbot_personal_waypoint_failcounter), " failed attempts), trying later\n");
1146                         }
1147                 }
1148
1149                 if(autocvar_bot_debug_goalstack)
1150                         debuggoalstack();
1151
1152                 // Heading
1153                 vector dir = ( ( self.goalcurrent.absmin + self.goalcurrent.absmax ) * 0.5 ) - (self.origin + self.view_ofs);
1154                 dir_z = 0;
1155                 bot_aimdir(dir, -1);
1156
1157                 // Go!
1158                 havocbot_movetogoal();
1159
1160                 if(self.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1161                 {
1162                         // Step 5: Waypoint reached
1163                         dprint(self.netname, "'s personal waypoint reached\n");
1164                         remove(self.havocbot_personal_waypoint);
1165                         self.aistatus &~= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1166                         return CMD_STATUS_FINISHED;
1167                 }
1168
1169                 return CMD_STATUS_EXECUTING;
1170         }
1171
1172         // Step 2: Linking waypoint
1173         if(self.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1174         {
1175                 // Wait until it is linked
1176                 if(!self.havocbot_personal_waypoint.wplinked)
1177                 {
1178                         dprint(self.netname, " waiting for personal waypoint to be linked\n");
1179                         return CMD_STATUS_EXECUTING;
1180                 }
1181
1182                 self.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1183                 self.aistatus &~= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1184                 self.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1185
1186                 // Step 3: Route to waypoint
1187                 dprint(self.netname, " walking to its personal waypoint\n");
1188
1189                 return CMD_STATUS_EXECUTING;
1190         }
1191
1192         // Step 1: Spawning waypoint
1193         wp = waypoint_spawnpersonal(pos);
1194         if(wp==world)
1195         {
1196                 dprint("Error: Can't spawn personal waypoint at ",vtos(pos),"\n");
1197                 return CMD_STATUS_ERROR;
1198         }
1199
1200         self.havocbot_personal_waypoint = wp;
1201         self.havocbot_personal_waypoint_failcounter = 0;
1202         self.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1203
1204         // if pos is inside a teleport, then let's mark it as teleport waypoint
1205         entity head;
1206         for(head = world; (head = find(head, classname, "trigger_teleport")); )
1207         {
1208                 if(WarpZoneLib_BoxTouchesBrush(pos, pos, head, world))
1209                 {
1210                         wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1211                         self.lastteleporttime = 0;
1212                 }
1213         }
1214
1215 /*
1216         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1217                 print("routing to a teleporter\n");
1218         else
1219                 print("routing to a non-teleporter\n");
1220 */
1221
1222         return CMD_STATUS_EXECUTING;
1223 }
1224
1225 float havocbot_resetgoal()
1226 {
1227         navigation_clearroute();
1228         return CMD_STATUS_FINISHED;
1229 }
1230
1231 void havocbot_setupbot()
1232 {
1233         self.bot_ai = havocbot_ai;
1234         self.cmd_moveto = havocbot_moveto;
1235         self.cmd_resetgoal = havocbot_resetgoal;
1236
1237         havocbot_chooserole();
1238 }
1239
1240 vector havocbot_dodge()
1241 {
1242         // LordHavoc: disabled because this is too expensive
1243         return '0 0 0';
1244 #if 0
1245         entity head;
1246         vector dodge, v, n;
1247         float danger, bestdanger, vl, d;
1248         dodge = '0 0 0';
1249         bestdanger = -20;
1250         // check for dangerous objects near bot or approaching bot
1251         head = findchainfloat(bot_dodge, TRUE);
1252         while(head)
1253         {
1254                 if (head.owner != self)
1255                 {
1256                         vl = vlen(head.velocity);
1257                         if (vl > autocvar_sv_maxspeed * 0.3)
1258                         {
1259                                 n = normalize(head.velocity);
1260                                 v = self.origin - head.origin;
1261                                 d = v * n;
1262                                 if (d > (0 - head.bot_dodgerating))
1263                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1264                                 {
1265                                         // calculate direction and distance from the flight path, by removing the forward axis
1266                                         v = v - (n * (v * n));
1267                                         danger = head.bot_dodgerating - vlen(v);
1268                                         if (bestdanger < danger)
1269                                         {
1270                                                 bestdanger = danger;
1271                                                 // dodge to the side of the object
1272                                                 dodge = normalize(v);
1273                                         }
1274                                 }
1275                         }
1276                         else
1277                         {
1278                                 danger = head.bot_dodgerating - vlen(head.origin - self.origin);
1279                                 if (bestdanger < danger)
1280                                 {
1281                                         bestdanger = danger;
1282                                         dodge = normalize(self.origin - head.origin);
1283                                 }
1284                         }
1285                 }
1286                 head = head.chain;
1287         }
1288         return dodge;
1289 #endif
1290 }