qcsrc/common/animdecide.qc

   1 // player animation data for this model
   2 // each vector is as follows:
   3 // _x = startframe
   4 // _y = numframes
   5 // _z = framerate
   6 .vector anim_die1; // player dies
   7 .vector anim_die2; // player dies differently
   8 .vector anim_draw; // player pulls out a weapon
   9 .vector anim_duckwalk; // player walking while crouching
  10 .vector anim_duckjump; // player jumping from a crouch
  11 .vector anim_duckidle; // player idling while crouching
  12 .vector anim_idle; // player standing
  13 .vector anim_jump; // player jump
  14 .vector anim_pain1; // player flinches from pain
  15 .vector anim_pain2; // player flinches from pain, differently
  16 .vector anim_shoot; // player shoots
  17 .vector anim_taunt; // player taunts others (FIXME: no code references this)
  18 .vector anim_run; // player running forward
  19 .vector anim_runbackwards; // player running backward
  20 .vector anim_strafeleft; // player shuffling left quickly
  21 .vector anim_straferight; // player shuffling right quickly
  22 .vector anim_forwardright; // player running forward and right
  23 .vector anim_forwardleft; // player running forward and left
  24 .vector anim_backright; // player running backward and right
  25 .vector anim_backleft; // player running back and left
  26 .vector anim_melee; // player doing the melee action
  27 .vector anim_duck; // player doing the melee action
  28 .vector anim_duckwalkbackwards;
  29 .vector anim_duckwalkstrafeleft;
  30 .vector anim_duckwalkstraferight;
  31 .vector anim_duckwalkforwardright;
  32 .vector anim_duckwalkforwardleft;
  33 .vector anim_duckwalkbackright;
  34 .vector anim_duckwalkbackleft;
  35
  36 void animdecide_init(entity e)
  37 {
  38         vector none = '0 0 0';
  39         e.anim_die1 = animfixfps(e, '0 1 0.5', none); // 2 seconds
  40         e.anim_die2 = animfixfps(e, '1 1 0.5', none); // 2 seconds
  41         e.anim_draw = animfixfps(e, '2 1 3', none);
  42         e.anim_duckwalk = animfixfps(e, '4 1 1', none);
  43         e.anim_duckjump = animfixfps(e, '5 1 10', none);
  44         e.anim_duckidle = animfixfps(e, '6 1 1', none);
  45         e.anim_idle = animfixfps(e, '7 1 1', none);
  46         e.anim_jump = animfixfps(e, '8 1 10', none);
  47         e.anim_pain1 = animfixfps(e, '9 1 2', none); // 0.5 seconds
  48         e.anim_pain2 = animfixfps(e, '10 1 2', none); // 0.5 seconds
  49         e.anim_shoot = animfixfps(e, '11 1 5', none); // analyze models and set framerate
  50         e.anim_taunt = animfixfps(e, '12 1 0.33', none);
  51         e.anim_run = animfixfps(e, '13 1 1', none);
  52         e.anim_runbackwards = animfixfps(e, '14 1 1', none);
  53         e.anim_strafeleft = animfixfps(e, '15 1 1', none);
  54         e.anim_straferight = animfixfps(e, '16 1 1', none);
  55         e.anim_forwardright = animfixfps(e, '19 1 1', '16 1 1');
  56         e.anim_forwardleft = animfixfps(e, '20 1 1', '15 1 1');
  57         e.anim_backright = animfixfps(e, '21 1 1', '16 1 1');
  58         e.anim_backleft  = animfixfps(e, '22 1 1', '15 1 1');
  59         e.anim_melee = animfixfps(e, '23 1 1', '11 1 1');
  60         e.anim_duckwalkbackwards = animfixfps(e, '24 1 1', '4 1 1');
  61         e.anim_duckwalkstrafeleft = animfixfps(e, '25 1 1', '4 1 1');
  62         e.anim_duckwalkstraferight = animfixfps(e, '26 1 1', '4 1 1');
  63         e.anim_duckwalkforwardright = animfixfps(e, '27 1 1', '4 1 1');
  64         e.anim_duckwalkforwardleft = animfixfps(e, '28 1 1', '4 1 1');
  65         e.anim_duckwalkbackright = animfixfps(e, '29 1 1', '4 1 1');
  66         e.anim_duckwalkbackleft  = animfixfps(e, '30 1 1', '4 1 1');
  67 }
  68
  69 #define ANIMPRIO_IDLE 0
  70 #define ANIMPRIO_STATIC 1
  71 #define ANIMPRIO_ACTIVE 2
  72 #define ANIMPRIO_DEAD 3
  73
  74 vector animdecide_getupperanim(entity e)
  75 {
  76         // is there an action?
  77         vector outframe = '-1 0 0';
  78         float t, a;
  79         if(e.anim_upper_time >= e.anim_upper_implicit_time)
  80         {
  81                 a = e.anim_upper_action;
  82                 t = e.anim_upper_time;
  83         }
  84         else
  85         {
  86                 a = e.anim_upper_implicit_action;
  87                 t = e.anim_upper_implicit_time;
  88         }
  89         switch(a)
  90         {
  91                 case ANIMACTION_DRAW: outframe = e.anim_draw; break;
  92                 case ANIMACTION_PAIN1: outframe = e.anim_pain1; break;
  93                 case ANIMACTION_PAIN2: outframe = e.anim_pain2; break;
  94                 case ANIMACTION_SHOOT: outframe = e.anim_shoot; break;
  95                 case ANIMACTION_TAUNT: outframe = e.anim_taunt; break;
  96                 case ANIMACTION_MELEE: outframe = e.anim_melee; break;
  97         }
  98         if(outframe_x >= 0)
  99         {
 100                 if(time <= t + outframe_y / outframe_z)
 101                 {
 102                         // animation is running!
 103                         return vec3(outframe_x, t, ANIMPRIO_ACTIVE);
 104                 }
 105         }
 106         // or, decide the anim by state
 107         t = max(e.anim_time, e.anim_implicit_time);
 108         // but all states are for lower body!
 109         return vec3(e.anim_idle_x, t, ANIMPRIO_IDLE);
 110 }
 111
 112 vector animdecide_getloweranim(entity e)
 113 {
 114         // death etc.
 115         if(e.anim_state & ANIMSTATE_FROZEN)
 116                 return vec3(e.anim_idle_x, e.anim_time, ANIMPRIO_DEAD);
 117         if(e.anim_state & ANIMSTATE_DEAD1)
 118                 return vec3(e.anim_die1_x, e.anim_time, ANIMPRIO_DEAD);
 119         if(e.anim_state & ANIMSTATE_DEAD2)
 120                 return vec3(e.anim_die2_x, e.anim_time, ANIMPRIO_DEAD);
 121
 122         // is there an action?
 123         vector outframe = '-1 0 0';
 124         float t, a;
 125         if(e.anim_lower_time >= e.anim_lower_implicit_time)
 126         {
 127                 a = e.anim_lower_action;
 128                 t = e.anim_lower_time;
 129         }
 130         else
 131         {
 132                 a = e.anim_lower_implicit_action;
 133                 t = e.anim_lower_implicit_time;
 134         }
 135         switch(a)
 136         {
 137                 case ANIMACTION_JUMP: if(e.anim_implicit_state & ANIMIMPLICITSTATE_INAIR) { if(e.anim_state & ANIMSTATE_DUCK) outframe = e.anim_duckjump; else outframe = e.anim_jump; } break;
 138         }
 139         if(outframe_x >= 0)
 140         {
 141                 if(time <= t + outframe_y / outframe_z)
 142                 {
 143                         // animation is running!
 144                         return vec3(outframe_x, t, ANIMPRIO_ACTIVE);
 145                 }
 146         }
 147         // or, decide the anim by state
 148         t = max(e.anim_time, e.anim_implicit_time);
 149         if(e.anim_state & ANIMSTATE_DUCK)
 150         {
 151                 if(e.anim_implicit_state & ANIMIMPLICITSTATE_INAIR)
 152                         return vec3(e.anim_duckjump_x, 0, ANIMPRIO_ACTIVE); // play the END of the jump anim
 153                 else switch(e.anim_implicit_state & (ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_LEFT | ANIMIMPLICITSTATE_RIGHT))
 154                 {
 155                         case ANIMIMPLICITSTATE_FORWARD:
 156                                 return vec3(e.anim_duckwalk_x, t, ANIMPRIO_ACTIVE);
 157                         case ANIMIMPLICITSTATE_BACKWARDS:
 158                                 return vec3(e.anim_duckwalkbackwards_x, t, ANIMPRIO_ACTIVE);
 159                         case ANIMIMPLICITSTATE_RIGHT:
 160                                 return vec3(e.anim_duckwalkstraferight_x, t, ANIMPRIO_ACTIVE);
 161                         case ANIMIMPLICITSTATE_LEFT:
 162                                 return vec3(e.anim_duckwalkstrafeleft_x, t, ANIMPRIO_ACTIVE);
 163                         case ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_RIGHT:
 164                                 return vec3(e.anim_duckwalkforwardright_x, t, ANIMPRIO_ACTIVE);
 165                         case ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_LEFT:
 166                                 return vec3(e.anim_duckwalkforwardleft_x, t, ANIMPRIO_ACTIVE);
 167                         case ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_RIGHT:
 168                                 return vec3(e.anim_duckwalkbackright_x, t, ANIMPRIO_ACTIVE);
 169                         case ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_LEFT:
 170                                 return vec3(e.anim_duckwalkbackleft_x, t, ANIMPRIO_ACTIVE);
 171                         default:
 172                                 return vec3(e.anim_duckidle_x, t, ANIMPRIO_STATIC);
 173                 }
 174         }
 175         else
 176         {
 177                 if(e.anim_implicit_state & ANIMIMPLICITSTATE_INAIR)
 178                         return vec3(e.anim_jump_x, 0, ANIMPRIO_ACTIVE); // play the END of the jump anim
 179                 else switch(e.anim_implicit_state & (ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_LEFT | ANIMIMPLICITSTATE_RIGHT))
 180                 {
 181                         case ANIMIMPLICITSTATE_FORWARD:
 182                                 return vec3(e.anim_run_x, t, ANIMPRIO_ACTIVE);
 183                         case ANIMIMPLICITSTATE_BACKWARDS:
 184                                 return vec3(e.anim_runbackwards_x, t, ANIMPRIO_ACTIVE);
 185                         case ANIMIMPLICITSTATE_RIGHT:
 186                                 return vec3(e.anim_straferight_x, t, ANIMPRIO_ACTIVE);
 187                         case ANIMIMPLICITSTATE_LEFT:
 188                                 return vec3(e.anim_strafeleft_x, t, ANIMPRIO_ACTIVE);
 189                         case ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_RIGHT:
 190                                 return vec3(e.anim_forwardright_x, t, ANIMPRIO_ACTIVE);
 191                         case ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_LEFT:
 192                                 return vec3(e.anim_forwardleft_x, t, ANIMPRIO_ACTIVE);
 193                         case ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_RIGHT:
 194                                 return vec3(e.anim_backright_x, t, ANIMPRIO_ACTIVE);
 195                         case ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_LEFT:
 196                                 return vec3(e.anim_backleft_x, t, ANIMPRIO_ACTIVE);
 197                         default:
 198                                 return vec3(e.anim_idle_x, t, ANIMPRIO_IDLE);
 199                 }
 200         }
 201         // can't get here
 202 }
 203
 204 void animdecide_setimplicitstate(entity e, float onground)
 205 {
 206         float s;
 207         s = 0;
 208
 209         makevectors(e.angles);
 210         vector v;
 211         v_x = e.velocity * v_forward;
 212         v_y = e.velocity * v_right;
 213
 214         // we want to match like this:
 215         // the 8 directions shall be "evenly spaced"
 216         // that means, the forward key includes anything from -67.5 to +67.5 degrees
 217         // which then means x > |y| * cot(3pi/8)
 218         //
 219         // BUT, the engine's clip-movement-to-keyboard function uses 0.5 here,
 220         // which would be an angle range from -63.43 to +63.43 degrees, making
 221         // it slightly less likely to "hit two keys at once", so let's do this
 222         // here too
 223
 224         if(vlen(v) > 10)
 225         {
 226                 if(v_x >  fabs(v_y) * 0.5)
 227                         s |= ANIMIMPLICITSTATE_FORWARD;
 228                 if(v_x < -fabs(v_y) * 0.5)
 229                         s |= ANIMIMPLICITSTATE_BACKWARDS;
 230                 if(v_y >  fabs(v_x) * 0.5)
 231                         s |= ANIMIMPLICITSTATE_RIGHT;
 232                 if(v_y < -fabs(v_x) * 0.5)
 233                         s |= ANIMIMPLICITSTATE_LEFT;
 234         }
 235         if(!onground)
 236                 s |= ANIMIMPLICITSTATE_INAIR;
 237
 238         // detect some kinds of otherwise misdetected jumps (ground to air transition)
 239         // NOTE: currently, in CSQC this is the only jump detection, as the explicit jump action is never called!
 240         if(!(e.anim_implicit_state & ANIMIMPLICITSTATE_INAIR) && (s & ANIMIMPLICITSTATE_INAIR))
 241         {
 242                 e.anim_lower_implicit_action = ANIMACTION_JUMP;
 243                 e.anim_lower_implicit_time = time;
 244         }
 245
 246         if(s != e.anim_implicit_state)
 247         {
 248                 e.anim_implicit_state = s;
 249                 e.anim_implicit_time = time;
 250         }
 251 }
 252 void animdecide_setframes(entity e, float support_blending, .float fld_frame, .float fld_frame1time, .float fld_frame2, .float fld_frame2time)
 253 {
 254         // _x: frame
 255         // _y: start time
 256         // _z: priority
 257         vector upper = animdecide_getupperanim(e);
 258         vector lower = animdecide_getloweranim(e);
 259         //print("UPPER: ", vtos(upper), ", LOWER: ", vtos(lower), "\n");
 260         if(upper_z > lower_z)
 261                 lower = upper;
 262         else if(lower_z > upper_z)
 263                 upper = lower;
 264         if(support_blending)
 265         {
 266                 if(e.frame1time != upper_y || e.frame2time != lower_y)
 267                         BITXOR_ASSIGN(e.effects, EF_RESTARTANIM_BIT);
 268                 e.fld_frame = upper_x;
 269                 e.fld_frame1time = upper_y;
 270                 e.fld_frame2 = lower_x;
 271                 e.fld_frame2time = lower_y;
 272         }
 273         else
 274         {
 275                 if(e.frame1time != upper_y)
 276                         BITXOR_ASSIGN(e.effects, EF_RESTARTANIM_BIT);
 277                 e.fld_frame = upper_x;
 278                 e.fld_frame1time = upper_y;
 279         }
 280 }
 281
 282 void animdecide_setstate(entity e, float newstate, float restart)
 283 {
 284         if(!restart)
 285                 if(newstate == e.anim_state)
 286                         return;
 287         e.anim_state = newstate;
 288         e.anim_time = time;
 289 }
 290 void animdecide_setaction(entity e, float action, float restart)
 291 {
 292         if(action < 0)
 293         {
 294                 if(!restart)
 295                         if(action == e.anim_lower_action)
 296                                 return;
 297                 e.anim_lower_action = action;
 298                 e.anim_lower_time = time;
 299         }
 300         else
 301         {
 302                 if(!restart)
 303                         if(action == e.anim_upper_action)
 304                                 return;
 305                 e.anim_upper_action = action;
 306                 e.anim_upper_time = time;
 307         }
 308 }