qcsrc/common/weapons/w_vaporizer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ VAPORIZER,
   4 /* function  */ W_Vaporizer,
   5 /* ammotype  */ ammo_cells,
   6 /* impulse   */ 7,
   7 /* flags     */ WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_FLAG_SUPERWEAPON | WEP_TYPE_HITSCAN,
   8 /* rating    */ BOT_PICKUP_RATING_HIGH,
   9 /* color     */ '0.5 1 1',
  10 /* modelname */ "minstanex",
  11 /* simplemdl */ "foobar",
  12 /* crosshair */ "gfx/crosshairminstanex 0.6",
  13 /* wepimg    */ "weaponminstanex",
  14 /* refname   */ "vaporizer",
  15 /* wepname   */ _("Vaporizer")
  16 );
  17
  18 #define VAPORIZER_SETTINGS(w_cvar,w_prop) VAPORIZER_SETTINGS_LIST(w_cvar, w_prop, VAPORIZER, vaporizer)
  19 #define VAPORIZER_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  20         w_cvar(id, sn, PRI, ammo) \
  21         w_cvar(id, sn, PRI, animtime) \
  22         w_cvar(id, sn, PRI, damage) \
  23         w_cvar(id, sn, PRI, refire) \
  24         w_cvar(id, sn, SEC, ammo) \
  25         w_cvar(id, sn, SEC, animtime) \
  26         w_cvar(id, sn, SEC, damage) \
  27         w_cvar(id, sn, SEC, delay) \
  28         w_cvar(id, sn, SEC, edgedamage) \
  29         w_cvar(id, sn, SEC, force) \
  30         w_cvar(id, sn, SEC, lifetime) \
  31         w_cvar(id, sn, SEC, radius) \
  32         w_cvar(id, sn, SEC, refire) \
  33         w_cvar(id, sn, SEC, shotangle) \
  34         w_cvar(id, sn, SEC, speed) \
  35         w_cvar(id, sn, SEC, spread) \
  36         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  37         w_prop(id, sn, float,  reloading_time, reload_time) \
  38         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  39         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  40         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  41         w_prop(id, sn, float,  weaponstart, weaponstart) \
  42         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
  43         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
  44
  45 #ifdef SVQC
  46 VAPORIZER_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  47 .float vaporizer_lasthit;
  48 .float jump_interval;
  49 #endif
  50 #else
  51 #ifdef SVQC
  52 void spawnfunc_weapon_vaporizer(void) { weapon_defaultspawnfunc(WEP_VAPORIZER); }
  53 void spawnfunc_weapon_minstanex(void) { spawnfunc_weapon_vaporizer(); }
  54
  55 void W_Vaporizer_Attack(void)
  56 {
  57         float flying, vaporizer_damage;
  58         flying = IsFlying(self); // do this BEFORE to make the trace values from FireRailgunBullet last
  59         vaporizer_damage = ((WEP_CVAR_PRI(vaporizer, damage) > 0) ? WEP_CVAR_PRI(vaporizer, damage) : 10000);
  60
  61         W_SetupShot(self, true, 0, "", CH_WEAPON_A, vaporizer_damage);
  62         // handle sound separately so we can change the volume
  63         // added bonus: no longer plays the strength sound (strength gives no bonus to instakill anyway)
  64         sound (self, CH_WEAPON_A, "weapons/minstanexfire.wav", VOL_BASE * 0.8, ATTEN_NORM);
  65
  66         yoda = 0;
  67         damage_goodhits = 0;
  68         FireRailgunBullet(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, vaporizer_damage, 800, 0, 0, 0, 0, WEP_VAPORIZER);
  69
  70         if(yoda && flying)
  71                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_ACHIEVEMENT_YODA);
  72         if(damage_goodhits && self.vaporizer_lasthit)
  73         {
  74                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_ACHIEVEMENT_IMPRESSIVE);
  75                 damage_goodhits = 0; // only every second time
  76         }
  77
  78         self.vaporizer_lasthit = damage_goodhits;
  79
  80         pointparticles(particleeffectnum("nex_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  81
  82         // teamcolor / hit beam effect
  83         vector v;
  84         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
  85         switch(self.team)
  86         {
  87                 case NUM_TEAM_1:   // Red
  88                         if(damage_goodhits)
  89                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3RED_HIT"), w_shotorg, v);
  90                         else
  91                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3RED"), w_shotorg, v);
  92                         break;
  93                 case NUM_TEAM_2:   // Blue
  94                         if(damage_goodhits)
  95                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3BLUE_HIT"), w_shotorg, v);
  96                         else
  97                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3BLUE"), w_shotorg, v);
  98                         break;
  99                 case NUM_TEAM_3:   // Yellow
 100                         if(damage_goodhits)
 101                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3YELLOW_HIT"), w_shotorg, v);
 102                         else
 103                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3YELLOW"), w_shotorg, v);
 104                         break;
 105                 case NUM_TEAM_4:   // Pink
 106                         if(damage_goodhits)
 107                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3PINK_HIT"), w_shotorg, v);
 108                         else
 109                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3PINK"), w_shotorg, v);
 110                         break;
 111                 default:
 112                         if(damage_goodhits)
 113                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3_HIT"), w_shotorg, v);
 114                         else
 115                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3"), w_shotorg, v);
 116                         break;
 117         }
 118
 119         W_DecreaseAmmo(((g_instagib) ? 1 : WEP_CVAR_PRI(vaporizer, ammo)));
 120 }
 121
 122 float W_Vaporizer(float req)
 123 {
 124         float ammo_amount;
 125         float vaporizer_ammo;
 126
 127         // now multiple WR_s use this
 128         vaporizer_ammo = ((g_instagib) ? 1 : WEP_CVAR_PRI(vaporizer, ammo));
 129
 130         switch(req)
 131         {
 132                 case WR_AIM:
 133                 {
 134                         if(self.WEP_AMMO(VAPORIZER) > 0)
 135                                 self.BUTTON_ATCK = bot_aim(1000000, 0, 1, false);
 136                         else
 137                                 self.BUTTON_ATCK2 = bot_aim(WEP_CVAR_SEC(vaporizer, speed), 0, WEP_CVAR_SEC(vaporizer, lifetime), false); // WEAPONTODO: replace with proper vaporizer cvars
 138
 139                         return true;
 140                 }
 141                 case WR_THINK:
 142                 {
 143                         // if the laser uses load, we also consider its ammo for reloading
 144                         if(WEP_CVAR(vaporizer, reload_ammo) && WEP_CVAR_SEC(vaporizer, ammo) && self.clip_load < min(vaporizer_ammo, WEP_CVAR_SEC(vaporizer, ammo))) // forced reload
 145                                 WEP_ACTION(self.weapon, WR_RELOAD);
 146                         else if(WEP_CVAR(vaporizer, reload_ammo) && self.clip_load < vaporizer_ammo) // forced reload
 147                                 WEP_ACTION(self.weapon, WR_RELOAD);
 148                         else if(self.BUTTON_ATCK)
 149                         {
 150                                 if(weapon_prepareattack(0, WEP_CVAR_PRI(vaporizer, refire)))
 151                                 {
 152                                         W_Vaporizer_Attack();
 153                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(vaporizer, animtime), w_ready);
 154                                 }
 155                         }
 156                         else if(self.BUTTON_ATCK2)
 157                         {
 158                                 if(self.jump_interval <= time)
 159                                 if(weapon_prepareattack(1, -1))
 160                                 {
 161                                         // handle refire manually, so that primary and secondary can be fired without conflictions (important for instagib)
 162                                         self.jump_interval = time + WEP_CVAR_SEC(vaporizer, refire) * W_WeaponRateFactor();
 163
 164                                         // decrease ammo for the laser?
 165                                         if(WEP_CVAR_SEC(vaporizer, ammo))
 166                                                 W_DecreaseAmmo(WEP_CVAR_SEC(vaporizer, ammo));
 167
 168                                         // ugly instagib hack to reuse the fire mode of the laser
 169                                         int oldwep = self.weapon; // we can't avoid this hack
 170                                         self.weapon = WEP_BLASTER;
 171                                         W_Blaster_Attack(
 172                                                 WEP_BLASTER | HITTYPE_SECONDARY,
 173                                                 WEP_CVAR_SEC(vaporizer, shotangle),
 174                                                 WEP_CVAR_SEC(vaporizer, damage),
 175                                                 WEP_CVAR_SEC(vaporizer, edgedamage),
 176                                                 WEP_CVAR_SEC(vaporizer, radius),
 177                                                 WEP_CVAR_SEC(vaporizer, force),
 178                                                 WEP_CVAR_SEC(vaporizer, speed),
 179                                                 WEP_CVAR_SEC(vaporizer, spread),
 180                                                 WEP_CVAR_SEC(vaporizer, delay),
 181                                                 WEP_CVAR_SEC(vaporizer, lifetime)
 182                                         );
 183                                         self.weapon = oldwep;
 184
 185                                         // now do normal refire
 186                                         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(vaporizer, animtime), w_ready);
 187                                 }
 188                         }
 189
 190                         return true;
 191                 }
 192                 case WR_INIT:
 193                 {
 194                         precache_model("models/nexflash.md3");
 195                         precache_model("models/weapons/g_minstanex.md3");
 196                         precache_model("models/weapons/v_minstanex.md3");
 197                         precache_model("models/weapons/h_minstanex.iqm");
 198                         precache_sound("weapons/minstanexfire.wav");
 199                         precache_sound("weapons/nexwhoosh1.wav");
 200                         precache_sound("weapons/nexwhoosh2.wav");
 201                         precache_sound("weapons/nexwhoosh3.wav");
 202                         //W_Blaster(WR_INIT); // Samual: Is this really the proper thing to do? Didn't we already run this previously?
 203                         VAPORIZER_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP);
 204                         return true;
 205                 }
 206                 case WR_SETUP:
 207                 {
 208                         self.ammo_field = WEP_AMMO(VAPORIZER);
 209                         self.vaporizer_lasthit = 0;
 210                         return true;
 211                 }
 212                 case WR_CHECKAMMO1:
 213                 {
 214                         ammo_amount = self.WEP_AMMO(VAPORIZER) >= vaporizer_ammo;
 215                         ammo_amount += self.(weapon_load[WEP_VAPORIZER]) >= vaporizer_ammo;
 216                         return ammo_amount;
 217                 }
 218                 case WR_CHECKAMMO2:
 219                 {
 220                         if(!WEP_CVAR_SEC(vaporizer, ammo))
 221                                 return true;
 222                         ammo_amount = self.WEP_AMMO(VAPORIZER) >= WEP_CVAR_SEC(vaporizer, ammo);
 223                         ammo_amount += self.(weapon_load[WEP_VAPORIZER]) >= WEP_CVAR_SEC(vaporizer, ammo);
 224                         return ammo_amount;
 225                 }
 226                 case WR_CONFIG:
 227                 {
 228                         VAPORIZER_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS);
 229                         return true;
 230                 }
 231                 case WR_RESETPLAYER:
 232                 {
 233                         self.vaporizer_lasthit = 0;
 234                         return true;
 235                 }
 236                 case WR_RELOAD:
 237                 {
 238                         float used_ammo;
 239                         if(WEP_CVAR_SEC(vaporizer, ammo))
 240                                 used_ammo = min(vaporizer_ammo, WEP_CVAR_SEC(vaporizer, ammo));
 241                         else
 242                                 used_ammo = vaporizer_ammo;
 243
 244                         W_Reload(used_ammo, "weapons/reload.wav");
 245                         return true;
 246                 }
 247                 case WR_SUICIDEMESSAGE:
 248                 {
 249                         return WEAPON_THINKING_WITH_PORTALS;
 250                 }
 251                 case WR_KILLMESSAGE:
 252                 {
 253                         return WEAPON_VAPORIZER_MURDER;
 254                 }
 255         }
 256         return false;
 257 }
 258 #endif
 259 #ifdef CSQC
 260 float W_Vaporizer(float req)
 261 {
 262         switch(req)
 263         {
 264                 case WR_IMPACTEFFECT:
 265                 {
 266                         vector org2;
 267                         org2 = w_org + w_backoff * 6;
 268                         if(w_deathtype & HITTYPE_SECONDARY)
 269                         {
 270                                 pointparticles(particleeffectnum("laser_impact"), org2, w_backoff * 1000, 1);
 271                                 if(!w_issilent) { sound(self, CH_SHOTS, "weapons/laserimpact.wav", VOL_BASE, ATTN_NORM); }
 272                         }
 273                         else
 274                         {
 275                                 pointparticles(particleeffectnum("nex_impact"), org2, '0 0 0', 1);
 276                                 if(!w_issilent) { sound(self, CH_SHOTS, "weapons/neximpact.wav", VOL_BASE, ATTN_NORM); }
 277                         }
 278                         return true;
 279                 }
 280                 case WR_INIT:
 281                 {
 282                         precache_sound("weapons/laserimpact.wav");
 283                         precache_sound("weapons/neximpact.wav");
 284                         if(autocvar_cl_reticle && autocvar_cl_reticle_weapon)
 285                         {
 286                                 precache_pic("gfx/reticle_nex");
 287                         }
 288                         return true;
 289                 }
 290                 case WR_ZOOMRETICLE:
 291                 {
 292                         if(button_zoom || zoomscript_caught)
 293                         {
 294                                 reticle_image = "gfx/reticle_nex";
 295                                 return true;
 296                         }
 297                         else
 298                         {
 299                                 // no weapon specific image for this weapon
 300                                 return false;
 301                         }
 302                 }
 303         }
 304         return false;
 305 }
 306 #endif
 307 #endif