qcsrc/common/weapons/all.qc

   1 #ifndef WEAPONS_ALL_C
   2 #define WEAPONS_ALL_C
   3
   4 #include "all.qh"
   5
   6 #if defined(CSQC)
   7         #include "../../client/defs.qh"
   8         #include "../constants.qh"
   9         #include "../stats.qh"
  10         #include "../../lib/warpzone/anglestransform.qh"
  11         #include "../../lib/warpzone/common.qh"
  12         #include "../../lib/warpzone/client.qh"
  13         #include "../util.qh"
  14         #include "../../client/autocvars.qh"
  15         #include "../deathtypes/all.qh"
  16         #include "../../lib/csqcmodel/interpolate.qh"
  17         #include "../movetypes/movetypes.qh"
  18         #include "../../client/main.qh"
  19         #include "../../lib/csqcmodel/cl_model.qh"
  20 #elif defined(MENUQC)
  21 #elif defined(SVQC)
  22     #include "../../lib/warpzone/anglestransform.qh"
  23     #include "../../lib/warpzone/common.qh"
  24     #include "../../lib/warpzone/util_server.qh"
  25     #include "../../lib/warpzone/server.qh"
  26     #include "../constants.qh"
  27     #include "../stats.qh"
  28     #include "../teams.qh"
  29     #include "../util.qh"
  30     #include "../monsters/all.qh"
  31     #include "config.qh"
  32     #include "../../server/weapons/csqcprojectile.qh"
  33     #include "../../server/weapons/tracing.qh"
  34     #include "../../server/t_items.qh"
  35     #include "../../server/autocvars.qh"
  36     #include "../../server/constants.qh"
  37     #include "../../server/defs.qh"
  38     #include "../notifications.qh"
  39     #include "../deathtypes/all.qh"
  40     #include "../../server/mutators/all.qh"
  41     #include "../mapinfo.qh"
  42     #include "../../server/command/common.qh"
  43     #include "../../lib/csqcmodel/sv_model.qh"
  44     #include "../../server/portals.qh"
  45     #include "../../server/g_hook.qh"
  46 #endif
  47 #ifndef MENUQC
  48         #include "calculations.qc"
  49 #endif
  50 #define IMPLEMENTATION
  51 #include "all.inc"
  52 #undef IMPLEMENTATION
  53
  54 // WEAPON PLUGIN SYSTEM
  55
  56 WepSet _WepSet_FromWeapon(int a)
  57 {
  58         a -= WEP_FIRST;
  59         if (Weapons_MAX > 24)
  60                 if (a >= 24)
  61                 {
  62                         a -= 24;
  63                         if (Weapons_MAX > 48)
  64                                 if (a >= 24)
  65                                 {
  66                                         a -= 24;
  67                                         return '0 0 1' * power2of(a);
  68                                 }
  69                         return '0 1 0' * power2of(a);
  70                 }
  71         return '1 0 0' * power2of(a);
  72 }
  73 #ifdef SVQC
  74         void WriteWepSet(float dst, WepSet w)
  75         {
  76                 if (Weapons_MAX > 48) WriteInt72_t(dst, w);
  77                 else if (Weapons_MAX > 24) WriteInt48_t(dst, w);
  78                 else WriteInt24_t(dst, w.x);
  79         }
  80 #endif
  81 #ifdef CSQC
  82         WepSet WepSet_GetFromStat()
  83         {
  84                 return STAT(WEAPONS);
  85         }
  86         WepSet WepSet_GetFromStat_InMap()
  87         {
  88                 return STAT(WEAPONSINMAP);
  89         }
  90         WepSet ReadWepSet()
  91         {
  92                 if (Weapons_MAX > 48) return ReadInt72_t();
  93                 if (Weapons_MAX > 24) return ReadInt48_t();
  94                 return ReadInt24_t() * '1 0 0';
  95         }
  96 #endif
  97
  98 string W_FixWeaponOrder(string order, float complete)
  99 {
 100         return fixPriorityList(order, WEP_FIRST, WEP_LAST, WEP_IMPULSE_BEGIN - WEP_FIRST, complete);
 101 }
 102 string W_NameWeaponOrder_MapFunc(string s)
 103 {
 104         entity wi;
 105         if (s == "0" || stof(s))
 106         {
 107                 wi = get_weaponinfo(stof(s));
 108                 if (wi != WEP_Null) return wi.netname;
 109         }
 110         return s;
 111 }
 112
 113 string W_UndeprecateName(string s)
 114 {
 115         switch (s)
 116         {
 117                 case "nex": return "vortex";
 118                 case "rocketlauncher": return "devastator";
 119                 case "laser": return "blaster";
 120                 case "minstanex": return "vaporizer";
 121                 case "grenadelauncher": return "mortar";
 122                 case "uzi": return "machinegun";
 123                 default: return s;
 124         }
 125 }
 126 string W_NameWeaponOrder(string order)
 127 {
 128         return mapPriorityList(order, W_NameWeaponOrder_MapFunc);
 129 }
 130 string W_NumberWeaponOrder_MapFunc(string s)
 131 {
 132         int i;
 133         if (s == "0" || stof(s)) return s;
 134         s = W_UndeprecateName(s);
 135         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 136                 if (s == get_weaponinfo(i).netname) return ftos(i);
 137         return s;
 138 }
 139 string W_NumberWeaponOrder(string order)
 140 {
 141         return mapPriorityList(order, W_NumberWeaponOrder_MapFunc);
 142 }
 143
 144 float W_FixWeaponOrder_BuildImpulseList_buf[Weapons_MAX];
 145 string W_FixWeaponOrder_BuildImpulseList_order;
 146 void W_FixWeaponOrder_BuildImpulseList_swap(int i, int j, entity pass)
 147 {
 148         float h;
 149         h = W_FixWeaponOrder_BuildImpulseList_buf[i];
 150         W_FixWeaponOrder_BuildImpulseList_buf[i] = W_FixWeaponOrder_BuildImpulseList_buf[j];
 151         W_FixWeaponOrder_BuildImpulseList_buf[j] = h;
 152 }
 153 float W_FixWeaponOrder_BuildImpulseList_cmp(int i, int j, entity pass)
 154 {
 155         entity e1, e2;
 156         float d;
 157         e1 = get_weaponinfo(W_FixWeaponOrder_BuildImpulseList_buf[i]);
 158         e2 = get_weaponinfo(W_FixWeaponOrder_BuildImpulseList_buf[j]);
 159         d = (e1.impulse + 9) % 10 - (e2.impulse + 9) % 10;
 160         if (d != 0) return -d;  // high impulse first!
 161         return strstrofs(strcat(" ", W_FixWeaponOrder_BuildImpulseList_order, " "),
 162                 sprintf(" %d ", W_FixWeaponOrder_BuildImpulseList_buf[i]), 0)
 163                -
 164                strstrofs(strcat(" ", W_FixWeaponOrder_BuildImpulseList_order, " "),
 165                 sprintf(" %d ", W_FixWeaponOrder_BuildImpulseList_buf[j]), 0)
 166         ;  // low char index first!
 167 }
 168 string W_FixWeaponOrder_BuildImpulseList(string o)
 169 {
 170         int i;
 171         W_FixWeaponOrder_BuildImpulseList_order = o;
 172         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 173                 W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST] = i;
 174         heapsort(WEP_LAST - WEP_FIRST + 1, W_FixWeaponOrder_BuildImpulseList_swap, W_FixWeaponOrder_BuildImpulseList_cmp,
 175                 world);
 176         o = "";
 177         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 178                 o = strcat(o, " ", ftos(W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST]));
 179         W_FixWeaponOrder_BuildImpulseList_order = string_null;
 180         return substring(o, 1, -1);
 181 }
 182
 183 string W_FixWeaponOrder_AllowIncomplete(string order)
 184 {
 185         return W_FixWeaponOrder(order, 0);
 186 }
 187
 188 string W_FixWeaponOrder_ForceComplete(string order)
 189 {
 190         if (order == "") order = W_NumberWeaponOrder(cvar_defstring("cl_weaponpriority"));
 191         return W_FixWeaponOrder(order, 1);
 192 }
 193
 194 void W_RandomWeapons(entity e, float n)
 195 {
 196         int i, j;
 197         WepSet remaining;
 198         WepSet result;
 199         remaining = e.weapons;
 200         result = '0 0 0';
 201         for (i = 0; i < n; ++i)
 202         {
 203                 RandomSelection_Init();
 204                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 205                         if (remaining & WepSet_FromWeapon(j)) RandomSelection_Add(world, j, string_null, 1, 1);
 206                 result |= WepSet_FromWeapon(RandomSelection_chosen_float);
 207                 remaining &= ~WepSet_FromWeapon(RandomSelection_chosen_float);
 208         }
 209         e.weapons = result;
 210 }
 211
 212 string GetAmmoPicture(.int ammotype)
 213 {
 214         switch (ammotype)
 215         {
 216                 case ammo_shells:  return ITEM_Shells.m_icon;
 217                 case ammo_nails:   return ITEM_Bullets.m_icon;
 218                 case ammo_rockets: return ITEM_Rockets.m_icon;
 219                 case ammo_cells:   return ITEM_Cells.m_icon;
 220                 case ammo_plasma:  return ITEM_Plasma.m_icon;
 221                 case ammo_fuel:    return ITEM_JetpackFuel.m_icon;
 222                 default: return "";  // wtf, no ammo type?
 223         }
 224 }
 225
 226 #ifdef CSQC
 227         .int GetAmmoFieldFromNum(int i)
 228         {
 229                 switch (i)
 230                 {
 231                         case 0: return ammo_shells;
 232                         case 1: return ammo_nails;
 233                         case 2: return ammo_rockets;
 234                         case 3: return ammo_cells;
 235                         case 4: return ammo_plasma;
 236                         case 5: return ammo_fuel;
 237                         default: return ammo_none;
 238                 }
 239         }
 240
 241         int GetAmmoStat(.int ammotype)
 242         {
 243                 switch (ammotype)
 244                 {
 245                         case ammo_shells: return STAT_SHELLS;
 246                         case ammo_nails: return STAT_NAILS;
 247                         case ammo_rockets: return STAT_ROCKETS;
 248                         case ammo_cells: return STAT_CELLS;
 249                         case ammo_plasma: return STAT_PLASMA.m_id;
 250                         case ammo_fuel: return STAT_FUEL.m_id;
 251                         default: return -1;
 252                 }
 253         }
 254 #endif
 255
 256 string W_Sound(string w_snd)
 257 {
 258         string output = strcat("weapons/", w_snd);
 259 #ifdef SVQC
 260                 MUTATOR_CALLHOOK(WeaponSound, w_snd, output);
 261                 return weapon_sound_output;
 262 #else
 263                 return output;
 264 #endif
 265 }
 266
 267 string W_Model(string w_mdl)
 268 {
 269         string output = strcat("models/weapons/", w_mdl);
 270 #ifdef SVQC
 271                 MUTATOR_CALLHOOK(WeaponModel, w_mdl, output);
 272                 return weapon_model_output;
 273 #else
 274                 return output;
 275 #endif
 276 }
 277
 278 #ifndef MENUQC
 279 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float algn)
 280 {
 281         switch (algn)
 282         {
 283                 default:
 284                 case 3:
 285                         // right alignment
 286                         break;
 287                 case 4:
 288                         // left
 289                         vecs.y = -vecs.y;
 290                         break;
 291                 case 1:
 292                 case 2:
 293                         // center
 294                         vecs.y = 0;
 295                         vecs.z -= 2;
 296                         break;
 297         }
 298         return vecs;
 299 }
 300
 301 vector shotorg_adjust_values(vector vecs, bool y_is_right, bool visual, int algn)
 302 {
 303 #ifdef SVQC
 304         string s;
 305 #endif
 306         if (visual)
 307         {
 308                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 309         }
 310 #ifdef SVQC
 311         else if (autocvar_g_shootfromeye)
 312         {
 313                 vecs.y = vecs.z = 0;
 314         }
 315         else if (autocvar_g_shootfromcenter)
 316         {
 317                 vecs.y = 0;
 318                 vecs.z -= 2;
 319         }
 320         else if ((s = autocvar_g_shootfromfixedorigin) != "")
 321         {
 322                 vector v = stov(s);
 323                 if (y_is_right) v.y = -v.y;
 324                 if (v.x != 0) vecs.x = v.x;
 325                 vecs.y = v.y;
 326                 vecs.z = v.z;
 327         }
 328 #endif
 329         else  // just do the same as top
 330         {
 331                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 332         }
 333
 334         return vecs;
 335 }
 336
 337 #define shotorg_adjust shotorg_adjust_values
 338
 339 /**
 340  * supported formats:
 341  *
 342  * 1. simple animated model, muzzle flash handling on h_ model:
 343  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 344  *      tags:
 345  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 346  *        shell = casings ejection point (must be on the right hand side of the gun)
 347  *        weapon = attachment for v_tuba.md3
 348  *    v_tuba.md3 - first and third person model
 349  *    g_tuba.md3 - pickup model
 350  *
 351  * 2. simple animated model, muzzle flash handling on v_ model:
 352  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 353  *      tags:
 354  *        weapon = attachment for v_tuba.md3
 355  *    v_tuba.md3 - first and third person model
 356  *      tags:
 357  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 358  *        shell = casings ejection point (must be on the right hand side of the gun)
 359  *    g_tuba.md3 - pickup model
 360  *
 361  * 3. fully animated model, muzzle flash handling on h_ model:
 362  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 363  *      tags:
 364  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 365  *        shell = casings ejection point (must be on the right hand side of the gun)
 366  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 367  *    v_tuba.md3 - third person model
 368  *    g_tuba.md3 - pickup model
 369  *
 370  * 4. fully animated model, muzzle flash handling on v_ model:
 371  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 372  *      tags:
 373  *        shot = muzzle end (shot origin)
 374  *        shell = casings ejection point (must be on the right hand side of the gun)
 375  *    v_tuba.md3 - third person model
 376  *      tags:
 377  *        shot = muzzle end (for muzzle flashes)
 378  *    g_tuba.md3 - pickup model
 379  *
 380  * writes:
 381  *   this.origin, this.angles
 382  *   this.weaponchild
 383  *   this.movedir, this.view_ofs
 384  *   attachment stuff
 385  *   anim stuff
 386  * to free:
 387  *   call again with ""
 388  *   remove the ent
 389  */
 390 void CL_WeaponEntity_SetModel(entity this, string name)
 391 {
 392         if (name == "")
 393         {
 394                 this.model = "";
 395                 if (this.weaponchild) remove(this.weaponchild);
 396                 this.weaponchild = NULL;
 397                 this.movedir = '0 0 0';
 398                 this.spawnorigin = '0 0 0';
 399                 this.oldorigin = '0 0 0';
 400                 this.anim_fire1  = '0 1 0.01';
 401                 this.anim_fire2  = '0 1 0.01';
 402                 this.anim_idle   = '0 1 0.01';
 403                 this.anim_reload = '0 1 0.01';
 404         }
 405         else
 406         {
 407                 // if there is a child entity, hide it until we're sure we use it
 408                 if (this.weaponchild) this.weaponchild.model = "";
 409                 _setmodel(this, W_Model(strcat("v_", name, ".md3")));
 410                 int v_shot_idx;  // used later
 411                 (v_shot_idx = gettagindex(this, "shot")) || (v_shot_idx = gettagindex(this, "tag_shot"));
 412
 413                 _setmodel(this, W_Model(strcat("h_", name, ".iqm")));
 414                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 415                 this.anim_fire1  = animfixfps(this, '0 1 0.01', '0 0 0');
 416                 this.anim_fire2  = animfixfps(this, '1 1 0.01', '0 0 0');
 417                 this.anim_idle   = animfixfps(this, '2 1 0.01', '0 0 0');
 418                 this.anim_reload = animfixfps(this, '3 1 0.01', '0 0 0');
 419
 420                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 421                 // if we don't, this is a "real" animated model
 422                 string t;
 423                 if ((t = "weapon", gettagindex(this, t)) || (t = "tag_weapon", gettagindex(this, t)))
 424                 {
 425                         if (!this.weaponchild)
 426                         {
 427                                 this.weaponchild = new(weaponchild);
 428                                 make_pure(this.weaponchild);
 429 #ifdef CSQC
 430                                 this.weaponchild.drawmask = MASK_NORMAL;
 431                                 this.weaponchild.renderflags |= RF_VIEWMODEL;
 432 #endif
 433                         }
 434                         _setmodel(this.weaponchild, W_Model(strcat("v_", name, ".md3")));
 435                         setattachment(this.weaponchild, this, t);
 436                 }
 437                 else
 438                 {
 439                         if (this.weaponchild) remove(this.weaponchild);
 440                         this.weaponchild = NULL;
 441                 }
 442
 443                 setorigin(this, '0 0 0');
 444                 this.angles = '0 0 0';
 445                 this.frame = 0;
 446 #ifdef SVQC
 447                 this.viewmodelforclient = NULL;
 448 #else
 449                 this.renderflags &= ~RF_VIEWMODEL;
 450 #endif
 451                 if (v_shot_idx)  // v_ model attached to invisible h_ model
 452                 {
 453                         this.movedir = gettaginfo(this.weaponchild, v_shot_idx);
 454                 }
 455                 else
 456                 {
 457                         int idx;
 458                         if ((idx = gettagindex(this, "shot")) || (idx = gettagindex(this, "tag_shot")))
 459                         {
 460                                 this.movedir = gettaginfo(this, idx);
 461                         }
 462                         else
 463                         {
 464                                 LOG_WARNINGF("weapon model %s does not support the 'shot' tag, will display shots TOTALLY wrong\n",
 465                                         this.model);
 466                                 this.movedir = '0 0 0';
 467                         }
 468                 }
 469                 {
 470                         int idx = 0;
 471                         // v_ model attached to invisible h_ model
 472                         if (this.weaponchild
 473                             && ((idx = gettagindex(this.weaponchild, "shell")) || (idx = gettagindex(this.weaponchild, "tag_shell"))))
 474                         {
 475                                 this.spawnorigin = gettaginfo(this.weaponchild, idx);
 476                         }
 477                         else if ((idx = gettagindex(this, "shell")) || (idx = gettagindex(this, "tag_shell")))
 478                         {
 479                                 this.spawnorigin = gettaginfo(this, idx);
 480                         }
 481                         else
 482                         {
 483                                 LOG_WARNINGF("weapon model %s does not support the 'shell' tag, will display casings wrong\n",
 484                                         this.model);
 485                                 this.spawnorigin = this.movedir;
 486                         }
 487                 }
 488                 if (v_shot_idx)
 489                 {
 490                         this.oldorigin = '0 0 0';  // use regular attachment
 491                 }
 492                 else
 493                 {
 494                         int idx;
 495                         if (this.weaponchild)
 496                                 (idx = gettagindex(this, "weapon")) || (idx = gettagindex(this, "tag_weapon"));
 497                         else
 498                                 (idx = gettagindex(this, "handle")) || (idx = gettagindex(this, "tag_handle"));
 499                         if (idx)
 500                         {
 501                                 this.oldorigin = this.movedir - gettaginfo(this, idx);
 502                         }
 503                         else
 504                         {
 505                                 LOG_WARNINGF(
 506                                         "weapon model %s does not support the 'handle' tag "
 507                                         "and neither does the v_ model support the 'shot' tag, "
 508                                         "will display muzzle flashes TOTALLY wrong\n",
 509                                         this.model);
 510                                 this.oldorigin = '0 0 0';  // there is no way to recover from this
 511                         }
 512                 }
 513
 514 #ifdef SVQC
 515                 this.viewmodelforclient = this.owner;
 516 #else
 517                 this.renderflags |= RF_VIEWMODEL;
 518 #endif
 519         }
 520
 521         this.view_ofs = '0 0 0';
 522
 523         if (this.movedir.x >= 0)
 524         {
 525 #ifdef SVQC
 526                 int algn = this.owner.cvar_cl_gunalign;
 527 #else
 528                 int algn = autocvar_cl_gunalign;
 529 #endif
 530                 vector v = this.movedir;
 531                 this.movedir = shotorg_adjust(v, false, false, algn);
 532                 this.view_ofs = shotorg_adjust(v, false, true, algn) - v;
 533         }
 534         int compressed_shotorg = compressShotOrigin(this.movedir);
 535         // make them match perfectly
 536 #ifdef SVQC
 537         this.movedir = decompressShotOrigin(this.owner.stat_shotorg = compressed_shotorg);
 538 #else
 539         this.movedir = decompressShotOrigin(compressed_shotorg);
 540 #endif
 541
 542         this.spawnorigin += this.view_ofs;  // offset the casings origin by the same amount
 543
 544         // check if an instant weapon switch occurred
 545         setorigin(this, this.view_ofs);
 546         // reset animstate now
 547         this.wframe = WFRAME_IDLE;
 548         setanim(this, this.anim_idle, true, false, true);
 549 }
 550 #endif
 551
 552 #ifndef MENUQC
 553
 554 REGISTER_NET_TEMP(wframe)
 555 #ifdef CSQC
 556 NET_HANDLE(wframe, bool isNew)
 557 {
 558         vector a;
 559         a.x = ReadCoord();
 560     a.y = ReadCoord();
 561     a.z = ReadCoord();
 562         bool restartanim = ReadByte();
 563         anim_set(viewmodel, a, !restartanim, restartanim, restartanim);
 564         viewmodel.state = ReadByte();
 565         viewmodel.weapon_nextthink = ReadFloat();
 566         viewmodel.alpha = ReadByte() / 255;
 567         switch (viewmodel.state)
 568         {
 569                 case WS_RAISE:
 570                 case WS_DROP:
 571                         viewmodel.weapon_switchdelay = ReadFloat();
 572                         break;
 573         default:
 574             viewmodel.weapon_switchdelay = 0;
 575             break;
 576         }
 577         return true;
 578 }
 579 #endif
 580
 581 #ifdef SVQC
 582 void wframe_send(entity actor, entity weaponentity, vector a, bool restartanim)
 583 {
 584         if (!IS_REAL_CLIENT(actor)) return;
 585         int channel = MSG_ONE;
 586         msg_entity = actor;
 587         WriteHeader(channel, wframe);
 588         WriteCoord(channel, a.x);
 589         WriteCoord(channel, a.y);
 590         WriteCoord(channel, a.z);
 591         WriteByte(channel, restartanim);
 592         WriteByte(channel, weaponentity.state);
 593         WriteFloat(channel, weaponentity.weapon_nextthink);
 594         WriteByte(channel, weaponentity.m_alpha * 255);
 595         Weapon w = Weapons_from(actor.weapon);
 596         switch (weaponentity.state)
 597         {
 598                 case WS_RAISE:
 599                         WriteFloat(channel, w.switchdelay_raise);
 600                         break;
 601                 case WS_DROP:
 602                         WriteFloat(channel, w.switchdelay_drop);
 603                         break;
 604         }
 605 }
 606 #endif
 607
 608 #endif
 609
 610 #endif