qcsrc/common/gamemodes/gamemode/freezetag/sv_freezetag.qc

   1 #include "sv_freezetag.qh"
   2
   3 #include <common/resources/sv_resources.qh>
   4 #include <server/elimination.qh>
   5
   6 float autocvar_g_freezetag_frozen_maxtime;
   7 float autocvar_g_freezetag_revive_clearspeed;
   8 float autocvar_g_freezetag_round_timelimit;
   9 //int autocvar_g_freezetag_teams;
  10 int autocvar_g_freezetag_teams_override;
  11 float autocvar_g_freezetag_warmup;
  12
  13 float autocvar_g_ft_start_health = 100;
  14 float autocvar_g_ft_start_armor = 100;
  15 float autocvar_g_ft_start_ammo_shells = 60;
  16 float autocvar_g_ft_start_ammo_nails = 320;
  17 float autocvar_g_ft_start_ammo_rockets = 160;
  18 float autocvar_g_ft_start_ammo_cells = 180;
  19 float autocvar_g_ft_start_ammo_plasma = 180;
  20 float autocvar_g_ft_start_ammo_fuel = 0;
  21
  22 void freezetag_count_alive_players()
  23 {
  24         total_players = 0;
  25         for (int i = 1; i <= NUM_TEAMS; ++i)
  26         {
  27                 Team_SetNumberOfAlivePlayers(Team_GetTeamFromIndex(i), 0);
  28         }
  29         FOREACH_CLIENT(IS_PLAYER(it) && Entity_HasValidTeam(it),
  30         {
  31                 ++total_players;
  32                 if (GetResource(it, RES_HEALTH) < 1 || STAT(FROZEN, it) == FROZEN_NORMAL)
  33                 {
  34                         continue;
  35                 }
  36                 entity team_ = Entity_GetTeam(it);
  37                 int num_alive = Team_GetNumberOfAlivePlayers(team_);
  38                 ++num_alive;
  39                 Team_SetNumberOfAlivePlayers(team_, num_alive);
  40         });
  41         FOREACH_CLIENT(IS_REAL_CLIENT(it),
  42         {
  43                 STAT(REDALIVE, it) = Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(1));
  44                 STAT(BLUEALIVE, it) = Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(2));
  45                 STAT(YELLOWALIVE, it) = Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(3));
  46                 STAT(PINKALIVE, it) = Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(4));
  47         });
  48
  49         eliminatedPlayers.SendFlags |= 1;
  50 }
  51
  52 bool freezetag_CheckTeams()
  53 {
  54         static float prev_missing_teams_mask;
  55         if (Team_GetNumberOfAliveTeams() == NumTeams(freezetag_teams))
  56         {
  57                 if(prev_missing_teams_mask > 0)
  58                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
  59                 prev_missing_teams_mask = -1;
  60                 return true;
  61         }
  62         if(total_players == 0)
  63         {
  64                 if(prev_missing_teams_mask > 0)
  65                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
  66                 prev_missing_teams_mask = -1;
  67                 return false;
  68         }
  69         int missing_teams_mask = 0;
  70         for (int i = 1; i <= NUM_TEAMS; ++i)
  71         {
  72                 if ((freezetag_teams & Team_IndexToBit(i)) &&
  73                         (Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(i)) == 0))
  74                 {
  75                         missing_teams_mask |= Team_IndexToBit(i);
  76                 }
  77         }
  78         if(prev_missing_teams_mask != missing_teams_mask)
  79         {
  80                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
  81                 prev_missing_teams_mask = missing_teams_mask;
  82         }
  83         return false;
  84 }
  85
  86 void nades_Clear(entity);
  87 void nades_GiveBonus(entity player, float score);
  88
  89 bool freezetag_CheckWinner()
  90 {
  91         if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
  92         {
  93                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_OVER);
  94                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_OVER);
  95                 FOREACH_CLIENT(IS_PLAYER(it), {
  96                         it.freezetag_frozen_timeout = 0;
  97                         it.freezetag_revive_time = 0;
  98                         nades_Clear(it);
  99                 });
 100                 game_stopped = true;
 101                 round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
 102                 return true;
 103         }
 104
 105         int winner_team = Team_GetWinnerAliveTeam();
 106         if (!winner_team)
 107                 return false;
 108
 109         if(winner_team > 0)
 110         {
 111                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
 112                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_ROUND_TEAM_WIN));
 113                 TeamScore_AddToTeam(winner_team, ST_FT_ROUNDS, +1);
 114         }
 115         else if(winner_team == -1)
 116         {
 117                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_TIED);
 118                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_TIED);
 119         }
 120
 121         FOREACH_CLIENT(IS_PLAYER(it), {
 122                 it.freezetag_frozen_timeout = 0;
 123                 it.freezetag_revive_time = 0;
 124                 nades_Clear(it);
 125         });
 126
 127         game_stopped = true;
 128         round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
 129         return true;
 130 }
 131
 132 entity freezetag_LastPlayerForTeam(entity this)
 133 {
 134         entity last_pl = NULL;
 135         FOREACH_CLIENT(IS_PLAYER(it) && it != this && SAME_TEAM(it, this), {
 136                 if (STAT(FROZEN, it) != FROZEN_NORMAL && GetResource(it, RES_HEALTH) >= 1)
 137                 {
 138                         if (!last_pl)
 139                                 last_pl = it;
 140                         else
 141                                 return NULL;
 142                 }
 143         });
 144         return last_pl;
 145 }
 146
 147 void freezetag_LastPlayerForTeam_Notify(entity this)
 148 {
 149         if(round_handler_IsActive())
 150         if(round_handler_IsRoundStarted())
 151         {
 152                 entity pl = freezetag_LastPlayerForTeam(this);
 153                 if(pl)
 154                         Send_Notification(NOTIF_ONE, pl, MSG_CENTER, CENTER_ALONE);
 155         }
 156 }
 157
 158 void freezetag_Add_Score(entity targ, entity attacker)
 159 {
 160         if(attacker == targ)
 161         {
 162                 // you froze your own dumb self
 163                 // counted as "suicide" already
 164                 GameRules_scoring_add(targ, SCORE, -1);
 165         }
 166         else if(IS_PLAYER(attacker))
 167         {
 168                 // got frozen by an enemy
 169                 // counted as "kill" and "death" already
 170                 GameRules_scoring_add(targ, SCORE, -1);
 171                 GameRules_scoring_add(attacker, SCORE, +1);
 172         }
 173         // else nothing - got frozen by the game type rules themselves
 174 }
 175
 176 // to be called when the player is frozen by freezetag (on death, spectator join etc), gives the score
 177 void freezetag_Freeze(entity targ, entity attacker)
 178 {
 179         if(STAT(FROZEN, targ))
 180                 return;
 181
 182         targ.freezetag_frozen_armor = GetResource(targ, RES_ARMOR);
 183
 184         targ.freezetag_frozen_time = time;
 185         if (autocvar_g_freezetag_revive_auto && autocvar_g_freezetag_frozen_maxtime > 0)
 186                 targ.freezetag_frozen_timeout = time + autocvar_g_freezetag_frozen_maxtime;
 187
 188         Freeze(targ, 0, FROZEN_NORMAL, true);
 189
 190         freezetag_count_alive_players();
 191
 192         freezetag_Add_Score(targ, attacker);
 193 }
 194
 195 bool freezetag_isEliminated(entity e)
 196 {
 197         if(IS_PLAYER(e) && (STAT(FROZEN, e) == FROZEN_NORMAL || IS_DEAD(e)))
 198                 return true;
 199         return false;
 200 }
 201
 202
 203 // ================
 204 // Bot player logic
 205 // ================
 206
 207 void(entity this) havocbot_role_ft_freeing;
 208 void(entity this) havocbot_role_ft_offense;
 209
 210 void havocbot_goalrating_ft_freeplayers(entity this, float ratingscale, vector org, float sradius)
 211 {
 212         entity best_pl = NULL;
 213         float best_dist2 = FLOAT_MAX;
 214         FOREACH_CLIENT(IS_PLAYER(it) && it != this && SAME_TEAM(it, this), {
 215                 if (STAT(FROZEN, it) == FROZEN_NORMAL)
 216                 {
 217                         if(vdist(it.origin - org, >, sradius))
 218                                 continue;
 219                         navigation_routerating(this, it, ratingscale, 2000);
 220                 }
 221                 else if (best_dist2
 222                         && GetResource(it, RES_HEALTH) < GetResource(this, RES_HEALTH) + 30
 223                         && vlen2(it.origin - org) < best_dist2)
 224                 {
 225                         // If teamate is not frozen still seek them out as fight better
 226                         // in a group.
 227                         best_dist2 = vlen2(it.origin - org);
 228                         if (best_dist2 < 700 ** 2)
 229                         {
 230                                 best_pl = NULL;
 231                                 best_dist2 = 0; // already close to a teammate
 232                         }
 233                         else
 234                                 best_pl = it;
 235                 }
 236         });
 237         if (best_pl)
 238                 navigation_routerating(this, best_pl, ratingscale / 2, 2000);
 239 }
 240
 241 void havocbot_role_ft_offense(entity this)
 242 {
 243         if(IS_DEAD(this))
 244                 return;
 245
 246         if (!this.havocbot_role_timeout)
 247                 this.havocbot_role_timeout = time + random() * 10 + 20;
 248
 249         // Count how many players on team are unfrozen.
 250         int unfrozen = 0;
 251         FOREACH_CLIENT(IS_PLAYER(it) && SAME_TEAM(it, this) && STAT(FROZEN, it) != FROZEN_NORMAL, {
 252                 unfrozen++;
 253         });
 254
 255         // If only one left on team or if role has timed out then start trying to free players.
 256         if ((!unfrozen && STAT(FROZEN, this) != FROZEN_NORMAL) || time > this.havocbot_role_timeout)
 257         {
 258                 LOG_TRACE("changing role to freeing");
 259                 this.havocbot_role = havocbot_role_ft_freeing;
 260                 this.havocbot_role_timeout = 0;
 261                 return;
 262         }
 263
 264         if (navigation_goalrating_timeout(this))
 265         {
 266                 navigation_goalrating_start(this);
 267                 havocbot_goalrating_items(this, 12000, this.origin, 10000);
 268                 havocbot_goalrating_enemyplayers(this, 10000, this.origin, 10000);
 269                 havocbot_goalrating_ft_freeplayers(this, 9000, this.origin, 10000);
 270                 havocbot_goalrating_waypoints(this, 1, this.origin, 3000);
 271                 navigation_goalrating_end(this);
 272
 273                 navigation_goalrating_timeout_set(this);
 274         }
 275 }
 276
 277 void havocbot_role_ft_freeing(entity this)
 278 {
 279         if(IS_DEAD(this))
 280                 return;
 281
 282         if (!this.havocbot_role_timeout)
 283                 this.havocbot_role_timeout = time + random() * 10 + 20;
 284
 285         if (time > this.havocbot_role_timeout)
 286         {
 287                 LOG_TRACE("changing role to offense");
 288                 this.havocbot_role = havocbot_role_ft_offense;
 289                 this.havocbot_role_timeout = 0;
 290                 return;
 291         }
 292
 293         if (navigation_goalrating_timeout(this))
 294         {
 295                 navigation_goalrating_start(this);
 296                 havocbot_goalrating_items(this, 10000, this.origin, 10000);
 297                 havocbot_goalrating_enemyplayers(this, 5000, this.origin, 10000);
 298                 havocbot_goalrating_ft_freeplayers(this, 20000, this.origin, 10000);
 299                 havocbot_goalrating_waypoints(this, 1, this.origin, 3000);
 300                 navigation_goalrating_end(this);
 301
 302                 navigation_goalrating_timeout_set(this);
 303         }
 304 }
 305
 306
 307 // ==============
 308 // Hook Functions
 309 // ==============
 310
 311 void ft_RemovePlayer(entity this)
 312 {
 313         if (STAT(FROZEN, this) != FROZEN_NORMAL)
 314                 freezetag_LastPlayerForTeam_Notify(this);
 315         Unfreeze(this, false);
 316
 317         SetResourceExplicit(this, RES_HEALTH, 0); // neccessary to correctly count alive players
 318         freezetag_count_alive_players();
 319 }
 320
 321 MUTATOR_HOOKFUNCTION(ft, ClientDisconnect)
 322 {
 323         entity player = M_ARGV(0, entity);
 324
 325         ft_RemovePlayer(player);
 326         return true;
 327 }
 328
 329 MUTATOR_HOOKFUNCTION(ft, MakePlayerObserver)
 330 {
 331         entity player = M_ARGV(0, entity);
 332
 333         ft_RemovePlayer(player);
 334 }
 335
 336 MUTATOR_HOOKFUNCTION(ft, PlayerDies)
 337 {
 338         entity frag_attacker = M_ARGV(1, entity);
 339         entity frag_target = M_ARGV(2, entity);
 340         float frag_deathtype = M_ARGV(3, float);
 341
 342         if(round_handler_IsActive())
 343         if(round_handler_CountdownRunning())
 344         {
 345                 if (STAT(FROZEN, frag_target) == FROZEN_NORMAL)
 346                         Unfreeze(frag_target, true);
 347                 freezetag_count_alive_players();
 348                 frag_target.respawn_time = time;
 349                 frag_target.respawn_flags |= RESPAWN_FORCE;
 350                 return true;
 351         }
 352
 353         frag_target.respawn_time = time + 1;
 354         frag_target.respawn_flags |= RESPAWN_FORCE;
 355
 356         // Cases DEATH_TEAMCHANGE and DEATH_AUTOTEAMCHANGE are needed to fix a bug whe
 357         // you succeed changing team through the menu: you both really die (gibbing) and get frozen
 358         if(ITEM_DAMAGE_NEEDKILL(frag_deathtype)
 359                 || frag_deathtype == DEATH_TEAMCHANGE.m_id || frag_deathtype == DEATH_AUTOTEAMCHANGE.m_id)
 360         {
 361                 // let the player die, they will be automatically frozen when they respawn
 362                 if (STAT(FROZEN, frag_target) != FROZEN_NORMAL)
 363                 {
 364                         freezetag_Add_Score(frag_target, frag_attacker);
 365                         freezetag_count_alive_players();
 366                         freezetag_LastPlayerForTeam_Notify(frag_target);
 367                         frag_target.freezetag_frozen_timeout = -2; // freeze on respawn
 368                 }
 369                 else
 370                 {
 371                         // soft-kill: setting health to something >= 1 after death, ammo won't be reset
 372                         SetResourceExplicit(frag_target, RES_HEALTH, 1);
 373                         // restore armor as it was removed in PlayerDamage
 374                         SetResourceExplicit(frag_target, RES_ARMOR, frag_target.freezetag_frozen_armor);
 375
 376                         // relocate
 377                         entity spot = SelectSpawnPoint(frag_target, true);
 378                         setorigin(frag_target, spot.origin);
 379                         frag_target.oldorigin = frag_target.origin;
 380                         frag_target.fixangle = true; // turn this way immediately
 381                         frag_target.angles = vec2(spot.angles);
 382                         frag_target.velocity = '0 0 0';
 383                         frag_target.oldvelocity = frag_target.velocity; // prevents fall damage, see CreatureFrame_FallDamage
 384                         frag_target.avelocity = '0 0 0';
 385                         frag_target.punchangle = '0 0 0';
 386                         frag_target.punchvector = '0 0 0';
 387                 }
 388                 return true;
 389         }
 390
 391         if (STAT(FROZEN, frag_target) == FROZEN_NORMAL)
 392                 return true;
 393
 394         freezetag_Freeze(frag_target, frag_attacker);
 395         freezetag_LastPlayerForTeam_Notify(frag_target);
 396
 397         if(frag_attacker == frag_target || frag_attacker == NULL)
 398         {
 399                 if(IS_PLAYER(frag_target))
 400                         Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_FREEZETAG_SELF);
 401                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_FREEZETAG_SELF, frag_target.netname);
 402         }
 403         else
 404         {
 405                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_FREEZETAG_FREEZE, frag_target.netname, frag_attacker.netname);
 406         }
 407
 408         return true;
 409 }
 410
 411 MUTATOR_HOOKFUNCTION(ft, PlayerSpawn)
 412 {
 413         entity player = M_ARGV(0, entity);
 414
 415         if(player.freezetag_frozen_timeout == -1) // if PlayerSpawn is called by reset_map_players
 416                 return true; // do nothing, round is starting right now
 417
 418         if(player.freezetag_frozen_timeout <= -2) // player was dead
 419         {
 420                 freezetag_Freeze(player, NULL);
 421                 return true;
 422         }
 423
 424         freezetag_count_alive_players();
 425
 426         if(round_handler_IsActive())
 427         if(round_handler_IsRoundStarted())
 428         {
 429                 Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_FREEZETAG_SPAWN_LATE);
 430                 freezetag_Freeze(player, NULL);
 431         }
 432
 433         return true;
 434 }
 435
 436 MUTATOR_HOOKFUNCTION(ft, reset_map_players)
 437 {
 438         FOREACH_CLIENT(IS_PLAYER(it), {
 439                 CS(it).killcount = 0;
 440                 it.freezetag_revive_time = 0;
 441                 it.freezetag_frozen_timeout = -1;
 442                 PutClientInServer(it);
 443                 it.freezetag_frozen_timeout = 0;
 444         });
 445         freezetag_count_alive_players();
 446         return true;
 447 }
 448
 449 MUTATOR_HOOKFUNCTION(ft, GiveFragsForKill, CBC_ORDER_FIRST)
 450 {
 451         M_ARGV(2, float) = 0; // no frags counted in Freeze Tag
 452         return true;
 453 }
 454
 455 MUTATOR_HOOKFUNCTION(ft, Unfreeze)
 456 {
 457         entity targ = M_ARGV(0, entity);
 458         targ.freezetag_frozen_time = 0;
 459         targ.freezetag_frozen_timeout = 0;
 460 }
 461
 462 MUTATOR_HOOKFUNCTION(ft, Damage_Calculate)
 463 {
 464         entity frag_attacker = M_ARGV(1, entity);
 465         entity frag_target = M_ARGV(2, entity);
 466         //float frag_deathtype = M_ARGV(3, float);
 467         //float frag_damage = M_ARGV(4, float);
 468         vector frag_force = M_ARGV(6, vector);
 469
 470         if (STAT(FROZEN, frag_target) == FROZEN_NORMAL && autocvar_g_freezetag_revive_auto_reducible
 471                 && autocvar_g_freezetag_frozen_maxtime > 0 && autocvar_g_freezetag_revive_auto)
 472         {
 473                 float t = 0;
 474                 if ((autocvar_g_freezetag_revive_auto_reducible < 0 || DIFF_TEAM(frag_attacker, frag_target))
 475                         && frag_target.freezetag_frozen_timeout > time)
 476                 {
 477                         if (fabs(autocvar_g_freezetag_revive_auto_reducible) == 1)
 478                         {
 479                                 float maxforce = autocvar_g_freezetag_revive_auto_reducible_maxforce;
 480                                 t = vlen(frag_force);
 481                                 // limit hit force considered at once, e.g when you have the Strength
 482                                 // powerup but also with weapons that fire multiple projectiles at once (crylink)
 483                                 if (frag_target.freezetag_frozen_force + t > maxforce)
 484                                 {
 485                                         t = max(0, maxforce - frag_target.freezetag_frozen_force);
 486                                         frag_target.freezetag_frozen_force = maxforce;
 487                                 }
 488                                 else
 489                                         frag_target.freezetag_frozen_force += t;
 490                                 t *= autocvar_g_freezetag_revive_auto_reducible_forcefactor;
 491                         }
 492                         frag_target.freezetag_frozen_timeout -= t;
 493                         if (frag_target.freezetag_frozen_timeout < time)
 494                                 frag_target.freezetag_frozen_timeout = time;
 495                 }
 496         }
 497 }
 498
 499 #ifdef IN_REVIVING_RANGE
 500         #undef IN_REVIVING_RANGE
 501 #endif
 502
 503 #define IN_REVIVING_RANGE(player, it, revive_extra_size) \
 504         (it != player && !IS_DEAD(it) && SAME_TEAM(it, player) \
 505         && boxesoverlap(player.absmin - revive_extra_size, player.absmax + revive_extra_size, it.absmin, it.absmax))
 506
 507 MUTATOR_HOOKFUNCTION(ft, PlayerPreThink, CBC_ORDER_FIRST)
 508 {
 509         if(game_stopped)
 510                 return true;
 511
 512         if(round_handler_IsActive())
 513         if(!round_handler_IsRoundStarted())
 514                 return true;
 515
 516         entity player = M_ARGV(0, entity);
 517         //if (STAT(FROZEN, player) == FROZEN_NORMAL)
 518         //if(player.freezetag_frozen_timeout > 0 && time < player.freezetag_frozen_timeout)
 519                 //player.iceblock.alpha = ICE_MIN_ALPHA + (ICE_MAX_ALPHA - ICE_MIN_ALPHA) * (player.freezetag_frozen_timeout - time) / (player.freezetag_frozen_timeout - player.freezetag_frozen_time);
 520
 521         player.freezetag_frozen_force = 0;
 522
 523         if (!(frametime && IS_PLAYER(player)))
 524                 return true;
 525
 526         entity revivers_last = NULL;
 527         entity revivers_first = NULL;
 528
 529         bool player_is_reviving = false;
 530         int n = 0;
 531         vector revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
 532         FOREACH_CLIENT(IS_PLAYER(it), {
 533                 // check if player is reviving anyone
 534                 if (STAT(FROZEN, it) == FROZEN_NORMAL)
 535                 {
 536                         if ((STAT(FROZEN, player) == FROZEN_NORMAL))
 537                                 continue;
 538                         if (!IN_REVIVING_RANGE(player, it, revive_extra_size))
 539                                 continue;
 540                         player_is_reviving = true;
 541                         break;
 542                 }
 543
 544                 if (!(STAT(FROZEN, player) == FROZEN_NORMAL))
 545                         continue; // both player and it are NOT frozen
 546                 if (!IN_REVIVING_RANGE(player, it, revive_extra_size))
 547                         continue;
 548
 549                 // found a teammate that is reviving player
 550                 if (autocvar_g_freezetag_revive_time_to_score > 0 && STAT(FROZEN, player) == FROZEN_NORMAL)
 551                 {
 552                         it.freezetag_revive_time += frametime / autocvar_g_freezetag_revive_time_to_score;
 553                         while (it.freezetag_revive_time > 1)
 554                         {
 555                                 GameRules_scoring_add(it, SCORE, +1);
 556                                 it.freezetag_revive_time -= 1;
 557                         }
 558                 }
 559                 if (revivers_last)
 560                         revivers_last.chain = it;
 561                 revivers_last = it;
 562                 if (!revivers_first)
 563                         revivers_first = it;
 564                 ++n;
 565         });
 566         if (revivers_last)
 567                 revivers_last.chain = NULL;
 568
 569         // allow normal revival during automatic revival
 570         // (if we wouldn't allow it then freezetag_frozen_timeout should be checked too in the previous loop)
 571         //if (STAT(FROZEN, player) == FROZEN_NORMAL) // redundant check
 572         if (!n && player.freezetag_frozen_timeout > 0 && time >= player.freezetag_frozen_timeout)
 573                 n = -1;
 574
 575         float base_progress = 0;
 576         if  (STAT(FROZEN, player) == FROZEN_NORMAL && autocvar_g_freezetag_revive_auto
 577                 && autocvar_g_freezetag_frozen_maxtime > 0 && autocvar_g_freezetag_revive_auto_progress)
 578         {
 579                 // NOTE if auto-revival is in progress, manual revive speed is reduced so that it always takes the same amount of time
 580                 base_progress = bound(0, (1 - (player.freezetag_frozen_timeout - time) / autocvar_g_freezetag_frozen_maxtime), 1);
 581         }
 582
 583         if (!n) // no teammate nearby
 584         {
 585                 float clearspeed = autocvar_g_freezetag_revive_clearspeed;
 586                 if (STAT(FROZEN, player) == FROZEN_NORMAL)
 587                 {
 588                         if (autocvar_g_freezetag_revive_time_to_score > 0)
 589                         {
 590                                 if (STAT(REVIVE_PROGRESS, player) > base_progress)
 591                                 {
 592                                         // reduce auto-revival time based on manual revival progress
 593                                         base_progress = STAT(REVIVE_PROGRESS, player);
 594                                         player.freezetag_frozen_timeout = time + autocvar_g_freezetag_frozen_maxtime * (1 - STAT(REVIVE_PROGRESS, player));
 595                                 }
 596                                 // don't clear revive progress, it would allow stacking points
 597                                 // by entering and exiting the revival zone many times
 598                                 STAT(REVIVE_PROGRESS, player) = base_progress;
 599                         }
 600                         else
 601                                 STAT(REVIVE_PROGRESS, player) = bound(base_progress, STAT(REVIVE_PROGRESS, player) - frametime * clearspeed * (1 - base_progress), 1);
 602                 }
 603                 else if (!STAT(FROZEN, player) && !player_is_reviving)
 604                         STAT(REVIVE_PROGRESS, player) = base_progress; // thawing nobody
 605         }
 606         else if (STAT(FROZEN, player) == FROZEN_NORMAL) // OK, there is at least one teammate reviving us
 607         {
 608                 float spd = autocvar_g_freezetag_revive_speed_t2s;
 609                 if (autocvar_g_freezetag_revive_time_to_score <= 0)
 610                         spd = autocvar_g_freezetag_revive_speed * (1 - base_progress);
 611                 STAT(REVIVE_PROGRESS, player) = bound(base_progress, STAT(REVIVE_PROGRESS, player) + frametime * max(1/60, spd), 1);
 612
 613                 if(STAT(REVIVE_PROGRESS, player) >= 1)
 614                 {
 615                         float frozen_time = time - player.freezetag_frozen_time;
 616                         Unfreeze(player, false);
 617                         SetResourceExplicit(player, RES_HEALTH, ((warmup_stage) ? warmup_start_health : start_health));
 618                         player.spawnshieldtime = time + autocvar_g_freezetag_revive_spawnshield;
 619                         freezetag_count_alive_players();
 620
 621                         if(n == -1)
 622                         {
 623                                 if(autocvar_sv_eventlog)
 624                                         GameLogEcho(strcat(":ft:autorevival:", ftos(player.playerid)));
 625                                 Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_FREEZETAG_AUTO_REVIVED, frozen_time);
 626                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_FREEZETAG_AUTO_REVIVED, player.netname, frozen_time);
 627                                 return true;
 628                         }
 629
 630                         // EVERY team mate nearby gets a point (even if multiple!)
 631                         for(entity it = revivers_first; it; it = it.chain)
 632                         {
 633                                 GameRules_scoring_add(it, FREEZETAG_REVIVALS, +1);
 634                                 if (autocvar_g_freezetag_revive_time_to_score <= 0)
 635                                         GameRules_scoring_add(it, SCORE, +1);
 636                                 nades_GiveBonus(it, autocvar_g_nades_bonus_score_low);
 637                         }
 638
 639                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_FREEZETAG_REVIVED, revivers_first.netname);
 640                         Send_Notification(NOTIF_ONE, revivers_first, MSG_CENTER, CENTER_FREEZETAG_REVIVE, player.netname);
 641                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_FREEZETAG_REVIVED, player.netname, revivers_first.netname);
 642                         if(autocvar_sv_eventlog)
 643                         {
 644                                 string revivers = "";
 645                                 for(entity it = revivers_first; it; it = it.chain)
 646                                         revivers = strcat(revivers, ftos(it.playerid), ",");
 647                                 revivers = substring(revivers, 0, strlen(revivers) - 1);
 648                                 GameLogEcho(strcat(":ft:revival:", ftos(player.playerid), ":", revivers));
 649                         }
 650                 }
 651
 652                 for(entity it = revivers_first; it; it = it.chain)
 653                         STAT(REVIVE_PROGRESS, it) = STAT(REVIVE_PROGRESS, player);
 654         }
 655
 656         if (STAT(FROZEN, player) == FROZEN_NORMAL)
 657         {
 658                 entity player_wp = player.waypointsprite_attached;
 659                 if (n > 0 || (n == 0 && STAT(REVIVE_PROGRESS, player) > 0.95))
 660                 {
 661                         WaypointSprite_UpdateSprites(player_wp, WP_Reviving, WP_Null, WP_Null);
 662                         WaypointSprite_UpdateTeamRadar(player_wp, RADARICON_WAYPOINT, WP_REVIVING_COLOR);
 663                 }
 664                 else
 665                 {
 666                         WaypointSprite_UpdateSprites(player_wp, WP_Frozen, WP_Null, WP_Null);
 667                         WaypointSprite_UpdateTeamRadar(player_wp, RADARICON_WAYPOINT, WP_FROZEN_COLOR);
 668                 }
 669
 670                 WaypointSprite_UpdateMaxHealth(player_wp, 1);
 671                 WaypointSprite_UpdateHealth(player_wp, STAT(REVIVE_PROGRESS, player));
 672         }
 673
 674         return true;
 675 }
 676
 677 MUTATOR_HOOKFUNCTION(ft, SetStartItems)
 678 {
 679         start_items &= ~(IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS);
 680         if(!cvar("g_use_ammunition"))
 681                 start_items |= IT_UNLIMITED_AMMO;
 682
 683         start_health       = warmup_start_health       = autocvar_g_ft_start_health;
 684         start_armorvalue   = warmup_start_armorvalue   = autocvar_g_ft_start_armor;
 685         start_ammo_shells  = warmup_start_ammo_shells  = autocvar_g_ft_start_ammo_shells;
 686         start_ammo_nails   = warmup_start_ammo_nails   = autocvar_g_ft_start_ammo_nails;
 687         start_ammo_rockets = warmup_start_ammo_rockets = autocvar_g_ft_start_ammo_rockets;
 688         start_ammo_cells   = warmup_start_ammo_cells   = autocvar_g_ft_start_ammo_cells;
 689         start_ammo_plasma  = warmup_start_ammo_plasma  = autocvar_g_ft_start_ammo_plasma;
 690         start_ammo_fuel    = warmup_start_ammo_fuel    = autocvar_g_ft_start_ammo_fuel;
 691 }
 692
 693 MUTATOR_HOOKFUNCTION(ft, HavocBot_ChooseRole)
 694 {
 695         entity bot = M_ARGV(0, entity);
 696
 697         if (!IS_DEAD(bot))
 698         {
 699                 if (random() < 0.5)
 700                         bot.havocbot_role = havocbot_role_ft_freeing;
 701                 else
 702                         bot.havocbot_role = havocbot_role_ft_offense;
 703         }
 704
 705         // if bots spawn all at once assign them a more appropriated role after a while
 706         if (time < CS(bot).jointime + 1)
 707                 bot.havocbot_role_timeout = time + 10 + random() * 10;
 708
 709         return true;
 710 }
 711
 712 MUTATOR_HOOKFUNCTION(ft, TeamBalance_CheckAllowedTeams, CBC_ORDER_EXCLUSIVE)
 713 {
 714         M_ARGV(0, float) = freezetag_teams;
 715         return true;
 716 }
 717
 718 MUTATOR_HOOKFUNCTION(ft, SetWeaponArena)
 719 {
 720         if(M_ARGV(0, string) == "0" || M_ARGV(0, string) == "")
 721                 M_ARGV(0, string) = autocvar_g_freezetag_weaponarena;
 722 }
 723
 724 MUTATOR_HOOKFUNCTION(ft, FragCenterMessage)
 725 {
 726         entity frag_attacker = M_ARGV(0, entity);
 727         entity frag_target = M_ARGV(1, entity);
 728         //float frag_deathtype = M_ARGV(2, float);
 729         int kill_count_to_attacker = M_ARGV(3, int);
 730         int kill_count_to_target = M_ARGV(4, int);
 731
 732         if(STAT(FROZEN, frag_target) == FROZEN_NORMAL)
 733                 return; // target was already frozen, so this is just pushing them off the cliff
 734
 735         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CHOICE, CHOICE_FRAG_FREEZE, frag_target.netname, kill_count_to_attacker, (IS_BOT_CLIENT(frag_target) ? -1 : CS(frag_target).ping));
 736         Send_Notification(NOTIF_ONE, frag_target, MSG_CHOICE, CHOICE_FRAGGED_FREEZE, frag_attacker.netname, kill_count_to_target,
 737                 GetResource(frag_attacker, RES_HEALTH), GetResource(frag_attacker, RES_ARMOR), (IS_BOT_CLIENT(frag_attacker) ? -1 : CS(frag_attacker).ping));
 738
 739         return true;
 740 }
 741
 742 MUTATOR_HOOKFUNCTION(ft, SV_ParseServerCommand)
 743 {
 744         string cmd_name = M_ARGV(0, string);
 745         if (cmd_name == "shuffleteams")
 746                 shuffleteams_on_reset_map = !(round_handler_IsActive() && !round_handler_IsRoundStarted());
 747         return false;
 748 }
 749
 750 MUTATOR_HOOKFUNCTION(ft, Scores_CountFragsRemaining)
 751 {
 752         // announce remaining frags
 753         return true;
 754 }
 755
 756 void freezetag_Initialize()
 757 {
 758         freezetag_teams = autocvar_g_freezetag_teams_override;
 759         if(freezetag_teams < 2)
 760                 freezetag_teams = cvar("g_freezetag_teams"); // read the cvar directly as it gets written earlier in the same frame
 761
 762         freezetag_teams = BITS(bound(2, freezetag_teams, 4));
 763         GameRules_scoring(freezetag_teams, SFL_SORT_PRIO_PRIMARY, 0, {
 764                 field_team(ST_FT_ROUNDS, "rounds", SFL_SORT_PRIO_PRIMARY);
 765                 field(SP_FREEZETAG_REVIVALS, "revivals", 0);
 766         });
 767
 768         round_handler_Spawn(freezetag_CheckTeams, freezetag_CheckWinner, func_null);
 769         round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
 770
 771         EliminatedPlayers_Init(freezetag_isEliminated);
 772 }