qcsrc/server/arena.qc

   1 float maxspawned;
   2 float numspawned;
   3 float arena_roundbased;
   4 .float spawned;
   5 .entity spawnqueue_next;
   6 .entity spawnqueue_prev;
   7 .float spawnqueue_in;
   8 entity spawnqueue_first;
   9 entity spawnqueue_last;
  10 entity champion;
  11 float warmup;
  12 .float caplayer;
  13
  14 void PutObserverInServer();
  15 void PutClientInServer();
  16
  17 float next_round;
  18 float redalive, bluealive, yellowalive, pinkalive;
  19 .float redalive_stat, bluealive_stat, yellowalive_stat, pinkalive_stat;
  20 float red_players, blue_players, yellow_players, pink_players;
  21 float total_players;
  22
  23 /**
  24  * Resets the state of all clients, items, flags, runes, keys, weapons, waypoints, ... of the map.
  25  * Sets the 'warmup' global variable.
  26  */
  27 void reset_map(float dorespawn)
  28 {
  29         entity oldself;
  30         oldself = self;
  31
  32         if(g_arena)
  33         {
  34                 warmup = max(time, game_starttime);
  35                 if(autocvar_g_arena_warmup > 0)
  36                         warmup += autocvar_g_arena_warmup;
  37         }
  38         else if(g_ca)
  39         {
  40                 warmup = max(time, game_starttime);
  41                 if(autocvar_g_ca_warmup > 0)
  42                         warmup += autocvar_g_ca_warmup;
  43                 allowed_to_spawn = 1;
  44         }
  45         else if(g_freezetag)
  46         {
  47                 redalive = bluealive = yellowalive = pinkalive = 0;
  48                 warmup = max(time, game_starttime);
  49                 if(autocvar_g_freezetag_warmup > 0)
  50                         warmup += autocvar_g_freezetag_warmup;
  51         }
  52         else if(g_race || g_cts)
  53                 race_ReadyRestart();
  54
  55         lms_lowest_lives = 999;
  56         lms_next_place = player_count;
  57
  58         for(self = world; (self = nextent(self)); )
  59         if(clienttype(self) == CLIENTTYPE_NOTACLIENT)
  60         {
  61                 if(self.reset)
  62                 {
  63                         self.reset();
  64                         continue;
  65                 }
  66
  67                 if(self.team_saved)
  68                         self.team = self.team_saved;
  69
  70                 if(self.flags & FL_PROJECTILE) // remove any projectiles left
  71                         remove(self);
  72         }
  73
  74         // Waypoints and assault start come LAST
  75         for(self = world; (self = nextent(self)); )
  76         if(clienttype(self) == CLIENTTYPE_NOTACLIENT)
  77         {
  78                 if(self.reset2)
  79                 {
  80                         self.reset2();
  81                         continue;
  82                 }
  83         }
  84
  85         // Moving the player reset code here since the player-reset depends
  86         // on spawnpoint entities which have to be reset first --blub
  87         if(dorespawn)
  88         FOR_EACH_CLIENT(self) {
  89                 if(self.flags & FL_CLIENT)                              // reset all players
  90                 {
  91                         if(g_arena)
  92                         {
  93                                 if(self.spawned)
  94                                         PutClientInServer();
  95                                 else
  96                                         PutObserverInServer();
  97                         }
  98                         else if(g_ca && self.caplayer) {
  99                                 self.classname = "player";
 100                                 PutClientInServer();
 101                         }
 102                         else if(g_freezetag)
 103                         {
 104                                 if(self.classname == "player")
 105                                         PutClientInServer();
 106                         }
 107                         else
 108                         {
 109                                 /*
 110                                 only reset players if a restart countdown is active
 111                                 this can either be due to cvar sv_ready_restart_after_countdown having set
 112                                 restart_mapalreadyrestarted to 1 after the countdown ended or when
 113                                 sv_ready_restart_after_countdown is not used and countdown is still running
 114                                 */
 115                                 if (restart_mapalreadyrestarted || (time < game_starttime))
 116                                 {
 117                                         //NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
 118                                         if (self.classname == "player") {
 119                                                 //PlayerScore_Clear(self);
 120                                                 if(g_lms)
 121                                                         PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives());
 122                                                 self.killcount = 0;
 123                                                 //stop the player from moving so that he stands still once he gets respawned
 124                                                 self.velocity = '0 0 0';
 125                                                 self.avelocity = '0 0 0';
 126                                                 self.movement = '0 0 0';
 127                                                 PutClientInServer();
 128                                         }
 129                                 }
 130                         }
 131                 }
 132         }
 133
 134         if(g_keyhunt)
 135                 kh_Controller_SetThink_NoMsg(autocvar_g_balance_keyhunt_delay_round+(game_starttime - time), kh_StartRound);
 136
 137         if(g_arena)
 138         if(champion && champion.classname == "player" && player_count > 1)
 139                 UpdateFrags(champion, +1);
 140
 141         self = oldself;
 142 }
 143
 144 void Spawnqueue_Insert(entity e)
 145 {
 146         if(e.spawnqueue_in)
 147                 return;
 148         dprint(strcat("Into queue: ", e.netname, "\n"));
 149         e.spawnqueue_in = TRUE;
 150         e.spawnqueue_prev = spawnqueue_last;
 151         e.spawnqueue_next = world;
 152         if(spawnqueue_last)
 153                 spawnqueue_last.spawnqueue_next = e;
 154         spawnqueue_last = e;
 155         if(!spawnqueue_first)
 156                 spawnqueue_first = e;
 157 }
 158
 159 void Spawnqueue_Remove(entity e)
 160 {
 161         if(!e.spawnqueue_in)
 162                 return;
 163         dprint(strcat("Out of queue: ", e.netname, "\n"));
 164         e.spawnqueue_in = FALSE;
 165         if(e == spawnqueue_first)
 166                 spawnqueue_first = e.spawnqueue_next;
 167         if(e == spawnqueue_last)
 168                 spawnqueue_last = e.spawnqueue_prev;
 169         if(e.spawnqueue_prev)
 170                 e.spawnqueue_prev.spawnqueue_next = e.spawnqueue_next;
 171         if(e.spawnqueue_next)
 172                 e.spawnqueue_next.spawnqueue_prev = e.spawnqueue_prev;
 173         e.spawnqueue_next = world;
 174         e.spawnqueue_prev = world;
 175 }
 176
 177 void Spawnqueue_Unmark(entity e)
 178 {
 179         if(!e.spawned)
 180                 return;
 181         e.spawned = FALSE;
 182         numspawned = numspawned - 1;
 183 }
 184
 185 void Spawnqueue_Mark(entity e)
 186 {
 187         if(e.spawned)
 188                 return;
 189         e.spawned = TRUE;
 190         numspawned = numspawned + 1;
 191 }
 192
 193 /**
 194  * If roundbased arena game mode is active, it centerprints the texts for the
 195  * player when player is waiting for the countdown to finish.
 196  * Blocks the players movement while countdown is active.
 197  * Unblocks the player once the countdown is over.
 198  *
 199  * Called in StartFrame()
 200  */
 201 float roundStartTime_prev; // prevent networkspam
 202 void Arena_Warmup()
 203 {
 204         float f;
 205         entity e;
 206
 207         if(gameover)
 208         {
 209                 if(warmup && time < warmup)
 210                 {
 211                         FOR_EACH_REALCLIENT(e)
 212                                 Send_CSQC_Centerprint_Generic_Expire(e, CPID_ROUND_STARTING);
 213                         warmup = 0;
 214                 }
 215                 if(champion && g_arena)
 216                 {
 217                         FOR_EACH_REALCLIENT(e)
 218                                 centerprint(e, strcat("The Champion is ", champion.netname));
 219                         champion = world;
 220                 }
 221                 return;
 222         }
 223         if(time < game_starttime)
 224                 return;
 225
 226         f = ceil(warmup - time);
 227
 228         if(g_ca)
 229         {
 230                 if(inWarmupStage)
 231                         allowed_to_spawn = 1;
 232                 else if (warmup == 0) //first warmup or warmup cleared
 233                 {
 234                         if (red_players && blue_players)
 235                                 reset_map(TRUE);
 236                         else if(f != roundStartTime_prev)
 237                         {
 238                                 FOR_EACH_REALCLIENT(self)
 239                                         Send_CSQC_Centerprint_Generic(self, CPID_ROUND_STARTING, "^1Need at least 1 player in each team to play CA", 2, 0);
 240                                 roundStartTime_prev = f;
 241                         }
 242                         return;
 243                 }
 244         }
 245
 246         if(time < warmup && !inWarmupStage)
 247         {
 248                 if (g_ca)
 249                         allowed_to_spawn = 1;
 250                 else if(champion && g_arena)
 251                 {
 252                         FOR_EACH_REALCLIENT(e)
 253                                 centerprint(e, strcat("The Champion is ", champion.netname));
 254                 }
 255
 256                 if(f != roundStartTime_prev) {
 257                         roundStartTime_prev = f;
 258
 259                         if(g_ca && !(red_players && blue_players)) {
 260                                 warmup = 0;
 261                                 return;
 262                         }
 263
 264                         if(f == 5)
 265                                 Announce("prepareforbattle");
 266                         else if(f == 3)
 267                                 Announce("3");
 268                         else if(f == 2)
 269                                 Announce("2");
 270                         else if(f == 1)
 271                                 Announce("1");
 272
 273                         FOR_EACH_REALCLIENT(e)
 274                                 Send_CSQC_Centerprint_Generic(e, CPID_ROUND_STARTING, "Round will start in %d", 1, f);
 275                 }
 276
 277                 if (g_arena) {
 278                         FOR_EACH_CLIENT(e)
 279                         {
 280                                 if(e.spawned && e.classname == "player")
 281                                         e.player_blocked = 1;
 282                         }
 283                 }
 284         }
 285         else if(f > -1 && f != roundStartTime_prev)
 286         {
 287                 roundStartTime_prev = f;
 288                 if(g_ca) {
 289                         if(red_players && blue_players)
 290                                 allowed_to_spawn = 0;
 291                         else
 292                         {
 293                                 warmup = 0;
 294                                 return;
 295                         }
 296                 }
 297                 Announce("begin");
 298                 FOR_EACH_REALCLIENT(e)
 299                         Send_CSQC_Centerprint_Generic(e, CPID_ROUND_STARTING, "^1Begin!", 1, 0);
 300
 301                 if(g_arena) {
 302                         FOR_EACH_CLIENT(e)
 303                         {
 304                                 if(e.player_blocked)
 305                                         e.player_blocked = 0;
 306                         }
 307                 }
 308         }
 309
 310         // clear champion to avoid centerprinting again the champion msg
 311         if (champion)
 312                 champion = world;
 313 }
 314
 315 void count_players()
 316 {
 317         // count amount of players in each team
 318         total_players = red_players = blue_players = yellow_players = pink_players = 0;
 319         FOR_EACH_PLAYER(self) {
 320                 if (self.team == COLOR_TEAM1)
 321                 {
 322                         red_players += 1;
 323                         total_players += 1;
 324                 }
 325                 else if (self.team == COLOR_TEAM2)
 326                 {
 327                         blue_players += 1;
 328                         total_players += 1;
 329                 }
 330                 else if (self.team == COLOR_TEAM3)
 331                 {
 332                         yellow_players += 1;
 333                         total_players += 1;
 334                 }
 335                 else if (self.team == COLOR_TEAM4)
 336                 {
 337                         pink_players += 1;
 338                         total_players += 1;
 339                 }
 340         }
 341 }
 342
 343 void count_alive_players()
 344 {
 345         redalive = bluealive = yellowalive = pinkalive = 0;
 346         FOR_EACH_PLAYER(self) {
 347                 if (self.team == COLOR_TEAM1 && self.health >= 1)
 348                         redalive += 1;
 349                 else if (self.team == COLOR_TEAM2 && self.health >= 1)
 350                         bluealive += 1;
 351         }
 352         FOR_EACH_REALCLIENT(self) {
 353                 self.redalive_stat = redalive;
 354                 self.bluealive_stat = bluealive;
 355         }
 356 }
 357
 358 /**
 359  * This function finds out whether an arena round is over 1 player is left.
 360  * It determines the last player who's still alive and saves it's entity reference
 361  * in the global variable 'champion'. Then the new enemy/enemies are put into the server.
 362  *
 363  * Gets called in StartFrame()
 364  */
 365 void Spawnqueue_Check()
 366 {
 367         if(time < warmup + 1 || inWarmupStage || intermission_running)
 368                 return;
 369
 370         if(g_ca) {
 371                 if(allowed_to_spawn) // round is not started yet
 372                         return;
 373                 if(!next_round) {
 374                         if(!(redalive && bluealive)) {
 375                                 // every player of (at least) one team is dead, round ends here
 376                                 if(redalive) {
 377                                         play2all("ctf/red_capture.wav");
 378                                         FOR_EACH_CLIENT(self) centerprint(self, "^1RED ^7team wins the round");
 379                                         TeamScore_AddToTeam(COLOR_TEAM1, ST_SCORE, +1);
 380                                 }
 381                                 else if(bluealive) {
 382                                         play2all("ctf/blue_capture.wav");
 383                                         FOR_EACH_CLIENT(self) centerprint(self, "^4BLUE ^7team wins the round");
 384                                         TeamScore_AddToTeam(COLOR_TEAM2, ST_SCORE, +1);
 385                                 }
 386                                 else
 387                                         FOR_EACH_CLIENT(self) centerprint(self, "^7Round tied");
 388                                 next_round = -1;
 389                         }
 390                         else if(time - warmup > autocvar_g_ca_round_timelimit) {
 391                                 FOR_EACH_CLIENT(self) centerprint(self, "^7Round tied");
 392                                 next_round = time + 5;
 393                         }
 394                 }
 395                 else if(next_round == -1) {
 396                         // wait for killed players to be put as spectators
 397                         if(!(red_players && blue_players))
 398                                 next_round = time + 5;
 399                 }
 400                 else if((next_round > 0 && next_round < time))
 401                 {
 402                         next_round = 0;
 403                         reset_map(TRUE);
 404                 }
 405         } else if(g_freezetag) {
 406                 if((next_round && next_round < time))
 407                 {
 408                         next_round = 0;
 409                         reset_map(TRUE);
 410                 }
 411         } else { // arena
 412                 //extend next_round if it isn't set yet and only 1 player is spawned
 413                 if(!next_round)
 414                 if(numspawned < 2)
 415                         next_round = time + 3;
 416
 417                 if(!arena_roundbased || (next_round && next_round < time && player_count > 1))
 418                 {
 419                         next_round = 0;
 420
 421                         if(arena_roundbased)
 422                         {
 423                                 champion = find(world, classname, "player");
 424                                 while(champion && champion.deadflag)
 425                                         champion = find(champion, classname, "player");
 426                                 reset_map(TRUE);
 427                         }
 428
 429                         while(numspawned < maxspawned && spawnqueue_first)
 430                         {
 431                                 self = spawnqueue_first;
 432
 433                                 bprint ("^4", self.netname, "^4 is the next challenger\n");
 434
 435                                 Spawnqueue_Remove(self);
 436                                 Spawnqueue_Mark(self);
 437
 438                                 self.classname = "player";
 439                                 PutClientInServer();
 440                         }
 441                 }
 442         }
 443 }
 444
 445 void Arena_Main()
 446 {
 447         if(!(g_ca || g_freezetag || g_arena))
 448                 return;
 449
 450         if(g_ca || g_freezetag)
 451         {
 452                 count_players();
 453                 if(g_ca)
 454                         count_alive_players();
 455                 Arena_Warmup();
 456         }
 457         else if(arena_roundbased)
 458                 Arena_Warmup();
 459
 460         Spawnqueue_Check();
 461 }
 462