qcsrc/common/monsters/sv_monsters.qc

   1 // =========================
   2 //  SVQC Monster Properties
   3 // =========================
   4
   5
   6 void M_Item_Touch ()
   7 {
   8         if(self && IS_PLAYER(other) && other.deadflag == DEAD_NO)
   9         {
  10                 Item_Touch();
  11                 self.think = SUB_Remove;
  12                 self.nextthink = time + 0.1;
  13         }
  14 }
  15
  16 void monster_item_spawn()
  17 {
  18         if(self.monster_loot)
  19                 self.monster_loot();
  20
  21         self.gravity = 1;
  22         self.velocity = randomvec() * 175 + '0 0 325';
  23         self.touch = M_Item_Touch;
  24
  25         SUB_SetFade(self, time + autocvar_g_monsters_drop_time, 1);
  26 }
  27
  28 void monster_dropitem()
  29 {
  30         if(!self.candrop || !self.monster_loot)
  31                 return;
  32
  33         vector org = self.origin + ((self.mins + self.maxs) * 0.5);
  34         entity e = spawn();
  35
  36         setorigin(e, org);
  37
  38         e.monster_loot = self.monster_loot;
  39
  40         other = e;
  41         MUTATOR_CALLHOOK(MonsterDropItem);
  42         e = other;
  43
  44         e.think = monster_item_spawn;
  45         e.nextthink = time + 0.3;
  46 }
  47
  48 void monsters_setframe(float _frame)
  49 {
  50         if(self.frame == _frame)
  51                 return;
  52
  53         self.anim_start_time = time;
  54         self.frame = _frame;
  55         self.SendFlags |= MSF_ANIM;
  56 }
  57
  58 float monster_isvalidtarget (entity targ, entity ent)
  59 {
  60         if(!targ || !ent)
  61                 return FALSE; // someone doesn't exist
  62
  63         if(targ == ent)
  64                 return FALSE; // don't attack ourselves
  65
  66         traceline(ent.origin, targ.origin, MOVE_NORMAL, ent);
  67
  68         if(trace_ent != targ)
  69                 return FALSE;
  70
  71         if(targ.vehicle_flags & VHF_ISVEHICLE)
  72         if not((get_monsterinfo(ent.monsterid)).spawnflags & MON_FLAG_RANGED)
  73                 return FALSE; // melee attacks are useless against vehicles
  74
  75         if(time < game_starttime)
  76                 return FALSE; // monsters do nothing before the match has started
  77
  78         if(vlen(targ.origin - ent.origin) >= ent.target_range)
  79                 return FALSE; // enemy is too far away
  80
  81         if(targ.takedamage == DAMAGE_NO)
  82                 return FALSE; // enemy can't be damaged
  83
  84         if(targ.items & IT_INVISIBILITY)
  85                 return FALSE; // enemy is invisible
  86
  87         if(substring(targ.classname, 0, 10) == "onslaught_")
  88                 return FALSE; // don't attack onslaught targets
  89
  90         if(IS_SPEC(targ) || IS_OBSERVER(targ))
  91                 return FALSE; // enemy is a spectator
  92
  93         if not(targ.vehicle_flags & VHF_ISVEHICLE)
  94         if(targ.deadflag != DEAD_NO || ent.deadflag != DEAD_NO || targ.health <= 0 || ent.health <= 0)
  95                 return FALSE; // enemy/self is dead
  96
  97         if(ent.monster_owner == targ)
  98                 return FALSE; // don't attack our master
  99
 100         if(targ.monster_owner == ent)
 101                 return FALSE; // don't attack our pet
 102
 103         if not(targ.vehicle_flags & VHF_ISVEHICLE)
 104         if(targ.flags & FL_NOTARGET)
 105                 return FALSE; // enemy can't be targeted
 106
 107         if not(autocvar_g_monsters_typefrag)
 108         if(targ.BUTTON_CHAT)
 109                 return FALSE; // no typefragging!
 110
 111         if not(IsDifferentTeam(targ, ent))
 112                 return FALSE; // enemy is on our team
 113
 114         if(autocvar_g_monsters_target_infront || ent.spawnflags & MONSTERFLAG_INFRONT)
 115         if(ent.enemy != targ)
 116         {
 117                 float dot;
 118
 119                 makevectors (ent.angles);
 120                 dot = normalize (targ.origin - ent.origin) * v_forward;
 121
 122                 if(dot <= 0.3)
 123                         return FALSE;
 124         }
 125
 126         return TRUE;
 127 }
 128
 129 entity FindTarget (entity ent)
 130 {
 131         if(MUTATOR_CALLHOOK(MonsterFindTarget)) { return ent.enemy; } // Handled by a mutator
 132
 133         entity head, closest_target = world;
 134         head = findradius(ent.origin, ent.target_range);
 135
 136         while(head) // find the closest acceptable target to pass to
 137         {
 138                 if(head.monster_attack)
 139                 if(monster_isvalidtarget(head, ent))
 140                 {
 141                         // if it's a player, use the view origin as reference (stolen from RadiusDamage functions in g_damage.qc)
 142                         vector head_center = CENTER_OR_VIEWOFS(head);
 143                         vector ent_center = CENTER_OR_VIEWOFS(ent);
 144
 145                         //if(ctf_CheckPassDirection(head_center, ent_center, ent.v_angle, head.WarpZone_findradius_nearest))
 146                         if(closest_target)
 147                         {
 148                                 vector closest_target_center = CENTER_OR_VIEWOFS(closest_target);
 149                                 if(vlen(ent_center - head_center) < vlen(ent_center - closest_target_center))
 150                                         { closest_target = head; }
 151                         }
 152                         else { closest_target = head; }
 153                 }
 154
 155                 head = head.chain;
 156         }
 157
 158         return closest_target;
 159 }
 160
 161 void MonsterTouch ()
 162 {
 163         if(other == world)
 164                 return;
 165
 166         if(self.enemy != other)
 167         if not(other.flags & FL_MONSTER)
 168         if(monster_isvalidtarget(other, self))
 169                 self.enemy = other;
 170 }
 171
 172 string get_monster_model_datafilename(string m, float sk, string fil)
 173 {
 174         if(m)
 175                 m = strcat(m, "_");
 176         else
 177                 m = "models/monsters/*_";
 178         if(sk >= 0)
 179                 m = strcat(m, ftos(sk));
 180         else
 181                 m = strcat(m, "*");
 182         return strcat(m, ".", fil);
 183 }
 184
 185 void PrecacheMonsterSounds(string f)
 186 {
 187         float fh;
 188         string s;
 189         fh = fopen(f, FILE_READ);
 190         if(fh < 0)
 191                 return;
 192         while((s = fgets(fh)))
 193         {
 194                 if(tokenize_console(s) != 3)
 195                 {
 196                         dprint("Invalid sound info line: ", s, "\n");
 197                         continue;
 198                 }
 199                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
 200         }
 201         fclose(fh);
 202 }
 203
 204 void precache_monstersounds()
 205 {
 206         string m = (get_monsterinfo(self.monsterid)).model;
 207         float globhandle, n, i;
 208         string f;
 209
 210         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
 211         if (globhandle < 0)
 212                 return;
 213         n = search_getsize(globhandle);
 214         for (i = 0; i < n; ++i)
 215         {
 216                 //print(search_getfilename(globhandle, i), "\n");
 217                 f = search_getfilename(globhandle, i);
 218                 PrecacheMonsterSounds(f);
 219         }
 220         search_end(globhandle);
 221 }
 222
 223 void ClearMonsterSounds()
 224 {
 225 #define _MSOUND(m) if(self.monstersound_##m) { strunzone(self.monstersound_##m); self.monstersound_##m = string_null; }
 226         ALLMONSTERSOUNDS
 227 #undef _MSOUND
 228 }
 229
 230 .string GetMonsterSoundSampleField(string type)
 231 {
 232         GetMonsterSoundSampleField_notFound = 0;
 233         switch(type)
 234         {
 235 #define _MSOUND(m) case #m: return monstersound_##m;
 236                 ALLMONSTERSOUNDS
 237 #undef _MSOUND
 238         }
 239         GetMonsterSoundSampleField_notFound = 1;
 240         return string_null;
 241 }
 242
 243 float LoadMonsterSounds(string f, float first)
 244 {
 245         float fh;
 246         string s;
 247         var .string field;
 248         fh = fopen(f, FILE_READ);
 249         if(fh < 0)
 250         {
 251                 dprint("Monster sound file not found: ", f, "\n");
 252                 return 0;
 253         }
 254         while((s = fgets(fh)))
 255         {
 256                 if(tokenize_console(s) != 3)
 257                         continue;
 258                 field = GetMonsterSoundSampleField(argv(0));
 259                 if(GetMonsterSoundSampleField_notFound)
 260                         continue;
 261                 if(self.field)
 262                         strunzone(self.field);
 263                 self.field = strzone(strcat(argv(1), " ", argv(2)));
 264         }
 265         fclose(fh);
 266         return 1;
 267 }
 268
 269 .float skin_for_monstersound;
 270 void UpdateMonsterSounds()
 271 {
 272         entity mon = get_monsterinfo(self.monsterid);
 273
 274         if(self.skin == self.skin_for_monstersound)
 275                 return;
 276         self.skin_for_monstersound = self.skin;
 277         ClearMonsterSounds();
 278         //LoadMonsterSounds("sound/monsters/default.sounds", 1);
 279         if(!autocvar_g_debug_defaultsounds)
 280         if(!LoadMonsterSounds(get_monster_model_datafilename(mon.model, self.skin, "sounds"), 0))
 281                 LoadMonsterSounds(get_monster_model_datafilename(mon.model, 0, "sounds"), 0);
 282 }
 283
 284 void MonsterSound(.string samplefield, float sound_delay, float delaytoo, float chan)
 285 {
 286         if(delaytoo && time < self.msound_delay)
 287                 return; // too early
 288         GlobalSound(self.samplefield, chan, VOICETYPE_PLAYERSOUND);
 289
 290         self.msound_delay = time + sound_delay;
 291 }
 292
 293 void monster_makevectors(entity e)
 294 {
 295         vector v;
 296
 297         v = CENTER_OR_VIEWOFS(e);
 298         self.v_angle = vectoangles(v - (self.origin + self.view_ofs));
 299         self.v_angle_x = -self.v_angle_x;
 300
 301         makevectors(self.v_angle);
 302 }
 303
 304 float monster_melee(entity targ, float damg, float anim, float er, float anim_finished, float deathtype, float dostop)
 305 {
 306         float rdmg = damg * random();
 307
 308         if (self.health <= 0)
 309                 return FALSE; // attacking while dead?!
 310
 311         if(dostop)
 312         {
 313                 self.velocity_x = 0;
 314                 self.velocity_y = 0;
 315                 self.state = MONSTER_STATE_ATTACK_MELEE;
 316                 self.SendFlags |= MSF_MOVE;
 317         }
 318
 319         monsters_setframe(anim);
 320
 321         if(anim_finished != 0)
 322                 self.attack_finished_single = time + anim_finished;
 323
 324         monster_makevectors(targ);
 325
 326         traceline(self.origin + self.view_ofs, self.origin + v_forward * er, 0, self);
 327
 328         if(trace_ent.takedamage)
 329                 Damage(trace_ent, self, self, rdmg * monster_skill, deathtype, trace_ent.origin, normalize(trace_ent.origin - self.origin));
 330
 331         return TRUE;
 332 }
 333
 334 void Monster_CheckMinibossFlag ()
 335 {
 336         if(MUTATOR_CALLHOOK(MonsterCheckBossFlag))
 337                 return;
 338
 339         float chance = random() * 100;
 340
 341         // g_monsters_miniboss_chance cvar or spawnflags 64 causes a monster to be a miniboss
 342         if ((self.spawnflags & MONSTERFLAG_MINIBOSS) || (chance < autocvar_g_monsters_miniboss_chance))
 343         {
 344                 self.health += autocvar_g_monsters_miniboss_healthboost;
 345                 if not(self.weapon)
 346                         self.weapon = WEP_NEX;
 347         }
 348 }
 349
 350 float Monster_CanRespawn(entity ent)
 351 {
 352         other = ent;
 353         if(MUTATOR_CALLHOOK(MonsterRespawn))
 354                 return TRUE; // enabled by a mutator
 355
 356         if(ent.spawnflags & MONSTERFLAG_NORESPAWN)
 357                 return FALSE;
 358
 359         if not(autocvar_g_monsters_respawn)
 360                 return FALSE;
 361
 362         return TRUE;
 363 }
 364
 365 void Monster_Fade ()
 366 {
 367         if(Monster_CanRespawn(self))
 368         {
 369                 self.monster_respawned = TRUE;
 370                 self.think = self.monster_spawnfunc;
 371                 self.nextthink = time + self.respawntime;
 372                 self.deadflag = DEAD_RESPAWNING;
 373                 if(self.spawnflags & MONSTER_RESPAWN_DEATHPOINT)
 374                 {
 375                         self.pos1 = self.origin;
 376                         self.pos2 = self.angles;
 377                 }
 378                 self.event_damage = func_null;
 379                 self.takedamage = DAMAGE_NO;
 380                 setorigin(self, self.pos1);
 381                 self.angles = self.pos2;
 382                 self.health = self.max_health;
 383
 384                 self.SendFlags |= MSF_MOVE;
 385                 self.SendFlags |= MSF_STATUS;
 386         }
 387         else
 388                 SUB_SetFade(self, time + 3, 1);
 389 }
 390
 391 float Monster_CanJump (vector vel)
 392 {
 393         if(self.state)
 394                 return FALSE; // already attacking
 395         if not(self.flags & FL_ONGROUND)
 396                 return FALSE; // not on the ground
 397         if(self.health <= 0)
 398                 return FALSE; // called when dead?
 399         if(time < self.attack_finished_single)
 400                 return FALSE; // still attacking
 401
 402         vector old = self.velocity;
 403
 404         self.velocity = vel;
 405         tracetoss(self, self);
 406         self.velocity = old;
 407         if (trace_ent != self.enemy)
 408                 return FALSE;
 409
 410         return TRUE;
 411 }
 412
 413 float monster_leap (float anm, void() touchfunc, vector vel, float anim_finished)
 414 {
 415         if(!Monster_CanJump(vel))
 416                 return FALSE;
 417
 418         monsters_setframe(anm);
 419         self.state = MONSTER_STATE_ATTACK_LEAP;
 420         self.touch = touchfunc;
 421         self.origin_z += 1;
 422         self.velocity = vel;
 423         self.flags &= ~FL_ONGROUND;
 424
 425         self.attack_finished_single = time + anim_finished;
 426
 427         return TRUE;
 428 }
 429
 430 void monster_checkattack(entity e, entity targ)
 431 {
 432         if(e == world)
 433                 return;
 434         if(targ == world)
 435                 return;
 436
 437         if not(e.monster_attackfunc)
 438                 return;
 439
 440         if(time < e.attack_finished_single)
 441                 return;
 442
 443         if(vlen(targ.origin - e.origin) <= e.attack_range)
 444         if(e.monster_attackfunc(MONSTER_ATTACK_MELEE))
 445         {
 446                 //monster_sound(e.msound_attack_melee, 0, FALSE);
 447                 MonsterSound(monstersound_melee, 0, FALSE, CH_VOICE);
 448                 return;
 449         }
 450
 451         if(vlen(targ.origin - e.origin) > e.attack_range)
 452         if(e.monster_attackfunc(MONSTER_ATTACK_RANGED))
 453         {
 454                 //monster_sound(e.msound_attack_ranged, 0, FALSE);
 455                 MonsterSound(monstersound_ranged, 0, FALSE, CH_VOICE);
 456                 return;
 457         }
 458 }
 459
 460 void monster_use ()
 461 {
 462         if not(self.enemy)
 463         if(self.health > 0)
 464         if(monster_isvalidtarget(activator, self))
 465                 self.enemy = activator;
 466 }
 467
 468 .float last_trace;
 469 .float last_enemycheck; // for checking enemy
 470 vector monster_pickmovetarget(entity targ)
 471 {
 472         // enemy is always preferred target
 473         if(self.enemy)
 474         {
 475                 makevectors(self.angles);
 476                 self.monster_movestate = MONSTER_MOVE_ENEMY;
 477                 self.last_trace = time + 1.2;
 478                 return self.enemy.origin;
 479         }
 480
 481         switch(self.monster_moveflags)
 482         {
 483                 case MONSTER_MOVE_OWNER:
 484                 {
 485                         self.monster_movestate = MONSTER_MOVE_OWNER;
 486                         self.last_trace = time + 0.3;
 487                         return (self.monster_owner) ? self.monster_owner.origin : self.origin;
 488                 }
 489                 case MONSTER_MOVE_SPAWNLOC:
 490                 {
 491                         self.monster_movestate = MONSTER_MOVE_SPAWNLOC;
 492                         self.last_trace = time + 2;
 493                         return self.pos1;
 494                 }
 495                 case MONSTER_MOVE_NOMOVE:
 496                 {
 497                         self.monster_movestate = MONSTER_MOVE_NOMOVE;
 498                         self.last_trace = time + 2;
 499                         return self.origin;
 500                 }
 501                 default:
 502                 case MONSTER_MOVE_WANDER:
 503                 {
 504                         vector pos;
 505                         self.monster_movestate = MONSTER_MOVE_WANDER;
 506                         self.last_trace = time + 2;
 507
 508                         self.angles_y = rint(random() * 500);
 509                         makevectors(self.angles);
 510                         pos = self.origin + v_forward * 600;
 511
 512                         if(self.flags & FL_FLY || self.flags & FL_SWIM)
 513                         if(self.spawnflags & MONSTERFLAG_FLY_VERTICAL)
 514                         {
 515                                 pos_z = random() * 200;
 516                                 if(random() >= 0.5)
 517                                         pos_z *= -1;
 518                         }
 519
 520                         if(targ)
 521                         {
 522                                 self.last_trace = time + 0.5;
 523                                 pos = targ.origin;
 524                         }
 525
 526                         return pos;
 527                 }
 528         }
 529 }
 530
 531 void monster_move(float runspeed, float walkspeed, float stopspeed, float manim_run, float manim_walk, float manim_idle)
 532 {
 533         fixedmakevectors(self.angles);
 534
 535         if(self.target2)
 536                 self.goalentity = find(world, targetname, self.target2);
 537
 538         entity targ;
 539
 540         if(self.frozen)
 541         {
 542                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
 543                 self.health = max(1, self.max_health * self.revive_progress);
 544
 545                 self.SendFlags |= MSF_STATUS;
 546
 547                 movelib_beak_simple(stopspeed);
 548
 549                 self.velocity = '0 0 0';
 550                 self.enemy = world;
 551                 self.nextthink = time + 0.1;
 552
 553                 if(self.revive_progress >= 1)
 554                         Unfreeze(self); // wait for next think before attacking
 555
 556                 // don't bother updating angles here?
 557                 if(self.origin != self.oldorigin)
 558                 {
 559                         self.oldorigin = self.origin;
 560                         self.SendFlags |= MSF_MOVE;
 561                 }
 562
 563                 return; // no moving while frozen
 564         }
 565
 566         if(self.flags & FL_SWIM)
 567         {
 568                 if(self.waterlevel < WATERLEVEL_WETFEET)
 569                 {
 570                         if(time >= self.last_trace)
 571                         {
 572                                 self.fish_wasdrowning = TRUE;
 573                                 self.last_trace = time + 0.4;
 574
 575                                 Damage (self, world, world, 2, DEATH_DROWN, self.origin, '0 0 0');
 576                                 self.angles = '90 90 0';
 577                                 if(random() < 0.5)
 578                                 {
 579                                         self.velocity_y += random() * 50;
 580                                         self.velocity_x -= random() * 50;
 581                                 }
 582                                 else
 583                                 {
 584                                         self.velocity_y -= random() * 50;
 585                                         self.velocity_x += random() * 50;
 586                                 }
 587                                 self.velocity_z += random() * 150;
 588                         }
 589
 590
 591                         self.movetype = MOVETYPE_BOUNCE;
 592                         //self.velocity_z = -200;
 593
 594                         self.SendFlags |= MSF_MOVE | MSF_ANG;
 595
 596                         return;
 597                 }
 598                 else if(self.fish_wasdrowning)
 599                 {
 600                         self.fish_wasdrowning = FALSE;
 601                         self.angles_x = 0;
 602                         self.movetype = MOVETYPE_WALK;
 603                 }
 604         }
 605
 606         targ = self.goalentity;
 607
 608         monster_target = targ;
 609         monster_speed_run = runspeed;
 610         monster_speed_walk = walkspeed;
 611
 612         if(MUTATOR_CALLHOOK(MonsterMove) || gameover || (round_handler_IsActive() && !round_handler_IsRoundStarted()) || time < game_starttime || (autocvar_g_campaign && !campaign_bots_may_start) || time < self.spawn_time)
 613         {
 614                 runspeed = walkspeed = 0;
 615                 if(time >= self.spawn_time)
 616                         monsters_setframe(manim_idle);
 617                 movelib_beak_simple(stopspeed);
 618                 if(self.oldorigin != self.origin)
 619                 {
 620                         self.oldorigin = self.origin;
 621                         self.SendFlags |= MSF_MOVE;
 622                 }
 623                 return;
 624         }
 625
 626         targ = monster_target;
 627         runspeed = monster_speed_run;
 628         walkspeed = monster_speed_walk;
 629
 630         if(teamplay)
 631         if(autocvar_g_monsters_teams)
 632         if(IsDifferentTeam(self.monster_owner, self))
 633                 self.monster_owner = world;
 634
 635         if(self.enemy && self.enemy.health < 1)
 636                 self.enemy = world; // enough!
 637
 638         if(time >= self.last_enemycheck)
 639         {
 640                 if not(monster_isvalidtarget(self.enemy, self))
 641                         self.enemy = world;
 642
 643                 if not(self.enemy)
 644                 {
 645                         self.enemy = FindTarget(self);
 646                         if(self.enemy)
 647                                 MonsterSound(monstersound_sight, 0, FALSE, CH_VOICE);
 648                                 //monster_sound(self.msound_sight, 0, FALSE);
 649                 }
 650
 651                 self.last_enemycheck = time + 0.5;
 652         }
 653
 654         if(self.state == MONSTER_STATE_ATTACK_MELEE && time >= self.attack_finished_single)
 655                 self.state = 0;
 656
 657         if(self.state != MONSTER_STATE_ATTACK_MELEE) // don't move if set
 658         if(time >= self.last_trace || self.enemy) // update enemy instantly
 659                 self.moveto = monster_pickmovetarget(targ);
 660
 661         if not(self.enemy)
 662                 MonsterSound(monstersound_idle, 5, TRUE, CH_VOICE);
 663                 //monster_sound(self.msound_idle, 5, TRUE);
 664
 665         if(self.state != MONSTER_STATE_ATTACK_LEAP && self.state != MONSTER_STATE_ATTACK_MELEE)
 666                 self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 667
 668         if(self.state == MONSTER_STATE_ATTACK_LEAP && (self.flags & FL_ONGROUND))
 669         {
 670                 self.state = 0;
 671                 self.touch = MonsterTouch;
 672         }
 673
 674         //self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 675
 676         float turny = 0;
 677         vector real_angle = vectoangles(self.steerto) - self.angles;
 678
 679         if(self.state != MONSTER_STATE_ATTACK_LEAP && self.state != MONSTER_STATE_ATTACK_MELEE)
 680                 turny = 20;
 681
 682         if(self.flags & FL_SWIM)
 683                 turny = vlen(self.angles - self.moveto);
 684
 685         if(turny)
 686         {
 687                 turny = bound(turny * -1, shortangle_f(real_angle_y, self.angles_y), turny);
 688                 self.angles_y += turny;
 689         }
 690
 691         if(self.state == MONSTER_STATE_ATTACK_MELEE)
 692                 self.moveto = self.origin;
 693
 694         if(self.enemy && self.enemy.vehicle)
 695                 runspeed = 0;
 696
 697         if(((self.flags & FL_FLY) || (self.flags & FL_SWIM)) && self.spawnflags & MONSTERFLAG_FLY_VERTICAL)
 698                 v_forward = normalize(self.moveto - self.origin);
 699         else
 700                 self.moveto_z = self.origin_z;
 701
 702         if(vlen(self.origin - self.moveto) > 64)
 703         {
 704                 if(self.flags & FL_FLY || self.flags & FL_SWIM)
 705                         movelib_move_simple(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 706                 else
 707                         movelib_move_simple_gravity(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 708
 709                 if(time > self.pain_finished)
 710                 if(time > self.attack_finished_single)
 711                 if(vlen(self.velocity) > 10)
 712                         monsters_setframe((self.enemy) ? manim_run : manim_walk);
 713                 else
 714                         monsters_setframe(manim_idle);
 715         }
 716         else
 717         {
 718                 entity e = find(world, targetname, self.target2);
 719                 if(e.target2)
 720                         self.target2 = e.target2;
 721                 else if(e.target)
 722                         self.target2 = e.target;
 723
 724                 movelib_beak_simple(stopspeed);
 725                 if(time > self.attack_finished_single)
 726                 if(time > self.pain_finished)
 727                 if (vlen(self.velocity) <= 30)
 728                         monsters_setframe(manim_idle);
 729         }
 730
 731         monster_checkattack(self, self.enemy);
 732
 733         if(self.angles != self.oldangles)
 734         {
 735                 self.oldangles = self.angles;
 736                 self.SendFlags |= MSF_ANG;
 737         }
 738
 739         if(self.origin != self.oldorigin)
 740         {
 741                 self.oldorigin = self.origin;
 742                 self.SendFlags |= MSF_MOVE;
 743         }
 744 }
 745
 746 void monster_dead_think()
 747 {
 748         self.think = monster_dead_think;
 749         self.nextthink = time + self.ticrate;
 750
 751         self.deadflag = DEAD_DEAD;
 752
 753         if(self.ltime != 0)
 754         if(time >= self.ltime)
 755         {
 756                 Monster_Fade();
 757                 return;
 758         }
 759
 760         if(self.oldorigin != self.origin)
 761         {
 762                 self.oldorigin = self.origin;
 763                 self.SendFlags |= MSF_MOVE;
 764         }
 765 }
 766
 767 void monsters_setstatus()
 768 {
 769         self.stat_monsters_total = monsters_total;
 770         self.stat_monsters_killed = monsters_killed;
 771 }
 772
 773 void Monster_Appear()
 774 {
 775         self.enemy = activator;
 776         self.spawnflags &= ~MONSTERFLAG_APPEAR;
 777         self.monster_spawnfunc();
 778 }
 779
 780 float Monster_CheckAppearFlags(entity ent)
 781 {
 782         if not(ent.spawnflags & MONSTERFLAG_APPEAR)
 783                 return FALSE;
 784
 785         ent.think = func_null;
 786         ent.nextthink = 0;
 787         ent.use = Monster_Appear;
 788         ent.flags = FL_MONSTER; // set so this monster can get butchered
 789
 790         return TRUE;
 791 }
 792
 793 void monsters_reset()
 794 {
 795         setorigin(self, self.pos1);
 796         self.angles = self.pos2;
 797
 798         self.health = self.max_health;
 799         self.velocity = '0 0 0';
 800         self.enemy = world;
 801         self.goalentity = world;
 802         self.attack_finished_single = 0;
 803         self.moveto = self.origin;
 804
 805         self.SendFlags |= MSF_STATUS;
 806 }
 807
 808 float monster_send(entity to, float sf)
 809 {
 810         WriteByte(MSG_ENTITY, ENT_CLIENT_MONSTER);
 811         WriteByte(MSG_ENTITY, sf);
 812         if(sf & MSF_SETUP)
 813         {
 814                 WriteByte(MSG_ENTITY, self.monsterid);
 815
 816                 WriteCoord(MSG_ENTITY, self.origin_x);
 817                 WriteCoord(MSG_ENTITY, self.origin_y);
 818                 WriteCoord(MSG_ENTITY, self.origin_z);
 819
 820                 WriteAngle(MSG_ENTITY, self.angles_x);
 821                 WriteAngle(MSG_ENTITY, self.angles_y);
 822
 823                 WriteByte(MSG_ENTITY, self.skin);
 824                 WriteByte(MSG_ENTITY, self.team);
 825         }
 826
 827         if(sf & MSF_ANG)
 828         {
 829                 WriteShort(MSG_ENTITY, rint(self.angles_x));
 830                 WriteShort(MSG_ENTITY, rint(self.angles_y));
 831         }
 832
 833         if(sf & MSF_MOVE)
 834         {
 835                 WriteShort(MSG_ENTITY, rint(self.origin_x));
 836                 WriteShort(MSG_ENTITY, rint(self.origin_y));
 837                 WriteShort(MSG_ENTITY, rint(self.origin_z));
 838
 839                 WriteShort(MSG_ENTITY, rint(self.velocity_x));
 840                 WriteShort(MSG_ENTITY, rint(self.velocity_y));
 841                 WriteShort(MSG_ENTITY, rint(self.velocity_z));
 842
 843                 WriteShort(MSG_ENTITY, rint(self.angles_y));
 844         }
 845
 846         if(sf & MSF_ANIM)
 847         {
 848                 WriteCoord(MSG_ENTITY, self.anim_start_time);
 849                 WriteByte(MSG_ENTITY, self.frame);
 850         }
 851
 852         if(sf & MSF_STATUS)
 853         {
 854                 WriteByte(MSG_ENTITY, self.skin);
 855
 856                 WriteByte(MSG_ENTITY, self.team);
 857
 858                 WriteByte(MSG_ENTITY, self.deadflag);
 859
 860                 if(self.health <= 0)
 861                         WriteByte(MSG_ENTITY, 0);
 862                 else
 863                         WriteByte(MSG_ENTITY, ceil((self.health / self.max_health) * 255));
 864         }
 865
 866         return TRUE;
 867 }
 868
 869 void monster_link(void() spawnproc)
 870 {
 871         Net_LinkEntity(self, TRUE, 0, monster_send);
 872         self.think        = spawnproc;
 873         self.nextthink  = time;
 874 }
 875
 876 void monsters_corpse_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 877 {
 878         self.health -= damage;
 879
 880         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 881
 882         if(self.health <= -100) // 100 health until gone?
 883         {
 884                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 885
 886                 self.think = SUB_Remove;
 887                 self.nextthink = time + 0.1;
 888         }
 889 }
 890
 891 void monster_die()
 892 {
 893         self.think = monster_dead_think;
 894         self.nextthink = self.ticrate;
 895         self.ltime = time + 5;
 896
 897         monster_dropitem();
 898
 899         MonsterSound(monstersound_death, 0, FALSE, CH_VOICE);
 900         //monster_sound(self.msound_death, 0, FALSE);
 901
 902         if(!(self.spawnflags & MONSTERFLAG_SPAWNED) && !self.monster_respawned)
 903                 monsters_killed += 1;
 904
 905         if(self.candrop && self.weapon)
 906                 W_ThrowNewWeapon(self, self.weapon, 0, self.origin, randomvec() * 150 + '0 0 325');
 907
 908         if(IS_CLIENT(self.realowner))
 909                 self.realowner.monstercount -= 1;
 910
 911         self.event_damage       = monsters_corpse_damage;
 912         self.solid                      = SOLID_CORPSE;
 913         self.takedamage         = DAMAGE_AIM;
 914         self.enemy                      = world;
 915         self.movetype           = MOVETYPE_TOSS;
 916         self.moveto                     = self.origin;
 917         self.touch                      = MonsterTouch; // reset incase monster was pouncing
 918         self.reset                      = func_null;
 919
 920         if not(self.flags & FL_FLY)
 921                 self.velocity = '0 0 0';
 922
 923         self.SendFlags |= MSF_MOVE;
 924
 925         // number of monsters spawned with mobspawn command
 926         totalspawned -= 1;
 927
 928         MON_ACTION(self.monsterid, MR_DEATH);
 929 }
 930
 931 void monsters_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 932 {
 933         if(self.frozen && deathtype != DEATH_KILL)
 934                 return;
 935
 936         if(time < self.pain_finished && deathtype != DEATH_KILL)
 937                 return;
 938
 939         if(time < self.spawnshieldtime)
 940                 return;
 941
 942         vector v;
 943         float take, save;
 944
 945         v = healtharmor_applydamage(self.armorvalue, self.m_armor_blockpercent, damage);
 946         take = v_x;
 947         save = v_y;
 948
 949         self.health -= take;
 950
 951         self.dmg_time = time;
 952
 953         if(sound_allowed(MSG_BROADCAST, attacker) && deathtype != DEATH_DROWN)
 954                 spamsound (self, CH_PAIN, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
 955
 956         self.velocity += force * self.damageforcescale;
 957
 958         if(deathtype != DEATH_DROWN)
 959         {
 960                 Violence_GibSplash_At(hitloc, force, 2, bound(0, take, 200) / 16, self, attacker);
 961                 if (take > 50)
 962                         Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 963                 if (take > 100)
 964                         Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 965         }
 966
 967         if(self.health <= 0)
 968         {
 969                 if(deathtype == DEATH_KILL)
 970                         self.candrop = FALSE; // killed by mobkill command
 971
 972                 // TODO: fix this?
 973                 activator = attacker;
 974                 other = self.enemy;
 975                 SUB_UseTargets();
 976                 self.target2 = self.oldtarget2; // reset to original target on death, incase we respawn
 977
 978                 monster_die();
 979
 980                 frag_attacker = attacker;
 981                 frag_target = self;
 982                 MUTATOR_CALLHOOK(MonsterDies);
 983
 984                 if(self.health <= -100) // check if we're already gibbed
 985                 {
 986                         Violence_GibSplash(self, 1, 0.5, attacker);
 987
 988                         self.think = SUB_Remove;
 989                         self.nextthink = time + 0.1;
 990                 }
 991         }
 992
 993         self.SendFlags |= MSF_STATUS;
 994 }
 995
 996 void monster_think()
 997 {
 998         self.think = monster_think;
 999         self.nextthink = self.ticrate;
1000
1001         MON_ACTION(self.monsterid, MR_THINK);
1002 }
1003
1004 void monster_spawn()
1005 {
1006         MON_ACTION(self.monsterid, MR_SETUP);
1007
1008         if not(self.monster_respawned)
1009                 Monster_CheckMinibossFlag();
1010
1011         self.max_health = self.health;
1012         self.pain_finished = self.nextthink;
1013         self.anim_start_time = time;
1014
1015         if not(self.noalign)
1016         {
1017                 setorigin(self, self.origin + '0 0 20');
1018                 tracebox(self.origin + '0 0 100', self.mins, self.maxs, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
1019                 setorigin(self, trace_endpos);
1020         }
1021
1022         if not(self.monster_respawned)
1023         if not(self.skin)
1024                 self.skin = rint(random() * 4);
1025
1026         if not(self.attack_range)
1027                 self.attack_range = autocvar_g_monsters_attack_range;
1028
1029         self.pos1 = self.origin;
1030
1031         //monster_setupsounds(self.netname);
1032         precache_monstersounds();
1033         UpdateMonsterSounds();
1034         //monster_precachesounds(self);
1035
1036         if(teamplay)
1037                 self.monster_attack = TRUE; // we can have monster enemies in team games
1038
1039         //monster_sound(self.msound_spawn, 0, FALSE);
1040         MonsterSound(monstersound_spawn, 0, FALSE, CH_VOICE);
1041
1042         self.think = monster_think;
1043         self.nextthink = time + self.ticrate;
1044
1045         self.SendFlags |= MSF_SETUP;
1046
1047         MUTATOR_CALLHOOK(MonsterSpawn);
1048 }
1049
1050 float monster_initialize(float mon_id, float nodrop)
1051 {
1052         if not(autocvar_g_monsters)
1053                 return FALSE;
1054
1055         entity mon = get_monsterinfo(mon_id);
1056
1057         // support for quake style removing monsters based on skill
1058         switch(monster_skill)
1059         {
1060                 case 0:
1061                 case 1: if(self.spawnflags & MONSTERSKILL_NOTEASY)              return FALSE; break;
1062                 case 2: if(self.spawnflags & MONSTERSKILL_NOTMEDIUM)    return FALSE; break;
1063                 default:
1064                 case 3: if(self.spawnflags & MONSTERSKILL_NOTHARD)              return FALSE; break;
1065         }
1066
1067         if(self.team && !teamplay)
1068                 self.team = 0;
1069
1070         if not(self.spawnflags & MONSTERFLAG_SPAWNED) // naturally spawned monster
1071         if not(self.monster_respawned)
1072                 monsters_total += 1;
1073
1074         setsize(self, mon.mins, mon.maxs);
1075         self.flags                              = FL_MONSTER;
1076         self.takedamage                 = DAMAGE_AIM;
1077         self.bot_attack                 = TRUE;
1078         self.iscreature                 = TRUE;
1079         self.teleportable               = TRUE;
1080         self.damagedbycontents  = TRUE;
1081         self.monsterid                  = mon_id;
1082         self.damageforcescale   = 0;
1083         self.event_damage               = monsters_damage;
1084         self.touch                              = MonsterTouch;
1085         self.use                                = monster_use;
1086         self.solid                              = SOLID_BBOX;
1087         self.movetype                   = MOVETYPE_WALK;
1088         self.spawnshieldtime    = time + autocvar_g_monsters_spawnshieldtime;
1089         self.enemy                              = world;
1090         self.velocity                   = '0 0 0';
1091         self.moveto                             = self.origin;
1092         self.pos2                               = self.angles;
1093         self.reset                              = monsters_reset;
1094         self.netname                    = mon.netname;
1095         self.monster_name               = M_NAME(mon_id);
1096         self.candrop                    = TRUE;
1097         self.view_ofs                   = '0 0 1' * (self.maxs_z * 0.5);
1098         self.oldtarget2                 = self.target2;
1099         self.deadflag                   = DEAD_NO;
1100         self.scale                              = 1;
1101         self.noalign                    = nodrop;
1102         self.spawn_time                 = time;
1103         self.gravity                    = 1;
1104         self.dphitcontentsmask  = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
1105
1106         if(mon.spawnflags & MONSTER_TYPE_SWIM)
1107                 self.flags |= FL_SWIM;
1108
1109         if(mon.spawnflags & MONSTER_TYPE_FLY)
1110         {
1111                 self.flags |= FL_FLY;
1112                 self.movetype = MOVETYPE_FLY;
1113         }
1114
1115         if(mon.spawnflags & MONSTER_SIZE_BROKEN)
1116                 self.scale = 1.3;
1117
1118         if not(self.ticrate)
1119                 self.ticrate = autocvar_g_monsters_think_delay;
1120
1121         self.ticrate = bound(sys_frametime, self.ticrate, 60);
1122
1123         if not(self.m_armor_blockpercent)
1124                 self.m_armor_blockpercent = 0.5;
1125
1126         if not(self.target_range)
1127                 self.target_range = autocvar_g_monsters_target_range;
1128
1129         if not(self.respawntime)
1130                 self.respawntime = autocvar_g_monsters_respawn_delay;
1131
1132         if not(self.monster_moveflags)
1133                 self.monster_moveflags = MONSTER_MOVE_WANDER;
1134
1135         monster_link(monster_spawn);
1136
1137         return TRUE;
1138 }