qcsrc/common/weapons/w_seeker.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ SEEKER,
   4 /* function */ w_seeker,
   5 /* ammotype */ IT_ROCKETS,
   6 /* impulse  */ 8,
   7 /* flags    */ WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH,
   8 /* rating   */ BOT_PICKUP_RATING_MID,
   9 /* model    */ "seeker",
  10 /* netname  */ "seeker",
  11 /* fullname */ _("T.A.G. Seeker")
  12 );
  13
  14 #define SEEKER_SETTINGS(w_cvar,w_prop) \
  15         w_cvar(WEP_SEEKER, seeker, MO_NONE, type) \
  16         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_ammo) \
  17         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_animtime) \
  18         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_damage) \
  19         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_edgedamage) \
  20         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_force) \
  21         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_lifetime) \
  22         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_lifetime_rand) \
  23         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_radius) \
  24         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_refire) \
  25         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_accel) \
  26         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_ammo) \
  27         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_animtime) \
  28         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_count) \
  29         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_damage) \
  30         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_damageforcescale) \
  31         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_decel) \
  32         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_delay) \
  33         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_edgedamage) \
  34         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_force) \
  35         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_health) \
  36         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_lifetime) \
  37         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_proxy) \
  38         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_proxy_delay) \
  39         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_proxy_maxrange) \
  40         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_radius) \
  41         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_refire) \
  42         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_smart) \
  43         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_smart_mindist) \
  44         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_smart_trace_max) \
  45         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_smart_trace_min) \
  46         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_speed_max) \
  47         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_turnrate) \
  48         w_cvar(WEP_SEEKER, seeker, MO_NONE, tag_ammo) \
  49         w_cvar(WEP_SEEKER, seeker, MO_NONE, tag_animtime) \
  50         w_cvar(WEP_SEEKER, seeker, MO_NONE, tag_damageforcescale) \
  51         w_cvar(WEP_SEEKER, seeker, MO_NONE, tag_health) \
  52         w_cvar(WEP_SEEKER, seeker, MO_NONE, tag_lifetime) \
  53         w_cvar(WEP_SEEKER, seeker, MO_NONE, tag_refire) \
  54         w_cvar(WEP_SEEKER, seeker, MO_NONE, tag_speed) \
  55         w_cvar(WEP_SEEKER, seeker, MO_NONE, tag_tracker_lifetime) \
  56         w_prop(WEP_SEEKER, seeker, reloading_ammo, reload_ammo) \
  57         w_prop(WEP_SEEKER, seeker, reloading_time, reload_time) \
  58         w_prop(WEP_SEEKER, seeker, switchdelay_raise, switchdelay_raise) \
  59         w_prop(WEP_SEEKER, seeker, switchdelay_drop, switchdelay_drop)
  60
  61 #ifdef SVQC
  62 SEEKER_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  63 .entity tag_target, wps_tag_tracker;
  64 .float tag_time;
  65 #endif
  66 #else
  67 #ifdef SVQC
  68 void spawnfunc_weapon_seeker (void) { weapon_defaultspawnfunc(WEP_SEEKER); }
  69
  70 // ============================
  71 // Begin: Missile functions, these are general functions to be manipulated by other code
  72 // ============================
  73 void Seeker_Missile_Explode ()
  74 {
  75         self.event_damage = func_null;
  76         RadiusDamage (self, self.realowner, WEP_CVAR(seeker, missile_damage), WEP_CVAR(seeker, missile_edgedamage), WEP_CVAR(seeker, missile_radius), world, world, WEP_CVAR(seeker, missile_force), self.projectiledeathtype, other);
  77
  78         remove (self);
  79 }
  80
  81 void Seeker_Missile_Touch()
  82 {
  83         PROJECTILE_TOUCH;
  84
  85         Seeker_Missile_Explode();
  86 }
  87
  88 void Seeker_Missile_Think()
  89 {
  90         entity e;
  91         vector desireddir, olddir, newdir, eorg;
  92         float turnrate;
  93         float dist;
  94         float spd;
  95
  96         if (time > self.cnt)
  97         {
  98                 self.projectiledeathtype |= HITTYPE_SPLASH;
  99                 Seeker_Missile_Explode();
 100         }
 101
 102         spd = vlen(self.velocity);
 103         spd = bound(
 104                 spd - WEP_CVAR(seeker, missile_decel) * frametime,
 105                 WEP_CVAR(seeker, missile_speed_max),
 106                 spd + WEP_CVAR(seeker, missile_accel) * frametime
 107         );
 108
 109         if (self.enemy != world)
 110                 if (self.enemy.takedamage != DAMAGE_AIM || self.enemy.deadflag != DEAD_NO)
 111                         self.enemy = world;
 112
 113         if (self.enemy != world)
 114         {
 115                 e               = self.enemy;
 116                 eorg            = 0.5 * (e.absmin + e.absmax);
 117                 turnrate        = WEP_CVAR(seeker, missile_turnrate); // how fast to turn
 118                 desireddir      = normalize(eorg - self.origin);
 119                 olddir          = normalize(self.velocity); // get my current direction
 120                 dist            = vlen(eorg - self.origin);
 121
 122                 // Do evasive maneuvers for world objects? ( this should be a cpu hog. :P )
 123                 if (WEP_CVAR(seeker, missile_smart) && (dist > WEP_CVAR(seeker, missile_smart_mindist)))
 124                 {
 125                         // Is it a better idea (shorter distance) to trace to the target itself?
 126                         if ( vlen(self.origin + olddir * self.wait) < dist)
 127                                 traceline(self.origin, self.origin + olddir * self.wait, FALSE, self);
 128                         else
 129                                 traceline(self.origin, eorg, FALSE, self);
 130
 131                         // Setup adaptive tracelength
 132                         self.wait = bound(WEP_CVAR(seeker, missile_smart_trace_min), vlen(self.origin - trace_endpos), self.wait = WEP_CVAR(seeker, missile_smart_trace_max));
 133
 134                         // Calc how important it is that we turn and add this to the desierd (enemy) dir.
 135                         desireddir  = normalize(((trace_plane_normal * (1 - trace_fraction)) + (desireddir * trace_fraction)) * 0.5);
 136                 }
 137
 138                 newdir = normalize(olddir + desireddir * turnrate); // take the average of the 2 directions; not the best method but simple & easy
 139                 self.velocity = newdir * spd; // make me fly in the new direction at my flight speed
 140         }
 141         else
 142                 dist = 0;
 143
 144         // Proxy
 145         if (WEP_CVAR(seeker, missile_proxy))
 146         {
 147                 if ( dist <= WEP_CVAR(seeker, missile_proxy_maxrange))
 148                 {
 149                         if (self.autoswitch == 0)
 150                         {
 151                                 self.autoswitch = time + WEP_CVAR(seeker, missile_proxy_delay);
 152                         }
 153                         else
 154                         {
 155                                 if (self.autoswitch <= time)
 156                                 {
 157                                         Seeker_Missile_Explode();
 158                                         self.autoswitch = 0;
 159                                 }
 160                         }
 161                 }
 162                 else
 163                 {
 164                         if (self.autoswitch != 0)
 165                                 self.autoswitch = 0;
 166                 }
 167         }
 168         ///////////////
 169
 170         if (self.enemy.deadflag != DEAD_NO)
 171         {
 172                 self.enemy = world;
 173                 self.cnt = time + 1 + (random() * 4);
 174                 self.nextthink = self.cnt;
 175                 return;
 176         }
 177
 178         //self.angles = vectoangles(self.velocity);                     // turn model in the new flight direction
 179         self.nextthink = time;// + 0.05; // csqc projectiles
 180         UpdateCSQCProjectile(self);
 181 }
 182
 183
 184
 185 void Seeker_Missile_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 186 {
 187         if (self.health <= 0)
 188                 return;
 189
 190         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 191                 return; // g_projectiles_damage says to halt
 192
 193         if (self.realowner == attacker)
 194                 self.health = self.health - (damage * 0.25);
 195         else
 196                 self.health = self.health - damage;
 197
 198         if (self.health <= 0)
 199                 W_PrepareExplosionByDamage(attacker, Seeker_Missile_Explode);
 200 }
 201
 202 /*
 203 void Seeker_Missile_Animate()
 204 {
 205         self.frame = self.frame +1;
 206         self.nextthink = time + 0.05;
 207
 208         if (self.enemy != world)
 209                 if (self.enemy.takedamage != DAMAGE_AIM || self.enemy.deadflag != DEAD_NO)
 210                         self.enemy = world;
 211
 212         if(self.frame == 5)
 213         {
 214                 self.think           = Seeker_Missile_Think;
 215                 self.nextthink       = time;// + cvar("g_balance_seeker_missile_activate_delay"); // cant dealy with csqc projectiles
 216
 217                 if (autocvar_g_balance_seeker_missile_proxy)
 218                         self.movetype    = MOVETYPE_BOUNCEMISSILE;
 219                 else
 220                         self.movetype    = MOVETYPE_FLYMISSILE;
 221         }
 222
 223         UpdateCSQCProjectile(self);
 224 }
 225 */
 226
 227 void Seeker_Fire_Missile(vector f_diff, entity m_target)
 228 {
 229         entity missile;
 230
 231         W_DecreaseAmmo(ammo_rockets, WEP_CVAR(seeker, missile_ammo), autocvar_g_balance_seeker_reload_ammo);
 232
 233         makevectors(self.v_angle);
 234         W_SetupShot_ProjectileSize (self, '-2 -2 -2', '2 2 2', FALSE, 2, "weapons/seeker_fire.wav", CH_WEAPON_A, 0);
 235         w_shotorg += f_diff;
 236         pointparticles(particleeffectnum("seeker_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 237
 238         //self.detornator         = FALSE;
 239
 240         missile                 = spawn();
 241         missile.owner           = missile.realowner = self;
 242         missile.classname       = "seeker_missile";
 243         missile.bot_dodge       = TRUE;
 244         missile.bot_dodgerating = WEP_CVAR(seeker, missile_damage);
 245
 246         missile.think           = Seeker_Missile_Think;
 247         missile.touch           = Seeker_Missile_Touch;
 248         missile.event_damage    = Seeker_Missile_Damage;
 249         missile.nextthink       = time;// + 0.2;// + cvar("g_balance_seeker_missile_activate_delay");
 250         missile.cnt             = time + WEP_CVAR(seeker, missile_lifetime);
 251         missile.enemy           = m_target;
 252         missile.solid           = SOLID_BBOX;
 253         missile.scale           = 2;
 254         missile.takedamage      = DAMAGE_YES;
 255         missile.health          = WEP_CVAR(seeker, missile_health);
 256         missile.damageforcescale = WEP_CVAR(seeker, missile_damageforcescale);
 257         missile.damagedbycontents = TRUE;
 258         //missile.think           = Seeker_Missile_Animate; // csqc projectiles.
 259
 260         if (missile.enemy != world)
 261                 missile.projectiledeathtype = WEP_SEEKER | HITTYPE_SECONDARY;
 262         else
 263                 missile.projectiledeathtype = WEP_SEEKER;
 264
 265
 266         setorigin (missile, w_shotorg);
 267         setsize (missile, '-4 -4 -4', '4 4 4');
 268         missile.movetype    = MOVETYPE_FLYMISSILE;
 269         missile.flags       = FL_PROJECTILE;
 270         missile.missile_flags = MIF_SPLASH | MIF_GUIDED_TAG;
 271
 272         W_SETUPPROJECTILEVELOCITY_UP(missile, g_balance_seeker_missile);
 273
 274         missile.angles = vectoangles (missile.velocity);
 275
 276         CSQCProjectile(missile, FALSE, PROJECTILE_SEEKER, TRUE);
 277
 278         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 279 }
 280
 281 // ============================
 282 // Begin: FLAC, close range attack meant for defeating rockets which are coming at you.
 283 // ============================
 284 void Seeker_Flac_Explode ()
 285 {
 286         self.event_damage = func_null;
 287
 288         RadiusDamage (self, self.realowner, WEP_CVAR(seeker, flac_damage), WEP_CVAR(seeker, flac_edgedamage), WEP_CVAR(seeker, flac_radius), world, world, WEP_CVAR(seeker, flac_force), self.projectiledeathtype, other);
 289
 290         remove (self);
 291 }
 292
 293 void Seeker_Flac_Touch()
 294 {
 295         PROJECTILE_TOUCH;
 296
 297         Seeker_Flac_Explode();
 298 }
 299
 300 void Seeker_Fire_Flac()
 301 {
 302         entity missile;
 303         vector f_diff;
 304         float c;
 305
 306         W_DecreaseAmmo(ammo_rockets, WEP_CVAR(seeker, flac_ammo), autocvar_g_balance_seeker_reload_ammo);
 307
 308         c = mod(self.bulletcounter, 4);
 309         switch(c)
 310         {
 311                 case 0:
 312                         f_diff = '-1.25 -3.75 0';
 313                         break;
 314                 case 1:
 315                         f_diff = '+1.25 -3.75 0';
 316                         break;
 317                 case 2:
 318                         f_diff = '-1.25 +3.75 0';
 319                         break;
 320                 case 3:
 321                 default:
 322                         f_diff = '+1.25 +3.75 0';
 323                         break;
 324         }
 325         W_SetupShot_ProjectileSize (self, '-2 -2 -2', '2 2 2', FALSE, 2, "weapons/flac_fire.wav", CH_WEAPON_A, WEP_CVAR(seeker, flac_damage));
 326         w_shotorg += f_diff;
 327
 328         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 329
 330         missile                                 = spawn ();
 331         missile.owner                   = missile.realowner = self;
 332         missile.classname               = "missile";
 333         missile.bot_dodge               = TRUE;
 334         missile.bot_dodgerating = WEP_CVAR(seeker, flac_damage);
 335         missile.touch                   = Seeker_Flac_Explode;
 336         missile.use                     = Seeker_Flac_Explode;
 337         missile.think                   = adaptor_think2use_hittype_splash;
 338         missile.nextthink               = time + WEP_CVAR(seeker, flac_lifetime) + WEP_CVAR(seeker, flac_lifetime_rand);
 339         missile.solid                   = SOLID_BBOX;
 340         missile.movetype                = MOVETYPE_FLY;
 341         missile.projectiledeathtype = WEP_SEEKER;
 342         missile.projectiledeathtype = WEP_SEEKER | HITTYPE_SECONDARY;
 343         missile.flags                           = FL_PROJECTILE;
 344         missile.missile_flags       = MIF_SPLASH;
 345
 346         // csqc projectiles
 347         //missile.angles                                = vectoangles (missile.velocity);
 348         //missile.scale = 0.4; // BUG: the model is too big
 349
 350         setorigin (missile, w_shotorg);
 351         setsize (missile, '-2 -2 -2', '2 2 2');
 352
 353         W_SETUPPROJECTILEVELOCITY_UP(missile, g_balance_seeker_flac);
 354         CSQCProjectile(missile, TRUE, PROJECTILE_FLAC, TRUE);
 355
 356         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 357 }
 358
 359 // ============================
 360 // Begin: Tag and rocket controllers
 361 // ============================
 362 entity Seeker_Tagged_Info(entity isowner, entity istarget)
 363 {
 364         entity tag;
 365         for(tag = world; (tag = find(tag, classname, "tag_tracker")); )
 366                 if ((tag.realowner == isowner) && (tag.tag_target == istarget))
 367                         return tag;
 368
 369         return world;
 370 }
 371
 372 void Seeker_Attack()
 373 {
 374         entity tracker, closest_target;
 375
 376         closest_target = world;
 377         for(tracker = world; (tracker = find(tracker, classname, "tag_tracker")); ) if (tracker.realowner == self)
 378         {
 379                 if (closest_target)
 380                 {
 381                         if (vlen(self.origin - tracker.tag_target.origin) < vlen(self.origin - closest_target.origin))
 382                                 closest_target = tracker.tag_target;
 383                 }
 384                 else
 385                         closest_target = tracker.tag_target;
 386         }
 387
 388         traceline(self.origin + self.view_ofs, closest_target.origin, MOVE_NOMONSTERS, self);
 389         if ((!closest_target) || ((trace_fraction < 1) && (trace_ent != closest_target)))
 390                 closest_target = world;
 391
 392         Seeker_Fire_Missile('0 0 0', closest_target);
 393 }
 394
 395 void Seeker_Vollycontroller_Think() // TODO: Merge this with Seeker_Attack
 396 {
 397         float c;
 398         entity oldself,oldenemy;
 399         self.cnt = self.cnt - 1;
 400
 401         if((!(self.realowner.items & IT_UNLIMITED_AMMO) && self.realowner.ammo_rockets < WEP_CVAR(seeker, missile_ammo)) || (self.cnt <= -1) || (self.realowner.deadflag != DEAD_NO) || (self.realowner.switchweapon != WEP_SEEKER))
 402         {
 403                 remove(self);
 404                 return;
 405         }
 406
 407         self.nextthink = time + WEP_CVAR(seeker, missile_delay) * W_WeaponRateFactor();
 408
 409         oldself = self;
 410         self = self.realowner;
 411
 412         oldenemy = self.enemy;
 413         self.enemy = oldself.enemy;
 414
 415         c = mod(self.cnt, 4);
 416         switch(c)
 417         {
 418                 case 0:
 419                         Seeker_Fire_Missile('-1.25 -3.75 0', self.enemy);
 420                         break;
 421                 case 1:
 422                         Seeker_Fire_Missile('+1.25 -3.75 0', self.enemy);
 423                         break;
 424                 case 2:
 425                         Seeker_Fire_Missile('-1.25 +3.75 0', self.enemy);
 426                         break;
 427                 case 3:
 428                 default:
 429                         Seeker_Fire_Missile('+1.25 +3.75 0', self.enemy);
 430                         break;
 431         }
 432
 433         self.enemy = oldenemy;
 434         self = oldself;
 435 }
 436
 437 void Seeker_Tracker_Think()
 438 {
 439         // commit suicide if: You die OR target dies OR you switch away from the seeker OR commit suicide if lifetime is up
 440         if ((self.realowner.deadflag != DEAD_NO) || (self.tag_target.deadflag != DEAD_NO) || (self.realowner.switchweapon != WEP_SEEKER)
 441         || (time > self.tag_time + WEP_CVAR(seeker, tag_tracker_lifetime)))
 442         {
 443                 if (self)
 444                 {
 445                         WaypointSprite_Kill(self.tag_target.wps_tag_tracker);
 446                         remove(self);
 447                 }
 448                 return;
 449         }
 450
 451         // Update the think method information
 452         self.nextthink = time;
 453 }
 454
 455 // ============================
 456 // Begin: Tag projectile
 457 // ============================
 458 void Seeker_Tag_Explode ()
 459 {
 460         //if(other==self.realowner)
 461         //    return;
 462         Damage_DamageInfo(self.origin, 0, 0, 0, self.velocity, WEP_SEEKER | HITTYPE_BOUNCE, other.species, self);
 463
 464         remove (self);
 465 }
 466
 467 void Seeker_Tag_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 468 {
 469         if (self.health <= 0)
 470                 return;
 471         self.health = self.health - damage;
 472         if (self.health <= 0)
 473                 Seeker_Tag_Explode();
 474 }
 475
 476 void Seeker_Tag_Touch()
 477 {
 478         vector dir;
 479         vector org2;
 480         entity e;
 481
 482         PROJECTILE_TOUCH;
 483
 484         dir     = normalize (self.realowner.origin - self.origin);
 485         org2    = findbetterlocation (self.origin, 8);
 486
 487         te_knightspike(org2);
 488
 489         self.event_damage = func_null;
 490         Damage_DamageInfo(self.origin, 0, 0, 0, self.velocity, WEP_SEEKER | HITTYPE_BOUNCE | HITTYPE_SECONDARY, other.species, self);
 491
 492         if (other.takedamage == DAMAGE_AIM && other.deadflag == DEAD_NO)
 493         {
 494                 // check to see if this person is already tagged by me
 495                 entity tag = Seeker_Tagged_Info(self.realowner, other);
 496
 497                 if (tag != world)
 498                 {
 499                         if (other.wps_tag_tracker && (WEP_CVAR(seeker, type) == 1)) // don't attach another waypointsprite without killing the old one first
 500                                 WaypointSprite_Kill(other.wps_tag_tracker);
 501
 502                         tag.tag_time = time;
 503                 }
 504                 else
 505                 {
 506                         //sprint(self.realowner, strcat("You just tagged ^2", other.netname, "^7 with a tracking device!\n"));
 507                         e             = spawn();
 508                         e.cnt         = WEP_CVAR(seeker, missile_count);
 509                         e.classname   = "tag_tracker";
 510                         e.owner       = self.owner;
 511                         e.realowner   = self.realowner;
 512
 513                         if(WEP_CVAR(seeker, type) == 1)
 514                         {
 515                                 e.tag_target  = other;
 516                                 e.tag_time    = time;
 517                                 e.think       = Seeker_Tracker_Think;
 518                         }
 519                         else
 520                         {
 521                                 e.enemy     = other;
 522                                 e.think     = Seeker_Vollycontroller_Think;
 523                         }
 524
 525                         e.nextthink   = time;
 526                 }
 527
 528                 if(WEP_CVAR(seeker, type) == 1)
 529                 {
 530                         WaypointSprite_Spawn("tagged-target", WEP_CVAR(seeker, tag_tracker_lifetime), 0, other, '0 0 64', self.realowner, 0, other, wps_tag_tracker, TRUE, RADARICON_TAGGED, '0.5 1 0');
 531                         WaypointSprite_UpdateRule(other.wps_tag_tracker, 0, SPRITERULE_DEFAULT);
 532                 }
 533         }
 534
 535         remove(self);
 536         return;
 537 }
 538
 539 void Seeker_Fire_Tag()
 540 {
 541         entity missile;
 542         W_DecreaseAmmo(ammo_rockets, WEP_CVAR(seeker, tag_ammo), autocvar_g_balance_seeker_reload_ammo);
 543
 544         W_SetupShot_ProjectileSize (self, '-2 -2 -2', '2 2 2', FALSE, 2, "weapons/tag_fire.wav", CH_WEAPON_A, WEP_CVAR(seeker, missile_damage) * WEP_CVAR(seeker, missile_count));
 545
 546         missile                 = spawn();
 547         missile.owner           = missile.realowner = self;
 548         missile.classname       = "seeker_tag";
 549         missile.bot_dodge       = TRUE;
 550         missile.bot_dodgerating = 50;
 551         missile.touch           = Seeker_Tag_Touch;
 552         missile.think           = SUB_Remove;
 553         missile.nextthink       = time + WEP_CVAR(seeker, tag_lifetime);
 554         missile.movetype        = MOVETYPE_FLY;
 555         missile.solid           = SOLID_BBOX;
 556
 557         missile.takedamage       = DAMAGE_YES;
 558         missile.event_damage     = Seeker_Tag_Damage;
 559         missile.health           = WEP_CVAR(seeker, tag_health);
 560         missile.damageforcescale = WEP_CVAR(seeker, tag_damageforcescale);
 561
 562         setorigin (missile, w_shotorg);
 563         setsize (missile, '-2 -2 -2', '2 2 2');
 564
 565         missile.flags       = FL_PROJECTILE;
 566         //missile.missile_flags = MIF_..?;
 567
 568         missile.movetype    = MOVETYPE_FLY;
 569         W_SETUPPROJECTILEVELOCITY(missile, g_balance_seeker_tag);
 570         missile.angles = vectoangles (missile.velocity);
 571
 572         CSQCProjectile(missile, TRUE, PROJECTILE_TAG, FALSE); // has sound
 573
 574         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 575 }
 576
 577 // ============================
 578 // Begin: Genereal weapon functions
 579 // ============================
 580
 581 float w_seeker(float req)
 582 {
 583         float ammo_amount;
 584
 585         switch(req)
 586         {
 587                 case WR_AIM:
 588                 {
 589                         if (WEP_CVAR(seeker, type) == 1)
 590                                 if (Seeker_Tagged_Info(self, self.enemy) != world)
 591                                         self.BUTTON_ATCK = bot_aim(WEP_CVAR(seeker, missile_speed_max), 0, WEP_CVAR(seeker, missile_lifetime), FALSE);
 592                                 else
 593                                         self.BUTTON_ATCK2 = bot_aim(WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), FALSE);
 594                         else
 595                                 self.BUTTON_ATCK = bot_aim(WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), FALSE);
 596                         return TRUE;
 597                 }
 598                 case WR_THINK:
 599                 {
 600                         if(autocvar_g_balance_seeker_reload_ammo && self.clip_load < min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo))) // forced reload
 601                                 WEP_ACTION(self.weapon, WR_RELOAD);
 602
 603                         else if (self.BUTTON_ATCK)
 604                         {
 605                                 if (WEP_CVAR(seeker, type) == 1)
 606                                 {
 607                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, missile_refire)))
 608                                         {
 609                                                 Seeker_Attack();
 610                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, missile_animtime), w_ready);
 611                                         }
 612                                 }
 613                                 else
 614                                 {
 615                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, tag_refire)))
 616                                         {
 617                                                 Seeker_Fire_Tag();
 618                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
 619                                         }
 620                                 }
 621                         }
 622
 623                         else if (self.BUTTON_ATCK2)
 624                         {
 625                                 if (WEP_CVAR(seeker, type) == 1)
 626                                 {
 627                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, tag_refire)))
 628                                         {
 629                                                 Seeker_Fire_Tag();
 630                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
 631                                         }
 632                                 }
 633                                 else
 634                                 {
 635                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, flac_refire)))
 636                                         {
 637                                                 Seeker_Fire_Flac();
 638                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, flac_animtime), w_ready);
 639                                         }
 640                                 }
 641                         }
 642
 643                         return TRUE;
 644                 }
 645                 case WR_INIT:
 646                 {
 647                         precache_model ("models/weapons/g_seeker.md3");
 648                         precache_model ("models/weapons/v_seeker.md3");
 649                         precache_model ("models/weapons/h_seeker.iqm");
 650                         precache_sound ("weapons/tag_fire.wav");
 651                         precache_sound ("weapons/flac_fire.wav");
 652                         precache_sound ("weapons/seeker_fire.wav");
 653                         SEEKER_SETTINGS(WEP_SKIPCVAR, WEP_SET_PROP)
 654                         return TRUE;
 655                 }
 656                 case WR_SETUP:
 657                 {
 658                         self.current_ammo = ammo_rockets;
 659                         return TRUE;
 660                 }
 661                 case WR_CHECKAMMO1:
 662                 {
 663                         if (WEP_CVAR(seeker, type) == 1)
 664                         {
 665                                 ammo_amount = self.ammo_rockets >= WEP_CVAR(seeker, missile_ammo);
 666                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, missile_ammo);
 667                         }
 668                         else
 669                         {
 670                                 ammo_amount = self.ammo_rockets >= WEP_CVAR(seeker, tag_ammo);
 671                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, tag_ammo);
 672                         }
 673                         return ammo_amount;
 674                 }
 675                 case WR_CHECKAMMO2:
 676                 {
 677                         if (WEP_CVAR(seeker, type) == 1)
 678                         {
 679                                 ammo_amount = self.ammo_rockets >= WEP_CVAR(seeker, tag_ammo);
 680                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, tag_ammo);
 681                         }
 682                         else
 683                         {
 684                                 ammo_amount = self.ammo_rockets >= WEP_CVAR(seeker, flac_ammo);
 685                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, flac_ammo);
 686                         }
 687                         return ammo_amount;
 688                 }
 689                 case WR_CONFIG:
 690                 {
 691                         SEEKER_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 692                         return TRUE;
 693                 }
 694                 case WR_RELOAD:
 695                 {
 696                         W_Reload(min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo)), "weapons/reload.wav");
 697                         return TRUE;
 698                 }
 699                 case WR_SUICIDEMESSAGE:
 700                 {
 701                         return WEAPON_SEEKER_SUICIDE;
 702                 }
 703                 case WR_KILLMESSAGE:
 704                 {
 705                         if(w_deathtype & HITTYPE_SECONDARY)
 706                                 return WEAPON_SEEKER_MURDER_TAG;
 707                         else
 708                                 return WEAPON_SEEKER_MURDER_SPRAY;
 709                 }
 710         }
 711         return TRUE;
 712 }
 713 #endif
 714 #ifdef CSQC
 715 float w_seeker(float req)
 716 {
 717         switch(req)
 718         {
 719                 case WR_IMPACTEFFECT:
 720                 {
 721                         vector org2;
 722                         org2 = w_org + w_backoff * 6;
 723                         if(w_deathtype & HITTYPE_BOUNCE)
 724                         {
 725                                 if(w_deathtype & HITTYPE_SECONDARY)
 726                                 {
 727                                         if(!w_issilent)
 728                                                 sound(self, CH_SHOTS, "weapons/tag_impact.wav", 1, ATTEN_NORM);
 729                                 }
 730                                 else
 731                                 {
 732                                         pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 733                                         if(!w_issilent)
 734                                         {
 735                                                 if (w_random<0.15)
 736                                                         sound(self, CH_SHOTS, "weapons/tagexp1.wav", 1, ATTEN_NORM);
 737                                                 else if (w_random<0.7)
 738                                                         sound(self, CH_SHOTS, "weapons/tagexp2.wav", 1, ATTEN_NORM);
 739                                                 else
 740                                                         sound(self, CH_SHOTS, "weapons/tagexp3.wav", 1, ATTEN_NORM);
 741                                         }
 742                                 }
 743                         }
 744                         else
 745                         {
 746                                 pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 747                                 if(!w_issilent)
 748                                 {
 749                                         if (w_random<0.15)
 750                                                 sound(self, CH_SHOTS, "weapons/seekerexp1.wav", 1, ATTEN_NORM);
 751                                         else if (w_random<0.7)
 752                                                 sound(self, CH_SHOTS, "weapons/seekerexp2.wav", 1, ATTEN_NORM);
 753                                         else
 754                                                 sound(self, CH_SHOTS, "weapons/seekerexp3.wav", 1, ATTEN_NORM);
 755                                 }
 756                         }
 757                         return TRUE;
 758                 }
 759                 case WR_INIT:
 760                 {
 761                         precache_sound("weapons/seekerexp1.wav");
 762                         precache_sound("weapons/seekerexp2.wav");
 763                         precache_sound("weapons/seekerexp3.wav");
 764                         precache_sound("weapons/tagexp1.wav");
 765                         precache_sound("weapons/tagexp2.wav");
 766                         precache_sound("weapons/tagexp3.wav");
 767                         precache_sound("weapons/tag_impact.wav");
 768                         return TRUE;
 769                 }
 770         }
 771
 772         return TRUE;
 773 }
 774 #endif
 775 #endif