qcsrc/common/weapons/w_vaporizer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ VAPORIZER,
   4 /* function  */ W_Vaporizer,
   5 /* ammotype  */ ammo_cells,
   6 /* impulse   */ 7,
   7 /* flags     */ WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_FLAG_SUPERWEAPON | WEP_TYPE_HITSCAN,
   8 /* rating    */ BOT_PICKUP_RATING_HIGH,
   9 /* color     */ '0.5 1 1',
  10 /* modelname */ "minstanex",
  11 /* simplemdl */ "foobar",
  12 /* crosshair */ "gfx/crosshairminstanex 0.4",
  13 /* refname   */ "vaporizer",
  14 /* wepname   */ _("Vaporizer")
  15 );
  16
  17 #define VAPORIZER_SETTINGS(w_cvar,w_prop) VAPORIZER_SETTINGS_LIST(w_cvar, w_prop, VAPORIZER, vaporizer)
  18 #define VAPORIZER_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  19         w_cvar(id, sn, PRI, ammo) \
  20         w_cvar(id, sn, PRI, animtime) \
  21         w_cvar(id, sn, PRI, refire) \
  22         w_cvar(id, sn, SEC, ammo) \
  23         w_cvar(id, sn, SEC, animtime) \
  24         w_cvar(id, sn, SEC, damage) \
  25         w_cvar(id, sn, SEC, delay) \
  26         w_cvar(id, sn, SEC, edgedamage) \
  27         w_cvar(id, sn, SEC, force) \
  28         w_cvar(id, sn, SEC, lifetime) \
  29         w_cvar(id, sn, SEC, radius) \
  30         w_cvar(id, sn, SEC, refire) \
  31         w_cvar(id, sn, SEC, shotangle) \
  32         w_cvar(id, sn, SEC, speed) \
  33         w_cvar(id, sn, SEC, spread) \
  34         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  35         w_prop(id, sn, float,  reloading_time, reload_time) \
  36         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  37         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  38         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  39         w_prop(id, sn, float,  weaponstart, weaponstart) \
  40         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride)
  41
  42 #ifdef SVQC
  43 VAPORIZER_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  44 .float vaporizer_lasthit;
  45 .float jump_interval;
  46 #endif
  47 #else
  48 #ifdef SVQC
  49 void spawnfunc_weapon_vaporizer (void) { weapon_defaultspawnfunc(WEP_VAPORIZER); }
  50 void spawnfunc_weapon_minstanex () { spawnfunc_weapon_vaporizer(); }
  51
  52 void W_Vaporizer_Attack (void)
  53 {
  54         float flying;
  55         flying = IsFlying(self); // do this BEFORE to make the trace values from FireRailgunBullet last
  56
  57         W_SetupShot (self, TRUE, 0, "weapons/minstanexfire.wav", CH_WEAPON_A, 10000);
  58
  59         yoda = 0;
  60         damage_goodhits = 0;
  61         FireRailgunBullet (w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, 10000, 800, 0, 0, 0, 0, WEP_VAPORIZER);
  62
  63         if(yoda && flying)
  64                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_ACHIEVEMENT_YODA);
  65         if(damage_goodhits && self.vaporizer_lasthit)
  66         {
  67                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_ACHIEVEMENT_IMPRESSIVE);
  68                 damage_goodhits = 0; // only every second time
  69         }
  70
  71         self.vaporizer_lasthit = damage_goodhits;
  72
  73         pointparticles(particleeffectnum("nex_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  74
  75         // teamcolor / hit beam effect
  76         vector v;
  77         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
  78         switch(self.team)
  79         {
  80                 case NUM_TEAM_1:   // Red
  81                         if(damage_goodhits)
  82                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3RED_HIT"), w_shotorg, v);
  83                         else
  84                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3RED"), w_shotorg, v);
  85                         break;
  86                 case NUM_TEAM_2:   // Blue
  87                         if(damage_goodhits)
  88                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3BLUE_HIT"), w_shotorg, v);
  89                         else
  90                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3BLUE"), w_shotorg, v);
  91                         break;
  92                 case NUM_TEAM_3:   // Yellow
  93                         if(damage_goodhits)
  94                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3YELLOW_HIT"), w_shotorg, v);
  95                         else
  96                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3YELLOW"), w_shotorg, v);
  97                         break;
  98                 case NUM_TEAM_4:   // Pink
  99                         if(damage_goodhits)
 100                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3PINK_HIT"), w_shotorg, v);
 101                         else
 102                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3PINK"), w_shotorg, v);
 103                         break;
 104                 default:
 105                         if(damage_goodhits)
 106                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3_HIT"), w_shotorg, v);
 107                         else
 108                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3"), w_shotorg, v);
 109                         break;
 110         }
 111
 112         W_DecreaseAmmo(((g_minstagib) ? 1 : WEP_CVAR_PRI(vaporizer, ammo)));
 113 }
 114
 115 float W_Vaporizer(float req)
 116 {
 117         float ammo_amount;
 118         float vaporizer_ammo;
 119
 120         // now multiple WR_s use this
 121         vaporizer_ammo = ((g_minstagib) ? 1 : WEP_CVAR_PRI(vaporizer, ammo));
 122
 123         switch(req)
 124         {
 125                 case WR_AIM:
 126                 {
 127                         if(self.WEP_AMMO(VAPORIZER) > 0)
 128                                 self.BUTTON_ATCK = bot_aim(1000000, 0, 1, FALSE);
 129                         else
 130                                 self.BUTTON_ATCK2 = bot_aim(WEP_CVAR_SEC(vaporizer, speed), 0, WEP_CVAR_SEC(vaporizer, lifetime), FALSE); // WEAPONTODO: replace with proper vaporizer cvars
 131
 132                         return TRUE;
 133                 }
 134                 case WR_THINK:
 135                 {
 136                         // if the laser uses load, we also consider its ammo for reloading
 137                         if(WEP_CVAR(vaporizer, reload_ammo) && WEP_CVAR_SEC(vaporizer, ammo) && self.clip_load < min(vaporizer_ammo, WEP_CVAR_SEC(vaporizer, ammo))) // forced reload
 138                                 WEP_ACTION(self.weapon, WR_RELOAD);
 139                         else if(WEP_CVAR(vaporizer, reload_ammo) && self.clip_load < vaporizer_ammo) // forced reload
 140                                 WEP_ACTION(self.weapon, WR_RELOAD);
 141                         else if (self.BUTTON_ATCK)
 142                         {
 143                                 if (weapon_prepareattack(0, WEP_CVAR_PRI(vaporizer, refire)))
 144                                 {
 145                                         W_Vaporizer_Attack();
 146                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(vaporizer, animtime), w_ready);
 147                                 }
 148                         }
 149                         else if (self.BUTTON_ATCK2)
 150                         {
 151                                 if (self.jump_interval <= time)
 152                                 if (weapon_prepareattack(1, -1))
 153                                 {
 154                                         // handle refire manually, so that primary and secondary can be fired without conflictions (important for minstagib)
 155                                         self.jump_interval = time + WEP_CVAR_SEC(vaporizer, refire) * W_WeaponRateFactor();
 156
 157                                         // decrease ammo for the laser?
 158                                         if(WEP_CVAR_SEC(vaporizer, ammo))
 159                                                 W_DecreaseAmmo(WEP_CVAR_SEC(vaporizer, ammo));
 160
 161                                         // ugly minstagib hack to reuse the fire mode of the laser
 162                                         float w;
 163                                         w = self.weapon;
 164                                         self.weapon = WEP_BLASTER;
 165                                         W_Blaster_Attack(
 166                                                 WEP_CVAR_SEC(vaporizer, shotangle),
 167                                                 WEP_CVAR_SEC(vaporizer, damage),
 168                                                 WEP_CVAR_SEC(vaporizer, edgedamage),
 169                                                 WEP_CVAR_SEC(vaporizer, radius),
 170                                                 WEP_CVAR_SEC(vaporizer, force),
 171                                                 WEP_CVAR_SEC(vaporizer, speed),
 172                                                 WEP_CVAR_SEC(vaporizer, spread),
 173                                                 WEP_CVAR_SEC(vaporizer, delay),
 174                                                 WEP_CVAR_SEC(vaporizer, lifetime)
 175                                         );
 176                                         self.weapon = w;
 177
 178                                         // now do normal refire
 179                                         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(vaporizer, animtime), w_ready);
 180                                 }
 181                         }
 182
 183                         return TRUE;
 184                 }
 185                 case WR_INIT:
 186                 {
 187                         precache_model("models/nexflash.md3");
 188                         precache_model("models/weapons/g_minstanex.md3");
 189                         precache_model("models/weapons/v_minstanex.md3");
 190                         precache_model("models/weapons/h_minstanex.iqm");
 191                         precache_sound("weapons/minstanexfire.wav");
 192                         precache_sound("weapons/nexwhoosh1.wav");
 193                         precache_sound("weapons/nexwhoosh2.wav");
 194                         precache_sound("weapons/nexwhoosh3.wav");
 195                         //W_Blaster(WR_INIT); // Samual: Is this really the proper thing to do? Didn't we already run this previously?
 196                         VAPORIZER_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP)
 197                         return TRUE;
 198                 }
 199                 case WR_SETUP:
 200                 {
 201                         self.ammo_field = WEP_AMMO(VAPORIZER);
 202                         self.vaporizer_lasthit = 0;
 203                         return TRUE;
 204                 }
 205                 case WR_CHECKAMMO1:
 206                 {
 207                         ammo_amount = self.WEP_AMMO(VAPORIZER) >= vaporizer_ammo;
 208                         ammo_amount += self.(weapon_load[WEP_VAPORIZER]) >= vaporizer_ammo;
 209                         return ammo_amount;
 210                 }
 211                 case WR_CHECKAMMO2:
 212                 {
 213                         if(!WEP_CVAR_SEC(vaporizer, ammo))
 214                                 return TRUE;
 215                         ammo_amount = self.WEP_AMMO(VAPORIZER) >= WEP_CVAR_SEC(vaporizer, ammo);
 216                         ammo_amount += self.(weapon_load[WEP_VAPORIZER]) >= WEP_CVAR_SEC(vaporizer, ammo);
 217                         return ammo_amount;
 218                 }
 219                 case WR_CONFIG:
 220                 {
 221                         VAPORIZER_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 222                         return TRUE;
 223                 }
 224                 case WR_RESETPLAYER:
 225                 {
 226                         self.vaporizer_lasthit = 0;
 227                         return TRUE;
 228                 }
 229                 case WR_RELOAD:
 230                 {
 231                         float used_ammo;
 232                         if(WEP_CVAR_SEC(vaporizer, ammo))
 233                                 used_ammo = min(vaporizer_ammo, WEP_CVAR_SEC(vaporizer, ammo));
 234                         else
 235                                 used_ammo = vaporizer_ammo;
 236
 237                         W_Reload(used_ammo, "weapons/reload.wav");
 238                         return TRUE;
 239                 }
 240                 case WR_SUICIDEMESSAGE:
 241                 {
 242                         return WEAPON_THINKING_WITH_PORTALS;
 243                 }
 244                 case WR_KILLMESSAGE:
 245                 {
 246                         return WEAPON_VAPORIZER_MURDER;
 247                 }
 248         }
 249         return TRUE;
 250 }
 251 #endif
 252 #ifdef CSQC
 253 float W_Vaporizer(float req)
 254 {
 255         switch(req)
 256         {
 257                 case WR_IMPACTEFFECT:
 258                 {
 259                         vector org2;
 260                         org2 = w_org + w_backoff * 6;
 261                         pointparticles(particleeffectnum("nex_impact"), org2, '0 0 0', 1);
 262                         if(!w_issilent)
 263                                 sound(self, CH_SHOTS, "weapons/neximpact.wav", VOL_BASE, ATTN_NORM);
 264
 265                         return TRUE;
 266                 }
 267                 case WR_INIT:
 268                 {
 269                         precache_sound("weapons/neximpact.wav");
 270                         if(autocvar_cl_reticle && autocvar_cl_reticle_weapon)
 271                         {
 272                                 precache_pic("gfx/reticle_nex");
 273                         }
 274                         return TRUE;
 275                 }
 276                 case WR_ZOOMRETICLE:
 277                 {
 278                         if(button_zoom || zoomscript_caught)
 279                         {
 280                                 reticle_image = "gfx/reticle_nex";
 281                                 return TRUE;
 282                         }
 283                         else
 284                         {
 285                                 // no weapon specific image for this weapon
 286                                 return FALSE;
 287                         }
 288                 }
 289         }
 290         return TRUE;
 291 }
 292 #endif
 293 #endif