qcsrc/common/monsters/monster/shambler.qc

   1 #ifdef REGISTER_MONSTER
   2 REGISTER_MONSTER(
   3 /* MON_##id   */ SHAMBLER,
   4 /* functions  */ M_Shambler, M_Shambler_Attack,
   5 /* spawnflags */ MONSTER_SIZE_BROKEN | MON_FLAG_SUPERMONSTER | MON_FLAG_MELEE | MON_FLAG_RANGED,
   6 /* mins,maxs  */ '-41 -41 -31', '41 41 65',
   7 /* model      */ "shambler.mdl",
   8 /* netname    */ "shambler",
   9 /* fullname   */ _("Shambler")
  10 );
  11
  12 #else
  13 #ifdef SVQC
  14 float autocvar_g_monster_shambler_health;
  15 float autocvar_g_monster_shambler_damageforcescale = 0.1;
  16 float autocvar_g_monster_shambler_attack_smash_damage;
  17 float autocvar_g_monster_shambler_attack_smash_range;
  18 float autocvar_g_monster_shambler_attack_claw_damage;
  19 float autocvar_g_monster_shambler_attack_lightning_damage;
  20 float autocvar_g_monster_shambler_attack_lightning_damage_zap = 15;
  21 float autocvar_g_monster_shambler_attack_lightning_force;
  22 float autocvar_g_monster_shambler_attack_lightning_radius;
  23 float autocvar_g_monster_shambler_attack_lightning_radius_zap;
  24 float autocvar_g_monster_shambler_attack_lightning_speed;
  25 float autocvar_g_monster_shambler_attack_lightning_speed_up;
  26 float autocvar_g_monster_shambler_speed_stop;
  27 float autocvar_g_monster_shambler_speed_run;
  28 float autocvar_g_monster_shambler_speed_walk;
  29
  30 /*
  31 const float shambler_anim_stand         = 0;
  32 const float shambler_anim_walk          = 1;
  33 const float shambler_anim_run           = 2;
  34 const float shambler_anim_smash         = 3;
  35 const float shambler_anim_swingr        = 4;
  36 const float shambler_anim_swingl        = 5;
  37 const float shambler_anim_magic         = 6;
  38 const float shambler_anim_pain          = 7;
  39 const float shambler_anim_death         = 8;
  40 */
  41
  42 .float shambler_lastattack; // delay attacks separately
  43
  44 void M_Shambler_Attack_Smash()
  45 {
  46         makevectors(self.angles);
  47         pointparticles(particleeffectnum("explosion_medium"), (self.origin + (v_forward * 150)) - ('0 0 1' * self.maxs.z), '0 0 0', 1);
  48         sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
  49
  50         // RadiusDamage does NOT support custom starting location, which means we must use this hack...
  51
  52         tracebox(self.origin + v_forward * 50, self.mins * 0.5, self.maxs * 0.5, self.origin + v_forward * autocvar_g_monster_shambler_attack_smash_range, MOVE_NORMAL, self);
  53
  54         if(trace_ent.takedamage)
  55                 Damage(trace_ent, self, self, (autocvar_g_monster_shambler_attack_smash_damage) * MONSTER_SKILLMOD(self), DEATH_MONSTER_SHAMBLER_SMASH, trace_ent.origin, normalize(trace_ent.origin - self.origin));
  56 }
  57
  58 void M_Shambler_Attack_Swing()
  59 {
  60         float r = (random() < 0.5);
  61         if(r && Monster_Attack_Melee(self.enemy, (autocvar_g_monster_shambler_attack_claw_damage), ((r) ? self.anim_melee2 : self.anim_melee3), self.attack_range, 0.8, DEATH_MONSTER_SHAMBLER_CLAW, true))
  62         {
  63                 Monster_Delay(1, 0, 0.5, M_Shambler_Attack_Swing);
  64                 self.attack_finished_single += 0.5;
  65                 self.anim_finished = self.attack_finished_single;
  66         }
  67 }
  68
  69 void M_Shambler_Attack_Lightning_Explode()
  70 {
  71         entity head;
  72
  73         sound(self, CH_SHOTS, "weapons/electro_impact.wav", VOL_BASE, ATTEN_NORM);
  74         pointparticles(particleeffectnum("electro_impact"), '0 0 0', '0 0 0', 1);
  75
  76         self.event_damage = func_null;
  77         self.takedamage = DAMAGE_NO;
  78         self.movetype = MOVETYPE_NONE;
  79         self.velocity = '0 0 0';
  80
  81         if(self.movetype == MOVETYPE_NONE)
  82                 self.velocity = self.oldvelocity;
  83
  84         RadiusDamage (self, self.realowner, (autocvar_g_monster_shambler_attack_lightning_damage), (autocvar_g_monster_shambler_attack_lightning_damage), (autocvar_g_monster_shambler_attack_lightning_radius), world, world, (autocvar_g_monster_shambler_attack_lightning_force), self.projectiledeathtype, other);
  85
  86         for(head = findradius(self.origin, (autocvar_g_monster_shambler_attack_lightning_radius_zap)); head; head = head.chain) if(head != self.realowner) if(head.takedamage)
  87         {
  88                 te_csqc_lightningarc(self.origin, head.origin);
  89                 Damage(head, self, self.realowner, (autocvar_g_monster_shambler_attack_lightning_damage_zap) * MONSTER_SKILLMOD(self), DEATH_MONSTER_SHAMBLER_ZAP, head.origin, '0 0 0');
  90         }
  91
  92         self.think = SUB_Remove;
  93         self.nextthink = time + 0.2;
  94 }
  95
  96 void M_Shambler_Attack_Lightning_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
  97 {
  98         if (self.health <= 0)
  99                 return;
 100
 101         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 102                 return; // g_projectiles_damage says to halt
 103
 104         self.health = self.health - damage;
 105
 106         if (self.health <= 0)
 107                 W_PrepareExplosionByDamage(attacker, self.use);
 108 }
 109
 110 void M_Shambler_Attack_Lightning_Touch()
 111 {
 112         PROJECTILE_TOUCH;
 113
 114         self.use ();
 115 }
 116
 117 void M_Shambler_Attack_Lightning_Think()
 118 {
 119         self.nextthink = time;
 120         if (time > self.cnt)
 121         {
 122                 other = world;
 123                 M_Shambler_Attack_Lightning_Explode();
 124                 return;
 125         }
 126 }
 127
 128 void M_Shambler_Attack_Lightning()
 129 {
 130         entity gren;
 131
 132         monster_makevectors(self.enemy);
 133
 134         gren = spawn ();
 135         gren.owner = gren.realowner = self;
 136         gren.classname = "grenade";
 137         gren.bot_dodge = true;
 138         gren.bot_dodgerating = (autocvar_g_monster_shambler_attack_lightning_damage);
 139         gren.movetype = MOVETYPE_BOUNCE;
 140         PROJECTILE_MAKETRIGGER(gren);
 141         gren.projectiledeathtype = DEATH_MONSTER_SHAMBLER_ZAP;
 142         setorigin(gren, CENTER_OR_VIEWOFS(self));
 143         setsize(gren, '-8 -8 -8', '8 8 8');
 144         gren.scale = 2.5;
 145
 146         gren.cnt = time + 5;
 147         gren.nextthink = time;
 148         gren.think = M_Shambler_Attack_Lightning_Think;
 149         gren.use = M_Shambler_Attack_Lightning_Explode;
 150         gren.touch = M_Shambler_Attack_Lightning_Touch;
 151
 152         gren.takedamage = DAMAGE_YES;
 153         gren.health = 50;
 154         gren.damageforcescale = 0;
 155         gren.event_damage = M_Shambler_Attack_Lightning_Damage;
 156         gren.damagedbycontents = true;
 157         gren.missile_flags = MIF_SPLASH | MIF_ARC;
 158         W_SetupProjVelocity_Explicit(gren, v_forward, v_up, (autocvar_g_monster_shambler_attack_lightning_speed), (autocvar_g_monster_shambler_attack_lightning_speed_up), 0, 0, false);
 159
 160         gren.angles = vectoangles (gren.velocity);
 161         gren.flags = FL_PROJECTILE;
 162
 163         CSQCProjectile(gren, true, PROJECTILE_SHAMBLER_LIGHTNING, true);
 164 }
 165
 166 float M_Shambler_Attack(float attack_type)
 167 {
 168         switch(attack_type)
 169         {
 170                 case MONSTER_ATTACK_MELEE:
 171                 {
 172                         M_Shambler_Attack_Swing();
 173                         return true;
 174                 }
 175                 case MONSTER_ATTACK_RANGED:
 176                 {
 177                         float randomness = random(), enemy_len = vlen(self.enemy.origin - self.origin);
 178
 179                         if(time >= self.shambler_lastattack) // shambler doesn't attack much
 180                         if(self.flags & FL_ONGROUND)
 181                         if(randomness <= 0.5 && enemy_len <= autocvar_g_monster_shambler_attack_smash_range)
 182                         {
 183                                 setanim(self, self.anim_melee2, true, true, false);
 184                                 Monster_Delay(1, 0, 0.7, M_Shambler_Attack_Smash);
 185                                 self.attack_finished_single = time + 1.1;
 186                                 self.anim_finished = time + 1.1;
 187                                 self.state = MONSTER_ATTACK_MELEE; // kinda a melee attack
 188                                 self.shambler_lastattack = time + 3 + random() * 1.5;
 189                                 return true;
 190                         }
 191                         else if(randomness <= 0.1 && enemy_len >= autocvar_g_monster_shambler_attack_smash_range * 1.5) // small chance, don't want this spammed
 192                         {
 193                                 setanim(self, self.anim_shoot, true, true, false);
 194                                 self.state = MONSTER_ATTACK_MELEE; // maybe we should rename this to something more general
 195                                 self.attack_finished_single = time + 1.1;
 196                                 self.anim_finished = 1.1;
 197                                 self.shambler_lastattack = time + 3 + random() * 1.5;
 198                                 Monster_Delay(1, 0, 0.6, M_Shambler_Attack_Lightning);
 199                                 return true;
 200                         }
 201
 202                         return false;
 203                 }
 204         }
 205
 206         return false;
 207 }
 208
 209 void spawnfunc_monster_shambler() { Monster_Spawn(MON_SHAMBLER); }
 210 #endif // SVQC
 211
 212 bool M_Shambler(int req)
 213 {
 214         switch(req)
 215         {
 216                 #ifdef SVQC
 217                 case MR_THINK:
 218                 {
 219                         return true;
 220                 }
 221                 case MR_PAIN:
 222                 {
 223                         self.pain_finished = time + 0.5;
 224                         setanim(self, self.anim_pain1, true, true, false);
 225                         return true;
 226                 }
 227                 case MR_DEATH:
 228                 {
 229                         setanim(self, self.anim_die1, false, true, true);
 230                         return true;
 231                 }
 232                 #endif
 233                 #ifndef MENUQC
 234                 case MR_ANIM:
 235                 {
 236                         vector none = '0 0 0';
 237                         self.anim_die1 = animfixfps(self, '8 1 0.5', none); // 2 seconds
 238                         self.anim_walk = animfixfps(self, '1 1 1', none);
 239                         self.anim_idle = animfixfps(self, '0 1 1', none);
 240                         self.anim_pain1 = animfixfps(self, '7 1 2', none); // 0.5 seconds
 241                         self.anim_melee1 = animfixfps(self, '3 1 5', none); // analyze models and set framerate
 242                         self.anim_melee2 = animfixfps(self, '4 1 5', none); // analyze models and set framerate
 243                         self.anim_melee3 = animfixfps(self, '5 1 5', none); // analyze models and set framerate
 244                         self.anim_shoot = animfixfps(self, '6 1 5', none); // analyze models and set framerate
 245                         self.anim_run = animfixfps(self, '2 1 1', none);
 246
 247                         return true;
 248                 }
 249                 #endif
 250                 #ifdef SVQC
 251                 case MR_SETUP:
 252                 {
 253                         if(!self.health) self.health = (autocvar_g_monster_shambler_health);
 254                         if(!self.attack_range) self.attack_range = 150;
 255                         if(!self.speed) { self.speed = (autocvar_g_monster_shambler_speed_walk); }
 256                         if(!self.speed2) { self.speed2 = (autocvar_g_monster_shambler_speed_run); }
 257                         if(!self.stopspeed) { self.stopspeed = (autocvar_g_monster_shambler_speed_stop); }
 258                         if(!self.damageforcescale) { self.damageforcescale = (autocvar_g_monster_shambler_damageforcescale); }
 259
 260                         self.monster_loot = spawnfunc_item_health_mega;
 261                         self.weapon = WEP_ELECTRO; // matches attacks better than WEP_VORTEX
 262
 263                         setanim(self, self.anim_shoot, false, true, true);
 264                         self.spawn_time = self.animstate_endtime;
 265                         self.spawnshieldtime = self.spawn_time;
 266
 267                         return true;
 268                 }
 269                 case MR_PRECACHE:
 270                 {
 271                         precache_model("models/monsters/shambler.mdl");
 272                         return true;
 273                 }
 274                 #endif
 275         }
 276
 277         return true;
 278 }
 279
 280 #endif // REGISTER_MONSTER