qcsrc/common/gamemodes/gamemode/onslaught/sv_onslaught.qc

   1 #include "sv_onslaught.qh"
   2 #include "sv_controlpoint.qh"
   3 #include "sv_generator.qh"
   4
   5 bool g_onslaught;
   6
   7 float autocvar_g_onslaught_teleport_wait;
   8 bool autocvar_g_onslaught_spawn_at_controlpoints;
   9 bool autocvar_g_onslaught_spawn_at_generator;
  10 float autocvar_g_onslaught_cp_proxydecap;
  11 float autocvar_g_onslaught_cp_proxydecap_distance = 512;
  12 float autocvar_g_onslaught_cp_proxydecap_dps = 100;
  13 float autocvar_g_onslaught_spawn_at_controlpoints_chance = 0.5;
  14 float autocvar_g_onslaught_spawn_at_controlpoints_random;
  15 float autocvar_g_onslaught_spawn_at_generator_chance;
  16 float autocvar_g_onslaught_spawn_at_generator_random;
  17 float autocvar_g_onslaught_cp_buildhealth;
  18 float autocvar_g_onslaught_cp_buildtime;
  19 float autocvar_g_onslaught_cp_health;
  20 float autocvar_g_onslaught_cp_regen;
  21 float autocvar_g_onslaught_gen_health;
  22 float autocvar_g_onslaught_shield_force = 100;
  23 float autocvar_g_onslaught_allow_vehicle_touch;
  24 float autocvar_g_onslaught_round_timelimit;
  25 float autocvar_g_onslaught_warmup;
  26 float autocvar_g_onslaught_teleport_radius;
  27 float autocvar_g_onslaught_spawn_choose;
  28 float autocvar_g_onslaught_click_radius;
  29
  30 void FixSize(entity e);
  31 entity cam;
  32
  33 // =======================
  34 // CaptureShield Functions
  35 // =======================
  36
  37 bool clientcamera_send(entity this, entity to, int sf)
  38 {
  39         WriteHeader(MSG_ENTITY, ENT_ONSCAMERA);
  40
  41         WriteVector(MSG_ENTITY, this.origin);
  42
  43         WriteAngle(MSG_ENTITY, this.angles_x);
  44         WriteAngle(MSG_ENTITY, this.angles_y);
  45         WriteAngle(MSG_ENTITY, this.angles_z);
  46
  47         return true;
  48 }
  49
  50 bool ons_CaptureShield_Customize(entity this, entity client)
  51 {
  52         entity e = WaypointSprite_getviewentity(client);
  53
  54         if(!this.enemy.isshielded && (ons_ControlPoint_Attackable(this.enemy, e.team) > 0 || this.enemy.classname != "onslaught_controlpoint")) { return false; }
  55         if(SAME_TEAM(this, e)) { return false; }
  56
  57         return true;
  58 }
  59
  60 void ons_CaptureShield_Touch(entity this, entity toucher)
  61 {
  62         if(!this.enemy.isshielded && (ons_ControlPoint_Attackable(this.enemy, toucher.team) > 0 || this.enemy.classname != "onslaught_controlpoint")) { return; }
  63         if(!IS_PLAYER(toucher)) { return; }
  64         if(SAME_TEAM(toucher, this)) { return; }
  65
  66         vector mymid = (this.absmin + this.absmax) * 0.5;
  67         vector theirmid = (toucher.absmin + toucher.absmax) * 0.5;
  68
  69         Damage(toucher, this, this, 0, DEATH_HURTTRIGGER.m_id, DMG_NOWEP, mymid, normalize(theirmid - mymid) * ons_captureshield_force);
  70
  71         if(IS_REAL_CLIENT(toucher))
  72         {
  73                 play2(toucher, SND(ONS_DAMAGEBLOCKEDBYSHIELD));
  74
  75                 if(this.enemy.classname == "onslaught_generator")
  76                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_GENERATOR_SHIELDED);
  77                 else
  78                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_CONTROLPOINT_SHIELDED);
  79         }
  80 }
  81
  82 void ons_CaptureShield_Reset(entity this)
  83 {
  84         this.colormap = this.enemy.colormap;
  85         this.team = this.enemy.team;
  86 }
  87
  88 void ons_CaptureShield_Spawn(entity generator, bool is_generator)
  89 {
  90         entity shield = new(ons_captureshield);
  91         IL_PUSH(g_onsshields, shield);
  92
  93         shield.enemy = generator;
  94         shield.team = generator.team;
  95         shield.colormap = generator.colormap;
  96         shield.reset = ons_CaptureShield_Reset;
  97         settouch(shield, ons_CaptureShield_Touch);
  98         setcefc(shield, ons_CaptureShield_Customize);
  99         shield.effects = EF_ADDITIVE;
 100         set_movetype(shield, MOVETYPE_NOCLIP);
 101         shield.solid = SOLID_TRIGGER;
 102         shield.avelocity = '7 0 11';
 103         shield.scale = 1;
 104         shield.model = ((is_generator) ? "models/onslaught/generator_shield.md3" : "models/onslaught/controlpoint_shield.md3");
 105
 106         precache_model(shield.model);
 107         setorigin(shield, generator.origin);
 108         _setmodel(shield, shield.model);
 109         setsize(shield, shield.scale * shield.mins, shield.scale * shield.maxs);
 110 }
 111
 112
 113 // ==========
 114 // Junk Pile
 115 // ==========
 116
 117 void setmodel_fixsize(entity e, Model m)
 118 {
 119         setmodel(e, m);
 120         FixSize(e);
 121 }
 122
 123 void onslaught_updatelinks()
 124 {
 125         entity l;
 126         // first check if the game has ended
 127         LOG_DEBUG("--- updatelinks ---");
 128         // mark generators as being shielded and networked
 129         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
 130         {
 131                 if (l.iscaptured)
 132                         LOG_DEBUG(etos(l), " (generator) belongs to team ", ftos(l.team));
 133                 else
 134                         LOG_DEBUG(etos(l), " (generator) is destroyed");
 135                 l.islinked = l.iscaptured;
 136                 l.isshielded = l.iscaptured;
 137                 l.sprite.SendFlags |= 16;
 138         }
 139         // mark points as shielded and not networked
 140         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
 141         {
 142                 l.islinked = false;
 143                 l.isshielded = true;
 144                 l.aregensneighbor = 0;
 145                 l.arecpsneighbor = 0;
 146                 LOG_DEBUG(etos(l), " (point) belongs to team ", ftos(l.team));
 147                 l.sprite.SendFlags |= 16;
 148         }
 149         // flow power outward from the generators through the network
 150         bool stop = false;
 151         while (!stop)
 152         {
 153                 stop = true;
 154                 for(l = ons_worldlinklist; l; l = l.ons_worldlinknext)
 155                 {
 156                         // if both points are captured by the same team, and only one of
 157                         // them is powered, mark the other one as powered as well
 158                         if (l.enemy.iscaptured && l.goalentity.iscaptured)
 159                                 if (l.enemy.islinked != l.goalentity.islinked)
 160                                         if(SAME_TEAM(l.enemy, l.goalentity))
 161                                         {
 162                                                 if (!l.goalentity.islinked)
 163                                                 {
 164                                                         stop = false;
 165                                                         l.goalentity.islinked = true;
 166                                                         LOG_DEBUG(etos(l), " (link) is marking ", etos(l.goalentity), " (point) because its team matches ", etos(l.enemy), " (point)");
 167                                                 }
 168                                                 else if (!l.enemy.islinked)
 169                                                 {
 170                                                         stop = false;
 171                                                         l.enemy.islinked = true;
 172                                                         LOG_DEBUG(etos(l), " (link) is marking ", etos(l.enemy), " (point) because its team matches ", etos(l.goalentity), " (point)");
 173                                                 }
 174                                         }
 175                 }
 176         }
 177         // now that we know which points are powered we can mark their neighbors
 178         // as unshielded if team differs
 179         for(l = ons_worldlinklist; l; l = l.ons_worldlinknext)
 180         {
 181                 if (l.goalentity.islinked)
 182                 {
 183                         if(DIFF_TEAM(l.goalentity, l.enemy))
 184                         {
 185                                 LOG_DEBUG(etos(l), " (link) is unshielding ", etos(l.enemy), " (point) because its team does not match ", etos(l.goalentity), " (point)");
 186                                 l.enemy.isshielded = false;
 187                         }
 188                         if(l.goalentity.classname == "onslaught_generator")
 189                                 l.enemy.aregensneighbor |= BIT(l.goalentity.team);
 190                         else
 191                                 l.enemy.arecpsneighbor |= BIT(l.goalentity.team);
 192                 }
 193                 if (l.enemy.islinked)
 194                 {
 195                         if(DIFF_TEAM(l.goalentity, l.enemy))
 196                         {
 197                                 LOG_DEBUG(etos(l), " (link) is unshielding ", etos(l.goalentity), " (point) because its team does not match ", etos(l.enemy), " (point)");
 198                                 l.goalentity.isshielded = false;
 199                         }
 200                         if(l.enemy.classname == "onslaught_generator")
 201                                 l.goalentity.aregensneighbor |= BIT(l.enemy.team);
 202                         else
 203                                 l.goalentity.arecpsneighbor |= BIT(l.enemy.team);
 204                 }
 205         }
 206         // now update the generators
 207         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
 208         {
 209                 if (l.isshielded)
 210                 {
 211                         LOG_DEBUG(etos(l), " (generator) is shielded");
 212                         l.takedamage = DAMAGE_NO;
 213                         if(l.bot_attack)
 214                                 IL_REMOVE(g_bot_targets, l);
 215                         l.bot_attack = false;
 216                 }
 217                 else
 218                 {
 219                         LOG_DEBUG(etos(l), " (generator) is not shielded");
 220                         l.takedamage = DAMAGE_AIM;
 221                         if(!l.bot_attack)
 222                                 IL_PUSH(g_bot_targets, l);
 223                         l.bot_attack = true;
 224                 }
 225
 226                 ons_Generator_UpdateSprite(l);
 227         }
 228         // now update the takedamage and alpha variables on control point icons
 229         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
 230         {
 231                 if (l.isshielded)
 232                 {
 233                         LOG_DEBUG(etos(l), " (point) is shielded");
 234                         if (l.goalentity)
 235                         {
 236                                 l.goalentity.takedamage = DAMAGE_NO;
 237                                 if(l.goalentity.bot_attack)
 238                                         IL_REMOVE(g_bot_targets, l.goalentity);
 239                                 l.goalentity.bot_attack = false;
 240                         }
 241                 }
 242                 else
 243                 {
 244                         LOG_DEBUG(etos(l), " (point) is not shielded");
 245                         if (l.goalentity)
 246                         {
 247                                 l.goalentity.takedamage = DAMAGE_AIM;
 248                                 if(!l.goalentity.bot_attack)
 249                                         IL_PUSH(g_bot_targets, l.goalentity);
 250                                 l.goalentity.bot_attack = true;
 251                         }
 252                 }
 253                 ons_ControlPoint_UpdateSprite(l);
 254         }
 255         IL_EACH(g_onsshields, true,
 256         {
 257                 it.team = it.enemy.team;
 258                 it.colormap = it.enemy.colormap;
 259         });
 260 }
 261
 262
 263 // ===================
 264 // Main Link Functions
 265 // ===================
 266
 267 bool ons_Link_Send(entity this, entity to, int sendflags)
 268 {
 269         WriteHeader(MSG_ENTITY, ENT_CLIENT_RADARLINK);
 270         WriteByte(MSG_ENTITY, sendflags);
 271         if(sendflags & 1)
 272         {
 273                 WriteVector(MSG_ENTITY, this.goalentity.origin);
 274         }
 275         if(sendflags & 2)
 276         {
 277                 WriteVector(MSG_ENTITY, this.enemy.origin);
 278         }
 279         if(sendflags & 4)
 280         {
 281                 WriteByte(MSG_ENTITY, this.clientcolors); // which is goalentity's color + enemy's color * 16
 282         }
 283         return true;
 284 }
 285
 286 void ons_Link_CheckUpdate(entity this)
 287 {
 288         // TODO check if the two sides have moved (currently they won't move anyway)
 289         float cc = 0, cc1 = 0, cc2 = 0;
 290
 291         if(this.goalentity.islinked || this.goalentity.iscaptured) { cc1 = (this.goalentity.team - 1) * 0x01; }
 292         if(this.enemy.islinked || this.enemy.iscaptured) { cc2 = (this.enemy.team - 1) * 0x10; }
 293
 294         cc = cc1 + cc2;
 295
 296         if(cc != this.clientcolors)
 297         {
 298                 this.clientcolors = cc;
 299                 this.SendFlags |= 4;
 300         }
 301
 302         this.nextthink = time;
 303 }
 304
 305 void ons_DelayedLinkSetup(entity this)
 306 {
 307         this.goalentity = find(NULL, targetname, this.target);
 308         this.enemy = find(NULL, targetname, this.target2);
 309         if(!this.goalentity) { objerror(this, "can not find target\n"); }
 310         if(!this.enemy) { objerror(this, "can not find target2\n"); }
 311
 312         LOG_DEBUG(etos(this.goalentity), " linked with ", etos(this.enemy));
 313         this.SendFlags |= 3;
 314         setthink(this, ons_Link_CheckUpdate);
 315         this.nextthink = time;
 316 }
 317
 318
 319 // =============================
 320 // Main Control Point Functions
 321 // =============================
 322
 323 int ons_ControlPoint_CanBeLinked(entity cp, int teamnumber)
 324 {
 325         if(cp.aregensneighbor & BIT(teamnumber)) return 2;
 326         if(cp.arecpsneighbor & BIT(teamnumber)) return 1;
 327
 328         return 0;
 329 }
 330
 331 int ons_ControlPoint_Attackable(entity cp, int teamnumber)
 332         // -2: SAME TEAM, attackable by enemy!
 333         // -1: SAME TEAM!
 334         // 0: off limits
 335         // 1: attack it
 336         // 2: touch it
 337         // 3: attack it (HIGH PRIO)
 338         // 4: touch it (HIGH PRIO)
 339 {
 340         int a;
 341
 342         if(cp.isshielded)
 343         {
 344                 return 0;
 345         }
 346         else if(cp.goalentity)
 347         {
 348                 // if there's already an icon built, nothing happens
 349                 if(cp.team == teamnumber)
 350                 {
 351                         a = ons_ControlPoint_CanBeLinked(cp, teamnumber);
 352                         if(a) // attackable by enemy?
 353                                 return -2; // EMERGENCY!
 354                         return -1;
 355                 }
 356                 // we know it can be linked, so no need to check
 357                 // but...
 358                 a = ons_ControlPoint_CanBeLinked(cp, teamnumber);
 359                 if(a == 2) // near our generator?
 360                         return 3; // EMERGENCY!
 361                 return 1;
 362         }
 363         else
 364         {
 365                 // free point
 366                 if(ons_ControlPoint_CanBeLinked(cp, teamnumber))
 367                 {
 368                         a = ons_ControlPoint_CanBeLinked(cp, teamnumber); // why was this here NUM_TEAM_1 + NUM_TEAM_2 - t
 369                         if(a == 2)
 370                                 return 4; // GET THIS ONE NOW!
 371                         else
 372                                 return 2; // TOUCH ME
 373                 }
 374         }
 375         return 0;
 376 }
 377
 378 void ons_ControlPoint_Icon_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
 379 {
 380         if(damage <= 0) { return; }
 381
 382         if (this.owner.isshielded)
 383         {
 384                 // this is protected by a shield, so ignore the damage
 385                 if (time > this.pain_finished)
 386                         if (IS_PLAYER(attacker))
 387                         {
 388                                 play2(attacker, SND(ONS_DAMAGEBLOCKEDBYSHIELD));
 389                                 this.pain_finished = time + 1;
 390                                 attacker.typehitsound += 1; // play both sounds (shield is way too quiet)
 391                         }
 392
 393                 return;
 394         }
 395
 396         if(IS_PLAYER(attacker))
 397         if(time - ons_notification_time[this.team] > 10)
 398         {
 399                 play2team(this.team, SND(ONS_CONTROLPOINT_UNDERATTACK));
 400                 ons_notification_time[this.team] = time;
 401         }
 402
 403         this.health = this.health - damage;
 404         if(this.owner.iscaptured)
 405                 WaypointSprite_UpdateHealth(this.owner.sprite, this.health);
 406         else
 407                 WaypointSprite_UpdateBuildFinished(this.owner.sprite, time + (this.max_health - this.health) / (this.count / ONS_CP_THINKRATE));
 408         this.pain_finished = time + 1;
 409         // particles on every hit
 410         pointparticles(EFFECT_SPARKS, hitloc, force*-1, 1);
 411         //sound on every hit
 412         if (random() < 0.5)
 413                 sound(this, CH_TRIGGER, SND_ONS_HIT1, VOL_BASE+0.3, ATTEN_NORM);
 414         else
 415                 sound(this, CH_TRIGGER, SND_ONS_HIT2, VOL_BASE+0.3, ATTEN_NORM);
 416
 417         if (this.health < 0)
 418         {
 419                 sound(this, CH_TRIGGER, SND_GRENADE_IMPACT, VOL_BASE, ATTEN_NORM);
 420                 pointparticles(EFFECT_ROCKET_EXPLODE, this.origin, '0 0 0', 1);
 421                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_ONSLAUGHT_CPDESTROYED), this.owner.message, attacker.netname);
 422
 423                 GameRules_scoring_add(attacker, ONS_TAKES, 1);
 424                 GameRules_scoring_add(attacker, SCORE, 10);
 425
 426                 this.owner.goalentity = NULL;
 427                 this.owner.islinked = false;
 428                 this.owner.iscaptured = false;
 429                 this.owner.team = 0;
 430                 this.owner.colormap = 1024;
 431
 432                 WaypointSprite_UpdateMaxHealth(this.owner.sprite, 0);
 433
 434                 onslaught_updatelinks();
 435
 436                 // Use targets now (somebody make sure this is in the right place..)
 437                 SUB_UseTargets(this.owner, this, NULL);
 438
 439                 this.owner.waslinked = this.owner.islinked;
 440                 if(this.owner.model != "models/onslaught/controlpoint_pad.md3")
 441                         setmodel_fixsize(this.owner, MDL_ONS_CP_PAD1);
 442                 //setsize(this, '-32 -32 0', '32 32 8');
 443
 444                 delete(this);
 445         }
 446
 447         this.SendFlags |= CPSF_STATUS;
 448 }
 449
 450 void ons_ControlPoint_Icon_Think(entity this)
 451 {
 452         this.nextthink = time + ONS_CP_THINKRATE;
 453
 454         if(autocvar_g_onslaught_cp_proxydecap)
 455         {
 456                 int _enemy_count = 0;
 457                 int _friendly_count = 0;
 458
 459                 FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it), {
 460                         if(vdist(it.origin - this.origin, <, autocvar_g_onslaught_cp_proxydecap_distance))
 461                         {
 462                                 if(SAME_TEAM(it, this))
 463                                         ++_friendly_count;
 464                                 else
 465                                         ++_enemy_count;
 466                         }
 467                 });
 468
 469                 _friendly_count = _friendly_count * (autocvar_g_onslaught_cp_proxydecap_dps * ONS_CP_THINKRATE);
 470                 _enemy_count = _enemy_count * (autocvar_g_onslaught_cp_proxydecap_dps * ONS_CP_THINKRATE);
 471
 472                 this.health = bound(0, this.health + (_friendly_count - _enemy_count), this.max_health);
 473                 this.SendFlags |= CPSF_STATUS;
 474                 if(this.health <= 0)
 475                 {
 476                         ons_ControlPoint_Icon_Damage(this, this, this, 1, 0, DMG_NOWEP, this.origin, '0 0 0');
 477                         return;
 478                 }
 479         }
 480
 481         if (time > this.pain_finished + 5)
 482         {
 483                 if(this.health < this.max_health)
 484                 {
 485                         this.health = this.health + this.count;
 486                         if (this.health >= this.max_health)
 487                                 this.health = this.max_health;
 488                         WaypointSprite_UpdateHealth(this.owner.sprite, this.health);
 489                 }
 490         }
 491
 492         if(this.owner.islinked != this.owner.waslinked)
 493         {
 494                 // unteam the spawnpoint if needed
 495                 int t = this.owner.team;
 496                 if(!this.owner.islinked)
 497                         this.owner.team = 0;
 498
 499                 SUB_UseTargets(this.owner, this, NULL);
 500
 501                 this.owner.team = t;
 502
 503                 this.owner.waslinked = this.owner.islinked;
 504         }
 505
 506         // damaged fx
 507         if(random() < 0.6 - this.health / this.max_health)
 508         {
 509                 Send_Effect(EFFECT_ELECTRIC_SPARKS, this.origin + randompos('-10 -10 -20', '10 10 20'), '0 0 0', 1);
 510
 511                 if(random() > 0.8)
 512                         sound(this, CH_PAIN, SND_ONS_SPARK1, VOL_BASE, ATTEN_NORM);
 513                 else if (random() > 0.5)
 514                         sound(this, CH_PAIN, SND_ONS_SPARK2, VOL_BASE, ATTEN_NORM);
 515         }
 516 }
 517
 518 void ons_ControlPoint_Icon_BuildThink(entity this)
 519 {
 520         int a;
 521
 522         this.nextthink = time + ONS_CP_THINKRATE;
 523
 524         // only do this if there is power
 525         a = ons_ControlPoint_CanBeLinked(this.owner, this.owner.team);
 526         if(!a)
 527                 return;
 528
 529         this.health = this.health + this.count;
 530
 531         this.SendFlags |= CPSF_STATUS;
 532
 533         if (this.health >= this.max_health)
 534         {
 535                 this.health = this.max_health;
 536                 this.count = autocvar_g_onslaught_cp_regen * ONS_CP_THINKRATE; // slow repair rate from now on
 537                 setthink(this, ons_ControlPoint_Icon_Think);
 538                 sound(this, CH_TRIGGER, SND_ONS_CONTROLPOINT_BUILT, VOL_BASE, ATTEN_NORM);
 539                 this.owner.iscaptured = true;
 540                 this.solid = SOLID_BBOX;
 541
 542                 Send_Effect(EFFECT_CAP(this.owner.team), this.owner.origin, '0 0 0', 1);
 543
 544                 WaypointSprite_UpdateMaxHealth(this.owner.sprite, this.max_health);
 545                 WaypointSprite_UpdateHealth(this.owner.sprite, this.health);
 546
 547                 if(IS_PLAYER(this.owner.ons_toucher))
 548                 {
 549                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ONSLAUGHT_CAPTURE, this.owner.ons_toucher.netname, this.owner.message);
 550                         Send_Notification(NOTIF_ALL_EXCEPT, this.owner.ons_toucher, MSG_CENTER, APP_TEAM_NUM(this.owner.ons_toucher.team, CENTER_ONS_CAPTURE_TEAM), this.owner.message);
 551                         Send_Notification(NOTIF_ONE, this.owner.ons_toucher, MSG_CENTER, CENTER_ONS_CAPTURE, this.owner.message);
 552                         GameRules_scoring_add(this.owner.ons_toucher, ONS_CAPS, 1);
 553                         GameRules_scoring_add_team(this.owner.ons_toucher, SCORE, 10);
 554                 }
 555
 556                 this.owner.ons_toucher = NULL;
 557
 558                 onslaught_updatelinks();
 559
 560                 // Use targets now (somebody make sure this is in the right place..)
 561                 SUB_UseTargets(this.owner, this, NULL);
 562
 563                 this.SendFlags |= CPSF_SETUP;
 564         }
 565         if(this.owner.model != MDL_ONS_CP_PAD2.model_str())
 566                 setmodel_fixsize(this.owner, MDL_ONS_CP_PAD2);
 567
 568         if(random() < 0.9 - this.health / this.max_health)
 569                 Send_Effect(EFFECT_RAGE, this.origin + 10 * randomvec(), '0 0 -1', 1);
 570 }
 571
 572 void onslaught_controlpoint_icon_link(entity e, void(entity this) spawnproc);
 573
 574 void ons_ControlPoint_Icon_Spawn(entity cp, entity player)
 575 {
 576         entity e = new(onslaught_controlpoint_icon);
 577
 578         setsize(e, CPICON_MIN, CPICON_MAX);
 579         setorigin(e, cp.origin + CPICON_OFFSET);
 580
 581         e.owner = cp;
 582         e.max_health = autocvar_g_onslaught_cp_health;
 583         e.health = autocvar_g_onslaught_cp_buildhealth;
 584         e.solid = SOLID_NOT;
 585         e.takedamage = DAMAGE_AIM;
 586         e.bot_attack = true;
 587         IL_PUSH(g_bot_targets, e);
 588         e.event_damage = ons_ControlPoint_Icon_Damage;
 589         e.team = player.team;
 590         e.colormap = 1024 + (e.team - 1) * 17;
 591         e.count = (e.max_health - e.health) * ONS_CP_THINKRATE / autocvar_g_onslaught_cp_buildtime; // how long it takes to build
 592
 593         sound(e, CH_TRIGGER, SND_ONS_CONTROLPOINT_BUILD, VOL_BASE, ATTEN_NORM);
 594
 595         cp.goalentity = e;
 596         cp.team = e.team;
 597         cp.colormap = e.colormap;
 598
 599         Send_Effect(EFFECT_FLAG_TOUCH(player.team), e.origin, '0 0 0', 1);
 600
 601         WaypointSprite_UpdateBuildFinished(cp.sprite, time + (e.max_health - e.health) / (e.count / ONS_CP_THINKRATE));
 602         WaypointSprite_UpdateRule(cp.sprite,cp.team,SPRITERULE_TEAMPLAY);
 603         cp.sprite.SendFlags |= 16;
 604
 605         onslaught_controlpoint_icon_link(e, ons_ControlPoint_Icon_BuildThink);
 606 }
 607
 608 entity ons_ControlPoint_Waypoint(entity e)
 609 {
 610         if(e.team)
 611         {
 612                 int a = ons_ControlPoint_Attackable(e, e.team);
 613
 614                 if(a == -2) { return WP_OnsCPDefend; } // defend now
 615                 if(a == -1 || a == 1 || a == 2) { return WP_OnsCP; } // touch
 616                 if(a == 3 || a == 4) { return WP_OnsCPAttack; } // attack
 617         }
 618         else
 619                 return WP_OnsCP;
 620
 621         return WP_Null;
 622 }
 623
 624 void ons_ControlPoint_UpdateSprite(entity e)
 625 {
 626         entity s1 = ons_ControlPoint_Waypoint(e);
 627         WaypointSprite_UpdateSprites(e.sprite, s1, s1, s1);
 628
 629         bool sh;
 630         sh = !(ons_ControlPoint_CanBeLinked(e, NUM_TEAM_1) || ons_ControlPoint_CanBeLinked(e, NUM_TEAM_2) || ons_ControlPoint_CanBeLinked(e, NUM_TEAM_3) || ons_ControlPoint_CanBeLinked(e, NUM_TEAM_4));
 631
 632         if(e.lastteam != e.team + 2 || e.lastshielded != sh || e.iscaptured != e.lastcaptured)
 633         {
 634                 if(e.iscaptured) // don't mess up build bars!
 635                 {
 636                         if(sh)
 637                         {
 638                                 WaypointSprite_UpdateMaxHealth(e.sprite, 0);
 639                         }
 640                         else
 641                         {
 642                                 WaypointSprite_UpdateMaxHealth(e.sprite, e.goalentity.max_health);
 643                                 WaypointSprite_UpdateHealth(e.sprite, e.goalentity.health);
 644                         }
 645                 }
 646                 if(e.lastshielded)
 647                 {
 648                         if(e.team)
 649                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, 0.5 * colormapPaletteColor(e.team - 1, false));
 650                         else
 651                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, '0.5 0.5 0.5');
 652                 }
 653                 else
 654                 {
 655                         if(e.team)
 656                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, colormapPaletteColor(e.team - 1, false));
 657                         else
 658                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, '0.75 0.75 0.75');
 659                 }
 660                 WaypointSprite_Ping(e.sprite);
 661
 662                 e.lastteam = e.team + 2;
 663                 e.lastshielded = sh;
 664                 e.lastcaptured = e.iscaptured;
 665         }
 666 }
 667
 668 void ons_ControlPoint_Touch(entity this, entity toucher)
 669 {
 670         int attackable;
 671
 672         if(IS_VEHICLE(toucher) && toucher.owner)
 673         if(autocvar_g_onslaught_allow_vehicle_touch)
 674                 toucher = toucher.owner;
 675         else
 676                 return;
 677
 678         if(!IS_PLAYER(toucher)) { return; }
 679         if(STAT(FROZEN, toucher)) { return; }
 680         if(IS_DEAD(toucher)) { return; }
 681
 682         if ( SAME_TEAM(this,toucher) )
 683         if ( this.iscaptured )
 684         {
 685                 if(time <= toucher.teleport_antispam)
 686                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_TELEPORT_ANTISPAM, rint(toucher.teleport_antispam - time));
 687                 else
 688                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_TELEPORT);
 689         }
 690
 691         attackable = ons_ControlPoint_Attackable(this, toucher.team);
 692         if(attackable != 2 && attackable != 4)
 693                 return;
 694         // we've verified that this player has a legitimate claim to this point,
 695         // so start building the captured point icon (which only captures this
 696         // point if it successfully builds without being destroyed first)
 697         ons_ControlPoint_Icon_Spawn(this, toucher);
 698
 699         this.ons_toucher = toucher;
 700
 701         onslaught_updatelinks();
 702 }
 703
 704 void ons_ControlPoint_Think(entity this)
 705 {
 706         this.nextthink = time + ONS_CP_THINKRATE;
 707         CSQCMODEL_AUTOUPDATE(this);
 708 }
 709
 710 void ons_ControlPoint_Reset(entity this)
 711 {
 712         if(this.goalentity)
 713                 delete(this.goalentity);
 714
 715         this.goalentity = NULL;
 716         this.team = 0;
 717         this.colormap = 1024;
 718         this.iscaptured = false;
 719         this.islinked = false;
 720         this.isshielded = true;
 721         setthink(this, ons_ControlPoint_Think);
 722         this.ons_toucher = NULL;
 723         this.nextthink = time + ONS_CP_THINKRATE;
 724         setmodel_fixsize(this, MDL_ONS_CP_PAD1);
 725
 726         WaypointSprite_UpdateMaxHealth(this.sprite, 0);
 727         WaypointSprite_UpdateRule(this.sprite,this.team,SPRITERULE_TEAMPLAY);
 728
 729         onslaught_updatelinks();
 730
 731         SUB_UseTargets(this, this, NULL); // to reset the structures, playerspawns etc.
 732
 733         CSQCMODEL_AUTOUPDATE(this);
 734 }
 735
 736 void ons_DelayedControlPoint_Setup(entity this)
 737 {
 738         onslaught_updatelinks();
 739
 740         // captureshield setup
 741         ons_CaptureShield_Spawn(this, false);
 742
 743         CSQCMODEL_AUTOINIT(this);
 744 }
 745
 746 void ons_ControlPoint_Setup(entity cp)
 747 {
 748         // main setup
 749         cp.ons_worldcpnext = ons_worldcplist; // link control point into ons_worldcplist
 750         ons_worldcplist = cp;
 751
 752         cp.netname = "Control point";
 753         cp.team = 0;
 754         cp.solid = SOLID_BBOX;
 755         set_movetype(cp, MOVETYPE_NONE);
 756         settouch(cp, ons_ControlPoint_Touch);
 757         setthink(cp, ons_ControlPoint_Think);
 758         cp.nextthink = time + ONS_CP_THINKRATE;
 759         cp.reset = ons_ControlPoint_Reset;
 760         cp.colormap = 1024;
 761         cp.iscaptured = false;
 762         cp.islinked = false;
 763         cp.isshielded = true;
 764
 765         if(cp.message == "") { cp.message = "a"; }
 766
 767         // appearence
 768         setmodel_fixsize(cp, MDL_ONS_CP_PAD1);
 769
 770         // control point placement
 771         if((cp.spawnflags & 1) || cp.noalign) // don't drop to floor, just stay at fixed location
 772         {
 773                 cp.noalign = true;
 774                 set_movetype(cp, MOVETYPE_NONE);
 775         }
 776         else // drop to floor, automatically find a platform and set that as spawn origin
 777         {
 778                 setorigin(cp, cp.origin + '0 0 20');
 779                 cp.noalign = false;
 780                 droptofloor(cp);
 781                 set_movetype(cp, MOVETYPE_TOSS);
 782         }
 783
 784         // waypointsprites
 785         WaypointSprite_SpawnFixed(WP_Null, cp.origin + CPGEN_WAYPOINT_OFFSET, cp, sprite, RADARICON_NONE);
 786         WaypointSprite_UpdateRule(cp.sprite, cp.team, SPRITERULE_TEAMPLAY);
 787
 788         InitializeEntity(cp, ons_DelayedControlPoint_Setup, INITPRIO_SETLOCATION);
 789 }
 790
 791
 792 // =========================
 793 // Main Generator Functions
 794 // =========================
 795
 796 entity ons_Generator_Waypoint(entity e)
 797 {
 798         if (e.isshielded)
 799                 return WP_OnsGenShielded;
 800         return WP_OnsGen;
 801 }
 802
 803 void ons_Generator_UpdateSprite(entity e)
 804 {
 805         entity s1 = ons_Generator_Waypoint(e);
 806         WaypointSprite_UpdateSprites(e.sprite, s1, s1, s1);
 807
 808         if(e.lastteam != e.team + 2 || e.lastshielded != e.isshielded)
 809         {
 810                 e.lastteam = e.team + 2;
 811                 e.lastshielded = e.isshielded;
 812                 if(e.lastshielded)
 813                 {
 814                         if(e.team)
 815                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, 0.5 * colormapPaletteColor(e.team - 1, false));
 816                         else
 817                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, '0.5 0.5 0.5');
 818                 }
 819                 else
 820                 {
 821                         if(e.team)
 822                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, colormapPaletteColor(e.team - 1, false));
 823                         else
 824                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, '0.75 0.75 0.75');
 825                 }
 826                 WaypointSprite_Ping(e.sprite);
 827         }
 828 }
 829
 830 void ons_camSetup(entity this)
 831 {
 832         vector dir;
 833         vector ang = '0 0 0';
 834         vector best_ang = '0 0 0';
 835         float best_trace_fraction = 0;
 836         while(ang.y < 360)
 837         {
 838                 dir = vec2(cos(ang.y * DEG2RAD), sin(ang.y * DEG2RAD));
 839                 dir *= 500;
 840                 traceline(this.origin, this.origin - dir, MOVE_WORLDONLY, this);
 841                 if(trace_fraction > best_trace_fraction)
 842                 {
 843                         best_trace_fraction = trace_fraction;
 844                         best_ang = ang;
 845                         if(trace_fraction == 1)
 846                                 break;
 847                 }
 848                 ang.y += 90;
 849                 if(ang.y == 360)
 850                         ang.y = 45;
 851         }
 852         cam.origin = this.origin;
 853         setorigin(cam, cam.origin);
 854         cam.angles = best_ang;
 855         Net_LinkEntity(cam, false, 0, clientcamera_send);
 856
 857         FOREACH_CLIENT(true, it.clientcamera = cam;);
 858
 859         WriteByte(MSG_ALL, SVC_SETVIEWANGLES);
 860         WriteAngle(MSG_ALL, cam.angles_x);
 861         WriteAngle(MSG_ALL, cam.angles_y);
 862         WriteAngle(MSG_ALL, cam.angles_z);
 863 }
 864
 865 void ons_GeneratorDamage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
 866 {
 867         if(damage <= 0) return;
 868         if(warmup_stage || game_stopped) return;
 869         if(!round_handler_IsRoundStarted()) return;
 870
 871         if (attacker != this)
 872         {
 873                 if (this.isshielded)
 874                 {
 875                         // generator is protected by a shield, so ignore the damage
 876                         if (time > this.pain_finished)
 877                                 if (IS_PLAYER(attacker))
 878                                 {
 879                                         play2(attacker, SND(ONS_DAMAGEBLOCKEDBYSHIELD));
 880                                         attacker.typehitsound += 1;
 881                                         this.pain_finished = time + 1;
 882                                 }
 883                         return;
 884                 }
 885                 if (time > this.pain_finished)
 886                 {
 887                         this.pain_finished = time + 10;
 888                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && SAME_TEAM(it, this), Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_GENERATOR_UNDERATTACK));
 889                         play2team(this.team, SND(ONS_GENERATOR_UNDERATTACK));
 890                 }
 891         }
 892         this.health = this.health - damage;
 893         WaypointSprite_UpdateHealth(this.sprite, this.health);
 894         // choose an animation frame based on health
 895         this.frame = 10 * bound(0, (1 - this.health / this.max_health), 1);
 896         // see if the generator is still functional, or dying
 897         if (this.health > 0)
 898         {
 899                 this.lasthealth = this.health;
 900         }
 901         else
 902         {
 903                 if (attacker == this)
 904                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_ONSLAUGHT_GENDESTROYED_OVERTIME));
 905                 else
 906                 {
 907                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_ONSLAUGHT_GENDESTROYED));
 908                         GameRules_scoring_add(attacker, SCORE, 100);
 909                 }
 910                 this.iscaptured = false;
 911                 this.islinked = false;
 912                 this.isshielded = false;
 913                 this.takedamage = DAMAGE_NO; // can't be hurt anymore
 914                 this.event_damage = func_null; // won't do anything if hurt
 915                 this.count = 0; // reset counter
 916                 setthink(this, func_null);
 917                 this.nextthink = 0;
 918                 //this.think(); // do the first explosion now
 919
 920                 WaypointSprite_UpdateMaxHealth(this.sprite, 0);
 921                 WaypointSprite_Ping(this.sprite);
 922                 //WaypointSprite_Kill(this.sprite); // can't do this yet, code too poor
 923
 924                 onslaught_updatelinks();
 925
 926                 ons_camSetup(this);
 927         }
 928
 929         // Throw some flaming gibs on damage, more damage = more chance for gib
 930         if(random() < damage/220)
 931         {
 932                 sound(this, CH_TRIGGER, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 933         }
 934         else
 935         {
 936                 // particles on every hit
 937                 Send_Effect(EFFECT_SPARKS, hitloc, force * -1, 1);
 938
 939                 //sound on every hit
 940                 if (random() < 0.5)
 941                         sound(this, CH_TRIGGER, SND_ONS_HIT1, VOL_BASE, ATTEN_NORM);
 942                 else
 943                         sound(this, CH_TRIGGER, SND_ONS_HIT2, VOL_BASE, ATTEN_NORM);
 944         }
 945
 946         this.SendFlags |= GSF_STATUS;
 947 }
 948
 949 void ons_GeneratorThink(entity this)
 950 {
 951         this.nextthink = time + GEN_THINKRATE;
 952
 953         if (game_stopped || this.isshielded || time < this.wait)
 954                 return;
 955
 956         this.wait = time + 5;
 957         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it),
 958         {
 959                 if (SAME_TEAM(it, this))
 960                 {
 961                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_ONS_NOTSHIELDED_TEAM);
 962                         soundto(MSG_ONE, it, CHAN_AUTO, SND(KH_ALARM), VOL_BASE, ATTEN_NONE); // FIXME: unique sound?
 963                 }
 964                 else
 965                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, APP_TEAM_NUM(this.team, CENTER_ONS_NOTSHIELDED));
 966         });
 967 }
 968
 969 void ons_GeneratorReset(entity this)
 970 {
 971         this.team = this.team_saved;
 972         this.lasthealth = this.max_health = this.health = autocvar_g_onslaught_gen_health;
 973         this.takedamage = DAMAGE_AIM;
 974         this.bot_attack = true;
 975         if(!IL_CONTAINS(g_bot_targets, this))
 976                 IL_PUSH(g_bot_targets, this);
 977         this.iscaptured = true;
 978         this.islinked = true;
 979         this.isshielded = true;
 980         this.event_damage = ons_GeneratorDamage;
 981         setthink(this, ons_GeneratorThink);
 982         this.nextthink = time + GEN_THINKRATE;
 983
 984         Net_LinkEntity(this, false, 0, generator_send);
 985
 986         this.SendFlags = GSF_SETUP; // just incase
 987         this.SendFlags |= GSF_STATUS;
 988
 989         WaypointSprite_UpdateMaxHealth(this.sprite, this.max_health);
 990         WaypointSprite_UpdateHealth(this.sprite, this.health);
 991         WaypointSprite_UpdateRule(this.sprite,this.team,SPRITERULE_TEAMPLAY);
 992
 993         onslaught_updatelinks();
 994 }
 995
 996 void ons_DelayedGeneratorSetup(entity this)
 997 {
 998         // bot waypoints
 999         waypoint_spawnforitem_force(this, this.origin);
1000         this.nearestwaypointtimeout = 0; // activate waypointing again
1001         this.bot_basewaypoint = this.nearestwaypoint;
1002
1003         // captureshield setup
1004         ons_CaptureShield_Spawn(this, true);
1005
1006         onslaught_updatelinks();
1007
1008         Net_LinkEntity(this, false, 0, generator_send);
1009 }
1010
1011
1012 void onslaught_generator_touch(entity this, entity toucher)
1013 {
1014         if ( IS_PLAYER(toucher) )
1015         if ( SAME_TEAM(this,toucher) )
1016         if ( this.iscaptured )
1017         {
1018                 Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_TELEPORT);
1019         }
1020 }
1021
1022 void ons_GeneratorSetup(entity gen) // called when spawning a generator entity on the map as a spawnfunc
1023 {
1024         // declarations
1025         int teamnumber = gen.team;
1026
1027         // main setup
1028         gen.ons_worldgeneratornext = ons_worldgeneratorlist; // link generator into ons_worldgeneratorlist
1029         ons_worldgeneratorlist = gen;
1030
1031         gen.netname = sprintf("%s generator", Team_ColoredFullName(teamnumber));
1032         gen.classname = "onslaught_generator";
1033         gen.solid = SOLID_BBOX;
1034         gen.team_saved = teamnumber;
1035         IL_PUSH(g_saved_team, gen);
1036         set_movetype(gen, MOVETYPE_NONE);
1037         gen.lasthealth = gen.max_health = gen.health = autocvar_g_onslaught_gen_health;
1038         gen.takedamage = DAMAGE_AIM;
1039         gen.bot_attack = true;
1040         IL_PUSH(g_bot_targets, gen);
1041         gen.event_damage = ons_GeneratorDamage;
1042         gen.reset = ons_GeneratorReset;
1043         setthink(gen, ons_GeneratorThink);
1044         gen.nextthink = time + GEN_THINKRATE;
1045         gen.iscaptured = true;
1046         gen.islinked = true;
1047         gen.isshielded = true;
1048         settouch(gen, onslaught_generator_touch);
1049
1050         // appearence
1051         // model handled by CSQC
1052         setsize(gen, GENERATOR_MIN, GENERATOR_MAX);
1053         setorigin(gen, (gen.origin + CPGEN_SPAWN_OFFSET));
1054         gen.colormap = 1024 + (teamnumber - 1) * 17;
1055
1056         // generator placement
1057         droptofloor(gen);
1058
1059         // waypointsprites
1060         WaypointSprite_SpawnFixed(WP_Null, gen.origin + CPGEN_WAYPOINT_OFFSET, gen, sprite, RADARICON_NONE);
1061         WaypointSprite_UpdateRule(gen.sprite, gen.team, SPRITERULE_TEAMPLAY);
1062         WaypointSprite_UpdateMaxHealth(gen.sprite, gen.max_health);
1063         WaypointSprite_UpdateHealth(gen.sprite, gen.health);
1064
1065         InitializeEntity(gen, ons_DelayedGeneratorSetup, INITPRIO_SETLOCATION);
1066 }
1067
1068
1069 // ===============
1070 //  Round Handler
1071 // ===============
1072
1073 int total_generators;
1074 void Onslaught_count_generators()
1075 {
1076         entity e;
1077         total_generators = redowned = blueowned = yellowowned = pinkowned = 0;
1078         for(e = ons_worldgeneratorlist; e; e = e.ons_worldgeneratornext)
1079         {
1080                 ++total_generators;
1081                 redowned += (e.team == NUM_TEAM_1 && e.health > 0);
1082                 blueowned += (e.team == NUM_TEAM_2 && e.health > 0);
1083                 yellowowned += (e.team == NUM_TEAM_3 && e.health > 0);
1084                 pinkowned += (e.team == NUM_TEAM_4 && e.health > 0);
1085         }
1086 }
1087
1088 int Onslaught_GetWinnerTeam()
1089 {
1090         int winner_team = 0;
1091         if(redowned > 0)
1092                 winner_team = NUM_TEAM_1;
1093         if(blueowned > 0)
1094         {
1095                 if(winner_team) return 0;
1096                 winner_team = NUM_TEAM_2;
1097         }
1098         if(yellowowned > 0)
1099         {
1100                 if(winner_team) return 0;
1101                 winner_team = NUM_TEAM_3;
1102         }
1103         if(pinkowned > 0)
1104         {
1105                 if(winner_team) return 0;
1106                 winner_team = NUM_TEAM_4;
1107         }
1108         if(winner_team)
1109                 return winner_team;
1110         return -1; // no generators left?
1111 }
1112
1113 void nades_Clear(entity e);
1114
1115 #define ONS_OWNED_GENERATORS() ((redowned > 0) + (blueowned > 0) + (yellowowned > 0) + (pinkowned > 0))
1116 #define ONS_OWNED_GENERATORS_OK() (ONS_OWNED_GENERATORS() > 1)
1117 bool Onslaught_CheckWinner()
1118 {
1119         if ((autocvar_timelimit && time > game_starttime + autocvar_timelimit * 60) || (round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0))
1120         {
1121                 ons_stalemate = true;
1122
1123                 if (!wpforenemy_announced)
1124                 {
1125                         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_CONTROLPOINT);
1126                         sound(NULL, CH_INFO, SND_ONS_GENERATOR_DECAY, VOL_BASE, ATTEN_NONE);
1127
1128                         wpforenemy_announced = true;
1129                 }
1130
1131                 entity tmp_entity; // temporary entity
1132                 float d;
1133                 for(tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext) if(time >= tmp_entity.ons_overtime_damagedelay)
1134                 {
1135                         // tmp_entity.max_health / 300 gives 5 minutes of overtime.
1136                         // control points reduce the overtime duration.
1137                         d = 1;
1138                         entity e;
1139                         for(e = ons_worldcplist; e; e = e.ons_worldcpnext)
1140                         {
1141                                 if(DIFF_TEAM(e, tmp_entity))
1142                                 if(e.islinked)
1143                                         d = d + 1;
1144                         }
1145
1146                         if(autocvar_g_campaign && autocvar__campaign_testrun)
1147                                 d = d * tmp_entity.max_health;
1148                         else
1149                                 d = d * tmp_entity.max_health / max(30, 60 * autocvar_timelimit_suddendeath);
1150
1151                         Damage(tmp_entity, tmp_entity, tmp_entity, d, DEATH_HURTTRIGGER.m_id, DMG_NOWEP, tmp_entity.origin, '0 0 0');
1152
1153                         tmp_entity.sprite.SendFlags |= 16;
1154
1155                         tmp_entity.ons_overtime_damagedelay = time + 1;
1156                 }
1157         }
1158         else { wpforenemy_announced = false; ons_stalemate = false; }
1159
1160         Onslaught_count_generators();
1161
1162         if(ONS_OWNED_GENERATORS_OK())
1163                 return 0;
1164
1165         int winner_team = Onslaught_GetWinnerTeam();
1166
1167         if(winner_team > 0)
1168         {
1169                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
1170                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_ROUND_TEAM_WIN));
1171                 TeamScore_AddToTeam(winner_team, ST_ONS_CAPS, +1);
1172         }
1173         else if(winner_team == -1)
1174         {
1175                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_TIED);
1176                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_TIED);
1177         }
1178
1179         ons_stalemate = false;
1180
1181         play2all(SND(CTF_CAPTURE(winner_team)));
1182
1183         round_handler_Init(7, autocvar_g_onslaught_warmup, autocvar_g_onslaught_round_timelimit);
1184
1185         FOREACH_CLIENT(IS_PLAYER(it), {
1186                 STAT(ROUNDLOST, it) = true;
1187                 it.player_blocked = true;
1188
1189                 nades_Clear(it);
1190         });
1191
1192         game_stopped = true;
1193         return 1;
1194 }
1195
1196 bool Onslaught_CheckPlayers()
1197 {
1198         return 1;
1199 }
1200
1201 void Onslaught_RoundStart()
1202 {
1203         entity tmp_entity;
1204         FOREACH_CLIENT(IS_PLAYER(it), it.player_blocked = false);
1205
1206         for(tmp_entity = ons_worldcplist; tmp_entity; tmp_entity = tmp_entity.ons_worldcpnext)
1207                 tmp_entity.sprite.SendFlags |= 16;
1208
1209         for(tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext)
1210                 tmp_entity.sprite.SendFlags |= 16;
1211 }
1212
1213
1214 // ================
1215 // Bot player logic
1216 // ================
1217
1218 // NOTE: LEGACY CODE, needs to be re-written!
1219
1220 void havocbot_goalrating_ons_offenseitems(entity this, float ratingscale, vector org, float sradius)
1221 {
1222         bool needarmor = false, needweapons = false;
1223
1224         // Needs armor/health?
1225         if(this.health<100)
1226                 needarmor = true;
1227
1228         // Needs weapons?
1229         int c = 0;
1230         FOREACH(Weapons, it != WEP_Null, {
1231                 if(STAT(WEAPONS, this) & (it.m_wepset))
1232                 if(++c >= 4)
1233                         break;
1234         });
1235
1236         if(c<4)
1237                 needweapons = true;
1238
1239         if(!needweapons && !needarmor)
1240                 return;
1241
1242         LOG_DEBUG(this.netname, " needs weapons ", ftos(needweapons));
1243         LOG_DEBUG(this.netname, " needs armor ", ftos(needarmor));
1244
1245         // See what is around
1246         IL_EACH(g_items, it.bot_pickup,
1247         {
1248                 // gather health and armor only
1249                 if (it.solid)
1250                 if ( ((it.health || it.armorvalue) && needarmor) || (STAT(WEAPONS, it) && needweapons ) )
1251                 if (vdist(it.origin - org, <, sradius))
1252                 {
1253                         int t = it.bot_pickupevalfunc(this, it);
1254                         if (t > 0)
1255                                 navigation_routerating(this, it, t * ratingscale, 500);
1256                 }
1257         });
1258 }
1259
1260 void havocbot_role_ons_setrole(entity this, int role)
1261 {
1262         LOG_DEBUG(this.netname," switched to ");
1263         switch(role)
1264         {
1265                 case HAVOCBOT_ONS_ROLE_DEFENSE:
1266                         LOG_DEBUG("defense");
1267                         this.havocbot_role = havocbot_role_ons_defense;
1268                         this.havocbot_role_flags = HAVOCBOT_ONS_ROLE_DEFENSE;
1269                         this.havocbot_role_timeout = 0;
1270                         break;
1271                 case HAVOCBOT_ONS_ROLE_ASSISTANT:
1272                         LOG_DEBUG("assistant");
1273                         this.havocbot_role = havocbot_role_ons_assistant;
1274                         this.havocbot_role_flags = HAVOCBOT_ONS_ROLE_ASSISTANT;
1275                         this.havocbot_role_timeout = 0;
1276                         break;
1277                 case HAVOCBOT_ONS_ROLE_OFFENSE:
1278                         LOG_DEBUG("offense");
1279                         this.havocbot_role = havocbot_role_ons_offense;
1280                         this.havocbot_role_flags = HAVOCBOT_ONS_ROLE_OFFENSE;
1281                         this.havocbot_role_timeout = 0;
1282                         break;
1283         }
1284         LOG_DEBUG("");
1285 }
1286
1287 void havocbot_goalrating_ons_controlpoints_attack(entity this, float ratingscale)
1288 {
1289         entity cp, cp1, cp2, best, wp;
1290         float radius, bestvalue;
1291         int c;
1292         bool found;
1293
1294         // Filter control points
1295         for(cp2 = ons_worldcplist; cp2; cp2 = cp2.ons_worldcpnext)
1296         {
1297                 cp2.wpcost = c = 0;
1298                 cp2.wpconsidered = false;
1299
1300                 if(cp2.isshielded)
1301                         continue;
1302
1303                 // Ignore owned controlpoints
1304                 if(!((cp2.aregensneighbor & BIT(this.team)) || (cp2.arecpsneighbor & BIT(this.team))))
1305                         continue;
1306
1307                 // Count team mates interested in this control point
1308                 // (easier and cleaner than keeping counters per cp and teams)
1309                 FOREACH_CLIENT(IS_PLAYER(it), {
1310                         if(SAME_TEAM(it, this))
1311                         if(it.havocbot_role_flags & HAVOCBOT_ONS_ROLE_OFFENSE)
1312                         if(it.havocbot_ons_target == cp2)
1313                                 ++c;
1314                 });
1315
1316                 // NOTE: probably decrease the cost of attackable control points
1317                 cp2.wpcost = c;
1318                 cp2.wpconsidered = true;
1319         }
1320
1321         // We'll consider only the best case
1322         bestvalue = 99999999999;
1323         cp = NULL;
1324         for(cp1 = ons_worldcplist; cp1; cp1 = cp1.ons_worldcpnext)
1325         {
1326                 if (!cp1.wpconsidered)
1327                         continue;
1328
1329                 if(cp1.wpcost<bestvalue)
1330                 {
1331                         bestvalue = cp1.wpcost;
1332                         cp = cp1;
1333                         this.havocbot_ons_target = cp1;
1334                 }
1335         }
1336
1337         if (!cp)
1338                 return;
1339
1340         LOG_DEBUG(this.netname, " chose cp ranked ", ftos(bestvalue));
1341
1342         if(cp.goalentity)
1343         {
1344                 // Should be attacked
1345                 // Rate waypoints near it
1346                 found = false;
1347                 best = NULL;
1348                 bestvalue = 99999999999;
1349                 for(radius=0; radius<1000 && !found; radius+=500)
1350                 {
1351                         for(wp=findradius(cp.origin,radius); wp; wp=wp.chain)
1352                         {
1353                                 if(!(wp.wpflags & WAYPOINTFLAG_GENERATED))
1354                                 if(wp.classname=="waypoint")
1355                                 if(checkpvs(wp.origin,cp))
1356                                 {
1357                                         found = true;
1358                                         if(wp.cnt<bestvalue)
1359                                         {
1360                                                 best = wp;
1361                                                 bestvalue = wp.cnt;
1362                                         }
1363                                 }
1364                         }
1365                 }
1366
1367                 if(best)
1368                 {
1369                         navigation_routerating(this, best, ratingscale, 10000);
1370                         best.cnt += 1;
1371
1372                         this.havocbot_attack_time = 0;
1373                         if(checkpvs(this.origin + this.view_ofs, cp))
1374                         if(checkpvs(this.origin + this.view_ofs, best))
1375                                 this.havocbot_attack_time = time + 2;
1376                 }
1377                 else
1378                 {
1379                         navigation_routerating(this, cp, ratingscale, 10000);
1380                 }
1381                 LOG_DEBUG(this.netname, " found an attackable controlpoint at ", vtos(cp.origin));
1382         }
1383         else
1384         {
1385                 // Should be touched
1386                 LOG_DEBUG(this.netname, " found a touchable controlpoint at ", vtos(cp.origin));
1387                 found = false;
1388
1389                 // Look for auto generated waypoint
1390                 if (!bot_waypoints_for_items)
1391                 for (wp = findradius(cp.origin,100); wp; wp = wp.chain)
1392                 {
1393                         if(wp.classname=="waypoint")
1394                         {
1395                                 navigation_routerating(this, wp, ratingscale, 10000);
1396                                 found = true;
1397                         }
1398                 }
1399
1400                 // Nothing found, rate the controlpoint itself
1401                 if (!found)
1402                         navigation_routerating(this, cp, ratingscale, 10000);
1403         }
1404 }
1405
1406 bool havocbot_goalrating_ons_generator_attack(entity this, float ratingscale)
1407 {
1408         entity g, wp, bestwp;
1409         bool found;
1410         int best;
1411
1412         for(g = ons_worldgeneratorlist; g; g = g.ons_worldgeneratornext)
1413         {
1414                 if(SAME_TEAM(g, this) || g.isshielded)
1415                         continue;
1416
1417                 // Should be attacked
1418                 // Rate waypoints near it
1419                 found = false;
1420                 bestwp = NULL;
1421                 best = 99999999999;
1422
1423                 for(wp=findradius(g.origin,400); wp; wp=wp.chain)
1424                 {
1425                         if(wp.classname=="waypoint")
1426                         if(checkpvs(wp.origin,g))
1427                         {
1428                                 found = true;
1429                                 if(wp.cnt<best)
1430                                 {
1431                                         bestwp = wp;
1432                                         best = wp.cnt;
1433                                 }
1434                         }
1435                 }
1436
1437                 if(bestwp)
1438                 {
1439                         LOG_DEBUG("waypoints found around generator");
1440                         navigation_routerating(this, bestwp, ratingscale, 10000);
1441                         bestwp.cnt += 1;
1442
1443                         this.havocbot_attack_time = 0;
1444                         if(checkpvs(this.origin + this.view_ofs, g))
1445                         if(checkpvs(this.origin + this.view_ofs, bestwp))
1446                                 this.havocbot_attack_time = time + 5;
1447
1448                         return true;
1449                 }
1450                 else
1451                 {
1452                         LOG_DEBUG("generator found without waypoints around");
1453                         // if there aren't waypoints near the generator go straight to it
1454                         navigation_routerating(this, g, ratingscale, 10000);
1455                         this.havocbot_attack_time = 0;
1456                         return true;
1457                 }
1458         }
1459         return false;
1460 }
1461
1462 void havocbot_role_ons_offense(entity this)
1463 {
1464         if(IS_DEAD(this))
1465         {
1466                 this.havocbot_attack_time = 0;
1467                 havocbot_ons_reset_role(this);
1468                 return;
1469         }
1470
1471         // Set the role timeout if necessary
1472         if (!this.havocbot_role_timeout)
1473                 this.havocbot_role_timeout = time + 120;
1474
1475         if (time > this.havocbot_role_timeout)
1476         {
1477                 havocbot_ons_reset_role(this);
1478                 return;
1479         }
1480
1481         if(this.havocbot_attack_time>time)
1482                 return;
1483
1484         if (navigation_goalrating_timeout(this))
1485         {
1486                 navigation_goalrating_start(this);
1487                 havocbot_goalrating_enemyplayers(this, 20000, this.origin, 650);
1488                 if(!havocbot_goalrating_ons_generator_attack(this, 20000))
1489                         havocbot_goalrating_ons_controlpoints_attack(this, 20000);
1490                 havocbot_goalrating_ons_offenseitems(this, 10000, this.origin, 10000);
1491                 navigation_goalrating_end(this);
1492
1493                 navigation_goalrating_timeout_set(this);
1494         }
1495 }
1496
1497 void havocbot_role_ons_assistant(entity this)
1498 {
1499         havocbot_ons_reset_role(this);
1500 }
1501
1502 void havocbot_role_ons_defense(entity this)
1503 {
1504         havocbot_ons_reset_role(this);
1505 }
1506
1507 void havocbot_ons_reset_role(entity this)
1508 {
1509         if(IS_DEAD(this))
1510                 return;
1511
1512         this.havocbot_ons_target = NULL;
1513
1514         // TODO: Defend control points or generator if necessary
1515
1516         havocbot_role_ons_setrole(this, HAVOCBOT_ONS_ROLE_OFFENSE);
1517 }
1518
1519
1520 /*
1521  * Find control point or generator owned by the same team self which is nearest to pos
1522  * if max_dist is positive, only control points within this range will be considered
1523  */
1524 entity ons_Nearest_ControlPoint(entity this, vector pos, float max_dist)
1525 {
1526         entity closest_target = NULL;
1527         for(entity cp = ons_worldcplist; cp; cp = cp.ons_worldcpnext)
1528         {
1529                 if(SAME_TEAM(cp, this))
1530                 if(cp.iscaptured)
1531                 if(max_dist <= 0 || vdist(cp.origin - pos, <=, max_dist))
1532                 if(vlen2(cp.origin - pos) <= vlen2(closest_target.origin - pos) || closest_target == NULL)
1533                         closest_target = cp;
1534         }
1535         for(entity gen = ons_worldgeneratorlist; gen; gen = gen.ons_worldgeneratornext)
1536         {
1537                 if(SAME_TEAM(gen, this))
1538                 if(max_dist <= 0 || vdist(gen.origin - pos, <, max_dist))
1539                 if(vlen2(gen.origin - pos) <= vlen2(closest_target.origin - pos) || closest_target == NULL)
1540                         closest_target = gen;
1541         }
1542
1543         return closest_target;
1544 }
1545
1546 /*
1547  * Find control point or generator owned by the same team self which is nearest to pos
1548  * if max_dist is positive, only control points within this range will be considered
1549  * This function only check distances on the XY plane, disregarding Z
1550  */
1551 entity ons_Nearest_ControlPoint_2D(entity this, vector pos, float max_dist)
1552 {
1553         entity closest_target = NULL;
1554         vector delta;
1555         float smallest_distance = 0, distance;
1556
1557         for(entity cp = ons_worldcplist; cp; cp = cp.ons_worldcpnext)
1558         {
1559                 delta = cp.origin - pos;
1560                 delta_z = 0;
1561                 distance = vlen(delta);
1562
1563                 if(SAME_TEAM(cp, this))
1564                 if(cp.iscaptured)
1565                 if(max_dist <= 0 || distance <= max_dist)
1566                 if(closest_target == NULL || distance <= smallest_distance )
1567                 {
1568                         closest_target = cp;
1569                         smallest_distance = distance;
1570                 }
1571         }
1572         for(entity gen = ons_worldgeneratorlist; gen; gen = gen.ons_worldgeneratornext)
1573         {
1574                 delta = gen.origin - pos;
1575                 delta_z = 0;
1576                 distance = vlen(delta);
1577
1578                 if(SAME_TEAM(gen, this))
1579                 if(max_dist <= 0 || distance <= max_dist)
1580                 if(closest_target == NULL || distance <= smallest_distance )
1581                 {
1582                         closest_target = gen;
1583                         smallest_distance = distance;
1584                 }
1585         }
1586
1587         return closest_target;
1588 }
1589 /**
1590  * find the number of control points and generators in the same team as this
1591  */
1592 int ons_Count_SelfControlPoints(entity this)
1593 {
1594         int n = 0;
1595         for(entity cp = ons_worldcplist; cp; cp = cp.ons_worldcpnext)
1596         {
1597                 if(SAME_TEAM(cp, this))
1598                 if(cp.iscaptured)
1599                         n++;
1600         }
1601         for(entity gen = ons_worldgeneratorlist; gen; gen = gen.ons_worldgeneratornext)
1602         {
1603                 if(SAME_TEAM(gen, this))
1604                         n++;
1605         }
1606         return n;
1607 }
1608
1609 /**
1610  * Teleport player to a random position near tele_target
1611  * if tele_effects is true, teleport sound+particles are created
1612  * return false on failure
1613  */
1614 bool ons_Teleport(entity player, entity tele_target, float range, bool tele_effects)
1615 {
1616         if ( !tele_target )
1617                 return false;
1618
1619         int i;
1620         vector loc;
1621         float theta;
1622         // narrow the range for each iteration to increase chances that a spawnpoint
1623         // can be found even if there's little room around the control point
1624         float iteration_scale = 1;
1625         for(i = 0; i < 16; ++i)
1626         {
1627                 iteration_scale -= i / 16;
1628                 theta = random() * 2 * M_PI;
1629                 loc_y = sin(theta);
1630                 loc_x = cos(theta);
1631                 loc_z = 0;
1632                 loc *= random() * range * iteration_scale;
1633
1634                 loc += tele_target.origin + '0 0 128' * iteration_scale;
1635
1636                 tracebox(loc, STAT(PL_MIN, player), STAT(PL_MAX, player), loc, MOVE_NORMAL, player);
1637                 if(trace_fraction == 1.0 && !trace_startsolid)
1638                 {
1639                         traceline(tele_target.origin, loc, MOVE_NOMONSTERS, tele_target); // double check to make sure we're not spawning outside the NULL
1640                         if(trace_fraction == 1.0 && !trace_startsolid)
1641                         {
1642                                 if ( tele_effects )
1643                                 {
1644                                         Send_Effect(EFFECT_TELEPORT, player.origin, '0 0 0', 1);
1645                                         sound (player, CH_TRIGGER, SND_TELEPORT, VOL_BASE, ATTEN_NORM);
1646                                 }
1647                                 setorigin(player, loc);
1648                                 player.angles = '0 1 0' * ( theta * RAD2DEG + 180 );
1649                                 makevectors(player.angles);
1650                                 player.fixangle = true;
1651                                 player.teleport_antispam = time + autocvar_g_onslaught_teleport_wait;
1652
1653                                 if ( tele_effects )
1654                                         Send_Effect(EFFECT_TELEPORT, player.origin + v_forward * 32, '0 0 0', 1);
1655                                 return true;
1656                         }
1657                 }
1658         }
1659
1660         return false;
1661 }
1662
1663 // ==============
1664 // Hook Functions
1665 // ==============
1666
1667 MUTATOR_HOOKFUNCTION(ons, reset_map_global)
1668 {
1669         FOREACH_CLIENT(IS_PLAYER(it), {
1670                 STAT(ROUNDLOST, it) = false;
1671                 it.ons_deathloc = '0 0 0';
1672                 PutClientInServer(it);
1673                 it.clientcamera = it;
1674         });
1675         return false;
1676 }
1677
1678 MUTATOR_HOOKFUNCTION(ons, ClientDisconnect)
1679 {
1680         entity player = M_ARGV(0, entity);
1681
1682         player.ons_deathloc = '0 0 0';
1683 }
1684
1685 MUTATOR_HOOKFUNCTION(ons, MakePlayerObserver)
1686 {
1687         entity player = M_ARGV(0, entity);
1688
1689         player.ons_deathloc = '0 0 0';
1690 }
1691
1692 MUTATOR_HOOKFUNCTION(ons, PlayerSpawn)
1693 {
1694         entity player = M_ARGV(0, entity);
1695
1696         if(!round_handler_IsRoundStarted())
1697         {
1698                 player.player_blocked = true;
1699                 return false;
1700         }
1701
1702         entity l;
1703         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
1704         {
1705                 l.sprite.SendFlags |= 16;
1706         }
1707         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
1708         {
1709                 l.sprite.SendFlags |= 16;
1710         }
1711
1712         if(ons_stalemate) { Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_OVERTIME_CONTROLPOINT); }
1713
1714         if ( autocvar_g_onslaught_spawn_choose )
1715         if ( player.ons_spawn_by )
1716         if ( ons_Teleport(player,player.ons_spawn_by,autocvar_g_onslaught_teleport_radius,false) )
1717         {
1718                 player.ons_spawn_by = NULL;
1719                 return false;
1720         }
1721
1722         if(autocvar_g_onslaught_spawn_at_controlpoints)
1723         if(random() <= autocvar_g_onslaught_spawn_at_controlpoints_chance)
1724         {
1725                 float random_target = autocvar_g_onslaught_spawn_at_controlpoints_random;
1726                 entity tmp_entity, closest_target = NULL;
1727                 vector spawn_loc = player.ons_deathloc;
1728
1729                 // new joining player or round reset, don't bother checking
1730                 if(spawn_loc == '0 0 0') { return false; }
1731
1732                 if(random_target) { RandomSelection_Init(); }
1733
1734                 for(tmp_entity = ons_worldcplist; tmp_entity; tmp_entity = tmp_entity.ons_worldcpnext)
1735                 {
1736                         if(SAME_TEAM(tmp_entity, player))
1737                         if(random_target)
1738                                 RandomSelection_AddEnt(tmp_entity, 1, 1);
1739                         else if(vlen2(tmp_entity.origin - spawn_loc) <= vlen2(closest_target.origin - spawn_loc) || closest_target == NULL)
1740                                 closest_target = tmp_entity;
1741                 }
1742
1743                 if(random_target) { closest_target = RandomSelection_chosen_ent; }
1744
1745                 if(closest_target)
1746                 {
1747                         float i;
1748                         vector loc;
1749                         float iteration_scale = 1;
1750                         for(i = 0; i < 10; ++i)
1751                         {
1752                                 iteration_scale -= i / 10;
1753                                 loc = closest_target.origin + '0 0 96' * iteration_scale;
1754                                 loc += ('0 1 0' * random()) * 128 * iteration_scale;
1755                                 tracebox(loc, STAT(PL_MIN, player), STAT(PL_MAX, player), loc, MOVE_NORMAL, player);
1756                                 if(trace_fraction == 1.0 && !trace_startsolid)
1757                                 {
1758                                         traceline(closest_target.origin, loc, MOVE_NOMONSTERS, closest_target); // double check to make sure we're not spawning outside the NULL
1759                                         if(trace_fraction == 1.0 && !trace_startsolid)
1760                                         {
1761                                                 setorigin(player, loc);
1762                                                 player.angles = normalize(loc - closest_target.origin) * RAD2DEG;
1763                                                 return false;
1764                                         }
1765                                 }
1766                         }
1767                 }
1768         }
1769
1770         if(autocvar_g_onslaught_spawn_at_generator)
1771         if(random() <= autocvar_g_onslaught_spawn_at_generator_chance)
1772         {
1773                 float random_target = autocvar_g_onslaught_spawn_at_generator_random;
1774                 entity tmp_entity, closest_target = NULL;
1775                 vector spawn_loc = player.ons_deathloc;
1776
1777                 // new joining player or round reset, don't bother checking
1778                 if(spawn_loc == '0 0 0') { return false; }
1779
1780                 if(random_target) { RandomSelection_Init(); }
1781
1782                 for(tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext)
1783                 {
1784                         if(random_target)
1785                                 RandomSelection_AddEnt(tmp_entity, 1, 1);
1786                         else
1787                         {
1788                                 if(SAME_TEAM(tmp_entity, player))
1789                                 if(vlen2(tmp_entity.origin - spawn_loc) <= vlen2(closest_target.origin - spawn_loc) || closest_target == NULL)
1790                                         closest_target = tmp_entity;
1791                         }
1792                 }
1793
1794                 if(random_target) { closest_target = RandomSelection_chosen_ent; }
1795
1796                 if(closest_target)
1797                 {
1798                         float i;
1799                         vector loc;
1800                         float iteration_scale = 1;
1801                         for(i = 0; i < 10; ++i)
1802                         {
1803                                 iteration_scale -= i / 10;
1804                                 loc = closest_target.origin + '0 0 128' * iteration_scale;
1805                                 loc += ('0 1 0' * random()) * 256 * iteration_scale;
1806                                 tracebox(loc, STAT(PL_MIN, player), STAT(PL_MAX, player), loc, MOVE_NORMAL, player);
1807                                 if(trace_fraction == 1.0 && !trace_startsolid)
1808                                 {
1809                                         traceline(closest_target.origin, loc, MOVE_NOMONSTERS, closest_target); // double check to make sure we're not spawning outside the NULL
1810                                         if(trace_fraction == 1.0 && !trace_startsolid)
1811                                         {
1812                                                 setorigin(player, loc);
1813                                                 player.angles = normalize(loc - closest_target.origin) * RAD2DEG;
1814                                                 return false;
1815                                         }
1816                                 }
1817                         }
1818                 }
1819         }
1820
1821         return false;
1822 }
1823
1824 MUTATOR_HOOKFUNCTION(ons, PlayerDies)
1825 {
1826         entity frag_target = M_ARGV(2, entity);
1827
1828         frag_target.ons_deathloc = frag_target.origin;
1829         entity l;
1830         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
1831         {
1832                 l.sprite.SendFlags |= 16;
1833         }
1834         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
1835         {
1836                 l.sprite.SendFlags |= 16;
1837         }
1838
1839         if ( autocvar_g_onslaught_spawn_choose )
1840         if ( ons_Count_SelfControlPoints(frag_target) > 1 )
1841                 stuffcmd(frag_target, "qc_cmd_cl hud clickradar\n");
1842
1843         return false;
1844 }
1845
1846 MUTATOR_HOOKFUNCTION(ons, MonsterMove)
1847 {
1848         entity mon = M_ARGV(0, entity);
1849
1850         entity e = find(NULL, targetname, mon.target);
1851         if (e != NULL)
1852                 mon.team = e.team;
1853 }
1854
1855 void ons_MonsterSpawn_Delayed(entity this)
1856 {
1857         entity own = this.owner;
1858
1859         if(!own) { delete(this); return; }
1860
1861         if(own.targetname)
1862         {
1863                 entity e = find(NULL, target, own.targetname);
1864                 if(e != NULL)
1865                 {
1866                         own.team = e.team;
1867
1868                         own.use(own, e, NULL);
1869                 }
1870         }
1871
1872         delete(this);
1873 }
1874
1875 MUTATOR_HOOKFUNCTION(ons, MonsterSpawn)
1876 {
1877         entity mon = M_ARGV(0, entity);
1878
1879         entity e = spawn();
1880         e.owner = mon;
1881         InitializeEntity(e, ons_MonsterSpawn_Delayed, INITPRIO_FINDTARGET);
1882 }
1883
1884 void ons_TurretSpawn_Delayed(entity this)
1885 {
1886         entity own = this.owner;
1887
1888         if(!own) { delete(this); return; }
1889
1890         if(own.targetname)
1891         {
1892                 entity e = find(NULL, target, own.targetname);
1893                 if(e != NULL)
1894                 {
1895                         own.team = e.team;
1896                         own.active = ACTIVE_NOT;
1897
1898                         own.use(own, e, NULL);
1899                 }
1900         }
1901
1902         delete(this);
1903 }
1904
1905 MUTATOR_HOOKFUNCTION(ons, TurretSpawn)
1906 {
1907         entity turret = M_ARGV(0, entity);
1908
1909         entity e = spawn();
1910         e.owner = turret;
1911         InitializeEntity(e, ons_TurretSpawn_Delayed, INITPRIO_FINDTARGET);
1912
1913         return false;
1914 }
1915
1916 MUTATOR_HOOKFUNCTION(ons, HavocBot_ChooseRole)
1917 {
1918         entity bot = M_ARGV(0, entity);
1919
1920         havocbot_ons_reset_role(bot);
1921         return true;
1922 }
1923
1924 MUTATOR_HOOKFUNCTION(ons, CheckAllowedTeams)
1925 {
1926         // onslaught is special
1927         for(entity tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext)
1928         {
1929                 switch(tmp_entity.team)
1930                 {
1931                         case NUM_TEAM_1: c1 = 0; break;
1932                         case NUM_TEAM_2: c2 = 0; break;
1933                         case NUM_TEAM_3: c3 = 0; break;
1934                         case NUM_TEAM_4: c4 = 0; break;
1935                 }
1936         }
1937
1938         return true;
1939 }
1940
1941 MUTATOR_HOOKFUNCTION(ons, SpectateCopy)
1942 {
1943         entity spectatee = M_ARGV(0, entity);
1944         entity client = M_ARGV(1, entity);
1945
1946         STAT(ROUNDLOST, client) = STAT(ROUNDLOST, spectatee); // make spectators see it too
1947 }
1948
1949 MUTATOR_HOOKFUNCTION(ons, SV_ParseClientCommand)
1950 {
1951         if(MUTATOR_RETURNVALUE) // command was already handled?
1952                 return false;
1953
1954         entity player = M_ARGV(0, entity);
1955         string cmd_name = M_ARGV(1, string);
1956         int cmd_argc = M_ARGV(2, int);
1957
1958         if ( cmd_name == "ons_spawn" )
1959         {
1960                 vector pos = player.origin;
1961                 if(cmd_argc > 1)
1962                         pos_x = stof(argv(1));
1963                 if(cmd_argc > 2)
1964                         pos_y = stof(argv(2));
1965                 if(cmd_argc > 3)
1966                         pos_z = stof(argv(3));
1967
1968                 if ( IS_PLAYER(player) )
1969                 {
1970                         if ( !STAT(FROZEN, player) )
1971                         {
1972                                 entity source_point = ons_Nearest_ControlPoint(player, player.origin, autocvar_g_onslaught_teleport_radius);
1973
1974                                 if ( !source_point && player.health > 0 )
1975                                 {
1976                                         sprint(player, "\nYou need to be next to a control point\n");
1977                                         return true;
1978                                 }
1979
1980
1981                                 entity closest_target = ons_Nearest_ControlPoint_2D(player, pos, autocvar_g_onslaught_click_radius);
1982
1983                                 if ( closest_target == NULL )
1984                                 {
1985                                         sprint(player, "\nNo control point found\n");
1986                                         return true;
1987                                 }
1988
1989                                 if ( player.health <= 0 )
1990                                 {
1991                                         player.ons_spawn_by = closest_target;
1992                                         player.respawn_flags = player.respawn_flags | RESPAWN_FORCE;
1993                                 }
1994                                 else
1995                                 {
1996                                         if ( source_point == closest_target )
1997                                         {
1998                                                 sprint(player, "\nTeleporting to the same point\n");
1999                                                 return true;
2000                                         }
2001
2002                                         if ( !ons_Teleport(player,closest_target,autocvar_g_onslaught_teleport_radius,true) )
2003                                                 sprint(player, "\nUnable to teleport there\n");
2004                                 }
2005
2006                                 return true;
2007                         }
2008
2009                         sprint(player, "\nNo teleportation for you\n");
2010                 }
2011
2012                 return true;
2013         }
2014         return false;
2015 }
2016
2017 MUTATOR_HOOKFUNCTION(ons, PlayerUseKey)
2018 {
2019         if(MUTATOR_RETURNVALUE || game_stopped) return false;
2020
2021         entity player = M_ARGV(0, entity);
2022
2023         if((time > player.teleport_antispam) && (!IS_DEAD(player)) && !player.vehicle)
2024         {
2025                 entity source_point = ons_Nearest_ControlPoint(player, player.origin, autocvar_g_onslaught_teleport_radius);
2026                 if ( source_point )
2027                 {
2028                         stuffcmd(player, "qc_cmd_cl hud clickradar\n");
2029                         return true;
2030                 }
2031         }
2032 }
2033
2034 MUTATOR_HOOKFUNCTION(ons, PlayHitsound)
2035 {
2036         entity frag_victim = M_ARGV(0, entity);
2037
2038         return (frag_victim.classname == "onslaught_generator" && !frag_victim.isshielded)
2039                 || (frag_victim.classname == "onslaught_controlpoint_icon" && !frag_victim.owner.isshielded);
2040 }
2041
2042 MUTATOR_HOOKFUNCTION(ons, SendWaypoint)
2043 {
2044     entity wp = M_ARGV(0, entity);
2045     entity to = M_ARGV(1, entity);
2046     int sf = M_ARGV(2, int);
2047     int wp_flag = M_ARGV(3, int);
2048
2049         if(sf & 16)
2050         {
2051                 if(wp.owner.classname == "onslaught_controlpoint")
2052                 {
2053                         entity wp_owner = wp.owner;
2054                         entity e = WaypointSprite_getviewentity(to);
2055                         if(SAME_TEAM(e, wp_owner) && wp_owner.goalentity.health >= wp_owner.goalentity.max_health) { wp_flag |= 2; }
2056                         if(!ons_ControlPoint_Attackable(wp_owner, e.team)) { wp_flag |= 2; }
2057                 }
2058                 if(wp.owner.classname == "onslaught_generator")
2059                 {
2060                         entity wp_owner = wp.owner;
2061                         if(wp_owner.isshielded && wp_owner.health >= wp_owner.max_health) { wp_flag |= 2; }
2062                         if(wp_owner.health <= 0) { wp_flag |= 2; }
2063                 }
2064         }
2065
2066         M_ARGV(3, int) = wp_flag;
2067 }
2068
2069 MUTATOR_HOOKFUNCTION(ons, TurretValidateTarget)
2070 {
2071         entity turret_target = M_ARGV(1, entity);
2072
2073         if(substring(turret_target.classname, 0, 10) == "onslaught_") // don't attack onslaught targets, that's the player's job!
2074         {
2075                 M_ARGV(3, float) = -3;
2076                 return true;
2077         }
2078
2079         return false;
2080 }
2081
2082 MUTATOR_HOOKFUNCTION(ons, TurretThink)
2083 {
2084     entity turret = M_ARGV(0, entity);
2085
2086         // ONS uses somewhat backwards linking.
2087         if(turret.target)
2088         {
2089                 entity e = find(NULL, targetname, turret.target);
2090                 if (e != NULL)
2091                         turret.team = e.team;
2092         }
2093
2094         if(turret.team != turret.tur_head.team)
2095                 turret_respawn(turret);
2096 }
2097
2098
2099 // ==========
2100 // Spawnfuncs
2101 // ==========
2102
2103 /*QUAKED spawnfunc_onslaught_link (0 .5 .8) (-16 -16 -16) (16 16 16)
2104   Link between control points.
2105
2106   This entity targets two different spawnfunc_onslaught_controlpoint or spawnfunc_onslaught_generator entities, and suppresses shielding on both if they are owned by different teams.
2107
2108 keys:
2109 "target" - first control point.
2110 "target2" - second control point.
2111  */
2112 spawnfunc(onslaught_link)
2113 {
2114         if(!g_onslaught) { delete(this); return; }
2115
2116         if (this.target == "" || this.target2 == "")
2117                 objerror(this, "target and target2 must be set\n");
2118
2119         this.ons_worldlinknext = ons_worldlinklist; // link into ons_worldlinklist
2120         ons_worldlinklist = this;
2121
2122         InitializeEntity(this, ons_DelayedLinkSetup, INITPRIO_FINDTARGET);
2123         Net_LinkEntity(this, false, 0, ons_Link_Send);
2124 }
2125
2126 /*QUAKED spawnfunc_onslaught_controlpoint (0 .5 .8) (-32 -32 0) (32 32 128)
2127   Control point. Be sure to give this enough clearance so that the shootable part has room to exist
2128
2129   This should link to an spawnfunc_onslaught_controlpoint entity or spawnfunc_onslaught_generator entity.
2130
2131 keys:
2132 "targetname" - name that spawnfunc_onslaught_link entities will use to target this.
2133 "target" - target any entities that are tied to this control point, such as vehicles and buildable structure entities.
2134 "message" - name of this control point (should reflect the location in the map, such as "center bridge", "north tower", etc)
2135  */
2136
2137 spawnfunc(onslaught_controlpoint)
2138 {
2139         if(!g_onslaught) { delete(this); return; }
2140
2141         ons_ControlPoint_Setup(this);
2142 }
2143
2144 /*QUAKED spawnfunc_onslaught_generator (0 .5 .8) (-32 -32 -24) (32 32 64)
2145   Base generator.
2146
2147   spawnfunc_onslaught_link entities can target this.
2148
2149 keys:
2150 "team" - team that owns this generator (5 = red, 14 = blue, etc), MUST BE SET.
2151 "targetname" - name that spawnfunc_onslaught_link entities will use to target this.
2152  */
2153 spawnfunc(onslaught_generator)
2154 {
2155         if(!g_onslaught) { delete(this); return; }
2156         if(!this.team) { objerror(this, "team must be set"); }
2157
2158         ons_GeneratorSetup(this);
2159 }
2160
2161 // scoreboard setup
2162 void ons_ScoreRules()
2163 {
2164         CheckAllowedTeams(NULL);
2165         int teams = 0;
2166         if(c1 >= 0) teams |= BIT(0);
2167         if(c2 >= 0) teams |= BIT(1);
2168         if(c3 >= 0) teams |= BIT(2);
2169         if(c4 >= 0) teams |= BIT(3);
2170         GameRules_scoring(teams, SFL_SORT_PRIO_PRIMARY, 0, {
2171             field_team(ST_ONS_CAPS, "destroyed", SFL_SORT_PRIO_PRIMARY);
2172             field(SP_ONS_CAPS, "caps", SFL_SORT_PRIO_SECONDARY);
2173             field(SP_ONS_TAKES, "takes", 0);
2174         });
2175 }
2176
2177 void ons_DelayedInit(entity this) // Do this check with a delay so we can wait for teams to be set up
2178 {
2179         ons_ScoreRules();
2180
2181         round_handler_Spawn(Onslaught_CheckPlayers, Onslaught_CheckWinner, Onslaught_RoundStart);
2182         round_handler_Init(5, autocvar_g_onslaught_warmup, autocvar_g_onslaught_round_timelimit);
2183 }
2184
2185 void ons_Initialize()
2186 {
2187         g_onslaught = true;
2188         ons_captureshield_force = autocvar_g_onslaught_shield_force;
2189
2190         cam = new(objective_camera);
2191
2192         InitializeEntity(NULL, ons_DelayedInit, INITPRIO_GAMETYPE);
2193 }