qcsrc/common/monsters/monster/shambler.qc

   1 #ifdef REGISTER_MONSTER
   2 REGISTER_MONSTER(
   3 /* MON_##id   */ SHAMBLER,
   4 /* function   */ m_shambler,
   5 /* mins,maxs  */ '-41 -41 -31', '41 41 65',
   6 /* model      */ "shambler.mdl",
   7 /* netname    */ "shambler",
   8 /* fullname   */ _("Shambler")
   9 );
  10
  11 #else
  12 #ifdef SVQC
  13 float autocvar_g_monster_shambler;
  14 float autocvar_g_monster_shambler_health;
  15 float autocvar_g_monster_shambler_damage;
  16 float autocvar_g_monster_shambler_attack_lightning_damage;
  17 float autocvar_g_monster_shambler_attack_claw_damage;
  18 float autocvar_g_monster_shambler_speed_walk;
  19 float autocvar_g_monster_shambler_speed_run;
  20
  21 const float shambler_anim_stand         = 0;
  22 const float shambler_anim_walk          = 1;
  23 const float shambler_anim_run           = 2;
  24 const float shambler_anim_smash         = 3;
  25 const float shambler_anim_swingr        = 4;
  26 const float shambler_anim_swingl        = 5;
  27 const float shambler_anim_magic         = 6;
  28 const float shambler_anim_pain          = 7;
  29 const float shambler_anim_death         = 8;
  30
  31 void shambler_smash()
  32 {
  33         monster_melee(self.enemy, autocvar_g_monster_shambler_damage, 0.3, DEATH_MONSTER_SHAMBLER_SMASH, TRUE);
  34 }
  35
  36 void shambler_delayedsmash()
  37 {
  38         monsters_setframe(shambler_anim_smash);
  39         defer(0.7, shambler_smash);
  40         self.attack_finished_single = time + 1.1;
  41 }
  42
  43 void shambler_swing()
  44 {
  45         float r = (random() < 0.5);
  46         monsters_setframe((r) ? shambler_anim_swingr : shambler_anim_swingl);
  47         monster_melee(self.enemy, autocvar_g_monster_shambler_attack_claw_damage, 0.3, DEATH_MONSTER_SHAMBLER_CLAW, TRUE);
  48         self.attack_finished_single = time + 0.8;
  49         if(r)
  50                 defer(0.5, shambler_swing);
  51 }
  52
  53 void CastLightning()
  54 {
  55         local vector org, dir;
  56         //vector v = '0 0 0';
  57
  58         self.effects |= EF_MUZZLEFLASH;
  59
  60         org = self.origin + '0 0 40';
  61
  62         dir = self.enemy.origin + '0 0 16' - org;
  63         dir = normalize (dir);
  64
  65         traceline (org, self.origin + dir * 1000, TRUE, self);
  66
  67         FireRailgunBullet (org, org + dir * 1000, autocvar_g_monster_shambler_attack_lightning_damage * monster_skill, 0, 0, 0, 0, 0, DEATH_MONSTER_SHAMBLER_ZAP);
  68
  69         // teamcolor / hit beam effect
  70         //v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
  71         //WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3"), org, v);
  72
  73         te_csqc_lightningarc(org, trace_endpos);
  74 }
  75
  76 float shambler_attack(float attack_type)
  77 {
  78         switch(attack_type)
  79         {
  80                 case MONSTER_ATTACK_MELEE:
  81                 {
  82                         float chance = random();
  83
  84                         if(chance > 0.6)
  85                                 shambler_delayedsmash();
  86                         else
  87                                 shambler_swing();
  88
  89                         return TRUE;
  90                 }
  91                 case MONSTER_ATTACK_RANGED:
  92                 {
  93                         monsters_setframe(shambler_anim_magic);
  94                         self.attack_finished_single = time + 1.1;
  95                         defer(0.6, CastLightning);
  96
  97                         return TRUE;
  98                 }
  99         }
 100
 101         return FALSE;
 102 }
 103
 104 void spawnfunc_monster_shambler()
 105 {
 106         if not(autocvar_g_monster_shambler) { remove(self); return; }
 107
 108         self.classname = "monster_shambler";
 109
 110         self.monster_spawnfunc = spawnfunc_monster_shambler;
 111
 112         if(Monster_CheckAppearFlags(self))
 113                 return;
 114
 115         if not(monster_initialize(MON_SHAMBLER, FALSE, MONSTER_SIZE_BROKEN)) { remove(self); return; }
 116 }
 117
 118 float m_shambler(float req)
 119 {
 120         switch(req)
 121         {
 122                 case MR_THINK:
 123                 {
 124                         monster_move(autocvar_g_monster_shambler_speed_run, autocvar_g_monster_shambler_speed_walk, 300, shambler_anim_run, shambler_anim_walk, shambler_anim_stand);
 125                         return TRUE;
 126                 }
 127                 case MR_DEATH:
 128                 {
 129                         monsters_setframe(shambler_anim_death);
 130                         return TRUE;
 131                 }
 132                 case MR_SETUP:
 133                 {
 134                         if not(self.health) self.health = autocvar_g_monster_shambler_health;
 135
 136                         self.monster_attackfunc = shambler_attack;
 137                         monsters_setframe(shambler_anim_stand);
 138                         self.weapon = WEP_NEX;
 139
 140                         return TRUE;
 141                 }
 142                 case MR_INIT:
 143                 {
 144                         // nothing
 145                         return TRUE;
 146                 }
 147         }
 148
 149         return TRUE;
 150 }
 151
 152 #endif // SVQC
 153 #ifdef CSQC
 154 float m_shambler(float req)
 155 {
 156         switch(req)
 157         {
 158                 case MR_DEATH:
 159                 {
 160                         // nothing
 161                         return TRUE;
 162                 }
 163                 case MR_INIT:
 164                 {
 165                         precache_model ("models/monsters/shambler.mdl");
 166                         return TRUE;
 167                 }
 168         }
 169
 170         return TRUE;
 171 }
 172
 173 #endif // CSQC
 174 #endif // REGISTER_MONSTER