qcsrc/common/weapons/w_devastator.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ DEVASTATOR,
   4 /* function  */ W_Devastator,
   5 /* ammotype  */ ammo_rockets,
   6 /* impulse   */ 9,
   7 /* flags     */ WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH,
   8 /* rating    */ BOT_PICKUP_RATING_HIGH,
   9 /* color     */ '1 1 0',
  10 /* modelname */ "rl",
  11 /* simplemdl */ "foobar",
  12 /* crosshair */ "gfx/crosshairrocketlauncher 0.5875",
  13 /* wepimg    */ "weaponrocketlauncher",
  14 /* refname   */ "devastator",
  15 /* wepname   */ _("Devastator")
  16 );
  17
  18 #define DEVASTATOR_SETTINGS(w_cvar,w_prop) DEVASTATOR_SETTINGS_LIST(w_cvar, w_prop, DEVASTATOR, devastator)
  19 #define DEVASTATOR_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  20         w_cvar(id, sn, NONE, ammo) \
  21         w_cvar(id, sn, NONE, animtime) \
  22         w_cvar(id, sn, NONE, damage) \
  23         w_cvar(id, sn, NONE, damageforcescale) \
  24         w_cvar(id, sn, NONE, detonatedelay) \
  25         w_cvar(id, sn, NONE, edgedamage) \
  26         w_cvar(id, sn, NONE, force) \
  27         w_cvar(id, sn, NONE, guidedelay) \
  28         w_cvar(id, sn, NONE, guidegoal) \
  29         w_cvar(id, sn, NONE, guiderate) \
  30         w_cvar(id, sn, NONE, guideratedelay) \
  31         w_cvar(id, sn, NONE, guidestop) \
  32         w_cvar(id, sn, NONE, health) \
  33         w_cvar(id, sn, NONE, lifetime) \
  34         w_cvar(id, sn, NONE, radius) \
  35         w_cvar(id, sn, NONE, refire) \
  36         w_cvar(id, sn, NONE, remote_damage) \
  37         w_cvar(id, sn, NONE, remote_edgedamage) \
  38         w_cvar(id, sn, NONE, remote_force) \
  39         w_cvar(id, sn, NONE, remote_jump_damage) \
  40         w_cvar(id, sn, NONE, remote_jump_radius) \
  41         w_cvar(id, sn, NONE, remote_jump_velocity_z_add) \
  42         w_cvar(id, sn, NONE, remote_jump_velocity_z_max) \
  43         w_cvar(id, sn, NONE, remote_jump_velocity_z_min) \
  44         w_cvar(id, sn, NONE, remote_radius) \
  45         w_cvar(id, sn, NONE, speed) \
  46         w_cvar(id, sn, NONE, speedaccel) \
  47         w_cvar(id, sn, NONE, speedstart) \
  48         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  49         w_prop(id, sn, float,  reloading_time, reload_time) \
  50         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  51         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  52         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  53         w_prop(id, sn, float,  weaponstart, weaponstart) \
  54         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
  55         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
  56
  57 #ifdef SVQC
  58 DEVASTATOR_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  59 .float rl_release;
  60 .float rl_detonate_later;
  61 #endif
  62 #else
  63 #ifdef SVQC
  64 void spawnfunc_weapon_devastator(void) { weapon_defaultspawnfunc(WEP_DEVASTATOR); }
  65 void spawnfunc_weapon_rocketlauncher(void) { spawnfunc_weapon_devastator(); }
  66
  67 void W_Devastator_Unregister(void)
  68 {
  69         if(self.realowner && self.realowner.lastrocket == self)
  70         {
  71                 self.realowner.lastrocket = world;
  72                 // self.realowner.rl_release = 1;
  73         }
  74 }
  75
  76 void W_Devastator_Explode(void)
  77 {
  78         W_Devastator_Unregister();
  79
  80         if(other.takedamage == DAMAGE_AIM)
  81                 if(IS_PLAYER(other))
  82                         if(DIFF_TEAM(self.realowner, other))
  83                                 if(other.deadflag == DEAD_NO)
  84                                         if(IsFlying(other))
  85                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
  86
  87         self.event_damage = func_null;
  88         self.takedamage = DAMAGE_NO;
  89
  90         RadiusDamage(
  91                 self,
  92                 self.realowner,
  93                 WEP_CVAR(devastator, damage),
  94                 WEP_CVAR(devastator, edgedamage),
  95                 WEP_CVAR(devastator, radius),
  96                 world,
  97                 world,
  98                 WEP_CVAR(devastator, force),
  99                 self.projectiledeathtype,
 100                 other
 101         );
 102
 103         if(self.realowner.weapon == WEP_DEVASTATOR)
 104         {
 105                 if(self.realowner.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo))
 106                 {
 107                         self.realowner.cnt = WEP_DEVASTATOR;
 108                         ATTACK_FINISHED(self.realowner) = time;
 109                         self.realowner.switchweapon = w_getbestweapon(self.realowner);
 110                 }
 111         }
 112         remove(self);
 113 }
 114
 115 void W_Devastator_DoRemoteExplode(void)
 116 {
 117         W_Devastator_Unregister();
 118
 119         self.event_damage = func_null;
 120         self.takedamage = DAMAGE_NO;
 121
 122         float handled_as_rocketjump = FALSE;
 123
 124         entity head = WarpZone_FindRadius(
 125                 self.origin,
 126                 WEP_CVAR(devastator, remote_jump_radius),
 127                 FALSE
 128         );
 129
 130         while(head)
 131         {
 132                 if(head.takedamage && (head == self.realowner))
 133                 {
 134                         float distance_to_head = vlen(self.origin - head.WarpZone_findradius_nearest);
 135                         if(distance_to_head <= WEP_CVAR(devastator, remote_jump_radius))
 136                         {
 137                                 head.velocity_x *= 0.9;
 138                                 head.velocity_y *= 0.9;
 139                                 head.velocity_z = bound(
 140                                         WEP_CVAR(devastator, remote_jump_velocity_z_min),
 141                                         head.velocity_z + WEP_CVAR(devastator, remote_jump_velocity_z_add),
 142                                         WEP_CVAR(devastator, remote_jump_velocity_z_max)
 143                                 );
 144
 145                                 handled_as_rocketjump = TRUE;
 146                                 RadiusDamage(
 147                                         self,
 148                                         head,
 149                                         WEP_CVAR(devastator, remote_jump_damage),
 150                                         WEP_CVAR(devastator, remote_jump_damage),
 151                                         WEP_CVAR(devastator, remote_jump_radius),
 152                                         world,
 153                                         head,
 154                                         0,
 155                                         self.projectiledeathtype | HITTYPE_BOUNCE,
 156                                         world
 157                                 );
 158                                 break;
 159                         }
 160                 }
 161                 head = head.chain;
 162         }
 163
 164         RadiusDamage(
 165                 self,
 166                 self.realowner,
 167                 WEP_CVAR(devastator, remote_damage),
 168                 WEP_CVAR(devastator, remote_edgedamage),
 169                 WEP_CVAR(devastator, remote_radius),
 170                 (handled_as_rocketjump ? head : world),
 171                 world,
 172                 WEP_CVAR(devastator, remote_force),
 173                 self.projectiledeathtype | HITTYPE_BOUNCE,
 174                 world
 175         );
 176
 177         if(self.realowner.weapon == WEP_DEVASTATOR)
 178         {
 179                 if(self.realowner.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo))
 180                 {
 181                         self.realowner.cnt = WEP_DEVASTATOR;
 182                         ATTACK_FINISHED(self.realowner) = time;
 183                         self.realowner.switchweapon = w_getbestweapon(self.realowner);
 184                 }
 185         }
 186         remove(self);
 187 }
 188
 189 void W_Devastator_RemoteExplode(void)
 190 {
 191         if(self.realowner.deadflag == DEAD_NO)
 192         if(self.realowner.lastrocket)
 193         {
 194                 if((self.spawnshieldtime >= 0)
 195                         ? (time >= self.spawnshieldtime) // timer
 196                         : (vlen(NearestPointOnBox(self.realowner, self.origin) - self.origin) > WEP_CVAR(devastator, remote_radius)) // safety device
 197                 )
 198                 {
 199                         W_Devastator_DoRemoteExplode();
 200                 }
 201         }
 202 }
 203
 204 vector W_Devastator_SteerTo(vector thisdir, vector goaldir, float maxturn_cos)
 205 {
 206         if(thisdir * goaldir > maxturn_cos)
 207                 return goaldir;
 208         if(thisdir * goaldir < -0.9998) // less than 1 degree and opposite
 209                 return thisdir; // refuse to guide (better than letting a numerical error happen)
 210         float f, m2;
 211         vector v;
 212         // solve:
 213         //   g = normalize(thisdir + goaldir * X)
 214         //   thisdir * g = maxturn
 215         //
 216         //   gg = thisdir + goaldir * X
 217         //   (thisdir * gg)^2 = maxturn^2 * (gg * gg)
 218         //
 219         //   (1 + (thisdir * goaldir) * X)^2 = maxturn^2 * (1 + X*X + 2 * X * thisdir * goaldir)
 220         f = thisdir * goaldir;
 221         //   (1 + f * X)^2 = maxturn^2 * (1 + X*X + 2 * X * f)
 222         //   0 = (m^2 - f^2) * x^2 + (2 * f * (m^2 - 1)) * x + (m^2 - 1)
 223         m2 = maxturn_cos * maxturn_cos;
 224         v = solve_quadratic(m2 - f * f, 2 * f * (m2 - 1), m2 - 1);
 225         return normalize(thisdir + goaldir * v_y); // the larger solution!
 226 }
 227 // assume thisdir == -goaldir:
 228 //   f == -1
 229 //   v = solve_qadratic(m2 - 1, -2 * (m2 - 1), m2 - 1)
 230 //   (m2 - 1) x^2 - 2 * (m2 - 1) * x + (m2 - 1) = 0
 231 //   x^2 - 2 * x + 1 = 0
 232 //   (x - 1)^2 = 0
 233 //   x = 1
 234 //   normalize(thisdir + goaldir)
 235 //   normalize(0)
 236
 237 void W_Devastator_Think(void)
 238 {
 239         vector desireddir, olddir, newdir, desiredorigin, goal;
 240         float velspeed, f;
 241         self.nextthink = time;
 242         if(time > self.cnt)
 243         {
 244                 other = world;
 245                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 246                 W_Devastator_Explode();
 247                 return;
 248         }
 249
 250         // accelerate
 251         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 252         velspeed = WEP_CVAR(devastator, speed) * g_weaponspeedfactor - (self.velocity * v_forward);
 253         if(velspeed > 0)
 254                 self.velocity = self.velocity + v_forward * min(WEP_CVAR(devastator, speedaccel) * g_weaponspeedfactor * frametime, velspeed);
 255
 256         // laser guided, or remote detonation
 257         if(self.realowner.weapon == WEP_DEVASTATOR)
 258         {
 259                 if(self == self.realowner.lastrocket)
 260                 if(!self.realowner.rl_release)
 261                 if(!self.BUTTON_ATCK2)
 262                 if(WEP_CVAR(devastator, guiderate))
 263                 if(time > self.pushltime)
 264                 if(self.realowner.deadflag == DEAD_NO)
 265                 {
 266                         f = WEP_CVAR(devastator, guideratedelay);
 267                         if(f)
 268                                 f = bound(0, (time - self.pushltime) / f, 1);
 269                         else
 270                                 f = 1;
 271
 272                         velspeed = vlen(self.velocity);
 273
 274                         makevectors(self.realowner.v_angle);
 275                         desireddir = WarpZone_RefSys_TransformVelocity(self.realowner, self, v_forward);
 276                         desiredorigin = WarpZone_RefSys_TransformOrigin(self.realowner, self, self.realowner.origin + self.realowner.view_ofs);
 277                         olddir = normalize(self.velocity);
 278
 279                         // now it gets tricky... we want to move like some curve to approximate the target direction
 280                         // but we are limiting the rate at which we can turn!
 281                         goal = desiredorigin + ((self.origin - desiredorigin) * desireddir + WEP_CVAR(devastator, guidegoal)) * desireddir;
 282                         newdir = W_Devastator_SteerTo(olddir, normalize(goal - self.origin), cos(WEP_CVAR(devastator, guiderate) * f * frametime * DEG2RAD));
 283
 284                         self.velocity = newdir * velspeed;
 285                         self.angles = vectoangles(self.velocity);
 286
 287                         if(!self.count)
 288                         {
 289                                 pointparticles(particleeffectnum("rocket_guide"), self.origin, self.velocity, 1);
 290                                 // TODO add a better sound here
 291                                 sound(self.realowner, CH_WEAPON_B, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 292                                 self.count = 1;
 293                         }
 294                 }
 295
 296                 if(self.rl_detonate_later)
 297                         W_Devastator_RemoteExplode();
 298         }
 299
 300         if(self.csqcprojectile_clientanimate == 0)
 301                 UpdateCSQCProjectile(self);
 302 }
 303
 304 void W_Devastator_Touch(void)
 305 {
 306         if(WarpZone_Projectile_Touch())
 307         {
 308                 if(wasfreed(self))
 309                         W_Devastator_Unregister();
 310                 return;
 311         }
 312         W_Devastator_Unregister();
 313         W_Devastator_Explode();
 314 }
 315
 316 void W_Devastator_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 317 {
 318         if(self.health <= 0)
 319                 return;
 320
 321         if(!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 322                 return; // g_projectiles_damage says to halt
 323
 324         self.health = self.health - damage;
 325         self.angles = vectoangles(self.velocity);
 326
 327         if(self.health <= 0)
 328                 W_PrepareExplosionByDamage(attacker, W_Devastator_Explode);
 329 }
 330
 331 void W_Devastator_Attack(void)
 332 {
 333         entity missile;
 334         entity flash;
 335
 336         W_DecreaseAmmo(WEP_CVAR(devastator, ammo));
 337
 338         W_SetupShot_ProjectileSize(self, '-3 -3 -3', '3 3 3', FALSE, 5, "weapons/rocket_fire.wav", CH_WEAPON_A, WEP_CVAR(devastator, damage));
 339         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 340
 341         missile = WarpZone_RefSys_SpawnSameRefSys(self);
 342         missile.owner = missile.realowner = self;
 343         self.lastrocket = missile;
 344         if(WEP_CVAR(devastator, detonatedelay) >= 0)
 345                 missile.spawnshieldtime = time + WEP_CVAR(devastator, detonatedelay);
 346         else
 347                 missile.spawnshieldtime = -1;
 348         missile.pushltime = time + WEP_CVAR(devastator, guidedelay);
 349         missile.classname = "rocket";
 350         missile.bot_dodge = TRUE;
 351         missile.bot_dodgerating = WEP_CVAR(devastator, damage) * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 352
 353         missile.takedamage = DAMAGE_YES;
 354         missile.damageforcescale = WEP_CVAR(devastator, damageforcescale);
 355         missile.health = WEP_CVAR(devastator, health);
 356         missile.event_damage = W_Devastator_Damage;
 357         missile.damagedbycontents = TRUE;
 358
 359         missile.movetype = MOVETYPE_FLY;
 360         PROJECTILE_MAKETRIGGER(missile);
 361         missile.projectiledeathtype = WEP_DEVASTATOR;
 362         setsize(missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 363
 364         setorigin(missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 365         W_SetupProjVelocity_Basic(missile, WEP_CVAR(devastator, speedstart), 0);
 366         missile.angles = vectoangles(missile.velocity);
 367
 368         missile.touch = W_Devastator_Touch;
 369         missile.think = W_Devastator_Think;
 370         missile.nextthink = time;
 371         missile.cnt = time + WEP_CVAR(devastator, lifetime);
 372         missile.flags = FL_PROJECTILE;
 373         missile.missile_flags = MIF_SPLASH;
 374
 375         CSQCProjectile(missile, WEP_CVAR(devastator, guiderate) == 0 && WEP_CVAR(devastator, speedaccel) == 0, PROJECTILE_ROCKET, FALSE); // because of fly sound
 376
 377         // muzzle flash for 1st person view
 378         flash = spawn();
 379         setmodel(flash, "models/flash.md3"); // precision set below
 380         SUB_SetFade(flash, time, 0.1);
 381         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 382         W_AttachToShotorg(flash, '5 0 0');
 383
 384         // common properties
 385         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 386 }
 387
 388 float W_Devastator(float req)
 389 {
 390         entity rock;
 391         float rockfound;
 392         float ammo_amount;
 393         switch(req)
 394         {
 395                 #if 0
 396                 case WR_AIM:
 397                 {
 398                         // aim and decide to fire if appropriate
 399                         self.BUTTON_ATCK = bot_aim(WEP_CVAR(devastator, speed), 0, WEP_CVAR(devastator, lifetime), FALSE);
 400                         if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 401                         {
 402                                 // decide whether to detonate rockets
 403                                 entity missile, targetlist, targ;
 404                                 targetlist = findchainfloat(bot_attack, TRUE);
 405                                 for(missile = world; (missile = find(missile, classname, "rocket")); ) if(missile.realowner == self)
 406                                 {
 407                                         targ = targetlist;
 408                                         while(targ)
 409                                         {
 410                                                 if(targ != missile.realowner && vlen(targ.origin - missile.origin) < WEP_CVAR(devastator, radius))
 411                                                 {
 412                                                         self.BUTTON_ATCK2 = TRUE;
 413                                                         break;
 414                                                 }
 415                                                 targ = targ.chain;
 416                                         }
 417                                 }
 418
 419                                 if(self.BUTTON_ATCK2) self.BUTTON_ATCK = FALSE;
 420                         }
 421
 422                         return TRUE;
 423                 }
 424                 #else
 425                 case WR_AIM:
 426                 {
 427                         // aim and decide to fire if appropriate
 428                         self.BUTTON_ATCK = bot_aim(WEP_CVAR(devastator, speed), 0, WEP_CVAR(devastator, lifetime), FALSE);
 429                         if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 430                         {
 431                                 // decide whether to detonate rockets
 432                                 entity missile, targetlist, targ;
 433                                 float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 434                                 float selfdamage, teamdamage, enemydamage;
 435                                 edgedamage = WEP_CVAR(devastator, edgedamage);
 436                                 coredamage = WEP_CVAR(devastator, damage);
 437                                 edgeradius = WEP_CVAR(devastator, radius);
 438                                 recipricoledgeradius = 1 / edgeradius;
 439                                 selfdamage = 0;
 440                                 teamdamage = 0;
 441                                 enemydamage = 0;
 442                                 targetlist = findchainfloat(bot_attack, TRUE);
 443                                 missile = find(world, classname, "rocket");
 444                                 while(missile)
 445                                 {
 446                                         if(missile.realowner != self)
 447                                         {
 448                                                 missile = find(missile, classname, "rocket");
 449                                                 continue;
 450                                         }
 451                                         targ = targetlist;
 452                                         while(targ)
 453                                         {
 454                                                 d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 455                                                 d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 456                                                 // count potential damage according to type of target
 457                                                 if(targ == self)
 458                                                         selfdamage = selfdamage + d;
 459                                                 else if(targ.team == self.team && teamplay)
 460                                                         teamdamage = teamdamage + d;
 461                                                 else if(bot_shouldattack(targ))
 462                                                         enemydamage = enemydamage + d;
 463                                                 targ = targ.chain;
 464                                         }
 465                                         missile = find(missile, classname, "rocket");
 466                                 }
 467                                 float desirabledamage;
 468                                 desirabledamage = enemydamage;
 469                                 if(time > self.invincible_finished && time > self.spawnshieldtime)
 470                                         desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 471                                 if(teamplay && self.team)
 472                                         desirabledamage = desirabledamage - teamdamage;
 473
 474                                 missile = find(world, classname, "rocket");
 475                                 while(missile)
 476                                 {
 477                                         if(missile.realowner != self)
 478                                         {
 479                                                 missile = find(missile, classname, "rocket");
 480                                                 continue;
 481                                         }
 482                                         makevectors(missile.v_angle);
 483                                         targ = targetlist;
 484                                         if(skill > 9) // normal players only do this for the target they are tracking
 485                                         {
 486                                                 targ = targetlist;
 487                                                 while(targ)
 488                                                 {
 489                                                         if(
 490                                                                 (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 491                                                                 && desirabledamage > 0.1*coredamage
 492                                                         )self.BUTTON_ATCK2 = TRUE;
 493                                                         targ = targ.chain;
 494                                                 }
 495                                         }else{
 496                                                 float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 497                                                 //As the distance gets larger, a correct detonation gets near imposible
 498                                                 //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 499                                                 if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 500                                                         if(IS_PLAYER(self.enemy))
 501                                                                 if(desirabledamage >= 0.1*coredamage)
 502                                                                         if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 503                                                                                 self.BUTTON_ATCK2 = TRUE;
 504                                         //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 505                                         }
 506
 507                                         missile = find(missile, classname, "rocket");
 508                                 }
 509                                 // if we would be doing at X percent of the core damage, detonate it
 510                                 // but don't fire a new shot at the same time!
 511                                 if(desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 512                                         self.BUTTON_ATCK2 = TRUE;
 513                                 if((skill > 6.5) && (selfdamage > self.health))
 514                                         self.BUTTON_ATCK2 = FALSE;
 515                                 //if(self.BUTTON_ATCK2 == TRUE)
 516                                 //      dprint(ftos(desirabledamage),"\n");
 517                                 if(self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 518                         }
 519
 520                         return TRUE;
 521                 }
 522                 #endif
 523                 case WR_THINK:
 524                 {
 525                         if(WEP_CVAR(devastator, reload_ammo) && self.clip_load < WEP_CVAR(devastator, ammo)) // forced reload
 526                                 WEP_ACTION(self.weapon, WR_RELOAD);
 527                         else
 528                         {
 529                                 if(self.BUTTON_ATCK)
 530                                 {
 531                                         if(self.rl_release || WEP_CVAR(devastator, guidestop))
 532                                         if(weapon_prepareattack(0, WEP_CVAR(devastator, refire)))
 533                                         {
 534                                                 W_Devastator_Attack();
 535                                                 weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(devastator, animtime), w_ready);
 536                                                 self.rl_release = 0;
 537                                         }
 538                                 }
 539                                 else
 540                                         self.rl_release = 1;
 541
 542                                 if(self.BUTTON_ATCK2)
 543                                 {
 544                                         rockfound = 0;
 545                                         for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.realowner == self)
 546                                         {
 547                                                 if(!rock.rl_detonate_later)
 548                                                 {
 549                                                         rock.rl_detonate_later = TRUE;
 550                                                         rockfound = 1;
 551                                                 }
 552                                         }
 553                                         if(rockfound)
 554                                                 sound(self, CH_WEAPON_B, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 555                                 }
 556                         }
 557
 558                         return TRUE;
 559                 }
 560                 case WR_INIT:
 561                 {
 562                         if(autocvar_sv_precacheweapons)
 563                         {
 564                                 precache_model("models/flash.md3");
 565                                 precache_model("models/weapons/g_rl.md3");
 566                                 precache_model("models/weapons/v_rl.md3");
 567                                 precache_model("models/weapons/h_rl.iqm");
 568                                 precache_sound("weapons/rocket_det.wav");
 569                                 precache_sound("weapons/rocket_fire.wav");
 570                                 precache_sound("weapons/rocket_mode.wav");
 571                         }
 572                         DEVASTATOR_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP)
 573                         return TRUE;
 574                 }
 575                 case WR_SETUP:
 576                 {
 577                         self.rl_release = 1;
 578                         return TRUE;
 579                 }
 580                 case WR_CHECKAMMO1:
 581                 {
 582                         #if 0
 583                         // don't switch while guiding a missile
 584                         if(ATTACK_FINISHED(self) <= time || self.weapon != WEP_DEVASTATOR)
 585                         {
 586                                 ammo_amount = FALSE;
 587                                 if(WEP_CVAR(devastator, reload_ammo))
 588                                 {
 589                                         if(self.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo) && self.(weapon_load[WEP_DEVASTATOR]) < WEP_CVAR(devastator, ammo))
 590                                                 ammo_amount = TRUE;
 591                                 }
 592                                 else if(self.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo))
 593                                         ammo_amount = TRUE;
 594                                 return !ammo_amount;
 595                         }
 596                         #endif
 597                         #if 0
 598                         if(self.rl_release == 0)
 599                         {
 600                                 printf("W_Devastator(WR_CHECKAMMO1): %d, %.2f, %d: TRUE\n", self.rl_release, self.WEP_AMMO(DEVASTATOR), WEP_CVAR(devastator, ammo));
 601                                 return TRUE;
 602                         }
 603                         else
 604                         {
 605                                 ammo_amount = self.WEP_AMMO(DEVASTATOR) >= WEP_CVAR(devastator, ammo);
 606                                 ammo_amount += self.(weapon_load[WEP_DEVASTATOR]) >= WEP_CVAR(devastator, ammo);
 607                                 printf("W_Devastator(WR_CHECKAMMO1): %d, %.2f, %d: %s\n", self.rl_release, self.WEP_AMMO(DEVASTATOR), WEP_CVAR(devastator, ammo), (ammo_amount ? "TRUE" : "FALSE"));
 608                                 return ammo_amount;
 609                         }
 610                         #else
 611                         ammo_amount = self.WEP_AMMO(DEVASTATOR) >= WEP_CVAR(devastator, ammo);
 612                         ammo_amount += self.(weapon_load[WEP_DEVASTATOR]) >= WEP_CVAR(devastator, ammo);
 613                         return ammo_amount;
 614                         #endif
 615                 }
 616                 case WR_CHECKAMMO2:
 617                 {
 618                         return FALSE;
 619                 }
 620                 case WR_CONFIG:
 621                 {
 622                         DEVASTATOR_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 623                         return TRUE;
 624                 }
 625                 case WR_RESETPLAYER:
 626                 {
 627                         self.rl_release = 0;
 628                         return TRUE;
 629                 }
 630                 case WR_RELOAD:
 631                 {
 632                         W_Reload(WEP_CVAR(devastator, ammo), "weapons/reload.wav");
 633                         return TRUE;
 634                 }
 635                 case WR_SUICIDEMESSAGE:
 636                 {
 637                         return WEAPON_DEVASTATOR_SUICIDE;
 638                 }
 639                 case WR_KILLMESSAGE:
 640                 {
 641                         if((w_deathtype & HITTYPE_BOUNCE) || (w_deathtype & HITTYPE_SPLASH))
 642                                 return WEAPON_DEVASTATOR_MURDER_SPLASH;
 643                         else
 644                                 return WEAPON_DEVASTATOR_MURDER_DIRECT;
 645                 }
 646         }
 647         return FALSE;
 648 }
 649 #endif
 650 #ifdef CSQC
 651 float W_Devastator(float req)
 652 {
 653         switch(req)
 654         {
 655                 case WR_IMPACTEFFECT:
 656                 {
 657                         vector org2;
 658                         org2 = w_org + w_backoff * 12;
 659                         pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 660                         if(!w_issilent)
 661                                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 662
 663                         return TRUE;
 664                 }
 665                 case WR_INIT:
 666                 {
 667                         precache_sound("weapons/rocket_impact.wav");
 668                         return TRUE;
 669                 }
 670                 case WR_ZOOMRETICLE:
 671                 {
 672                         // no weapon specific image for this weapon
 673                         return FALSE;
 674                 }
 675         }
 676         return FALSE;
 677 }
 678 #endif
 679 #endif