qcsrc/menu/xonotic/hudskinlist.qc

   1 #ifndef HUDSKINLIST_H
   2 #define HUDSKINLIST_H
   3 #include "listbox.qc"
   4 CLASS(XonoticHUDSkinList, XonoticListBox)
   5         METHOD(XonoticHUDSkinList, configureXonoticHUDSkinList, void(entity));
   6         ATTRIB(XonoticHUDSkinList, rowsPerItem, float, 1)
   7         METHOD(XonoticHUDSkinList, resizeNotify, void(entity, vector, vector, vector, vector));
   8         METHOD(XonoticHUDSkinList, draw, void(entity));
   9         METHOD(XonoticHUDSkinList, drawListBoxItem, void(entity, int, vector, bool, bool));
  10         METHOD(XonoticHUDSkinList, getHUDSkins, void(entity));
  11         METHOD(XonoticHUDSkinList, setHUDSkin, void(entity));
  12         METHOD(XonoticHUDSkinList, hudskinName, string(entity, float));
  13         METHOD(XonoticHUDSkinList, doubleClickListBoxItem, void(entity, float, vector));
  14         METHOD(XonoticHUDSkinList, keyDown, float(entity, float, float, float));
  15         METHOD(XonoticHUDSkinList, destroy, void(entity));
  16         METHOD(XonoticHUDSkinList, showNotify, void(entity));
  17
  18         ATTRIB(XonoticHUDSkinList, listHUDSkin, float, -1)
  19         ATTRIB(XonoticHUDSkinList, realFontSize, vector, '0 0 0')
  20         ATTRIB(XonoticHUDSkinList, columnNameOrigin, float, 0)
  21         ATTRIB(XonoticHUDSkinList, columnNameSize, float, 0)
  22         ATTRIB(XonoticHUDSkinList, realUpperMargin, float, 0)
  23         ATTRIB(XonoticHUDSkinList, origin, vector, '0 0 0')
  24         ATTRIB(XonoticHUDSkinList, itemAbsSize, vector, '0 0 0')
  25
  26         ATTRIB(XonoticHUDSkinList, filterString, string, string_null)
  27         ATTRIB(XonoticHUDSkinList, delayedRefreshTime, float, 0)
  28 ENDCLASS(XonoticHUDSkinList)
  29
  30 #ifndef IMPLEMENTATION
  31 // public:
  32 entity hudskinlist;
  33 entity makeXonoticHUDSkinList();
  34 void SaveHUDSkin_Click(entity btn, entity me);
  35 void SetHUDSkin_Click(entity btn, entity me);
  36 #endif
  37 void HUDSkinList_Refresh_Click(entity btn, entity me);
  38 void HUDSkinList_Filter_Change(entity box, entity me);
  39 #endif
  40
  41 #ifdef IMPLEMENTATION
  42
  43 entity makeXonoticHUDSkinList()
  44 {
  45         entity me;
  46         me = NEW(XonoticHUDSkinList);
  47         me.configureXonoticHUDSkinList(me);
  48         return me;
  49 }
  50
  51 void XonoticHUDSkinList_configureXonoticHUDSkinList(entity me)
  52 {
  53         me.configureXonoticListBox(me);
  54         me.getHUDSkins(me);
  55 }
  56
  57 string XonoticHUDSkinList_hudskinName(entity me, float i)
  58 {
  59         string s;
  60         s = bufstr_get(me.listHUDSkin, i);
  61
  62         if(substring(s, 0, 1) == "/")
  63                 s = substring(s, 1, strlen(s) - 1);  // remove the first forward slash
  64
  65         return s;
  66 }
  67
  68 void getAllHUDSkins(entity me, string subdir)
  69 {
  70         string s;
  71         if(me.filterString)
  72                 s = me.filterString;
  73         else
  74                 s = "*";
  75         s = strcat(subdir, "hud_", s, ".cfg");
  76         float strlen_subdir = strlen(subdir);
  77
  78         float list, i, n;
  79         list = search_begin(s, false, true);
  80         if(list >= 0)
  81         {
  82                 n = search_getsize(list);
  83                 for(i = 0; i < n; ++i)
  84                 {
  85                         s = search_getfilename(list, i); // get initial full file name
  86                         s = substring(s, strlen_subdir + 4, (strlen(s) - strlen_subdir - 4 - 4)); // remove "hud_" prefix and ".cfg" suffix
  87                         bufstr_add(me.listHUDSkin, s, true);
  88                 }
  89                 search_end(list);
  90         }
  91 }
  92
  93 void XonoticHUDSkinList_getHUDSkins(entity me)
  94 {
  95         if (me.listHUDSkin >= 0)
  96                 buf_del(me.listHUDSkin);
  97         me.listHUDSkin = buf_create();
  98         if (me.listHUDSkin < 0)
  99         {
 100                 me.nItems = 0;
 101                 return;
 102         }
 103         getAllHUDSkins(me, "");
 104         getAllHUDSkins(me, "data/");
 105         me.nItems = buf_getsize(me.listHUDSkin);
 106         if(me.nItems > 0)
 107                 buf_sort(me.listHUDSkin, 128, false);
 108 }
 109
 110 void XonoticHUDSkinList_destroy(entity me)
 111 {
 112         if(me.nItems > 0)
 113                 buf_del(me.listHUDSkin);
 114 }
 115
 116 void XonoticHUDSkinList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 117 {
 118         me.itemAbsSize = '0 0 0';
 119         SUPER(XonoticHUDSkinList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 120
 121         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize.y * me.itemHeight));
 122         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize.x * (1 - me.controlWidth)));
 123         me.realUpperMargin = 0.5 * (1 - me.realFontSize.y);
 124
 125         me.columnNameOrigin = me.realFontSize.x;
 126         me.columnNameSize = 1 - 2 * me.realFontSize.x;
 127 }
 128
 129 void XonoticHUDSkinList_drawListBoxItem(entity me, int i, vector absSize, bool isSelected, bool isFocused)
 130 {
 131         string s;
 132         if(isSelected)
 133                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 134         else if(isFocused)
 135         {
 136                 me.focusedItemAlpha = getFadedAlpha(me.focusedItemAlpha, SKINALPHA_LISTBOX_FOCUSED, SKINFADEALPHA_LISTBOX_FOCUSED);
 137                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_FOCUSED, me.focusedItemAlpha);
 138         }
 139
 140         s = me.hudskinName(me,i);
 141         s = draw_TextShortenToWidth(s, me.columnNameSize, 0, me.realFontSize);
 142         draw_Text(me.realUpperMargin * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, SKINCOLOR_TEXT, SKINALPHA_TEXT, 1);
 143 }
 144
 145 void XonoticHUDSkinList_showNotify(entity me)
 146 {
 147         me.getHUDSkins(me);
 148 }
 149
 150 void HUDSkinList_Refresh_Click(entity btn, entity me)
 151 {
 152         me.getHUDSkins(me);
 153         me.setSelected(me, 0); //always select the first element after a list update
 154 }
 155
 156 void HUDSkinList_Filter_Change(entity box, entity me)
 157 {
 158         if(me.filterString)
 159                 strunzone(me.filterString);
 160
 161         if(box.text != "")
 162         {
 163                 if (strstrofs(box.text, "*", 0) >= 0 || strstrofs(box.text, "?", 0) >= 0)
 164                         me.filterString = strzone(box.text);
 165                 else
 166                         me.filterString = strzone(strcat("*", box.text, "*"));
 167         }
 168         else
 169                 me.filterString = string_null;
 170
 171         me.getHUDSkins(me);
 172 }
 173
 174 void SaveHUDSkin_Click(entity btn, entity me)
 175 {
 176         localcmd("hud save myconfig\n");
 177         me.delayedRefreshTime = time + 1;
 178 }
 179
 180 void XonoticHUDSkinList_draw(entity me)
 181 {
 182         if(me.delayedRefreshTime > 0 && me.delayedRefreshTime < time)
 183         {
 184                 HUDSkinList_Refresh_Click(NULL, me);
 185                 me.delayedRefreshTime = 0;
 186         }
 187         SUPER(XonoticHUDSkinList).draw(me);
 188 }
 189
 190 void XonoticHUDSkinList_setHUDSkin(entity me)
 191 {
 192         string s = me.hudskinName(me, me.selectedItem);
 193         localcmd("exec \"hud_", s, ".cfg\"\n");
 194 }
 195
 196 void SetHUDSkin_Click(entity btn, entity me)
 197 {
 198         me.setHUDSkin(me);
 199 }
 200
 201 void XonoticHUDSkinList_doubleClickListBoxItem(entity me, float i, vector where)
 202 {
 203         m_play_click_sound(MENU_SOUND_EXECUTE);
 204         me.setHUDSkin(me);
 205 }
 206
 207 float XonoticHUDSkinList_keyDown(entity me, float scan, float ascii, float shift)
 208 {
 209         if(scan == K_ENTER || scan == K_KP_ENTER)
 210         {
 211                 me.setHUDSkin(me);
 212                 return 1;
 213         }
 214         else
 215         {
 216                 return SUPER(XonoticHUDSkinList).keyDown(me, scan, ascii, shift);
 217         }
 218 }
 219 #endif
 220