qcsrc/common/monsters/sv_monsters.qc

   1 // =========================
   2 //  SVQC Monster Properties
   3 // =========================
   4
   5
   6 void M_Item_Touch ()
   7 {
   8         if(self && IS_PLAYER(other) && other.deadflag == DEAD_NO)
   9         {
  10                 Item_Touch();
  11                 self.think = SUB_Remove;
  12                 self.nextthink = time + 0.1;
  13         }
  14 }
  15
  16 void monster_item_spawn()
  17 {
  18         if(self.monster_loot)
  19                 self.monster_loot();
  20
  21         self.gravity = 1;
  22         self.velocity = randomvec() * 175 + '0 0 325';
  23         self.touch = M_Item_Touch;
  24
  25         SUB_SetFade(self, time + autocvar_g_monsters_drop_time, 1);
  26 }
  27
  28 void monster_dropitem()
  29 {
  30         if(!self.candrop || !self.monster_loot)
  31                 return;
  32
  33         vector org = self.origin + ((self.mins + self.maxs) * 0.5);
  34         entity e = spawn();
  35
  36         setorigin(e, org);
  37
  38         e.monster_loot = self.monster_loot;
  39
  40         other = e;
  41         MUTATOR_CALLHOOK(MonsterDropItem);
  42         e = other;
  43
  44         e.think = monster_item_spawn;
  45         e.nextthink = time + 0.3;
  46 }
  47
  48 void monsters_setframe(float _frame)
  49 {
  50         if(self.frame == _frame)
  51                 return;
  52
  53         self.anim_start_time = time;
  54         self.frame = _frame;
  55         self.SendFlags |= MSF_ANIM;
  56 }
  57
  58 float monster_isvalidtarget (entity targ, entity ent)
  59 {
  60         if(!targ || !ent)
  61                 return FALSE; // someone doesn't exist
  62
  63         if(targ == ent)
  64                 return FALSE; // don't attack ourselves
  65
  66         if(time < game_starttime)
  67                 return FALSE; // monsters do nothing before the match has started
  68
  69         WarpZone_TraceLine(ent.origin, targ.origin, MOVE_NORMAL, ent);
  70
  71         if(vlen(targ.origin - ent.origin) >= ent.target_range)
  72                 return FALSE; // enemy is too far away
  73
  74         if(trace_ent != targ)
  75                 return FALSE; // we can't see the enemy
  76
  77         if(targ.takedamage == DAMAGE_NO)
  78                 return FALSE; // enemy can't be damaged
  79
  80         if(targ.items & IT_INVISIBILITY)
  81                 return FALSE; // enemy is invisible
  82
  83         if(substring(targ.classname, 0, 10) == "onslaught_")
  84                 return FALSE; // don't attack onslaught targets
  85
  86         if(IS_SPEC(targ) || IS_OBSERVER(targ))
  87                 return FALSE; // enemy is a spectator
  88
  89         if(targ.deadflag != DEAD_NO || ent.deadflag != DEAD_NO || targ.health <= 0 || ent.health <= 0)
  90                 return FALSE; // enemy/self is dead
  91
  92         if(ent.monster_owner == targ)
  93                 return FALSE; // don't attack our master
  94
  95         if(targ.monster_owner == ent)
  96                 return FALSE; // don't attack our pet
  97
  98         if(targ.flags & FL_NOTARGET)
  99                 return FALSE; // enemy can't be targeted
 100
 101         if not(autocvar_g_monsters_typefrag)
 102         if(targ.BUTTON_CHAT)
 103                 return FALSE; // no typefragging!
 104
 105         if not(IsDifferentTeam(targ, ent))
 106                 return FALSE; // enemy is on our team
 107
 108         if(autocvar_g_monsters_target_infront)
 109         if(ent.enemy != targ)
 110         {
 111                 float dot;
 112
 113                 makevectors (ent.angles);
 114                 dot = normalize (targ.origin - ent.origin) * v_forward;
 115
 116                 if(dot <= 0.3)
 117                         return FALSE;
 118         }
 119
 120         return TRUE;
 121 }
 122
 123 entity FindTarget (entity ent)
 124 {
 125         if(MUTATOR_CALLHOOK(MonsterFindTarget)) { return ent.enemy; } // Handled by a mutator
 126
 127         entity head, closest_target = world;
 128         head = findradius(ent.origin, ent.target_range);
 129
 130         while(head) // find the closest acceptable target to pass to
 131         {
 132                 if(monster_isvalidtarget(head, ent))
 133                 {
 134                         // if it's a player, use the view origin as reference (stolen from RadiusDamage functions in g_damage.qc)
 135                         vector head_center = CENTER_OR_VIEWOFS(head);
 136                         vector ent_center = CENTER_OR_VIEWOFS(ent);
 137
 138                         //if(ctf_CheckPassDirection(head_center, ent_center, ent.v_angle, head.WarpZone_findradius_nearest))
 139                         if(closest_target)
 140                         {
 141                                 vector closest_target_center = CENTER_OR_VIEWOFS(closest_target);
 142                                 if(vlen(ent_center - head_center) < vlen(ent_center - closest_target_center))
 143                                         { closest_target = head; }
 144                         }
 145                         else { closest_target = head; }
 146                 }
 147
 148                 head = head.chain;
 149         }
 150
 151         return closest_target;
 152 }
 153
 154 void MonsterTouch ()
 155 {
 156         if(other == world)
 157                 return;
 158
 159         if(self.enemy != other)
 160         if not(other.flags & FL_MONSTER)
 161         if(monster_isvalidtarget(other, self))
 162                 self.enemy = other;
 163 }
 164
 165 void monster_sound(string msound, float sound_delay, float delaytoo)
 166 {
 167         if(delaytoo && time < self.msound_delay)
 168                 return; // too early
 169
 170         if(msound == "")
 171                 return; // sound doesn't exist
 172
 173         sound(self, CHAN_AUTO, msound, VOL_BASE, ATTEN_NORM);
 174
 175         self.msound_delay = time + sound_delay;
 176 }
 177
 178 void monster_precachesounds(entity e)
 179 {
 180         precache_sound(e.msound_idle);
 181         precache_sound(e.msound_death);
 182         precache_sound(e.msound_attack_melee);
 183         precache_sound(e.msound_attack_ranged);
 184         precache_sound(e.msound_sight);
 185         precache_sound(e.msound_pain);
 186 }
 187
 188 void monster_setupsounds(string mon)
 189 {
 190         if(self.msound_idle == "") self.msound_idle = strzone(strcat("monsters/", mon, "_idle.wav"));
 191         if(self.msound_death == "") self.msound_death = strzone(strcat("monsters/", mon, "_death.wav"));
 192         if(self.msound_pain == "") self.msound_pain = strzone(strcat("monsters/", mon, "_pain.wav"));
 193         if(self.msound_attack_melee == "") self.msound_attack_melee = strzone(strcat("monsters/", mon, "_melee.wav"));
 194         if(self.msound_attack_ranged == "") self.msound_attack_ranged = strzone(strcat("monsters/", mon, "_attack.wav"));
 195         if(self.msound_sight == "") self.msound_sight = strzone(strcat("monsters/", mon, "_sight.wav"));
 196 }
 197
 198 void monster_makevectors(entity e)
 199 {
 200         vector v;
 201
 202         v = CENTER_OR_VIEWOFS(e);
 203         self.v_angle = vectoangles(v - (self.origin + self.view_ofs));
 204         self.v_angle_x = -self.v_angle_x;
 205
 206         makevectors(self.v_angle);
 207 }
 208
 209 float monster_melee(entity targ, float damg, float anim, float er, float anim_finished, float deathtype, float dostop)
 210 {
 211         float rdmg = damg * random();
 212
 213         if (self.health <= 0)
 214                 return FALSE;
 215         if (targ == world)
 216                 return FALSE;
 217
 218         if(dostop)
 219         {
 220                 self.velocity_x = 0;
 221                 self.velocity_y = 0;
 222                 self.state = MONSTER_STATE_ATTACK_MELEE;
 223                 self.SendFlags |= MSF_MOVE;
 224         }
 225
 226         monsters_setframe(anim);
 227
 228         if(anim_finished != 0)
 229                 self.attack_finished_single = time + anim_finished;
 230
 231         monster_makevectors(targ);
 232
 233         traceline(self.origin + self.view_ofs, self.origin + v_forward * er, 0, self);
 234
 235         if(trace_ent.takedamage)
 236                 Damage(targ, self, self, rdmg * monster_skill, deathtype, targ.origin, normalize(targ.origin - self.origin));
 237
 238         return TRUE;
 239 }
 240
 241 void Monster_CheckMinibossFlag ()
 242 {
 243         if(MUTATOR_CALLHOOK(MonsterCheckBossFlag))
 244                 return;
 245
 246         float chance = random() * 100;
 247
 248         // g_monsters_miniboss_chance cvar or spawnflags 64 causes a monster to be a miniboss
 249         if ((self.spawnflags & MONSTERFLAG_MINIBOSS) || (chance < autocvar_g_monsters_miniboss_chance))
 250         {
 251                 self.health += autocvar_g_monsters_miniboss_healthboost;
 252                 if not(self.weapon)
 253                         self.weapon = WEP_NEX;
 254         }
 255 }
 256
 257 float Monster_CanRespawn(entity ent)
 258 {
 259         other = ent;
 260         if(MUTATOR_CALLHOOK(MonsterRespawn))
 261                 return TRUE; // enabled by a mutator
 262
 263         if(ent.spawnflags & MONSTERFLAG_NORESPAWN)
 264                 return FALSE;
 265
 266         if not(autocvar_g_monsters_respawn)
 267                 return FALSE;
 268
 269         return TRUE;
 270 }
 271
 272 void Monster_Fade ()
 273 {
 274         if(Monster_CanRespawn(self))
 275         {
 276                 self.monster_respawned = TRUE;
 277                 self.think = self.monster_spawnfunc;
 278                 self.nextthink = time + self.respawntime;
 279                 self.deadflag = DEAD_RESPAWNING;
 280                 if(self.spawnflags & MONSTER_RESPAWN_DEATHPOINT)
 281                 {
 282                         self.pos1 = self.origin;
 283                         self.pos2 = self.angles;
 284                 }
 285                 self.event_damage = func_null;
 286                 self.takedamage = DAMAGE_NO;
 287                 setorigin(self, self.pos1);
 288                 self.angles = self.pos2;
 289                 self.health = self.max_health;
 290
 291                 self.SendFlags |= MSF_MOVE;
 292                 self.SendFlags |= MSF_STATUS;
 293         }
 294         else
 295                 SUB_SetFade(self, time + 3, 1);
 296 }
 297
 298 float Monster_CanJump (vector vel)
 299 {
 300         if(self.state)
 301                 return FALSE; // already attacking
 302         if not(self.flags & FL_ONGROUND)
 303                 return FALSE; // not on the ground
 304         if(self.health <= 0)
 305                 return FALSE; // called when dead?
 306         if(time < self.attack_finished_single)
 307                 return FALSE; // still attacking
 308
 309         vector old = self.velocity;
 310
 311         self.velocity = vel;
 312         tracetoss(self, self);
 313         self.velocity = old;
 314         if (trace_ent != self.enemy)
 315                 return FALSE;
 316
 317         return TRUE;
 318 }
 319
 320 float monster_leap (float anm, void() touchfunc, vector vel, float anim_finished)
 321 {
 322         if(!Monster_CanJump(vel))
 323                 return FALSE;
 324
 325         monsters_setframe(anm);
 326         self.state = MONSTER_STATE_ATTACK_LEAP;
 327         self.touch = touchfunc;
 328         self.origin_z += 1;
 329         self.velocity = vel;
 330         self.flags &= ~FL_ONGROUND;
 331
 332         self.attack_finished_single = time + anim_finished;
 333
 334         return TRUE;
 335 }
 336
 337 void monster_checkattack(entity e, entity targ)
 338 {
 339         if(e == world)
 340                 return;
 341         if(targ == world)
 342                 return;
 343
 344         if not(e.monster_attackfunc)
 345                 return;
 346
 347         if(time < e.attack_finished_single)
 348                 return;
 349
 350         if(vlen(targ.origin - e.origin) <= e.attack_range)
 351         if(e.monster_attackfunc(MONSTER_ATTACK_MELEE))
 352         {
 353                 monster_sound(e.msound_attack_melee, 0, FALSE);
 354                 return;
 355         }
 356
 357         if(vlen(targ.origin - e.origin) > e.attack_range)
 358         if(e.monster_attackfunc(MONSTER_ATTACK_RANGED))
 359         {
 360                 monster_sound(e.msound_attack_ranged, 0, FALSE);
 361                 return;
 362         }
 363 }
 364
 365 void monster_use ()
 366 {
 367         if (self.enemy)
 368                 return;
 369         if (self.health <= 0)
 370                 return;
 371
 372         if(!monster_isvalidtarget(activator, self))
 373                 return;
 374
 375         self.enemy = activator;
 376 }
 377
 378 .float last_trace;
 379 .float last_enemycheck; // for checking enemy
 380 vector monster_pickmovetarget(entity targ)
 381 {
 382         // enemy is always preferred target
 383         if(self.enemy)
 384         {
 385                 self.monster_movestate = MONSTER_MOVE_ENEMY;
 386                 self.last_trace = time + 1.2;
 387                 return self.enemy.origin;
 388         }
 389
 390         switch(self.monster_moveflags)
 391         {
 392                 case MONSTER_MOVE_OWNER:
 393                 {
 394                         self.monster_movestate = MONSTER_MOVE_OWNER;
 395                         self.last_trace = time + 0.3;
 396                         if(self.monster_owner && self.monster_owner.classname != "td_spawnpoint")
 397                                 return self.monster_owner.origin;
 398                 }
 399                 case MONSTER_MOVE_SPAWNLOC:
 400                 {
 401                         self.monster_movestate = MONSTER_MOVE_SPAWNLOC;
 402                         self.last_trace = time + 2;
 403                         return self.pos1;
 404                 }
 405                 case MONSTER_MOVE_NOMOVE:
 406                 {
 407                         self.monster_movestate = MONSTER_MOVE_NOMOVE;
 408                         self.last_trace = time + 2;
 409                         return self.origin;
 410                 }
 411                 default:
 412                 case MONSTER_MOVE_WANDER:
 413                 {
 414                         vector pos;
 415                         self.monster_movestate = MONSTER_MOVE_WANDER;
 416                         self.last_trace = time + 2;
 417
 418                         self.angles_y = random() * 500;
 419                         makevectors(self.angles);
 420                         pos = self.origin + v_forward * 600;
 421
 422                         if(self.flags & FL_FLY || self.flags & FL_SWIM)
 423                         {
 424                                 pos_z = random() * 200;
 425                                 if(random() >= 0.5)
 426                                         pos_z *= -1;
 427                         }
 428
 429                         if(targ)
 430                         {
 431                                 self.last_trace = time + 0.5;
 432                                 pos = targ.origin;
 433                         }
 434
 435                         return pos;
 436                 }
 437         }
 438 }
 439
 440 void monster_move(float runspeed, float walkspeed, float stopspeed, float manim_run, float manim_walk, float manim_idle)
 441 {
 442         fixedmakevectors(self.angles);
 443
 444         if(self.target2)
 445                 self.goalentity = find(world, targetname, self.target2);
 446
 447         entity targ;
 448
 449         if(self.frozen)
 450         {
 451                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
 452                 self.health = max(1, self.max_health * self.revive_progress);
 453
 454                 if(self.sprite) WaypointSprite_UpdateHealth(self.sprite, self.health);
 455
 456                 movelib_beak_simple(stopspeed);
 457
 458                 self.velocity = '0 0 0';
 459                 self.enemy = world;
 460                 self.nextthink = time + 0.1;
 461
 462                 if(self.revive_progress >= 1)
 463                         Unfreeze(self); // wait for next think before attacking
 464
 465                 // don't bother updating angles here?
 466                 if(self.origin != self.oldorigin)
 467                 {
 468                         self.oldorigin = self.origin;
 469                         self.SendFlags |= MSF_MOVE;
 470                 }
 471
 472                 return; // no moving while frozen
 473         }
 474
 475         if(self.flags & FL_SWIM)
 476         {
 477                 if(self.waterlevel < WATERLEVEL_WETFEET)
 478                 {
 479                         if(time >= self.last_trace)
 480                         {
 481                                 self.last_trace = time + 0.4;
 482
 483                                 Damage (self, world, world, 2, DEATH_DROWN, self.origin, '0 0 0');
 484                                 self.angles = '90 90 0';
 485                                 if(random() < 0.5)
 486                                 {
 487                                         self.velocity_y += random() * 50;
 488                                         self.velocity_x -= random() * 50;
 489                                 }
 490                                 else
 491                                 {
 492                                         self.velocity_y -= random() * 50;
 493                                         self.velocity_x += random() * 50;
 494                                 }
 495                                 self.velocity_z += random() * 150;
 496                         }
 497
 498
 499                         self.movetype = MOVETYPE_BOUNCE;
 500                         //self.velocity_z = -200;
 501
 502                         self.SendFlags |= MSF_MOVE | MSF_ANG;
 503
 504                         return;
 505                 }
 506                 else
 507                 {
 508                         self.angles = '0 0 0';
 509                         self.movetype = MOVETYPE_WALK;
 510                 }
 511         }
 512
 513         targ = self.goalentity;
 514
 515         monster_target = targ;
 516         monster_speed_run = runspeed;
 517         monster_speed_walk = walkspeed;
 518
 519         if(MUTATOR_CALLHOOK(MonsterMove) || gameover || (round_handler_IsActive() && !round_handler_IsRoundStarted()) || time < game_starttime || (autocvar_g_campaign && !campaign_bots_may_start) || time < self.spawn_time)
 520         {
 521                 runspeed = walkspeed = 0;
 522                 if(time >= self.spawn_time)
 523                         monsters_setframe(manim_idle);
 524                 movelib_beak_simple(stopspeed);
 525                 self.SendFlags |= MSF_MOVE;
 526                 return;
 527         }
 528
 529         targ = monster_target;
 530         runspeed = monster_speed_run;
 531         walkspeed = monster_speed_walk;
 532
 533         if(teamplay)
 534         if(autocvar_g_monsters_teams)
 535         if(IsDifferentTeam(self.monster_owner, self))
 536                 self.monster_owner = world;
 537
 538         if(self.enemy && self.enemy.health < 1)
 539                 self.enemy = world; // enough!
 540
 541         if(time >= self.last_enemycheck)
 542         {
 543                 if not(monster_isvalidtarget(self.enemy, self))
 544                         self.enemy = world;
 545
 546                 if not(self.enemy)
 547                 {
 548                         self.enemy = FindTarget(self);
 549                         if(self.enemy)
 550                                 monster_sound(self.msound_sight, 0, FALSE);
 551                 }
 552
 553                 self.last_enemycheck = time + 2;
 554         }
 555
 556         if(self.state == MONSTER_STATE_ATTACK_MELEE && time >= self.attack_finished_single)
 557                 self.state = 0;
 558
 559         if(self.state != MONSTER_STATE_ATTACK_MELEE) // don't move if set
 560         if(time >= self.last_trace || self.enemy) // update enemy instantly
 561                 self.moveto = monster_pickmovetarget(targ);
 562
 563         if not(self.enemy)
 564                 monster_sound(self.msound_idle, 5, TRUE);
 565
 566         if(self.state != MONSTER_STATE_ATTACK_LEAP && self.state != MONSTER_STATE_ATTACK_MELEE)
 567                 self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 568
 569         if(self.state == MONSTER_STATE_ATTACK_LEAP && (self.flags & FL_ONGROUND))
 570         {
 571                 self.state = 0;
 572                 self.touch = MonsterTouch;
 573         }
 574
 575         //self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 576
 577         float turny = 0;
 578         vector real_angle = vectoangles(self.steerto) - self.angles;
 579
 580         if(self.state != MONSTER_STATE_ATTACK_LEAP && self.state != MONSTER_STATE_ATTACK_MELEE)
 581                 turny = 20;
 582
 583         if(self.flags & FL_SWIM)
 584                 turny = vlen(self.angles - self.moveto);
 585
 586         if(turny)
 587         {
 588                 turny = bound(turny * -1, shortangle_f(real_angle_y, self.angles_y), turny);
 589                 self.angles_y += turny;
 590         }
 591
 592         if(self.state == MONSTER_STATE_ATTACK_MELEE)
 593                 self.moveto = self.origin;
 594         else if(self.enemy)
 595                 self.moveto = self.moveto * 0.9 + ((self.origin + v_forward * 500) + randomvec() * 400) * 0.1;
 596
 597         if not(self.flags & FL_FLY || self.flags & FL_SWIM)
 598                 self.moveto_z = self.origin_z;
 599
 600         if(self.flags & FL_FLY || self.flags & FL_SWIM)
 601                 v_forward = normalize(self.moveto - self.origin);
 602
 603         if(vlen(self.origin - self.moveto) > 64)
 604         {
 605                 if(self.flags & FL_FLY || self.flags & FL_SWIM)
 606                         movelib_move_simple(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 607                 else
 608                         movelib_move_simple_gravity(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 609                 if(time > self.pain_finished)
 610                 if(time > self.attack_finished_single)
 611                 if(vlen(self.velocity) > 0)
 612                         monsters_setframe((self.enemy) ? manim_run : manim_walk);
 613                 else
 614                         monsters_setframe(manim_idle);
 615         }
 616         else
 617         {
 618                 entity e = find(world, targetname, self.target2);
 619                 if(e.target2)
 620                         self.target2 = e.target2;
 621                 else if(e.target)
 622                         self.target2 = e.target;
 623
 624                 movelib_beak_simple(stopspeed);
 625                 if(time > self.attack_finished_single)
 626                 if(time > self.pain_finished)
 627                 if (vlen(self.velocity) <= 30)
 628                         monsters_setframe(manim_idle);
 629         }
 630
 631         monster_checkattack(self, self.enemy);
 632
 633         if(self.angles != self.oldangles)
 634         {
 635                 self.oldangles = self.angles;
 636                 self.SendFlags |= MSF_ANG;
 637         }
 638
 639         if(self.origin != self.oldorigin)
 640         {
 641                 self.oldorigin = self.origin;
 642                 self.SendFlags |= MSF_MOVE;
 643         }
 644 }
 645
 646 void monster_dead_think()
 647 {
 648         self.think = monster_dead_think;
 649         self.nextthink = time + 0.3; // don't need to update so often now
 650
 651         self.deadflag = DEAD_DEAD;
 652
 653         if(time >= self.ltime)
 654         {
 655                 Monster_Fade();
 656                 return;
 657         }
 658
 659         self.SendFlags |= MSF_MOVE; // keep up to date on the monster's location
 660 }
 661
 662 void monsters_setstatus()
 663 {
 664         self.stat_monsters_total = monsters_total;
 665         self.stat_monsters_killed = monsters_killed;
 666 }
 667
 668 void Monster_Appear()
 669 {
 670         self.enemy = activator;
 671         self.spawnflags &= ~MONSTERFLAG_APPEAR;
 672         self.monster_spawnfunc();
 673 }
 674
 675 float Monster_CheckAppearFlags(entity ent)
 676 {
 677         if not(ent.spawnflags & MONSTERFLAG_APPEAR)
 678                 return FALSE;
 679
 680         ent.think = func_null;
 681         ent.nextthink = 0;
 682         ent.use = Monster_Appear;
 683         ent.flags = FL_MONSTER; // set so this monster can get butchered
 684
 685         return TRUE;
 686 }
 687
 688 void monsters_reset()
 689 {
 690         setorigin(self, self.pos1);
 691         self.angles = self.pos2;
 692
 693         self.health = self.max_health;
 694         self.velocity = '0 0 0';
 695         self.enemy = world;
 696         self.goalentity = world;
 697         self.attack_finished_single = 0;
 698         self.moveto = self.origin;
 699
 700         WaypointSprite_UpdateHealth(self.sprite, self.health);
 701 }
 702
 703 float monster_send(entity to, float sf)
 704 {
 705         WriteByte(MSG_ENTITY, ENT_CLIENT_MONSTER);
 706         WriteByte(MSG_ENTITY, sf);
 707         if(sf & MSF_SETUP)
 708         {
 709             WriteByte(MSG_ENTITY, self.monsterid);
 710
 711             WriteCoord(MSG_ENTITY, self.origin_x);
 712             WriteCoord(MSG_ENTITY, self.origin_y);
 713             WriteCoord(MSG_ENTITY, self.origin_z);
 714
 715             WriteAngle(MSG_ENTITY, self.angles_x);
 716             WriteAngle(MSG_ENTITY, self.angles_y);
 717
 718                 WriteByte(MSG_ENTITY, self.skin);
 719                 WriteByte(MSG_ENTITY, self.team);
 720     }
 721
 722     if(sf & MSF_ANG)
 723     {
 724         WriteShort(MSG_ENTITY, rint(self.angles_x));
 725         WriteShort(MSG_ENTITY, rint(self.angles_y));
 726     }
 727
 728     if(sf & MSF_MOVE)
 729     {
 730         WriteShort(MSG_ENTITY, rint(self.origin_x));
 731         WriteShort(MSG_ENTITY, rint(self.origin_y));
 732         WriteShort(MSG_ENTITY, rint(self.origin_z));
 733
 734         WriteShort(MSG_ENTITY, rint(self.velocity_x));
 735         WriteShort(MSG_ENTITY, rint(self.velocity_y));
 736         WriteShort(MSG_ENTITY, rint(self.velocity_z));
 737
 738         WriteShort(MSG_ENTITY, rint(self.angles_y));
 739     }
 740
 741     if(sf & MSF_ANIM)
 742     {
 743         WriteCoord(MSG_ENTITY, self.anim_start_time);
 744         WriteByte(MSG_ENTITY, self.frame);
 745     }
 746
 747     if(sf & MSF_STATUS)
 748     {
 749                 WriteByte(MSG_ENTITY, self.skin);
 750
 751         WriteByte(MSG_ENTITY, self.team);
 752
 753                 WriteByte(MSG_ENTITY, self.deadflag);
 754
 755         if(self.health <= 0)
 756             WriteByte(MSG_ENTITY, 0);
 757         else
 758             WriteByte(MSG_ENTITY, ceil((self.health / self.max_health) * 255));
 759     }
 760
 761         return TRUE;
 762 }
 763
 764 void monster_link(void() spawnproc)
 765 {
 766     Net_LinkEntity(self, TRUE, 0, monster_send);
 767     self.think      = spawnproc;
 768     self.nextthink  = time;
 769 }
 770
 771 void monsters_corpse_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 772 {
 773         self.health -= damage;
 774
 775         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 776
 777         if(self.health <= -100) // 100 health until gone?
 778         {
 779                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 780
 781                 self.think = SUB_Remove;
 782                 self.nextthink = time + 0.1;
 783         }
 784 }
 785
 786 void monster_die()
 787 {
 788         self.think = monster_dead_think;
 789         self.nextthink = self.ticrate;
 790         self.ltime = time + 5;
 791
 792         monster_dropitem();
 793
 794         WaypointSprite_Kill(self.sprite);
 795
 796         if(self.weaponentity)
 797         {
 798                 remove(self.weaponentity);
 799                 self.weaponentity = world;
 800         }
 801
 802         monster_sound(self.msound_death, 0, FALSE);
 803
 804         if(!(self.spawnflags & MONSTERFLAG_SPAWNED) && !self.monster_respawned)
 805                 monsters_killed += 1;
 806
 807         if(self.candrop && self.weapon)
 808                 W_ThrowNewWeapon(self, self.weapon, 0, self.origin, randomvec() * 150 + '0 0 325');
 809
 810         if(IS_CLIENT(self.realowner))
 811                 self.realowner.monstercount -= 1;
 812
 813         self.event_damage       = monsters_corpse_damage;
 814         self.solid                      = SOLID_CORPSE;
 815         self.takedamage         = DAMAGE_AIM;
 816         self.enemy                      = world;
 817         self.movetype           = MOVETYPE_TOSS;
 818         self.moveto                     = self.origin;
 819         self.touch                      = MonsterTouch; // reset incase monster was pouncing
 820
 821         if not(self.flags & FL_FLY)
 822                 self.velocity = '0 0 0';
 823
 824         self.SendFlags |= MSF_MOVE;
 825
 826         // number of monsters spawned with mobspawn command
 827         totalspawned -= 1;
 828
 829         MON_ACTION(self.monsterid, MR_DEATH);
 830 }
 831
 832 void monsters_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 833 {
 834         if(self.frozen && deathtype != DEATH_KILL)
 835                 return;
 836
 837         if(time < self.pain_finished && deathtype != DEATH_KILL)
 838                 return;
 839
 840         if(time < self.spawnshieldtime)
 841                 return;
 842
 843         if(deathtype != DEATH_KILL)
 844                 damage *= self.armorvalue;
 845
 846         if(self.weaponentity && self.weaponentity.classname == "shield")
 847                 self.weaponentity.health -= damage;
 848
 849         self.health -= damage;
 850
 851         if(self.sprite)
 852                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 853
 854         self.dmg_time = time;
 855
 856         if(sound_allowed(MSG_BROADCAST, attacker) && deathtype != DEATH_DROWN)
 857                 spamsound (self, CH_PAIN, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
 858
 859         self.velocity += force * self.damageforcescale;
 860
 861         if(deathtype != DEATH_DROWN)
 862         {
 863                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 864                 if (damage > 50)
 865                         Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 866                 if (damage > 100)
 867                         Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 868         }
 869
 870         if(self.health <= 0)
 871         {
 872                 // Update one more time to avoid waypoint fading without emptying healthbar
 873                 if(self.sprite)
 874                         WaypointSprite_UpdateHealth(self.sprite, 0);
 875
 876                 if(deathtype == DEATH_KILL)
 877                         self.candrop = FALSE; // killed by mobkill command
 878
 879                 // TODO: fix this?
 880                 activator = attacker;
 881                 other = self.enemy;
 882                 SUB_UseTargets();
 883                 self.target2 = self.oldtarget2; // reset to original target on death, incase we respawn
 884
 885                 monster_die();
 886
 887                 frag_attacker = attacker;
 888                 frag_target = self;
 889                 MUTATOR_CALLHOOK(MonsterDies);
 890
 891                 if(self.health <= -100) // check if we're already gibbed
 892                 {
 893                         Violence_GibSplash(self, 1, 0.5, attacker);
 894
 895                         self.think = SUB_Remove;
 896                         self.nextthink = time + 0.1;
 897                 }
 898         }
 899
 900         self.SendFlags |= MSF_STATUS;
 901 }
 902
 903 void monster_think()
 904 {
 905         self.think = monster_think;
 906         self.nextthink = self.ticrate;
 907
 908         MON_ACTION(self.monsterid, MR_THINK);
 909 }
 910
 911 void monster_spawn()
 912 {
 913         MON_ACTION(self.monsterid, MR_SETUP);
 914
 915         if not(self.monster_respawned)
 916                 Monster_CheckMinibossFlag();
 917
 918         self.max_health = self.health;
 919         self.pain_finished = self.nextthink;
 920         self.anim_start_time = time;
 921
 922         if not(self.noalign)
 923         {
 924                 setorigin(self, self.origin + '0 0 20');
 925                 tracebox(self.origin + '0 0 100', self.mins, self.maxs, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
 926                 setorigin(self, trace_endpos);
 927         }
 928
 929         if not(self.monster_respawned)
 930         if not(self.skin)
 931                 self.skin = rint(random() * 4);
 932
 933         if not(self.attack_range)
 934                 self.attack_range = autocvar_g_monsters_attack_range;
 935
 936         self.pos1 = self.origin;
 937
 938         monster_setupsounds(self.netname);
 939
 940         monster_precachesounds(self);
 941
 942         if(teamplay)
 943                 self.monster_attack = TRUE; // we can have monster enemies in team games
 944
 945         if(autocvar_g_monsters_healthbars)
 946         {
 947                 WaypointSprite_Spawn(strzone(strdecolorize(self.monster_name)), 0, 600, self, '0 0 1' * (self.maxs_z + 15), world, 0, self, sprite, FALSE, RADARICON_DANGER, ((self.team) ? Team_ColorRGB(self.team) : '1 0 0'));
 948                 WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
 949                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 950         }
 951
 952         monster_sound(self.msound_spawn, 0, FALSE);
 953
 954         MUTATOR_CALLHOOK(MonsterSpawn);
 955
 956         self.think = monster_think;
 957         self.nextthink = time + self.ticrate;
 958
 959         self.SendFlags |= MSF_SETUP;
 960 }
 961
 962 float monster_initialize(float mon_id, float nodrop)
 963 {
 964         if not(autocvar_g_monsters)
 965                 return FALSE;
 966
 967         vector min_s, max_s;
 968         entity mon = get_monsterinfo(mon_id);
 969
 970         // support for quake style removing monsters based on skill
 971         switch(monster_skill)
 972         {
 973                 case 1: if(self.spawnflags & MONSTERSKILL_NOTEASY)              return FALSE; break;
 974                 case 2: if(self.spawnflags & MONSTERSKILL_NOTMEDIUM)    return FALSE; break;
 975                 case 3: if(self.spawnflags & MONSTERSKILL_NOTHARD)              return FALSE; break;
 976                 case 4: if(self.spawnflags & MONSTERSKILL_NOTINSANE)    return FALSE; break;
 977                 case 5: if(self.spawnflags & MONSTERSKILL_NOTNIGHTMARE) return FALSE; break;
 978         }
 979
 980         if(self.monster_name == "")
 981                 self.monster_name = M_NAME(mon_id);
 982
 983         if(self.team && !teamplay)
 984                 self.team = 0;
 985
 986         self.flags = FL_MONSTER;
 987
 988         if not(self.spawnflags & MONSTERFLAG_SPAWNED) // naturally spawned monster
 989         if not(self.monster_respawned)
 990                 monsters_total += 1;
 991
 992         min_s = mon.mins;
 993         max_s = mon.maxs;
 994
 995         self.netname = mon.netname;
 996
 997         setsize(self, min_s, max_s);
 998         self.takedamage                 = DAMAGE_AIM;
 999         self.bot_attack                 = TRUE;
1000         self.iscreature                 = TRUE;
1001         self.teleportable               = TRUE;
1002         self.damagedbycontents  = TRUE;
1003         self.monsterid                  = mon_id;
1004         self.damageforcescale   = 0;
1005         self.event_damage               = monsters_damage;
1006         self.touch                              = MonsterTouch;
1007         self.use                                = monster_use;
1008         self.solid                              = SOLID_BBOX;
1009         self.movetype                   = MOVETYPE_WALK;
1010         self.spawnshieldtime    = time + autocvar_g_monsters_spawnshieldtime;
1011         monsters_spawned           += 1;
1012         self.enemy                              = world;
1013         self.velocity                   = '0 0 0';
1014         self.moveto                             = self.origin;
1015         self.pos2                               = self.angles;
1016         self.reset                              = monsters_reset;
1017         self.candrop                    = TRUE;
1018         self.view_ofs                   = '0 0 1' * (self.maxs_z * 0.5);
1019         self.oldtarget2                 = self.target2;
1020         self.deadflag                   = DEAD_NO;
1021         self.noalign                    = nodrop;
1022         self.spawn_time                 = time;
1023         self.gravity                    = 1;
1024         self.dphitcontentsmask  = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
1025
1026         if(mon.spawnflags & MONSTER_TYPE_SWIM)
1027                 self.flags |= FL_SWIM;
1028
1029         if(mon.spawnflags & MONSTER_TYPE_FLY)
1030         {
1031                 self.flags |= FL_FLY;
1032                 self.movetype = MOVETYPE_FLY;
1033         }
1034
1035         if not(self.scale)
1036                 self.scale = 1;
1037
1038         if(mon.spawnflags & MONSTER_SIZE_BROKEN)
1039                 self.scale = 1.3;
1040
1041         if not(self.ticrate)
1042                 self.ticrate = autocvar_g_monsters_think_delay;
1043
1044         self.ticrate = bound(sys_frametime, self.ticrate, 60);
1045
1046         if not(self.armorvalue)
1047                 self.armorvalue = 1; // multiplier
1048
1049         if not(self.target_range)
1050                 self.target_range = autocvar_g_monsters_target_range;
1051
1052         if not(self.respawntime)
1053                 self.respawntime = autocvar_g_monsters_respawn_delay;
1054
1055         if not(self.monster_moveflags)
1056                 self.monster_moveflags = MONSTER_MOVE_WANDER;
1057
1058         monster_link(monster_spawn);
1059
1060         return TRUE;
1061 }