qcsrc/menu/xonotic/util.qc

   1 float GL_CheckExtension(string ext)
   2 {
   3         return (strstrofs(strcat(" ", cvar_string("gl_info_extensions"), " "), strcat(" ", ext, " "), 0) >= 0);
   4 }
   5
   6 float GL_Have_TextureCompression()
   7 {
   8         return (GL_CheckExtension("GL_EXT_texture_compression_s3tc") && GL_CheckExtension("GL_ARB_texture_compression"));
   9 }
  10
  11 void loadTooltips()
  12 {
  13         tooltipdb = db_load(language_filename("tooltips.db"));
  14 }
  15 void unloadTooltips()
  16 {
  17         if(tooltipdb >= 0)
  18                 db_close(tooltipdb);
  19         tooltipdb = -1;
  20 }
  21 string getZonedTooltipForIdentifier(string s)
  22 {
  23         string t;
  24         if(s == "")
  25                 return string_null;
  26         if(tooltipdb >= 0)
  27         {
  28                 t = db_get(tooltipdb, s);
  29                 if(t == "-")
  30                         return string_null;
  31                 if(t != "")
  32                         return strzone(t);
  33         }
  34         if(prvm_language == "en")
  35         {
  36                 t = cvar_description(s);
  37                 if(t != "" && t != "custom cvar")
  38                         return strzone(t);
  39         }
  40         dprint("WARNING: no tooltip set for ", s, "\n");
  41         return string_null;
  42 }
  43
  44 void forAllDescendants(entity root, void(entity, entity) funcPre, void(entity, entity) funcPost, entity pass)
  45 {
  46         depthfirst(root, parent, firstChild, nextSibling, funcPre, funcPost, pass);
  47 }
  48
  49 .string cvarName;
  50 void SUB_Null_ee(entity e1, entity e2)
  51 {
  52 }
  53 void saveCvarsOf(entity ignore, entity e)
  54 {
  55         if(e.saveCvars)
  56                 e.saveCvars(e);
  57 }
  58 void loadCvarsOf(entity ignore, entity e)
  59 {
  60         if(e.loadCvars)
  61                 e.loadCvars(e);
  62 }
  63 void saveAllCvars(entity root)
  64 {
  65         forAllDescendants(root, saveCvarsOf, SUB_Null_ee, NULL);
  66 }
  67 void loadAllCvars(entity root)
  68 {
  69         forAllDescendants(root, loadCvarsOf, SUB_Null_ee, NULL);
  70 }
  71
  72 .string cvarNames_Multi;
  73 .void(entity me) saveCvars_Multi;
  74 string getCvarsMulti(entity me)
  75 {
  76         if (me.cvarNames_Multi)
  77                 return me.cvarNames_Multi;
  78         return string_null;
  79 }
  80 void saveCvarsMulti(entity me)
  81 {
  82         float n, i;
  83         string s;
  84
  85         me.saveCvars_Multi(me);
  86         s = cvar_string(me.cvarName);
  87
  88         n = tokenize_console(me.cvarNames_Multi);
  89         for(i = 0; i < n; ++i)
  90                 cvar_set(argv(i), s);
  91 }
  92 void makeMulti(entity e, string otherCvars)
  93 {
  94         e.cvarNames_Multi = otherCvars;
  95         e.saveCvars_Multi = e.saveCvars;
  96         e.saveCvars = saveCvarsMulti;
  97 }
  98
  99 .void(entity me) saveCvars_Callback;
 100 .entity saveCvars_Callback_ent;
 101 .void(entity me, entity cb) saveCvars_Callback_func;
 102 void saveCvarsCallback(entity me)
 103 {
 104         me.saveCvars_Callback(me);
 105         me.saveCvars_Callback_func(me.saveCvars_Callback_ent, me);
 106 }
 107 void makeCallback(entity e, entity cbent, void(entity, entity) cbfunc)
 108 {
 109         e.saveCvars_Callback = e.saveCvars;
 110         e.saveCvars = saveCvarsCallback;
 111         e.saveCvars_Callback_ent = cbent;
 112         e.saveCvars_Callback_func = cbfunc;
 113 }
 114
 115 .void(entity) draw_setDependent;
 116 .string cvar_setDependent;
 117 .float cvarMin_setDependent;
 118 .float cvarMax_setDependent;
 119 .string cvar2_setDependent;
 120 .float cvar2Min_setDependent;
 121 .float cvar2Max_setDependent;
 122 .string cvar3_setDependent;
 123 .float cvar3Min_setDependent;
 124 .float cvar3Max_setDependent;
 125 .float op_setDependent;
 126 .string cvarString_setDependent;
 127 .string cvarValue_setDependent;
 128 .float(entity) func_setDependent;
 129 void setDependent_Check(entity e)
 130 {
 131         float f;
 132         string s;
 133         if(e.func_setDependent)
 134         {
 135                 e.disabled = !(e.func_setDependent(e));
 136         }
 137         else if(e.cvarString_setDependent)
 138         {
 139                 s = cvar_string(e.cvarString_setDependent);
 140                 e.disabled = (cvar_string(e.cvarString_setDependent) == e.cvarValue_setDependent);
 141         }
 142         else
 143         {
 144                 if(e.cvar_setDependent)
 145                 {
 146                         f = cvar(e.cvar_setDependent);
 147                         if(e.cvarMin_setDependent <= e.cvarMax_setDependent)
 148                                 e.disabled = ((f < e.cvarMin_setDependent) || (f > e.cvarMax_setDependent));
 149                         else
 150                                 e.disabled = ((f >= e.cvarMax_setDependent) && (f <= e.cvarMin_setDependent));
 151                 }
 152                 if(e.cvar2_setDependent)
 153                 {
 154                         f = cvar(e.cvar2_setDependent);
 155                         if(e.cvar2Min_setDependent <= e.cvar2Max_setDependent)
 156                                 e.disabled = (e.disabled + ((f < e.cvar2Min_setDependent) || (f > e.cvar2Max_setDependent)) > e.op_setDependent);
 157                         else
 158                                 e.disabled = (e.disabled + ((f >= e.cvar2Max_setDependent) && (f <= e.cvar2Min_setDependent)) > e.op_setDependent);
 159                 }
 160                 if(e.cvar3_setDependent)
 161                 {
 162                         f = cvar(e.cvar3_setDependent);
 163                         if(e.cvar3Min_setDependent <= e.cvar3Max_setDependent)
 164                                 e.disabled = (e.disabled + ((f < e.cvar3Min_setDependent) || (f > e.cvar3Max_setDependent)) > e.op_setDependent);
 165                         else
 166                                 e.disabled = (e.disabled + ((f >= e.cvar3Max_setDependent) && (f <= e.cvar3Min_setDependent)) > e.op_setDependent);
 167                 }
 168         }
 169 }
 170 void setDependent_Draw(entity e)
 171 {
 172         setDependent_Check(e);
 173         e.draw_setDependent(e);
 174 }
 175 void setDependent(entity e, string theCvarName, float theCvarMin, float theCvarMax)
 176 {
 177         e.draw_setDependent = e.draw;
 178         e.cvar_setDependent = theCvarName;
 179         e.cvarMin_setDependent = theCvarMin;
 180         e.cvarMax_setDependent = theCvarMax;
 181         e.cvar2_setDependent = string_null;
 182         e.cvar3_setDependent = string_null;
 183         e.func_setDependent = func_null;
 184         e.draw = setDependent_Draw;
 185         setDependent_Check(e);
 186 }
 187 void setDependentStringNotEqual(entity e, string theCvarName, string theCvarValue)
 188 {
 189         e.draw_setDependent = e.draw;
 190         e.cvarString_setDependent = theCvarName;
 191         e.cvarValue_setDependent = theCvarValue;
 192         e.cvar_setDependent = string_null;
 193         e.cvar2_setDependent = string_null;
 194         e.cvar3_setDependent = string_null;
 195         e.func_setDependent = func_null;
 196         e.draw = setDependent_Draw;
 197         setDependent_Check(e);
 198 }
 199 void setDependentAND(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 200 {
 201         e.draw_setDependent = e.draw;
 202         e.cvar_setDependent = theCvarName;
 203         e.cvarMin_setDependent = theCvarMin;
 204         e.cvarMax_setDependent = theCvarMax;
 205         e.cvar2_setDependent = theCvar2Name;
 206         e.cvar2Min_setDependent = theCvar2Min;
 207         e.cvar2Max_setDependent = theCvar2Max;
 208         e.cvar3_setDependent = string_null;
 209         e.op_setDependent = 0;
 210         e.func_setDependent = func_null;
 211         e.draw = setDependent_Draw;
 212         setDependent_Check(e);
 213 }
 214 void setDependentOR(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 215 {
 216         e.draw_setDependent = e.draw;
 217         e.cvar_setDependent = theCvarName;
 218         e.cvarMin_setDependent = theCvarMin;
 219         e.cvarMax_setDependent = theCvarMax;
 220         e.cvar2_setDependent = theCvar2Name;
 221         e.cvar2Min_setDependent = theCvar2Min;
 222         e.cvar2Max_setDependent = theCvar2Max;
 223         e.cvar3_setDependent = string_null;
 224         e.op_setDependent = 1;
 225         e.func_setDependent = func_null;
 226         e.draw = setDependent_Draw;
 227         setDependent_Check(e);
 228 }
 229 void setDependentAND3(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max, string theCvar3Name, float theCvar3Min, float theCvar3Max)
 230 {
 231         e.draw_setDependent = e.draw;
 232         e.cvar_setDependent = theCvarName;
 233         e.cvarMin_setDependent = theCvarMin;
 234         e.cvarMax_setDependent = theCvarMax;
 235         e.cvar2_setDependent = theCvar2Name;
 236         e.cvar2Min_setDependent = theCvar2Min;
 237         e.cvar2Max_setDependent = theCvar2Max;
 238         e.cvar3_setDependent = theCvar3Name;
 239         e.cvar3Min_setDependent = theCvar3Min;
 240         e.cvar3Max_setDependent = theCvar3Max;
 241         e.op_setDependent = 0;
 242         e.func_setDependent = func_null;
 243         e.draw = setDependent_Draw;
 244         setDependent_Check(e);
 245 }
 246 void setDependentWeird(entity e, float(entity) func)
 247 {
 248         e.draw_setDependent = e.draw;
 249         e.func_setDependent = func;
 250         e.draw = setDependent_Draw;
 251         setDependent_Check(e);
 252 }
 253
 254 // URI SYSTEM ////////////////////////////////////////////////////////
 255
 256 float _Nex_ExtResponseSystem_Queried;
 257 string _Nex_ExtResponseSystem_UpdateTo;
 258 string _Nex_ExtResponseSystem_UpdateToURL;
 259 string _Nex_ExtResponseSystem_Packs;
 260 float _Nex_ExtResponseSystem_PacksStep;
 261
 262 void URI_Get_Callback(float id, float status, string data)
 263 {
 264         if(url_URI_Get_Callback(id, status, data))
 265         {
 266                 // handled
 267         }
 268         else if (id == URI_GET_DISCARD)
 269         {
 270                 // discard
 271         }
 272         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
 273         {
 274                 // sv_cmd curl
 275                 Curl_URI_Get_Callback(id, status, data);
 276         }
 277         else if (id == URI_GET_UPDATENOTIFICATION)
 278         {
 279                 UpdateNotification_URI_Get_Callback(id, status, data);
 280         }
 281         else
 282         {
 283                 print(sprintf(_("Received HTTP request data for an invalid id %d.\n"), id));
 284         }
 285 }
 286
 287 void UpdateNotification_URI_Get_Callback(float id, float status, string data)
 288 {
 289         float n;
 290
 291         if(_Nex_ExtResponseSystem_UpdateTo)
 292         {
 293                 dprint("error: UpdateNotification_URI_Get_Callback has been called before\n");
 294                 return;
 295         }
 296         if(status != 0)
 297         {
 298                 print(sprintf(_("error receiving update notification: status is %d\n"), status));
 299                 return;
 300         }
 301         if(substring(data, 0, 1) == "<")
 302         {
 303                 print(_("error: received HTML instead of an update notification\n"));
 304                 return;
 305         }
 306         if(strstrofs(data, "\r", 0) != -1)
 307         {
 308                 print(_("error: received carriage returns from update notification server\n"));
 309                 return;
 310         }
 311
 312         if(data == "")
 313                 n = 0;
 314         else
 315                 n = tokenizebyseparator(data, "\n");
 316
 317         if(n >= 1)
 318         {
 319                 _Nex_ExtResponseSystem_UpdateTo = argv(0);
 320
 321                 if(vercmp(cvar_string("g_xonoticversion"), _Nex_ExtResponseSystem_UpdateTo) >= 0)
 322                 {
 323                         _Nex_ExtResponseSystem_UpdateTo = ""; // no update needed
 324                 }
 325                 else
 326                 {
 327                         // update needed
 328                         if(n >= 2)
 329                                 print(sprintf(_("Update can be downloaded at:\n%s\n"), argv(1)));
 330                         if(n >= 3)
 331                                 _Nex_ExtResponseSystem_UpdateToURL = strzone(argv(2));
 332                 }
 333
 334                 _Nex_ExtResponseSystem_UpdateTo = strzone(_Nex_ExtResponseSystem_UpdateTo);
 335
 336                 if(n >= 4)
 337                 {
 338                         _Nex_ExtResponseSystem_BannedServers = strzone(argv(3));
 339                         _Nex_ExtResponseSystem_BannedServersNeedsRefresh = 1;
 340                 }
 341
 342                 if(n >= 5)
 343                 {
 344                         if(cvar("menu_updatecheck_getpacks"))
 345                         {
 346                                 _Nex_ExtResponseSystem_Packs = strzone(argv(4));
 347                                 _Nex_ExtResponseSystem_PacksStep = 1;
 348                         }
 349                 }
 350         }
 351 }
 352
 353 // END OF URI SYSTEM ////////////////////////////////////////////////////////
 354
 355 float preMenuInit()
 356 {
 357         vector sz;
 358         vector boxA, boxB;
 359
 360         MapInfo_Cache_Create();
 361         MapInfo_Enumerate();
 362         if(!MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
 363         {
 364                 draw_reset_cropped();
 365
 366                 sz = eX * 0.025 + eY * 0.025 * (draw_scale_x / draw_scale_y);
 367                 draw_CenterText('0.5 0.5 0' - 1.25 * sz_y * eY, _("Autogenerating mapinfo for newly added maps..."), sz, '1 1 1', 1, 0);
 368
 369                 boxA = '0.05 0.5 0' + 0.25 * sz_y * eY;
 370                 boxB = '0.95 0.5 0' + 1.25 * sz_y * eY;
 371                 draw_Fill(boxA, boxB - boxA, '1 1 1', 1);
 372
 373                 boxA += sz * 0.1;
 374                 boxB -= sz * 0.1;
 375                 draw_Fill(boxA, boxB - boxA, '0.1 0.1 0.1', 1);
 376
 377                 boxB_x = boxA_x * (1 - MapInfo_progress) + boxB_x * MapInfo_progress;
 378                 draw_Fill(boxA, boxB - boxA, '0 0 1', 1);
 379
 380                 return FALSE;
 381         }
 382         return TRUE;
 383 }
 384
 385 string campaign_name_previous;
 386 float campaign_won_previous;
 387 #ifdef WATERMARK
 388 var string autocvar_menu_watermark = WATERMARK();
 389 #else
 390 var string autocvar_menu_watermark = "";
 391 #endif
 392 void postMenuDraw()
 393 {
 394         if(autocvar_menu_watermark != "")
 395         {
 396                 vector fs = '48 48 0';
 397                 draw_CenterText('0.5 0.1 0', sprintf(_("^1%s TEST BUILD"), autocvar_menu_watermark), globalToBoxSize('32 32 0', draw_scale), '1 1 1', 0.05, 1);
 398         }
 399 }
 400 void preMenuDraw()
 401 {
 402         vector fs, sz, line, mid;
 403
 404         if(cvar("menu_updatecheck"))
 405         {
 406                 if(!_Nex_ExtResponseSystem_Queried)
 407                 {
 408                         _Nex_ExtResponseSystem_Queried = 1;
 409                         float startcnt;
 410                         string uri;
 411
 412                         cvar_set("cl_startcount", ftos(startcnt = cvar("cl_startcount") + 1));
 413
 414                         // for privacy, munge the start count a little
 415                         startcnt = floor((floor(startcnt / 10) + random()) * 10);
 416                         uri = sprintf("http://www.xonotic.org/dl/checkupdate.txt?version=%s&cnt=%d", uri_escape(cvar_string("g_xonoticversion")), startcnt);
 417
 418 #ifdef CVAR_POPCON
 419                         float cvar_handle, popcon_handle;
 420                         float n, i, j;
 421                         string k, s;
 422                         cvar_handle = buf_create();
 423                         buf_cvarlist(cvar_handle, "", "");
 424                         n = buf_getsize(cvar_handle);
 425                         popcon_handle = buf_create();
 426                         for(i= 0, j = 0; i < n; ++i)
 427                         {
 428                                 k = bufstr_get(cvar_handle, i);
 429                                 if(!(cvar_type(k) & CVAR_TYPEFLAG_SAVED))
 430                                         continue;
 431                                 s = sprintf("%s=%d", uri_escape(k), cvar_string(k) != cvar_defstring(k));
 432                                 bufstr_set(popcon_handle, j, s);
 433                                 ++j;
 434                         }
 435                         buf_del(cvar_handle);
 436                         uri_postbuf(
 437                                 uri, URI_GET_UPDATENOTIFICATION,
 438                                 "application/x-www-form-urlencoded",
 439                                 "&",
 440                                 popcon_handle
 441                         );
 442                         buf_del(popcon_handle);
 443 #else
 444                         uri_get(uri, URI_GET_UPDATENOTIFICATION);
 445 #endif
 446                 }
 447         }
 448
 449         if(_Nex_ExtResponseSystem_PacksStep > 0)
 450         {
 451                 float n;
 452                 float allgood;
 453                 n = tokenize_console(_Nex_ExtResponseSystem_Packs);
 454                 allgood = TRUE;
 455                 for(i = 0; i+1 < n; i += 2)
 456                 {
 457                         if(fexists(argv(i+1)))
 458                                 continue;
 459                         allgood = FALSE;
 460                         if(_Nex_ExtResponseSystem_PacksStep == 1) // first run
 461                                 localcmd("\ncurl --pak \"", argv(i), "\"\n");
 462                 }
 463                 if(allgood)
 464                 {
 465                         if(_Nex_ExtResponseSystem_PacksStep == 2)
 466                                 localcmd("\nmenu_restart\n");
 467                         _Nex_ExtResponseSystem_PacksStep = 0;
 468                 }
 469                 else
 470                         _Nex_ExtResponseSystem_PacksStep = 2;
 471         }
 472
 473         if(_Nex_ExtResponseSystem_UpdateTo != "")
 474         {
 475                 // TODO rather turn this into a dialog
 476                 fs = ((1/draw_scale_x) * eX + (1/draw_scale_y) * eY) * 12;
 477                 line = eY * fs_y;
 478                 string l1, l2;
 479                 l1 = sprintf(_("Update to %s now!"), _Nex_ExtResponseSystem_UpdateTo);
 480                 l2 = "http://www.xonotic.org/";
 481                 if(_Nex_ExtResponseSystem_UpdateToURL)
 482                         l2 = _Nex_ExtResponseSystem_UpdateToURL;
 483
 484                 sz_x = draw_TextWidth("    ", 0, fs) + max(
 485                                 draw_TextWidth(l1, 0, fs),
 486                                 draw_TextWidth(l2, 0, fs)
 487                         );
 488                 sz_y = 3 * fs_y;
 489
 490                 draw_alpha = bound(0, sin(time * 0.112 - 0.3) * 10, 1);
 491                 mid = eX * (0.5 + 0.5 * (1 - sz_x) * cos(time * 0.071))
 492                     + eY * (0.5 + 0.5 * (1 - sz_y) * sin(time * 0.071));
 493
 494                 draw_Fill(mid - 0.5 * sz, sz, '1 1 0', 1);
 495                 draw_CenterText(mid - 1 * line, l1, fs, '1 0 0', 1, 0);
 496                 draw_CenterText(mid - 0 * line, l2, fs, '0 0 1', 1, 0);
 497         }
 498         if not(campaign_name_previous)
 499                 campaign_name_previous = strzone(strcat(campaign_name, "x")); // force unequal
 500         if(campaign_name == campaign_name_previous)
 501         {
 502                 if(cvar(strcat("g_campaign", campaign_name, "_won")))
 503                 {
 504                         if(!campaign_won_previous)
 505                         {
 506                                 m_display();
 507                                 DialogOpenButton_Click_withCoords(NULL, main.winnerDialog, '0 0 0', eX * conwidth + eY * conheight);
 508                         }
 509                         campaign_won_previous = 1;
 510                 }
 511                 else
 512                         campaign_won_previous = 0;
 513         }
 514         else
 515         {
 516                 strunzone(campaign_name_previous);
 517                 campaign_name_previous = strzone(campaign_name);
 518                 campaign_won_previous = cvar(strcat("g_campaign", campaign_name, "_won"));
 519         }
 520 }
 521
 522 string resolvemod(string m)
 523 {
 524         if(m == "=")
 525                 return getcurrentmod();
 526         else
 527                 return m;
 528 }
 529
 530 float updateCompression()
 531 {
 532         float have_dds, have_jpg, have_tga;
 533         float can_dds;
 534         have_dds = (fexists("dds/particles/particlefont.dds"));
 535         have_jpg = (fexists("particles/particlefont.jpg"));
 536         have_tga = (fexists("particles/particlefont.tga"));
 537         can_dds = GL_Have_TextureCompression();
 538         if(have_dds && (have_jpg || have_tga))
 539         {
 540                 // both? Let's only use good quality precompressed files
 541                 // but ONLY if we actually support it!
 542                 if(can_dds)
 543                 {
 544                         // these builds are meant to have GOOD quality, so let's not compress non-skinframes
 545                         cvar_set("gl_texturecompression", "0");
 546                         return 1;
 547
 548                         //cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 549                         //return 2;
 550                 }
 551                 else
 552                 {
 553                         cvar_set("gl_texturecompression", "0");
 554                         cvar_set("r_texture_dds_load", "0");
 555                         return 0;
 556                 }
 557         }
 558         else if(have_dds)
 559         {
 560                 // DDS only? We probably always want texture compression
 561                 cvar_set("gl_texturecompression", "1");
 562                 cvar_set("r_texture_dds_load", "1");
 563                 if(!can_dds)
 564                         print(_("^1ERROR: Texture compression is required but not supported.\n^1Expect visual problems.\n"));
 565                 return 0;
 566         }
 567         else
 568         {
 569                 // TGA only? Allow runtime compression
 570                 if(can_dds)
 571                 {
 572                         cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 573                         return 2;
 574                 }
 575                 else
 576                 {
 577                         cvar_set("gl_texturecompression", "0");
 578                         cvar_set("r_texture_dds_load", "0");
 579                         return 0;
 580                 }
 581         }
 582 }
 583
 584 // note: include only those that should be in the menu!
 585 #define GAMETYPES \
 586         GAMETYPE(MAPINFO_TYPE_ARENA) \
 587         GAMETYPE(MAPINFO_TYPE_ASSAULT) \
 588         GAMETYPE(MAPINFO_TYPE_CTF) \
 589         GAMETYPE(MAPINFO_TYPE_CA) \
 590         GAMETYPE(MAPINFO_TYPE_DEATHMATCH) \
 591         GAMETYPE(MAPINFO_TYPE_DOMINATION) \
 592         GAMETYPE(MAPINFO_TYPE_FREEZETAG) \
 593         GAMETYPE(MAPINFO_TYPE_KEEPAWAY) \
 594         GAMETYPE(MAPINFO_TYPE_KEYHUNT) \
 595         GAMETYPE(MAPINFO_TYPE_LMS) \
 596         GAMETYPE(MAPINFO_TYPE_NEXBALL) \
 597         GAMETYPE(MAPINFO_TYPE_ONSLAUGHT) \
 598         GAMETYPE(MAPINFO_TYPE_RACE) \
 599         GAMETYPE(MAPINFO_TYPE_CTS) \
 600         GAMETYPE(MAPINFO_TYPE_RUNEMATCH) \
 601         GAMETYPE(MAPINFO_TYPE_TEAM_DEATHMATCH) \
 602         /* nothing */
 603
 604 float GameType_GetID(float cnt)
 605 {
 606         float i;
 607         i = 0;
 608
 609         #define GAMETYPE(id) if(i++ == cnt) return id;
 610         GAMETYPES
 611         #undef GAMETYPE
 612
 613         return 0;
 614 }
 615
 616 float GameType_GetCount()
 617 {
 618         float i;
 619         i = 0;
 620
 621         #define GAMETYPE(id) ++i;
 622         GAMETYPES
 623         #undef GAMETYPE
 624
 625         return i;
 626 }
 627
 628 string GameType_GetName(float cnt)
 629 {
 630         float i = GameType_GetID(cnt);
 631
 632         if(i)
 633                 return MapInfo_Type_ToText(i);
 634
 635         return "";
 636 }
 637
 638 string GameType_GetIcon(float cnt)
 639 {
 640         float i = GameType_GetID(cnt);
 641
 642         if(i)
 643                 return strcat("gametype_", MapInfo_Type_ToString(i));
 644
 645         return "";
 646 }
 647
 648 /*string GameType_GetTeams(float cnt) // poor implementation, later something else could be done that's better?
 649 {
 650         float i = GameType_GetID(cnt);
 651         string s = _MapInfo_GetDefaultEx(i);
 652
 653         if(i)
 654         {
 655                 if(strstrofs(s, "teams", 0) >= 0)
 656                         return _("teamplay");
 657                 else
 658                         return _("free for all");
 659         }
 660
 661         return _("tuba for all");
 662 }*/
 663
 664 void dialog_hudpanel_common_notoggle(entity me, string panelname)
 665 {
 666         float i;
 667         entity e;
 668
 669         me.TR(me);
 670                 me.TD(me, 1, 1.4, e = makeXonoticTextLabel(0, _("Background:")));
 671                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg"))));
 672                                 e.addValue(e, _("Default"), "");
 673                                 e.addValue(e, _("Disable"), "0");
 674                                 e.addValue(e, strzone(strcat("border_", panelname)), strzone(strcat("border_", panelname)));
 675                                 e.configureXonoticTextSliderValues(e);
 676         me.TR(me);
 677                 me.TDempty(me, 0.2);
 678                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Color:")));
 679                 me.TD(me, 2, 2.6, e = makeXonoticColorpickerString(strzone(strcat("hud_panel_", panelname, "_bg_color")), "hud_panel_bg_color"));
 680                         setDependentStringNotEqual(e, strzone(strcat("hud_panel_", panelname, "_bg_color")), "");
 681         me.TR(me);
 682                 me.TDempty(me, 0.2);
 683                 me.TD(me, 1, 1.0, e = makeXonoticCheckBoxString("", "1 1 1", strzone(strcat("hud_panel_", panelname, "_bg_color")), _("Use default")));
 684         me.TR(me);
 685                 me.TDempty(me, 0.2);
 686                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Border size:")));
 687                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_border"))));
 688                                 e.addValue(e, _("Default"), "");
 689                                 e.addValue(e, _("Disable"), "0");
 690                                 for(i = 1; i <= 10; ++i)
 691                                         e.addValue(e, strzone(ftos_decimals(i * 2, 0)), strzone(ftos(i * 2)));
 692                                 e.configureXonoticTextSliderValues(e);
 693         me.TR(me);
 694                 me.TDempty(me, 0.2);
 695                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Alpha:")));
 696                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_alpha"))));
 697                                 e.addValue(e, _("Default"), "");
 698                                 for(i = 1; i <= 10; ++i)
 699                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 700                                 e.configureXonoticTextSliderValues(e);
 701         me.TR(me);
 702                 me.TDempty(me, 0.2);
 703                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Team Color:")));
 704                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_color_team"))));
 705                                 e.addValue(e, _("Default"), "");
 706                                 e.addValue(e, _("Disable"), "0");
 707                                 for(i = 1; i <= 10; ++i)
 708                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 709                                 e.configureXonoticTextSliderValues(e);
 710         me.TR(me);
 711                 me.TDempty(me, 0.4);
 712                 me.TD(me, 1, 3.6, e = makeXonoticCheckBox(0, "hud_configure_teamcolorforced", _("Test team color in configure mode")));
 713         me.TR(me);
 714                 me.TDempty(me, 0.2);
 715                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Padding:")));
 716                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_padding"))));
 717                                 e.addValue(e, _("Default"), "");
 718                                 for(i = 0; i <= 10; ++i)
 719                                         e.addValue(e, strzone(ftos_decimals(i - 5, 0)), strzone(ftos(i - 5)));
 720                                 e.configureXonoticTextSliderValues(e);
 721 }