qcsrc/common/mapinfo.qc

   1 #include "mapinfo.qh"
   2 #if defined(CSQC)
   3     #include "../client/defs.qh"
   4     #include "util.qh"
   5     #include <common/weapons/_all.qh>
   6 #elif defined(MENUQC)
   7 #elif defined(SVQC)
   8     #include "util.qh"
   9     #include <common/monsters/_mod.qh>
  10 #endif
  11
  12 #ifdef MENUQC
  13 #define WARN_COND false
  14 #else
  15 bool autocvar_g_mapinfo_ignore_warnings;
  16 #define WARN_COND (!autocvar_g_mapinfo_ignore_warnings && MapInfo_Map_bspname == mi_shortname)
  17 #endif
  18
  19 // generic string stuff
  20
  21 int _MapInfo_Cache_Active;
  22 int _MapInfo_Cache_DB_NameToIndex;
  23 int _MapInfo_Cache_Buf_IndexToMapData;
  24
  25 void MapInfo_Cache_Destroy()
  26 {
  27         if(!_MapInfo_Cache_Active)
  28                 return;
  29
  30         db_close(_MapInfo_Cache_DB_NameToIndex);
  31         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
  32         _MapInfo_Cache_Active = 0;
  33 }
  34
  35 void MapInfo_Cache_Create()
  36 {
  37         MapInfo_Cache_Destroy();
  38         _MapInfo_Cache_DB_NameToIndex = db_create();
  39         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
  40         _MapInfo_Cache_Active = 1;
  41 }
  42
  43 void MapInfo_Cache_Invalidate()
  44 {
  45         if(!_MapInfo_Cache_Active)
  46                 return;
  47
  48         MapInfo_Cache_Create();
  49 }
  50
  51 void MapInfo_Cache_Store()
  52 {
  53         float i;
  54         string s;
  55         if(!_MapInfo_Cache_Active)
  56                 return;
  57
  58         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
  59         if(s == "")
  60         {
  61                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
  62                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
  63         }
  64         else
  65                 i = stof(s);
  66
  67         // now store all the stuff
  68         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData,   i, MapInfo_Map_bspname);
  69         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_title);
  70         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_titlestring);
  71         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_description);
  72         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_author);
  73         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedGametypes));
  74         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedFeatures));
  75         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_flags));
  76 }
  77
  78 float MapInfo_Cache_Retrieve(string map)
  79 {
  80         float i;
  81         string s;
  82         if(!_MapInfo_Cache_Active)
  83                 return 0;
  84
  85         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
  86         if(s == "")
  87                 return 0;
  88         i = stof(s);
  89
  90         // now retrieve all the stuff
  91         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i);
  92         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  93         MapInfo_Map_titlestring = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  94         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  95         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  96         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  97         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  98         MapInfo_Map_flags = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  99
 100         return 1;
 101 }
 102
 103 // GLOB HANDLING (for all BSP files)
 104 float _MapInfo_globopen;
 105 float _MapInfo_globcount;
 106 float _MapInfo_globhandle;
 107 string _MapInfo_GlobItem(float i)
 108 {
 109         string s;
 110         if(!_MapInfo_globopen)
 111                 return string_null;
 112         s = search_getfilename(_MapInfo_globhandle, i);
 113         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
 114 }
 115
 116 void MapInfo_Enumerate()
 117 {
 118         if(_MapInfo_globopen)
 119         {
 120                 search_end(_MapInfo_globhandle);
 121                 _MapInfo_globopen = 0;
 122         }
 123         MapInfo_Cache_Invalidate();
 124         _MapInfo_globhandle = search_begin("maps/*.bsp", true, true);
 125         if(_MapInfo_globhandle >= 0)
 126         {
 127                 _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
 128                 _MapInfo_globopen = 1;
 129         }
 130         else
 131                 _MapInfo_globcount = 0;
 132 }
 133
 134 // filter the info by game type mask (updates MapInfo_count)
 135 //
 136 float _MapInfo_filtered;
 137 float _MapInfo_filtered_allocated;
 138 float MapInfo_FilterList_Lookup(float i)
 139 {
 140         return stof(bufstr_get(_MapInfo_filtered, i));
 141 }
 142
 143 void _MapInfo_FilterList_swap(float i, float j, entity pass)
 144 {
 145         string h;
 146         h = bufstr_get(_MapInfo_filtered, i);
 147         bufstr_set(_MapInfo_filtered, i, bufstr_get(_MapInfo_filtered, j));
 148         bufstr_set(_MapInfo_filtered, j, h);
 149 }
 150
 151 float _MapInfo_FilterList_cmp(float i, float j, entity pass)
 152 {
 153         string a, b;
 154         a = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, i)));
 155         b = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, j)));
 156         return strcasecmp(a, b);
 157 }
 158
 159 float MapInfo_FilterGametype(Gametype pGametype, int pFeatures, int pFlagsRequired, int pFlagsForbidden, bool pAbortOnGenerate)
 160 {
 161         return _MapInfo_FilterGametype(pGametype.m_flags, pFeatures, pFlagsRequired, pFlagsForbidden, pAbortOnGenerate);
 162 }
 163 float _MapInfo_FilterGametype(int pGametype, int pFeatures, int pFlagsRequired, int pFlagsForbidden, bool pAbortOnGenerate)
 164 {
 165         float i, j;
 166         if (!_MapInfo_filtered_allocated)
 167         {
 168                 _MapInfo_filtered_allocated = 1;
 169                 _MapInfo_filtered = buf_create();
 170         }
 171         MapInfo_count = 0;
 172         for(i = 0, j = -1; i < _MapInfo_globcount; ++i)
 173         {
 174                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, NULL) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 175                         if(pAbortOnGenerate)
 176                         {
 177                                 LOG_TRACE("Autogenerated a .mapinfo, doing the rest later.");
 178                                 MapInfo_progress = i / _MapInfo_globcount;
 179                                 return 0;
 180                         }
 181                 if((MapInfo_Map_supportedGametypes & pGametype) != 0)
 182                 if((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures)
 183                 if((MapInfo_Map_flags & pFlagsForbidden) == 0)
 184                 if((MapInfo_Map_flags & pFlagsRequired) == pFlagsRequired)
 185                         bufstr_set(_MapInfo_filtered, ++j, ftos(i));
 186         }
 187         MapInfo_count = j + 1;
 188         MapInfo_ClearTemps();
 189
 190         // sometimes the glob isn't sorted nicely, so fix it here...
 191         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, NULL);
 192
 193         return 1;
 194 }
 195 void MapInfo_FilterString(string sf)
 196 {
 197         // this function further filters _MapInfo_filtered, which is prepared by MapInfo_FilterGametype by string
 198         float i, j;
 199         string title;
 200
 201         for(i = 0, j = -1; i < MapInfo_count; ++i)
 202         {
 203                 if (MapInfo_Get_ByID(i))
 204                 {
 205                         // prepare for keyword filter
 206                         if (MapInfo_Map_title && strstrofs(MapInfo_Map_title, "<TITLE>", 0) == -1)
 207                                 title = MapInfo_Map_title;
 208                         else
 209                                 title = MapInfo_Map_bspname;
 210                         // keyword filter
 211                         if((strstrofs(strtolower(title), strtolower(sf), 0)) >= 0)
 212                                 bufstr_set(_MapInfo_filtered, ++j, bufstr_get(_MapInfo_filtered, i));
 213                 }
 214         }
 215         MapInfo_count = j + 1;
 216         MapInfo_ClearTemps();
 217
 218         // sometimes the glob isn't sorted nicely, so fix it here...
 219         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, NULL);
 220 }
 221
 222 void MapInfo_Filter_Free()
 223 {
 224         if(_MapInfo_filtered_allocated)
 225         {
 226                 buf_del(_MapInfo_filtered);
 227                 _MapInfo_filtered_allocated = 0;
 228         }
 229 }
 230
 231 // load info about the i-th map into the MapInfo_Map_* globals
 232 string MapInfo_BSPName_ByID(float i)
 233 {
 234         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
 235 }
 236
 237 string unquote(string s)
 238 {
 239         float l = strlen(s);
 240         for(float i = 0; i < l; ++i)
 241         {
 242                 string ch = substring(s, i, 1);
 243                 if((ch != " ") && (ch != "\""))
 244                 {
 245                         for(float j = l - i - 1; j > 0; --j)
 246                         {
 247                                 ch = substring(s, i+j, 1);
 248                                 if(ch != " ") if(ch != "\"")
 249                                         return substring(s, i, j+1);
 250                         }
 251                         return substring(s, i, 1);
 252                 }
 253         }
 254         return "";
 255 }
 256
 257 float MapInfo_Get_ByID(float i)
 258 {
 259         if(MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, NULL))
 260                 return 1;
 261         return 0;
 262 }
 263
 264 string _MapInfo_Map_worldspawn_music;
 265
 266 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
 267 {
 268         string fn;
 269         float fh;
 270         string s, k, v;
 271         vector o;
 272         float i;
 273         float inWorldspawn;
 274         float r;
 275         float diameter, spawnpoints;
 276         float spawnplaces;
 277
 278         vector mapMins, mapMaxs;
 279
 280         r = 1;
 281         fn = strcat("maps/", pFilename, ".ent");
 282         fh = fopen(fn, FILE_READ);
 283         if(fh < 0)
 284         {
 285                 r = 2;
 286                 fn = strcat("maps/", pFilename, ".bsp");
 287                 fh = fopen(fn, FILE_READ);
 288         }
 289         if(fh < 0)
 290                 return 0;
 291         LOG_INFO("Analyzing ", fn, " to generate initial mapinfo");
 292
 293         inWorldspawn = 2;
 294         MapInfo_Map_flags = 0;
 295         MapInfo_Map_supportedGametypes = 0;
 296         spawnpoints = 0;
 297         spawnplaces = 0;
 298         _MapInfo_Map_worldspawn_music = "";
 299         mapMins = '0 0 0';
 300         mapMaxs = '0 0 0';
 301
 302         for (;;)
 303         {
 304                 if (!((s = fgets(fh))))
 305                         break;
 306                 if(inWorldspawn == 1)
 307                         if(startsWith(s, "}"))
 308                                 inWorldspawn = 0;
 309                 k = unquote(car(s));
 310                 v = unquote(cdr(s));
 311                 if(inWorldspawn)
 312                 {
 313                         if(k == "classname" && v == "worldspawn")
 314                                 inWorldspawn = 1;
 315                         else if(k == "author")
 316                                 MapInfo_Map_author = v;
 317                         else if(k == "_description")
 318                                 MapInfo_Map_description = v;
 319                         else if(k == "music")
 320                                 _MapInfo_Map_worldspawn_music = v;
 321                         else if(k == "noise")
 322                                 _MapInfo_Map_worldspawn_music = v;
 323                         else if(k == "message")
 324                         {
 325                                 i = strstrofs(v, " by ", 0);
 326                                 if(MapInfo_Map_author == "<AUTHOR>" && i >= 0)
 327                                 {
 328                                         MapInfo_Map_title = substring(v, 0, i);
 329                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
 330                                 }
 331                                 else
 332                                         MapInfo_Map_title = v;
 333                         }
 334                 }
 335                 else
 336                 {
 337                         if(k == "origin")
 338                         {
 339                                 o = stov(strcat("'", v, "'"));
 340                                 mapMins.x = min(mapMins.x, o.x);
 341                                 mapMins.y = min(mapMins.y, o.y);
 342                                 mapMins.z = min(mapMins.z, o.z);
 343                                 mapMaxs.x = max(mapMaxs.x, o.x);
 344                                 mapMaxs.y = max(mapMaxs.y, o.y);
 345                                 mapMaxs.z = max(mapMaxs.z, o.z);
 346                         }
 347                         else if(k == "race_place")
 348                         {
 349                                 if(stof(v) > 0)
 350                                         spawnplaces = 1;
 351                         }
 352                         else if(k == "classname")
 353                         {
 354                                 if(v == "info_player_team1")
 355                                         ++spawnpoints;
 356                                 else if(v == "info_player_team2")
 357                                         ++spawnpoints;
 358                                 else if(v == "info_player_start")
 359                                         ++spawnpoints;
 360                                 else if(v == "info_player_deathmatch")
 361                                         ++spawnpoints;
 362                                 else if(v == "weapon_nex")
 363                                         { }
 364                                 else if(v == "weapon_railgun")
 365                                         { }
 366                                 else if(startsWith(v, "weapon_"))
 367                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 368                                 else if(startsWith(v, "turret_"))
 369                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
 370                                 else if(startsWith(v, "vehicle_"))
 371                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
 372                                 else if(startsWith(v, "monster_"))
 373                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_MONSTERS;
 374                                 else if(v == "target_music" || v == "trigger_music")
 375                                         _MapInfo_Map_worldspawn_music = string_null; // don't use regular BGM
 376                                 else
 377                                         FOREACH(Gametypes, true, it.m_generate_mapinfo(it, v));
 378                         }
 379                 }
 380         }
 381         if(inWorldspawn)
 382         {
 383                 LOG_WARN(fn, " ended still in worldspawn, BUG");
 384                 return 0;
 385         }
 386         diameter = vlen(mapMaxs - mapMins);
 387
 388         int twoBaseModes = 0;
 389         FOREACH(Gametypes, it.m_isTwoBaseMode(), twoBaseModes |= it.m_flags);
 390         if(twoBaseModes && (twoBaseModes &= MapInfo_Map_supportedGametypes))
 391         {
 392                 // we have a symmetrical map, don't add the modes without bases
 393         }
 394         else
 395         {
 396                 FOREACH(Gametypes, it.m_isAlwaysSupported(it, spawnpoints, diameter), MapInfo_Map_supportedGametypes |= it.m_flags);
 397         }
 398
 399         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE.m_flags)
 400         if(!spawnplaces)
 401         {
 402                 MapInfo_Map_supportedGametypes &= ~MAPINFO_TYPE_RACE.m_flags;
 403                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS.m_flags;
 404         }
 405
 406         LOG_TRACE("-> diameter ",    ftos(diameter));
 407         LOG_TRACE(";  spawnpoints ", ftos(spawnpoints));
 408         LOG_TRACE(";  modes ",       ftos(MapInfo_Map_supportedGametypes));
 409
 410         fclose(fh);
 411
 412         return r;
 413 }
 414
 415 void _MapInfo_Map_Reset()
 416 {
 417         MapInfo_Map_title = "<TITLE>";
 418         MapInfo_Map_titlestring = "<TITLE>";
 419         MapInfo_Map_description = "<DESCRIPTION>";
 420         MapInfo_Map_author = "<AUTHOR>";
 421         MapInfo_Map_supportedGametypes = 0;
 422         MapInfo_Map_supportedFeatures = 0;
 423         MapInfo_Map_flags = 0;
 424         MapInfo_Map_clientstuff = "";
 425         MapInfo_Map_fog = "";
 426         MapInfo_Map_mins = '0 0 0';
 427         MapInfo_Map_maxs = '0 0 0';
 428 }
 429
 430 string _MapInfo_GetDefault(Gametype t)
 431 {
 432         return t.m_legacydefaults;
 433 }
 434
 435 void _MapInfo_Map_ApplyGametype(string s, Gametype pWantedType, Gametype pThisType, int load_default)
 436 {
 437         string sa;
 438         MapInfo_Map_supportedGametypes |= pThisType.m_flags;
 439         if(!(pThisType.m_flags & pWantedType.m_flags))
 440                 return;
 441
 442         if(load_default)
 443                 _MapInfo_Map_ApplyGametype(_MapInfo_GetDefault(pThisType), pWantedType, pThisType, false);
 444
 445         if(!pWantedType.frags) // these modes don't use fraglimit
 446         {
 447                 cvar_set("fraglimit", "0");
 448         }
 449         else
 450         {
 451                 sa = car(s);
 452                 if(sa != "")
 453                         cvar_set("fraglimit", sa);
 454                 s = cdr(s);
 455         }
 456
 457         sa = car(s);
 458         if(sa != "")
 459                 cvar_set("timelimit", sa);
 460         s = cdr(s);
 461
 462         if(pWantedType.m_setTeams)
 463         {
 464                 sa = car(s);
 465                 if(sa != "")
 466                         pWantedType.m_setTeams(sa);
 467                 s = cdr(s);
 468         }
 469
 470         // rc = timelimit timelimit_qualification laps laps_teamplay
 471         if(pWantedType == MAPINFO_TYPE_RACE)
 472         {
 473                 cvar_set("fraglimit", "0"); // special case!
 474
 475                 sa = car(s); if(sa == "") sa = cvar_string("timelimit");
 476                 cvar_set("g_race_qualifying_timelimit", sa);
 477                 s = cdr(s);
 478
 479                 sa = car(s);
 480                 if(sa != "")
 481                         if(cvar("g_race_teams") < 2)
 482                                 cvar_set("fraglimit", sa);
 483                 s = cdr(s);
 484
 485                 sa = car(s);
 486                 if(sa != "")
 487                         if(cvar("g_race_teams") >= 2)
 488                                 cvar_set("fraglimit", sa);
 489                 s = cdr(s);
 490         }
 491
 492         if(!pWantedType.frags) // these modes don't use fraglimit
 493         {
 494                 cvar_set("leadlimit", "0");
 495         }
 496         else
 497         {
 498                 sa = car(s);
 499                 if(sa != "")
 500                         cvar_set("leadlimit", sa);
 501                 s = cdr(s);
 502         }
 503 }
 504
 505 string _MapInfo_GetDefaultEx(Gametype t)
 506 {
 507         return t ? t.model2 : "";
 508 }
 509
 510 float _MapInfo_GetTeamPlayBool(Gametype t)
 511 {
 512         return t ? t.team : false;
 513 }
 514
 515 void _MapInfo_Map_ApplyGametypeEx(string s, Gametype pWantedType, Gametype pThisType)
 516 {
 517         MapInfo_Map_supportedGametypes |= pThisType.m_flags;
 518         if (!(pThisType.m_flags & pWantedType.m_flags))
 519                 return;
 520
 521         // reset all the cvars to their defaults
 522
 523         cvar_set("timelimit", cvar_defstring("timelimit"));
 524         cvar_set("leadlimit", cvar_defstring("leadlimit"));
 525         cvar_set("fraglimit", cvar_defstring("fraglimit"));
 526         FOREACH(Gametypes, true, it.m_parse_mapinfo(string_null, string_null));
 527
 528         string fraglimit_normal = string_null;
 529         string fraglimit_teams = string_null;
 530
 531         for (s = strcat(_MapInfo_GetDefaultEx(pWantedType), " ", s); s != ""; s = cdr(s)) {
 532                 string sa = car(s);
 533                 if (sa == "") continue;
 534                 int p = strstrofs(sa, "=", 0);
 535                 if (p < 0) {
 536                         if(WARN_COND)
 537                                 LOG_WARNF("Invalid gametype setting in mapinfo for gametype %s: %s", MapInfo_Type_ToString(pWantedType), sa);
 538                         continue;
 539                 }
 540                 string k = substring(sa, 0, p);
 541                 string v = substring(sa, p + 1, -1);
 542                 bool handled = true;
 543                 switch (k) {
 544                         case "timelimit":
 545                         {
 546                                 cvar_set("timelimit", v);
 547                                 break;
 548                         }
 549                         case "leadlimit":
 550                         {
 551                                 cvar_set("leadlimit", v);
 552                                 break;
 553                         }
 554                         case "pointlimit":
 555                         case "fraglimit":
 556                         case "lives":
 557                         case "laplimit":
 558                         case "caplimit":
 559                         {
 560                                 fraglimit_normal = v;
 561                                 break;
 562                         }
 563                         case "teampointlimit":
 564                         case "teamlaplimit":
 565                         {
 566                                 fraglimit_teams = v;
 567                                 break;
 568                         }
 569                         default:
 570                         {
 571                             handled = false;
 572                             break;
 573                         }
 574                 }
 575                 FOREACH(Gametypes, true, handled |= it.m_parse_mapinfo(k, v));
 576                 if (!handled && WARN_COND)
 577             LOG_WARNF("Invalid gametype setting in mapinfo for gametype %s: %s", MapInfo_Type_ToString(pWantedType), sa);
 578         }
 579
 580         if (pWantedType == MAPINFO_TYPE_RACE && cvar("g_race_teams") >= 2)
 581         {
 582                 if(fraglimit_teams)
 583                         cvar_set("fraglimit", fraglimit_teams);
 584         }
 585         else
 586         {
 587                 if(fraglimit_normal)
 588                         cvar_set("fraglimit", fraglimit_normal);
 589         }
 590 }
 591
 592 Gametype MapInfo_Type_FromString(string gtype)
 593 {
 594         string replacement = "";
 595         bool do_warn = true;
 596         switch (gtype)
 597         {
 598                 case "nexball":   replacement = "nb"; break;
 599                 case "freezetag": replacement = "ft"; break;
 600                 case "keepaway":  replacement = "ka"; break;
 601                 case "invasion":  replacement = "inv"; break;
 602                 case "assault":   replacement = "as"; break;
 603                 case "race":      replacement = "rc"; break;
 604                 // quake 3 compat
 605                 case "ffa":       replacement = "dm"; do_warn = false; break;
 606                 case "cctf":
 607                 case "oneflag":   replacement = "ctf"; do_warn = false; break;
 608                 case "team":      replacement = "tdm"; do_warn = false; break;
 609                 case "tourney":   replacement = "duel"; do_warn = false; break;
 610         }
 611         if (replacement != "")
 612         {
 613                 if(do_warn && WARN_COND)
 614                         LOG_WARNF("MapInfo_Type_FromString (probably %s): using deprecated name '%s'. Should use '%s'.", MapInfo_Map_bspname, gtype, replacement);
 615                 gtype = replacement;
 616         }
 617         FOREACH(Gametypes, it.mdl == gtype, return it);
 618         return NULL;
 619 }
 620
 621 string MapInfo_Type_Description(Gametype t)
 622 {
 623         return t ? t.gametype_description : "";
 624 }
 625
 626 string MapInfo_Type_ToString(Gametype t)
 627 {
 628         return t ? t.mdl : "";
 629 }
 630
 631 string MapInfo_Type_ToText(Gametype t)
 632 {
 633         /* xgettext:no-c-format */
 634         return t ? t.message : _("@!#%'n Tuba Throwing");
 635 }
 636
 637 void _MapInfo_Parse_Settemp(string pFilename, string acl, float type, string s, float recurse)
 638 {
 639         string t;
 640         float fh, o;
 641         t = car(s); s = cdr(s);
 642
 643         // limited support of "" and comments
 644         //   remove trailing and leading " of t
 645         if(substring(t, 0, 1) == "\"")
 646         {
 647                 if(substring(t, -1, 1) == "\"")
 648                         t = substring(t, 1, -2);
 649         }
 650
 651         //   remove leading " of s
 652         if(substring(s, 0, 1) == "\"")
 653         {
 654                 s = substring(s, 1, -1);
 655         }
 656         //   remove trailing " of s, and all that follows (cvar description)
 657         o = strstrofs(s, "\"", 0);
 658         if(o >= 0)
 659                 s = substring(s, 0, o);
 660
 661         //   remove // comments
 662         o = strstrofs(s, "//", 0);
 663         if(o >= 0)
 664                 s = substring(s, 0, o);
 665
 666         //   remove trailing spaces
 667         while(substring(s, -1, 1) == " ")
 668                 s = substring(s, 0, -2);
 669
 670         if(t == "#include")
 671         {
 672                 if(recurse > 0)
 673                 {
 674                         fh = fopen(s, FILE_READ);
 675                         if(fh < 0)
 676                         {
 677                                 if(WARN_COND)
 678                                         LOG_WARN("Map ", pFilename, " references not existing config file ", s);
 679                         }
 680                         else
 681                         {
 682                                 while((s = fgets(fh)))
 683                                 {
 684                                         // catch different sorts of comments
 685                                         if(s == "")                    // empty lines
 686                                                 continue;
 687                                         if(substring(s, 0, 1) == "#")  // UNIX style
 688                                                 continue;
 689                                         if(substring(s, 0, 2) == "//") // C++ style
 690                                                 continue;
 691                                         if(substring(s, 0, 1) == "_")  // q3map style
 692                                                 continue;
 693
 694                                         if(substring(s, 0, 4) == "set ")
 695                                                 s = substring(s, 4, -1);
 696                                         if(substring(s, 0, 5) == "seta ")
 697                                                 s = substring(s, 5, -1);
 698
 699                                         _MapInfo_Parse_Settemp(pFilename, acl, type, s, recurse - 1);
 700                                 }
 701                                 fclose(fh);
 702                         }
 703                 }
 704                 else if(WARN_COND)
 705                         LOG_WARN("Map ", pFilename, " uses too many levels of inclusion");
 706         }
 707         else if(t == ""
 708                 || !cvar_value_issafe(t)
 709                 || !cvar_value_issafe(s)
 710                 || matchacl(MAPINFO_SETTEMP_ACL_SYSTEM, t) <= 0)
 711         {
 712                 if (WARN_COND)
 713                         LOG_WARN("Map ", pFilename, " contains a potentially harmful setting, ignored");
 714         }
 715         else if(matchacl(acl, t) <= 0)
 716         {
 717                 if (WARN_COND)
 718                         LOG_WARN("Map ", pFilename, " contains a denied setting, ignored");
 719         }
 720         else
 721         {
 722                 if(type == 0) // server set
 723                 {
 724                         LOG_TRACE("Applying temporary setting ", t, " := ", s);
 725                 #if 0
 726                         if(cvar("g_campaign"))
 727                                 cvar_set(t, s); // this is a wrapper and is always temporary anyway; no need to backup old values then
 728                         else
 729                 #endif
 730                                 cvar_settemp(t, s);
 731                 }
 732                 else
 733                 {
 734                         LOG_TRACE("Applying temporary client setting ", t, " := ", s);
 735                         MapInfo_Map_clientstuff = strcat(
 736                                         MapInfo_Map_clientstuff, "cl_cmd settemp \"", t, "\" \"", s, "\"\n"
 737                                         );
 738                 }
 739         }
 740 }
 741
 742 float MapInfo_isRedundant(string fn, string t)
 743 {
 744         // normalize file name
 745         fn = strreplace("_", "", fn);
 746         fn = strreplace("-", "", fn);
 747
 748         // normalize visible title
 749         t = strreplace(":", "", t);
 750         t = strreplace(" ", "", t);
 751         t = strreplace("_", "", t);
 752         t = strreplace("-", "", t);
 753         t = strreplace("'", "", t);
 754         t = strdecolorize(t);
 755
 756         // we allow the visible title to have punctuation the file name does
 757         // not, but not vice versa
 758         if(!strcasecmp(fn, t))
 759                 return true;
 760
 761         return false;
 762 }
 763
 764 bool _MapInfo_ParseArena(int fh, string pFilename, Gametype pGametypeToSet, bool isdefi)
 765 {
 766         // NOTE: .arena files can hold more than 1 map's information!
 767         // to handle this, we're going to store gathered information in local variables and save it if we encounter the correct map name
 768         bool testing_map = false; // testing a potential mapinfo section (within brackets)
 769         bool dosave = false; // variables will be stored in map info upon reaching finishing bracket
 770         string stored_Map_description = "";
 771         string stored_Map_title = "";
 772         int stored_supportedGametypes = 0;
 773         string t, s;
 774         for (;;)
 775         {
 776                 if (!((s = fgets(fh))))
 777                         break;
 778
 779                 // catch different sorts of comments
 780                 if(s == "")                    // empty lines
 781                         continue;
 782                 if(substring(s, 0, 1) == "#")  // UNIX style
 783                         continue;
 784                 if(substring(s, 0, 2) == "//") // C++ style
 785                         continue;
 786                 if(substring(s, 0, 1) == "_")  // q3map style
 787                         continue;
 788                 if(s == "{")
 789                 {
 790                         if(testing_map)
 791                                 return false; // edge case? already in a bracketed section!
 792                         testing_map = true;
 793                         continue;
 794                 }
 795                 if(s == "}" || s == " }") // check for a space (common practice in kool maps)
 796                 {
 797                         if(!testing_map)
 798                                 return false; // no starting bracket! let the mapinfo generation system handle it
 799                         testing_map = false;
 800                         if(dosave)
 801                         {
 802                                 if(stored_Map_description != "")
 803                                         MapInfo_Map_description = stored_Map_description;
 804                                 if(stored_Map_title != "")
 805                                         MapInfo_Map_title = stored_Map_title;
 806                                 FOREACH(Gametypes, it.m_flags & stored_supportedGametypes,
 807                                 {
 808                                         _MapInfo_Map_ApplyGametype ("", pGametypeToSet, it, true);
 809                                 });
 810                                 return true; // no need to continue through the file, we have our map!
 811                         }
 812                         else
 813                         {
 814                                 // discard any gathered locals, we're not using the correct map!
 815                                 stored_Map_description = "";
 816                                 stored_Map_title = "";
 817                                 stored_supportedGametypes = 0;
 818                                 continue;
 819                         }
 820                 }
 821
 822                 s = strreplace("\t", " ", s);
 823
 824                 float p = strstrofs(s, "//", 0);
 825                 if(p >= 0)
 826                         s = substring(s, 0, p);
 827
 828                 t = car(s); s = cdr(s);
 829                 //   remove trailing spaces
 830                 while(substring(s, -1, 1) == " ")
 831                         s = substring(s, 0, -2);
 832                 //   remove leading spaces
 833                 while(substring(s, 0, 1) == " ")
 834                         s = substring(s, 1, -1);
 835                 // limited support of ""
 836                 //   remove trailing and leading " of s
 837                 if(substring(s, 0, 1) == "\"")
 838                 {
 839                         if(substring(s, -1, 1) == "\"")
 840                                 s = substring(s, 1, -2);
 841                 }
 842                 if(t == "longname")
 843                 {
 844                         // in .defi files, this is the description, whereas in .arena files, this is generally the title
 845                         if(isdefi)
 846                                 stored_Map_description = s;
 847                         else
 848                                 stored_Map_title = s;
 849                 }
 850                 else if(t == "author")
 851                         MapInfo_Map_author = s;
 852                 else if(t == "type")
 853                 {
 854                         // if there is a valid gametype in this .arena file, include it in the menu
 855                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 856                         // type in quake 3 holds all the supported gametypes, so we must loop through all of them
 857                         FOREACH_WORD(s, true,
 858                         {
 859                                 Gametype f = MapInfo_Type_FromString(it);
 860                                 if(f)
 861                                         stored_supportedGametypes |= f.m_flags;
 862                         });
 863                 }
 864                 else if(t == "style" && isdefi)
 865                 {
 866                         // we have a defrag map on our hands, add CTS!
 867                         // TODO: styles
 868                         stored_supportedGametypes |= MAPINFO_TYPE_CTS.m_flags;
 869                 }
 870                 else if(t == "map")
 871                 {
 872                         if(strtolower(s) == strtolower(pFilename))
 873                                 dosave = true; // yay, found our map!
 874                 }
 875                 // TODO: fraglimit
 876         }
 877
 878         // didn't find a closing bracket, uh oh!
 879         // nothing has been saved anyway, let's abort and use generated mapinfo
 880         if(testing_map)
 881                 return false;
 882         return true;
 883 }
 884
 885 #if defined(CSQC) || defined(MENUQC)
 886 string(string filename) whichpack = #503;
 887 #endif
 888 string _MapInfo_FindArenaFile(string pFilename, string extension)
 889 {
 890         string base_pack = whichpack(strcat("maps/", pFilename, ".bsp"));
 891         string fallback = strcat("scripts/", pFilename, extension);
 892         if(base_pack == "") // this map isn't packaged!
 893                 return fallback;
 894
 895         int glob = search_begin(strcat("scripts/*", extension), true, true);
 896         if(glob < 0)
 897                 return fallback;
 898         int n = search_getsize(glob);
 899         for(int j = 0; j < n; ++j)
 900         {
 901                 string file = search_getfilename(glob, j);
 902                 if(whichpack(file) != base_pack)
 903                         continue; // not in the same pk3!
 904
 905                 int fh = fopen(file, FILE_READ);
 906                 if(fh < 0)
 907                         continue; // how?
 908                 for(string s; (s = fgets(fh)); )
 909                 {
 910                         int offset = strstrofs(s, "map", 0);
 911                         if(offset >= 0)
 912                         {
 913                                 if(strstrofs(strtolower(s), strcat("\"", strtolower(pFilename), "\""), offset) >= 0) // quake 3 is case insensitive
 914                                 {
 915                                         fclose(fh);
 916                                         search_end(glob);
 917                                         return file; // FOUND IT!
 918                                 }
 919                         }
 920                 }
 921                 fclose(fh);
 922         }
 923
 924         search_end(glob);
 925         return fallback; // if we get here, a valid .arena file could not be found
 926 }
 927
 928 // load info about a map by name into the MapInfo_Map_* globals
 929 float MapInfo_Get_ByName_NoFallbacks(string pFilename, int pAllowGenerate, Gametype pGametypeToSet)
 930 {
 931         string fn;
 932         string s, t;
 933         float fh;
 934         int f, i;
 935         float r, n;
 936         string acl;
 937
 938         acl = MAPINFO_SETTEMP_ACL_USER;
 939
 940         if(strstrofs(pFilename, "/", 0) >= 0)
 941         {
 942                 LOG_WARN("Invalid character in map name, ignored");
 943                 return 0;
 944         }
 945
 946         if(pGametypeToSet == NULL)
 947                 if(MapInfo_Cache_Retrieve(pFilename))
 948                         return 1;
 949
 950         r = 1;
 951
 952         MapInfo_Map_bspname = pFilename;
 953
 954         // default all generic fields so they have "good" values in case something fails
 955         fn = strcat("maps/", pFilename, ".mapinfo");
 956         fh = fopen(fn, FILE_READ);
 957         if(fh < 0)
 958         {
 959                 bool isdefi = false;
 960                 // try for a .arena or .defi file if no .mapinfo exists
 961                 fn = _MapInfo_FindArenaFile(pFilename, ".arena");
 962                 fh = fopen(fn, FILE_READ);
 963                 if(fh < 0)
 964                 {
 965                         isdefi = true;
 966                         fn = _MapInfo_FindArenaFile(pFilename, ".defi");
 967                         fh = fopen(fn, FILE_READ);
 968                 }
 969                 if(fh >= 0)
 970                 {
 971                         _MapInfo_Map_Reset();
 972                         if(_MapInfo_ParseArena(fh, pFilename, pGametypeToSet, isdefi))
 973                                 goto mapinfo_handled; // skip generation
 974                 }
 975
 976                 fn = strcat("maps/autogenerated/", pFilename, ".mapinfo");
 977                 fh = fopen(fn, FILE_READ);
 978                 if(fh < 0)
 979                 {
 980                         if(!pAllowGenerate)
 981                                 return 0;
 982                         _MapInfo_Map_Reset();
 983                         r = _MapInfo_Generate(pFilename);
 984                         if(!r)
 985                                 return 0;
 986                         fh = fopen(fn, FILE_WRITE);
 987                         fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
 988                         fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
 989                         fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
 990                         if(_MapInfo_Map_worldspawn_music != "")
 991                         {
 992                                 if(
 993                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".wav"
 994                                         ||
 995                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".ogg"
 996                                 )
 997                                         fputs(fh, strcat("cdtrack ", substring(_MapInfo_Map_worldspawn_music, 0, strlen(_MapInfo_Map_worldspawn_music) - 4), "\n"));
 998                                 else
 999                                         fputs(fh, strcat("cdtrack ", _MapInfo_Map_worldspawn_music, "\n"));
1000                         }
1001                         else
1002                         {
1003                                 n = tokenize_console(cvar_string("g_cdtracks_remaplist"));
1004                                 s = strcat(" ", cvar_string("g_cdtracks_dontusebydefault"), " ");
1005                                 for (;;)
1006                                 {
1007                                         i = floor(random() * n);
1008                                         if(strstrofs(s, strcat(" ", argv(i), " "), 0) < 0)
1009                                                 break;
1010                                 }
1011                                 fputs(fh, strcat("cdtrack ", ftos(i + 1), "\n"));
1012                         }
1013                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)
1014                                 fputs(fh, "has weapons\n");
1015                         else
1016                                 fputs(fh, "// uncomment this if you added weapon pickups: has weapons\n");
1017                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_TURRETS)
1018                                 fputs(fh, "has turrets\n");
1019                         else
1020                                 fputs(fh, "// uncomment this if you added turrets: has turrets\n");
1021                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_VEHICLES)
1022                                 fputs(fh, "has vehicles\n");
1023                         else
1024                                 fputs(fh, "// uncomment this if you added vehicles: has vehicles\n");
1025                         if(MapInfo_Map_flags & MAPINFO_FLAG_FRUSTRATING)
1026                                 fputs(fh, "frustrating\n");
1027
1028                         FOREACH(Gametypes, MapInfo_Map_supportedGametypes & it.m_flags, {
1029                                 fputs(fh, sprintf("gametype %s // defaults: %s\n", MapInfo_Type_ToString(it), _MapInfo_GetDefaultEx(it)));
1030                         });
1031
1032                         fputs(fh, "// optional: fog density red green blue alpha mindist maxdist\n");
1033                         fputs(fh, "// optional: settemp_for_type (all|gametypename) cvarname value\n");
1034                         fputs(fh, "// optional: clientsettemp_for_type (all|gametypename) cvarname value\n");
1035                         fputs(fh, "// optional: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
1036                         fputs(fh, "// optional: hidden\n");
1037
1038                         fclose(fh);
1039                         r = 2;
1040                         // return r;
1041                         fh = fopen(fn, FILE_READ);
1042                         if(fh < 0)
1043                                 error("... but I just wrote it!");
1044                 }
1045
1046                 if(WARN_COND)
1047                         LOG_WARN("autogenerated mapinfo file ", fn, " has been loaded; please edit that file and move it to maps/", pFilename, ".mapinfo");
1048         }
1049
1050         _MapInfo_Map_Reset();
1051         for (;;)
1052         {
1053                 if (!((s = fgets(fh))))
1054                         break;
1055
1056                 // catch different sorts of comments
1057                 if(s == "")                    // empty lines
1058                         continue;
1059                 if(substring(s, 0, 1) == "#")  // UNIX style
1060                         continue;
1061                 if(substring(s, 0, 2) == "//") // C++ style
1062                         continue;
1063                 if(substring(s, 0, 1) == "_")  // q3map style
1064                         continue;
1065
1066                 float p = strstrofs(s, "//", 0);
1067                 if(p >= 0)
1068                         s = substring(s, 0, p);
1069
1070                 t = car(s); s = cdr(s);
1071                 if(t == "title")
1072                         MapInfo_Map_title = s;
1073                 else if(t == "description")
1074                         MapInfo_Map_description = s;
1075                 else if(t == "author")
1076                         MapInfo_Map_author = s;
1077                 else if(t == "has")
1078                 {
1079                         t = car(s); // s = cdr(s);
1080                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
1081                         else if(t == "turrets") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
1082                         else if(t == "vehicles") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
1083                         else if(t == "monsters") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_MONSTERS;
1084                         else if(t == "new_toys") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
1085                         else if(WARN_COND)
1086                                 LOG_WARN("Map ", pFilename, " supports unknown feature ", t, ", ignored");
1087                 }
1088                 else if(t == "hidden")
1089                 {
1090                         MapInfo_Map_flags |= MAPINFO_FLAG_HIDDEN;
1091                 }
1092                 else if(t == "forbidden")
1093                 {
1094                         MapInfo_Map_flags |= MAPINFO_FLAG_FORBIDDEN;
1095                 }
1096                 else if(t == "frustrating")
1097                 {
1098                         MapInfo_Map_flags |= MAPINFO_FLAG_FRUSTRATING;
1099                 }
1100                 else if(t == "noautomaplist")
1101                 {
1102                         MapInfo_Map_flags |= MAPINFO_FLAG_NOAUTOMAPLIST;
1103                 }
1104                 else if(t == "gameversion_min")
1105                 {
1106                         if (cvar("gameversion") < stof(s))
1107                                 MapInfo_Map_flags |= MAPINFO_FLAG_NOAUTOMAPLIST;
1108                 }
1109                 else if(t == "type")
1110                 {
1111                         t = car(s); s = cdr(s);
1112                         Gametype f = MapInfo_Type_FromString(t);
1113                         //if(WARN_COND)
1114                                 //LOG_WARN("Map ", pFilename, " contains the legacy 'type' keyword which is deprecated and will be removed in the future. Please migrate the mapinfo file to 'gametype'.");
1115                         if(f)
1116                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f, true);
1117                         else if(WARN_COND)
1118                                 LOG_DEBUG("Map ", pFilename, " supports unknown game type ", t, ", ignored");
1119                 }
1120                 else if(t == "gametype")
1121                 {
1122                         t = car(s); s = cdr(s);
1123                         Gametype f = MapInfo_Type_FromString(t);
1124                         if(f)
1125                                 _MapInfo_Map_ApplyGametypeEx (s, pGametypeToSet, f);
1126                         else if(WARN_COND)
1127                                 LOG_DEBUG("Map ", pFilename, " supports unknown game type ", t, ", ignored");
1128                 }
1129                 else if(t == "size")
1130                 {
1131                         float a, b, c, d, e;
1132                         t = car(s); s = cdr(s); a = stof(t);
1133                         t = car(s); s = cdr(s); b = stof(t);
1134                         t = car(s); s = cdr(s); c = stof(t);
1135                         t = car(s); s = cdr(s); d = stof(t);
1136                         t = car(s); s = cdr(s); e = stof(t);
1137                         if(s == "")
1138                         {
1139                                 if(WARN_COND)
1140                                         LOG_WARN("Map ", pFilename, " contains an incorrect size line (not enough params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z");
1141                         }
1142                         else
1143                         {
1144                                 t = car(s); s = cdr(s); f = stof(t);
1145                                 if(s != "")
1146                                 {
1147                                         if(WARN_COND)
1148                                                 LOG_WARN("Map ", pFilename, " contains an incorrect size line (too many params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z");
1149                                 }
1150                                 else
1151                                 {
1152                                         if(a >= d || b >= e || c >= f)
1153                                         {
1154                                                 if(WARN_COND)
1155                                                         LOG_WARN("Map ", pFilename, " contains an incorrect size line, mins have to be < maxs");
1156                                         }
1157                                         else
1158                                         {
1159                                                 MapInfo_Map_mins.x = a;
1160                                                 MapInfo_Map_mins.y = b;
1161                                                 MapInfo_Map_mins.z = c;
1162                                                 MapInfo_Map_maxs.x = d;
1163                                                 MapInfo_Map_maxs.y = e;
1164                                                 MapInfo_Map_maxs.z = f;
1165                                         }
1166                                 }
1167                         }
1168                 }
1169                 else if(t == "settemp_for_type")
1170                 {
1171                         t = car(s); s = cdr(s);
1172                         bool all = t == "all";
1173                         Gametype f = NULL;
1174                         if(all || (f = MapInfo_Type_FromString(t)))
1175                         {
1176                                 if((all ? MAPINFO_TYPE_ALL : f.m_flags) & pGametypeToSet.m_flags)
1177                                 {
1178                                         _MapInfo_Parse_Settemp(pFilename, acl, 0, s, 1);
1179                                 }
1180                         }
1181                         else
1182                         {
1183                                 LOG_DEBUG("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored");
1184                         }
1185                 }
1186                 else if(t == "clientsettemp_for_type")
1187                 {
1188                         t = car(s); s = cdr(s);
1189                         bool all = t == "all";
1190                         Gametype f = NULL;
1191                         if(all || (f = MapInfo_Type_FromString(t)))
1192                         {
1193                                 if((all ? MAPINFO_TYPE_ALL : f.m_flags) & pGametypeToSet.m_flags)
1194                                 {
1195                                         _MapInfo_Parse_Settemp(pFilename, acl, 1, s, 1);
1196                                 }
1197                         }
1198                         else
1199                         {
1200                                 LOG_DEBUG("Map ", pFilename, " has a client setting for unknown game type ", t, ", ignored");
1201                         }
1202                 }
1203                 else if(t == "fog")
1204                 {
1205                         if (!cvar_value_issafe(s))
1206                         {
1207                                 if(WARN_COND)
1208                                         LOG_WARN("Map ", pFilename, " contains a potentially harmful fog setting, ignored");
1209                         }
1210                         else
1211                                 MapInfo_Map_fog = s;
1212                 }
1213                 else if(t == "cdtrack")
1214                 {
1215                         t = car(s); s = cdr(s);
1216                         // We do this only if pGametypeToSet even though this
1217                         // content is theoretically game type independent,
1218                         // because MapInfo_Map_clientstuff contains otherwise
1219                         // game type dependent stuff. That way this value stays
1220                         // empty when not setting a game type to not set any
1221                         // false expectations.
1222                         if(pGametypeToSet)
1223                         {
1224                                 if (!cvar_value_issafe(t))
1225                                 {
1226                                         if(WARN_COND)
1227                                                 LOG_WARN("Map ", pFilename, " contains a potentially harmful cdtrack, ignored");
1228                                 }
1229                                 else
1230                                         MapInfo_Map_clientstuff = strcat(
1231                                                 MapInfo_Map_clientstuff, "cd loop \"", t, "\"\n"
1232                                         );
1233                         }
1234                 }
1235                 else if(WARN_COND)
1236                         LOG_WARN("Map ", pFilename, " provides unknown info item ", t, ", ignored");
1237         }
1238         LABEL(mapinfo_handled)
1239         fclose(fh);
1240
1241         if(MapInfo_Map_title == "<TITLE>")
1242                 MapInfo_Map_titlestring = MapInfo_Map_bspname;
1243         else if(MapInfo_isRedundant(MapInfo_Map_bspname, MapInfo_Map_title))
1244                 MapInfo_Map_titlestring = MapInfo_Map_title;
1245         else
1246                 MapInfo_Map_titlestring = sprintf("%s: %s", MapInfo_Map_bspname, MapInfo_Map_title);
1247
1248         MapInfo_Cache_Store();
1249         if(MapInfo_Map_supportedGametypes != 0)
1250                 return r;
1251         if (WARN_COND)
1252                 LOG_WARN("Map ", pFilename, " supports no game types, ignored");
1253         return 0;
1254 }
1255 int MapInfo_Get_ByName(string pFilename, float pAllowGenerate, Gametype pGametypeToSet)
1256 {
1257         int r = MapInfo_Get_ByName_NoFallbacks(pFilename, pAllowGenerate, pGametypeToSet);
1258
1259         FOREACH(Gametypes, it.m_isForcedSupported(it), _MapInfo_Map_ApplyGametypeEx("", pGametypeToSet, it));
1260
1261         if(pGametypeToSet)
1262         {
1263                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet.m_flags))
1264                 {
1265                         error("Can't select the requested game type. This should never happen as the caller should prevent it!\n");
1266                         //_MapInfo_Map_ApplyGametypeEx("", pGametypeToSet, MAPINFO_TYPE_DEATHMATCH);
1267                         //return;
1268                 }
1269         }
1270
1271         return r;
1272 }
1273
1274 float MapInfo_FindName(string s)
1275 {
1276         // if there is exactly one map of prefix s, return it
1277         // if not, return the null string
1278         // note that DP sorts glob results... so I can use a binary search
1279         float l, r, m, cmp;
1280         l = 0;
1281         r = MapInfo_count;
1282         // invariants: r is behind s, l-1 is equal or before
1283         while(l != r)
1284         {
1285                 m = floor((l + r) / 2);
1286                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
1287                 cmp = strcasecmp(MapInfo_FindName_match, s);
1288                 if(cmp == 0)
1289                         return m; // found and good
1290                 if(cmp < 0)
1291                         l = m + 1; // l-1 is before s
1292                 else
1293                         r = m; // behind s
1294         }
1295         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
1296         MapInfo_FindName_firstResult = l;
1297         // r == l, so: l is behind s, l-1 is before
1298         // SO: if there is any, l is the one with the right prefix
1299         //     and l+1 may be one too
1300         if(l == MapInfo_count)
1301         {
1302                 MapInfo_FindName_match = string_null;
1303                 MapInfo_FindName_firstResult = -1;
1304                 return -1; // no MapInfo_FindName_match, behind last item
1305         }
1306         if(!startsWithNocase(MapInfo_FindName_match, s))
1307         {
1308                 MapInfo_FindName_match = string_null;
1309                 MapInfo_FindName_firstResult = -1;
1310                 return -1; // wrong prefix
1311         }
1312         if(l == MapInfo_count - 1)
1313                 return l; // last one, nothing can follow => unique
1314         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
1315         {
1316                 MapInfo_FindName_match = string_null;
1317                 return -1; // ambigous MapInfo_FindName_match
1318         }
1319         return l;
1320 }
1321
1322 string MapInfo_FixName(string s)
1323 {
1324         MapInfo_FindName(s);
1325         return MapInfo_FindName_match;
1326 }
1327
1328 int MapInfo_CurrentFeatures()
1329 {
1330         int req = 0;
1331     // TODO: find a better way to check if weapons are required on the map
1332         if(!(cvar("g_instagib") || cvar("g_overkill") || cvar("g_nix") || cvar("g_weaponarena") || !cvar("g_pickup_items")
1333                 || cvar("g_race") || cvar("g_cts") || cvar("g_nexball") || cvar("g_ca") || cvar("g_freezetag") || cvar("g_lms")))
1334                 req |= MAPINFO_FEATURE_WEAPONS;
1335         return req;
1336 }
1337
1338 Gametype MapInfo_CurrentGametype()
1339 {
1340         Gametype prev = REGISTRY_GET(Gametypes, cvar("gamecfg"));
1341         FOREACH(Gametypes, cvar(it.netname) && it != prev, return it);
1342         return prev ? prev : MAPINFO_TYPE_DEATHMATCH;
1343 }
1344
1345 float _MapInfo_CheckMap(string s, bool gametype_only) // returns 0 if the map can't be played with the current settings, 1 otherwise
1346 {
1347         if(!MapInfo_Get_ByName(s, 1, NULL))
1348                 return 0;
1349         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype().m_flags) == 0)
1350                 return 0;
1351         if (gametype_only)
1352                 return 1;
1353         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
1354                 return 0;
1355         return 1;
1356 }
1357
1358 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1359 {
1360         float r;
1361         r = _MapInfo_CheckMap(s, false);
1362         MapInfo_ClearTemps();
1363         return r;
1364 }
1365
1366 void MapInfo_SwitchGameType(Gametype t)
1367 {
1368         FOREACH(Gametypes, true, cvar_set(it.netname, (it == t) ? "1" : "0"));
1369 }
1370
1371 void MapInfo_LoadMap(string s, float reinit)
1372 {
1373         MapInfo_Map_supportedGametypes = 0;
1374         // we shouldn't need this, as LoadMapSettings already fixes the gametype
1375         //if(!MapInfo_CheckMap(s))
1376         //{
1377         //      print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
1378         //      MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH.m_flags);
1379         //}
1380
1381         LOG_INFO("Switching to map ", s);
1382
1383         cvar_settemp_restore();
1384         if(reinit)
1385                 localcmd(strcat("\nmap ", s, "\n"));
1386         else
1387                 localcmd(strcat("\nchangelevel ", s, "\n"));
1388 }
1389
1390 string MapInfo_ListAllowedMaps(Gametype type, float pRequiredFlags, float pForbiddenFlags)
1391 {
1392         string out;
1393
1394         // to make absolutely sure:
1395         MapInfo_Enumerate();
1396         MapInfo_FilterGametype(type, MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1397
1398         out = "";
1399         for(float i = 0; i < MapInfo_count; ++i)
1400                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1401         return substring(out, 1, strlen(out) - 1);
1402 }
1403
1404 string MapInfo_ListAllAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1405 {
1406         string out;
1407
1408         // to make absolutely sure:
1409         MapInfo_Enumerate();
1410         _MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, pRequiredFlags, pForbiddenFlags, 0);
1411
1412         out = "";
1413         for(float i = 0; i < MapInfo_count; ++i)
1414                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1415
1416         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1417
1418         return substring(out, 1, strlen(out) - 1);
1419 }
1420
1421 void MapInfo_LoadMapSettings_SaveGameType(Gametype t)
1422 {
1423         MapInfo_SwitchGameType(t);
1424         cvar_set("gamecfg", ftos(t.m_id));
1425         MapInfo_LoadedGametype = t;
1426 }
1427
1428 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
1429 {
1430         Gametype t = MapInfo_CurrentGametype();
1431         MapInfo_LoadMapSettings_SaveGameType(t);
1432
1433         if(!_MapInfo_CheckMap(s, true)) // with underscore, it keeps temps
1434         {
1435                 if(cvar("g_mapinfo_allow_unsupported_modes_and_let_stuff_break"))
1436                 {
1437                         LOG_SEVERE("can't play the selected map in the given game mode. Working with only the override settings.");
1438                         _MapInfo_Map_ApplyGametypeEx("", t, t);
1439                         return; // do not call Get_ByName!
1440                 }
1441
1442                 if(MapInfo_Map_supportedGametypes == 0)
1443                 {
1444                         LOG_SEVERE("Mapinfo system is not functional at all. Assuming deathmatch.");
1445                         MapInfo_Map_supportedGametypes = MAPINFO_TYPE_DEATHMATCH.m_flags;
1446                         MapInfo_LoadMapSettings_SaveGameType(MAPINFO_TYPE_DEATHMATCH);
1447                         _MapInfo_Map_ApplyGametypeEx("", MAPINFO_TYPE_DEATHMATCH, MAPINFO_TYPE_DEATHMATCH);
1448                         return; // do not call Get_ByName!
1449                 }
1450
1451                 int _t = 1;
1452                 while(!(MapInfo_Map_supportedGametypes & 1))
1453                 {
1454                         _t <<= 1;
1455                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes >> 1);
1456                 }
1457                 Gametype t_prev = t;
1458                 FOREACH(Gametypes, it.m_flags == _t, { t = it; break; });
1459
1460                 // t is now a supported mode!
1461                 LOG_WARNF("can't play the selected map in the given game mode (%s). Falling back to a supported mode (%s).", t_prev.mdl, t.mdl);
1462                 MapInfo_LoadMapSettings_SaveGameType(t);
1463         }
1464         if(!_MapInfo_CheckMap(s, false)) { // with underscore, it keeps temps
1465                 LOG_WARNF("the selected map lacks features required by current settings; playing anyway.");
1466         }
1467         MapInfo_Get_ByName(s, 1, t);
1468 }
1469
1470 void MapInfo_ClearTemps()
1471 {
1472         MapInfo_Map_bspname = string_null;
1473         MapInfo_Map_title = string_null;
1474         MapInfo_Map_titlestring = string_null;
1475         MapInfo_Map_description = string_null;
1476         MapInfo_Map_author = string_null;
1477         MapInfo_Map_clientstuff = string_null;
1478         MapInfo_Map_supportedGametypes = 0;
1479         MapInfo_Map_supportedFeatures = 0;
1480 }
1481
1482 void MapInfo_Shutdown()
1483 {
1484         MapInfo_ClearTemps();
1485         MapInfo_Filter_Free();
1486         MapInfo_Cache_Destroy();
1487         if(_MapInfo_globopen)
1488         {
1489                 search_end(_MapInfo_globhandle);
1490                 _MapInfo_globhandle = -1;
1491                 _MapInfo_globopen = false;
1492         }
1493 }
1494
1495 int MapInfo_ForbiddenFlags()
1496 {
1497         int f = MAPINFO_FLAG_FORBIDDEN;
1498
1499 #ifdef GAMEQC
1500         if (!cvar("g_maplist_allow_hidden"))
1501 #endif
1502                 f |= MAPINFO_FLAG_HIDDEN;
1503
1504         if (!cvar("g_maplist_allow_frustrating"))
1505                 f |= MAPINFO_FLAG_FRUSTRATING;
1506
1507         return f;
1508 }
1509
1510 int MapInfo_RequiredFlags()
1511 {
1512         int f = 0;
1513
1514         if(cvar("g_maplist_allow_frustrating") > 1)
1515                 f |= MAPINFO_FLAG_FRUSTRATING;
1516
1517         return f;
1518 }