qcsrc/menu/xonotic/dialog_multiplayer_profile.qc

   1 #include "dialog_multiplayer_profile.qh"
   2
   3 #include "playermodel.qh"
   4 #include "statslist.qh"
   5 #include "languagelist.qh"
   6 #include "textlabel.qh"
   7 #include "commandbutton.qh"
   8 #include "inputbox.qh"
   9 #include "colorpicker.qh"
  10 #include "charmap.qh"
  11 #include "colorbutton.qh"
  12 #include "checkbox.qh"
  13 #include "radiobutton.qh"
  14
  15 entity makeXonoticProfileTab()
  16 {
  17         entity me;
  18         me = NEW(XonoticProfileTab);
  19         me.configureDialog(me);
  20         return me;
  21 }
  22 void XonoticProfileTab_draw(entity me)
  23 {
  24         if(cvar_string("_cl_name") == "Player")
  25                 me.playerNameLabel.alpha = ((mod(time * 2, 2) < 1) ? 1 : 0);
  26         else
  27                 me.playerNameLabel.alpha = me.playerNameLabelAlpha;
  28         SUPER(XonoticProfileTab).draw(me);
  29 }
  30 void language_selector_click(entity me, entity btn)
  31 {
  32         localcmd("\nmenu_cmd languageselect\n");
  33 }
  34 void XonoticProfileTab_fill(entity me)
  35 {
  36         entity e, pms, label, box;
  37         float i;
  38         entity profileApplyButton = makeXonoticCommandButton(_("Apply immediately"), '0 0 0',
  39                 "color -1 -1;"
  40                 "name \"$_cl_name\";"
  41                 "playermodel $_cl_playermodel;"
  42                 "playerskin $_cl_playerskin;"
  43                 , COMMANDBUTTON_APPLY);
  44         profileApplyButton.disableOnClick = true;
  45
  46         // ==============
  47         //  NAME SECTION
  48         // ==============
  49         me.gotoRC(me, 0.5, 0);
  50                 me.TD(me, 1, 3, me.playerNameLabel = makeXonoticHeaderLabel(_("Name")));
  51
  52         me.gotoRC(me, 1.5, 0);
  53                 me.TD(me, 1, 3, label = makeXonoticTextLabel(0.5, string_null));
  54                         label.allowCut = 1;
  55                         label.allowColors = 1;
  56                         label.alpha = 1;
  57                         label.isBold = true;
  58                         label.fontSize = SKINFONTSIZE_TITLE;
  59
  60         me.gotoRC(me, 2.5, 0);
  61                 me.TD(me, 1, 3.0, box = makeXonoticInputBox_T(1, "_cl_name",
  62                         _("Name under which you will appear in the game")));
  63                         box.forbiddenCharacters = "\r\n\\\"$"; // don't care, isn't getting saved
  64                         box.maxLength = -127; // negative means encoded length in bytes
  65                         box.saveImmediately = 0;  // Sorry, can't do this, it spams "name" commands.
  66                         box.enableClearButton = 0;
  67                         box.applyButton = profileApplyButton;
  68                         label.textEntity = box;
  69         me.TR(me);
  70                 me.TD(me, 5, 1, e = makeXonoticColorpicker(box));
  71                 me.TD(me, 5, 2, e = makeXonoticCharmap(box));
  72
  73         // ===============
  74         //  MODEL SECTION
  75         // ===============
  76         //me.gotoRC(me, 0.5, 3.1); me.setFirstColumn(me, me.currentColumn); // TOP RIGHT
  77         //me.gotoRC(me, 9, 3.1); me.setFirstColumn(me, me.currentColumn); // BOTTOM RIGHT
  78         me.gotoRC(me, 9, 0); me.setFirstColumn(me, me.currentColumn); // BOTTOM LEFT
  79                 me.TD(me, 1, 3, e = makeXonoticHeaderLabel(_("Model")));
  80
  81         me.TR(me);
  82                 //me.TDempty(me, 0); // MODEL LEFT, COLOR RIGHT
  83                 me.TDempty(me, 1); // MODEL RIGHT, COLOR LEFT
  84                 pms = makeXonoticPlayerModelSelector();
  85                 me.TD(me, 1, 0.3, e = makeXonoticButton("<<", '0 0 0'));
  86                         e.onClick = PlayerModelSelector_Prev_Click;
  87                         e.onClickEntity = pms;
  88                         e.applyButton = profileApplyButton;
  89                 me.TD(me, 11.5, 1.4, pms);
  90                 me.TD(me, 1, 0.3, e = makeXonoticButton(">>", '0 0 0'));
  91                         e.onClick = PlayerModelSelector_Next_Click;
  92                         e.onClickEntity = pms;
  93                         e.applyButton = profileApplyButton;
  94
  95         //me.setFirstColumn(me, me.currentColumn + 2); // MODEL LEFT, COLOR RIGHT
  96         me.gotoRC(me, me.currentRow, 0); me.setFirstColumn(me, me.currentColumn); // MODEL RIGHT, COLOR LEFT
  97         me.TR(me);
  98                 me.TD(me, 1, 1, e = makeXonoticHeaderLabel(_("Glowing color")));
  99                 for(i = 0; i < 15; ++i)
 100                 {
 101                         if(mod(i, 5) == 0)
 102                                 me.TR(me);
 103                         me.TDNoMargin(me, 1, 0.2, e = makeXonoticColorButton(1, 0, i), '0 1 0');
 104                                 e.applyButton = profileApplyButton;
 105                 }
 106         me.TR(me);
 107         me.TR(me);
 108                 me.TD(me, 1, 1, e = makeXonoticHeaderLabel(_("Detail color")));
 109                 for(i = 0; i < 15; ++i)
 110                 {
 111                         if(mod(i, 5) == 0)
 112                                 me.TR(me);
 113                         me.TDNoMargin(me, 1, 0.2, e = makeXonoticColorButton(2, 1, i), '0 1 0');
 114                                 e.applyButton = profileApplyButton;
 115                 }
 116
 117         // ====================
 118         //  STATISTICS SECTION
 119         // ====================
 120         me.gotoRC(me, 0.5, 3.1); me.setFirstColumn(me, me.currentColumn); // TOP RIGHT
 121         //me.gotoRC(me, 9, 3.1); me.setFirstColumn(me, me.currentColumn); // BOTTOM RIGHT
 122         //me.gotoRC(me, 9, 0); me.setFirstColumn(me, me.currentColumn); // BOTTOM LEFT
 123                 me.TD(me, 1, 3, e = makeXonoticHeaderLabel(_("Statistics")));
 124
 125         me.TR(me);
 126                 me.TDempty(me, 0.25);
 127                 me.TD(me, 1, 2.5, e = makeXonoticCheckBox(0, "cl_allow_uidtracking", _("Allow player statistics to track your client")));
 128                         e.sendCvars = true;
 129         me.TR(me);
 130                 me.TDempty(me, 0.25);
 131                 me.TD(me, 1, 2.5, e = makeXonoticCheckBox(0, "cl_allow_uid2name", _("Allow player statistics to use your nickname")));
 132                         e.sendCvars = true;
 133                         setDependent(e, "cl_allow_uidtracking", 1, 1);
 134         me.gotoRC(me, 4, 3.1); // TOP RIGHT
 135         //me.gotoRC(me, 12.5, 3.1); // BOTTOM RIGHT
 136         //me.gotoRC(me, 12.5, 0); // BOTTOM LEFT
 137                 me.TDempty(me, 0.25);
 138                 me.TD(me, 9, 2.5, statslist = makeXonoticStatsList());
 139                 //setDependent(statslist, "cl_allow_uidtracking", 1, 1);
 140
 141         // =================
 142         //  COUNTRY SECTION
 143         // =================
 144         me.gotoRC(me, 16, 3.1); me.setFirstColumn(me, me.currentColumn); // BOTTOM SECTION, TOP POS
 145         //me.gotoRC(me, 13.5, 3.1); me.setFirstColumn(me, me.currentColumn); // BOTTOM SECTION, TOP POS
 146         //me.gotoRC(me, 0.5, 3.1); me.setFirstColumn(me, me.currentColumn); // TOP SECTION, TOP POS
 147                 me.TD(me, 1, 3, e = makeXonoticHeaderLabel(_("Country")));
 148
 149         me.TR(me);
 150                 me.TDempty(me, 0.75);
 151                 me.TD(me, 1, 1.5, e = makeXonoticButton(_("Select language..."), '0 0 0'));
 152                         e.onClick = language_selector_click;
 153                         e.onClickEntity = me;
 154                 /*
 155                 me.TDempty(me, 0.5);
 156                 me.TD(me, 4.5, 2, e = makeXonoticLanguageList()); // todo: cl_country: create proper country list
 157                 */
 158
 159
 160         // ================
 161         //  GENDER SECTION
 162         // ================
 163         me.gotoRC(me, 13.5, 3.1); me.setFirstColumn(me, me.currentColumn); // BOTTOM SECTION, TOP POS
 164         //me.gotoRC(me, 19.5, 3.1); me.setFirstColumn(me, me.currentColumn); // BOTTOM SECTION, BOTTOM POS
 165         //me.gotoRC(me, 6.5, 3.1); me.setFirstColumn(me, me.currentColumn); // TOP SECTION, BOTTOM POS
 166         #if 0
 167                 me.TD(me, 1, 1, e = makeXonoticTextLabel(0, _("Gender:")));
 168                 me.TD(me, 1, 2, e = makeXonoticTextSlider("_cl_gender"));
 169                         e.addValue(e, _("Undisclosed"), "0");
 170                         e.addValue(e, _("Female"), "1");
 171                         e.addValue(e, _("Male"), "2");
 172                         e.configureXonoticTextSliderValues(e);
 173         #else
 174                         me.TD(me, 1, 3, e = makeXonoticHeaderLabel(_("Gender")));
 175                 me.TR(me);
 176                         #define GENDERWIDTH_OFFSET 0.25
 177                         #define GENDERWIDTH_LENGTH 2.5
 178                         #define GENDERWIDTH_ITEM (GENDERWIDTH_LENGTH / 3)
 179                         me.TDempty(me, GENDERWIDTH_OFFSET);
 180                         me.TD(me, 1, GENDERWIDTH_ITEM, e = makeXonoticRadioButton(3, "_cl_gender", "2", _("Female")));
 181                         me.TD(me, 1, GENDERWIDTH_ITEM, e = makeXonoticRadioButton(3, "_cl_gender", "1", _("Male")));
 182                         me.TD(me, 1, GENDERWIDTH_ITEM, e = makeXonoticRadioButton(3, "_cl_gender", "0", _("Undisclosed")));
 183         #endif
 184
 185         me.gotoRC(me, me.rows - 1, 0);
 186                 me.TD(me, 1, me.columns, profileApplyButton);
 187 }